00001  IDENTIFICATION DIVISION.                                         09/03/98
00002  PROGRAM-ID.             DTSCSSF.                                 DTSCSDC
00003  AUTHOR.                 TRICOASTAL CONSULTING LTD.                  LV006
00004  DATE-WRITTEN.           NOVEMBER 1991.                           DTSCSDC
00005  DATE-COMPILED.                                                   DTSCSDC
00006      SKIP3                                                        DTSCSDC
00007 *****                                                             DTSCSDC
00008 *                                                                 DTSCSDC
00009 *    FUNCTION:  SIGN OFF SCREEN PROCESSOR.                        DTSCSDC
00010 *                                                                 DTSCSDC
00011 *                                                                 DTSCSDC
00012 *    MODIFICATION LOG:                                            DTSCSDC
00013 *                                                                 DTSCSDC
00014 *    11/06/91  INITIAL DEVELOPMENT.                               DTSCSDC
00015 *              WORK ORDER:                      PROGRAMMER: TCL   DTSCSDC
00016 *                                                                 DTSCSDC
00017 *    04/06/94  MODIFIED FOR MONTANA.                              DTSCSDC
00018 *              WORK ORDER:                      PROGRAMMER: EHH   DTSCSDC
00019 *                                                                 DTSCSDC
00020 *    08/12/1998  REVIEWED AND MODIFIED FOR DC.                       CL**2
00021 *                REFERENCE: DC DEVELOPMENT      PROGRAMMER: EHH      CL**2
00022 *                                                                    CL**2
00023 *    MM/DD/YYYY  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX      CL**2
00024 *                XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX      CL**2
00025 *                REFERENCE: XXXXXXXXXXXXXXX     PROGRAMMER: XXX      CL**2
00026 *                                                                 DTSCSDC
00027 *                                                                 DTSCSDC
00028 *    DESCRIPTION:                                                 DTSCSDC
00029 *                                                                 DTSCSDC
00030 *        IF LCCM-NO-MSG                                           DTSCSDC
00031 *            MOVE PMSG-SIGNOFF-COMPLETE TO LCCM-MSG-AREA.         DTSCSDC
00032 *                                                                 DTSCSDC
00033 *        DELETE ALL TEMPORARY STORAGE AREAS ASSOCIATED WITH       DTSCSDC
00034 *        THE PSEUDO CONVERSATION (VIA LINK TO DTSCU898).             CL**2
00035 *                                                                 DTSCSDC
00036 *        SEND THE SF SCREEN (WITH THE MESSAGE FROM LCCM-MSG-AREA).DTSCSDC
00037 *                                                                 DTSCSDC
00038 *        LINK TO 'UCTRAN', TURNING THE WORK STATION UPPER CASE    DTSCSDC
00039 *        TRANSLATION INDICATOR TO 'ON'.                           DTSCSDC
00040 *                                                                 DTSCSDC
00041 *        RETURN TO CICS, ENDING THE PSEUDO CONVERSATION.          DTSCSDC
00042 *                                                                 DTSCSDC
00043 *                                                                 DTSCSDC
00044 *****                                                             DTSCSDC
00045      SKIP3                                                        DTSCSDC
00046  ENVIRONMENT DIVISION.                                            DTSCSDC
00047      SKIP3                                                        DTSCSDC
00048  DATA DIVISION.                                                   DTSCSDC
00049      SKIP3                                                        DTSCSDC
00050  WORKING-STORAGE SECTION.                                         DTSCSDC
000505 77  PAN-VALET PICTURE X(24) VALUE '006DTSCSDC   09/03/98'.       DTSCSDC
00051      SKIP3                                                        DTSCSDC
00052  01  WRK-AREA.                                                    DTSCSDC
00053      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'SSF '.    DTSCSDC
00054      05  WRK-RESP-CD                 PIC S9(08)  COMP.            DTSCSDC
00055                                                                   DTSCSDC
00056      05  WRK-SCR-ID                  PIC  X(02)  VALUE 'SF'.      DTSCSDC
00057                                                                   DTSCSDC
00058      05  WRK-THANK-YOU-IND           PIC  X(01).                  DTSCSDC
00059                                                                   DTSCSDC
00060      05  UCPARM                      PIC  X(01)  VALUE 'U'.          CL**4
00061      EJECT                                                        DTSCSDC
00062  01  PMSG-LITERALS.                                               DTSCSDC
00063      05  PMSG-THANK-YOU.                                          DTSCSDC
00064          10  FILLER                      PIC  X(04)  VALUE 'P999'.DTSCSDC
00065          10  PMSG-THANK-YOU-MESSAGE.                              DTSCSDC
00066              15  FILLER                  PIC  X(30)               DTSCSDC
00067                VALUE 'DTS (UI TAX SYSTEM) SIGN OFF C'.               CL**2
00068              15  FILLER                  PIC  X(30)               DTSCSDC
00069                VALUE 'OMPLETED                      '.            DTSCSDC
00070      EJECT                                                        DTSCSDC
00071  01  L831-COMM-AREA.                                              DTSCSDC
00072  ++INCLUDE DTSIL831                                                  CL**2
00073      SKIP3                                                        DTSCSDC
00074      05  FSKL-REC.                                                DTSCSDC
00075  ++INCLUDE DTSIFSKL                                                  CL**2
00076      SKIP3                                                        DTSCSDC
00077      05  FOPR-REC REDEFINES FSKL-REC.                             DTSCSDC
00078  ++INCLUDE DTSIFOPR                                                  CL**2
00079      EJECT                                                        DTSCSDC
00080  01  L851-COMM-AREA.                                              DTSCSDC
00081  ++INCLUDE DTSIL851                                                  CL**2
00082      SKIP3                                                        DTSCSDC
00083      05  MAP-AREA REDEFINES L851-MAP-AREA.                        DTSCSDC
00084  ++INCLUDE DTSISSF                                                   CL**2
00085      EJECT                                                        DTSCSDC
00086  01  L805-COMM-AREA.                                              DTSCSDC
00087  ++INCLUDE DTSIL805                                                  CL**2
00088      EJECT                                                        DTSCSDC
00089  01  CATB-LITERALS.                                               DTSCSDC
00090  ++INCLUDE DTSICATB                                                  CL**2
00091      EJECT                                                        DTSCSDC
00092  LINKAGE SECTION.                                                 DTSCSDC
00093      SKIP3                                                        DTSCSDC
00094  01  DFHCOMMAREA.                                                 DTSCSDC
00095  ++INCLUDE DTSILCCM                                                  CL**2
00096      EJECT                                                        DTSCSDC
00097  PROCEDURE DIVISION.                                              DTSCSDC
00098      SKIP2                                                        DTSCSDC
00099      IF LCCM-NO-MSG                                               DTSCSDC
00100          PERFORM P1000-FOPR-UPDATE THRU P1000-EXIT.               DTSCSDC
00101                                                                   DTSCSDC
00102      PERFORM S898-TS-DELETE THRU S898-EXIT.                       DTSCSDC
00103                                                                   DTSCSDC
00104      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCSDC
00105                                                                   DTSCSDC
00106      IF LCCM-NO-MSG                                               DTSCSDC
00107          MOVE PMSG-THANK-YOU TO LCCM-MSG-AREA.                    DTSCSDC
00108                                                                   DTSCSDC
00109      PERFORM S805-MSG-AREA THRU S805-EXIT.                        DTSCSDC
00110                                                                   DTSCSDC
00111      PERFORM S2100-SEND THRU S2100-EXIT.                          DTSCSDC
00112                                                                   DTSCSDC
00113      PERFORM SUCTRAN-ON THRU SUCTRAN-EXIT.                        DTSCSDC
00114                                                                   DTSCSDC
00115      SET LCCM-END-CONVERSATION-88 TO TRUE.                        DTSCSDC
00116                                                                   DTSCSDC
00117      EXEC CICS                                                    DTSCSDC
00118          RETURN                                                   DTSCSDC
00119      END-EXEC.                                                    DTSCSDC
00120      SKIP2                                                        DTSCSDC
00121      GOBACK.                                                      DTSCSDC
00122      EJECT                                                        DTSCSDC
00123  P1000-FOPR-UPDATE.                                               DTSCSDC
00124      MOVE LOW-VALUES TO FOPR-KEY-AREA.                            DTSCSDC
00125      SET FOPR-OPR-88 TO TRUE.                                     DTSCSDC
00126      MOVE LCCM-OP-ID TO FOPR-OP-ID.                               DTSCSDC
00127                                                                   DTSCSDC
00128      PERFORM S831-REF-READ THRU S831-EXIT.                        DTSCSDC
00129      IF L831-OK-88                                                DTSCSDC
00130          NEXT SENTENCE                                            DTSCSDC
00131      ELSE                                                         DTSCSDC
00132          GO TO P1000-EXIT.                                        DTSCSDC
00133                                                                   DTSCSDC
00134      IF LCCM-OP-ALARM-IND = SPACES OR LOW-VALUES                  DTSCSDC
00135          NEXT SENTENCE                                            DTSCSDC
00136      ELSE                                                         DTSCSDC
00137          MOVE LCCM-OP-ALARM-IND TO FOPR-ALARM-IND.                DTSCSDC
00138                                                                   DTSCSDC
00139      IF LCCM-OP-ARPT-EDIT-MINIMAL-88                                 CL**2
00140             OR                                                       CL**2
00141         LCCM-OP-ARPT-EDIT-FULL-88                                    CL**2
00142          MOVE LCCM-OP-ARPT-EDIT-MODE TO FOPR-ARPT-EDIT-MODE.         CL**2
00143                                                                      CL**2
00144      IF LCCM-PRINTER-ID = SPACES OR LOW-VALUES                    DTSCSDC
00145          NEXT SENTENCE                                            DTSCSDC
00146      ELSE                                                         DTSCSDC
00147          MOVE LCCM-PRINTER-ID TO FOPR-PRINTER-ID.                 DTSCSDC
00148                                                                   DTSCSDC
00149      IF LCCM-BATCH-NO NUMERIC                                     DTSCSDC
00150          MOVE LCCM-BATCH-NO TO FOPR-BATCH-NO.                     DTSCSDC
00151                                                                   DTSCSDC
00152      PERFORM S831-REF-REWRITE THRU S831-EXIT.                     DTSCSDC
00153  P1000-EXIT.                                                      DTSCSDC
00154      EXIT.                                                        DTSCSDC
00155      EJECT                                                        DTSCSDC
00156  S805-MSG-AREA.                                                   DTSCSDC
00157      MOVE LCCM-MSG-AREA TO L805-MSG-AREA.                         DTSCSDC
00158                                                                   DTSCSDC
00159      EXEC CICS                                                    DTSCSDC
00160          LINK                                                     DTSCSDC
00161              PROGRAM ('DTSCU805')                                    CL**2
00162              COMMAREA (L805-COMM-AREA)                            DTSCSDC
00163      END-EXEC.                                                    DTSCSDC
00164                                                                   DTSCSDC
00165      MOVE L805-S-MSG-AREA TO MAP-MSG-AREA.                        DTSCSDC
00166                                                                   DTSCSDC
00167      MOVE SPACES TO MAP-MSG-ID (1:3).                             DTSCSDC
00168  S805-EXIT.                                                       DTSCSDC
00169      EXIT.                                                        DTSCSDC
00170      SKIP3                                                        DTSCSDC
00171  S831-REF-READ.                                                   DTSCSDC
00172      SET L831-READ-88 TO TRUE.                                    DTSCSDC
00173      GO TO S831-REF-IO.                                           DTSCSDC
00174                                                                   DTSCSDC
00175  S831-REF-REWRITE.                                                DTSCSDC
00176      SET L831-REWRITE-88 TO TRUE.                                 DTSCSDC
00177      GO TO S831-REF-IO.                                           DTSCSDC
00178                                                                   DTSCSDC
00179  S831-REF-IO.                                                     DTSCSDC
00180                                                                   DTSCSDC
00181      EXEC CICS                                                    DTSCSDC
00182          LINK                                                     DTSCSDC
00183              PROGRAM ('DTSCU831')                                    CL**2
00184              COMMAREA (L831-COMM-AREA)                            DTSCSDC
00185      END-EXEC.                                                    DTSCSDC
00186                                                                   DTSCSDC
00187  S831-EXIT.                                                       DTSCSDC
00188      EXIT.                                                        DTSCSDC
00189      SKIP3                                                        DTSCSDC
00190  S898-TS-DELETE.                                                  DTSCSDC
00191      EXEC CICS                                                    DTSCSDC
00192          LINK                                                     DTSCSDC
00193              PROGRAM ('DTSCU898')                                    CL**2
00194      END-EXEC.                                                    DTSCSDC
00195  S898-EXIT.                                                       DTSCSDC
00196      EXIT.                                                        DTSCSDC
00197      SKIP3                                                        DTSCSDC
00198  SUCTRAN-ON.                                                      DTSCSDC
00199                                                                      CL**2
00200 *****                                                                CL**2
00201 *                                                                    CL**2
00202 *    UCTRAN VERSION 4.1                                              CL**4
00203 *                                                                    CL**2
00204 *****                                                                CL**2
00205                                                                      CL**2
00206      EXEC CICS                                                       CL**3
00207          LINK                                                        CL**3
00208              PROGRAM ('UCTRAN41')                                    CL**6
00209              COMMAREA (UCPARM)                                       CL**4
00210      END-EXEC.                                                       CL**3
00211                                                                   DTSCSDC
00212      GO TO SUCTRAN-EXIT.                                          DTSCSDC
00213                                                                   DTSCSDC
00214  SUCTRAN-EXIT.                                                    DTSCSDC
00215      EXIT.                                                        DTSCSDC
00216      EJECT                                                        DTSCSDC
00217  S2100-SEND.                                                      DTSCSDC
00218      MOVE CATB-CURSOR TO MAP-CURSOR-FIELD-L.                      DTSCSDC
00219                                                                   DTSCSDC
00220      SET L851-SEND-88 TO TRUE.                                    DTSCSDC
00221                                                                      CL**2
00222      MOVE WRK-SCR-ID TO L851-SCR-ID                               DTSCSDC
00223                         LCCM-SCR-ID.                              DTSCSDC
00224                                                                   DTSCSDC
00225      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND.                    DTSCSDC
00226                                                                      CL**2
00227      MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE.                         DTSCSDC
00228                                                                      CL**2
00229      EXEC CICS                                                    DTSCSDC
00230          LINK                                                     DTSCSDC
00231              PROGRAM ('DTSCU851')                                    CL**2
00232              COMMAREA (L851-COMM-AREA)                            DTSCSDC
00233      END-EXEC.                                                    DTSCSDC
00234                                                                   DTSCSDC
00235  S2100-EXIT.                                                      DTSCSDC
00236      EXIT.                                                        DTSCSDC
