00001  IDENTIFICATION DIVISION.                                         01/11/05
00002  PROGRAM-ID.             DTSBR105.                                DTSBR105
00003  AUTHOR.                 MT DEPT OF LABOR/UI PROGRAMMING SECTION     LV020
00004  DATE-WRITTEN.           AUGUST 1994.                             DTSBR105
00005  DATE-COMPILED.                                                   DTSBR105
00006      SKIP3                                                        DTSBR105
00007 *****                                                             DTSBR105
00008 *    CALLING SEQUENCE:  DTSBD400 CALLS                            DTSBR105
00009 *                       DTSBD314 WHICH UPDATES DTSIR105           DTSBR105
00010 *                       DTSBR105 READS DTSIR105 RECORDS.          DTSBR105
00011 *                                                                 DTSBR105
00012 *    FUNCTION:  LETTER TO COOPERATING OUT-OF-STATE AGENCY.        DTSBR105
00013 *                                                                 DTSBR105
00014 *                                                                 DTSBR105
00015 *    MODIFICATION HISTORY:                                        DTSBR105
00016 *                                                                 DTSBR105
00017 * 08-07-94 INITIAL DEVELOPMENT                                    DTSBR105
00018 *          REFERENCE RFP #RAP             AUTHOR OF CHANGE - SFW  DTSBR105
00019 *                                                                 DTSBR105
00020 * 01-30-95 CHANGED PRINT LINES FOR ADDRESS AND THE PRINT LINE     DTSBR105
00021 *          AND COLUMN FOR THE DATE (L002-LONG-TEXT-AREA) FOR      DTSBR105
00022 *          BETTER PLACEMENT ON LETTERHEAD MAILED IN WINDOW        DTSBR105
00023 *          ENVELOPES.                                             DTSBR105
00024 *          REFERENCE RFP #RAP                    PROGRAMMER: MJA  DTSBR105
00025 *                                                                 DTSBR105
00026 * 03-01-95 CHANGED PAGE LIMIT FROM 62 LINES TO 60 LINES.          DTSBR105
00027 *          REFERENCE RFP # RAP                   PROGRAMMER: MJA  DTSBR105
00028 *                                                                 DTSBR105
00029 * 04-02-95 MOVED REPORT LINES DOWN TO ACCOMODATE AGENCY BLUE      DTSBR105
00030 *          LETTERHEAD, MOVED LEFT MARGIN TWO CHARACTERS TO THE    DTSBR105
00031 *          LEFT.                                                  DTSBR105
00032 *          REFERENCE RFP # TPR 15                PROGRAMMER: MJA  DTSBR105
00033 *                                                                 DTSBR105
00034 * 11/26/97 INCREASE THE LENGTH OF WS-OPR-UNIT-NAME.  REQUIRED     DTSBR105
00035 *          TO REFLECT THE JULY 1, 1997 MOVE OF UI TAX FUNCTIONS   DTSBR105
00036 *          FROM DLI TO DOR.                                       DTSBR105
00037 *                                                                 DTSBR105
00038 * 10/27/98 MODIFIED TO CONFORM TO DUTAS STANDARDS.                DTSBR105
00039 *          REFERENCE RFP #****                   PROGRAMMER: DVS  DTSBR105
00040 *                                                                 DTSBR105
00041 * 08/14/99 MODIFIED TO CONFORM TO DUTAS LAZER PRINTING            DTSBR105
00042 *          REFERENCE RFP #****                   PROGRAMMER: DVS  DTSBR105
00043 *                                                                 DTSBR105
00044 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR105
00045 *          XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR105
00046 *          REFERENCE RFP #****                   PROGRAMMER: XXX  DTSBR105
00047 *                                                                 DTSBR105
00048 *                                                                 DTSBR105
00049 *    DESCRIPTION:                                                 DTSBR105
00050 *                                                                 DTSBR105
00051 *        THIS MODULE PRINTS A LETTER TO A COOPERATING             DTSBR105
00052 *        OUT-OF-STATE AGENCY REQUESTING THEIR ASSISTANCE GETTING  DTSBR105
00053 *        AN EMPLOYER REGISTRATION FORM (UI-1) FROM AN EMPLOYER.   DTSBR105
00054 *                                                                 DTSBR105
00055 *                                                                 DTSBR105
00056 *    RECORDS READ:                                                DTSBR105
00057 *                                                                 DTSBR105
00058 *        NONE.                                                    DTSBR105
00059 *                                                                 DTSBR105
00060 *                                                                 DTSBR105
00061 *    PRINTED OUTPUTS:                                             DTSBR105
00062 *                                                                 DTSBR105
00063 *        105R1  LETTER TO OUT-OF-STATE AGENCY                     DTSBR105
00064 *                                                                 DTSBR105
00065 *                                                                 DTSBR105
00066 *    RECORDS WRITTEN:                                             DTSBR105
00067 *                                                                 DTSBR105
00068 *        NONE.                                                    DTSBR105
00069 *                                                                 DTSBR105
00070 *                                                                 DTSBR105
00071 *    MODULES CALLED:                                              DTSBR105
00072 *                                                                 DTSBR105
00073 *        DTSBU002 DATE ALPHA CONVERSION MODULE                    DTSBR105
00074 *        DTSBU071 NAME EDIT/CONVERSION MODULE                     DTSBR105
00075 *        DTSBU082 OPERATOR ID EDIT/LOOKUP MODULE                  DTSBR105
00076 *                                                                 DTSBR105
00077 *                                                                 DTSBR105
00078 *****                                                             DTSBR105
00079      EJECT                                                        DTSBR105
00080  ENVIRONMENT DIVISION.                                            DTSBR105
00081      SKIP2                                                        DTSBR105
00082  CONFIGURATION SECTION.                                           DTSBR105
00083  SPECIAL-NAMES. C01 IS TOP-OF-PAGE.                               DTSBR105
00084      SKIP1                                                        DTSBR105
00085  INPUT-OUTPUT SECTION.                                            DTSBR105
00086      SKIP1                                                        DTSBR105
00087  FILE-CONTROL.                                                    DTSBR105
00088      SELECT PRT-FILE ASSIGN TO RPT105R1.                          DTSBR105
00089      SKIP3                                                        DTSBR105
00090  DATA DIVISION.                                                   DTSBR105
00091      SKIP3                                                        DTSBR105
00092  FILE SECTION.                                                    DTSBR105
00093      SKIP2                                                        DTSBR105
00094  FD  PRT-FILE                                                     DTSBR105
00095      RECORDING MODE IS F                                          DTSBR105
00096      BLOCK CONTAINS 0 RECORDS                                     DTSBR105
00097      LABEL RECORDS ARE OMITTED.                                   DTSBR105
00098  01  XEROX-REPORT.                                                DTSBR105
00099      05  FILLER                      PIC X(1).                    DTSBR105
00100      05  XEROX-RPT                   PIC X(132).                  DTSBR105
00101      EJECT                                                        DTSBR105
00102  WORKING-STORAGE SECTION.                                         DTSBR105
001025 77  PAN-VALET PICTURE X(24) VALUE '020DTSBR105  01/11/05'.       DTSBR105
00103      SKIP3                                                        DTSBR105
00104  01  WRK-AREA.                                                    DTSBR105
00105      05  WRK-ABEND-CD                PIC S9(04)  COMP  VALUE +105.DTSBR105
00106      05  FIRST-TIME-IND              PIC  X(01)  VALUE 'Y'.       DTSBR105
00107      05  WS-OPR-NAME                 PIC  X(32)  VALUE SPACES.    DTSBR105
00108      05  WS-OPR-UNIT-NAME            PIC  X(50)  VALUE SPACES.    DTSBR105
00109      05  WS-OPR-VOICE.                                            DTSBR105
00110          10  WS-OPR-VOICE-AREA       PIC X(03)  VALUE SPACES.     DTSBR105
00111          10  WS-OPR-VOICE-1          PIC X(03)  VALUE SPACES.     DTSBR105
00112          10  WS-OPR-VOICE-2          PIC X(04)  VALUE SPACES.     DTSBR105
00113          10  WS-OPR-VOICE-EXT        PIC X(04)  VALUE SPACES.     DTSBR105
00114                                                                   DTSBR105
00115  01  VSCA-LINE.                                                   DTSBR105
00116      05  VSCA-DATA                   PIC X(133) VALUE SPACES.     DTSBR105
00117                                                                   DTSBR105
00118      EJECT                                                        DTSBR105
00119  01  L002-LINK-AREA.                                              DTSBR105
00120  ++INCLUDE DTSIL002                                               DTSBR105
00121      EJECT                                                        DTSBR105
00122  01  L071-LINK-AREA.                                              DTSBR105
00123  ++INCLUDE DTSIL071                                               DTSBR105
00124      EJECT                                                        DTSBR105
00125  01  L082-LINK-AREA.                                              DTSBR105
00126  ++INCLUDE DTSIL082                                               DTSBR105
00127      EJECT                                                        DTSBR105
00128  ++INCLUDE DTSXLRQI                                               DTSBR105
00129      SKIP3                                                        DTSBR105
00130  01  LETTER-HEADING.                                              DTSBR105
00131      05  LTH-LINE-8.                                              DTSBR105
00132          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR105
00133          10  WS-LONG-TEXT-AREA       PIC  X(18).                  DTSBR105
00134      05  LTH-LINE-10.                                             DTSBR105
00135          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR105
00136          10  WS-AGENCY-FMT-LINE-1    PIC  X(40).                  DTSBR105
00137      05  LTH-LINE-11.                                             DTSBR105
00138          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR105
00139          10  WS-AGENCY-FMT-LINE-2    PIC  X(40).                  DTSBR105
00140      05  LTH-LINE-12.                                             DTSBR105
00141          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR105
00142          10  WS-AGENCY-FMT-LINE-3    PIC  X(40).                  DTSBR105
00143      05  LTH-LINE-13.                                             DTSBR105
00144          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR105
00145          10  WS-AGENCY-FMT-LINE-4    PIC  X(40).                  DTSBR105
00146      05  LTH-LINE-14.                                             DTSBR105
00147          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR105
00148          10  WS-AGENCY-FMT-LINE-5    PIC  X(40).                  DTSBR105
00149      05  LTH-LINE-16.                                             DTSBR105
00150          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR105
00151          10  FILLER                  PIC  X(13)                   DTSBR105
00152                 VALUE 'ACCOUNT NO:  '.                            DTSBR105
00153          10  WS-EMP-NO               PIC  999B999.                DTSBR105
00154      SKIP2                                                        DTSBR105
00155  ++INCLUDE DTSIZ105                                               DTSBR105
00156      EJECT                                                        DTSBR105
00157  LINKAGE SECTION.                                                 DTSBR105
00158      SKIP3                                                        DTSBR105
00159  01  LRCM-LINK-AREA.                                              DTSBR105
00160  ++INCLUDE DTSILRCM                                               DTSBR105
00161      EJECT                                                        DTSBR105
00162  01  R105-REC.                                                    DTSBR105
00163  ++INCLUDE DTSIR105                                               DTSBR105
00164      EJECT                                                        DTSBR105
00165  PROCEDURE DIVISION USING LRCM-LINK-AREA                          DTSBR105
00166                           R105-REC.                               DTSBR105
00167      SKIP2                                                        DTSBR105
00168      IF FIRST-TIME-IND = 'Y'                                      DTSBR105
00169          PERFORM I1000-INITIATE THRU I1000-EXIT                   DTSBR105
00170          MOVE 'N' TO FIRST-TIME-IND.                              DTSBR105
00171      SKIP1                                                        DTSBR105
00172      IF LRCM-EOR-88                                               DTSBR105
00173          PERFORM T1000-TERMINATE THRU T1000-EXIT                  DTSBR105
00174      ELSE                                                         DTSBR105
00175          PERFORM P1000-PROCESS THRU P1000-EXIT.                   DTSBR105
00176      SKIP2                                                        DTSBR105
00177      GOBACK.                                                      DTSBR105
00178      EJECT                                                        DTSBR105
00179  I1000-INITIATE.                                                  DTSBR105
00180      SKIP1                                                        DTSBR105
00181      OPEN OUTPUT PRT-FILE.                                        DTSBR105
00182      MOVE SPACES TO XEROX-REPORT.                                 DTSBR105
00183      MOVE 'RPT105R1' TO REPORT-NUMBER.                            DTSBR105
00184      WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE1                 DTSBR105
00185          AFTER ADVANCING TOP-OF-PAGE.                             DTSBR105
00186      WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE2.                DTSBR105
00187 *    WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE3.                DTSBR105
00188 *    WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE4.                DTSBR105
00189      WRITE XEROX-REPORT     FROM VSCA-LINE AFTER ADVANCING 15.    DTSBR105
00190      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE1.                DTSBR105
00191      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE2.                DTSBR105
00192      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE3.                DTSBR105
00193      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE4.                DTSBR105
00194      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE5.                DTSBR105
00195                                                                   DTSBR105
00196  I1000-EXIT.                                                      DTSBR105
00197      EXIT.                                                        DTSBR105
00198      EJECT                                                        DTSBR105
00199  P1000-PROCESS.                                                   DTSBR105
00200      SKIP1                                                        DTSBR105
00201      MOVE R105-OP-ID TO L082-OP-ID.                               DTSBR105
00202      PERFORM S082-OP-ID-INFO THRU S082-EXIT.                      DTSBR105
00203      IF L082-NOT-VALID-OP OR L082-INTERNAL-88                     DTSBR105
00204          MOVE SPACES TO WS-OPR-NAME                               DTSBR105
00205          MOVE LRCM-DEFAULT-NAME TO WS-OPR-UNIT-NAME               DTSBR105
00206          MOVE LRCM-DEFAULT-VOICE TO WS-OPR-VOICE                  DTSBR105
00207      ELSE                                                         DTSBR105
00208          MOVE L082-UNIT-NAME TO WS-OPR-UNIT-NAME                  DTSBR105
00209          MOVE L082-VOICE-1   TO WS-OPR-VOICE                      DTSBR105
00210          MOVE L082-NAME      TO L071-NAM                          DTSBR105
00211          MOVE 2              TO L071-NAME-FORMAT                  DTSBR105
00212          PERFORM S071-DESLASH-NAME THRU S071-EXIT                 DTSBR105
00213          MOVE L071-NAM       TO WS-OPR-NAME.                      DTSBR105
00214      SKIP1                                                        DTSBR105
00215      MOVE R105-MAIL-DATE TO L002-DATE.                            DTSBR105
00216      SET L002-MIXED-CASE TO TRUE.                                 DTSBR105
00217      PERFORM S002-DATE-ALPHA THRU S002-EXIT.                      DTSBR105
00218      SKIP1                                                        DTSBR105
00219      PERFORM P2000-PRINT-HEADER THRU P2000-EXIT.                  DTSBR105
00220      PERFORM P3000-PRINT-DETAIL THRU P3000-EXIT.                  DTSBR105
00221      PERFORM P4000-PRINT-FOOTER THRU P4000-EXIT.                  DTSBR105
00222      SKIP2                                                        DTSBR105
00223  P1000-EXIT.                                                      DTSBR105
00224      EXIT.                                                        DTSBR105
00225                                                                   DTSBR105
00226  P2000-PRINT-HEADER.                                              DTSBR105
00227      MOVE L002-LONG-TEXT-AREA TO WS-LONG-TEXT-AREA.               DTSBR105
00228      MOVE R105-AGENCY-FMT-LINE (1) TO WS-AGENCY-FMT-LINE-1.       DTSBR105
00229      MOVE R105-AGENCY-FMT-LINE (2) TO WS-AGENCY-FMT-LINE-2.       DTSBR105
00230      MOVE R105-AGENCY-FMT-LINE (3) TO WS-AGENCY-FMT-LINE-3.       DTSBR105
00231      MOVE R105-AGENCY-FMT-LINE (4) TO WS-AGENCY-FMT-LINE-4.       DTSBR105
00232      MOVE R105-AGENCY-FMT-LINE (5) TO WS-AGENCY-FMT-LINE-5.       DTSBR105
00233      MOVE R105-EMP-NO              TO WS-EMP-NO.                  DTSBR105
00234      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING TOP-OF-PAGEDTSBR105
00235      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING 6 LINE.    DTSBR105
00236      WRITE XEROX-REPORT FROM LTH-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR105
00237      WRITE XEROX-REPORT FROM LTH-LINE-10 AFTER ADVANCING 2 LINE.  DTSBR105
00238      WRITE XEROX-REPORT FROM LTH-LINE-11 AFTER ADVANCING 1 LINE.  DTSBR105
00239      WRITE XEROX-REPORT FROM LTH-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR105
00240      WRITE XEROX-REPORT FROM LTH-LINE-13 AFTER ADVANCING 1 LINE.  DTSBR105
00241      WRITE XEROX-REPORT FROM LTH-LINE-14 AFTER ADVANCING 1 LINE.  DTSBR105
00242      WRITE XEROX-REPORT FROM LTH-LINE-16 AFTER ADVANCING 2 LINE.  DTSBR105
00243                                                                   DTSBR105
00244  P2000-EXIT.                                                      DTSBR105
00245      EXIT.                                                        DTSBR105
00246                                                                   DTSBR105
00247  P3000-PRINT-DETAIL.                                              DTSBR105
00248      MOVE R105-FMT-LINE (1) TO WS-FMT-LINE-1.                     DTSBR105
00249      MOVE R105-FMT-LINE (2) TO WS-FMT-LINE-2.                     DTSBR105
00250      MOVE R105-FMT-LINE (3) TO WS-FMT-LINE-3.                     DTSBR105
00251      MOVE R105-FMT-LINE (4) TO WS-FMT-LINE-4.                     DTSBR105
00252      MOVE R105-FMT-LINE (5) TO WS-FMT-LINE-5.                     DTSBR105
00253      WRITE XEROX-REPORT FROM LTD-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR105
00254      WRITE XEROX-REPORT FROM LTD-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR105
00255      WRITE XEROX-REPORT FROM LTD-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR105
00256 *    WRITE XEROX-REPORT FROM LTD-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR105
00257      WRITE XEROX-REPORT FROM LTD-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR105
00258      WRITE XEROX-REPORT FROM LTD-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR105
00259      WRITE XEROX-REPORT FROM LTD-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR105
00260      WRITE XEROX-REPORT FROM LTD-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR105
00261      WRITE XEROX-REPORT FROM LTD-LINE-9 AFTER ADVANCING 1 LINE.   DTSBR105
00262      WRITE XEROX-REPORT FROM LTD-LINE-10 AFTER ADVANCING 1 LINE.  DTSBR105
00263      WRITE XEROX-REPORT FROM LTD-LINE-11 AFTER ADVANCING 1 LINE.  DTSBR105
00264      WRITE XEROX-REPORT FROM LTD-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR105
00265      WRITE XEROX-REPORT FROM LTD-LINE-13 AFTER ADVANCING 1 LINE.  DTSBR105
00266      WRITE XEROX-REPORT FROM LTD-LINE-14 AFTER ADVANCING 1 LINE.  DTSBR105
00267      WRITE XEROX-REPORT FROM LTD-LINE-15 AFTER ADVANCING 1 LINE.  DTSBR105
00268      WRITE XEROX-REPORT FROM LTD-LINE-16 AFTER ADVANCING 1 LINE.  DTSBR105
00269      WRITE XEROX-REPORT FROM LTD-LINE-17 AFTER ADVANCING 1 LINE.  DTSBR105
00270      WRITE XEROX-REPORT FROM LTD-LINE-18 AFTER ADVANCING 1 LINE.  DTSBR105
00271      WRITE XEROX-REPORT FROM LTD-LINE-19 AFTER ADVANCING 1 LINE.  DTSBR105
00272                                                                   DTSBR105
00273  P3000-EXIT.                                                      DTSBR105
00274      EXIT.                                                        DTSBR105
00275                                                                   DTSBR105
00276  P4000-PRINT-FOOTER.                                              DTSBR105
00277      MOVE WS-OPR-VOICE-1      TO WS-OPR-VOICE-ONE.                DTSBR105
00278      MOVE WS-OPR-VOICE-2      TO WS-OPR-VOICE-TWO.                DTSBR105
00279      MOVE WS-OPR-NAME         TO WS-OPR-NAME-FOOTER.              DTSBR105
00280      MOVE WS-OPR-UNIT-NAME    TO WS-OPR-UNIT-NAME-FOOTER.         DTSBR105
00281      WRITE XEROX-REPORT FROM LTF-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR105
00282      WRITE XEROX-REPORT FROM LTF-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR105
00283      WRITE XEROX-REPORT FROM LTF-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR105
00284      WRITE XEROX-REPORT FROM LTF-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR105
00285      WRITE XEROX-REPORT FROM LTF-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR105
00286      WRITE XEROX-REPORT FROM LTF-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR105
00287      WRITE XEROX-REPORT FROM LTF-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR105
00288      WRITE XEROX-REPORT FROM LTF-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR105
00289                                                                   DTSBR105
00290  P4000-EXIT.                                                      DTSBR105
00291      EXIT.                                                        DTSBR105
00292                                                                   DTSBR105
00293      EJECT                                                        DTSBR105
00294  T1000-TERMINATE.                                                 DTSBR105
00295      SKIP1                                                        DTSBR105
00296      CLOSE PRT-FILE.                                              DTSBR105
00297      SKIP2                                                        DTSBR105
00298  T1000-EXIT.                                                      DTSBR105
00299      EXIT.                                                        DTSBR105
00300      EJECT                                                        DTSBR105
00301  S002-DATE-ALPHA.                                                 DTSBR105
00302      SKIP1                                                        DTSBR105
00303      CALL 'DTSBU002' USING L002-LINK-AREA.                        DTSBR105
00304      SKIP2                                                        DTSBR105
00305  S002-EXIT.                                                       DTSBR105
00306      EXIT.                                                        DTSBR105
00307      SKIP3                                                        DTSBR105
00308  S071-DESLASH-NAME.                                               DTSBR105
00309      SKIP1                                                        DTSBR105
00310      CALL 'DTSBU071' USING L071-LINK-AREA.                        DTSBR105
00311      SKIP2                                                        DTSBR105
00312  S071-EXIT.                                                       DTSBR105
00313      EXIT.                                                        DTSBR105
00314      SKIP3                                                        DTSBR105
00315  S082-OP-ID-INFO.                                                 DTSBR105
00316      SKIP1                                                        DTSBR105
00317      CALL 'DTSBU082' USING L082-LINK-AREA.                        DTSBR105
00318      SKIP2                                                        DTSBR105
00319  S082-EXIT.                                                       DTSBR105
00320      EXIT.                                                        DTSBR105
00321      SKIP3                                                        DTSBR105
00322  S999-ABEND.                                                      DTSBR105
00323      SKIP1                                                        DTSBR105
00324      CALL 'DTSBU999' USING WRK-ABEND-CD.                          DTSBR105
00325      SKIP2                                                        DTSBR105
00326  S999-EXIT.                                                       DTSBR105
00327      EXIT.                                                        DTSBR105
00328                                                                   DTSBR105
