00001  IDENTIFICATION DIVISION.                                         08/02/02
00002  PROGRAM-ID.             OJRCU607.                                OJRCU607
00003  AUTHOR.                 TRW.                                        LV001
00004  DATE-WRITTEN.           MAR 2002.                                OJRCU607
00005  DATE-COMPILED.                                                   OJRCU607
00006      SKIP3                                                        OJRCU607
00007 *****                                                             OJRCU607
00008 *                                                                 OJRCU607
00009 *    FUNCTION:  ONLINE EDIT OF PARMS FOR SUBMISSION OF 607 REPORT OJRCU607
00010 *                                                                 OJRCU607
00011 *                                                                 OJRCU607
00012 *    MODIFICATION LOG:                                            OJRCU607
00013 *                                                                 OJRCU607
00014 *    03/19/02  INITIAL DEVELOPMENT.                               OJRCU607
00015 *              WORK ORDER:                      PROGRAMMER: JMO.  OJRCU607
00016 *                                                                 OJRCU607
00017 *                                                                 OJRCU607
00018 *    MAINTENANCE NOTES:                                           OJRCU607
00019 *                                                                 OJRCU607
00020 *      REPORT INFO COMES FROM REDEFINED TABLE IN COPYBOOK         OJRCU607
00021 *                                                                 OJRCU607
00022 *****                                                             OJRCU607
00023      SKIP3                                                        OJRCU607
00024  ENVIRONMENT DIVISION.                                            OJRCU607
00025      EJECT                                                        OJRCU607
00026  DATA DIVISION.                                                   OJRCU607
00027  WORKING-STORAGE SECTION.                                         OJRCU607
000275 77  PAN-VALET PICTURE X(24) VALUE '001OJRCU607  08/02/02'.       OJRCU607
00028                                                                   OJRCU607
00029  01  WRK-AREA.                                                    OJRCU607
00030      05  ABEND-MSG                   PIC  X(60) VALUE SPACES.     OJRCU607
00031                                                                   OJRCU607
00032      05  WRK-SUB                     PIC S9(04)  COMP.            OJRCU607
00033                                                                   OJRCU607
00034      05  WRK-RESP-CD                 PIC S9(08)  COMP.            OJRCU607
00035                                                                   OJRCU607
00036      05  WRK-PARM                    PIC  X(32).                  OJRCU607
00037                                                                   OJRCU607
00038  01  L001-COMM-AREA.                                              OJRCU607
00039  ++INCLUDE DTSIL001                                               OJRCU607
00040  01  L810-COMM-AREA.                                              OJRCU607
00041      05  L810-CONTROL-BLOCK.                                      OJRCU607
00042  ++INCLUDE DTSIL810                                               OJRCU607
00043      05 MSKL-REC.                                                 OJRCU607
00044  ++INCLUDE DTSIMSKL                                               OJRCU607
00045      05 MHDR-REC.                                                 OJRCU607
00046  ++INCLUDE DTSIMHDR                                               OJRCU607
00047      EJECT                                                        OJRCU607
00048 * 607 PARM DEFINITIONS                                            OJRCU607
00049  ++INCLUDE OJRWE607                                               OJRCU607
00050      EJECT                                                        OJRCU607
00051  LINKAGE SECTION.                                                 OJRCU607
00052      SKIP3                                                        OJRCU607
00053  01  DFHCOMMAREA.                                                 OJRCU607
00054  ++INCLUDE DTSILCCM                                               OJRCU607
00055      SKIP3                                                        OJRCU607
00056 * PARM EDIT AND DATA CAPTURE AREA                                 OJRCU607
00057  ++INCLUDE OJRILCCM                                               OJRCU607
00058                                                                   OJRCU607
00059  PROCEDURE DIVISION.                                              OJRCU607
00060                                                                   OJRCU607
00061      PERFORM I0000-INITIALIZE THRU I0000-EXIT.                    OJRCU607
00062                                                                   OJRCU607
00063  MAINLINE-EXIT.                                                   OJRCU607
00064                                                                   OJRCU607
00065      EXEC CICS                                                    OJRCU607
00066          RETURN                                                   OJRCU607
00067      END-EXEC.                                                    OJRCU607
00068                                                                   OJRCU607
00069      GOBACK.                                                      OJRCU607
00070      EJECT                                                        OJRCU607
00071                                                                   OJRCU607
00072  I0000-INITIALIZE.                                                OJRCU607
00073      SET WRK-EDIT-PASSED-88 TO TRUE                               OJRCU607
00074      INITIALIZE LCCM-MSG-AREA                                     OJRCU607
00075                                                                   OJRCU607
00076      IF LCCM-GET-DEFAULTS-88                                      OJRCU607
00077         PERFORM I0100-GET-MASTER THRU I0100-EXIT                  OJRCU607
00078         IF LCCM-NO-MSG                                            OJRCU607
00079            PERFORM I0200-MOVE-FROM-MHDR THRU I0200-EXIT           OJRCU607
00080         END-IF                                                    OJRCU607
00081      ELSE                                                         OJRCU607
00082          PERFORM I0500-MOVE-FROM-LCCM THRU I0500-EXIT             OJRCU607
00083      END-IF                                                       OJRCU607
00084                                                                   OJRCU607
00085      PERFORM I1000-EDIT-AND-DEFAULT-PARMS THRU I1000-EXIT         OJRCU607
00086                                                                   OJRCU607
00087      IF WRK-EDIT-PASSED-88                                        OJRCU607
00088         PERFORM I2000-MOVE-TO-LCCM THRU I2000-EXIT                OJRCU607
00089      ELSE                                                         OJRCU607
00090          SET LCCM-MSG   TO TRUE                                   OJRCU607
00091      END-IF.                                                      OJRCU607
00092  I0000-EXIT.                                                      OJRCU607
00093      EXIT.                                                        OJRCU607
00094                                                                   OJRCU607
00095                                                                   OJRCU607
00096  I0100-GET-MASTER.                                                OJRCU607
00097      MOVE LOW-VALUES    TO MHDR-KEY-AREA                          OJRCU607
00098      MOVE +0            TO MHDR-EMP-NO                            OJRCU607
00099      SET  MHDR-HDR-88   TO TRUE                                   OJRCU607
00100      SET  L810-READ-88  TO TRUE                                   OJRCU607
00101      MOVE MHDR-KEY-AREA TO MSKL-KEY-AREA                          OJRCU607
00102      PERFORM S810-MASTER-IO THRU S810-EXIT                        OJRCU607
00103      IF L810-FILE-CLOSED-88                                       OJRCU607
00104         MOVE L810-MSG-AREA TO LCCM-MSG-AREA                       OJRCU607
00105         SET  WRK-EDIT-FAILED-88 TO TRUE                           OJRCU607
00106      ELSE                                                         OJRCU607
00107          MOVE MSKL-REC TO MHDR-REC                                OJRCU607
00108      END-IF.                                                      OJRCU607
00109  I0100-EXIT.                                                      OJRCU607
00110      EXIT.                                                        OJRCU607
00111                                                                   OJRCU607
00112  I0200-MOVE-FROM-MHDR.                                            OJRCU607
00113 *JMO ASRA   MOVE  +0  TO   OJR-PARM-COMPLETED-START-DATE,         OJRCU607
00114 *JMO                       OJR-PARM-COMPLETED-END-DATE            OJRCU607
00115                                                                   OJRCU607
00116      MOVE SPACES TO   OJR-PARM-COMPLETED-START-DATE,              OJRCU607
00117                       OJR-PARM-COMPLETED-END-DATE                 OJRCU607
00118                                                                   OJRCU607
00119      PERFORM VARYING WRK-SUB                                      OJRCU607
00120              FROM 1 BY 1                                          OJRCU607
00121              UNTIL WRK-SUB > 5                                    OJRCU607
00122                                                                   OJRCU607
00123           INITIALIZE     OJR-PARM-ASSIGN-TYPE(WRK-SUB),           OJRCU607
00124                          OJR-PARM-FLD-REP-ID(WRK-SUB)             OJRCU607
00125                                                                   OJRCU607
00126      END-PERFORM                                                  OJRCU607
00127                                                                   OJRCU607
00128      MOVE MHDR-CMPL-MONTH-BEGIN-DATE  TO  WRK-DISPLAY             OJRCU607
00129      MOVE WRK-DISPLAY(6:2)            TO  WRK-PARM(1:2)           OJRCU607
00130      MOVE WRK-DISPLAY(8:2)            TO  WRK-PARM(3:2)           OJRCU607
00131      MOVE WRK-DISPLAY(4:2)            TO  WRK-PARM(5:2)           OJRCU607
00132      MOVE WRK-PARM                    TO                          OJRCU607
00133                                  OJR-PARM-PROCESSED-START-DATE    OJRCU607
00134                                                                   OJRCU607
00135      MOVE MHDR-CMPL-MONTH-END-DATE    TO  WRK-DISPLAY             OJRCU607
00136      MOVE WRK-DISPLAY(6:2)            TO  WRK-PARM(1:2)           OJRCU607
00137      MOVE WRK-DISPLAY(8:2)            TO  WRK-PARM(3:2)           OJRCU607
00138      MOVE WRK-DISPLAY(4:2)            TO  WRK-PARM(5:2)           OJRCU607
00139      MOVE WRK-PARM                    TO                          OJRCU607
00140                                  OJR-PARM-PROCESSED-END-DATE.     OJRCU607
00141  I0200-EXIT.                                                      OJRCU607
00142      EXIT.                                                        OJRCU607
00143                                                                   OJRCU607
00144  I0500-MOVE-FROM-LCCM.                                            OJRCU607
00145      MOVE LCCM-PARM-VALUE(1) TO WRK-PARM                          OJRCU607
00146      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(1)) TO                      OJRCU607
00147           OJR-PARM-PROCESSED-START-DATE                           OJRCU607
00148                                                                   OJRCU607
00149      MOVE LCCM-PARM-VALUE(2) TO WRK-PARM                          OJRCU607
00150      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(2)) TO                      OJRCU607
00151           OJR-PARM-PROCESSED-END-DATE                             OJRCU607
00152                                                                   OJRCU607
00153      MOVE LCCM-PARM-VALUE(3) TO WRK-PARM                          OJRCU607
00154      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(3)) TO                      OJRCU607
00155           OJR-PARM-COMPLETED-START-DATE                           OJRCU607
00156                                                                   OJRCU607
00157      MOVE LCCM-PARM-VALUE(4) TO WRK-PARM                          OJRCU607
00158      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(4)) TO                      OJRCU607
00159           OJR-PARM-COMPLETED-END-DATE                             OJRCU607
00160                                                                   OJRCU607
00161      MOVE LCCM-PARM-VALUE(5) TO WRK-PARM                          OJRCU607
00162      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(5)) TO                      OJRCU607
00163           OJR-PARM-ASSIGN-TYPE(1)                                 OJRCU607
00164                                                                   OJRCU607
00165      MOVE LCCM-PARM-VALUE(6) TO WRK-PARM                          OJRCU607
00166      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(6)) TO                      OJRCU607
00167           OJR-PARM-ASSIGN-TYPE(2)                                 OJRCU607
00168                                                                   OJRCU607
00169      MOVE LCCM-PARM-VALUE(7) TO WRK-PARM                          OJRCU607
00170      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(7)) TO                      OJRCU607
00171           OJR-PARM-ASSIGN-TYPE(3)                                 OJRCU607
00172                                                                   OJRCU607
00173      MOVE LCCM-PARM-VALUE(8) TO WRK-PARM                          OJRCU607
00174      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(8)) TO                      OJRCU607
00175           OJR-PARM-ASSIGN-TYPE(4)                                 OJRCU607
00176                                                                   OJRCU607
00177      MOVE LCCM-PARM-VALUE(9) TO WRK-PARM                          OJRCU607
00178      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(9)) TO                      OJRCU607
00179           OJR-PARM-ASSIGN-TYPE(5)                                 OJRCU607
00180                                                                   OJRCU607
00181      MOVE LCCM-PARM-VALUE(10) TO WRK-PARM                         OJRCU607
00182      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(10)) TO                     OJRCU607
00183           OJR-PARM-FLD-REP-ID(1)                                  OJRCU607
00184                                                                   OJRCU607
00185      MOVE LCCM-PARM-VALUE(11) TO WRK-PARM                         OJRCU607
00186      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(11)) TO                     OJRCU607
00187           OJR-PARM-FLD-REP-ID(2)                                  OJRCU607
00188                                                                   OJRCU607
00189      MOVE LCCM-PARM-VALUE(12) TO WRK-PARM                         OJRCU607
00190      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(12)) TO                     OJRCU607
00191           OJR-PARM-FLD-REP-ID(3)                                  OJRCU607
00192                                                                   OJRCU607
00193      MOVE LCCM-PARM-VALUE(13) TO WRK-PARM                         OJRCU607
00194      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(13)) TO                     OJRCU607
00195           OJR-PARM-FLD-REP-ID(4)                                  OJRCU607
00196                                                                   OJRCU607
00197      MOVE LCCM-PARM-VALUE(14) TO WRK-PARM                         OJRCU607
00198      MOVE WRK-PARM(1:LCCM-PARM-LENGTH(14)) TO                     OJRCU607
00199           OJR-PARM-FLD-REP-ID(5).                                 OJRCU607
00200  I0500-EXIT.                                                      OJRCU607
00201      EXIT.                                                        OJRCU607
00202                                                                   OJRCU607
00203  ++INCLUDE OJRPE607                                               OJRCU607
00204                                                                   OJRCU607
00205  I2000-MOVE-TO-LCCM.                                              OJRCU607
00206      MOVE OJR-PARM-PROCESSED-START-DATE TO  LCCM-PARM-VALUE(1)    OJRCU607
00207      MOVE OJR-PARM-PROCESSED-END-DATE   TO  LCCM-PARM-VALUE(2)    OJRCU607
00208      MOVE OJR-PARM-COMPLETED-START-DATE TO  LCCM-PARM-VALUE(3)    OJRCU607
00209      MOVE OJR-PARM-COMPLETED-END-DATE   TO  LCCM-PARM-VALUE(4)    OJRCU607
00210      MOVE OJR-PARM-ASSIGN-TYPE(1)       TO  LCCM-PARM-VALUE(5)    OJRCU607
00211      MOVE OJR-PARM-ASSIGN-TYPE(2)       TO  LCCM-PARM-VALUE(6)    OJRCU607
00212      MOVE OJR-PARM-ASSIGN-TYPE(3)       TO  LCCM-PARM-VALUE(7)    OJRCU607
00213      MOVE OJR-PARM-ASSIGN-TYPE(4)       TO  LCCM-PARM-VALUE(8)    OJRCU607
00214      MOVE OJR-PARM-ASSIGN-TYPE(5)       TO  LCCM-PARM-VALUE(9)    OJRCU607
00215      MOVE OJR-PARM-FLD-REP-ID(1)        TO  LCCM-PARM-VALUE(10)   OJRCU607
00216      MOVE OJR-PARM-FLD-REP-ID(2)        TO  LCCM-PARM-VALUE(11)   OJRCU607
00217      MOVE OJR-PARM-FLD-REP-ID(3)        TO  LCCM-PARM-VALUE(12)   OJRCU607
00218      MOVE OJR-PARM-FLD-REP-ID(4)        TO  LCCM-PARM-VALUE(13)   OJRCU607
00219      MOVE OJR-PARM-FLD-REP-ID(5)        TO  LCCM-PARM-VALUE(14).  OJRCU607
00220  I2000-EXIT.                                                      OJRCU607
00221       EXIT.                                                       OJRCU607
00222                                                                   OJRCU607
00223  S001-FROM-FED-8.                                                 OJRCU607
00224      SET L001-FROM-FED-8 TO TRUE.                                 OJRCU607
00225      GO TO S001-DATE.                                             OJRCU607
00226      SKIP1                                                        OJRCU607
00227  S001-FROM-CAL-6.                                                 OJRCU607
00228      SET L001-FROM-CAL-6 TO TRUE.                                 OJRCU607
00229      GO TO S001-DATE.                                             OJRCU607
00230      SKIP1                                                        OJRCU607
00231  S001-FROM-ABS-DAY.                                               OJRCU607
00232      SET L001-FROM-ABS-DAY TO TRUE.                               OJRCU607
00233      GO TO S001-DATE.                                             OJRCU607
00234      SKIP1                                                        OJRCU607
00235  S001-DATE.                                                       OJRCU607
00236      EXEC CICS LINK                                               OJRCU607
00237          PROGRAM  ('DTSCU001')                                    OJRCU607
00238          COMMAREA (L001-COMM-AREA)                                OJRCU607
00239      END-EXEC.                                                    OJRCU607
00240  S001-EXIT.                                                       OJRCU607
00241      EXIT.                                                        OJRCU607
00242                                                                   OJRCU607
00243  S810-MASTER-IO.                                                  OJRCU607
00244      EXEC CICS LINK                                               OJRCU607
00245          PROGRAM  ('DTSCU810')                                    OJRCU607
00246          COMMAREA (L810-COMM-AREA)                                OJRCU607
00247      END-EXEC.                                                    OJRCU607
00248  S810-EXIT.                                                       OJRCU607
00249      EXIT.                                                        OJRCU607
