00001  IDENTIFICATION DIVISION.                                         12/30/05
00002  PROGRAM-ID.             DTSBR108.                                DTSBR108
00003  AUTHOR.                 TRW/TDS OUTSOURCES                          LV024
00004  DATE-WRITTEN.           JUNE 2000.                               DTSBR108
00005  DATE-COMPILED.                                                   DTSBR108
00006      SKIP3                                                        DTSBR108
00007 *****                                                             DTSBR108
00008 *                                                                 DTSBR108
00009 * CALLING SEQUENCE:  DTSBD400 CALLS                               DTSBR108
00010 *                    DTSBD312 WHICH UPDATES DTSIR108              DTSBR108
00011 *                    DTSBR108 READS DTSIR108 RECORDS.             DTSBR108
00012 *                                                                 DTSBR108
00013 *    FUNCTION:  NOT LIABLE LETTERS.                               DTSBR108
00014 *                                                                 DTSBR108
00015 *                                                                 DTSBR108
00016 *    MODIFICATION HISTORY:                                        DTSBR108
00017 *                                                                 DTSBR108
00018 * 08-01-94 INITIAL DEVELOPMENT                                    DTSBR108
00019 *          REFERENCE RFP #RAP             AUTHOR OF CHANGE - SFW  DTSBR108
00020 *                                                                 DTSBR108
00021 * 01-31-95 CHANGED PRINT LINES FOR ADDRESS AND THE PRINT LINE     DTSBR108
00022 *          AND COLUMN FOR THE DATE (L002-LONG-TEXT-AREA) FOR      DTSBR108
00023 *          BETTER PLACEMENT ON LETTERHEAD MAILED IN WINDOW        DTSBR108
00024 *          ENVELOPES.                                             DTSBR108
00025 *          REFERENCE RFP #RAP                    PROGRAMMER: MJA  DTSBR108
00026 *                                                                 DTSBR108
00027 * 02-07-95 CHANGED LINE LIMIT FROM 62 TO 60 LINES.                DTSBR108
00028 *          REFERENCE RFP # RAP                   PROGRAMMER: MJA  DTSBR108
00029 *                                                                 DTSBR108
00030 * 04-02-95 MOVED REPORT LINES DOWN TO ACCOMODATE AGENCY BLUE      DTSBR108
00031 *          LETTERHEAD AND LEFT MARGIN TWO CHARACTERS TO THE LEFT. DTSBR108
00032 *          REFERENCE RFP # TPR 15                PROGRAMMER: MJA  DTSBR108
00033 *                                                                 DTSBR108
00034 * 11/26/97 INCREASE THE LENGTH OF WS-OPR-UNIT-NAME.  REQUIRED     DTSBR108
00035 *          TO REFLECT THE JULY 1, 1997 MOVE OF UI TAX FUNCTIONS   DTSBR108
00036 *          FROM DLI TO DOR.                                       DTSBR108
00037 *                                                                 DTSBR108
00038 * 11/03/98 MODIFIED PROGRAM TO MEET TO DUTAS SPECIFICATIONS ..    DTSBR108
00039 *          SCM                                                    DTSBR108
00040 *                                                                 DTSBR108
00041 * 08-25-99 MODIFIED PROGRAM TO INCLUDE STATEMENTS FOR XEROX LASER DTSBR108
00042 *          REPORT PRINTING.                                       DTSBR108
00043 *          REFERENCE RFP #****                   PROGRAMMER: DVS  DTSBR108
00044 *                                                                 DTSBR108
00045 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR108
00046 *          XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR108
00047 *          REFERENCE RFP #****                   PROGRAMMER: XXX  DTSBR108
00048 *                                                                 DTSBR108
00049 *                                                                 DTSBR108
00050 *    DESCRIPTION:                                                 DTSBR108
00051 *                                                                 DTSBR108
00052 *        THIS MODULE PRINTS LETTERS TO FOUR DIFFERENT KINDS OF    DTSBR108
00053 *        EMPLOYERS WHO HAVE BEEN DETERMINED TO BE NOT LIABLE      DTSBR108
00054 *        (REGULAR, CHURCH, AGRICULTURAL AND DOMESTIC).            DTSBR108
00055 *                                                                 DTSBR108
00056 *                                                                 DTSBR108
00057 *    RECORDS READ:                                                DTSBR108
00058 *                                                                 DTSBR108
00059 *        NONE.                                                    DTSBR108
00060 *                                                                 DTSBR108
00061 *                                                                 DTSBR108
00062 *    PRINTED OUTPUTS:                                             DTSBR108
00063 *                                                                 DTSBR108
00064 *        108R1  NOT LIABLE LETTERS.                               DTSBR108
00065 *                                                                 DTSBR108
00066 *                                                                 DTSBR108
00067 *    RECORDS WRITTEN:                                             DTSBR108
00068 *                                                                 DTSBR108
00069 *        NONE.                                                    DTSBR108
00070 *                                                                 DTSBR108
00071 *                                                                 DTSBR108
00072 *    MODULES CALLED:                                              DTSBR108
00073 *                                                                 DTSBR108
00074 *        MACBU002  DATE ALPHA CONVERSION MODULE                   DTSBR108
00075 *        MACBU071  NAME EDIT/CONVERSION MODULE                    DTSBR108
00076 *        MACBU082  OPERATOR ID EDIT/LOOKUP MODULE                 DTSBR108
00077 *                                                                 DTSBR108
00078 *                                                                 DTSBR108
00079 *****                                                             DTSBR108
00080      EJECT                                                        DTSBR108
00081  ENVIRONMENT DIVISION.                                            DTSBR108
00082      SKIP2                                                        DTSBR108
00083  CONFIGURATION SECTION.                                           DTSBR108
00084  SPECIAL-NAMES. C01 IS TOP-OF-PAGE.                               DTSBR108
00085      SKIP1                                                        DTSBR108
00086  INPUT-OUTPUT SECTION.                                            DTSBR108
00087      SKIP1                                                        DTSBR108
00088  FILE-CONTROL.                                                    DTSBR108
00089      SELECT PRT-FILE  ASSIGN TO RPT108R1.                         DTSBR108
00090      SKIP3                                                        DTSBR108
00091  DATA DIVISION.                                                   DTSBR108
00092      SKIP3                                                        DTSBR108
00093  FILE SECTION.                                                    DTSBR108
00094      SKIP2                                                        DTSBR108
00095  FD  PRT-FILE                                                     DTSBR108
00096      RECORDING MODE IS F                                          DTSBR108
00097      BLOCK CONTAINS 0 RECORDS                                     DTSBR108
00098      LABEL RECORDS ARE OMITTED.                                   DTSBR108
00099  01  XEROX-REPORT.                                                DTSBR108
00100      05  FILLER                      PIC X(1).                    DTSBR108
00101      05  XEROX-RPT                   PIC X(132).                  DTSBR108
00102      EJECT                                                        DTSBR108
00103  WORKING-STORAGE SECTION.                                         DTSBR108
001035 77  PAN-VALET PICTURE X(24) VALUE '024DTSBR108  12/30/05'.       DTSBR108
00104      SKIP3                                                        DTSBR108
00105  01  WRK-AREA.                                                    DTSBR108
00106      05  WRK-ABEND-CD                PIC S9(04)  COMP  VALUE +108.DTSBR108
00107      05  FIRST-TIME-IND              PIC  X(01)  VALUE 'Y'.       DTSBR108
00108      05  WS-OPR-NAME                 PIC  X(32)  VALUE SPACES.    DTSBR108
00109      05  WS-OPR-UNIT-NAME            PIC  X(50)  VALUE SPACES.    DTSBR108
00110                                                                   DTSBR108
00111      05  WS-OPR-VOICE.                                            DTSBR108
00112          10  WS-OPR-VOICE-AREA       PIC X(03)  VALUE SPACES.     DTSBR108
00113          10  WS-OPR-VOICE-1          PIC X(03)  VALUE SPACES.     DTSBR108
00114          10  WS-OPR-VOICE-2          PIC X(04)  VALUE SPACES.     DTSBR108
00115          10  WS-OPR-VOICE-EXT        PIC X(04)  VALUE SPACES.     DTSBR108
00116                                                                   DTSBR108
00117  01  VSCA-LINE.                                                   DTSBR108
00118      05  VSCA-DATA                   PIC X(133) VALUE SPACES.     DTSBR108
00119                                                                   DTSBR108
00120      EJECT                                                        DTSBR108
00121  01  L002-LINK-AREA.                                              DTSBR108
00122  ++INCLUDE DTSIL002                                               DTSBR108
00123      EJECT                                                        DTSBR108
00124  01  L071-LINK-AREA.                                              DTSBR108
00125  ++INCLUDE DTSIL071                                               DTSBR108
00126      EJECT                                                        DTSBR108
00127  01  L082-LINK-AREA.                                              DTSBR108
00128  ++INCLUDE DTSIL082                                               DTSBR108
00129      EJECT                                                        DTSBR108
00130  ++INCLUDE DTSXLRQW                                               DTSBR108
00131      SKIP3                                                        DTSBR108
00132  01  LETTER-HEADING.                                              DTSBR108
00133      05  LTH-LINE-12.                                             DTSBR108
00134          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR108
00135          10  WS-LONG-TEXT-AREA       PIC  X(18).                  DTSBR108
00136      05  LTH-LINE-15.                                             DTSBR108
00137          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR108
00138          10  WS-FMT-LINE-1           PIC  X(40).                  DTSBR108
00139      05  LTH-LINE-16.                                             DTSBR108
00140          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR108
00141          10  WS-FMT-LINE-2           PIC  X(40).                  DTSBR108
00142      05  LTH-LINE-17.                                             DTSBR108
00143          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR108
00144          10  WS-FMT-LINE-3           PIC  X(40).                  DTSBR108
00145      05  LTH-LINE-18.                                             DTSBR108
00146          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR108
00147          10  WS-FMT-LINE-4           PIC  X(40).                  DTSBR108
00148      05  LTH-LINE-19.                                             DTSBR108
00149          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR108
00150          10  WS-FMT-LINE-5           PIC  X(40).                  DTSBR108
00151      05  LTH-LINE-21.                                             DTSBR108
00152          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR108
00153          10  FILLER                  PIC  X(13)                   DTSBR108
00154                 VALUE 'ACCOUNT NO:  '.                            DTSBR108
00155          10 WS-EMP-NO                PIC  999B999.                DTSBR108
00156      SKIP2                                                        DTSBR108
00157  ++INCLUDE DTSIZ108                                               DTSBR108
00158      EJECT                                                        DTSBR108
00159  LINKAGE SECTION.                                                 DTSBR108
00160      SKIP3                                                        DTSBR108
00161  01  LRCM-LINK-AREA.                                              DTSBR108
00162  ++INCLUDE DTSILRCM                                               DTSBR108
00163      EJECT                                                        DTSBR108
00164  01  R108-REC.                                                    DTSBR108
00165  ++INCLUDE DTSIR108                                               DTSBR108
00166      EJECT                                                        DTSBR108
00167  PROCEDURE DIVISION USING LRCM-LINK-AREA                          DTSBR108
00168                           R108-REC.                               DTSBR108
00169      SKIP2                                                        DTSBR108
00170      IF FIRST-TIME-IND = 'Y'                                      DTSBR108
00171          PERFORM I1000-INITIATE THRU I1000-EXIT                   DTSBR108
00172          MOVE 'N' TO FIRST-TIME-IND.                              DTSBR108
00173      SKIP1                                                        DTSBR108
00174      IF LRCM-EOR-88                                               DTSBR108
00175          PERFORM T1000-TERMINATE THRU T1000-EXIT                  DTSBR108
00176      ELSE                                                         DTSBR108
00177          PERFORM P1000-PROCESS THRU P1000-EXIT.                   DTSBR108
00178      SKIP2                                                        DTSBR108
00179      GOBACK.                                                      DTSBR108
00180      EJECT                                                        DTSBR108
00181  I1000-INITIATE.                                                  DTSBR108
00182                                                                   DTSBR108
00183      OPEN OUTPUT PRT-FILE.                                        DTSBR108
00184      MOVE SPACES TO XEROX-REPORT.                                 DTSBR108
00185                                                                   DTSBR108
00186      WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE1                 DTSBR108
00187          AFTER ADVANCING TOP-OF-PAGE.                             DTSBR108
00188                                                                   DTSBR108
00189      WRITE XEROX-REPORT     FROM VSCA-LINE                        DTSBR108
00190          AFTER ADVANCING TOP-OF-PAGE.                             DTSBR108
00191 *    WRITE XEROX-REPORT     FROM VSCA-LINE AFTER ADVANCING 8.     DTSBR108
00192 *    WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE1.                DTSBR108
00193                                                                   DTSBR108
00194  I1000-EXIT.                                                      DTSBR108
00195      EXIT.                                                        DTSBR108
00196      EJECT                                                        DTSBR108
00197  P1000-PROCESS.                                                   DTSBR108
00198      SKIP1                                                        DTSBR108
00199      MOVE R108-OP-ID TO L082-OP-ID.                               DTSBR108
00200      PERFORM S082-OP-ID-INFO THRU S082-EXIT.                      DTSBR108
00201      IF L082-NOT-VALID-OP OR L082-INTERNAL-88                     DTSBR108
00202          MOVE SPACES TO WS-OPR-NAME                               DTSBR108
00203          MOVE LRCM-DEFAULT-NAME TO WS-OPR-UNIT-NAME               DTSBR108
00204          MOVE LRCM-DEFAULT-VOICE TO WS-OPR-VOICE                  DTSBR108
00205      ELSE                                                         DTSBR108
00206          MOVE L082-VOICE-1 TO WS-OPR-VOICE                        DTSBR108
00207          MOVE L082-UNIT-NAME TO WS-OPR-UNIT-NAME                  DTSBR108
00208          MOVE L082-NAME TO L071-NAM                               DTSBR108
00209          MOVE 2 TO L071-NAME-FORMAT                               DTSBR108
00210          PERFORM S071-DESLASH-NAME THRU S071-EXIT                 DTSBR108
00211          MOVE L071-NAM TO WS-OPR-NAME.                            DTSBR108
00212      SKIP1                                                        DTSBR108
00213      MOVE R108-MAIL-DATE TO L002-DATE.                            DTSBR108
00214      SET L002-MIXED-CASE TO TRUE.                                 DTSBR108
00215      PERFORM S002-DATE-ALPHA THRU S002-EXIT.                      DTSBR108
00216      SKIP1                                                        DTSBR108
00217      PERFORM P3000-PRINT-HEADER THRU P3000-EXIT.                  DTSBR108
00218      SKIP1                                                        DTSBR108
00219      IF R108-REGULAR-88                                           DTSBR108
00220          PERFORM P4000-PRINT-REGULAR THRU P4000-EXIT              DTSBR108
00221      ELSE                                                         DTSBR108
00222      IF R108-CHURCH-88                                            DTSBR108
00223          PERFORM P5000-PRINT-CHURCH THRU P5000-EXIT               DTSBR108
00224      ELSE                                                         DTSBR108
00225          PERFORM P6000-PRINT-DOMESTIC THRU P6000-EXIT.            DTSBR108
00226      SKIP1                                                        DTSBR108
00227      PERFORM P7000-PRINT-FOOTER THRU P7000-EXIT.                  DTSBR108
00228      PERFORM P2000-SELF-MAILER-RTN THRU P2000-EXIT.               DTSBR108
00229      SKIP2                                                        DTSBR108
00230  P1000-EXIT.                                                      DTSBR108
00231      EXIT.                                                        DTSBR108
00232      EJECT                                                        DTSBR108
00233  P2000-SELF-MAILER-RTN.                                           DTSBR108
00234       MOVE R108-FMT-LINE (1) TO WS-ADDR-FMT-LINE-1.               DTSBR108
00235       MOVE R108-FMT-LINE (2) TO WS-ADDR-FMT-LINE-2.               DTSBR108
00236       MOVE R108-FMT-LINE (3) TO WS-ADDR-FMT-LINE-3.               DTSBR108
00237       MOVE R108-FMT-LINE (4) TO WS-ADDR-FMT-LINE-4.               DTSBR108
00238       MOVE R108-FMT-LINE (5) TO WS-ADDR-FMT-LINE-5.               DTSBR108
00239       PERFORM P8000-PRINT-VSCA-ADDR THRU P8000-EXIT.              DTSBR108
00240  P2000-EXIT.                                                      DTSBR108
00241      EXIT.                                                        DTSBR108
00242      EJECT                                                        DTSBR108
00243  P3000-PRINT-HEADER.                                              DTSBR108
00244      MOVE L002-LONG-TEXT-AREA TO WS-LONG-TEXT-AREA.               DTSBR108
00245      MOVE R108-FMT-LINE (1) TO WS-FMT-LINE-1.                     DTSBR108
00246      MOVE R108-FMT-LINE (2) TO WS-FMT-LINE-2.                     DTSBR108
00247      MOVE R108-FMT-LINE (3) TO WS-FMT-LINE-3.                     DTSBR108
00248      MOVE R108-FMT-LINE (4) TO WS-FMT-LINE-4.                     DTSBR108
00249      MOVE R108-FMT-LINE (5) TO WS-FMT-LINE-5.                     DTSBR108
00250      MOVE R108-EMP-NO       TO WS-EMP-NO.                         DTSBR108
00251      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING TOP-OF-PAGEDTSBR108
00252      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING 5 LINE.    DTSBR108
00253      WRITE XEROX-REPORT FROM LTH-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR108
00254      WRITE XEROX-REPORT FROM LTH-LINE-15 AFTER ADVANCING 1 LINE.  DTSBR108
00255      WRITE XEROX-REPORT FROM LTH-LINE-16 AFTER ADVANCING 1 LINE.  DTSBR108
00256      WRITE XEROX-REPORT FROM LTH-LINE-17 AFTER ADVANCING 1 LINE.  DTSBR108
00257      WRITE XEROX-REPORT FROM LTH-LINE-18 AFTER ADVANCING 1 LINE.  DTSBR108
00258      WRITE XEROX-REPORT FROM LTH-LINE-19 AFTER ADVANCING 1 LINE.  DTSBR108
00259      WRITE XEROX-REPORT FROM LTH-LINE-21 AFTER ADVANCING 2 LINE.  DTSBR108
00260                                                                   DTSBR108
00261  P3000-EXIT.                                                      DTSBR108
00262      EXIT.                                                        DTSBR108
00263                                                                   DTSBR108
00264  P4000-PRINT-REGULAR.                                             DTSBR108
00265      WRITE XEROX-REPORT FROM RED-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR108
00266      WRITE XEROX-REPORT FROM RED-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR108
00267      WRITE XEROX-REPORT FROM RED-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR108
00268 *    WRITE XEROX-REPORT FROM RED-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR108
00269      WRITE XEROX-REPORT FROM RED-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR108
00270      WRITE XEROX-REPORT FROM RED-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR108
00271      WRITE XEROX-REPORT FROM RED-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR108
00272      WRITE XEROX-REPORT FROM RED-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR108
00273                                                                   DTSBR108
00274  P4000-EXIT.                                                      DTSBR108
00275      EXIT.                                                        DTSBR108
00276                                                                   DTSBR108
00277  P5000-PRINT-CHURCH.                                              DTSBR108
00278      WRITE XEROX-REPORT FROM CHD-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR108
00279      WRITE XEROX-REPORT FROM CHD-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR108
00280      WRITE XEROX-REPORT FROM CHD-LINE-2A AFTER ADVANCING 1 LINE.  DTSBR108
00281      WRITE XEROX-REPORT FROM CHD-LINE-2B AFTER ADVANCING 1 LINE.  DTSBR108
00282      WRITE XEROX-REPORT FROM CHD-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR108
00283 *    WRITE XEROX-REPORT FROM CHD-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR108
00284      WRITE XEROX-REPORT FROM CHD-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR108
00285      WRITE XEROX-REPORT FROM CHD-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR108
00286      WRITE XEROX-REPORT FROM CHD-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR108
00287      WRITE XEROX-REPORT FROM CHD-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR108
00288      WRITE XEROX-REPORT FROM CHD-LINE-9 AFTER ADVANCING 1 LINE.   DTSBR108
00289 *    WRITE XEROX-REPORT FROM CHD-LINE-10 AFTER ADVANCING 1 LINE.  DTSBR108
00290      WRITE XEROX-REPORT FROM CHD-LINE-11 AFTER ADVANCING 1 LINE.  DTSBR108
00291      WRITE XEROX-REPORT FROM CHD-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR108
00292      WRITE XEROX-REPORT FROM CHD-LINE-13 AFTER ADVANCING 1 LINE.  DTSBR108
00293      WRITE XEROX-REPORT FROM CHD-LINE-13A AFTER ADVANCING 1 LINE. DTSBR108
00294      WRITE XEROX-REPORT FROM CHD-LINE-14 AFTER ADVANCING 1 LINE.  DTSBR108
00295      WRITE XEROX-REPORT FROM CHD-LINE-15 AFTER ADVANCING 1 LINE.  DTSBR108
00296 *    WRITE XEROX-REPORT FROM CHD-LINE-16 AFTER ADVANCING 1 LINE.  DTSBR108
00297                                                                   DTSBR108
00298  P5000-EXIT.                                                      DTSBR108
00299      EXIT.                                                        DTSBR108
00300                                                                   DTSBR108
00301  P6000-PRINT-DOMESTIC.                                            DTSBR108
00302      WRITE XEROX-REPORT FROM DOD-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR108
00303      WRITE XEROX-REPORT FROM DOD-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR108
00304      WRITE XEROX-REPORT FROM DOD-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR108
00305      WRITE XEROX-REPORT FROM DOD-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR108
00306      WRITE XEROX-REPORT FROM DOD-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR108
00307      WRITE XEROX-REPORT FROM DOD-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR108
00308      WRITE XEROX-REPORT FROM DOD-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR108
00309                                                                   DTSBR108
00310  P6000-EXIT.                                                      DTSBR108
00311      EXIT.                                                        DTSBR108
00312                                                                   DTSBR108
00313  P7000-PRINT-FOOTER.                                              DTSBR108
00314      MOVE WS-OPR-VOICE-AREA   TO WS-OPR-VOICE-AREA-CD.            DTSBR108
00315      MOVE WS-OPR-VOICE-1      TO WS-OPR-VOICE-ONE.                DTSBR108
00316      MOVE WS-OPR-VOICE-2      TO WS-OPR-VOICE-TWO.                DTSBR108
00317      MOVE WS-OPR-NAME         TO WS-OPR-NAME-FOOTER.              DTSBR108
00318      MOVE WS-OPR-UNIT-NAME    TO WS-OPR-UNIT-NAME-FOOTER.         DTSBR108
00319      WRITE XEROX-REPORT FROM LTF-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR108
00320      WRITE XEROX-REPORT FROM LTF-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR108
00321      WRITE XEROX-REPORT FROM LTF-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR108
00322 *    WRITE XEROX-REPORT FROM LTF-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR108
00323      WRITE XEROX-REPORT FROM LTF-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR108
00324 *    WRITE XEROX-REPORT FROM LTF-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR108
00325      WRITE XEROX-REPORT FROM LTF-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR108
00326      WRITE XEROX-REPORT FROM LTF-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR108
00327      WRITE XEROX-REPORT FROM LTF-LINE-9 AFTER ADVANCING 1 LINE.   DTSBR108
00328                                                                   DTSBR108
00329  P7000-EXIT.                                                      DTSBR108
00330      EXIT.                                                        DTSBR108
00331                                                                   DTSBR108
00332  P8000-PRINT-VSCA-ADDR.                                           DTSBR108
00333      WRITE XEROX-REPORT     FROM VSCA-LINE                        DTSBR108
00334          AFTER ADVANCING TOP-OF-PAGE.                             DTSBR108
00335      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING 10 LINE.   DTSBR108
00336      WRITE XEROX-REPORT FROM VSCA-ADDR-LINE-17                    DTSBR108
00337              AFTER ADVANCING 1 LINE.                              DTSBR108
00338      WRITE XEROX-REPORT FROM VSCA-ADDR-LINE-18                    DTSBR108
00339              AFTER ADVANCING 1 LINE.                              DTSBR108
00340      WRITE XEROX-REPORT FROM VSCA-ADDR-LINE-19                    DTSBR108
00341              AFTER ADVANCING 1 LINE.                              DTSBR108
00342      WRITE XEROX-REPORT FROM VSCA-ADDR-LINE-20                    DTSBR108
00343              AFTER ADVANCING 1 LINE.                              DTSBR108
00344      WRITE XEROX-REPORT FROM VSCA-ADDR-LINE-21                    DTSBR108
00345              AFTER ADVANCING 1 LINE.                              DTSBR108
00346                                                                   DTSBR108
00347  P8000-EXIT.                                                      DTSBR108
00348      EXIT.                                                        DTSBR108
00349                                                                   DTSBR108
00350  T1000-TERMINATE.                                                 DTSBR108
00351      SKIP1                                                        DTSBR108
00352      CLOSE PRT-FILE.                                              DTSBR108
00353      SKIP2                                                        DTSBR108
00354  T1000-EXIT.                                                      DTSBR108
00355      EXIT.                                                        DTSBR108
00356      EJECT                                                        DTSBR108
00357  S002-DATE-ALPHA.                                                 DTSBR108
00358      SKIP1                                                        DTSBR108
00359      CALL 'DTSBU002' USING L002-LINK-AREA.                        DTSBR108
00360      SKIP2                                                        DTSBR108
00361  S002-EXIT.                                                       DTSBR108
00362      EXIT.                                                        DTSBR108
00363      SKIP3                                                        DTSBR108
00364  S071-DESLASH-NAME.                                               DTSBR108
00365      SKIP1                                                        DTSBR108
00366      CALL 'DTSBU071' USING L071-LINK-AREA.                        DTSBR108
00367      SKIP2                                                        DTSBR108
00368  S071-EXIT.                                                       DTSBR108
00369      EXIT.                                                        DTSBR108
00370      SKIP3                                                        DTSBR108
00371  S082-OP-ID-INFO.                                                 DTSBR108
00372      SKIP1                                                        DTSBR108
00373      CALL 'DTSBU082' USING L082-LINK-AREA.                        DTSBR108
00374      SKIP2                                                        DTSBR108
00375  S082-EXIT.                                                       DTSBR108
00376      EXIT.                                                        DTSBR108
00377      SKIP3                                                        DTSBR108
00378  S999-ABEND.                                                      DTSBR108
00379      SKIP1                                                        DTSBR108
00380      CALL 'DTSBU999' USING WRK-ABEND-CD.                          DTSBR108
00381      SKIP2                                                        DTSBR108
00382  S999-EXIT.                                                       DTSBR108
00383      EXIT.                                                        DTSBR108
00384                                                                   DTSBR108
