00001  IDENTIFICATION DIVISION.                                         08/02/02
00002  PROGRAM-ID.             OJRCU001.                                OJRCU001
00003  AUTHOR.                 TRW.                                        LV001
00004  DATE-WRITTEN.           NOV 2001.                                OJRCU001
00005  DATE-COMPILED.                                                   OJRCU001
00006      SKIP3                                                        OJRCU001
00007 *****                                                             OJRCU001
00008 *                                                                 OJRCU001
00009 *    FUNCTION:  EDIT DATE PARMS FOR REPORT GENERATION.            OJRCU001
00010 *                                                                 OJRCU001
00011 *                                                                 OJRCU001
00012 *    MODIFICATION LOG:                                            OJRCU001
00013 *                                                                 OJRCU001
00014 *    11/26/01  INITIAL DEVELOPMENT.                               OJRCU001
00015 *              WORK ORDER:                      PROGRAMMER: JMO.  OJRCU001
00016 *                                                                 OJRCU001
00017 *    XX/XX/XX  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU001
00018 *              XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU001
00019 *              WORK ORDER:                      PROGRAMMER: XXX   OJRCU001
00020 *                                                                 OJRCU001
00021 *                                                                 OJRCU001
00022 *  DESCRIPTION:                                                   OJRCU001
00023 *                                                                 OJRCU001
00024 *    CLEAR:                                                       OJRCU001
00025 *                                                                 OJRCU001
00026 *      DATA FIELDS DISPLAYED: NONE.                               OJRCU001
00027 *      MESSAGE: NONE                                              OJRCU001
00028 *                                                                 OJRCU001
00029 *                                                                 OJRCU001
00030 *    INQUIRY:                                                     OJRCU001
00031 *                                                                 OJRCU001
00032 *      SET DEFAULT PARM VALUES                                    OJRCU001
00033 *                                                                 OJRCU001
00034 *                                                                 OJRCU001
00035 *    UPDATE:                                                      OJRCU001
00036 *                                                                 OJRCU001
00037 *      EDIT PARMS                                                 OJRCU001
00038 *                                                                 OJRCU001
00039 *                                                                 OJRCU001
00040 *    RECORDS READ:                                                OJRCU001
00041 *                                                                 OJRCU001
00042 *      MASTER:                                                    OJRCU001
00043 *                                                                 OJRCU001
00044 *        NONE.                                                    OJRCU001
00045 *                                                                 OJRCU001
00046 *                                                                 OJRCU001
00047 *      ALTERNATE INDEX:                                           OJRCU001
00048 *                                                                 OJRCU001
00049 *        NONE.                                                    OJRCU001
00050 *                                                                 OJRCU001
00051 *                                                                 OJRCU001
00052 *      REFERENCE:                                                 OJRCU001
00053 *                                                                 OJRCU001
00054 *        NONE.                                                    OJRCU001
00055 *                                                                 OJRCU001
00056 *                                                                 OJRCU001
00057 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU001
00058 *                                                                 OJRCU001
00059 *        NONE.                                                    OJRCU001
00060 *                                                                 OJRCU001
00061 *                                                                 OJRCU001
00062 *    RECORDS UPDATED:                                             OJRCU001
00063 *                                                                 OJRCU001
00064 *      MASTER:                                                    OJRCU001
00065 *                                                                 OJRCU001
00066 *        NONE.                                                    OJRCU001
00067 *                                                                 OJRCU001
00068 *                                                                 OJRCU001
00069 *      REFERENCE:                                                 OJRCU001
00070 *                                                                 OJRCU001
00071 *        NONE                                                     OJRCU001
00072 *                                                                 OJRCU001
00073 *                                                                 OJRCU001
00074 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU001
00075 *                                                                 OJRCU001
00076 *        NONE.                                                    OJRCU001
00077 *                                                                 OJRCU001
00078 *                                                                 OJRCU001
00079 *    ON-LINE EVENT FILE RECORDS WRITTEN:                          OJRCU001
00080 *                                                                 OJRCU001
00081 *      NONE.                                                      OJRCU001
00082 *                                                                 OJRCU001
00083 *                                                                 OJRCU001
00084 *    MODULES (OTHER THAN STANDARD SCREEN PROCESSING               OJRCU001
00085 *    UTILITY MODULES) LINKED TO:                                  OJRCU001
00086 *                                                                 OJRCU001
00087 *      DTSCU013 COUNT FROM SCREEN FORMAT/EDIT.                    OJRCU001
00088 *                                                                 OJRCU001
00089 *                                                                 OJRCU001
00090 *    MAINTENANCE NOTES:                                           OJRCU001
00091 *                                                                 OJRCU001
00092 *                                                                 OJRCU001
00093 *****                                                             OJRCU001
00094      SKIP3                                                        OJRCU001
00095  ENVIRONMENT DIVISION.                                            OJRCU001
00096      EJECT                                                        OJRCU001
00097  DATA DIVISION.                                                   OJRCU001
00098  WORKING-STORAGE SECTION.                                         OJRCU001
000985 77  PAN-VALET PICTURE X(24) VALUE '001OJRCU001  08/02/02'.       OJRCU001
00099                                                                   OJRCU001
00100  01  WRK-AREA.                                                    OJRCU001
00101      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'U001'.    OJRCU001
00102      05  WRK-RESP-CD                 PIC S9(08)  COMP.            OJRCU001
00103                                                                   OJRCU001
00104      05  WRK-MAPSET-NAME             PIC  X(08)  VALUE 'DTSMSET'. OJRCU001
00105      05  WRK-MAP-NAME.                                            OJRCU001
00106          10  WRK-MAP-NAME-PREFIX     PIC  X(04)  VALUE 'OJRM'.    OJRCU001
00107          10  WRK-MAP-NAME-SUFFIX     PIC  X(04)  VALUE '001 '.    OJRCU001
00108                                                                   OJRCU001
00109      05  WRK-F03-SCR-ID              PIC  X(02)  VALUE '80'.      OJRCU001
00110                                                                   OJRCU001
00111      05  WRK-MAX-PARMS               PIC  9(03)  COMP-3           OJRCU001
00112                                                  VALUE 16.        OJRCU001
00113                                                                   OJRCU001
00114      05  WRK-MSG-AREA                PIC  X(64) VALUE SPACES.     OJRCU001
00115                                                                   OJRCU001
00116      05  WRK-ENTER-MSG               PIC  X(64) VALUE             OJRCU001
00117          'PRESS ENTER WHEN DONE'.                                 OJRCU001
00118                                                                   OJRCU001
00119      05  WRK-PARM                    PIC  X(32).                  OJRCU001
00120                                                                   OJRCU001
00121      05  WRK-SUB                     PIC S9(04)  COMP.            OJRCU001
00122                                                                   OJRCU001
00123      05  WRK-CFKD-SUBMIT             PIC  X(09)                   OJRCU001
00124                                      VALUE 'F9=SUBMIT'.           OJRCU001
00125      EJECT                                                        OJRCU001
00126  01  SCREEN-CONTROL.                                              OJRCU001
00127      05  SCR-ACCESS-IND              PIC X(01).                   OJRCU001
00128          88  SCR-ACCESS-INQ                  VALUE '1'.           OJRCU001
00129          88  SCR-ACCESS-UPDATE               VALUE '2'.           OJRCU001
00130      SKIP1                                                        OJRCU001
00131      05  CURSOR-SET-IND              PIC X(01).                   OJRCU001
00132          88  CURSOR-SET-YES                  VALUE 'Y'.           OJRCU001
00133          88  CURSOR-SET-NO                   VALUE 'N'.           OJRCU001
00134          88  CURSOR-SET-GOTO                 VALUE 'G'.           OJRCU001
00135      SKIP1                                                        OJRCU001
00136      05  REQ-IND                     PIC X(01).                   OJRCU001
00137          88  REQ-ERROR                       VALUE 'O'.           OJRCU001
00138          88  REQ-JUMP                        VALUE 'J'.           OJRCU001
00139          88  REQ-INQUIRE                     VALUE 'I'.           OJRCU001
00140          88  REQ-CLEAR                       VALUE 'C'.           OJRCU001
00141          88  REQ-EDIT                        VALUE 'E'.           OJRCU001
00142          88  REQ-UPDATE                      VALUE 'U'.           OJRCU001
00143          88  REQ-CURSOR-TO-GOTO              VALUE 'G'.           OJRCU001
00144      SKIP1                                                        OJRCU001
00145      05  RESP-IND                    PIC X(01).                   OJRCU001
00146          88  RESP-SEND-MSGONLY               VALUE 'O'.           OJRCU001
00147          88  RESP-SEND-MAP                   VALUE 'M'.           OJRCU001
00148          88  RESP-JUMP                       VALUE 'J'.           OJRCU001
00149          88  RESP-CURSOR-TO-GOTO             VALUE 'G'.           OJRCU001
00150      SKIP1                                                        OJRCU001
00151      05  SCR-ATB-AN                  PIC  X(01).                  OJRCU001
00152      05  SCR-ATB-NUM                 PIC  X(01).                  OJRCU001
00153      EJECT                                                        OJRCU001
00154  01  L013-COMM-AREA.                                              OJRCU001
00155  ++INCLUDE DTSIL013                                               OJRCU001
00156      EJECT                                                        OJRCU001
00157 * ERROR MSG MODULE                                                OJRCU001
00158  01  L805-COMM-AREA.                                              OJRCU001
00159  ++INCLUDE DTSIL805                                               OJRCU001
00160      EJECT                                                        OJRCU001
00161 * MAP DEFINITION                                                  OJRCU001
00162  01  L851-COMM-AREA.                                              OJRCU001
00163  ++INCLUDE DTSIL851                                               OJRCU001
00164      SKIP3                                                        OJRCU001
00165      05  MAP-AREA REDEFINES L851-MAP-AREA.                        OJRCU001
00166          10 OJR-WINDOW-AREA.                                      OJRCU001
00167  ++INCLUDE OJRIS001                                               OJRCU001
00168      EJECT                                                        OJRCU001
00169 * ATTRIBUTE LITERALS                                              OJRCU001
00170  01  CATB-LITERALS.                                               OJRCU001
00171  ++INCLUDE DTSICATB                                               OJRCU001
00172      SKIP3                                                        OJRCU001
00173 * FUNCTION KEY DESCRIPTION LITERALS                               OJRCU001
00174  01  CFKD-LITERALS.                                               OJRCU001
00175  ++INCLUDE DTSICFKD                                               OJRCU001
00176      EJECT                                                        OJRCU001
00177 * ERROR CODE MESSAGE LITERALS                                     OJRCU001
00178  01  CECD-LITERALS.                                               OJRCU001
00179  ++INCLUDE DTSICECD                                               OJRCU001
00180      EJECT                                                        OJRCU001
00181  LINKAGE SECTION.                                                 OJRCU001
00182      SKIP3                                                        OJRCU001
00183  01  DFHCOMMAREA.                                                 OJRCU001
00184  ++INCLUDE DTSILCCM                                               OJRCU001
00185      SKIP3                                                        OJRCU001
00186 * PARM EDIT AND DATA CAPTURE AREA                                 OJRCU001
00187  ++INCLUDE OJRILCCM                                               OJRCU001
00188                                                                   OJRCU001
00189  PROCEDURE DIVISION.                                              OJRCU001
00190                                                                   OJRCU001
00191      MOVE LOW-VALUES TO MAP-AREA                                  OJRCU001
00192                                                                   OJRCU001
00193      MOVE SPACE TO REQ-IND                                        OJRCU001
00194                                                                   OJRCU001
00195      PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT                OJRCU001
00196      SKIP1                                                        OJRCU001
00197 *-----------------------------------------------------            OJRCU001
00198 *    P1000-ANALYZE-REQUEST HAS DETERMINED, BASED ON THE           OJRCU001
00199 *    "AID" KEY PRESSED AND THE CONTEXT OF THE CURRENT             OJRCU001
00200 *    REQUEST WITHIN THE PSEUDO CONVERSATION, THE TYPE             OJRCU001
00201 *    OF ACTIVITY THE WORK STATION OPERATOR HAS REQUESTED.         OJRCU001
00202 *                                                                 OJRCU001
00203 *    THE REQUEST, REFLECTED IN REQ-IND WILL NOW BE                OJRCU001
00204 *    PROCESSED.                                                   OJRCU001
00205 *                                                                 OJRCU001
00206 *    THE REQUEST PROCESSING PARAGRAPHS WILL SET RESP-IND,         OJRCU001
00207 *    INDICATING THE TYPE OF RESPONSE TO BE SENT TO THE            OJRCU001
00208 *    WORK STATION OPERATOR.                                       OJRCU001
00209 *-----------------------------------------------------            OJRCU001
00210      SKIP1                                                        OJRCU001
00211      INITIALIZE RESP-IND                                          OJRCU001
00212      SKIP1                                                        OJRCU001
00213      EVALUATE TRUE                                                OJRCU001
00214          WHEN REQ-ERROR                                           OJRCU001
00215              PERFORM P2000-REQUEST-ERROR THRU P2000-EXIT          OJRCU001
00216          WHEN REQ-JUMP                                            OJRCU001
00217              PERFORM P3000-REQUEST-JUMP THRU P3000-EXIT           OJRCU001
00218          WHEN REQ-CLEAR                                           OJRCU001
00219              PERFORM P4000-REQUEST-CLEAR   THRU P4000-EXIT        OJRCU001
00220          WHEN REQ-INQUIRE                                         OJRCU001
00221              PERFORM P6000-DETERMINE-REQ   THRU P6000-EXIT        OJRCU001
00222          WHEN OTHER                                               OJRCU001
00223              GO TO S899-ABEND                                     OJRCU001
00224      END-EVALUATE.                                                OJRCU001
00225      SKIP3                                                        OJRCU001
00226  MAINLINE-EXIT.                                                   OJRCU001
00227                                                                   OJRCU001
00228      EXEC CICS                                                    OJRCU001
00229          RETURN                                                   OJRCU001
00230      END-EXEC.                                                    OJRCU001
00231                                                                   OJRCU001
00232      GOBACK.                                                      OJRCU001
00233      EJECT                                                        OJRCU001
00234                                                                   OJRCU001
00235 /*****************************************************************OJRCU001
00236 * DETERMINE CURRENT SCREEN STATE AND REQUEST COMBINATION         *OJRCU001
00237 ******************************************************************OJRCU001
00238  P1000-ANALYZE-REQUEST.                                           OJRCU001
00239      SKIP1                                                        OJRCU001
00240 *-----------------------------------------------------            OJRCU001
00241 *     IF SCREEN IS NOT CURRENTLY DISPLAYED (JUMP TO HERE)         OJRCU001
00242 *     THEN ANY KEY PRESSED WILL BE IGNORED (WILL BE               OJRCU001
00243 *     REPLACED WITH ENTER)                                        OJRCU001
00244 *-----------------------------------------------------            OJRCU001
00245      IF LCCM-SEND-MAP-88                                          OJRCU001
00246         SET REQ-INQUIRE TO TRUE                                   OJRCU001
00247         GO TO P1000-EXIT                                          OJRCU001
00248      END-IF                                                       OJRCU001
00249      SKIP3                                                        OJRCU001
00250 *-----------------------------------------------------            OJRCU001
00251 *    REQUEST TO CLEAR THE SCREEN                                  OJRCU001
00252 *-----------------------------------------------------            OJRCU001
00253      IF LCCM-F12-88                                               OJRCU001
00254         MOVE LOW-VALUES   TO MAP-AREA                             OJRCU001
00255         SET REQ-CLEAR     TO TRUE                                 OJRCU001
00256         GO TO P1000-EXIT                                          OJRCU001
00257      END-IF                                                       OJRCU001
00258      SKIP3                                                        OJRCU001
00259 *-----------------------------------------------------            OJRCU001
00260 *    ALL OTHER PA KEYS ARE NOT ACTIVE                             OJRCU001
00261 *-----------------------------------------------------            OJRCU001
00262      IF LCCM-PA-88                                                OJRCU001
00263        PERFORM S804-INVALID-KEY THRU S804-EXIT                    OJRCU001
00264        SET REQ-ERROR TO TRUE                                      OJRCU001
00265        GO TO P1000-EXIT                                           OJRCU001
00266      END-IF                                                       OJRCU001
00267      SKIP3                                                        OJRCU001
00268 *-----------------------------------------------------            OJRCU001
00269 *    IF EXIT KEY PRESSED, JUMP TO NEXT HIGHER FUNCTION            OJRCU001
00270 *-----------------------------------------------------            OJRCU001
00271      IF LCCM-F03-88                                               OJRCU001
00272         MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                    OJRCU001
00273         SET REQ-JUMP TO TRUE                                      OJRCU001
00274         GO TO P1000-EXIT                                          OJRCU001
00275      END-IF                                                       OJRCU001
00276      SKIP3                                                        OJRCU001
00277 *-----------------------------------------------------            OJRCU001
00278 *    IF ENTER - PROCESS PARM UPDATES                              OJRCU001
00279 *-----------------------------------------------------            OJRCU001
00280      IF LCCM-ENTER-88                                             OJRCU001
00281          SET REQ-INQUIRE TO TRUE                                  OJRCU001
00282          GO TO P1000-EXIT                                         OJRCU001
00283      END-IF                                                       OJRCU001
00284      SKIP3                                                        OJRCU001
00285 *-----------------------------------------------------            OJRCU001
00286 *     ANY OTHER KEY IS INVALID                                    OJRCU001
00287 *-----------------------------------------------------            OJRCU001
00288      PERFORM S804-INVALID-KEY THRU S804-EXIT                      OJRCU001
00289      SET REQ-ERROR TO TRUE.                                       OJRCU001
00290  P1000-EXIT.                                                      OJRCU001
00291      EXIT.                                                        OJRCU001
00292      SKIP3                                                        OJRCU001
00293 /*****************************************************************OJRCU001
00294 * ANALYZE REQUEST HAS DETERMINED AN ERROR THAT MUST BE REPORTED. *OJRCU001
00295 * VERIFY THAT A MESSAGE HAS BEEN FILLED IN.                      *OJRCU001
00296 ******************************************************************OJRCU001
00297      SKIP1                                                        OJRCU001
00298  P2000-REQUEST-ERROR.                                             OJRCU001
00299      IF LCCM-MSG                                                  OJRCU001
00300         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU001
00301      ELSE                                                         OJRCU001
00302         GO TO S899-ABEND                                          OJRCU001
00303      END-IF.                                                      OJRCU001
00304  P2000-EXIT.                                                      OJRCU001
00305      EXIT.                                                        OJRCU001
00306 /*****************************************************************OJRCU001
00307 * JUMP TO A DIFFERENT SCREEN TYPE WAS REQUESTED                  *OJRCU001
00308 ******************************************************************OJRCU001
00309      SKIP1                                                        OJRCU001
00310  P3000-REQUEST-JUMP.                                              OJRCU001
00311 *-----------------------------------------------------            OJRCU001
00312 *    VERIFY THAT THE REQUESTED SCREEN EXISTS AND IS ACCESSIBLE    OJRCU001
00313 *    BY USER                                                      OJRCU001
00314 *-----------------------------------------------------            OJRCU001
00315      PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT                  OJRCU001
00316      SKIP3                                                        OJRCU001
00317 *-----------------------------------------------------            OJRCU001
00318 *    VERIFICATION RETURN LCCM-MSG IF ERROR DETECTED               OJRCU001
00319 *-----------------------------------------------------            OJRCU001
00320      IF LCCM-MSG                                                  OJRCU001
00321         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU001
00322         SET CURSOR-SET-GOTO TO TRUE                               OJRCU001
00323         GO TO P3000-EXIT                                          OJRCU001
00324      END-IF                                                       OJRCU001
00325      SKIP3                                                        OJRCU001
00326 *-----------------------------------------------------            OJRCU001
00327 *    CLEAN UP INDICATORS AND PAGING STORAGE PRIOR TO LEAVING      OJRCU001
00328 *-----------------------------------------------------            OJRCU001
00329      MOVE LOW-VALUES TO LCCM-SCR-STATUS                           OJRCU001
00330                         LCCM-SCR-HOLD-AREA                        OJRCU001
00331      MOVE +0 TO LCCM-SCR-ABSTIME                                  OJRCU001
00332      SET RESP-JUMP TO TRUE.                                       OJRCU001
00333  P3000-EXIT.                                                      OJRCU001
00334      EXIT.                                                        OJRCU001
00335 /*****************************************************************OJRCU001
00336 * CLEAR KEY WAS PRESSED                                          *OJRCU001
00337 ******************************************************************OJRCU001
00338  P4000-REQUEST-CLEAR.                                             OJRCU001
00339      SET LCCM-SCR-CLEAR  TO TRUE                                  OJRCU001
00340      SET RESP-SEND-MAP   TO TRUE.                                 OJRCU001
00341  P4000-EXIT.                                                      OJRCU001
00342      EXIT.                                                        OJRCU001
00343      SKIP1                                                        OJRCU001
00344                                                                   OJRCU001
00345 /*****************************************************************OJRCU001
00346 * INQUIRY WAS REQUESTED                                          *OJRCU001
00347 ******************************************************************OJRCU001
00348                                                                   OJRCU001
00349  P6000-DETERMINE-REQ.                                             OJRCU001
00350      SET LCCM-END-TASK-88 TO TRUE                                 OJRCU001
00351      IF LCCM-SEND-MAP-88                                          OJRCU001
00352         PERFORM P6100-BUILD-MAP THRU P6100-EXIT                   OJRCU001
00353         PERFORM S9300-SEND-MAP  THRU S9300-EXIT                   OJRCU001
00354      ELSE                                                         OJRCU001
00355         PERFORM S9100-RECEIVE    THRU S9100-EXIT                  OJRCU001
00356         PERFORM P6200-BUILD-LCCM THRU P6200-EXIT                  OJRCU001
00357      END-IF.                                                      OJRCU001
00358  P6000-EXIT.                                                      OJRCU001
00359      EXIT.                                                        OJRCU001
00360                                                                   OJRCU001
00361  P6100-BUILD-MAP.                                                 OJRCU001
00362      INITIALIZE OJR-WINDOW-AREA                                   OJRCU001
00363      MOVE CATB-CURSOR                    TO MAP-DATE-MM-L         OJRCU001
00364      MOVE LCCM-PARM-VALUE(LCCM-PARM-SUB) TO WRK-PARM              OJRCU001
00365      MOVE WRK-PARM(1:2)                  TO MAP-DATE-MM           OJRCU001
00366      MOVE WRK-PARM(3:2)                  TO MAP-DATE-DD           OJRCU001
00367      MOVE WRK-PARM(5:2)                  TO MAP-DATE-YY.          OJRCU001
00368  P6100-EXIT.                                                      OJRCU001
00369      EXIT.                                                        OJRCU001
00370                                                                   OJRCU001
00371  P6200-BUILD-LCCM.                                                OJRCU001
00372      INITIALIZE WRK-PARM                                          OJRCU001
00373      MOVE MAP-DATE-MM           TO WRK-PARM(1:2)                  OJRCU001
00374      MOVE MAP-DATE-DD           TO WRK-PARM(3:2)                  OJRCU001
00375      MOVE MAP-DATE-YY           TO WRK-PARM(5:2)                  OJRCU001
00376      MOVE WRK-PARM              TO LCCM-PARM-VALUE(LCCM-PARM-SUB).OJRCU001
00377  P6200-EXIT.                                                      OJRCU001
00378      EXIT.                                                        OJRCU001
00379                                                                   OJRCU001
00380                                                                   OJRCU001
00381 /*****************************************************************OJRCU001
00382 * LINKS TO UTILITY MODULES                                        OJRCU001
00383 ******************************************************************OJRCU001
00384      SKIP1                                                        OJRCU001
00385  S013-SCREEN-COUNT.                                               OJRCU001
00386      EXEC CICS LINK                                               OJRCU001
00387          PROGRAM  ('DTSCU013')                                    OJRCU001
00388          COMMAREA (L013-COMM-AREA)                                OJRCU001
00389      END-EXEC.                                                    OJRCU001
00390  S013-EXIT.                                                       OJRCU001
00391      EXIT.                                                        OJRCU001
00392      EJECT                                                        OJRCU001
00393  S803-REQ-SCR-ID-EDIT.                                            OJRCU001
00394      EXEC CICS LINK                                               OJRCU001
00395          PROGRAM  ('DTSCU803')                                    OJRCU001
00396          COMMAREA (DFHCOMMAREA)                                   OJRCU001
00397      END-EXEC.                                                    OJRCU001
00398  S803-EXIT.                                                       OJRCU001
00399      EXIT.                                                        OJRCU001
00400      SKIP3                                                        OJRCU001
00401  S804-INVALID-KEY.                                                OJRCU001
00402      EXEC CICS LINK                                               OJRCU001
00403          PROGRAM  ('DTSCU804')                                    OJRCU001
00404          COMMAREA (DFHCOMMAREA)                                   OJRCU001
00405      END-EXEC.                                                    OJRCU001
00406  S804-EXIT.                                                       OJRCU001
00407      EXIT.                                                        OJRCU001
00408      SKIP3                                                        OJRCU001
00409  S851-SCREEN-PROCESSING.                                          OJRCU001
00410      IF LCCM-SEND-MAP-88                                          OJRCU001
00411         IF L851-ALARM-IND = 'N'                                   OJRCU001
00412            EXEC CICS                                              OJRCU001
00413                SEND                                               OJRCU001
00414                    MAP    (WRK-MAP-NAME)                          OJRCU001
00415                    MAPSET (WRK-MAPSET-NAME)                       OJRCU001
00416                    FROM   (OJR-WINDOW-AREA)                       OJRCU001
00417                    CURSOR                                         OJRCU001
00418                    FREEKB                                         OJRCU001
00419                    RESP   (WRK-RESP-CD)                           OJRCU001
00420            END-EXEC                                               OJRCU001
00421         ELSE                                                      OJRCU001
00422             EXEC CICS                                             OJRCU001
00423                 SEND                                              OJRCU001
00424                     MAP    (WRK-MAP-NAME)                         OJRCU001
00425                     MAPSET (WRK-MAPSET-NAME)                      OJRCU001
00426                     FROM   (OJR-WINDOW-AREA)                      OJRCU001
00427                     CURSOR                                        OJRCU001
00428                     FREEKB                                        OJRCU001
00429                     ALARM                                         OJRCU001
00430                     RESP   (WRK-RESP-CD)                          OJRCU001
00431             END-EXEC                                              OJRCU001
00432         END-IF                                                    OJRCU001
00433      ELSE                                                         OJRCU001
00434          INITIALIZE OJR-WINDOW-AREA                               OJRCU001
00435          EXEC CICS                                                OJRCU001
00436              RECEIVE                                              OJRCU001
00437                     MAP    (WRK-MAP-NAME)                         OJRCU001
00438                     MAPSET (WRK-MAPSET-NAME)                      OJRCU001
00439                     INTO   (OJR-WINDOW-AREA)                      OJRCU001
00440                     RESP   (WRK-RESP-CD)                          OJRCU001
00441          END-EXEC                                                 OJRCU001
00442 *        MOVE EIBAID TO LCCM-AID                                  OJRCU001
00443      END-IF                                                       OJRCU001
00444                                                                   OJRCU001
00445      IF WRK-RESP-CD NOT = DFHRESP(NORMAL)                         OJRCU001
00446         GO TO S899-ABEND                                          OJRCU001
00447      END-IF.                                                      OJRCU001
00448  S851-EXIT.                                                       OJRCU001
00449      EXIT.                                                        OJRCU001
00450      SKIP3                                                        OJRCU001
00451  S899-ABEND.                                                      OJRCU001
00452      EXEC CICS ABEND                                              OJRCU001
00453          ABCODE(WRK-ABEND-CD)                                     OJRCU001
00454      END-EXEC.                                                    OJRCU001
00455 *S899-EXIT.                                                       OJRCU001
00456 *    EXIT.                                                        OJRCU001
00457  S1101-ERROR.                                                     OJRCU001
00458      MOVE WRK-MSG-AREA  TO LCCM-MSG-AREA.                         OJRCU001
00459  S1101-EXIT.                                                      OJRCU001
00460      EXIT.                                                        OJRCU001
00461                                                                   OJRCU001
00462                                                                   OJRCU001
00463  S5900-SET-ATTRB.                                                 OJRCU001
00464      MOVE CATB-UNPROT-NORM-NUM-MDTON    TO MAP-DATE-MM-A          OJRCU001
00465      MOVE CATB-UNPROT-NORM-NUM-MDTON    TO MAP-DATE-DD-A          OJRCU001
00466      MOVE CATB-UNPROT-NORM-NUM-MDTON    TO MAP-DATE-YY-A.         OJRCU001
00467  S5900-EXIT.                                                      OJRCU001
00468      EXIT.                                                        OJRCU001
00469                                                                   OJRCU001
00470 /*****************************************************************OJRCU001
00471 * MAP ROUTINES                                                   *OJRCU001
00472 ******************************************************************OJRCU001
00473  S9100-RECEIVE.                                                   OJRCU001
00474      SET L851-RECEIVE-88 TO TRUE.                                 OJRCU001
00475      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU001
00476  S9100-EXIT.                                                      OJRCU001
00477      EXIT.                                                        OJRCU001
00478                                                                   OJRCU001
00479  S9300-SEND-MAP.                                                  OJRCU001
00480      PERFORM S5900-SET-ATTRB THRU S5900-EXIT                      OJRCU001
00481      IF NOT LCCM-NO-MSG                                           OJRCU001
00482         MOVE 'INVALID DATE'          TO MAP-MSG-TEXT              OJRCU001
00483         MOVE CATB-PROT-BRT-MDTON     TO MAP-MSG-TEXT-A            OJRCU001
00484      ELSE                                                         OJRCU001
00485          MOVE CATB-ASKIP-NORM-MDTOFF TO MAP-MSG-TEXT-A            OJRCU001
00486      END-IF                                                       OJRCU001
00487      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT                   OJRCU001
00488      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU001
00489  S9300-EXIT.                                                      OJRCU001
00490      EXIT.                                                        OJRCU001
00491                                                                   OJRCU001
00492                                                                   OJRCU001
00493  S9900-PREPARE-SEND.                                              OJRCU001
00494      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND                     OJRCU001
00495      MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE.                         OJRCU001
00496  S9900-EXIT.                                                      OJRCU001
00497      EXIT.                                                        OJRCU001
