00001  IDENTIFICATION DIVISION.                                         08/02/02
00002  PROGRAM-ID.             OJRCU004.                                OJRCU004
00003  AUTHOR.                 TRW.                                        LV001
00004  DATE-WRITTEN.           DEC 2001.                                OJRCU004
00005  DATE-COMPILED.                                                   OJRCU004
00006      SKIP3                                                        OJRCU004
00007 *****                                                             OJRCU004
00008 *                                                                 OJRCU004
00009 *    FUNCTION:  EDIT TEXT PARMS FOR REPORT GENERATION.            OJRCU004
00010 *                                                                 OJRCU004
00011 *                                                                 OJRCU004
00012 *    MODIFICATION LOG:                                            OJRCU004
00013 *                                                                 OJRCU004
00014 *    12/16/01  INITIAL DEVELOPMENT.                               OJRCU004
00015 *              WORK ORDER:                      PROGRAMMER: JMO.  OJRCU004
00016 *                                                                 OJRCU004
00017 *    XX/XX/XX  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU004
00018 *              XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU004
00019 *              WORK ORDER:                      PROGRAMMER: XXX   OJRCU004
00020 *                                                                 OJRCU004
00021 *                                                                 OJRCU004
00022 *  DESCRIPTION:                                                   OJRCU004
00023 *                                                                 OJRCU004
00024 *    CLEAR:                                                       OJRCU004
00025 *                                                                 OJRCU004
00026 *      DATA FIELDS DISPLAYED: NONE.                               OJRCU004
00027 *      MESSAGE: NONE                                              OJRCU004
00028 *                                                                 OJRCU004
00029 *                                                                 OJRCU004
00030 *    INQUIRY:                                                     OJRCU004
00031 *                                                                 OJRCU004
00032 *      SET DEFAULT PARM VALUES                                    OJRCU004
00033 *                                                                 OJRCU004
00034 *                                                                 OJRCU004
00035 *    UPDATE:                                                      OJRCU004
00036 *                                                                 OJRCU004
00037 *      EDIT PARMS                                                 OJRCU004
00038 *                                                                 OJRCU004
00039 *                                                                 OJRCU004
00040 *    RECORDS READ:                                                OJRCU004
00041 *                                                                 OJRCU004
00042 *      MASTER:                                                    OJRCU004
00043 *                                                                 OJRCU004
00044 *        NONE.                                                    OJRCU004
00045 *                                                                 OJRCU004
00046 *                                                                 OJRCU004
00047 *      ALTERNATE INDEX:                                           OJRCU004
00048 *                                                                 OJRCU004
00049 *        NONE.                                                    OJRCU004
00050 *                                                                 OJRCU004
00051 *                                                                 OJRCU004
00052 *      REFERENCE:                                                 OJRCU004
00053 *                                                                 OJRCU004
00054 *        NONE.                                                    OJRCU004
00055 *                                                                 OJRCU004
00056 *                                                                 OJRCU004
00057 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU004
00058 *                                                                 OJRCU004
00059 *        NONE.                                                    OJRCU004
00060 *                                                                 OJRCU004
00061 *                                                                 OJRCU004
00062 *    RECORDS UPDATED:                                             OJRCU004
00063 *                                                                 OJRCU004
00064 *      MASTER:                                                    OJRCU004
00065 *                                                                 OJRCU004
00066 *        NONE.                                                    OJRCU004
00067 *                                                                 OJRCU004
00068 *                                                                 OJRCU004
00069 *      REFERENCE:                                                 OJRCU004
00070 *                                                                 OJRCU004
00071 *        NONE                                                     OJRCU004
00072 *                                                                 OJRCU004
00073 *                                                                 OJRCU004
00074 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU004
00075 *                                                                 OJRCU004
00076 *        NONE.                                                    OJRCU004
00077 *                                                                 OJRCU004
00078 *                                                                 OJRCU004
00079 *    ON-LINE EVENT FILE RECORDS WRITTEN:                          OJRCU004
00080 *                                                                 OJRCU004
00081 *      NONE.                                                      OJRCU004
00082 *                                                                 OJRCU004
00083 *                                                                 OJRCU004
00084 *    MODULES (OTHER THAN STANDARD SCREEN PROCESSING               OJRCU004
00085 *    UTILITY MODULES) LINKED TO:                                  OJRCU004
00086 *                                                                 OJRCU004
00087 *      DTSCU013 COUNT FROM SCREEN FORMAT/EDIT.                    OJRCU004
00088 *                                                                 OJRCU004
00089 *                                                                 OJRCU004
00090 *    MAINTENANCE NOTES:                                           OJRCU004
00091 *                                                                 OJRCU004
00092 *                                                                 OJRCU004
00093 *****                                                             OJRCU004
00094      SKIP3                                                        OJRCU004
00095  ENVIRONMENT DIVISION.                                            OJRCU004
00096      EJECT                                                        OJRCU004
00097  DATA DIVISION.                                                   OJRCU004
00098  WORKING-STORAGE SECTION.                                         OJRCU004
000985 77  PAN-VALET PICTURE X(24) VALUE '001OJRCU004  08/02/02'.       OJRCU004
00099                                                                   OJRCU004
00100  01  WRK-AREA.                                                    OJRCU004
00101      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'U004'.    OJRCU004
00102      05  WRK-RESP-CD                 PIC S9(08)  COMP.            OJRCU004
00103                                                                   OJRCU004
00104      05  WRK-MAPSET-NAME             PIC  X(08)  VALUE 'DTSMSET'. OJRCU004
00105      05  WRK-MAP-NAME.                                            OJRCU004
00106          10  WRK-MAP-NAME-PREFIX     PIC  X(04)  VALUE 'OJRM'.    OJRCU004
00107          10  WRK-MAP-NAME-SUFFIX     PIC  X(04)  VALUE '004 '.    OJRCU004
00108                                                                   OJRCU004
00109      05  WRK-F03-SCR-ID              PIC  X(02)  VALUE '80'.      OJRCU004
00110                                                                   OJRCU004
00111      05  WRK-MAX-PARMS               PIC  9(03)  COMP-3           OJRCU004
00112                                                  VALUE 16.        OJRCU004
00113                                                                   OJRCU004
00114      05  WRK-MSG-AREA                PIC  X(64) VALUE SPACES.     OJRCU004
00115                                                                   OJRCU004
00116      05  WRK-ENTER-MSG               PIC  X(64) VALUE             OJRCU004
00117          'PRESS ENTER WHEN DONE'.                                 OJRCU004
00118                                                                   OJRCU004
00119      05  WRK-PARM                    PIC  X(32).                  OJRCU004
00120                                                                   OJRCU004
00121      05  WRK-SUB                     PIC S9(04)  COMP.            OJRCU004
00122                                                                   OJRCU004
00123      05  WRK-CFKD-SUBMIT             PIC  X(09)                   OJRCU004
00124                                      VALUE 'F9=SUBMIT'.           OJRCU004
00125      EJECT                                                        OJRCU004
00126  01  SCREEN-CONTROL.                                              OJRCU004
00127      05  SCR-ACCESS-IND              PIC X(01).                   OJRCU004
00128          88  SCR-ACCESS-INQ                  VALUE '1'.           OJRCU004
00129          88  SCR-ACCESS-UPDATE               VALUE '2'.           OJRCU004
00130      SKIP1                                                        OJRCU004
00131      05  CURSOR-SET-IND              PIC X(01).                   OJRCU004
00132          88  CURSOR-SET-YES                  VALUE 'Y'.           OJRCU004
00133          88  CURSOR-SET-NO                   VALUE 'N'.           OJRCU004
00134          88  CURSOR-SET-GOTO                 VALUE 'G'.           OJRCU004
00135      SKIP1                                                        OJRCU004
00136      05  REQ-IND                     PIC X(01).                   OJRCU004
00137          88  REQ-ERROR                       VALUE 'O'.           OJRCU004
00138          88  REQ-JUMP                        VALUE 'J'.           OJRCU004
00139          88  REQ-INQUIRE                     VALUE 'I'.           OJRCU004
00140          88  REQ-CLEAR                       VALUE 'C'.           OJRCU004
00141          88  REQ-EDIT                        VALUE 'E'.           OJRCU004
00142          88  REQ-UPDATE                      VALUE 'U'.           OJRCU004
00143          88  REQ-CURSOR-TO-GOTO              VALUE 'G'.           OJRCU004
00144      SKIP1                                                        OJRCU004
00145      05  RESP-IND                    PIC X(01).                   OJRCU004
00146          88  RESP-SEND-MSGONLY               VALUE 'O'.           OJRCU004
00147          88  RESP-SEND-MAP                   VALUE 'M'.           OJRCU004
00148          88  RESP-JUMP                       VALUE 'J'.           OJRCU004
00149          88  RESP-CURSOR-TO-GOTO             VALUE 'G'.           OJRCU004
00150      SKIP1                                                        OJRCU004
00151      05  SCR-ATB-AN                  PIC  X(01).                  OJRCU004
00152      05  SCR-ATB-NUM                 PIC  X(01).                  OJRCU004
00153      EJECT                                                        OJRCU004
00154  01  L013-COMM-AREA.                                              OJRCU004
00155  ++INCLUDE DTSIL013                                               OJRCU004
00156      EJECT                                                        OJRCU004
00157 * ERROR MSG MODULE                                                OJRCU004
00158  01  L805-COMM-AREA.                                              OJRCU004
00159  ++INCLUDE DTSIL805                                               OJRCU004
00160      EJECT                                                        OJRCU004
00161 * MAP DEFINITION                                                  OJRCU004
00162  01  L851-COMM-AREA.                                              OJRCU004
00163  ++INCLUDE DTSIL851                                               OJRCU004
00164      SKIP3                                                        OJRCU004
00165      05  MAP-AREA REDEFINES L851-MAP-AREA.                        OJRCU004
00166          10 OJR-WINDOW-AREA.                                      OJRCU004
00167  ++INCLUDE OJRIS004                                               OJRCU004
00168      EJECT                                                        OJRCU004
00169 * ATTRIBUTE LITERALS                                              OJRCU004
00170  01  CATB-LITERALS.                                               OJRCU004
00171  ++INCLUDE DTSICATB                                               OJRCU004
00172      SKIP3                                                        OJRCU004
00173 * FUNCTION KEY DESCRIPTION LITERALS                               OJRCU004
00174  01  CFKD-LITERALS.                                               OJRCU004
00175  ++INCLUDE DTSICFKD                                               OJRCU004
00176      EJECT                                                        OJRCU004
00177 * ERROR CODE MESSAGE LITERALS                                     OJRCU004
00178  01  CECD-LITERALS.                                               OJRCU004
00179  ++INCLUDE DTSICECD                                               OJRCU004
00180      EJECT                                                        OJRCU004
00181  LINKAGE SECTION.                                                 OJRCU004
00182      SKIP3                                                        OJRCU004
00183  01  DFHCOMMAREA.                                                 OJRCU004
00184  ++INCLUDE DTSILCCM                                               OJRCU004
00185      SKIP3                                                        OJRCU004
00186 * PARM EDIT AND DATA CAPTURE AREA                                 OJRCU004
00187  ++INCLUDE OJRILCCM                                               OJRCU004
00188                                                                   OJRCU004
00189  PROCEDURE DIVISION.                                              OJRCU004
00190                                                                   OJRCU004
00191      MOVE LOW-VALUES TO MAP-AREA                                  OJRCU004
00192                                                                   OJRCU004
00193      MOVE SPACE TO REQ-IND                                        OJRCU004
00194                                                                   OJRCU004
00195      PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT                OJRCU004
00196      SKIP1                                                        OJRCU004
00197 *-----------------------------------------------------            OJRCU004
00198 *    P1000-ANALYZE-REQUEST HAS DETERMINED, BASED ON THE           OJRCU004
00199 *    "AID" KEY PRESSED AND THE CONTEXT OF THE CURRENT             OJRCU004
00200 *    REQUEST WITHIN THE PSEUDO CONVERSATION, THE TYPE             OJRCU004
00201 *    OF ACTIVITY THE WORK STATION OPERATOR HAS REQUESTED.         OJRCU004
00202 *                                                                 OJRCU004
00203 *    THE REQUEST, REFLECTED IN REQ-IND WILL NOW BE                OJRCU004
00204 *    PROCESSED.                                                   OJRCU004
00205 *                                                                 OJRCU004
00206 *    THE REQUEST PROCESSING PARAGRAPHS WILL SET RESP-IND,         OJRCU004
00207 *    INDICATING THE TYPE OF RESPONSE TO BE SENT TO THE            OJRCU004
00208 *    WORK STATION OPERATOR.                                       OJRCU004
00209 *-----------------------------------------------------            OJRCU004
00210      SKIP1                                                        OJRCU004
00211      INITIALIZE RESP-IND                                          OJRCU004
00212      SKIP1                                                        OJRCU004
00213      EVALUATE TRUE                                                OJRCU004
00214          WHEN REQ-ERROR                                           OJRCU004
00215              PERFORM P2000-REQUEST-ERROR THRU P2000-EXIT          OJRCU004
00216          WHEN REQ-JUMP                                            OJRCU004
00217              PERFORM P3000-REQUEST-JUMP THRU P3000-EXIT           OJRCU004
00218          WHEN REQ-CLEAR                                           OJRCU004
00219              PERFORM P4000-REQUEST-CLEAR   THRU P4000-EXIT        OJRCU004
00220          WHEN REQ-INQUIRE                                         OJRCU004
00221              PERFORM P6000-DETERMINE-REQ   THRU P6000-EXIT        OJRCU004
00222          WHEN OTHER                                               OJRCU004
00223              GO TO S899-ABEND                                     OJRCU004
00224      END-EVALUATE.                                                OJRCU004
00225      SKIP3                                                        OJRCU004
00226  MAINLINE-EXIT.                                                   OJRCU004
00227                                                                   OJRCU004
00228      EXEC CICS                                                    OJRCU004
00229          RETURN                                                   OJRCU004
00230      END-EXEC.                                                    OJRCU004
00231                                                                   OJRCU004
00232      GOBACK.                                                      OJRCU004
00233      EJECT                                                        OJRCU004
00234                                                                   OJRCU004
00235 /*****************************************************************OJRCU004
00236 * DETERMINE CURRENT SCREEN STATE AND REQUEST COMBINATION         *OJRCU004
00237 ******************************************************************OJRCU004
00238  P1000-ANALYZE-REQUEST.                                           OJRCU004
00239      SKIP1                                                        OJRCU004
00240 *-----------------------------------------------------            OJRCU004
00241 *     IF SCREEN IS NOT CURRENTLY DISPLAYED (JUMP TO HERE)         OJRCU004
00242 *     THEN ANY KEY PRESSED WILL BE IGNORED (WILL BE               OJRCU004
00243 *     REPLACED WITH ENTER)                                        OJRCU004
00244 *-----------------------------------------------------            OJRCU004
00245      IF LCCM-SEND-MAP-88                                          OJRCU004
00246         SET REQ-INQUIRE TO TRUE                                   OJRCU004
00247         GO TO P1000-EXIT                                          OJRCU004
00248      END-IF                                                       OJRCU004
00249      SKIP3                                                        OJRCU004
00250 *-----------------------------------------------------            OJRCU004
00251 *    REQUEST TO CLEAR THE SCREEN                                  OJRCU004
00252 *-----------------------------------------------------            OJRCU004
00253      IF LCCM-F12-88                                               OJRCU004
00254         MOVE LOW-VALUES   TO MAP-AREA                             OJRCU004
00255         SET REQ-CLEAR     TO TRUE                                 OJRCU004
00256         GO TO P1000-EXIT                                          OJRCU004
00257      END-IF                                                       OJRCU004
00258      SKIP3                                                        OJRCU004
00259 *-----------------------------------------------------            OJRCU004
00260 *    ALL OTHER PA KEYS ARE NOT ACTIVE                             OJRCU004
00261 *-----------------------------------------------------            OJRCU004
00262      IF LCCM-PA-88                                                OJRCU004
00263        PERFORM S804-INVALID-KEY THRU S804-EXIT                    OJRCU004
00264        SET REQ-ERROR TO TRUE                                      OJRCU004
00265        GO TO P1000-EXIT                                           OJRCU004
00266      END-IF                                                       OJRCU004
00267      SKIP3                                                        OJRCU004
00268 *-----------------------------------------------------            OJRCU004
00269 *    IF EXIT KEY PRESSED, JUMP TO NEXT HIGHER FUNCTION            OJRCU004
00270 *-----------------------------------------------------            OJRCU004
00271      IF LCCM-F03-88                                               OJRCU004
00272         MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                    OJRCU004
00273         SET REQ-JUMP TO TRUE                                      OJRCU004
00274         GO TO P1000-EXIT                                          OJRCU004
00275      END-IF                                                       OJRCU004
00276      SKIP3                                                        OJRCU004
00277 *-----------------------------------------------------            OJRCU004
00278 *    IF ENTER - PROCESS PARM UPDATES                              OJRCU004
00279 *-----------------------------------------------------            OJRCU004
00280      IF LCCM-ENTER-88                                             OJRCU004
00281          SET REQ-INQUIRE TO TRUE                                  OJRCU004
00282          GO TO P1000-EXIT                                         OJRCU004
00283      END-IF                                                       OJRCU004
00284      SKIP3                                                        OJRCU004
00285 *-----------------------------------------------------            OJRCU004
00286 *     ANY OTHER KEY IS INVALID                                    OJRCU004
00287 *-----------------------------------------------------            OJRCU004
00288      PERFORM S804-INVALID-KEY THRU S804-EXIT                      OJRCU004
00289      SET REQ-ERROR TO TRUE.                                       OJRCU004
00290  P1000-EXIT.                                                      OJRCU004
00291      EXIT.                                                        OJRCU004
00292      SKIP3                                                        OJRCU004
00293 /*****************************************************************OJRCU004
00294 * ANALYZE REQUEST HAS DETERMINED AN ERROR THAT MUST BE REPORTED. *OJRCU004
00295 * VERIFY THAT A MESSAGE HAS BEEN FILLED IN.                      *OJRCU004
00296 ******************************************************************OJRCU004
00297      SKIP1                                                        OJRCU004
00298  P2000-REQUEST-ERROR.                                             OJRCU004
00299      IF LCCM-MSG                                                  OJRCU004
00300         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU004
00301      ELSE                                                         OJRCU004
00302         GO TO S899-ABEND                                          OJRCU004
00303      END-IF.                                                      OJRCU004
00304  P2000-EXIT.                                                      OJRCU004
00305      EXIT.                                                        OJRCU004
00306 /*****************************************************************OJRCU004
00307 * JUMP TO A DIFFERENT SCREEN TYPE WAS REQUESTED                  *OJRCU004
00308 ******************************************************************OJRCU004
00309      SKIP1                                                        OJRCU004
00310  P3000-REQUEST-JUMP.                                              OJRCU004
00311 *-----------------------------------------------------            OJRCU004
00312 *    VERIFY THAT THE REQUESTED SCREEN EXISTS AND IS ACCESSIBLE    OJRCU004
00313 *    BY USER                                                      OJRCU004
00314 *-----------------------------------------------------            OJRCU004
00315      PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT                  OJRCU004
00316      SKIP3                                                        OJRCU004
00317 *-----------------------------------------------------            OJRCU004
00318 *    VERIFICATION RETURN LCCM-MSG IF ERROR DETECTED               OJRCU004
00319 *-----------------------------------------------------            OJRCU004
00320      IF LCCM-MSG                                                  OJRCU004
00321         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU004
00322         SET CURSOR-SET-GOTO TO TRUE                               OJRCU004
00323         GO TO P3000-EXIT                                          OJRCU004
00324      END-IF                                                       OJRCU004
00325      SKIP3                                                        OJRCU004
00326 *-----------------------------------------------------            OJRCU004
00327 *    CLEAN UP INDICATORS AND PAGING STORAGE PRIOR TO LEAVING      OJRCU004
00328 *-----------------------------------------------------            OJRCU004
00329      MOVE LOW-VALUES TO LCCM-SCR-STATUS                           OJRCU004
00330                         LCCM-SCR-HOLD-AREA                        OJRCU004
00331      MOVE +0 TO LCCM-SCR-ABSTIME                                  OJRCU004
00332      SET RESP-JUMP TO TRUE.                                       OJRCU004
00333  P3000-EXIT.                                                      OJRCU004
00334      EXIT.                                                        OJRCU004
00335 /*****************************************************************OJRCU004
00336 * CLEAR KEY WAS PRESSED                                          *OJRCU004
00337 ******************************************************************OJRCU004
00338  P4000-REQUEST-CLEAR.                                             OJRCU004
00339      SET LCCM-SCR-CLEAR  TO TRUE                                  OJRCU004
00340      SET RESP-SEND-MAP   TO TRUE.                                 OJRCU004
00341  P4000-EXIT.                                                      OJRCU004
00342      EXIT.                                                        OJRCU004
00343      SKIP1                                                        OJRCU004
00344                                                                   OJRCU004
00345 /*****************************************************************OJRCU004
00346 * INQUIRY WAS REQUESTED                                          *OJRCU004
00347 ******************************************************************OJRCU004
00348                                                                   OJRCU004
00349  P6000-DETERMINE-REQ.                                             OJRCU004
00350      SET LCCM-END-TASK-88 TO TRUE                                 OJRCU004
00351      IF LCCM-SEND-MAP-88                                          OJRCU004
00352         PERFORM P6100-BUILD-MAP THRU P6100-EXIT                   OJRCU004
00353         PERFORM S9300-SEND-MAP  THRU S9300-EXIT                   OJRCU004
00354      ELSE                                                         OJRCU004
00355         PERFORM S9100-RECEIVE    THRU S9100-EXIT                  OJRCU004
00356         PERFORM P6200-BUILD-LCCM THRU P6200-EXIT                  OJRCU004
00357      END-IF.                                                      OJRCU004
00358  P6000-EXIT.                                                      OJRCU004
00359      EXIT.                                                        OJRCU004
00360                                                                   OJRCU004
00361  P6100-BUILD-MAP.                                                 OJRCU004
00362      INITIALIZE OJR-WINDOW-AREA                                   OJRCU004
00363      MOVE CATB-CURSOR                    TO MAP-TEXT-L            OJRCU004
00364      MOVE LCCM-PARM-VALUE(LCCM-PARM-SUB) TO WRK-PARM              OJRCU004
00365      MOVE WRK-PARM(1:32)                 TO MAP-TEXT.             OJRCU004
00366  P6100-EXIT.                                                      OJRCU004
00367      EXIT.                                                        OJRCU004
00368                                                                   OJRCU004
00369  P6200-BUILD-LCCM.                                                OJRCU004
00370      INITIALIZE WRK-PARM                                          OJRCU004
00371      MOVE MAP-TEXT              TO WRK-PARM(1:32)                 OJRCU004
00372      MOVE WRK-PARM              TO LCCM-PARM-VALUE(LCCM-PARM-SUB).OJRCU004
00373  P6200-EXIT.                                                      OJRCU004
00374      EXIT.                                                        OJRCU004
00375                                                                   OJRCU004
00376                                                                   OJRCU004
00377 /*****************************************************************OJRCU004
00378 * LINKS TO UTILITY MODULES                                        OJRCU004
00379 ******************************************************************OJRCU004
00380      SKIP1                                                        OJRCU004
00381  S013-SCREEN-COUNT.                                               OJRCU004
00382      EXEC CICS LINK                                               OJRCU004
00383          PROGRAM  ('DTSCU013')                                    OJRCU004
00384          COMMAREA (L013-COMM-AREA)                                OJRCU004
00385      END-EXEC.                                                    OJRCU004
00386  S013-EXIT.                                                       OJRCU004
00387      EXIT.                                                        OJRCU004
00388      EJECT                                                        OJRCU004
00389  S803-REQ-SCR-ID-EDIT.                                            OJRCU004
00390      EXEC CICS LINK                                               OJRCU004
00391          PROGRAM  ('DTSCU803')                                    OJRCU004
00392          COMMAREA (DFHCOMMAREA)                                   OJRCU004
00393      END-EXEC.                                                    OJRCU004
00394  S803-EXIT.                                                       OJRCU004
00395      EXIT.                                                        OJRCU004
00396      SKIP3                                                        OJRCU004
00397  S804-INVALID-KEY.                                                OJRCU004
00398      EXEC CICS LINK                                               OJRCU004
00399          PROGRAM  ('DTSCU804')                                    OJRCU004
00400          COMMAREA (DFHCOMMAREA)                                   OJRCU004
00401      END-EXEC.                                                    OJRCU004
00402  S804-EXIT.                                                       OJRCU004
00403      EXIT.                                                        OJRCU004
00404      SKIP3                                                        OJRCU004
00405  S851-SCREEN-PROCESSING.                                          OJRCU004
00406      IF LCCM-SEND-MAP-88                                          OJRCU004
00407         IF L851-ALARM-IND = 'N'                                   OJRCU004
00408            EXEC CICS                                              OJRCU004
00409                SEND                                               OJRCU004
00410                    MAP    (WRK-MAP-NAME)                          OJRCU004
00411                    MAPSET (WRK-MAPSET-NAME)                       OJRCU004
00412                    FROM   (OJR-WINDOW-AREA)                       OJRCU004
00413                    CURSOR                                         OJRCU004
00414                    FREEKB                                         OJRCU004
00415                    RESP   (WRK-RESP-CD)                           OJRCU004
00416            END-EXEC                                               OJRCU004
00417         ELSE                                                      OJRCU004
00418             EXEC CICS                                             OJRCU004
00419                 SEND                                              OJRCU004
00420                     MAP    (WRK-MAP-NAME)                         OJRCU004
00421                     MAPSET (WRK-MAPSET-NAME)                      OJRCU004
00422                     FROM   (OJR-WINDOW-AREA)                      OJRCU004
00423                     CURSOR                                        OJRCU004
00424                     FREEKB                                        OJRCU004
00425                     ALARM                                         OJRCU004
00426                     RESP   (WRK-RESP-CD)                          OJRCU004
00427             END-EXEC                                              OJRCU004
00428         END-IF                                                    OJRCU004
00429      ELSE                                                         OJRCU004
00430          INITIALIZE OJR-WINDOW-AREA                               OJRCU004
00431          EXEC CICS                                                OJRCU004
00432              RECEIVE                                              OJRCU004
00433                     MAP    (WRK-MAP-NAME)                         OJRCU004
00434                     MAPSET (WRK-MAPSET-NAME)                      OJRCU004
00435                     INTO   (OJR-WINDOW-AREA)                      OJRCU004
00436                     RESP   (WRK-RESP-CD)                          OJRCU004
00437          END-EXEC                                                 OJRCU004
00438 *04/10   MOVE EIBAID TO LCCM-AID                                  OJRCU004
00439      END-IF                                                       OJRCU004
00440                                                                   OJRCU004
00441      IF WRK-RESP-CD NOT = DFHRESP(NORMAL)                         OJRCU004
00442         GO TO S899-ABEND                                          OJRCU004
00443      END-IF.                                                      OJRCU004
00444  S851-EXIT.                                                       OJRCU004
00445      EXIT.                                                        OJRCU004
00446      SKIP3                                                        OJRCU004
00447  S899-ABEND.                                                      OJRCU004
00448      EXEC CICS ABEND                                              OJRCU004
00449          ABCODE(WRK-ABEND-CD)                                     OJRCU004
00450      END-EXEC.                                                    OJRCU004
00451 *S899-EXIT.                                                       OJRCU004
00452 *    EXIT.                                                        OJRCU004
00453  S1101-ERROR.                                                     OJRCU004
00454      MOVE WRK-MSG-AREA  TO LCCM-MSG-AREA.                         OJRCU004
00455  S1101-EXIT.                                                      OJRCU004
00456      EXIT.                                                        OJRCU004
00457                                                                   OJRCU004
00458                                                                   OJRCU004
00459  S5900-SET-ATTRB.                                                 OJRCU004
00460      MOVE CATB-UNPROT-NORM-AN-MDTON      TO MAP-TEXT-A.           OJRCU004
00461  S5900-EXIT.                                                      OJRCU004
00462      EXIT.                                                        OJRCU004
00463                                                                   OJRCU004
00464 /*****************************************************************OJRCU004
00465 * MAP ROUTINES                                                   *OJRCU004
00466 ******************************************************************OJRCU004
00467  S9100-RECEIVE.                                                   OJRCU004
00468      SET L851-RECEIVE-88 TO TRUE.                                 OJRCU004
00469      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU004
00470  S9100-EXIT.                                                      OJRCU004
00471      EXIT.                                                        OJRCU004
00472                                                                   OJRCU004
00473  S9300-SEND-MAP.                                                  OJRCU004
00474      PERFORM S5900-SET-ATTRB THRU S5900-EXIT                      OJRCU004
00475      IF NOT LCCM-NO-MSG                                           OJRCU004
00476         MOVE 'INVALID ENTRY'         TO MAP-MSG-TEXT              OJRCU004
00477         MOVE CATB-PROT-BRT-MDTON     TO MAP-MSG-TEXT-A            OJRCU004
00478      ELSE                                                         OJRCU004
00479          MOVE CATB-ASKIP-NORM-MDTOFF TO MAP-MSG-TEXT-A            OJRCU004
00480      END-IF                                                       OJRCU004
00481      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT                   OJRCU004
00482      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU004
00483  S9300-EXIT.                                                      OJRCU004
00484      EXIT.                                                        OJRCU004
00485                                                                   OJRCU004
00486                                                                   OJRCU004
00487  S9900-PREPARE-SEND.                                              OJRCU004
00488      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND                     OJRCU004
00489      MOVE LCCM-MSG-TYPE     TO L851-MSG-TYPE.                     OJRCU004
00490  S9900-EXIT.                                                      OJRCU004
00491      EXIT.                                                        OJRCU004
