00001  IDENTIFICATION DIVISION.                                         08/02/02
00002  PROGRAM-ID.             OJRCU002.                                OJRCU002
00003  AUTHOR.                 TRW.                                        LV001
00004  DATE-WRITTEN.           DEC 2001.                                OJRCU002
00005  DATE-COMPILED.                                                   OJRCU002
00006      SKIP3                                                        OJRCU002
00007 *****                                                             OJRCU002
00008 *                                                                 OJRCU002
00009 *    FUNCTION:  EDIT YEAR AND QUARTER PARMS FOR REPORT GENERATION.OJRCU002
00010 *                                                                 OJRCU002
00011 *                                                                 OJRCU002
00012 *    MODIFICATION LOG:                                            OJRCU002
00013 *                                                                 OJRCU002
00014 *    12/16/01  INITIAL DEVELOPMENT.                               OJRCU002
00015 *              WORK ORDER:                      PROGRAMMER: JMO.  OJRCU002
00016 *                                                                 OJRCU002
00017 *    XX/XX/XX  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU002
00018 *              XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU002
00019 *              WORK ORDER:                      PROGRAMMER: XXX   OJRCU002
00020 *                                                                 OJRCU002
00021 *                                                                 OJRCU002
00022 *  DESCRIPTION:                                                   OJRCU002
00023 *                                                                 OJRCU002
00024 *    CLEAR:                                                       OJRCU002
00025 *                                                                 OJRCU002
00026 *      DATA FIELDS DISPLAYED: NONE.                               OJRCU002
00027 *      MESSAGE: NONE                                              OJRCU002
00028 *                                                                 OJRCU002
00029 *                                                                 OJRCU002
00030 *    INQUIRY:                                                     OJRCU002
00031 *                                                                 OJRCU002
00032 *      SET DEFAULT PARM VALUES                                    OJRCU002
00033 *                                                                 OJRCU002
00034 *                                                                 OJRCU002
00035 *    UPDATE:                                                      OJRCU002
00036 *                                                                 OJRCU002
00037 *      EDIT PARMS                                                 OJRCU002
00038 *                                                                 OJRCU002
00039 *                                                                 OJRCU002
00040 *    RECORDS READ:                                                OJRCU002
00041 *                                                                 OJRCU002
00042 *      MASTER:                                                    OJRCU002
00043 *                                                                 OJRCU002
00044 *        NONE.                                                    OJRCU002
00045 *                                                                 OJRCU002
00046 *                                                                 OJRCU002
00047 *      ALTERNATE INDEX:                                           OJRCU002
00048 *                                                                 OJRCU002
00049 *        NONE.                                                    OJRCU002
00050 *                                                                 OJRCU002
00051 *                                                                 OJRCU002
00052 *      REFERENCE:                                                 OJRCU002
00053 *                                                                 OJRCU002
00054 *        NONE.                                                    OJRCU002
00055 *                                                                 OJRCU002
00056 *                                                                 OJRCU002
00057 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU002
00058 *                                                                 OJRCU002
00059 *        NONE.                                                    OJRCU002
00060 *                                                                 OJRCU002
00061 *                                                                 OJRCU002
00062 *    RECORDS UPDATED:                                             OJRCU002
00063 *                                                                 OJRCU002
00064 *      MASTER:                                                    OJRCU002
00065 *                                                                 OJRCU002
00066 *        NONE.                                                    OJRCU002
00067 *                                                                 OJRCU002
00068 *                                                                 OJRCU002
00069 *      REFERENCE:                                                 OJRCU002
00070 *                                                                 OJRCU002
00071 *        NONE                                                     OJRCU002
00072 *                                                                 OJRCU002
00073 *                                                                 OJRCU002
00074 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU002
00075 *                                                                 OJRCU002
00076 *        NONE.                                                    OJRCU002
00077 *                                                                 OJRCU002
00078 *                                                                 OJRCU002
00079 *    ON-LINE EVENT FILE RECORDS WRITTEN:                          OJRCU002
00080 *                                                                 OJRCU002
00081 *      NONE.                                                      OJRCU002
00082 *                                                                 OJRCU002
00083 *                                                                 OJRCU002
00084 *    MODULES (OTHER THAN STANDARD SCREEN PROCESSING               OJRCU002
00085 *    UTILITY MODULES) LINKED TO:                                  OJRCU002
00086 *                                                                 OJRCU002
00087 *      DTSCU013 COUNT FROM SCREEN FORMAT/EDIT.                    OJRCU002
00088 *                                                                 OJRCU002
00089 *                                                                 OJRCU002
00090 *    MAINTENANCE NOTES:                                           OJRCU002
00091 *                                                                 OJRCU002
00092 *                                                                 OJRCU002
00093 *****                                                             OJRCU002
00094      SKIP3                                                        OJRCU002
00095  ENVIRONMENT DIVISION.                                            OJRCU002
00096      EJECT                                                        OJRCU002
00097  DATA DIVISION.                                                   OJRCU002
00098  WORKING-STORAGE SECTION.                                         OJRCU002
000985 77  PAN-VALET PICTURE X(24) VALUE '001OJRCU002  08/02/02'.       OJRCU002
00099                                                                   OJRCU002
00100  01  WRK-AREA.                                                    OJRCU002
00101      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'U002'.    OJRCU002
00102      05  WRK-RESP-CD                 PIC S9(08)  COMP.            OJRCU002
00103                                                                   OJRCU002
00104      05  WRK-MAPSET-NAME             PIC  X(08)  VALUE 'DTSMSET'. OJRCU002
00105      05  WRK-MAP-NAME.                                            OJRCU002
00106          10  WRK-MAP-NAME-PREFIX     PIC  X(04)  VALUE 'OJRM'.    OJRCU002
00107          10  WRK-MAP-NAME-SUFFIX     PIC  X(04)  VALUE '002 '.    OJRCU002
00108                                                                   OJRCU002
00109      05  WRK-F03-SCR-ID              PIC  X(02)  VALUE '80'.      OJRCU002
00110                                                                   OJRCU002
00111      05  WRK-MAX-PARMS               PIC  9(03)  COMP-3           OJRCU002
00112                                                  VALUE 16.        OJRCU002
00113                                                                   OJRCU002
00114      05  WRK-MSG-AREA                PIC  X(64) VALUE SPACES.     OJRCU002
00115                                                                   OJRCU002
00116      05  WRK-ENTER-MSG               PIC  X(64) VALUE             OJRCU002
00117          'PRESS ENTER WHEN DONE'.                                 OJRCU002
00118                                                                   OJRCU002
00119      05  WRK-PARM                    PIC  X(32).                  OJRCU002
00120                                                                   OJRCU002
00121      05  WRK-SUB                     PIC S9(04)  COMP.            OJRCU002
00122                                                                   OJRCU002
00123      05  WRK-CFKD-SUBMIT             PIC  X(09)                   OJRCU002
00124                                      VALUE 'F9=SUBMIT'.           OJRCU002
00125      EJECT                                                        OJRCU002
00126  01  SCREEN-CONTROL.                                              OJRCU002
00127      05  SCR-ACCESS-IND              PIC X(01).                   OJRCU002
00128          88  SCR-ACCESS-INQ                  VALUE '1'.           OJRCU002
00129          88  SCR-ACCESS-UPDATE               VALUE '2'.           OJRCU002
00130      SKIP1                                                        OJRCU002
00131      05  CURSOR-SET-IND              PIC X(01).                   OJRCU002
00132          88  CURSOR-SET-YES                  VALUE 'Y'.           OJRCU002
00133          88  CURSOR-SET-NO                   VALUE 'N'.           OJRCU002
00134          88  CURSOR-SET-GOTO                 VALUE 'G'.           OJRCU002
00135      SKIP1                                                        OJRCU002
00136      05  REQ-IND                     PIC X(01).                   OJRCU002
00137          88  REQ-ERROR                       VALUE 'O'.           OJRCU002
00138          88  REQ-JUMP                        VALUE 'J'.           OJRCU002
00139          88  REQ-INQUIRE                     VALUE 'I'.           OJRCU002
00140          88  REQ-CLEAR                       VALUE 'C'.           OJRCU002
00141          88  REQ-EDIT                        VALUE 'E'.           OJRCU002
00142          88  REQ-UPDATE                      VALUE 'U'.           OJRCU002
00143          88  REQ-CURSOR-TO-GOTO              VALUE 'G'.           OJRCU002
00144      SKIP1                                                        OJRCU002
00145      05  RESP-IND                    PIC X(01).                   OJRCU002
00146          88  RESP-SEND-MSGONLY               VALUE 'O'.           OJRCU002
00147          88  RESP-SEND-MAP                   VALUE 'M'.           OJRCU002
00148          88  RESP-JUMP                       VALUE 'J'.           OJRCU002
00149          88  RESP-CURSOR-TO-GOTO             VALUE 'G'.           OJRCU002
00150      SKIP1                                                        OJRCU002
00151      05  SCR-ATB-AN                  PIC  X(01).                  OJRCU002
00152      05  SCR-ATB-NUM                 PIC  X(01).                  OJRCU002
00153      EJECT                                                        OJRCU002
00154  01  L013-COMM-AREA.                                              OJRCU002
00155  ++INCLUDE DTSIL013                                               OJRCU002
00156      EJECT                                                        OJRCU002
00157 * ERROR MSG MODULE                                                OJRCU002
00158  01  L805-COMM-AREA.                                              OJRCU002
00159  ++INCLUDE DTSIL805                                               OJRCU002
00160      EJECT                                                        OJRCU002
00161 * MAP DEFINITION                                                  OJRCU002
00162  01  L851-COMM-AREA.                                              OJRCU002
00163  ++INCLUDE DTSIL851                                               OJRCU002
00164      SKIP3                                                        OJRCU002
00165      05  MAP-AREA REDEFINES L851-MAP-AREA.                        OJRCU002
00166          10 OJR-WINDOW-AREA.                                      OJRCU002
00167  ++INCLUDE OJRIS002                                               OJRCU002
00168      EJECT                                                        OJRCU002
00169 * ATTRIBUTE LITERALS                                              OJRCU002
00170  01  CATB-LITERALS.                                               OJRCU002
00171  ++INCLUDE DTSICATB                                               OJRCU002
00172      SKIP3                                                        OJRCU002
00173 * FUNCTION KEY DESCRIPTION LITERALS                               OJRCU002
00174  01  CFKD-LITERALS.                                               OJRCU002
00175  ++INCLUDE DTSICFKD                                               OJRCU002
00176      EJECT                                                        OJRCU002
00177 * ERROR CODE MESSAGE LITERALS                                     OJRCU002
00178  01  CECD-LITERALS.                                               OJRCU002
00179  ++INCLUDE DTSICECD                                               OJRCU002
00180      EJECT                                                        OJRCU002
00181  LINKAGE SECTION.                                                 OJRCU002
00182      SKIP3                                                        OJRCU002
00183  01  DFHCOMMAREA.                                                 OJRCU002
00184  ++INCLUDE DTSILCCM                                               OJRCU002
00185      SKIP3                                                        OJRCU002
00186 * PARM EDIT AND DATA CAPTURE AREA                                 OJRCU002
00187  ++INCLUDE OJRILCCM                                               OJRCU002
00188                                                                   OJRCU002
00189  PROCEDURE DIVISION.                                              OJRCU002
00190                                                                   OJRCU002
00191      MOVE LOW-VALUES TO MAP-AREA                                  OJRCU002
00192                                                                   OJRCU002
00193      MOVE SPACE TO REQ-IND                                        OJRCU002
00194                                                                   OJRCU002
00195      PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT                OJRCU002
00196      SKIP1                                                        OJRCU002
00197 *-----------------------------------------------------            OJRCU002
00198 *    P1000-ANALYZE-REQUEST HAS DETERMINED, BASED ON THE           OJRCU002
00199 *    "AID" KEY PRESSED AND THE CONTEXT OF THE CURRENT             OJRCU002
00200 *    REQUEST WITHIN THE PSEUDO CONVERSATION, THE TYPE             OJRCU002
00201 *    OF ACTIVITY THE WORK STATION OPERATOR HAS REQUESTED.         OJRCU002
00202 *                                                                 OJRCU002
00203 *    THE REQUEST, REFLECTED IN REQ-IND WILL NOW BE                OJRCU002
00204 *    PROCESSED.                                                   OJRCU002
00205 *                                                                 OJRCU002
00206 *    THE REQUEST PROCESSING PARAGRAPHS WILL SET RESP-IND,         OJRCU002
00207 *    INDICATING THE TYPE OF RESPONSE TO BE SENT TO THE            OJRCU002
00208 *    WORK STATION OPERATOR.                                       OJRCU002
00209 *-----------------------------------------------------            OJRCU002
00210      SKIP1                                                        OJRCU002
00211      INITIALIZE RESP-IND                                          OJRCU002
00212      SKIP1                                                        OJRCU002
00213      EVALUATE TRUE                                                OJRCU002
00214          WHEN REQ-ERROR                                           OJRCU002
00215              PERFORM P2000-REQUEST-ERROR THRU P2000-EXIT          OJRCU002
00216          WHEN REQ-JUMP                                            OJRCU002
00217              PERFORM P3000-REQUEST-JUMP THRU P3000-EXIT           OJRCU002
00218          WHEN REQ-CLEAR                                           OJRCU002
00219              PERFORM P4000-REQUEST-CLEAR   THRU P4000-EXIT        OJRCU002
00220          WHEN REQ-INQUIRE                                         OJRCU002
00221              PERFORM P6000-DETERMINE-REQ   THRU P6000-EXIT        OJRCU002
00222          WHEN OTHER                                               OJRCU002
00223              GO TO S899-ABEND                                     OJRCU002
00224      END-EVALUATE.                                                OJRCU002
00225      SKIP3                                                        OJRCU002
00226  MAINLINE-EXIT.                                                   OJRCU002
00227                                                                   OJRCU002
00228      EXEC CICS                                                    OJRCU002
00229          RETURN                                                   OJRCU002
00230      END-EXEC.                                                    OJRCU002
00231                                                                   OJRCU002
00232      GOBACK.                                                      OJRCU002
00233      EJECT                                                        OJRCU002
00234                                                                   OJRCU002
00235 /*****************************************************************OJRCU002
00236 * DETERMINE CURRENT SCREEN STATE AND REQUEST COMBINATION         *OJRCU002
00237 ******************************************************************OJRCU002
00238  P1000-ANALYZE-REQUEST.                                           OJRCU002
00239      SKIP1                                                        OJRCU002
00240 *-----------------------------------------------------            OJRCU002
00241 *     IF SCREEN IS NOT CURRENTLY DISPLAYED (JUMP TO HERE)         OJRCU002
00242 *     THEN ANY KEY PRESSED WILL BE IGNORED (WILL BE               OJRCU002
00243 *     REPLACED WITH ENTER)                                        OJRCU002
00244 *-----------------------------------------------------            OJRCU002
00245      IF LCCM-SEND-MAP-88                                          OJRCU002
00246         SET REQ-INQUIRE TO TRUE                                   OJRCU002
00247         GO TO P1000-EXIT                                          OJRCU002
00248      END-IF                                                       OJRCU002
00249      SKIP3                                                        OJRCU002
00250 *-----------------------------------------------------            OJRCU002
00251 *    REQUEST TO CLEAR THE SCREEN                                  OJRCU002
00252 *-----------------------------------------------------            OJRCU002
00253      IF LCCM-F12-88                                               OJRCU002
00254         MOVE LOW-VALUES   TO MAP-AREA                             OJRCU002
00255         SET REQ-CLEAR     TO TRUE                                 OJRCU002
00256         GO TO P1000-EXIT                                          OJRCU002
00257      END-IF                                                       OJRCU002
00258      SKIP3                                                        OJRCU002
00259 *-----------------------------------------------------            OJRCU002
00260 *    ALL OTHER PA KEYS ARE NOT ACTIVE                             OJRCU002
00261 *-----------------------------------------------------            OJRCU002
00262      IF LCCM-PA-88                                                OJRCU002
00263        PERFORM S804-INVALID-KEY THRU S804-EXIT                    OJRCU002
00264        SET REQ-ERROR TO TRUE                                      OJRCU002
00265        GO TO P1000-EXIT                                           OJRCU002
00266      END-IF                                                       OJRCU002
00267      SKIP3                                                        OJRCU002
00268 *-----------------------------------------------------            OJRCU002
00269 *    IF EXIT KEY PRESSED, JUMP TO NEXT HIGHER FUNCTION            OJRCU002
00270 *-----------------------------------------------------            OJRCU002
00271      IF LCCM-F03-88                                               OJRCU002
00272         MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                    OJRCU002
00273         SET REQ-JUMP TO TRUE                                      OJRCU002
00274         GO TO P1000-EXIT                                          OJRCU002
00275      END-IF                                                       OJRCU002
00276      SKIP3                                                        OJRCU002
00277 *-----------------------------------------------------            OJRCU002
00278 *    IF ENTER - PROCESS PARM UPDATES                              OJRCU002
00279 *-----------------------------------------------------            OJRCU002
00280      IF LCCM-ENTER-88                                             OJRCU002
00281          SET REQ-INQUIRE TO TRUE                                  OJRCU002
00282          GO TO P1000-EXIT                                         OJRCU002
00283      END-IF                                                       OJRCU002
00284      SKIP3                                                        OJRCU002
00285 *-----------------------------------------------------            OJRCU002
00286 *     ANY OTHER KEY IS INVALID                                    OJRCU002
00287 *-----------------------------------------------------            OJRCU002
00288      PERFORM S804-INVALID-KEY THRU S804-EXIT                      OJRCU002
00289      SET REQ-ERROR TO TRUE.                                       OJRCU002
00290  P1000-EXIT.                                                      OJRCU002
00291      EXIT.                                                        OJRCU002
00292      SKIP3                                                        OJRCU002
00293 /*****************************************************************OJRCU002
00294 * ANALYZE REQUEST HAS DETERMINED AN ERROR THAT MUST BE REPORTED. *OJRCU002
00295 * VERIFY THAT A MESSAGE HAS BEEN FILLED IN.                      *OJRCU002
00296 ******************************************************************OJRCU002
00297      SKIP1                                                        OJRCU002
00298  P2000-REQUEST-ERROR.                                             OJRCU002
00299      IF LCCM-MSG                                                  OJRCU002
00300         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU002
00301      ELSE                                                         OJRCU002
00302         GO TO S899-ABEND                                          OJRCU002
00303      END-IF.                                                      OJRCU002
00304  P2000-EXIT.                                                      OJRCU002
00305      EXIT.                                                        OJRCU002
00306 /*****************************************************************OJRCU002
00307 * JUMP TO A DIFFERENT SCREEN TYPE WAS REQUESTED                  *OJRCU002
00308 ******************************************************************OJRCU002
00309      SKIP1                                                        OJRCU002
00310  P3000-REQUEST-JUMP.                                              OJRCU002
00311 *-----------------------------------------------------            OJRCU002
00312 *    VERIFY THAT THE REQUESTED SCREEN EXISTS AND IS ACCESSIBLE    OJRCU002
00313 *    BY USER                                                      OJRCU002
00314 *-----------------------------------------------------            OJRCU002
00315      PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT                  OJRCU002
00316      SKIP3                                                        OJRCU002
00317 *-----------------------------------------------------            OJRCU002
00318 *    VERIFICATION RETURN LCCM-MSG IF ERROR DETECTED               OJRCU002
00319 *-----------------------------------------------------            OJRCU002
00320      IF LCCM-MSG                                                  OJRCU002
00321         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU002
00322         SET CURSOR-SET-GOTO TO TRUE                               OJRCU002
00323         GO TO P3000-EXIT                                          OJRCU002
00324      END-IF                                                       OJRCU002
00325      SKIP3                                                        OJRCU002
00326 *-----------------------------------------------------            OJRCU002
00327 *    CLEAN UP INDICATORS AND PAGING STORAGE PRIOR TO LEAVING      OJRCU002
00328 *-----------------------------------------------------            OJRCU002
00329      MOVE LOW-VALUES TO LCCM-SCR-STATUS                           OJRCU002
00330                         LCCM-SCR-HOLD-AREA                        OJRCU002
00331      MOVE +0 TO LCCM-SCR-ABSTIME                                  OJRCU002
00332      SET RESP-JUMP TO TRUE.                                       OJRCU002
00333  P3000-EXIT.                                                      OJRCU002
00334      EXIT.                                                        OJRCU002
00335 /*****************************************************************OJRCU002
00336 * CLEAR KEY WAS PRESSED                                          *OJRCU002
00337 ******************************************************************OJRCU002
00338  P4000-REQUEST-CLEAR.                                             OJRCU002
00339      SET LCCM-SCR-CLEAR  TO TRUE                                  OJRCU002
00340      SET RESP-SEND-MAP   TO TRUE.                                 OJRCU002
00341  P4000-EXIT.                                                      OJRCU002
00342      EXIT.                                                        OJRCU002
00343      SKIP1                                                        OJRCU002
00344                                                                   OJRCU002
00345 /*****************************************************************OJRCU002
00346 * INQUIRY WAS REQUESTED                                          *OJRCU002
00347 ******************************************************************OJRCU002
00348                                                                   OJRCU002
00349  P6000-DETERMINE-REQ.                                             OJRCU002
00350      SET LCCM-END-TASK-88 TO TRUE                                 OJRCU002
00351      IF LCCM-SEND-MAP-88                                          OJRCU002
00352         PERFORM P6100-BUILD-MAP THRU P6100-EXIT                   OJRCU002
00353         PERFORM S9300-SEND-MAP  THRU S9300-EXIT                   OJRCU002
00354      ELSE                                                         OJRCU002
00355         PERFORM S9100-RECEIVE    THRU S9100-EXIT                  OJRCU002
00356         PERFORM P6200-BUILD-LCCM THRU P6200-EXIT                  OJRCU002
00357      END-IF.                                                      OJRCU002
00358  P6000-EXIT.                                                      OJRCU002
00359      EXIT.                                                        OJRCU002
00360                                                                   OJRCU002
00361  P6100-BUILD-MAP.                                                 OJRCU002
00362      INITIALIZE OJR-WINDOW-AREA                                   OJRCU002
00363      MOVE CATB-CURSOR                    TO MAP-DATE-YY-L         OJRCU002
00364      MOVE LCCM-PARM-VALUE(LCCM-PARM-SUB) TO WRK-PARM              OJRCU002
00365      MOVE WRK-PARM(1:2)                  TO MAP-DATE-YY           OJRCU002
00366      MOVE WRK-PARM(3:1)                  TO MAP-DATE-Q.           OJRCU002
00367  P6100-EXIT.                                                      OJRCU002
00368      EXIT.                                                        OJRCU002
00369                                                                   OJRCU002
00370  P6200-BUILD-LCCM.                                                OJRCU002
00371      INITIALIZE WRK-PARM                                          OJRCU002
00372      MOVE MAP-DATE-YY           TO WRK-PARM(1:2)                  OJRCU002
00373      MOVE MAP-DATE-Q            TO WRK-PARM(3:1)                  OJRCU002
00374      MOVE WRK-PARM              TO LCCM-PARM-VALUE(LCCM-PARM-SUB).OJRCU002
00375  P6200-EXIT.                                                      OJRCU002
00376      EXIT.                                                        OJRCU002
00377                                                                   OJRCU002
00378                                                                   OJRCU002
00379 /*****************************************************************OJRCU002
00380 * LINKS TO UTILITY MODULES                                        OJRCU002
00381 ******************************************************************OJRCU002
00382      SKIP1                                                        OJRCU002
00383  S013-SCREEN-COUNT.                                               OJRCU002
00384      EXEC CICS LINK                                               OJRCU002
00385          PROGRAM  ('DTSCU013')                                    OJRCU002
00386          COMMAREA (L013-COMM-AREA)                                OJRCU002
00387      END-EXEC.                                                    OJRCU002
00388  S013-EXIT.                                                       OJRCU002
00389      EXIT.                                                        OJRCU002
00390      EJECT                                                        OJRCU002
00391  S803-REQ-SCR-ID-EDIT.                                            OJRCU002
00392      EXEC CICS LINK                                               OJRCU002
00393          PROGRAM  ('DTSCU803')                                    OJRCU002
00394          COMMAREA (DFHCOMMAREA)                                   OJRCU002
00395      END-EXEC.                                                    OJRCU002
00396  S803-EXIT.                                                       OJRCU002
00397      EXIT.                                                        OJRCU002
00398      SKIP3                                                        OJRCU002
00399  S804-INVALID-KEY.                                                OJRCU002
00400      EXEC CICS LINK                                               OJRCU002
00401          PROGRAM  ('DTSCU804')                                    OJRCU002
00402          COMMAREA (DFHCOMMAREA)                                   OJRCU002
00403      END-EXEC.                                                    OJRCU002
00404  S804-EXIT.                                                       OJRCU002
00405      EXIT.                                                        OJRCU002
00406      SKIP3                                                        OJRCU002
00407  S851-SCREEN-PROCESSING.                                          OJRCU002
00408      IF LCCM-SEND-MAP-88                                          OJRCU002
00409         IF L851-ALARM-IND = 'N'                                   OJRCU002
00410            EXEC CICS                                              OJRCU002
00411                SEND                                               OJRCU002
00412                    MAP    (WRK-MAP-NAME)                          OJRCU002
00413                    MAPSET (WRK-MAPSET-NAME)                       OJRCU002
00414                    FROM   (OJR-WINDOW-AREA)                       OJRCU002
00415                    CURSOR                                         OJRCU002
00416                    FREEKB                                         OJRCU002
00417                    RESP   (WRK-RESP-CD)                           OJRCU002
00418            END-EXEC                                               OJRCU002
00419         ELSE                                                      OJRCU002
00420             EXEC CICS                                             OJRCU002
00421                 SEND                                              OJRCU002
00422                     MAP    (WRK-MAP-NAME)                         OJRCU002
00423                     MAPSET (WRK-MAPSET-NAME)                      OJRCU002
00424                     FROM   (OJR-WINDOW-AREA)                      OJRCU002
00425                     CURSOR                                        OJRCU002
00426                     FREEKB                                        OJRCU002
00427                     ALARM                                         OJRCU002
00428                     RESP   (WRK-RESP-CD)                          OJRCU002
00429             END-EXEC                                              OJRCU002
00430         END-IF                                                    OJRCU002
00431      ELSE                                                         OJRCU002
00432          INITIALIZE OJR-WINDOW-AREA                               OJRCU002
00433          EXEC CICS                                                OJRCU002
00434              RECEIVE                                              OJRCU002
00435                     MAP    (WRK-MAP-NAME)                         OJRCU002
00436                     MAPSET (WRK-MAPSET-NAME)                      OJRCU002
00437                     INTO   (OJR-WINDOW-AREA)                      OJRCU002
00438                     RESP   (WRK-RESP-CD)                          OJRCU002
00439          END-EXEC                                                 OJRCU002
00440 *        MOVE EIBAID TO LCCM-AID                                  OJRCU002
00441      END-IF                                                       OJRCU002
00442                                                                   OJRCU002
00443      IF WRK-RESP-CD NOT = DFHRESP(NORMAL)                         OJRCU002
00444         GO TO S899-ABEND                                          OJRCU002
00445      END-IF.                                                      OJRCU002
00446  S851-EXIT.                                                       OJRCU002
00447      EXIT.                                                        OJRCU002
00448      SKIP3                                                        OJRCU002
00449  S899-ABEND.                                                      OJRCU002
00450      EXEC CICS ABEND                                              OJRCU002
00451          ABCODE(WRK-ABEND-CD)                                     OJRCU002
00452      END-EXEC.                                                    OJRCU002
00453 *S899-EXIT.                                                       OJRCU002
00454 *    EXIT.                                                        OJRCU002
00455  S1101-ERROR.                                                     OJRCU002
00456      MOVE WRK-MSG-AREA  TO LCCM-MSG-AREA.                         OJRCU002
00457  S1101-EXIT.                                                      OJRCU002
00458      EXIT.                                                        OJRCU002
00459                                                                   OJRCU002
00460                                                                   OJRCU002
00461  S5900-SET-ATTRB.                                                 OJRCU002
00462      MOVE CATB-UNPROT-NORM-NUM-MDTON     TO MAP-DATE-YY-A         OJRCU002
00463      MOVE CATB-UNPROT-NORM-NUM-MDTON     TO MAP-DATE-Q-A.         OJRCU002
00464  S5900-EXIT.                                                      OJRCU002
00465      EXIT.                                                        OJRCU002
00466                                                                   OJRCU002
00467 /*****************************************************************OJRCU002
00468 * MAP ROUTINES                                                   *OJRCU002
00469 ******************************************************************OJRCU002
00470  S9100-RECEIVE.                                                   OJRCU002
00471      SET L851-RECEIVE-88 TO TRUE.                                 OJRCU002
00472      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU002
00473  S9100-EXIT.                                                      OJRCU002
00474      EXIT.                                                        OJRCU002
00475                                                                   OJRCU002
00476  S9300-SEND-MAP.                                                  OJRCU002
00477      PERFORM S5900-SET-ATTRB THRU S5900-EXIT                      OJRCU002
00478      IF NOT LCCM-NO-MSG                                           OJRCU002
00479         MOVE 'INVALID QUARTER'       TO MAP-MSG-TEXT              OJRCU002
00480         MOVE CATB-PROT-BRT-MDTON     TO MAP-MSG-TEXT-A            OJRCU002
00481      ELSE                                                         OJRCU002
00482          MOVE CATB-ASKIP-NORM-MDTOFF TO MAP-MSG-TEXT-A            OJRCU002
00483      END-IF                                                       OJRCU002
00484      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT                   OJRCU002
00485      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU002
00486  S9300-EXIT.                                                      OJRCU002
00487      EXIT.                                                        OJRCU002
00488                                                                   OJRCU002
00489                                                                   OJRCU002
00490  S9900-PREPARE-SEND.                                              OJRCU002
00491      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND                     OJRCU002
00492      MOVE LCCM-MSG-TYPE     TO L851-MSG-TYPE.                     OJRCU002
00493  S9900-EXIT.                                                      OJRCU002
00494      EXIT.                                                        OJRCU002
