00001  IDENTIFICATION DIVISION.                                         01/11/05
00002  PROGRAM-ID.             DTSBR103.                                DTSBR103
00003  AUTHOR.                 MT DEPT OF LABOR/UI PROGRAMMING SECTION     LV018
00004  DATE-WRITTEN.           AUGUST 1994.                             DTSBR103
00005  DATE-COMPILED.                                                   DTSBR103
00006      SKIP3                                                        DTSBR103
00007 *****                                                             DTSBR103
00008 *    CALLING SEQUENCE:  DTSBD400 CALLS                            DTSBR103
00009 *                       DTSBD314 WHICH UPDATES DTSIR103           DTSBR103
00010 *                       DTSBR103 READS DTSIR103 RECORDS.          DTSBR103
00011 *                                                                 DTSBR103
00012 *    FUNCTION:  EMPLOYER REGISTRATION CYCLE A - 2ND GENERIC       DTSBR103
00013 *               LETTER.                                           DTSBR103
00014 *                                                                 DTSBR103
00015 *                                                                 DTSBR103
00016 *    MODIFICATION HISTORY:                                        DTSBR103
00017 *                                                                 DTSBR103
00018 * 08-06-94 INITIAL DEVELOPMENT                                    DTSBR103
00019 *          REFERENCE RFP #RAP             AUTHOR OF CHANGE - SFW  DTSBR103
00020 *                                                                 DTSBR103
00021 * 01-31-95 CHANGED PRINT LINES FOR ADDRESS AND "SECOND REQUEST",  DTSBR103
00022 *          AND LINE AND COLUMN FOR THE DATE (L002-LONG-TEXT-AREA) DTSBR103
00023 *          FOR BETTER PLACEMENT ON LETTERHEAD MAILED IN WINDOW    DTSBR103
00024 *          ENVELOPES.                                             DTSBR103
00025 *          REFERENCE RFP #RAP                    PROGRAMMER: MJA  DTSBR103
00026 *                                                                 DTSBR103
00027 * 03-01-95 CHANGED PAGE LIMIT FROM 62 LINES TO 60 LINES.          DTSBR103
00028 *          REFERENCE RFP # RAP                   PROGRAMMER: MJA  DTSBR103
00029 *                                                                 DTSBR103
00030 * 04-02-95 MOVED ALL LINES DOWN TO ACCOMODATE AGENCY BLUE LETTER- DTSBR103
00031 *          HEAD, MOVED LEFT MARGIN TWO CHARACTERS TO THE LEFT,    DTSBR103
00032 *          AND "SECOND REQUEST" LINE TO BOTTOM OF THE LETTER.     DTSBR103
00033 *          REFERENCE RFP # TPR 15                PROGRAMMER: MJA  DTSBR103
00034 *                                                                 DTSBR103
00035 * 09-28-95 NEW WORDING ON LETTER TO ACCOMODATE COMBINED REGISTRA- DTSBR103
00036 *          TION WITH REVENUE AND NEW COMBINED BLUE LETTERHEAD.    DTSBR103
00037 *          CHANGED DATE TO MM/DD/YY AND LEFT JUSTIFIED.           DTSBR103
00038 *          REFERENCE RFP #****                   PROGRAMMER: XXX  DTSBR103
00039 *                                                                 DTSBR103
00040 * 11/26/97 INCREASE THE LENGTH OF WS-OPR-UNIT-NAME.  REQUIRED     DTSBR103
00041 *          TO REFLECT THE JULY 1, 1997 MOVE OF UI TAX FUNCTIONS   DTSBR103
00042 *          FROM DLI TO DOR.                                       DTSBR103
00043 *                                                                 DTSBR103
00044 * 12/13/97 MOVE AND REFORMAT DISPLAY OF R103-MAIL-DATE AS         DTSBR103
00045 *          REQUIRED FOR COMPUTER GENERATED DOR LETTERHEAD.        DTSBR103
00046 *          REFERENCE: TCL 217                    PROGRAMMER: EHH  DTSBR103
00047 *                                                                 DTSBR103
00048 * 10/28/98 MODIFIED PROGRAM TO CONFORM TO DUTAS STANDARDS.        DTSBR103
00049 *          REFERENCE RFP #****                   PROGRAMMER: DVS  DTSBR103
00050 *                                                                 DTSBR103
00051 * 08/14/99 MODIFIED PROGRAM TO CONFORM TO DUTAS XEROX LAZER       DTSBR103
00052 *          PRINT FORMAT.                                          DTSBR103
00053 *          REFERENCE RFP #****                   PROGRAMMER: ZL1  DTSBR103
00054 *                                                                 DTSBR103
00055 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR103
00056 *          XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR103
00057 *          REFERENCE RFP #****                   PROGRAMMER: XXX  DTSBR103
00058 *                                                                 DTSBR103
00059 *                                                                 DTSBR103
00060 *    DESCRIPTION:                                                 DTSBR103
00061 *                                                                 DTSBR103
00062 *        THIS MODULE PRINTS THE SECOND GENERIC LETTER TO THE      DTSBR103
00063 *        EMPLOYER FOR REGISTRATION CYCLE A.                       DTSBR103
00064 *                                                                 DTSBR103
00065 *                                                                 DTSBR103
00066 *    RECORDS READ:                                                DTSBR103
00067 *                                                                 DTSBR103
00068 *        NONE.                                                    DTSBR103
00069 *                                                                 DTSBR103
00070 *                                                                 DTSBR103
00071 *    PRINTED OUTPUTS:                                             DTSBR103
00072 *                                                                 DTSBR103
00073 *        103R1  GENERIC 2ND LETTER                                DTSBR103
00074 *                                                                 DTSBR103
00075 *                                                                 DTSBR103
00076 *    RECORDS WRITTEN:                                             DTSBR103
00077 *                                                                 DTSBR103
00078 *        NONE.                                                    DTSBR103
00079 *                                                                 DTSBR103
00080 *                                                                 DTSBR103
00081 *    MODULES CALLED:                                              DTSBR103
00082 *                                                                 DTSBR103
00083 *        DTSBU001 DATE CONVERSION MODULE                          DTSBR103
00084 *        DTSBU071 NAME EDIT/CONVERSION MODULE                     DTSBR103
00085 *        DTSBU082 OPERATOR ID EDIT/LOOKUP MODULE                  DTSBR103
00086 *                                                                 DTSBR103
00087 *                                                                 DTSBR103
00088 *****                                                             DTSBR103
00089      EJECT                                                        DTSBR103
00090  ENVIRONMENT DIVISION.                                            DTSBR103
00091      SKIP2                                                        DTSBR103
00092  CONFIGURATION SECTION.                                           DTSBR103
00093  SPECIAL-NAMES. C01 IS TOP-OF-PAGE.                               DTSBR103
00094      SKIP1                                                        DTSBR103
00095  INPUT-OUTPUT SECTION.                                            DTSBR103
00096      SKIP1                                                        DTSBR103
00097  FILE-CONTROL.                                                    DTSBR103
00098      SELECT PRT-FILE ASSIGN TO RPT103R1.                          DTSBR103
00099      SKIP3                                                        DTSBR103
00100  DATA DIVISION.                                                   DTSBR103
00101      SKIP3                                                        DTSBR103
00102  FILE SECTION.                                                    DTSBR103
00103      SKIP2                                                        DTSBR103
00104  FD  PRT-FILE                                                     DTSBR103
00105      RECORDING MODE IS F                                          DTSBR103
00106      BLOCK CONTAINS 0 RECORDS                                     DTSBR103
00107      LABEL RECORDS ARE OMITTED.                                   DTSBR103
00108  01  XEROX-REPORT.                                                DTSBR103
00109      05  FILLER                      PIC X(1).                    DTSBR103
00110      05  XEROX-RPT                   PIC X(132).                  DTSBR103
00111      EJECT                                                        DTSBR103
00112                                                                   DTSBR103
00113  WORKING-STORAGE SECTION.                                         DTSBR103
001135 77  PAN-VALET PICTURE X(24) VALUE '018DTSBR103  01/11/05'.       DTSBR103
00114      SKIP3                                                        DTSBR103
00115  01  WRK-AREA.                                                    DTSBR103
00116      05  WRK-ABEND-CD                PIC S9(04)  COMP  VALUE +103.DTSBR103
00117      05  FIRST-TIME-IND              PIC  X(01)  VALUE 'Y'.       DTSBR103
00118      05  WS-OPR-NAME                 PIC  X(32)  VALUE SPACE.     DTSBR103
00119      05  WS-OPR-UNIT-NAME            PIC  X(50)  VALUE SPACE.     DTSBR103
00120      05  WS-OPR-VOICE.                                            DTSBR103
00121          10  WS-OPR-VOICE-AREA       PIC  X(03)  VALUE SPACES.    DTSBR103
00122          10  WS-OPR-VOICE-1          PIC  X(03)  VALUE SPACES.    DTSBR103
00123          10  WS-OPR-VOICE-2          PIC  X(04)  VALUE SPACES.    DTSBR103
00124          10  WS-OPR-VOICE-EXT        PIC  X(04)  VALUE SPACES.    DTSBR103
00125  01  VSCA-LINE                       PIC  X(133) VALUE SPACES.    DTSBR103
00126      EJECT                                                        DTSBR103
00127  01  L001-LINK-AREA.                                              DTSBR103
00128  ++INCLUDE DTSIL001                                               DTSBR103
00129      EJECT                                                        DTSBR103
00130  01  L002-LINK-AREA.                                              DTSBR103
00131  ++INCLUDE DTSIL002                                               DTSBR103
00132      EJECT                                                        DTSBR103
00133  01  L071-LINK-AREA.                                              DTSBR103
00134  ++INCLUDE DTSIL071                                               DTSBR103
00135      EJECT                                                        DTSBR103
00136  01  L082-LINK-AREA.                                              DTSBR103
00137  ++INCLUDE DTSIL082                                               DTSBR103
00138      EJECT                                                        DTSBR103
00139 *REPORT SECTION.                                                  DTSBR103
00140  ++INCLUDE DTSXLRQI                                               DTSBR103
00141      SKIP3                                                        DTSBR103
00142  01  LETTER-HEADING.                                              DTSBR103
00143      05  LTH-LINE-12.                                             DTSBR103
00144          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR103
00145          10  WS-LONG-TEXT-AREA       PIC  X(18).                  DTSBR103
00146      05  LTH-LINE-15.                                             DTSBR103
00147          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR103
00148          10  WS-FMT-LINE-1           PIC  X(40).                  DTSBR103
00149      05  LTH-LINE-16.                                             DTSBR103
00150          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR103
00151          10  WS-FMT-LINE-2           PIC  X(40).                  DTSBR103
00152      05  LTH-LINE-17.                                             DTSBR103
00153          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR103
00154          10  WS-FMT-LINE-3           PIC  X(40).                  DTSBR103
00155      05  LTH-LINE-18.                                             DTSBR103
00156          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR103
00157          10  WS-FMT-LINE-4           PIC  X(40).                  DTSBR103
00158      05  LTH-LINE-19.                                             DTSBR103
00159          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR103
00160          10  WS-FMT-LINE-5           PIC  X(40).                  DTSBR103
00161      05  LTH-LINE-22.                                             DTSBR103
00162          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR103
00163          10  FILLER                  PIC  X(13)                   DTSBR103
00164                 VALUE 'ACCOUNT NO:  '.                            DTSBR103
00165          10  WS-EMP-NO               PIC  999B999.                DTSBR103
00166      SKIP2                                                        DTSBR103
00167  ++INCLUDE DTSIZ103                                               DTSBR103
00168  LINKAGE SECTION.                                                 DTSBR103
00169      SKIP3                                                        DTSBR103
00170  01  LRCM-LINK-AREA.                                              DTSBR103
00171  ++INCLUDE DTSILRCM                                               DTSBR103
00172      EJECT                                                        DTSBR103
00173  01  R103-REC.                                                    DTSBR103
00174  ++INCLUDE DTSIR103                                               DTSBR103
00175      EJECT                                                        DTSBR103
00176      EJECT                                                        DTSBR103
00177  PROCEDURE DIVISION USING LRCM-LINK-AREA                          DTSBR103
00178                           R103-REC.                               DTSBR103
00179      SKIP2                                                        DTSBR103
00180      IF FIRST-TIME-IND = 'Y'                                      DTSBR103
00181          PERFORM I1000-INITIATE THRU I1000-EXIT                   DTSBR103
00182          MOVE 'N' TO FIRST-TIME-IND.                              DTSBR103
00183      SKIP1                                                        DTSBR103
00184      IF LRCM-EOR-88                                               DTSBR103
00185          PERFORM T1000-TERMINATE THRU T1000-EXIT                  DTSBR103
00186      ELSE                                                         DTSBR103
00187          PERFORM P1000-PROCESS THRU P1000-EXIT.                   DTSBR103
00188      SKIP2                                                        DTSBR103
00189      GOBACK.                                                      DTSBR103
00190      EJECT                                                        DTSBR103
00191  I1000-INITIATE.                                                  DTSBR103
00192      SKIP1                                                        DTSBR103
00193      OPEN OUTPUT PRT-FILE.                                        DTSBR103
00194      MOVE SPACES TO XEROX-REPORT.                                 DTSBR103
00195      MOVE 'RPT103R1' TO REPORT-NUMBER.                            DTSBR103
00196                                                                   DTSBR103
00197      WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE1                 DTSBR103
00198          AFTER ADVANCING TOP-OF-PAGE.                             DTSBR103
00199      WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE2.                DTSBR103
00200      WRITE XEROX-REPORT     FROM VSCA-LINE AFTER ADVANCING 15.    DTSBR103
00201      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE1.                DTSBR103
00202      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE2.                DTSBR103
00203      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE3.                DTSBR103
00204      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE4.                DTSBR103
00205      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE5.                DTSBR103
00206                                                                   DTSBR103
00207      SKIP2                                                        DTSBR103
00208  I1000-EXIT.                                                      DTSBR103
00209      EXIT.                                                        DTSBR103
00210      EJECT                                                        DTSBR103
00211  P1000-PROCESS.                                                   DTSBR103
00212      SKIP1                                                        DTSBR103
00213      MOVE R103-OP-ID TO L082-OP-ID.                               DTSBR103
00214      PERFORM S082-OP-ID-INFO THRU S082-EXIT.                      DTSBR103
00215      IF L082-NOT-VALID-OP OR L082-INTERNAL-88                     DTSBR103
00216          MOVE SPACES TO WS-OPR-NAME                               DTSBR103
00217          MOVE LRCM-DEFAULT-NAME TO WS-OPR-UNIT-NAME               DTSBR103
00218          MOVE LRCM-DEFAULT-VOICE TO WS-OPR-VOICE                  DTSBR103
00219      ELSE                                                         DTSBR103
00220          MOVE L082-UNIT-NAME TO WS-OPR-UNIT-NAME                  DTSBR103
00221          MOVE L082-VOICE-1 TO WS-OPR-VOICE                        DTSBR103
00222          MOVE L082-NAME TO L071-NAM                               DTSBR103
00223          MOVE 2 TO L071-NAME-FORMAT                               DTSBR103
00224          PERFORM S071-DESLASH-NAME THRU S071-EXIT                 DTSBR103
00225          MOVE L071-NAM TO WS-OPR-NAME.                            DTSBR103
00226      SKIP1                                                        DTSBR103
00227 *****MOVE R103-MAIL-DATE TO L001-FED-8-DATE-9.                    DTSBR103
00228 *****SET L001-FROM-FED-8 TO TRUE.                                 DTSBR103
00229 *****PERFORM S001-DATE-CONVERT THRU S001-EXIT.                    DTSBR103
00230      SKIP1                                                        DTSBR103
00231      MOVE R103-MAIL-DATE TO L002-DATE.                            DTSBR103
00232      SET L002-MIXED-CASE TO TRUE.                                 DTSBR103
00233      PERFORM S002-DATE-ALPHA THRU S002-EXIT.                      DTSBR103
00234      SKIP1                                                        DTSBR103
00235      PERFORM P2000-PRINT-HEADER THRU P2000-EXIT.                  DTSBR103
00236      PERFORM P3000-PRINT-DETAIL THRU P3000-EXIT.                  DTSBR103
00237      PERFORM P4000-PRINT-FOOTER THRU P4000-EXIT.                  DTSBR103
00238      SKIP2                                                        DTSBR103
00239  P1000-EXIT.                                                      DTSBR103
00240      EXIT.                                                        DTSBR103
00241      EJECT                                                        DTSBR103
00242                                                                   DTSBR103
00243  P2000-PRINT-HEADER.                                              DTSBR103
00244      MOVE L002-LONG-TEXT-AREA TO WS-LONG-TEXT-AREA.               DTSBR103
00245      MOVE R103-FMT-LINE (1) TO WS-FMT-LINE-1.                     DTSBR103
00246      MOVE R103-FMT-LINE (2) TO WS-FMT-LINE-2.                     DTSBR103
00247      MOVE R103-FMT-LINE (3) TO WS-FMT-LINE-3.                     DTSBR103
00248      MOVE R103-FMT-LINE (4) TO WS-FMT-LINE-4.                     DTSBR103
00249      MOVE R103-FMT-LINE (5) TO WS-FMT-LINE-5.                     DTSBR103
00250      MOVE R103-EMP-NO       TO WS-EMP-NO.                         DTSBR103
00251      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING TOP-OF-PAGEDTSBR103
00252      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING 11 LINE.   DTSBR103
00253      WRITE XEROX-REPORT FROM LTH-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR103
00254      WRITE XEROX-REPORT FROM LTH-LINE-15 AFTER ADVANCING 1 LINE.  DTSBR103
00255      WRITE XEROX-REPORT FROM LTH-LINE-16 AFTER ADVANCING 1 LINE.  DTSBR103
00256      WRITE XEROX-REPORT FROM LTH-LINE-17 AFTER ADVANCING 1 LINE.  DTSBR103
00257      WRITE XEROX-REPORT FROM LTH-LINE-18 AFTER ADVANCING 1 LINE.  DTSBR103
00258      WRITE XEROX-REPORT FROM LTH-LINE-19 AFTER ADVANCING 1 LINE.  DTSBR103
00259      WRITE XEROX-REPORT FROM LTH-LINE-22 AFTER ADVANCING 3 LINE.  DTSBR103
00260                                                                   DTSBR103
00261  P2000-EXIT.                                                      DTSBR103
00262      EXIT.                                                        DTSBR103
00263                                                                   DTSBR103
00264  P3000-PRINT-DETAIL.                                              DTSBR103
00265      WRITE XEROX-REPORT FROM LTD-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR103
00266      WRITE XEROX-REPORT FROM LTD-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR103
00267      WRITE XEROX-REPORT FROM LTD-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR103
00268 *    WRITE XEROX-REPORT FROM LTD-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR103
00269      WRITE XEROX-REPORT FROM LTD-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR103
00270      WRITE XEROX-REPORT FROM LTD-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR103
00271      WRITE XEROX-REPORT FROM LTD-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR103
00272 *    WRITE XEROX-REPORT FROM LTD-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR103
00273                                                                   DTSBR103
00274  P3000-EXIT.                                                      DTSBR103
00275      EXIT.                                                        DTSBR103
00276                                                                   DTSBR103
00277  P4000-PRINT-FOOTER.                                              DTSBR103
00278      MOVE WS-OPR-VOICE-AREA   TO WS-OPR-VOICE-AREA-CODE.          DTSBR103
00279      MOVE WS-OPR-VOICE-1      TO WS-OPR-VOICE-ONE.                DTSBR103
00280      MOVE WS-OPR-VOICE-2      TO WS-OPR-VOICE-TWO.                DTSBR103
00281      MOVE WS-OPR-NAME         TO WS-OPR-NAME-FOOTER.              DTSBR103
00282      MOVE WS-OPR-UNIT-NAME    TO WS-OPR-UNIT-NAME-FOOTER.         DTSBR103
00283      WRITE XEROX-REPORT FROM LTF-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR103
00284      WRITE XEROX-REPORT FROM LTF-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR103
00285      WRITE XEROX-REPORT FROM LTF-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR103
00286      WRITE XEROX-REPORT FROM LTF-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR103
00287      WRITE XEROX-REPORT FROM LTF-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR103
00288      WRITE XEROX-REPORT FROM LTF-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR103
00289      WRITE XEROX-REPORT FROM LTF-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR103
00290      WRITE XEROX-REPORT FROM LTF-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR103
00291      WRITE XEROX-REPORT FROM LTF-LINE-9 AFTER ADVANCING 1 LINE.   DTSBR103
00292      WRITE XEROX-REPORT FROM LTF-LINE-10 AFTER ADVANCING 1 LINE.  DTSBR103
00293                                                                   DTSBR103
00294  P4000-EXIT.                                                      DTSBR103
00295      EXIT.                                                        DTSBR103
00296                                                                   DTSBR103
00297  T1000-TERMINATE.                                                 DTSBR103
00298      SKIP1                                                        DTSBR103
00299      CLOSE PRT-FILE.                                              DTSBR103
00300      SKIP2                                                        DTSBR103
00301  T1000-EXIT.                                                      DTSBR103
00302      EXIT.                                                        DTSBR103
00303      EJECT                                                        DTSBR103
00304  S001-DATE-CONVERT.                                               DTSBR103
00305      SKIP1                                                        DTSBR103
00306      CALL 'DTSBU001' USING L001-LINK-AREA.                        DTSBR103
00307      SKIP2                                                        DTSBR103
00308  S001-EXIT.                                                       DTSBR103
00309      EXIT.                                                        DTSBR103
00310      SKIP3                                                        DTSBR103
00311  S002-DATE-ALPHA.                                                 DTSBR103
00312      SKIP1                                                        DTSBR103
00313      CALL 'DTSBU002' USING L002-LINK-AREA.                        DTSBR103
00314      SKIP2                                                        DTSBR103
00315  S002-EXIT.                                                       DTSBR103
00316      EXIT.                                                        DTSBR103
00317      SKIP3                                                        DTSBR103
00318  S071-DESLASH-NAME.                                               DTSBR103
00319      SKIP1                                                        DTSBR103
00320      CALL 'DTSBU071' USING L071-LINK-AREA.                        DTSBR103
00321      SKIP2                                                        DTSBR103
00322  S071-EXIT.                                                       DTSBR103
00323      EXIT.                                                        DTSBR103
00324      SKIP3                                                        DTSBR103
00325  S082-OP-ID-INFO.                                                 DTSBR103
00326      SKIP1                                                        DTSBR103
00327      CALL 'DTSBU082' USING L082-LINK-AREA.                        DTSBR103
00328      SKIP2                                                        DTSBR103
00329  S082-EXIT.                                                       DTSBR103
00330      EXIT.                                                        DTSBR103
00331      SKIP3                                                        DTSBR103
00332  S999-ABEND.                                                      DTSBR103
00333      SKIP1                                                        DTSBR103
00334      CALL 'DTSBU999' USING WRK-ABEND-CD.                          DTSBR103
00335      SKIP2                                                        DTSBR103
00336  S999-EXIT.                                                       DTSBR103
00337      EXIT.                                                        DTSBR103
00338                                                                   DTSBR103
