00001  IDENTIFICATION DIVISION.                                         01/23/03
00002  PROGRAM-ID.             DTSCS70.                                 DTSCS70
00003  AUTHOR.                 TRICOASTAL CONSULTING LTD.                  LV006
00004  DATE-WRITTEN.           NOVEMBER 1991.                           DTSCS70
00005  DATE-COMPILED.                                                   DTSCS70
00006      SKIP3                                                        DTSCS70
00007 *****                                                             DTSCS70
00008 *                                                                 DTSCS70
00009 *    FUNCTION:  MISCELLANEOUS MENU SCREEN PROCESSOR.              DTSCS70
00010 *                                                                 DTSCS70
00011 *                                                                 DTSCS70
00012 *    MODIFICATION LOG:                                            DTSCS70
00013 *                                                                 DTSCS70
00014 *    11/06/91  INITIAL DEVELOPMENT.                               DTSCS70
00015 *              WORK ORDER:                      PROGRAMMER: TCL   DTSCS70
00016 *                                                                 DTSCS70
00017 *    04/11/94  MODIFIED FOR MONTANA.                              DTSCS70
00018 *              WORK ORDER:                      PROGRAMMER: RHC   DTSCS70
00019 *                                                                 DTSCS70
00020 *    05/12/96  ADDED SCREEN 7A, ELECTRONIC FILER INQUIRY/UPDATE,  DTSCS70
00021 *              TO P1000-ANALYZE-REQUEST.                          DTSCS70
00022 *              REFERENCE RFP: WARP II           PROGRAMMER: MJA   DTSCS70
00023 *                                                                 DTSCS70
00024 *    08/13/1998  REVIEWED AND MODIFIED FOR DC.                    DTSCS70
00025 *                REFERENCE: DC DEVELOPMENT      PROGRAMMER: EHH   DTSCS70
00026 *                                                                 DTSCS70
00027 *    11/20/2001  ADDED CODE TO ACCEPT 7C AS A VALID SCREEN.       DTSCS70
00028 *                REFERENCE: DC DEVELOPMENT      PROGRAMMER: ZL1   DTSCS70
00029 *                                                                 DTSCS70
00030 *    01/02/2003  ADDED CODE TO ACCEPT 7D AS A VALID SCREEN.       DTSCS70
00031 *                REFERENCE: DC DEVELOPMENT      PROGRAMMER: SM1   DTSCS70
00032 *                                                                 DTSCS70
00033 *    MM/DD/YYYY  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   DTSCS70
00034 *                XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   DTSCS70
00035 *                REFERENCE: XXXXXXXXXXXXXXX     PROGRAMMER: XXX   DTSCS70
00036 *                                                                 DTSCS70
00037 *                                                                 DTSCS70
00038 *    DESCRIPTION:                                                 DTSCS70
00039 *                                                                 DTSCS70
00040 *    IF SCREEN '70' NOT CURRENTLY DISPLAYED                       DTSCS70
00041 *        SEND SCREEN 70 (WITH PMSG-KEY-OPTION MESSAGE)            DTSCS70
00042 *        RETURN TO DRIVER.                                        DTSCS70
00043 *                                                                 DTSCS70
00044 *    RECEIVE SCREEN '70'.                                         DTSCS70
00045 *                                                                 DTSCS70
00046 *    IF CLEAR KEY PRESSED                                         DTSCS70
00047 *        SEND SCREEN 70 (WITH PMSG-KEY-OPTION MESSAGE)            DTSCS70
00048 *        SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00049 *        RETURN TO DRIVER.                                        DTSCS70
00050 *                                                                 DTSCS70
00051 *    IF PA2 KEY PRESSED                                           DTSCS70
00052 *        SEND SCREEN 70 (DATA ONLY)                               DTSCS70
00053 *        SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00054 *        RETURN TO DRIVER.                                        DTSCS70
00055 *                                                                 DTSCS70
00056 *    IF F3 KEY PRESSED                                            DTSCS70
00057 *        MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                   DTSCS70
00058 *        SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS70
00059 *        RETURN TO DRIVER.                                        DTSCS70
00060 *                                                                 DTSCS70
00061 *    IF F4 KEY PRESSED                                            DTSCS70
00062 *        MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID                DTSCS70
00063 *        SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS70
00064 *        RETURN TO DRIVER.                                        DTSCS70
00065 *                                                                 DTSCS70
00066 *    IF NOT ENTER KEY PRESSED                                     DTSCS70
00067 *        BUILD INVALID KEY MESSAGE (VIA LINK TO DTSCU804)         DTSCS70
00068 *        SEND SCREEN 70 (WITH THE INVALID KEY PRESSED MESSAGE)    DTSCS70
00069 *        SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00070 *        RETURN TO DRIVER.                                        DTSCS70
00071 *                                                                 DTSCS70
00072 *                                                                 DTSCS70
00073 *    IF MAP-OPT = SPACES OR LOW-VALUES OR '70'                    DTSCS70
00074 *        SEND SCREEN 00 (WITH THE PMSG-KEY-OPTION MESSAGE)        DTSCS70
00075 *        SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00076 *        RETURN TO DRIVER.                                        DTSCS70
00077 *                                                                 DTSCS70
00078 *    CONVERT MAP-OPT INTO A SCREEN IDENTIFIER, PLACING THE        DTSCS70
00079 *    RESULT IN LCCM-REQ-SCR-ID.                                   DTSCS70
00080 *                                                                 DTSCS70
00081 *    EDIT LCCM-REQ-SCR-ID FOR VALIDITY (VIA A CALL TO DTSIU803).  DTSCS70
00082 *                                                                 DTSCS70
00083 *    IF LCCM-REQ-SCR-ID VALID (LCCM-NO-MSG)                       DTSCS70
00084 *        SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS70
00085 *        RETURN TO DRIVER                                         DTSCS70
00086 *    ELSE                                                         DTSCS70
00087 *        SEND SCREEN 70 (WITH ERROR MESSAGE)                      DTSCS70
00088 *        SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00089 *        RETURN TO DRIVER.                                        DTSCS70
00090 *                                                                 DTSCS70
00091 *                                                                 DTSCS70
00092 *****                                                             DTSCS70
00093      SKIP3                                                        DTSCS70
00094  ENVIRONMENT DIVISION.                                            DTSCS70
00095      SKIP3                                                        DTSCS70
00096  DATA DIVISION.                                                   DTSCS70
00097      SKIP3                                                        DTSCS70
00098  WORKING-STORAGE SECTION.                                         DTSCS70
000985 77  PAN-VALET PICTURE X(24) VALUE '006DTSCS70   01/23/03'.       DTSCS70
00099      SKIP3                                                        DTSCS70
00100  01  WRK-AREA.                                                    DTSCS70
00101      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'S70 '.    DTSCS70
00102      05  WRK-RESP-CD                 PIC S9(08)  COMP.            DTSCS70
00103                                                                   DTSCS70
00104      05  WRK-SCR-ID                  PIC  X(02)  VALUE '70'.      DTSCS70
00105      05  WRK-F03-SCR-ID              PIC  X(02)  VALUE '00'.      DTSCS70
00106                                                                   DTSCS70
00107      05  RESP-IND                    PIC  X(01).                  DTSCS70
00108          88  RESP-CURSOR-TO-OPT-88           VALUE 'C'.           DTSCS70
00109          88  RESP-MSGONLY-88                 VALUE 'M'.           DTSCS70
00110          88  RESP-SCREEN-88                  VALUE 'S'.           DTSCS70
00111          88  RESP-JUMP-88                    VALUE 'J'.           DTSCS70
00112                                                                   DTSCS70
00113      05  CURSOR-IND                  PIC  X(01).                  DTSCS70
00114          88  CURSOR-SET-88                  VALUE 'Y'.            DTSCS70
00115                                                                   DTSCS70
00116      05  WRK-DATE-AREA.                                           DTSCS70
00117          10  WRK-DATE                PIC  X(08).                  DTSCS70
00118          10  FILLER                  PIC  X(01)  VALUE '.'.       DTSCS70
00119      EJECT                                                        DTSCS70
00120  01  L851-COMM-AREA.                                              DTSCS70
00121  ++INCLUDE DTSIL851                                               DTSCS70
00122      SKIP3                                                        DTSCS70
00123      05  MAP-AREA REDEFINES L851-MAP-AREA.                        DTSCS70
00124  ++INCLUDE DTSISSM                                                DTSCS70
00125      EJECT                                                        DTSCS70
00126  01  L805-COMM-AREA.                                              DTSCS70
00127  ++INCLUDE DTSIL805                                               DTSCS70
00128      EJECT                                                        DTSCS70
00129  01  CATB-LITERALS.                                               DTSCS70
00130  ++INCLUDE DTSICATB                                               DTSCS70
00131      SKIP3                                                        DTSCS70
00132  01  EMSG-LITERALS.                                               DTSCS70
00133  ++INCLUDE DTSICECD                                               DTSCS70
00134      SKIP3                                                        DTSCS70
00135  01  PMSG-LITERALS.                                               DTSCS70
00136  ++INCLUDE DTSICPCD                                               DTSCS70
00137      EJECT                                                        DTSCS70
00138  LINKAGE SECTION.                                                 DTSCS70
00139      SKIP3                                                        DTSCS70
00140  01  DFHCOMMAREA.                                                 DTSCS70
00141  ++INCLUDE DTSILCCM                                               DTSCS70
00142      EJECT                                                        DTSCS70
00143  PROCEDURE DIVISION.                                              DTSCS70
00144      SKIP2                                                        DTSCS70
00145      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS70
00146                                                                   DTSCS70
00147      MOVE 'N' TO CURSOR-IND.                                      DTSCS70
00148      SKIP2                                                        DTSCS70
00149      MOVE SPACE TO RESP-IND.                                      DTSCS70
00150      PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT.               DTSCS70
00151      SKIP2                                                        DTSCS70
00152      IF RESP-MSGONLY-88                                           DTSCS70
00153          MOVE LOW-VALUES TO MAP-AREA                              DTSCS70
00154          PERFORM S805-MSG-AREA THRU S805-EXIT                     DTSCS70
00155          PERFORM S2200-SEND-DATAONLY THRU S2200-EXIT              DTSCS70
00156          SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00157      ELSE                                                         DTSCS70
00158      IF RESP-SCREEN-88                                            DTSCS70
00159          PERFORM P2000-CONSTRUCT-S-AREA THRU P2000-EXIT           DTSCS70
00160          PERFORM S2100-SEND THRU S2100-EXIT                       DTSCS70
00161          SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00162      ELSE                                                         DTSCS70
00163      IF RESP-JUMP-88                                              DTSCS70
00164          SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS70
00165      ELSE                                                         DTSCS70
00166      IF RESP-CURSOR-TO-OPT-88                                     DTSCS70
00167          MOVE LOW-VALUES TO MAP-AREA                              DTSCS70
00168          MOVE CATB-CURSOR TO MAP-OPT-L                            DTSCS70
00169          SET CURSOR-SET-88 TO TRUE                                DTSCS70
00170          PERFORM S2200-SEND-DATAONLY THRU S2200-EXIT              DTSCS70
00171          SET LCCM-END-TASK-88 TO TRUE                             DTSCS70
00172      ELSE                                                         DTSCS70
00173          PERFORM S899-ABEND THRU S899-EXIT.                       DTSCS70
00174      SKIP2                                                        DTSCS70
00175      EXEC CICS                                                    DTSCS70
00176          RETURN                                                   DTSCS70
00177      END-EXEC.                                                    DTSCS70
00178      SKIP2                                                        DTSCS70
00179      GOBACK.                                                      DTSCS70
00180      EJECT                                                        DTSCS70
00181  P1000-ANALYZE-REQUEST.                                           DTSCS70
00182      IF LCCM-SCR-ID NOT = WRK-SCR-ID                              DTSCS70
00183          MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA                    DTSCS70
00184          SET RESP-SCREEN-88 TO TRUE                               DTSCS70
00185          GO TO P1000-EXIT.                                        DTSCS70
00186                                                                   DTSCS70
00187      PERFORM S1100-RECEIVE THRU S1100-EXIT.                       DTSCS70
00188                                                                   DTSCS70
00189      IF LCCM-CLEAR-88 OR LCCM-F12-88                              DTSCS70
00190          MOVE LOW-VALUES TO MAP-AREA                              DTSCS70
00191          MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA                    DTSCS70
00192          SET RESP-SCREEN-88 TO TRUE                               DTSCS70
00193          GO TO P1000-EXIT.                                        DTSCS70
00194                                                                   DTSCS70
00195      IF LCCM-PA2-88                                               DTSCS70
00196          SET RESP-CURSOR-TO-OPT-88 TO TRUE                        DTSCS70
00197          GO TO P1000-EXIT.                                        DTSCS70
00198                                                                   DTSCS70
00199      IF LCCM-ENTER-88 OR LCCM-F03-88 OR LCCM-F04-88 OR LCCM-F14-88DTSCS70
00200          NEXT SENTENCE                                            DTSCS70
00201      ELSE                                                         DTSCS70
00202          PERFORM S804-INVALID-KEY THRU S804-EXIT                  DTSCS70
00203          SET RESP-MSGONLY-88 TO TRUE                              DTSCS70
00204          GO TO P1000-EXIT.                                        DTSCS70
00205                                                                   DTSCS70
00206      IF LCCM-F03-88                                               DTSCS70
00207          MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                   DTSCS70
00208          SET RESP-JUMP-88 TO TRUE                                 DTSCS70
00209          GO TO P1000-EXIT.                                        DTSCS70
00210                                                                   DTSCS70
00211      IF LCCM-F04-88                                               DTSCS70
00212          MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID                DTSCS70
00213          SET RESP-JUMP-88 TO TRUE                                 DTSCS70
00214          GO TO P1000-EXIT.                                        DTSCS70
00215                                                                   DTSCS70
00216      IF LCCM-F14-88                                               DTSCS70
00217          MOVE LCCM-CORR-SCR-ID TO LCCM-REQ-SCR-ID                 DTSCS70
00218          PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT              DTSCS70
00219          IF LCCM-MSG                                              DTSCS70
00220              SET RESP-SCREEN-88 TO TRUE                           DTSCS70
00221              GO TO P1000-EXIT                                     DTSCS70
00222          ELSE                                                     DTSCS70
00223              SET RESP-JUMP-88 TO TRUE                             DTSCS70
00224              GO TO P1000-EXIT.                                    DTSCS70
00225                                                                   DTSCS70
00226      IF MAP-OPT = SPACES OR LOW-VALUES OR WRK-SCR-ID              DTSCS70
00227          MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA                    DTSCS70
00228          SET RESP-SCREEN-88 TO TRUE                               DTSCS70
00229          GO TO P1000-EXIT.                                        DTSCS70
00230                                                                   DTSCS70
00231      IF MAP-OPT = '1 ' OR ' 1'                                    DTSCS70
00232          MOVE '71' TO LCCM-REQ-SCR-ID                             DTSCS70
00233      ELSE                                                         DTSCS70
00234      IF MAP-OPT = '2 ' OR ' 2'                                    DTSCS70
00235          MOVE '72' TO LCCM-REQ-SCR-ID                             DTSCS70
00236      ELSE                                                         DTSCS70
00237      IF MAP-OPT = '3 ' OR ' 3'                                    DTSCS70
00238          MOVE '73' TO LCCM-REQ-SCR-ID                             DTSCS70
00239      ELSE                                                         DTSCS70
00240      IF MAP-OPT = '4 ' OR ' 4'                                    DTSCS70
00241          MOVE '74' TO LCCM-REQ-SCR-ID                             DTSCS70
00242      ELSE                                                         DTSCS70
00243      IF MAP-OPT = '5 ' OR ' 5'                                    DTSCS70
00244          MOVE '75' TO LCCM-REQ-SCR-ID                             DTSCS70
00245      ELSE                                                         DTSCS70
00246      IF MAP-OPT = '6 ' OR ' 6'                                    DTSCS70
00247          MOVE '76' TO LCCM-REQ-SCR-ID                             DTSCS70
00248      ELSE                                                         DTSCS70
00249      IF MAP-OPT = '7 ' OR ' 7'                                    DTSCS70
00250          MOVE '77' TO LCCM-REQ-SCR-ID                             DTSCS70
00251      ELSE                                                         DTSCS70
00252      IF MAP-OPT = '8 ' OR ' 8'                                    DTSCS70
00253          MOVE '78' TO LCCM-REQ-SCR-ID                             DTSCS70
00254      ELSE                                                         DTSCS70
00255      IF MAP-OPT = '9 ' OR ' 9'                                    DTSCS70
00256          MOVE '79' TO LCCM-REQ-SCR-ID                             DTSCS70
00257      ELSE                                                         DTSCS70
00258      IF MAP-OPT = 'A ' OR ' A'                                    DTSCS70
00259          MOVE '7A' TO LCCM-REQ-SCR-ID                             DTSCS70
00260      ELSE                                                         DTSCS70
00261      IF MAP-OPT = 'B ' OR ' B'                                    DTSCS70
00262          MOVE '7B' TO LCCM-REQ-SCR-ID                             DTSCS70
00263      ELSE                                                         DTSCS70
00264      IF MAP-OPT = 'C ' OR ' C'                                    DTSCS70
00265          MOVE '7C' TO LCCM-REQ-SCR-ID                             DTSCS70
00266      ELSE                                                         DTSCS70
00267      IF MAP-OPT = 'D ' OR ' D'                                    DTSCS70
00268          MOVE '7D' TO LCCM-REQ-SCR-ID                             DTSCS70
00269      ELSE                                                         DTSCS70
00270          MOVE MAP-OPT TO LCCM-REQ-SCR-ID.                         DTSCS70
00271                                                                   DTSCS70
00272      PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT.                 DTSCS70
00273      IF LCCM-MSG                                                  DTSCS70
00274          SET RESP-SCREEN-88 TO TRUE                               DTSCS70
00275      ELSE                                                         DTSCS70
00276          SET RESP-JUMP-88 TO TRUE.                                DTSCS70
00277  P1000-EXIT.                                                      DTSCS70
00278      EXIT.                                                        DTSCS70
00279      EJECT                                                        DTSCS70
00280  P2000-CONSTRUCT-S-AREA.                                          DTSCS70
00281      MOVE LCCM-TASK-START-DISP-DATE TO MAP-SYS-DATE.              DTSCS70
00282      MOVE LCCM-TASK-START-DISP-TIME TO MAP-SYS-TIME.              DTSCS70
00283      MOVE LCCM-CICS-REGION-NAME TO MAP-CICS-REGION-NAME.          DTSCS70
00284                                                                   DTSCS70
00285      PERFORM S805-MSG-AREA THRU S805-EXIT.                        DTSCS70
00286  P2000-EXIT.                                                      DTSCS70
00287      EXIT.                                                        DTSCS70
00288      EJECT                                                        DTSCS70
00289  S803-REQ-SCR-ID-EDIT.                                            DTSCS70
00290                                                                   DTSCS70
00291      EXEC CICS                                                    DTSCS70
00292          LINK                                                     DTSCS70
00293              PROGRAM ('DTSCU803')                                 DTSCS70
00294              COMMAREA (DFHCOMMAREA)                               DTSCS70
00295      END-EXEC.                                                    DTSCS70
00296                                                                   DTSCS70
00297  S803-EXIT.                                                       DTSCS70
00298      EXIT.                                                        DTSCS70
00299      SKIP3                                                        DTSCS70
00300  S804-INVALID-KEY.                                                DTSCS70
00301                                                                   DTSCS70
00302      EXEC CICS                                                    DTSCS70
00303          LINK                                                     DTSCS70
00304              PROGRAM ('DTSCU804')                                 DTSCS70
00305              COMMAREA (DFHCOMMAREA)                               DTSCS70
00306      END-EXEC.                                                    DTSCS70
00307                                                                   DTSCS70
00308  S804-EXIT.                                                       DTSCS70
00309      EXIT.                                                        DTSCS70
00310      SKIP3                                                        DTSCS70
00311  S805-MSG-AREA.                                                   DTSCS70
00312      MOVE LCCM-MSG-AREA TO L805-MSG-AREA.                         DTSCS70
00313                                                                   DTSCS70
00314      EXEC CICS                                                    DTSCS70
00315          LINK                                                     DTSCS70
00316              PROGRAM ('DTSCU805')                                 DTSCS70
00317              COMMAREA (L805-COMM-AREA)                            DTSCS70
00318      END-EXEC.                                                    DTSCS70
00319                                                                   DTSCS70
00320      MOVE L805-S-MSG-AREA TO MAP-MSG-AREA.                        DTSCS70
00321  S805-EXIT.                                                       DTSCS70
00322      EXIT.                                                        DTSCS70
00323      SKIP3                                                        DTSCS70
00324  S851-SCREEN-PROCESSING.                                          DTSCS70
00325      EXEC CICS                                                    DTSCS70
00326          LINK                                                     DTSCS70
00327              PROGRAM ('DTSCU851')                                 DTSCS70
00328              COMMAREA (L851-COMM-AREA)                            DTSCS70
00329      END-EXEC.                                                    DTSCS70
00330  S851-EXIT.                                                       DTSCS70
00331      EXIT.                                                        DTSCS70
00332      SKIP3                                                        DTSCS70
00333  S899-ABEND.                                                      DTSCS70
00334                                                                   DTSCS70
00335      EXEC CICS                                                    DTSCS70
00336          ABEND                                                    DTSCS70
00337              ABCODE (WRK-ABEND-CD)                                DTSCS70
00338      END-EXEC.                                                    DTSCS70
00339                                                                   DTSCS70
00340  S899-EXIT.                                                       DTSCS70
00341      EXIT.                                                        DTSCS70
00342      EJECT                                                        DTSCS70
00343  S1100-RECEIVE.                                                   DTSCS70
00344      SET L851-RECEIVE-88 TO TRUE.                                 DTSCS70
00345      MOVE WRK-SCR-ID TO L851-SCR-ID.                              DTSCS70
00346      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS70
00347      MOVE L851-AID TO LCCM-AID.                                   DTSCS70
00348      MOVE L851-CURSOR TO LCCM-CURSOR.                             DTSCS70
00349  S1100-EXIT.                                                      DTSCS70
00350      EXIT.                                                        DTSCS70
00351      SKIP3                                                        DTSCS70
00352  S2100-SEND.                                                      DTSCS70
00353      SET L851-SEND-88 TO TRUE.                                    DTSCS70
00354      PERFORM S2900-PREPARE-SEND THRU S2900-EXIT.                  DTSCS70
00355      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS70
00356  S2100-EXIT.                                                      DTSCS70
00357      EXIT.                                                        DTSCS70
00358      SKIP3                                                        DTSCS70
00359  S2200-SEND-DATAONLY.                                             DTSCS70
00360      SET L851-SEND-DATAONLY-88 TO TRUE.                           DTSCS70
00361      PERFORM S2900-PREPARE-SEND THRU S2900-EXIT.                  DTSCS70
00362      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS70
00363  S2200-EXIT.                                                      DTSCS70
00364      EXIT.                                                        DTSCS70
00365      SKIP3                                                        DTSCS70
00366  S2900-PREPARE-SEND.                                              DTSCS70
00367      MOVE WRK-SCR-ID TO L851-SCR-ID                               DTSCS70
00368                         LCCM-SCR-ID.                              DTSCS70
00369      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND.                    DTSCS70
00370      MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE.                         DTSCS70
00371      IF CURSOR-SET-88                                             DTSCS70
00372          NEXT SENTENCE                                            DTSCS70
00373      ELSE                                                         DTSCS70
00374          MOVE CATB-CURSOR TO MAP-OPT-L.                           DTSCS70
00375  S2900-EXIT.                                                      DTSCS70
00376      EXIT.                                                        DTSCS70
