00001  IDENTIFICATION DIVISION.                                         03/29/11
00002  PROGRAM-ID.             DTSCDRV.                                 DTSCDRV
00003  AUTHOR.                 TRICOASTAL CONSULTING LTD.                  LV011
00004  DATE-WRITTEN.           MARCH 1994.                              DTSCDRV
00005  DATE-COMPILED.                                                   DTSCDRV
00006      SKIP3                                                        DTSCDRV
00007 *****                                                             DTSCDRV
00008 *                                                                 DTSCDRV
00009 *    FUNCTION:  CICS TRANSACTION DRIVER.                          DTSCDRV
00010 *                                                                 DTSCDRV
00011 *                                                                 DTSCDRV
00012 *    MODIFICATION LOG:                                            DTSCDRV
00013 *                                                                 DTSCDRV
00014 *    03/18/94  INITIAL DEVELOPMENT.                               DTSCDRV
00015 *              WORK ORDER:                      PROGRAMMER: EHH   DTSCDRV
00016 *                                                                 DTSCDRV
00017 *    01/27/95  CLEAR LCCM-YRQ WHEN EMP NO CHANGES ON A SCREEN     DTSCDRV
00018 *              WHICH DOESN'T UPDATE LCCM-YRQ.                     DTSCDRV
00019 *              WORK ORDER: CR036                PROGRAMMER: RHC   DTSCDRV
00020 *                                                                 DTSCDRV
00021 *    03/23/95  REPLACE CALL TO DTSCU005 WITH AN ASKTIME           DTSCDRV
00022 *              COMMAND AND A FORMATTIME COMMAND.  ELIMINATES      DTSCDRV
00023 *              TWO LINK COMMANDS IN EACH TASK.                    DTSCDRV
00024 *              WORK ORDER: NON                  PROGRAMMER: EHH   DTSCDRV
00025 *                                                                 DTSCDRV
00026 *    04/04/95  ADD R1 TO THE LIST OF SCREENS WHICH RETAINS YRQ.   DTSCDRV
00027 *              WORK ORDER: CR071                PROGRAMMER: RHC   DTSCDRV
00028 *                                                                 DTSCDRV
00029 *    05/09/95  LCCM-*-ITEM-MAX  WERE CHANGED TO  LCCM-*-TRAN-MAX. DTSCDRV
00030 *              THEY NO LONGER INCLUDE THE CHECKS IN THE COUNTS.   DTSCDRV
00031 *              WORK ORDER: CR076                PROGRAMMER: RHC   DTSCDRV
00032 *                                                                 DTSCDRV
00033 *    09/21/95  INITIALIZE LCCM-FIRST-JR-EMP-NO.  FIRST EMPLOYER   DTSCDRV
00034 *              NUMBER ISSUED UNDER THE "JOINT REGISTRATION"       DTSCDRV
00035 *              PROCESS.                                           DTSCDRV
00036 *              WORK ORDER: JR                   PROGRAMMER: EHH   DTSCDRV
00037 *                                                                 DTSCDRV
00038 *    09/18/97  BOTH CICSAORT AND CICSAORX ARE TEST REGIONS.       DTSCDRV
00039 *              WORK ORDER: TCL 213              PROGRAMMER: EHH   DTSCDRV
00040 *                                                                 DTSCDRV
00041 *    08/13/1998  REVIEWED AND MODIFIED FOR DC.                    DTSCDRV
00042 *                REFERENCE: DC DEVELOPMENT      PROGRAMMER: EHH   DTSCDRV
00043 *                                                                 DTSCDRV
00044 *    05/13/1999  INITIALIZE LCCM-PICKUP-YRQ.                      DTSCDRV
00045 *                REFERENCE: PICKUP DIR          PROGRAMMER: EHH   DTSCDRV
00046 *                                                                 DTSCDRV
00047 *    03/11/2011  RECOMPILED WITH NEW VERSION OF DTSILCCM -        DTSCDRV
00048 *                NON-DOES CHECK EMPLOYER NUMBER ADDED.            DTSCDRV
00049 *                REFERENCE: LOCKBOX             PROGRAMMER: GD    DTSCDRV
00050 *                                                                 DTSCDRV
00051 *    MM/DD/YYYY  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   DTSCDRV
00052 *                XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   DTSCDRV
00053 *                REFERENCE: XXXXXXXXXXXXXXX     PROGRAMMER: XXX   DTSCDRV
00054 *                                                                 DTSCDRV
00055 *                                                                 DTSCDRV
00056 *    DESCRIPTION:                                                 DTSCDRV
00057 *                                                                 DTSCDRV
00058 *    DTSCDRV IS THE DRIVER MODULE FOR CICS TRANSACTION DTS.       DTSCDRV
00059 *    DTS IS, OF COURSE, A PSEUDO CONVERSATIONAL TRANSACTION.      DTSCDRV
00060 *                                                                 DTSCDRV
00061 *    DTSCDRV EITHER STARTS A PSEUDO CONVERSATION OR               DTSCDRV
00062 *    CONTINUES A PSEUDO CONVERSATION.                             DTSCDRV
00063 *                                                                 DTSCDRV
00064 *****                                                             DTSCDRV
00065      SKIP3                                                        DTSCDRV
00066  ENVIRONMENT DIVISION.                                            DTSCDRV
00067      SKIP3                                                        DTSCDRV
00068  DATA DIVISION.                                                   DTSCDRV
00069      SKIP3                                                        DTSCDRV
00070  WORKING-STORAGE SECTION.                                         DTSCDRV
000705 77  PAN-VALET PICTURE X(24) VALUE '011DTSCDRV   03/29/11'.       DTSCDRV
00071      SKIP3                                                        DTSCDRV
00072  01  WRK-AREA.                                                    DTSCDRV
00073      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'DRV '.    DTSCDRV
00074                                                                   DTSCDRV
00075      05  WRK-RESP-CD                 PIC S9(08)  COMP.            DTSCDRV
00076                                                                   DTSCDRV
00077      05  WRK-LCCM-LENGTH             PIC S9(04)  COMP VALUE +4080.DTSCDRV
00078                                                                   DTSCDRV
00079      05  WRK-MOD-NAME.                                            DTSCDRV
00080          10  FILLER                  PIC  X(05)  VALUE 'DTSCS'.   DTSCDRV
00081          10  WRK-MOD-SCR-ID          PIC  X(02).                  DTSCDRV
00082              88  WRK-MOD-SCR-YRQ-88          VALUE '24' THRU '26' DTSCDRV
00083                                                    '31' THRU '36' DTSCDRV
00084                                                    'L1'.          DTSCDRV
00085          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSCDRV
00086                                                                   DTSCDRV
00087      05  WRK-ELAPSE-ABSTIME          PIC S9(15)  COMP-3.          DTSCDRV
00088                                                                   DTSCDRV
00089      05  WRK-PRE-LINK-EMP-NO         PIC S9(07)  COMP-3.          DTSCDRV
00090      SKIP3                                                        DTSCDRV
00091  01  DATE-TIME-AREAS.                                             DTSCDRV
00092      05  WRK-DAYOFMONTH              PIC S9(08)  COMP.            DTSCDRV
00093      05  WRK-MONTHOFYEAR             PIC S9(08)  COMP.            DTSCDRV
00094      05  WRK-YEAR                    PIC S9(08)  COMP.            DTSCDRV
00095                                                                   DTSCDRV
00096      05  WRK-DATE                    PIC  9(08).                  DTSCDRV
00097      05  FILLER REDEFINES WRK-DATE.                               DTSCDRV
00098          10  WRK-DATE-YEAR           PIC  9(04).                  DTSCDRV
00099          10  WRK-DATE-MONTH          PIC  9(02).                  DTSCDRV
00100          10  WRK-DATE-DAY            PIC  9(02).                  DTSCDRV
00101      EJECT                                                        DTSCDRV
00102  01  LCCM-COMM-AREA.                                              DTSCDRV
00103  ++INCLUDE DTSILCCM                                               DTSCDRV
00104      EJECT                                                        DTSCDRV
00105  01  L001-COMM-AREA.                                              DTSCDRV
00106  ++INCLUDE DTSIL001                                               DTSCDRV
00107      EJECT                                                        DTSCDRV
00108  01  L005-COMM-AREA.                                              DTSCDRV
00109  ++INCLUDE DTSIL005                                               DTSCDRV
00110      EJECT                                                        DTSCDRV
00111  01  L810-COMM-AREA.                                              DTSCDRV
00112      05  L810-CONTROL-BLOCK.                                      DTSCDRV
00113  ++INCLUDE DTSIL810                                               DTSCDRV
00114      SKIP3                                                        DTSCDRV
00115      05  MSKL-REC.                                                DTSCDRV
00116  ++INCLUDE DTSIMSKL                                               DTSCDRV
00117      SKIP3                                                        DTSCDRV
00118      05  MHDR-REC REDEFINES MSKL-REC.                             DTSCDRV
00119  ++INCLUDE DTSIMHDR                                               DTSCDRV
00120      EJECT                                                        DTSCDRV
00121  LINKAGE SECTION.                                                 DTSCDRV
00122      SKIP3                                                        DTSCDRV
00123  01  DFHCOMMAREA                         PIC  X(4080).            DTSCDRV
00124      EJECT                                                        DTSCDRV
00125  PROCEDURE DIVISION.                                              DTSCDRV
00126      SKIP2                                                        DTSCDRV
00127 *****                                                             DTSCDRV
00128 *                                                                 DTSCDRV
00129 *    CONTROL IS PASSED TO DTSCU899 FOLLOWING AN ABEND             DTSCDRV
00130 *    ANYWHERE IN A DTS TASK.                                      DTSCDRV
00131 *                                                                 DTSCDRV
00132 *    DTSCU899 CLEANS UP TEMPORARY STORAGE AND ABENDS              DTSCDRV
00133 *    THE TASK.                                                    DTSCDRV
00134 *                                                                 DTSCDRV
00135 *****                                                             DTSCDRV
00136                                                                   DTSCDRV
00137      EXEC CICS                                                    DTSCDRV
00138          HANDLE ABEND                                             DTSCDRV
00139              PROGRAM ('DTSCU899')                                 DTSCDRV
00140              RESP (WRK-RESP-CD)                                   DTSCDRV
00141      END-EXEC.                                                    DTSCDRV
00142                                                                   DTSCDRV
00143      IF WRK-RESP-CD NOT = DFHRESP (NORMAL)                        DTSCDRV
00144          PERFORM S899-ABEND THRU S899-EXIT.                       DTSCDRV
00145      SKIP3                                                        DTSCDRV
00146 *****                                                             DTSCDRV
00147 *                                                                 DTSCDRV
00148 *         IF EIBCALEN = WRK-LCCM-LENGTH                           DTSCDRV
00149 *                                                                 DTSCDRV
00150 *             THIS TASK IS THE CONTINUATION OF A 'DTS' PSEUDO     DTSCDRV
00151 *             CONVERSATION; THE INTER-TASK COMMUNICATION AREA     DTSCDRV
00152 *             NECESSARY FOR THE CONTINUATION OF THE 'DTS'         DTSCDRV
00153 *             PSEUDO CONVERSATION IS IN DFHCOMMAREA               DTSCDRV
00154 *                                                                 DTSCDRV
00155 *         ELSE                                                    DTSCDRV
00156 *                                                                 DTSCDRV
00157 *         IF EIBCALEN NOT = +0                                    DTSCDRV
00158 *                                                                 DTSCDRV
00159 *             THERE ARE BIG TIME PROBLEMS AND THE TASK IS ABENDED DTSCDRV
00160 *                                                                 DTSCDRV
00161 *         ELSE                                                    DTSCDRV
00162 *                                                                 DTSCDRV
00163 *             THIS TASK IS THE INITIATION OF A 'DTS' PSEUDO       DTSCDRV
00164 *             CONVERSATION.                                       DTSCDRV
00165 *                                                                 DTSCDRV
00166 *****                                                             DTSCDRV
00167                                                                   DTSCDRV
00168      IF EIBCALEN = WRK-LCCM-LENGTH                                DTSCDRV
00169          PERFORM P2000-CONTINUE-CONVERSATION THRU P2000-EXIT      DTSCDRV
00170      ELSE                                                         DTSCDRV
00171      IF EIBCALEN NOT = +0                                         DTSCDRV
00172          PERFORM S899-ABEND THRU S899-EXIT                        DTSCDRV
00173      ELSE                                                         DTSCDRV
00174          PERFORM P1000-START-CONVERSATION THRU P1000-EXIT.        DTSCDRV
00175      SKIP3                                                        DTSCDRV
00176 *****                                                             DTSCDRV
00177 *                                                                 DTSCDRV
00178 *    AFTER LINK(S) TO THE APPROPRIATE SCREEN PROCESSING           DTSCDRV
00179 *    MODULE(S) THE TASK IS TERMINATED.                            DTSCDRV
00180 *                                                                 DTSCDRV
00181 *    THE PSEUDO CONVERSATION IS CONTINUED OR THE PSEUDO           DTSCDRV
00182 *    CONVERSATION IS ENDED.                                       DTSCDRV
00183 *                                                                 DTSCDRV
00184 *****                                                             DTSCDRV
00185                                                                   DTSCDRV
00186      IF LCCM-END-TASK-88                                          DTSCDRV
00187                                                                   DTSCDRV
00188          EXEC CICS                                                DTSCDRV
00189              RETURN                                               DTSCDRV
00190                  TRANSID (LCCM-CICS-TRAN-ID)                      DTSCDRV
00191                  COMMAREA (LCCM-COMM-AREA)                        DTSCDRV
00192          END-EXEC                                                 DTSCDRV
00193      ELSE                                                         DTSCDRV
00194                                                                   DTSCDRV
00195          EXEC CICS                                                DTSCDRV
00196              RETURN                                               DTSCDRV
00197          END-EXEC.                                                DTSCDRV
00198      SKIP2                                                        DTSCDRV
00199      GOBACK.                                                      DTSCDRV
00200      EJECT                                                        DTSCDRV
00201  P1000-START-CONVERSATION.                                        DTSCDRV
00202      PERFORM S898-DELETE-ALL-TS THRU S898-EXIT.                   DTSCDRV
00203                                                                   DTSCDRV
00204      MOVE LOW-VALUES TO LCCM-COMM-AREA.                           DTSCDRV
00205                                                                   DTSCDRV
00206 *****MOVE WRK-LCCM-LENGTH TO LCCM-LENGTH.                         DTSCDRV
00207                                                                   DTSCDRV
00208      MOVE +0 TO LCCM-MHDR-AREA-ESTB-ABSTIME.                      DTSCDRV
00209                                                                   DTSCDRV
00210      MOVE +0 TO LCCM-BATCH-NO                                     DTSCDRV
00211                 LCCM-ITEM-NO.                                     DTSCDRV
00212                                                                   DTSCDRV
00213      PERFORM P3000-INIT-TASK-AREA THRU P3000-EXIT.                DTSCDRV
00214                                                                   DTSCDRV
00215      PERFORM S801-SECURITY-CHECK THRU S801-EXIT.                  DTSCDRV
00216                                                                   DTSCDRV
00217      EXEC CICS                                                    DTSCDRV
00218          ASSIGN                                                   DTSCDRV
00219              APPLID (LCCM-CICS-REGION-NAME)                       DTSCDRV
00220      END-EXEC.                                                    DTSCDRV
00221                                                                   DTSCDRV
00222 *****                                                             DTSCDRV
00223 *                                                                 DTSCDRV
00224 *    FOLLOWING SENTENCE DETERMINES THE "REGION NAME" DISPLAYED    DTSCDRV
00225 *    ON THE FIRST LINE OF EACH DTS TRANSACTION SCREEN.  CODE      DTSCDRV
00226 *    IS COMMENTED OUT UNTIL WE LEARN THE DHS REGION NAMES.        DTSCDRV
00227 *                                                                 DTSCDRV
00228 *****                                                             DTSCDRV
00229                                                                   DTSCDRV
00230 *****IF EIBTRNID = 'DTSC'                                         DTSCDRV
00231 *********IF LCCM-CICS-REGION-NAME = 'CICSAORT' OR 'CICSAORX'      DTSCDRV
00232 *************MOVE 'TESTCOMB' TO LCCM-CICS-REGION-NAME             DTSCDRV
00233 *********ELSE                                                     DTSCDRV
00234 *************MOVE 'COMBINED' TO LCCM-CICS-REGION-NAME             DTSCDRV
00235 *****ELSE                                                         DTSCDRV
00236 *********IF LCCM-CICS-REGION-NAME = 'CICSAORT' OR 'CICSAORX'      DTSCDRV
00237 *************MOVE 'TEST' TO LCCM-CICS-REGION-NAME                 DTSCDRV
00238 *********ELSE                                                     DTSCDRV
00239 *************MOVE SPACES TO LCCM-CICS-REGION-NAME.                DTSCDRV
00240                                                                   DTSCDRV
00241      MOVE EIBTRNID TO LCCM-CICS-TRAN-ID.                          DTSCDRV
00242                                                                   DTSCDRV
00243      MOVE EIBTRMID TO LCCM-CICS-TERM-ID.                          DTSCDRV
00244                                                                   DTSCDRV
00245      MOVE 'DTS' TO LCCM-TS-NAME-PREFIX (1:3).                     DTSCDRV
00246                                                                   DTSCDRV
00247      MOVE LCCM-CICS-TERM-ID TO LCCM-TS-NAME-PREFIX (4:4).         DTSCDRV
00248                                                                   DTSCDRV
00249      MOVE '78' TO LCCM-CORR-SCR-ID.                               DTSCDRV
00250                                                                   DTSCDRV
00251      MOVE +19924 TO LCCM-PICKUP-YRQ.                              DTSCDRV
00252                                                                   DTSCDRV
00253      MOVE +010010            TO LCCM-NON-DOES-EMP-NO.             DTSCDRV
00254                                                                   DTSCDRV
00255      MOVE LCCM-CURR-RUN-DATE TO LCCM-COMP-DATE.                   DTSCDRV
00256                                                                   DTSCDRV
00257      MOVE LCCM-OP-PRINTER-ID TO LCCM-PRINTER-ID.                  DTSCDRV
00258                                                                   DTSCDRV
00259      MOVE LCCM-OP-ALARM-IND TO LCCM-ALARM-IND.                    DTSCDRV
00260                                                                   DTSCDRV
00261      MOVE '1' TO LCCM-ENTRY-MODE.                                 DTSCDRV
00262                                                                   DTSCDRV
00263      MOVE LCCM-OP-ARPT-EDIT-MODE TO LCCM-ARPT-EDIT-MODE.          DTSCDRV
00264                                                                   DTSCDRV
00265 *****MOVE +50 TO LCCM-DEFAULT-TRAN-MAX.                           DTSCDRV
00266                                                                   DTSCDRV
00267 *****MOVE LCCM-DEFAULT-TRAN-MAX TO LCCM-TRAN-MAX.                 DTSCDRV
00268                                                                   DTSCDRV
00269      MOVE 0 TO LCCM-EMP-NO                                        DTSCDRV
00270                LCCM-ASSIGN-NO                                     DTSCDRV
00271                LCCM-YRQ.                                          DTSCDRV
00272                                                                   DTSCDRV
00273      MOVE LCCM-OP-ID TO LCCM-RESP-OP-ID                           DTSCDRV
00274                         LCCM-CORR-QUEUE-OP-ID.                    DTSCDRV
00275                                                                   DTSCDRV
00276      SET LCCM-COMBINE-NO-88 TO TRUE.                              DTSCDRV
00277                                                                   DTSCDRV
00278      MOVE '00' TO LCCM-REQ-SCR-ID.                                DTSCDRV
00279                                                                   DTSCDRV
00280      MOVE 'SF' TO LCCM-PRIOR-SCR-ID.                              DTSCDRV
00281                                                                   DTSCDRV
00282      SET LCCM-ENTER-88 TO TRUE.                                   DTSCDRV
00283                                                                   DTSCDRV
00284      MOVE +0 TO LCCM-CURSOR-ROW                                   DTSCDRV
00285                 LCCM-CURSOR-COL.                                  DTSCDRV
00286                                                                   DTSCDRV
00287      MOVE SPACES TO LCCM-SCR-ID                                   DTSCDRV
00288                     LCCM-SCR-STATUS.                              DTSCDRV
00289                                                                   DTSCDRV
00290      MOVE +0 TO LCCM-SCR-ABSTIME.                                 DTSCDRV
00291                                                                   DTSCDRV
00292      IF LCCM-ERROR-MSG                                            DTSCDRV
00293          MOVE 'SF' TO LCCM-REQ-SCR-ID.                            DTSCDRV
00294                                                                   DTSCDRV
00295      SET LCCM-LINK-SCREEN-88 TO TRUE.                             DTSCDRV
00296                                                                   DTSCDRV
00297      PERFORM P4000-SCREEN-DRIVER-LOOP THRU P4000-EXIT             DTSCDRV
00298          UNTIL NOT LCCM-LINK-SCREEN-88.                           DTSCDRV
00299  P1000-EXIT.                                                      DTSCDRV
00300      EXIT.                                                        DTSCDRV
00301      EJECT                                                        DTSCDRV
00302  P2000-CONTINUE-CONVERSATION.                                     DTSCDRV
00303      MOVE DFHCOMMAREA TO LCCM-COMM-AREA.                          DTSCDRV
00304                                                                   DTSCDRV
00305                                                                   DTSCDRV
00306      MOVE SPACE TO LCCM-REQ-SCR-ID.                               DTSCDRV
00307                                                                   DTSCDRV
00308      PERFORM P3000-INIT-TASK-AREA THRU P3000-EXIT.                DTSCDRV
00309                                                                   DTSCDRV
00310      IF LCCM-REQ-SCR-ID = SPACES                                  DTSCDRV
00311          MOVE LCCM-SCR-ID TO LCCM-REQ-SCR-ID.                     DTSCDRV
00312                                                                   DTSCDRV
00313      SET LCCM-LINK-SCREEN-88 TO TRUE.                             DTSCDRV
00314                                                                   DTSCDRV
00315      PERFORM P4000-SCREEN-DRIVER-LOOP THRU P4000-EXIT             DTSCDRV
00316          UNTIL NOT LCCM-LINK-SCREEN-88.                           DTSCDRV
00317  P2000-EXIT.                                                      DTSCDRV
00318      EXIT.                                                        DTSCDRV
00319      EJECT                                                        DTSCDRV
00320  P3000-INIT-TASK-AREA.                                            DTSCDRV
00321      MOVE '1' TO L005-OPTION.                                     DTSCDRV
00322                                                                   DTSCDRV
00323      PERFORM S005-ABSTIME THRU S005-EXIT.                         DTSCDRV
00324                                                                   DTSCDRV
00325                                                                   DTSCDRV
00326      MOVE L005-DATE TO LCCM-TASK-START-DATE.                      DTSCDRV
00327                                                                   DTSCDRV
00328      MOVE L005-SLASH-DATE TO LCCM-TASK-START-DISP-DATE.           DTSCDRV
00329                                                                   DTSCDRV
00330      MOVE L005-TIME TO LCCM-TASK-START-TIME.                      DTSCDRV
00331                                                                   DTSCDRV
00332      MOVE L005-DISPLAY-TIME TO LCCM-TASK-START-DISP-TIME.         DTSCDRV
00333                                                                   DTSCDRV
00334      MOVE L005-ABSTIME TO LCCM-TASK-START-ABSTIME.                DTSCDRV
00335                                                                   DTSCDRV
00336      MOVE EIBTASKN TO LCCM-TASK-ID.                               DTSCDRV
00337                                                                   DTSCDRV
00338                                                                   DTSCDRV
00339      EXEC CICS                                                    DTSCDRV
00340          ASSIGN                                                   DTSCDRV
00341              NETNAME (LCCM-TASK-NETNAME)                          DTSCDRV
00342              RESP (WRK-RESP-CD)                                   DTSCDRV
00343      END-EXEC.                                                    DTSCDRV
00344                                                                   DTSCDRV
00345      IF WRK-RESP-CD NOT = DFHRESP (NORMAL)                        DTSCDRV
00346          MOVE 'UNKOWN' TO LCCM-TASK-NETNAME.                      DTSCDRV
00347                                                                   DTSCDRV
00348                                                                   DTSCDRV
00349      MOVE SPACES TO LCCM-MSG-AREA.                                DTSCDRV
00350                                                                   DTSCDRV
00351      COMPUTE WRK-ELAPSE-ABSTIME                                   DTSCDRV
00352        = LCCM-TASK-START-ABSTIME - LCCM-MHDR-AREA-ESTB-ABSTIME.   DTSCDRV
00353                                                                   DTSCDRV
00354      IF WRK-ELAPSE-ABSTIME < 1800000                              DTSCDRV
00355          GO TO P3000-EXIT.                                        DTSCDRV
00356                                                                   DTSCDRV
00357      MOVE LCCM-TASK-START-ABSTIME TO LCCM-MHDR-AREA-ESTB-ABSTIME. DTSCDRV
00358                                                                   DTSCDRV
00359      MOVE LCCM-TASK-START-DATE TO LCCM-CURR-RUN-DATE              DTSCDRV
00360                                   LCCM-CURR-MAIL-DATE             DTSCDRV
00361                                   LCCM-PRIOR-RUN-DATE             DTSCDRV
00362                                   LCCM-NEXT-RUN-DATE.             DTSCDRV
00363                                                                   DTSCDRV
00364      MOVE +0 TO LCCM-LAST-UC30-MASS-MAIL-YRQ                      DTSCDRV
00365                 LCCM-LAST-PEN-ASSESSED-YRQ                        DTSCDRV
00366                 LCCM-LAST-UC30-DEL-MAIL-YRQ                       DTSCDRV
00367                 LCCM-FIRST-PURSUED-RPT-YRQ                        DTSCDRV
00368                 LCCM-LAST-RATE-END-YRQ.                           DTSCDRV
00369                                                                   DTSCDRV
00370                                                                   DTSCDRV
00371                                                                   DTSCDRV
00372      SET L810-READ-88 TO TRUE.                                    DTSCDRV
00373                                                                   DTSCDRV
00374      MOVE LOW-VALUES TO MHDR-KEY-AREA.                            DTSCDRV
00375                                                                   DTSCDRV
00376      MOVE +0 TO MHDR-EMP-NO.                                      DTSCDRV
00377                                                                   DTSCDRV
00378      SET MHDR-HDR-88 TO TRUE.                                     DTSCDRV
00379                                                                   DTSCDRV
00380      PERFORM S810-MASTER-IO THRU S810-EXIT.                       DTSCDRV
00381                                                                   DTSCDRV
00382      IF L810-FILE-CLOSED-88                                       DTSCDRV
00383          MOVE L810-MSG-AREA TO LCCM-MSG-AREA                      DTSCDRV
00384      ELSE                                                         DTSCDRV
00385      IF L810-NO-REC-88                                            DTSCDRV
00386          NEXT SENTENCE                                            DTSCDRV
00387      ELSE                                                         DTSCDRV
00388          MOVE MHDR-CURR-RUN-DATE TO LCCM-CURR-RUN-DATE            DTSCDRV
00389          MOVE MHDR-CURR-MAIL-DATE TO LCCM-CURR-MAIL-DATE          DTSCDRV
00390          MOVE MHDR-PRIOR-RUN-DATE TO LCCM-PRIOR-RUN-DATE          DTSCDRV
00391          MOVE MHDR-NEXT-RUN-DATE TO LCCM-NEXT-RUN-DATE            DTSCDRV
00392          MOVE MHDR-LAST-UC30-MASS-MAIL-YRQ                        DTSCDRV
00393            TO LCCM-LAST-UC30-MASS-MAIL-YRQ                        DTSCDRV
00394          MOVE MHDR-LAST-PEN-ASSESSED-YRQ                          DTSCDRV
00395            TO LCCM-LAST-PEN-ASSESSED-YRQ                          DTSCDRV
00396          MOVE MHDR-LAST-UC30-DEL-MAIL-YRQ                         DTSCDRV
00397            TO LCCM-LAST-UC30-DEL-MAIL-YRQ                         DTSCDRV
00398          MOVE MHDR-FIRST-PURSUED-RPT-YRQ                          DTSCDRV
00399            TO LCCM-FIRST-PURSUED-RPT-YRQ                          DTSCDRV
00400          MOVE MHDR-LAST-RATE-END-YRQ                              DTSCDRV
00401            TO LCCM-LAST-RATE-END-YRQ.                             DTSCDRV
00402  P3000-EXIT.                                                      DTSCDRV
00403      EXIT.                                                        DTSCDRV
00404      EJECT                                                        DTSCDRV
00405  P4000-SCREEN-DRIVER-LOOP.                                        DTSCDRV
00406 ******************************************************************DTSCDRV
00407 *    INCLUDES LOGIC TO CLEAR LCCM-YRQ WHENEVER THE EMP NO CHANGES DTSCDRV
00408 *    ON A SCREEN WHICH DOESN'T UPDATE LCCM-YRQ.                   DTSCDRV
00409 ******************************************************************DTSCDRV
00410      MOVE LCCM-EMP-NO     TO WRK-PRE-LINK-EMP-NO.                 DTSCDRV
00411                                                                   DTSCDRV
00412      MOVE LCCM-REQ-SCR-ID TO WRK-MOD-SCR-ID.                      DTSCDRV
00413                                                                   DTSCDRV
00414      EXEC CICS                                                    DTSCDRV
00415          LINK                                                     DTSCDRV
00416              PROGRAM (WRK-MOD-NAME)                               DTSCDRV
00417              COMMAREA (LCCM-COMM-AREA)                            DTSCDRV
00418              RESP (WRK-RESP-CD)                                   DTSCDRV
00419      END-EXEC.                                                    DTSCDRV
00420                                                                   DTSCDRV
00421      IF WRK-MOD-SCR-YRQ-88                                        DTSCDRV
00422          NEXT SENTENCE                                            DTSCDRV
00423      ELSE                                                         DTSCDRV
00424          IF LCCM-EMP-NO  NOT =  WRK-PRE-LINK-EMP-NO               DTSCDRV
00425              MOVE +0 TO LCCM-YRQ.                                 DTSCDRV
00426                                                                   DTSCDRV
00427      IF WRK-RESP-CD NOT = DFHRESP (NORMAL)                        DTSCDRV
00428          PERFORM S899-ABEND THRU S899-EXIT.                       DTSCDRV
00429                                                                   DTSCDRV
00430      IF NOT LCCM-LINK-SCREEN-88                                   DTSCDRV
00431          GO TO P4000-EXIT.                                        DTSCDRV
00432                                                                   DTSCDRV
00433      IF LCCM-SCR-ID = LCCM-REQ-SCR-ID                             DTSCDRV
00434          PERFORM S899-ABEND THRU S899-EXIT.                       DTSCDRV
00435                                                                   DTSCDRV
00436      IF LCCM-SCR-MENU-88                                          DTSCDRV
00437          IF LCCM-PRIOR-SCR-MENU-88 OR LCCM-PRIOR-SCR-SF-88        DTSCDRV
00438              MOVE LCCM-SCR-ID TO LCCM-PRIOR-SCR-ID                DTSCDRV
00439          ELSE                                                     DTSCDRV
00440          IF LCCM-PRIOR-SCR-ID = LCCM-REQ-SCR-ID                   DTSCDRV
00441              MOVE LCCM-SCR-ID TO LCCM-PRIOR-SCR-ID                DTSCDRV
00442          ELSE                                                     DTSCDRV
00443              NEXT SENTENCE                                        DTSCDRV
00444      ELSE                                                         DTSCDRV
00445      IF LCCM-REQ-SCR-EDIT-88 OR LCCM-SCR-EDIT-88                  DTSCDRV
00446          NEXT SENTENCE                                            DTSCDRV
00447      ELSE                                                         DTSCDRV
00448          MOVE LCCM-SCR-ID TO LCCM-PRIOR-SCR-ID.                   DTSCDRV
00449  P4000-EXIT.                                                      DTSCDRV
00450      EXIT.                                                        DTSCDRV
00451      EJECT                                                        DTSCDRV
00452  S005-ABSTIME.                                                    DTSCDRV
00453                                                                   DTSCDRV
00454 *****EXEC CICS                                                    DTSCDRV
00455 *****    LINK                                                     DTSCDRV
00456 *****        PROGRAM ('DTSCU005')                                 DTSCDRV
00457 *****        COMMAREA (L005-COMM-AREA)                            DTSCDRV
00458 *****END-EXEC.                                                    DTSCDRV
00459      SKIP3                                                        DTSCDRV
00460      EXEC CICS                                                    DTSCDRV
00461          ASKTIME                                                  DTSCDRV
00462              ABSTIME (L005-ABSTIME)                               DTSCDRV
00463      END-EXEC.                                                    DTSCDRV
00464                                                                   DTSCDRV
00465      EXEC CICS                                                    DTSCDRV
00466          FORMATTIME                                               DTSCDRV
00467              ABSTIME (L005-ABSTIME)                               DTSCDRV
00468              DAYOFMONTH (WRK-DAYOFMONTH)                          DTSCDRV
00469              MONTHOFYEAR (WRK-MONTHOFYEAR)                        DTSCDRV
00470              YEAR (WRK-YEAR)                                      DTSCDRV
00471              MMDDYY (L005-SLASH-DATE)                             DTSCDRV
00472              DATESEP ('/')                                        DTSCDRV
00473              TIME (L005-DISPLAY-TIME)                             DTSCDRV
00474              TIMESEP (':')                                        DTSCDRV
00475      END-EXEC.                                                    DTSCDRV
00476                                                                   DTSCDRV
00477                                                                   DTSCDRV
00478      MOVE WRK-YEAR TO WRK-DATE-YEAR.                              DTSCDRV
00479                                                                   DTSCDRV
00480      MOVE WRK-MONTHOFYEAR TO WRK-DATE-MONTH.                      DTSCDRV
00481                                                                   DTSCDRV
00482      MOVE WRK-DAYOFMONTH TO WRK-DATE-DAY.                         DTSCDRV
00483                                                                   DTSCDRV
00484      MOVE WRK-DATE TO L005-DATE.                                  DTSCDRV
00485                                                                   DTSCDRV
00486      MOVE EIBTIME TO L005-TIME.                                   DTSCDRV
00487  S005-EXIT.                                                       DTSCDRV
00488      EXIT.                                                        DTSCDRV
00489      SKIP3                                                        DTSCDRV
00490  S801-SECURITY-CHECK.                                             DTSCDRV
00491                                                                   DTSCDRV
00492      EXEC CICS                                                    DTSCDRV
00493          LINK                                                     DTSCDRV
00494              PROGRAM ('DTSCU801')                                 DTSCDRV
00495              COMMAREA (LCCM-COMM-AREA)                            DTSCDRV
00496      END-EXEC.                                                    DTSCDRV
00497                                                                   DTSCDRV
00498  S801-EXIT.                                                       DTSCDRV
00499      EXIT.                                                        DTSCDRV
00500      SKIP3                                                        DTSCDRV
00501  S810-MASTER-IO.                                                  DTSCDRV
00502                                                                   DTSCDRV
00503      EXEC CICS                                                    DTSCDRV
00504          LINK                                                     DTSCDRV
00505              PROGRAM ('DTSCU810')                                 DTSCDRV
00506              COMMAREA (L810-COMM-AREA)                            DTSCDRV
00507      END-EXEC.                                                    DTSCDRV
00508                                                                   DTSCDRV
00509  S810-EXIT.                                                       DTSCDRV
00510      EXIT.                                                        DTSCDRV
00511      SKIP3                                                        DTSCDRV
00512  S898-DELETE-ALL-TS.                                              DTSCDRV
00513                                                                   DTSCDRV
00514      EXEC CICS                                                    DTSCDRV
00515          LINK                                                     DTSCDRV
00516              PROGRAM ('DTSCU898')                                 DTSCDRV
00517      END-EXEC.                                                    DTSCDRV
00518                                                                   DTSCDRV
00519  S898-EXIT.                                                       DTSCDRV
00520      EXIT.                                                        DTSCDRV
00521      SKIP3                                                        DTSCDRV
00522  S899-ABEND.                                                      DTSCDRV
00523                                                                   DTSCDRV
00524      EXEC CICS                                                    DTSCDRV
00525          ABEND                                                    DTSCDRV
00526              ABCODE (WRK-ABEND-CD)                                DTSCDRV
00527      END-EXEC.                                                    DTSCDRV
00528                                                                   DTSCDRV
00529  S899-EXIT.                                                       DTSCDRV
00530      EXIT.                                                        DTSCDRV
