00001  IDENTIFICATION DIVISION.                                         11/28/01
00002  PROGRAM-ID.             DTSBR521.                                DTSBR521
00003  AUTHOR.                 D.SHEPPERSON                                LV223
00004  DATE-WRITTEN.           MAY 1999.                                DTSBR521
00005  DATE-COMPILED.                                                   DTSBR521
00006      SKIP3                                                        DTSBR521
00007 *****                                                             DTSBR521
00008 *                                                                 DTSBR521
00009 *    FUNCTION:  EMPLOYER EXPERIENCE RATING SUMMARY                DTSBR521
00010 *               - RATE TABLE SUMMARY AS OF YY/Q                   DTSBR521
00011 *                                                                 DTSBR521
00012 *    CALLING SEQUENCE:  DTSBD750 WRITES DTSIR521 RECORDS          DTSBR521
00013 *                       DTSBR521 READS  DTSIR521 RECORDS          DTSBR521
00014 *                       TO PRODUCE THE RATE ASSIGNMENT REPORT.    DTSBR521
00015 *                                                                 DTSBR521
00016 *    MODIFICATION HISTORY:                                        DTSBR521
00017 *                                                                 DTSBR521
00018 * 11-25-97 INITIAL DEVELOPMENT                                    DTSBR521
00019 *          REFERENCE RFP #TCL 227         AUTHOR OF CHANGE - EHH  DTSBR521
00020 *                                                                 DTSBR521
00021 * 05-18-99 MODIFIED TO MEET DUTAS PROGRAMMING SPECIFICATIONS      DTSBR521
00022 *          REFERENCE RFP #****            AUTHOR OF CHANGE - DVS  DTSBR521
00023 *                                                                 DTSBR521
00024 *                                                                 DTSBR521
00025 *    DESCRIPTION:                                                 DTSBR521
00026 *                                                                 DTSBR521
00027 *        THIS MODULE GENERATES THE EMPLOYER EXPERIENCE RATING     DTSBR521
00028 *        SUMMARY REPORT.                                          DTSBR521
00029 *                                                                 DTSBR521
00030 *                                                                 DTSBR521
00031 *    RECORDS READ:                                                DTSBR521
00032 *                                                                 DTSBR521
00033 *        NONE.                                                    DTSBR521
00034 *                                                                 DTSBR521
00035 *    REFERENCE FILE RECORDS READ:                                 DTSBR521
00036 *                                                                 DTSBR521
00037 *        FUIR.                                                    DTSBR521
00038 *                                                                 DTSBR521
00039 *    PRINTED OUTPUTS:                                             DTSBR521
00040 *                                                                 DTSBR521
00041 *        521R1  EMPLOYER ANNUAL RATE SUMMARY REPORT.              DTSBR521
00042 *                                                                 DTSBR521
00043 *                                                                 DTSBR521
00044 *    RECORDS WRITTEN:                                             DTSBR521
00045 *                                                                 DTSBR521
00046 *        NONE.                                                    DTSBR521
00047 *                                                                 DTSBR521
00048 *                                                                 DTSBR521
00049 *    MODULES CALLED:                                              DTSBR521
00050 *                                                                 DTSBR521
00051 *        DTSBU001 EMP REGISTRATION CODES EDIT/DESCRIPTION         DTSBR521
00052 *        DTSBU004 QUARTER CONVERSION MODULE                       DTSBR521
00053 *        DTSBU056 UI RATE DESCRIPTION MODULE                      DTSBR521
00054 *        DTSBU057 FORMAT RESERVE RATIO FOR DISPLAY ON PRINTED     DTSBR521
00055 *                 OUTPUT.                                         DTSBR521
00056 *                                                                 DTSBR521
00057 *****                                                             DTSBR521
00058      EJECT                                                        DTSBR521
00059  ENVIRONMENT DIVISION.                                            DTSBR521
00060                                                                   DTSBR521
00061  CONFIGURATION SECTION.                                           DTSBR521
00062  SPECIAL-NAMES. C01 IS TOP-OF-PAGE.                               DTSBR521
00063                                                                   DTSBR521
00064  INPUT-OUTPUT SECTION.                                            DTSBR521
00065                                                                   DTSBR521
00066  FILE-CONTROL.                                                    DTSBR521
00067      SELECT PRT-FILE ASSIGN TO RPT521R1.                          DTSBR521
00068                                                                   DTSBR521
00069  DATA DIVISION.                                                   DTSBR521
00070                                                                   DTSBR521
00071  FILE SECTION.                                                    DTSBR521
00072                                                                   DTSBR521
00073  FD  PRT-FILE                                                     DTSBR521
00074      RECORDING MODE IS F.                                         DTSBR521
00075  01  PRT-RECORD              PIC X(133).                          DTSBR521
00076                                                                   DTSBR521
00077      EJECT                                                        DTSBR521
00078  WORKING-STORAGE SECTION.                                         DTSBR521
000785 77  PAN-VALET PICTURE X(24) VALUE '223DTSBR521  11/28/01'.       DTSBR521
00079                                                                   DTSBR521
00080  01  WRK-AREA.                                                    DTSBR521
00081      05  WRK-ABEND-CD                PIC S9(04)  COMP  VALUE +521.DTSBR521
00082      05  FIRST-TIME-IND              PIC  X(01)  VALUE 'Y'.       DTSBR521
00083      05  ABEND-MSG                   PIC  X(60).                  DTSBR521
00084                                                                   DTSBR521
00085      05  WS-LINE-CNT                 PIC S9(02)  COMP-3 VALUE 60. DTSBR521
00086      05  WS-LINE-CNT2                PIC S9(02)  COMP-3 VALUE +0. DTSBR521
00087      05  WS-PAGE-CNT                 PIC S9(05)  COMP-3 VALUE +0. DTSBR521
00088                                                                   DTSBR521
00089      05  WS-SUB                      PIC S9(04)  COMP.            DTSBR521
00090      05  WS-OUTPUT-HEADING           PIC  X(55).                  DTSBR521
00091      05  WS-FUIR-MIN-RATIO           PIC S9(02)V9(05).            DTSBR521
00092      05  WS-FUIR-MAX-RATIO           PIC S9(02)V9(05).            DTSBR521
00093      05  WS-FUIR-UI-RATE             PIC S9(01)V9999              DTSBR521
00094                                      COMP-3 VALUE 0.              DTSBR521
00095      05  WS-FUIR-UI-RATE-D           PIC X(07).                   DTSBR521
00096      05  WS-EFF-QTR-UNPACK           PIC  9(05).                  DTSBR521
00097      05  WS-OUT-TAXABLE-WAGES1       PIC S9(11)V99.               DTSBR521
00098      05  WS-OUT-TAXABLE-WAGES2       PIC S9(11)V99.               DTSBR521
00099      05  WS-UI-RATE-CATEGORY         PIC X.                       DTSBR521
00100      05  WS-TAX-QTR-FROM             PIC X(04).                   DTSBR521
00101      05  WS-TAX-QTR-THRU             PIC X(04).                   DTSBR521
00102      05  WS-TAX-PD-FROM-THRU.                                     DTSBR521
00103          10 WS-TAX-PD-FROM-DT        PIC X(04).                   DTSBR521
00104          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00105          10 FILLER                   PIC X(01) VALUE '-'.         DTSBR521
00106          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00107          10 WS-TAX-PD-THRU-DT        PIC X(04).                   DTSBR521
00108      05  WS-TRUST-FND-FROM-THRU.                                  DTSBR521
00109          10 WS-TRUST-FROM-DT         PIC X(04).                   DTSBR521
00110          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00111          10 FILLER                   PIC X(01) VALUE '-'.         DTSBR521
00112          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00113          10 WS-TRUST-THRU-DT         PIC X(04).                   DTSBR521
00114      05  WS-BENEFIT-CHG-FROM-THRU.                                DTSBR521
00115          10 WS-BENEF-FROM-DT         PIC X(04).                   DTSBR521
00116          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00117          10 FILLER                   PIC X(01) VALUE '-'.         DTSBR521
00118          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00119          10 WS-BENEF-THRU-DT         PIC X(04).                   DTSBR521
00120      05  WS-TAX-WAGE1-FROM-THRU.                                  DTSBR521
00121          10 WS-TAX-WAGE1-FROM        PIC X(04).                   DTSBR521
00122          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00123          10 FILLER                   PIC X(01) VALUE '-'.         DTSBR521
00124          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00125          10 WS-TAX-WAGE1-THRU        PIC X(04).                   DTSBR521
00126      05  WS-TAX-WAGE2-FROM-THRU.                                  DTSBR521
00127          10 WS-TAX-WAGE2-FROM        PIC X(04).                   DTSBR521
00128          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00129          10 FILLER                   PIC X(01) VALUE '-'.         DTSBR521
00130          10 FILLER                   PIC X(01) VALUE SPACE.       DTSBR521
00131          10 WS-TAX-WAGE2-THRU        PIC X(04).                   DTSBR521
00132      EJECT                                                        DTSBR521
00133  01  WS-OUTPUT-LINE.                                              DTSBR521
00134          10  WS-REG-UI-RATE          PIC S9V9999     COMP-3.      DTSBR521
00135          10  WS-REG-UI-RATE-D        PIC X(07).                   DTSBR521
00136          10  WS-REG-TRUST-FUND-INT   PIC S9(09)V99   COMP-3.      DTSBR521
00137          10  WS-REG-BENEFITS-CHGD    PIC S9(09)V99   COMP-3.      DTSBR521
00138          10  WS-REG-MIN-RATIO        PIC S9(02)V99.               DTSBR521
00139          10  WS-REG-MAX-RATIO        PIC S9(02)V99.               DTSBR521
00140          10  WS-REG-EMPL-COUNT       PIC S9(07)      COMP-3.      DTSBR521
00141          10  WS-REG-UI-TAX-PAID      PIC S9(09)V99   COMP-3.      DTSBR521
00142          10  WS-REG-CURRENT-RESERVE  PIC S9(09)V99   COMP-3.      DTSBR521
00143          10  WS-REG-TAXABLE-WAGES1   PIC S9(11)V99   COMP-3.      DTSBR521
00144          10  WS-REG-TAXABLE-WAGES2   PIC S9(11)V99   COMP-3.      DTSBR521
00145      EJECT                                                        DTSBR521
00146  01  WS-OUTPUT-CLASSIFIED.                                        DTSBR521
00147      05  WS-CLASSF-FIELDS.                                        DTSBR521
00148          10  WS-CLS-TRUST-FUND-INT   PIC S9(09)V99   COMP-3.      DTSBR521
00149          10  WS-CLS-BENEFITS-CHGD    PIC S9(09)V99   COMP-3.      DTSBR521
00150          10  WS-CLS-EMPL-COUNT       PIC S9(07)      COMP-3.      DTSBR521
00151          10  WS-CLS-UI-RATE          PIC  99V9.                   DTSBR521
00152          10  WS-CLS-UI-TAX-PAID      PIC S9(09)V99   COMP-3.      DTSBR521
00153          10  WS-CLS-CURRENT-RESERVE  PIC S9(09)V99   COMP-3.      DTSBR521
00154          10  WS-CLS-TAXABLE-WAGES1   PIC S9(11)V99   COMP-3.      DTSBR521
00155          10  WS-CLS-TAXABLE-WAGES2   PIC S9(11)V99   COMP-3.      DTSBR521
00156      EJECT                                                        DTSBR521
00157  01  WS-EMPLR-AREA.                                               DTSBR521
00158      05  WS-EMPLR-FIELDS.                                         DTSBR521
00159          10  WS-EMP-UI-TAX-PAID      PIC S9(09)V99   COMP-3.      DTSBR521
00160          10  WS-EMP-TRUST-FUND-INT   PIC S9(09)V99   COMP-3.      DTSBR521
00161          10  WS-EMP-BENEFITS-CHGD    PIC S9(09)V99   COMP-3.      DTSBR521
00162          10  WS-EMP-EMPL-COUNT       PIC S9(07)      COMP-3.      DTSBR521
00163          10  WS-EMP-UI-RATE          PIC X(07).                   DTSBR521
00164          10  WS-EMP-CURRENT-RESERVE  PIC S9(09)V99   COMP-3.      DTSBR521
00165          10  WS-EMP-TAXABLE-WAGES1   PIC S9(11)V99   COMP-3.      DTSBR521
00166          10  WS-EMP-TAXABLE-WAGES2   PIC S9(11)V99   COMP-3.      DTSBR521
00167                                                                   DTSBR521
00168  01  WS-GRAND-AREA.                                               DTSBR521
00169      05  WS-GRAND-TOTAL-FIELDS.                                   DTSBR521
00170          10  WS-GRD-TAXABLE-WAGES1   PIC S9(11)V99   COMP-3.      DTSBR521
00171          10  WS-GRD-TAXABLE-WAGES2   PIC S9(11)V99   COMP-3.      DTSBR521
00172          10  WS-GRD-TRUST-FUND-INT   PIC S9(09)V99   COMP-3.      DTSBR521
00173          10  WS-GRD-BENEFITS-CHGD    PIC S9(09)V99   COMP-3.      DTSBR521
00174          10  WS-GRD-EMPLR-COUNT      PIC S9(07)      COMP-3.      DTSBR521
00175          10  WS-GRD-UI-TAX-PAID      PIC S9(09)V99   COMP-3.      DTSBR521
00176          10  WS-GRD-CURRENT-RESERVE  PIC S9(09)V99   COMP-3.      DTSBR521
00177      EJECT                                                        DTSBR521
00178  01  FUIR-REC.                                                    DTSBR521
00179  ++INCLUDE DTSIFUIR                                               DTSBR521
00180      EJECT                                                        DTSBR521
00181  01  L001-LINK-AREA.                                              DTSBR521
00182  ++INCLUDE DTSIL001                                               DTSBR521
00183      EJECT                                                        DTSBR521
00184  01  L004-LINK-AREA.                                              DTSBR521
00185  ++INCLUDE DTSIL004                                               DTSBR521
00186      EJECT                                                        DTSBR521
00187  01  L056-LINK-AREA.                                              DTSBR521
00188  ++INCLUDE DTSIL056                                               DTSBR521
00189      EJECT                                                        DTSBR521
00190  01  L057-LINK-AREA.                                              DTSBR521
00191  ++INCLUDE DTSIL057                                               DTSBR521
00192      EJECT                                                        DTSBR521
00193  01  L931-LINK-AREA.                                              DTSBR521
00194  ++INCLUDE DTSIL931                                               DTSBR521
00195      EJECT                                                        DTSBR521
00196  01  FSKL-REC.                                                    DTSBR521
00197  ++INCLUDE DTSIFSKL                                               DTSBR521
00198      EJECT                                                        DTSBR521
00199  01  PAGE-HEADING.                                                DTSBR521
00200      05  HDR-LINE-1.                                              DTSBR521
00201          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00202          10  FILLER                  PIC  X(05)                   DTSBR521
00203                 VALUE '521R1'.                                    DTSBR521
00204          10  FILLER                  PIC  X(34)  VALUE SPACES.    DTSBR521
00205          10  HDR-AGY-NAME-LINE1      PIC  X(50).                  DTSBR521
00206          10  FILLER                  PIC  X(28)  VALUE SPACES.    DTSBR521
00207          10  FILLER                  PIC  X(05)                   DTSBR521
00208                 VALUE 'DATE:'.                                    DTSBR521
00209          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00210          10  HDR-SYS-DATE            PIC  X(08).                  DTSBR521
00211      05  HDR-LINE-2.                                              DTSBR521
00212          10  FILLER                  PIC  X(40)  VALUE SPACES.    DTSBR521
00213          10  HDR-AGY-NAME-LINE2      PIC  X(50).                  DTSBR521
00214          10  FILLER                  PIC  X(28)  VALUE SPACES.    DTSBR521
00215          10  FILLER                  PIC  X(05)                   DTSBR521
00216                 VALUE 'TIME:'.                                    DTSBR521
00217          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00218          10  HDR-SYS-TIME            PIC  X(08).                  DTSBR521
00219      05  HDR-LINE-3.                                              DTSBR521
00220          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00221          10  FILLER                  PIC  X(33)                   DTSBR521
00222                 VALUE 'ROUTE TO:  REGISTRATION AND RATES'.        DTSBR521
00223          10  FILLER                  PIC  X(84)  VALUE SPACES.    DTSBR521
00224          10  FILLER                  PIC  X(05)                   DTSBR521
00225                 VALUE 'PAGE:'.                                    DTSBR521
00226          10  FILLER                  PIC  X(03)  VALUE SPACES.    DTSBR521
00227          10  HDR-PAGE-CNT            PIC  ZZ,ZZ9.                 DTSBR521
00228      05  HDR-LINE-4.                                              DTSBR521
00229          10  FILLER                  PIC  X(11)  VALUE SPACES.    DTSBR521
00230          10  FILLER                  PIC  X(20)                   DTSBR521
00231                 VALUE '                    '.                     DTSBR521
00232          10  FILLER                  PIC  X(17)  VALUE SPACES.    DTSBR521
00233          10  FILLER                  PIC  X(32)                   DTSBR521
00234                VALUE ' RATE ASSIGNMENT SUMMARY REPORT '.          DTSBR521
00235      05  HDR-LINE-5.                                              DTSBR521
00236          10  FILLER                  PIC  X(60)  VALUE SPACES.    DTSBR521
00237          10  FILLER                  PIC X(06)                    DTSBR521
00238                 VALUE 'TABLE '.                                   DTSBR521
00239          10  WS-FUIR-RATE-TABLE      PIC X(05).                   DTSBR521
00240      05  HDR-LINE-6                  PIC  X(133) VALUE SPACES.    DTSBR521
00241      05  HDR-LINE-7.                                              DTSBR521
00242          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00243          10  FILLER                  PIC  X(20)                   DTSBR521
00244                VALUE 'RATE EFFECTIVE QTR: '.                      DTSBR521
00245          10  HDR-EFF-QTR-UNPACK      PIC  99/9.                   DTSBR521
00246      05  HDR-LINE-8                  PIC  X(133) VALUE SPACES.    DTSBR521
00247      05  HDR-LINE-9.                                              DTSBR521
00248          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00249          10  FILLER                  PIC  X(40)                   DTSBR521
00250                 VALUE ' MIN    MAX    UI   EMPLYR    UI TAX PAI'. DTSBR521
00251          10  FILLER                  PIC  X(40)                   DTSBR521
00252                 VALUE 'D   TRUST FUND INT   BENFTS CHRGD    CUR'. DTSBR521
00253          10  FILLER                  PIC  X(40)                   DTSBR521
00254                 VALUE 'RENT RESERVE       TAXABLE WAGES      TA'. DTSBR521
00255          10  FILLER                  PIC  X(11)                   DTSBR521
00256                 VALUE 'XABLE WAGES'.                              DTSBR521
00257      05  HDR-LINE-10.                                             DTSBR521
00258          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00259          10  FILLER                  PIC  X(27)                   DTSBR521
00260                 VALUE 'RATIO  RATIO  RATE   COUNT '.              DTSBR521
00261          10  FILLER                  PIC  X(03)  VALUE SPACES.    DTSBR521
00262          10  HDR-TAX-PD-FROM-THRU    PIC  X(11).                  DTSBR521
00263          10  FILLER                  PIC  X(05)  VALUE SPACES.    DTSBR521
00264          10  HDR-TRUST-FND-FROM-THRU PIC  X(11).                  DTSBR521
00265          10  FILLER                  PIC  X(05)  VALUE SPACES.    DTSBR521
00266          10  HDR-BENEF-CHG-FROM-THRU PIC  X(11).                  DTSBR521
00267          10  FILLER                  PIC  X(11)  VALUE SPACES.    DTSBR521
00268          10  WS-CURR-RESERVE-DT      PIC  X(08).                  DTSBR521
00269          10  FILLER                  PIC  X(09)  VALUE SPACES.    DTSBR521
00270          10  HDR-TAX-WAGE1-FROM-THRU PIC  X(11).                  DTSBR521
00271          10  FILLER                  PIC  X(08)  VALUE SPACES.    DTSBR521
00272          10  HDR-TAX-WAGE2-FROM-THRU PIC  X(11).                  DTSBR521
00273                                                                   DTSBR521
00274  01  DETAIL-LINE.                                                 DTSBR521
00275      05  DTL-LINE-2.                                              DTSBR521
00276          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00277          10  WS-FUIR-MIN-RATIO-D     PIC  X(05).                  DTSBR521
00278          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00279          10  WS-FUIR-MAX-RATIO-D     PIC  X(05).                  DTSBR521
00280          10  FILLER                  PIC  X(02)  VALUE SPACES.    DTSBR521
00281          10  DTL-REG-UI-RATE-D       PIC  X(04).                  DTSBR521
00282          10  FILLER                  PIC  X(02)  VALUE SPACE.     DTSBR521
00283          10  DTL-REG-EMPL-COUNT      PIC   ZZZ,ZZ9.               DTSBR521
00284          10  DTL-REG-UI-TAX-PAID     PIC  -ZZZ,ZZZ,ZZ9.99.        DTSBR521
00285          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00286          10  DTL-REG-TRUST-FUND-INT  PIC  -ZZZ,ZZZ,ZZ9.99.        DTSBR521
00287          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00288          10  DTL-REG-BENEFITS-CHGD   PIC  -ZZZ,ZZZ,ZZ9.99.        DTSBR521
00289          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00290          10  DTL-REG-CURRENT-RESERVE PIC  -ZZ,ZZZ,ZZZ,ZZ9.99.     DTSBR521
00291          10  FILLER                  PIC  X(02)  VALUE SPACES.    DTSBR521
00292          10  DTL-REG-TAXABLE-WAGES1  PIC  -ZZ,ZZZ,ZZZ,ZZ9.99.     DTSBR521
00293          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00294          10  DTL-REG-TAXABLE-WAGES2  PIC  -ZZ,ZZZ,ZZZ,ZZ9.99.     DTSBR521
00295      SKIP2                                                        DTSBR521
00296  01  CLASSIFIED-TOTALS.                                           DTSBR521
00297      05  DTL-CLS-LINE-3.                                          DTSBR521
00298          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00299          10  FILLER                  PIC  X(18)                   DTSBR521
00300                 VALUE 'CLASSIFIED TOTAL  '.                       DTSBR521
00301          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00302          10  DTL-CLS-EMPL-COUNT      PIC  ZZZ,ZZ9.                DTSBR521
00303          10  DTL-CLS-UI-TAX-PAID     PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00304          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00305          10  DTL-CLS-TRUST-FUND-INT  PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00306          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00307          10  DTL-CLS-BENEFITS-CHGD   PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00308          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00309          10  DTL-CLS-CURRENT-RESERVE PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00310          10  FILLER                  PIC  X(02)  VALUE SPACES.    DTSBR521
00311          10  DTL-CLS-TAXABLE-WAGES1  PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00312          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00313          10  DTL-CLS-TAXABLE-WAGES2  PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00314                                                                   DTSBR521
00315  01  NONCLASSIF-TOTALS.                                           DTSBR521
00316      05  DTL-EMP-LINE-3.                                          DTSBR521
00317          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00318          10  FILLER                  PIC  X(13)                   DTSBR521
00319                 VALUE 'NEW EMPLOYER '.                            DTSBR521
00320          10  DTL-EMP-UI-RATE         PIC X(04).                   DTSBR521
00321          10  FILLER                  PIC  X(02)  VALUE SPACES.    DTSBR521
00322          10  DTL-EMP-EMPL-COUNT      PIC  ZZZ,ZZ9.                DTSBR521
00323          10  DTL-EMP-UI-TAX-PAID     PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00324          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00325          10  DTL-EMP-TRUST-FUND-INT  PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00326          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00327          10  DTL-EMP-BENEFITS-CHGD   PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00328          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00329          10  DTL-EMP-CURRENT-RESERVE PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00330          10  FILLER                  PIC  X(02)  VALUE SPACES.    DTSBR521
00331          10  DTL-EMP-TAXABLE-WAGES1  PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00332          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00333          10  DTL-EMP-TAXABLE-WAGES2  PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00334  01  CONTROL-FOOTING-FINAL.                                       DTSBR521
00335      05  CFF-GRD-LINE-3.                                          DTSBR521
00336          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00337          10  FILLER                  PIC  X(14)                   DTSBR521
00338                 VALUE 'GRAND TOTAL   '.                           DTSBR521
00339          10  FILLER                  PIC  X(05)  VALUE SPACES.    DTSBR521
00340          10  CFF-GRD-EMPLR-COUNT     PIC  ZZZ,ZZ9.                DTSBR521
00341          10  CFF-GRD-UI-TAX-PAID     PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00342          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00343          10  CFF-GRD-TRUST-FUND-INT  PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00344          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00345          10  CFF-GRD-BENEFITS-CHGD   PIC -ZZZ,ZZZ,ZZ9.99.         DTSBR521
00346          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00347          10  CFF-GRD-CURRENT-RESERVE PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00348          10  FILLER                  PIC  X(02)  VALUE SPACES.    DTSBR521
00349          10  CFF-GRD-TAXABLE-WAGES1  PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00350          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR521
00351          10  CFF-GRD-TAXABLE-WAGES2  PIC -ZZ,ZZZ,ZZZ,ZZ9.99.      DTSBR521
00352      EJECT                                                        DTSBR521
00353  LINKAGE SECTION.                                                 DTSBR521
00354      SKIP3                                                        DTSBR521
00355  01  LRCM-LINK-AREA.                                              DTSBR521
00356  ++INCLUDE DTSILRCM                                               DTSBR521
00357      EJECT                                                        DTSBR521
00358  01  R521-REC.                                                    DTSBR521
00359  ++INCLUDE DTSIR521                                               DTSBR521
00360      EJECT                                                        DTSBR521
00361  PROCEDURE DIVISION USING LRCM-LINK-AREA                          DTSBR521
00362                           R521-REC.                               DTSBR521
00363      IF FIRST-TIME-IND = 'Y'                                      DTSBR521
00364          PERFORM I1000-INITIATE THRU I1000-EXIT                   DTSBR521
00365          MOVE 'N' TO FIRST-TIME-IND.                              DTSBR521
00366                                                                   DTSBR521
00367      IF LRCM-EOR-88                                               DTSBR521
00368          PERFORM T1000-TERMINATE THRU T1000-EXIT                  DTSBR521
00369      ELSE                                                         DTSBR521
00370          PERFORM P1000-PROCESS THRU P1000-EXIT.                   DTSBR521
00371                                                                   DTSBR521
00372      GOBACK.                                                      DTSBR521
00373      EJECT                                                        DTSBR521
00374  I1000-INITIATE.                                                  DTSBR521
00375                                                                   DTSBR521
00376      OPEN OUTPUT PRT-FILE.                                        DTSBR521
00377      MOVE LRCM-SYS-DATE TO HDR-SYS-DATE.                          DTSBR521
00378      MOVE LRCM-SYS-TIME TO HDR-SYS-TIME.                          DTSBR521
00379      MOVE LRCM-AGY-NAME-LINE1 TO HDR-AGY-NAME-LINE1.              DTSBR521
00380      MOVE LRCM-AGY-NAME-LINE2 TO HDR-AGY-NAME-LINE2.              DTSBR521
00381      MOVE SPACES TO PRT-RECORD.                                   DTSBR521
00382                                                                   DTSBR521
00383      MOVE R521-EFF-QTR            TO   WS-EFF-QTR-UNPACK.         DTSBR521
00384      MOVE WS-EFF-QTR-UNPACK (3:3) TO  HDR-EFF-QTR-UNPACK.         DTSBR521
00385                                                                   DTSBR521
00386      MOVE R521-COMPUTED-RATE    TO WS-FUIR-UI-RATE.               DTSBR521
00387      MOVE R521-UI-RATE-CATEGORY TO WS-UI-RATE-CATEGORY.           DTSBR521
00388                                                                   DTSBR521
00389      PERFORM I2000-SET-FUIR-AREA  THRU I2000-EXIT.                DTSBR521
00390                                                                   DTSBR521
00391      PERFORM I2200-INITIALIZE-RTN THRU I2200-EXIT.                DTSBR521
00392                                                                   DTSBR521
00393      PERFORM I3000-INIT-DATES     THRU I3000-EXIT.                DTSBR521
00394                                                                   DTSBR521
00395      PERFORM I2100-SET-RATIO THRU I2100-EXIT                      DTSBR521
00396              VARYING FUIR-RATE-IDX FROM 1 BY 1 UNTIL              DTSBR521
00397              FUIR-RATE-IDX GREATER FUIR-RATE-CNT                  DTSBR521
00398                                                                   DTSBR521
00399      INITIALIZE WS-CLS-TRUST-FUND-INT                             DTSBR521
00400                 WS-CLS-BENEFITS-CHGD                              DTSBR521
00401                 WS-CLS-EMPL-COUNT                                 DTSBR521
00402                 WS-CLS-UI-TAX-PAID                                DTSBR521
00403                 WS-CLS-CURRENT-RESERVE                            DTSBR521
00404                 WS-CLS-TAXABLE-WAGES1                             DTSBR521
00405                 WS-CLS-TAXABLE-WAGES2.                            DTSBR521
00406                                                                   DTSBR521
00407       INITIALIZE WS-EMP-UI-TAX-PAID                               DTSBR521
00408                  WS-EMP-TRUST-FUND-INT                            DTSBR521
00409                  WS-EMP-BENEFITS-CHGD                             DTSBR521
00410                  WS-EMP-EMPL-COUNT                                DTSBR521
00411                  WS-EMP-UI-RATE                                   DTSBR521
00412                  WS-EMP-CURRENT-RESERVE                           DTSBR521
00413                  WS-EMP-TAXABLE-WAGES1                            DTSBR521
00414                  WS-EMP-TAXABLE-WAGES2.                           DTSBR521
00415                                                                   DTSBR521
00416      INITIALIZE  WS-GRD-TAXABLE-WAGES1                            DTSBR521
00417                  WS-GRD-TAXABLE-WAGES2                            DTSBR521
00418                  WS-GRD-TRUST-FUND-INT                            DTSBR521
00419                  WS-GRD-BENEFITS-CHGD                             DTSBR521
00420                  WS-GRD-EMPLR-COUNT                               DTSBR521
00421                  WS-GRD-UI-TAX-PAID                               DTSBR521
00422                  WS-GRD-CURRENT-RESERVE.                          DTSBR521
00423  I1000-EXIT.                                                      DTSBR521
00424      EXIT.                                                        DTSBR521
00425                                                                   DTSBR521
00426  I2000-SET-FUIR-AREA.                                             DTSBR521
00427                                                                   DTSBR521
00428        MOVE LOW-VALUES TO FUIR-KEY-AREA.                          DTSBR521
00429                                                                   DTSBR521
00430        SET FUIR-UIR-88 TO TRUE.                                   DTSBR521
00431                                                                   DTSBR521
00432        MOVE R521-EFF-QTR TO FUIR-EFF-YRQ.                         DTSBR521
00433                                                                   DTSBR521
00434        MOVE FUIR-KEY-AREA TO FSKL-KEY-AREA.                       DTSBR521
00435                                                                   DTSBR521
00436        PERFORM S931-READ THRU S931-EXIT.                          DTSBR521
00437                                                                   DTSBR521
00438        IF L931-NO-REC-88                                          DTSBR521
00439           MOVE 'NO FUIR RECORD OCCURRENCE FOR RATE YEAR'          DTSBR521
00440             TO ABEND-MSG                                          DTSBR521
00441           PERFORM S999-ABEND THRU S999-EXIT.                      DTSBR521
00442                                                                   DTSBR521
00443        MOVE FSKL-REC TO FUIR-REC.                                 DTSBR521
00444                                                                   DTSBR521
00445        MOVE FUIR-RATE-TABLE  TO WS-FUIR-RATE-TABLE.               DTSBR521
00446                                                                   DTSBR521
00447  I2000-EXIT.                                                      DTSBR521
00448      EXIT.                                                        DTSBR521
00449                                                                   DTSBR521
00450  I2100-SET-RATIO.                                                 DTSBR521
00451       MOVE ZEROES   TO  WS-FUIR-UI-RATE .                         DTSBR521
00452       MOVE ZEROES   TO  WS-FUIR-MIN-RATIO.                        DTSBR521
00453       MOVE ZEROES   TO  WS-FUIR-MAX-RATIO.                        DTSBR521
00454                                                                   DTSBR521
00455       IF R521-RATE-NONCLASSIFIED-88                               DTSBR521
00456          MOVE  FUIR-DEFAULT-NEW-EMP-RATE TO WS-FUIR-UI-RATE       DTSBR521
00457          PERFORM I2300-CNV-RATIO THRU I2300-EXIT                  DTSBR521
00458          MOVE WS-FUIR-UI-RATE-D TO WS-EMP-UI-RATE                 DTSBR521
00459          SET FUIR-RATE-IDX TO FUIR-RATE-CNT                       DTSBR521
00460       ELSE                                                        DTSBR521
00461       IF FUIR-UI-RATE (FUIR-RATE-IDX) = R521-COMPUTED-RATE        DTSBR521
00462          MOVE FUIR-MIN-RATIO (FUIR-RATE-IDX) TO                   DTSBR521
00463               WS-FUIR-MIN-RATIO                                   DTSBR521
00464          MOVE FUIR-MAX-RATIO (FUIR-RATE-IDX) TO                   DTSBR521
00465               WS-FUIR-MAX-RATIO                                   DTSBR521
00466          MOVE FUIR-UI-RATE (FUIR-RATE-IDX) TO                     DTSBR521
00467               WS-FUIR-UI-RATE                                     DTSBR521
00468          PERFORM I2300-CNV-RATIO THRU I2300-EXIT                  DTSBR521
00469          SET FUIR-RATE-IDX TO FUIR-RATE-CNT                       DTSBR521
00470       END-IF.                                                     DTSBR521
00471  I2100-EXIT.                                                      DTSBR521
00472      EXIT.                                                        DTSBR521
00473                                                                   DTSBR521
00474  I2200-INITIALIZE-RTN.                                            DTSBR521
00475         INITIALIZE WS-REG-TRUST-FUND-INT                          DTSBR521
00476                    WS-REG-BENEFITS-CHGD                           DTSBR521
00477                    WS-REG-EMPL-COUNT                              DTSBR521
00478                    WS-REG-UI-RATE                                 DTSBR521
00479                    WS-REG-UI-RATE-D                               DTSBR521
00480                    WS-REG-UI-TAX-PAID                             DTSBR521
00481                    WS-REG-CURRENT-RESERVE                         DTSBR521
00482                    WS-REG-TAXABLE-WAGES1                          DTSBR521
00483                    WS-REG-TAXABLE-WAGES2.                         DTSBR521
00484  I2200-EXIT.                                                      DTSBR521
00485      EXIT.                                                        DTSBR521
00486                                                                   DTSBR521
00487  I2300-CNV-RATIO.                                                 DTSBR521
00488        IF WS-FUIR-UI-RATE > 0                                     DTSBR521
00489           MOVE WS-FUIR-UI-RATE    TO L056-RATE                    DTSBR521
00490           SET L056-DISP1-RIGHT-88 TO TRUE                         DTSBR521
00491           PERFORM S056-RATE-DISPLAY                               DTSBR521
00492              THRU S056-EXIT                                       DTSBR521
00493           MOVE L056-DISP-RATE     TO WS-FUIR-UI-RATE-D            DTSBR521
00494                                                                   DTSBR521
00495           MOVE WS-FUIR-MIN-RATIO  TO L057-RATIO                   DTSBR521
00496           PERFORM S057-RATIO-DISPLAY                              DTSBR521
00497              THRU S057-EXIT                                       DTSBR521
00498           MOVE L057-DISP-RATIO    TO WS-FUIR-MIN-RATIO-D          DTSBR521
00499                                                                   DTSBR521
00500           MOVE WS-FUIR-MAX-RATIO  TO L057-RATIO                   DTSBR521
00501           PERFORM S057-RATIO-DISPLAY                              DTSBR521
00502              THRU S057-EXIT                                       DTSBR521
00503           MOVE L057-DISP-RATIO    TO WS-FUIR-MAX-RATIO-D          DTSBR521
00504                                                                   DTSBR521
00505        ELSE                                                       DTSBR521
00506            MOVE   'UI RATES NOT LOADED CORRECTLY'                 DTSBR521
00507            TO ABEND-MSG                                           DTSBR521
00508          PERFORM S999-ABEND THRU S999-EXIT.                       DTSBR521
00509  I2300-EXIT.                                                      DTSBR521
00510      EXIT.                                                        DTSBR521
00511                                                                   DTSBR521
00512  I3000-INIT-DATES.                                                DTSBR521
00513      SKIP1                                                        DTSBR521
00514      MOVE R521-CURRENT-RESERVE-THRU-DATE TO L001-FED-8-DATE-9.    DTSBR521
00515      SET L001-FROM-FED-8 TO TRUE.                                 DTSBR521
00516      PERFORM S001-DATE THRU S001-EXIT.                            DTSBR521
00517      MOVE L001-SLASH-DATE TO WS-CURR-RESERVE-DT.                  DTSBR521
00518      SKIP1                                                        DTSBR521
00519       IF R521-UI-TAX-PAID-FROM-YRQ GREATER ZEROS                  DTSBR521
00520          MOVE R521-UI-TAX-PAID-FROM-YRQ  TO                       DTSBR521
00521               L004-QTR-5-9                                        DTSBR521
00522          PERFORM S004-FROM-5 THRU S004-EXIT                       DTSBR521
00523          MOVE L004-SLASH-QTR TO WS-TAX-PD-FROM-DT                 DTSBR521
00524       ELSE                                                        DTSBR521
00525            MOVE SPACES TO WS-TAX-PD-FROM-DT                       DTSBR521
00526       END-IF.                                                     DTSBR521
00527                                                                   DTSBR521
00528       IF R521-UI-TAX-PAID-THRU-YRQ GREATER ZEROS                  DTSBR521
00529          MOVE R521-UI-TAX-PAID-THRU-YRQ  TO                       DTSBR521
00530               L004-QTR-5-9                                        DTSBR521
00531          PERFORM S004-FROM-5 THRU S004-EXIT                       DTSBR521
00532          MOVE L004-SLASH-QTR TO WS-TAX-PD-THRU-DT                 DTSBR521
00533       ELSE                                                        DTSBR521
00534            MOVE SPACES TO WS-TAX-PD-THRU-DT                       DTSBR521
00535       END-IF.                                                     DTSBR521
00536                                                                   DTSBR521
00537       MOVE WS-TAX-PD-FROM-THRU TO HDR-TAX-PD-FROM-THRU.           DTSBR521
00538                                                                   DTSBR521
00539       IF  R521-TRUST-FUND-INT-FROM-YRQ GREATER ZEROES             DTSBR521
00540          MOVE  R521-TRUST-FUND-INT-FROM-YRQ TO                    DTSBR521
00541               L004-QTR-5-9                                        DTSBR521
00542          PERFORM S004-FROM-5 THRU S004-EXIT                       DTSBR521
00543          MOVE L004-SLASH-QTR TO WS-TRUST-FROM-DT                  DTSBR521
00544       ELSE                                                        DTSBR521
00545            MOVE SPACES TO WS-TRUST-FROM-DT                        DTSBR521
00546       END-IF.                                                     DTSBR521
00547       IF  R521-TRUST-FUND-INT-THRU-YRQ GREATER ZEROS              DTSBR521
00548          MOVE  R521-TRUST-FUND-INT-THRU-YRQ TO                    DTSBR521
00549               L004-QTR-5-9                                        DTSBR521
00550          PERFORM S004-FROM-5 THRU S004-EXIT                       DTSBR521
00551          MOVE L004-SLASH-QTR TO WS-TRUST-THRU-DT                  DTSBR521
00552       ELSE                                                        DTSBR521
00553            MOVE SPACES TO WS-TRUST-THRU-DT                        DTSBR521
00554       END-IF.                                                     DTSBR521
00555                                                                   DTSBR521
00556       MOVE WS-TRUST-FND-FROM-THRU TO HDR-TRUST-FND-FROM-THRU.     DTSBR521
00557                                                                   DTSBR521
00558       IF  R521-UI-BEN-CHGD-FROM-YRQ GREATER ZEROS                 DTSBR521
00559          MOVE  R521-UI-BEN-CHGD-FROM-YRQ TO                       DTSBR521
00560               L004-QTR-5-9                                        DTSBR521
00561          PERFORM S004-FROM-5 THRU S004-EXIT                       DTSBR521
00562          MOVE L004-SLASH-QTR TO WS-BENEF-FROM-DT                  DTSBR521
00563       ELSE                                                        DTSBR521
00564            MOVE SPACES TO WS-BENEF-FROM-DT                        DTSBR521
00565       END-IF.                                                     DTSBR521
00566       IF  R521-UI-BEN-CHGD-FROM-YRQ GREATER ZEROS                 DTSBR521
00567          MOVE  R521-UI-BEN-CHGD-FROM-YRQ TO                       DTSBR521
00568               L004-QTR-5-9                                        DTSBR521
00569          PERFORM S004-FROM-5 THRU S004-EXIT                       DTSBR521
00570          MOVE L004-SLASH-QTR TO WS-BENEF-THRU-DT                  DTSBR521
00571       ELSE                                                        DTSBR521
00572            MOVE SPACES TO WS-BENEF-THRU-DT                        DTSBR521
00573       END-IF.                                                     DTSBR521
00574                                                                   DTSBR521
00575       MOVE WS-BENEFIT-CHG-FROM-THRU TO HDR-BENEF-CHG-FROM-THRU.   DTSBR521
00576                                                                   DTSBR521
00577       PERFORM P2000-TAX-QTRS THRU P2000-EXIT VARYING              DTSBR521
00578               R521-WAGES-YRQ-IDX FROM 1 BY 1 UNTIL                DTSBR521
00579               R521-WAGES-YRQ-IDX > 2.                             DTSBR521
00580  I3000-EXIT.                                                      DTSBR521
00581      EXIT.                                                        DTSBR521
00582      EJECT                                                        DTSBR521
00583  P1000-PROCESS.                                                   DTSBR521
00584                                                                   DTSBR521
00585       PERFORM P3000-TAX-WAGES  THRU P3000-EXIT VARYING            DTSBR521
00586               R521-TAX-WAGE-IDX FROM 1 BY 1 UNTIL                 DTSBR521
00587               R521-TAX-WAGE-IDX > 2.                              DTSBR521
00588                                                                   DTSBR521
00589       IF R521-COMPUTED-RATE = WS-FUIR-UI-RATE                     DTSBR521
00590          IF  R521-UI-RATE-CATEGORY =  WS-UI-RATE-CATEGORY         DTSBR521
00591              MOVE WS-FUIR-UI-RATE-D TO WS-REG-UI-RATE-D           DTSBR521
00592              MOVE WS-REG-UI-RATE-D (4:4) TO DTL-REG-UI-RATE-D     DTSBR521
00593          ELSE                                                     DTSBR521
00594            PERFORM P1200-EMPLR-CATEGORY THRU P1200-EXIT           DTSBR521
00595            PERFORM P1300-RESET-TOTALS  THRU P1300-EXIT            DTSBR521
00596       ELSE                                                        DTSBR521
00597                                                                   DTSBR521
00598          MOVE WS-REG-EMPL-COUNT        TO DTL-REG-EMPL-COUNT      DTSBR521
00599          MOVE WS-REG-UI-TAX-PAID       TO DTL-REG-UI-TAX-PAID     DTSBR521
00600          MOVE WS-REG-TRUST-FUND-INT    TO DTL-REG-TRUST-FUND-INT  DTSBR521
00601          MOVE WS-REG-BENEFITS-CHGD     TO DTL-REG-BENEFITS-CHGD   DTSBR521
00602          MOVE WS-REG-CURRENT-RESERVE   TO DTL-REG-CURRENT-RESERVE DTSBR521
00603          MOVE WS-REG-TAXABLE-WAGES1    TO DTL-REG-TAXABLE-WAGES1  DTSBR521
00604          MOVE WS-REG-TAXABLE-WAGES2    TO DTL-REG-TAXABLE-WAGES2  DTSBR521
00605                                                                   DTSBR521
00606          PERFORM P5000-PRINT-HEADER THRU P5000-EXIT               DTSBR521
00607          WRITE PRT-RECORD FROM DTL-LINE-2  AFTER 2                DTSBR521
00608          ADD +2    TO WS-LINE-CNT2                                DTSBR521
00609                                                                   DTSBR521
00610          MOVE R521-COMPUTED-RATE TO WS-FUIR-UI-RATE               DTSBR521
00611          MOVE R521-UI-RATE-CATEGORY TO WS-UI-RATE-CATEGORY        DTSBR521
00612          PERFORM P1300-RESET-TOTALS  THRU P1300-EXIT              DTSBR521
00613          PERFORM I2100-SET-RATIO THRU I2100-EXIT                  DTSBR521
00614                  VARYING FUIR-RATE-IDX FROM 1 BY 1 UNTIL          DTSBR521
00615                  FUIR-RATE-IDX GREATER FUIR-RATE-CNT              DTSBR521
00616          MOVE WS-FUIR-UI-RATE-D TO WS-REG-UI-RATE-D               DTSBR521
00617          MOVE WS-REG-UI-RATE-D (4:4) TO DTL-REG-UI-RATE-D         DTSBR521
00618       END-IF.                                                     DTSBR521
00619                                                                   DTSBR521
00620        PERFORM P1100-ADD-REGULAR    THRU P1100-EXIT.              DTSBR521
00621        PERFORM P1050-EMPLR-CLASS    THRU P1050-EXIT.              DTSBR521
00622  P1000-EXIT.                                                      DTSBR521
00623       EXIT.                                                       DTSBR521
00624       EJECT                                                       DTSBR521
00625  P1050-EMPLR-CLASS.                                               DTSBR521
00626       IF R521-RATE-CLASSIFIED-88                                  DTSBR521
00627          ADD R521-TRUST-FUND-INTEREST-AMT TO                      DTSBR521
00628              WS-CLS-TRUST-FUND-INT                                DTSBR521
00629          ADD R521-BENEFITS-CHARGED-AMT TO                         DTSBR521
00630              WS-CLS-BENEFITS-CHGD                                 DTSBR521
00631          ADD R521-UI-TAX-PAID-AMT TO                              DTSBR521
00632              WS-CLS-UI-TAX-PAID                                   DTSBR521
00633          ADD R521-CURRENT-RESERVE-AMT TO                          DTSBR521
00634              WS-CLS-CURRENT-RESERVE                               DTSBR521
00635          ADD WS-OUT-TAXABLE-WAGES1 TO                             DTSBR521
00636              WS-CLS-TAXABLE-WAGES1                                DTSBR521
00637          ADD WS-OUT-TAXABLE-WAGES2 TO                             DTSBR521
00638              WS-CLS-TAXABLE-WAGES2                                DTSBR521
00639         ADD 1 TO WS-CLS-EMPL-COUNT                                DTSBR521
00640       END-IF.                                                     DTSBR521
00641                                                                   DTSBR521
00642       IF R521-RATE-NONCLASSIFIED-88                               DTSBR521
00643          ADD R521-TRUST-FUND-INTEREST-AMT TO                      DTSBR521
00644              WS-EMP-TRUST-FUND-INT                                DTSBR521
00645          ADD R521-BENEFITS-CHARGED-AMT TO                         DTSBR521
00646              WS-EMP-BENEFITS-CHGD                                 DTSBR521
00647          ADD R521-UI-TAX-PAID-AMT TO                              DTSBR521
00648              WS-EMP-UI-TAX-PAID                                   DTSBR521
00649          ADD R521-CURRENT-RESERVE-AMT TO                          DTSBR521
00650              WS-EMP-CURRENT-RESERVE                               DTSBR521
00651          ADD WS-OUT-TAXABLE-WAGES1 TO                             DTSBR521
00652              WS-EMP-TAXABLE-WAGES1                                DTSBR521
00653          ADD WS-OUT-TAXABLE-WAGES2 TO                             DTSBR521
00654              WS-EMP-TAXABLE-WAGES2                                DTSBR521
00655          ADD 1 TO  WS-EMP-EMPL-COUNT                              DTSBR521
00656       END-IF.                                                     DTSBR521
00657                                                                   DTSBR521
00658  P1050-EXIT.                                                      DTSBR521
00659      EXIT.                                                        DTSBR521
00660                                                                   DTSBR521
00661  P1100-ADD-REGULAR.                                               DTSBR521
00662        ADD   R521-TRUST-FUND-INTEREST-AMT TO                      DTSBR521
00663              WS-REG-TRUST-FUND-INT.                               DTSBR521
00664        ADD   R521-BENEFITS-CHARGED-AMT TO                         DTSBR521
00665              WS-REG-BENEFITS-CHGD.                                DTSBR521
00666        ADD   R521-UI-TAX-PAID-AMT TO                              DTSBR521
00667              WS-REG-UI-TAX-PAID.                                  DTSBR521
00668        ADD   R521-CURRENT-RESERVE-AMT TO                          DTSBR521
00669              WS-REG-CURRENT-RESERVE.                              DTSBR521
00670        ADD   WS-OUT-TAXABLE-WAGES1    TO                          DTSBR521
00671              WS-REG-TAXABLE-WAGES1.                               DTSBR521
00672        ADD   WS-OUT-TAXABLE-WAGES2    TO                          DTSBR521
00673              WS-REG-TAXABLE-WAGES2.                               DTSBR521
00674        ADD 1 TO WS-REG-EMPL-COUNT.                                DTSBR521
00675  P1100-EXIT.                                                      DTSBR521
00676      EXIT.                                                        DTSBR521
00677                                                                   DTSBR521
00678  P1200-EMPLR-CATEGORY.                                            DTSBR521
00679       MOVE R521-COMPUTED-RATE      TO WS-FUIR-UI-RATE             DTSBR521
00680       MOVE R521-UI-RATE-CATEGORY   TO WS-UI-RATE-CATEGORY.        DTSBR521
00681  P1200-EXIT.                                                      DTSBR521
00682      EXIT.                                                        DTSBR521
00683                                                                   DTSBR521
00684  P1300-RESET-TOTALS.                                              DTSBR521
00685      INITIALIZE WS-REG-TRUST-FUND-INT                             DTSBR521
00686                 WS-REG-BENEFITS-CHGD                              DTSBR521
00687                 WS-REG-EMPL-COUNT                                 DTSBR521
00688                 WS-REG-UI-TAX-PAID                                DTSBR521
00689                 WS-REG-CURRENT-RESERVE                            DTSBR521
00690                 WS-REG-TAXABLE-WAGES1                             DTSBR521
00691                 WS-REG-TAXABLE-WAGES2.                            DTSBR521
00692  P1300-EXIT.                                                      DTSBR521
00693      EXIT.                                                        DTSBR521
00694                                                                   DTSBR521
00695  P2000-TAX-QTRS.                                                  DTSBR521
00696                                                                   DTSBR521
00697       IF R521-WAGES-FROM-YRQ (R521-WAGES-YRQ-IDX) > 0             DTSBR521
00698          MOVE R521-WAGES-FROM-YRQ (R521-WAGES-YRQ-IDX)            DTSBR521
00699               TO L004-QTR-5-9                                     DTSBR521
00700          PERFORM S004-FROM-5 THRU S004-EXIT                       DTSBR521
00701          MOVE L004-SLASH-QTR TO WS-TAX-QTR-FROM                   DTSBR521
00702        ELSE                                                       DTSBR521
00703          MOVE SPACES TO WS-TAX-QTR-FROM                           DTSBR521
00704        END-IF.                                                    DTSBR521
00705       IF R521-WAGES-FROM-YRQ (R521-WAGES-YRQ-IDX) > 0             DTSBR521
00706          MOVE R521-WAGES-THRU-YRQ (R521-WAGES-YRQ-IDX)            DTSBR521
00707               TO L004-QTR-5-9                                     DTSBR521
00708        PERFORM S004-FROM-5 THRU S004-EXIT                         DTSBR521
00709        MOVE L004-SLASH-QTR TO WS-TAX-QTR-THRU                     DTSBR521
00710       ELSE                                                        DTSBR521
00711          MOVE SPACES TO WS-TAX-QTR-THRU                           DTSBR521
00712       END-IF.                                                     DTSBR521
00713       EVALUATE TRUE                                               DTSBR521
00714          WHEN R521-WAGES-YRQ-IDX = 1                              DTSBR521
00715              MOVE WS-TAX-QTR-FROM TO WS-TAX-WAGE1-FROM            DTSBR521
00716              MOVE WS-TAX-QTR-THRU TO WS-TAX-WAGE1-THRU            DTSBR521
00717              MOVE WS-TAX-WAGE1-FROM-THRU TO                       DTSBR521
00718                      HDR-TAX-WAGE1-FROM-THRU                      DTSBR521
00719          WHEN R521-WAGES-YRQ-IDX = 2                              DTSBR521
00720              MOVE WS-TAX-QTR-FROM TO WS-TAX-WAGE2-FROM            DTSBR521
00721              MOVE WS-TAX-QTR-THRU TO WS-TAX-WAGE2-THRU            DTSBR521
00722              MOVE WS-TAX-WAGE2-FROM-THRU TO                       DTSBR521
00723                      HDR-TAX-WAGE2-FROM-THRU                      DTSBR521
00724       END-EVALUATE.                                               DTSBR521
00725                                                                   DTSBR521
00726  P2000-EXIT.                                                      DTSBR521
00727      EXIT.                                                        DTSBR521
00728  P3000-TAX-WAGES.                                                 DTSBR521
00729      EVALUATE TRUE                                                DTSBR521
00730          WHEN R521-TAX-WAGE-IDX = 1                               DTSBR521
00731              MOVE R521-TAX-WAGE (R521-TAX-WAGE-IDX) TO            DTSBR521
00732                   WS-OUT-TAXABLE-WAGES1                           DTSBR521
00733          WHEN R521-TAX-WAGE-IDX = 2                               DTSBR521
00734              MOVE R521-TAX-WAGE (R521-TAX-WAGE-IDX) TO            DTSBR521
00735                   WS-OUT-TAXABLE-WAGES2                           DTSBR521
00736      END-EVALUATE.                                                DTSBR521
00737  P3000-EXIT.                                                      DTSBR521
00738      EXIT.                                                        DTSBR521
00739                                                                   DTSBR521
00740  P4000-GRAND-TOTALS.                                              DTSBR521
00741                                                                   DTSBR521
00742      ADD WS-CLS-EMPL-COUNT   WS-EMP-EMPL-COUNT                    DTSBR521
00743      GIVING WS-GRD-EMPLR-COUNT.                                   DTSBR521
00744      ADD WS-CLS-TRUST-FUND-INT   WS-EMP-TRUST-FUND-INT            DTSBR521
00745      GIVING WS-GRD-TRUST-FUND-INT.                                DTSBR521
00746      ADD WS-CLS-BENEFITS-CHGD  WS-EMP-BENEFITS-CHGD               DTSBR521
00747      GIVING WS-GRD-BENEFITS-CHGD.                                 DTSBR521
00748      ADD WS-CLS-UI-TAX-PAID  WS-EMP-UI-TAX-PAID                   DTSBR521
00749      GIVING WS-GRD-UI-TAX-PAID.                                   DTSBR521
00750      ADD WS-CLS-CURRENT-RESERVE WS-EMP-CURRENT-RESERVE            DTSBR521
00751      GIVING WS-GRD-CURRENT-RESERVE.                               DTSBR521
00752      ADD WS-CLS-TAXABLE-WAGES1  WS-EMP-TAXABLE-WAGES1             DTSBR521
00753      GIVING WS-GRD-TAXABLE-WAGES1.                                DTSBR521
00754      ADD WS-CLS-TAXABLE-WAGES2  WS-EMP-TAXABLE-WAGES2             DTSBR521
00755      GIVING WS-GRD-TAXABLE-WAGES2.                                DTSBR521
00756                                                                   DTSBR521
00757  P4000-EXIT.                                                      DTSBR521
00758      EXIT.                                                        DTSBR521
00759                                                                   DTSBR521
00760  P5000-PRINT-HEADER.                                              DTSBR521
00761      IF WS-LINE-CNT GREATER 58 OR                                 DTSBR521
00762           WS-LINE-CNT2 GREATER 58                                 DTSBR521
00763         MOVE +0          TO WS-LINE-CNT                           DTSBR521
00764         MOVE +0          TO WS-LINE-CNT2                          DTSBR521
00765         ADD  +1          TO WS-PAGE-CNT                           DTSBR521
00766         MOVE WS-PAGE-CNT TO HDR-PAGE-CNT                          DTSBR521
00767         WRITE PRT-RECORD FROM HDR-LINE-1 AFTER TOP-OF-PAGE        DTSBR521
00768         WRITE PRT-RECORD FROM HDR-LINE-2 AFTER 1                  DTSBR521
00769         WRITE PRT-RECORD FROM HDR-LINE-3 AFTER 1                  DTSBR521
00770         WRITE PRT-RECORD FROM HDR-LINE-4 AFTER 1                  DTSBR521
00771         WRITE PRT-RECORD FROM HDR-LINE-5 AFTER 1                  DTSBR521
00772         WRITE PRT-RECORD FROM HDR-LINE-6 AFTER 1                  DTSBR521
00773         WRITE PRT-RECORD FROM HDR-LINE-7 AFTER 1                  DTSBR521
00774         WRITE PRT-RECORD FROM HDR-LINE-8 AFTER 1                  DTSBR521
00775         WRITE PRT-RECORD FROM HDR-LINE-9 AFTER 1                  DTSBR521
00776         WRITE PRT-RECORD FROM HDR-LINE-10 AFTER 1                 DTSBR521
00777         ADD +10   TO WS-LINE-CNT2.                                DTSBR521
00778  P5000-EXIT.                                                      DTSBR521
00779      EXIT.                                                        DTSBR521
00780                                                                   DTSBR521
00781  T1000-TERMINATE.                                                 DTSBR521
00782                                                                   DTSBR521
00783      IF WS-LINE-CNT2 > 52                                         DTSBR521
00784         ADD +6    TO WS-LINE-CNT2                                 DTSBR521
00785         PERFORM P5000-PRINT-HEADER THRU P5000-EXIT                DTSBR521
00786      END-IF.                                                      DTSBR521
00787                                                                   DTSBR521
00788      MOVE WS-REG-UI-RATE-D (4:4)   TO DTL-REG-UI-RATE-D.          DTSBR521
00789      MOVE WS-REG-EMPL-COUNT        TO DTL-REG-EMPL-COUNT.         DTSBR521
00790      MOVE WS-REG-UI-TAX-PAID       TO DTL-REG-UI-TAX-PAID.        DTSBR521
00791      MOVE WS-REG-TRUST-FUND-INT    TO DTL-REG-TRUST-FUND-INT.     DTSBR521
00792      MOVE WS-REG-BENEFITS-CHGD     TO DTL-REG-BENEFITS-CHGD.      DTSBR521
00793      MOVE WS-REG-CURRENT-RESERVE   TO DTL-REG-CURRENT-RESERVE.    DTSBR521
00794      MOVE WS-REG-TAXABLE-WAGES1    TO DTL-REG-TAXABLE-WAGES1.     DTSBR521
00795      MOVE WS-REG-TAXABLE-WAGES2    TO DTL-REG-TAXABLE-WAGES2.     DTSBR521
00796      WRITE PRT-RECORD FROM DTL-LINE-2 AFTER 2.                    DTSBR521
00797                                                                   DTSBR521
00798      IF WS-LINE-CNT2 > 52                                         DTSBR521
00799         ADD +6    TO WS-LINE-CNT2                                 DTSBR521
00800         PERFORM P5000-PRINT-HEADER THRU P5000-EXIT                DTSBR521
00801      END-IF.                                                      DTSBR521
00802                                                                   DTSBR521
00803      MOVE WS-CLS-EMPL-COUNT        TO DTL-CLS-EMPL-COUNT.         DTSBR521
00804      MOVE WS-CLS-UI-TAX-PAID       TO DTL-CLS-UI-TAX-PAID.        DTSBR521
00805      MOVE WS-CLS-TRUST-FUND-INT    TO DTL-CLS-TRUST-FUND-INT.     DTSBR521
00806      MOVE WS-CLS-BENEFITS-CHGD     TO DTL-CLS-BENEFITS-CHGD.      DTSBR521
00807      MOVE WS-CLS-CURRENT-RESERVE   TO DTL-CLS-CURRENT-RESERVE.    DTSBR521
00808      MOVE WS-CLS-TAXABLE-WAGES1    TO DTL-CLS-TAXABLE-WAGES1.     DTSBR521
00809      MOVE WS-CLS-TAXABLE-WAGES2    TO DTL-CLS-TAXABLE-WAGES2.     DTSBR521
00810      WRITE PRT-RECORD FROM DTL-CLS-LINE-3  AFTER 3.               DTSBR521
00811                                                                   DTSBR521
00812      IF WS-LINE-CNT2 > 52                                         DTSBR521
00813         ADD +6    TO WS-LINE-CNT2                                 DTSBR521
00814         PERFORM P5000-PRINT-HEADER THRU P5000-EXIT                DTSBR521
00815      END-IF.                                                      DTSBR521
00816                                                                   DTSBR521
00817      MOVE WS-EMP-UI-RATE (4:4)     TO DTL-EMP-UI-RATE.            DTSBR521
00818      MOVE WS-EMP-EMPL-COUNT        TO DTL-EMP-EMPL-COUNT.         DTSBR521
00819      MOVE WS-EMP-UI-TAX-PAID       TO DTL-EMP-UI-TAX-PAID.        DTSBR521
00820      MOVE WS-EMP-TRUST-FUND-INT    TO DTL-EMP-TRUST-FUND-INT.     DTSBR521
00821      MOVE WS-EMP-BENEFITS-CHGD     TO DTL-EMP-BENEFITS-CHGD.      DTSBR521
00822      MOVE WS-EMP-CURRENT-RESERVE   TO DTL-EMP-CURRENT-RESERVE.    DTSBR521
00823      MOVE WS-EMP-TAXABLE-WAGES1    TO DTL-EMP-TAXABLE-WAGES1.     DTSBR521
00824      MOVE WS-EMP-TAXABLE-WAGES2    TO DTL-EMP-TAXABLE-WAGES2.     DTSBR521
00825      WRITE PRT-RECORD FROM DTL-EMP-LINE-3  AFTER 3.               DTSBR521
00826                                                                   DTSBR521
00827      IF WS-LINE-CNT2 > 52                                         DTSBR521
00828         ADD +6    TO WS-LINE-CNT2                                 DTSBR521
00829         PERFORM P5000-PRINT-HEADER THRU P5000-EXIT                DTSBR521
00830      END-IF.                                                      DTSBR521
00831                                                                   DTSBR521
00832      PERFORM P4000-GRAND-TOTALS THRU P4000-EXIT.                  DTSBR521
00833      MOVE WS-GRD-EMPLR-COUNT       TO CFF-GRD-EMPLR-COUNT.        DTSBR521
00834      MOVE WS-GRD-UI-TAX-PAID       TO CFF-GRD-UI-TAX-PAID.        DTSBR521
00835      MOVE WS-GRD-TRUST-FUND-INT    TO CFF-GRD-TRUST-FUND-INT.     DTSBR521
00836      MOVE WS-GRD-BENEFITS-CHGD     TO CFF-GRD-BENEFITS-CHGD.      DTSBR521
00837      MOVE WS-GRD-CURRENT-RESERVE   TO CFF-GRD-CURRENT-RESERVE.    DTSBR521
00838      MOVE WS-GRD-TAXABLE-WAGES1    TO CFF-GRD-TAXABLE-WAGES1.     DTSBR521
00839      MOVE WS-GRD-TAXABLE-WAGES2    TO CFF-GRD-TAXABLE-WAGES2.     DTSBR521
00840      WRITE PRT-RECORD FROM CFF-GRD-LINE-3  AFTER 3.               DTSBR521
00841                                                                   DTSBR521
00842      CLOSE PRT-FILE.                                              DTSBR521
00843                                                                   DTSBR521
00844  T1000-EXIT.                                                      DTSBR521
00845      EXIT.                                                        DTSBR521
00846      EJECT                                                        DTSBR521
00847  S001-DATE.                                                       DTSBR521
00848                                                                   DTSBR521
00849       CALL 'DTSBU001' USING L001-LINK-AREA.                       DTSBR521
00850                                                                   DTSBR521
00851  S001-EXIT.                                                       DTSBR521
00852      EXIT.                                                        DTSBR521
00853                                                                   DTSBR521
00854  S004-FROM-5.                                                     DTSBR521
00855                                                                   DTSBR521
00856      SET L004-FROM-5 TO TRUE.                                     DTSBR521
00857                                                                   DTSBR521
00858      CALL 'DTSBU004' USING L004-LINK-AREA.                        DTSBR521
00859                                                                   DTSBR521
00860  S004-EXIT.                                                       DTSBR521
00861      EXIT.                                                        DTSBR521
00862                                                                   DTSBR521
00863  S056-RATE-DISPLAY.                                               DTSBR521
00864                                                                   DTSBR521
00865      CALL 'DTSBU056' USING L056-LINK-AREA.                        DTSBR521
00866                                                                   DTSBR521
00867  S056-EXIT.                                                       DTSBR521
00868      EXIT.                                                        DTSBR521
00869                                                                   DTSBR521
00870  S057-RATIO-DISPLAY.                                              DTSBR521
00871                                                                   DTSBR521
00872      CALL 'DTSBU057' USING L057-LINK-AREA.                        DTSBR521
00873                                                                   DTSBR521
00874  S057-EXIT.                                                       DTSBR521
00875      EXIT.                                                        DTSBR521
00876                                                                   DTSBR521
00877  S931-READ.                                                       DTSBR521
00878      SET L931-READ-88 TO TRUE.                                    DTSBR521
00879      GO TO S931-REF-I.                                            DTSBR521
00880                                                                   DTSBR521
00881  S931-REF-I.                                                      DTSBR521
00882       CALL 'DTSBU931' USING L931-LINK-AREA                        DTSBR521
00883                             FSKL-REC.                             DTSBR521
00884  S931-EXIT.                                                       DTSBR521
00885       EXIT.                                                       DTSBR521
00886                                                                   DTSBR521
00887  S999-ABEND.                                                      DTSBR521
00888                                                                   DTSBR521
00889      CALL 'DTSBU999' USING WRK-ABEND-CD.                          DTSBR521
00890                                                                   DTSBR521
00891  S999-EXIT.                                                       DTSBR521
00892      EXIT.                                                        DTSBR521
