00001  IDENTIFICATION DIVISION.                                         08/02/02
00002  PROGRAM-ID.             OJRCU003.                                OJRCU003
00003  AUTHOR.                 TRW.                                        LV001
00004  DATE-WRITTEN.           DEC 2001.                                OJRCU003
00005  DATE-COMPILED.                                                   OJRCU003
00006      SKIP3                                                        OJRCU003
00007 *****                                                             OJRCU003
00008 *                                                                 OJRCU003
00009 *    FUNCTION:  EDIT USER ID PARMS FOR REPORT GENERATION.         OJRCU003
00010 *                                                                 OJRCU003
00011 *                                                                 OJRCU003
00012 *    MODIFICATION LOG:                                            OJRCU003
00013 *                                                                 OJRCU003
00014 *    12/16/01  INITIAL DEVELOPMENT.                               OJRCU003
00015 *              WORK ORDER:                      PROGRAMMER: JMO.  OJRCU003
00016 *                                                                 OJRCU003
00017 *    XX/XX/XX  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU003
00018 *              XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   OJRCU003
00019 *              WORK ORDER:                      PROGRAMMER: XXX   OJRCU003
00020 *                                                                 OJRCU003
00021 *                                                                 OJRCU003
00022 *  DESCRIPTION:                                                   OJRCU003
00023 *                                                                 OJRCU003
00024 *    CLEAR:                                                       OJRCU003
00025 *                                                                 OJRCU003
00026 *      DATA FIELDS DISPLAYED: NONE.                               OJRCU003
00027 *      MESSAGE: NONE                                              OJRCU003
00028 *                                                                 OJRCU003
00029 *                                                                 OJRCU003
00030 *    INQUIRY:                                                     OJRCU003
00031 *                                                                 OJRCU003
00032 *      SET DEFAULT PARM VALUES                                    OJRCU003
00033 *                                                                 OJRCU003
00034 *                                                                 OJRCU003
00035 *    UPDATE:                                                      OJRCU003
00036 *                                                                 OJRCU003
00037 *      EDIT PARMS                                                 OJRCU003
00038 *                                                                 OJRCU003
00039 *                                                                 OJRCU003
00040 *    RECORDS READ:                                                OJRCU003
00041 *                                                                 OJRCU003
00042 *      MASTER:                                                    OJRCU003
00043 *                                                                 OJRCU003
00044 *        NONE.                                                    OJRCU003
00045 *                                                                 OJRCU003
00046 *                                                                 OJRCU003
00047 *      ALTERNATE INDEX:                                           OJRCU003
00048 *                                                                 OJRCU003
00049 *        NONE.                                                    OJRCU003
00050 *                                                                 OJRCU003
00051 *                                                                 OJRCU003
00052 *      REFERENCE:                                                 OJRCU003
00053 *                                                                 OJRCU003
00054 *        NONE.                                                    OJRCU003
00055 *                                                                 OJRCU003
00056 *                                                                 OJRCU003
00057 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU003
00058 *                                                                 OJRCU003
00059 *        NONE.                                                    OJRCU003
00060 *                                                                 OJRCU003
00061 *                                                                 OJRCU003
00062 *    RECORDS UPDATED:                                             OJRCU003
00063 *                                                                 OJRCU003
00064 *      MASTER:                                                    OJRCU003
00065 *                                                                 OJRCU003
00066 *        NONE.                                                    OJRCU003
00067 *                                                                 OJRCU003
00068 *                                                                 OJRCU003
00069 *      REFERENCE:                                                 OJRCU003
00070 *                                                                 OJRCU003
00071 *        NONE                                                     OJRCU003
00072 *                                                                 OJRCU003
00073 *                                                                 OJRCU003
00074 *      ACCOUNTING TRANSACTION COLLECTION:                         OJRCU003
00075 *                                                                 OJRCU003
00076 *        NONE.                                                    OJRCU003
00077 *                                                                 OJRCU003
00078 *                                                                 OJRCU003
00079 *    ON-LINE EVENT FILE RECORDS WRITTEN:                          OJRCU003
00080 *                                                                 OJRCU003
00081 *      NONE.                                                      OJRCU003
00082 *                                                                 OJRCU003
00083 *                                                                 OJRCU003
00084 *    MODULES (OTHER THAN STANDARD SCREEN PROCESSING               OJRCU003
00085 *    UTILITY MODULES) LINKED TO:                                  OJRCU003
00086 *                                                                 OJRCU003
00087 *      DTSCU013 COUNT FROM SCREEN FORMAT/EDIT.                    OJRCU003
00088 *                                                                 OJRCU003
00089 *                                                                 OJRCU003
00090 *    MAINTENANCE NOTES:                                           OJRCU003
00091 *                                                                 OJRCU003
00092 *                                                                 OJRCU003
00093 *****                                                             OJRCU003
00094      SKIP3                                                        OJRCU003
00095  ENVIRONMENT DIVISION.                                            OJRCU003
00096      EJECT                                                        OJRCU003
00097  DATA DIVISION.                                                   OJRCU003
00098  WORKING-STORAGE SECTION.                                         OJRCU003
000985 77  PAN-VALET PICTURE X(24) VALUE '001OJRCU003  08/02/02'.       OJRCU003
00099                                                                   OJRCU003
00100  01  WRK-AREA.                                                    OJRCU003
00101      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'U003'.    OJRCU003
00102      05  WRK-RESP-CD                 PIC S9(08)  COMP.            OJRCU003
00103                                                                   OJRCU003
00104      05  WRK-MAPSET-NAME             PIC  X(08)  VALUE 'DTSMSET'. OJRCU003
00105      05  WRK-MAP-NAME.                                            OJRCU003
00106          10  WRK-MAP-NAME-PREFIX     PIC  X(04)  VALUE 'OJRM'.    OJRCU003
00107          10  WRK-MAP-NAME-SUFFIX     PIC  X(04)  VALUE '003 '.    OJRCU003
00108                                                                   OJRCU003
00109      05  WRK-F03-SCR-ID              PIC  X(02)  VALUE '80'.      OJRCU003
00110                                                                   OJRCU003
00111      05  WRK-MAX-PARMS               PIC  9(03)  COMP-3           OJRCU003
00112                                                  VALUE 16.        OJRCU003
00113                                                                   OJRCU003
00114      05  WRK-MSG-AREA                PIC  X(64) VALUE SPACES.     OJRCU003
00115                                                                   OJRCU003
00116      05  WRK-ENTER-MSG               PIC  X(64) VALUE             OJRCU003
00117          'PRESS ENTER WHEN DONE'.                                 OJRCU003
00118                                                                   OJRCU003
00119      05  WRK-PARM                    PIC  X(32).                  OJRCU003
00120                                                                   OJRCU003
00121      05  WRK-SUB                     PIC S9(04)  COMP.            OJRCU003
00122                                                                   OJRCU003
00123      05  WRK-CFKD-SUBMIT             PIC  X(09)                   OJRCU003
00124                                      VALUE 'F9=SUBMIT'.           OJRCU003
00125      EJECT                                                        OJRCU003
00126  01  SCREEN-CONTROL.                                              OJRCU003
00127      05  SCR-ACCESS-IND              PIC X(01).                   OJRCU003
00128          88  SCR-ACCESS-INQ                  VALUE '1'.           OJRCU003
00129          88  SCR-ACCESS-UPDATE               VALUE '2'.           OJRCU003
00130      SKIP1                                                        OJRCU003
00131      05  CURSOR-SET-IND              PIC X(01).                   OJRCU003
00132          88  CURSOR-SET-YES                  VALUE 'Y'.           OJRCU003
00133          88  CURSOR-SET-NO                   VALUE 'N'.           OJRCU003
00134          88  CURSOR-SET-GOTO                 VALUE 'G'.           OJRCU003
00135      SKIP1                                                        OJRCU003
00136      05  REQ-IND                     PIC X(01).                   OJRCU003
00137          88  REQ-ERROR                       VALUE 'O'.           OJRCU003
00138          88  REQ-JUMP                        VALUE 'J'.           OJRCU003
00139          88  REQ-INQUIRE                     VALUE 'I'.           OJRCU003
00140          88  REQ-CLEAR                       VALUE 'C'.           OJRCU003
00141          88  REQ-EDIT                        VALUE 'E'.           OJRCU003
00142          88  REQ-UPDATE                      VALUE 'U'.           OJRCU003
00143          88  REQ-CURSOR-TO-GOTO              VALUE 'G'.           OJRCU003
00144      SKIP1                                                        OJRCU003
00145      05  RESP-IND                    PIC X(01).                   OJRCU003
00146          88  RESP-SEND-MSGONLY               VALUE 'O'.           OJRCU003
00147          88  RESP-SEND-MAP                   VALUE 'M'.           OJRCU003
00148          88  RESP-JUMP                       VALUE 'J'.           OJRCU003
00149          88  RESP-CURSOR-TO-GOTO             VALUE 'G'.           OJRCU003
00150      SKIP1                                                        OJRCU003
00151      05  SCR-ATB-AN                  PIC  X(01).                  OJRCU003
00152      05  SCR-ATB-NUM                 PIC  X(01).                  OJRCU003
00153      EJECT                                                        OJRCU003
00154  01  L013-COMM-AREA.                                              OJRCU003
00155  ++INCLUDE DTSIL013                                               OJRCU003
00156      EJECT                                                        OJRCU003
00157 * ERROR MSG MODULE                                                OJRCU003
00158  01  L805-COMM-AREA.                                              OJRCU003
00159  ++INCLUDE DTSIL805                                               OJRCU003
00160      EJECT                                                        OJRCU003
00161 * MAP DEFINITION                                                  OJRCU003
00162  01  L851-COMM-AREA.                                              OJRCU003
00163  ++INCLUDE DTSIL851                                               OJRCU003
00164      SKIP3                                                        OJRCU003
00165      05  MAP-AREA REDEFINES L851-MAP-AREA.                        OJRCU003
00166          10 OJR-WINDOW-AREA.                                      OJRCU003
00167  ++INCLUDE OJRIS003                                               OJRCU003
00168      EJECT                                                        OJRCU003
00169 * ATTRIBUTE LITERALS                                              OJRCU003
00170  01  CATB-LITERALS.                                               OJRCU003
00171  ++INCLUDE DTSICATB                                               OJRCU003
00172      SKIP3                                                        OJRCU003
00173 * FUNCTION KEY DESCRIPTION LITERALS                               OJRCU003
00174  01  CFKD-LITERALS.                                               OJRCU003
00175  ++INCLUDE DTSICFKD                                               OJRCU003
00176      EJECT                                                        OJRCU003
00177 * ERROR CODE MESSAGE LITERALS                                     OJRCU003
00178  01  CECD-LITERALS.                                               OJRCU003
00179  ++INCLUDE DTSICECD                                               OJRCU003
00180      EJECT                                                        OJRCU003
00181  LINKAGE SECTION.                                                 OJRCU003
00182      SKIP3                                                        OJRCU003
00183  01  DFHCOMMAREA.                                                 OJRCU003
00184  ++INCLUDE DTSILCCM                                               OJRCU003
00185      SKIP3                                                        OJRCU003
00186 * PARM EDIT AND DATA CAPTURE AREA                                 OJRCU003
00187  ++INCLUDE OJRILCCM                                               OJRCU003
00188                                                                   OJRCU003
00189  PROCEDURE DIVISION.                                              OJRCU003
00190                                                                   OJRCU003
00191      MOVE LOW-VALUES TO MAP-AREA                                  OJRCU003
00192                                                                   OJRCU003
00193      MOVE SPACE TO REQ-IND                                        OJRCU003
00194                                                                   OJRCU003
00195      PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT                OJRCU003
00196      SKIP1                                                        OJRCU003
00197 *-----------------------------------------------------            OJRCU003
00198 *    P1000-ANALYZE-REQUEST HAS DETERMINED, BASED ON THE           OJRCU003
00199 *    "AID" KEY PRESSED AND THE CONTEXT OF THE CURRENT             OJRCU003
00200 *    REQUEST WITHIN THE PSEUDO CONVERSATION, THE TYPE             OJRCU003
00201 *    OF ACTIVITY THE WORK STATION OPERATOR HAS REQUESTED.         OJRCU003
00202 *                                                                 OJRCU003
00203 *    THE REQUEST, REFLECTED IN REQ-IND WILL NOW BE                OJRCU003
00204 *    PROCESSED.                                                   OJRCU003
00205 *                                                                 OJRCU003
00206 *    THE REQUEST PROCESSING PARAGRAPHS WILL SET RESP-IND,         OJRCU003
00207 *    INDICATING THE TYPE OF RESPONSE TO BE SENT TO THE            OJRCU003
00208 *    WORK STATION OPERATOR.                                       OJRCU003
00209 *-----------------------------------------------------            OJRCU003
00210      SKIP1                                                        OJRCU003
00211      INITIALIZE RESP-IND                                          OJRCU003
00212      SKIP1                                                        OJRCU003
00213      EVALUATE TRUE                                                OJRCU003
00214          WHEN REQ-ERROR                                           OJRCU003
00215              PERFORM P2000-REQUEST-ERROR THRU P2000-EXIT          OJRCU003
00216          WHEN REQ-JUMP                                            OJRCU003
00217              PERFORM P3000-REQUEST-JUMP THRU P3000-EXIT           OJRCU003
00218          WHEN REQ-CLEAR                                           OJRCU003
00219              PERFORM P4000-REQUEST-CLEAR   THRU P4000-EXIT        OJRCU003
00220          WHEN REQ-INQUIRE                                         OJRCU003
00221              PERFORM P6000-DETERMINE-REQ   THRU P6000-EXIT        OJRCU003
00222          WHEN OTHER                                               OJRCU003
00223              GO TO S899-ABEND                                     OJRCU003
00224      END-EVALUATE.                                                OJRCU003
00225      SKIP3                                                        OJRCU003
00226  MAINLINE-EXIT.                                                   OJRCU003
00227                                                                   OJRCU003
00228      EXEC CICS                                                    OJRCU003
00229          RETURN                                                   OJRCU003
00230      END-EXEC.                                                    OJRCU003
00231                                                                   OJRCU003
00232      GOBACK.                                                      OJRCU003
00233      EJECT                                                        OJRCU003
00234                                                                   OJRCU003
00235 /*****************************************************************OJRCU003
00236 * DETERMINE CURRENT SCREEN STATE AND REQUEST COMBINATION         *OJRCU003
00237 ******************************************************************OJRCU003
00238  P1000-ANALYZE-REQUEST.                                           OJRCU003
00239      SKIP1                                                        OJRCU003
00240 *-----------------------------------------------------            OJRCU003
00241 *     IF SCREEN IS NOT CURRENTLY DISPLAYED (JUMP TO HERE)         OJRCU003
00242 *     THEN ANY KEY PRESSED WILL BE IGNORED (WILL BE               OJRCU003
00243 *     REPLACED WITH ENTER)                                        OJRCU003
00244 *-----------------------------------------------------            OJRCU003
00245      IF LCCM-SEND-MAP-88                                          OJRCU003
00246         SET REQ-INQUIRE TO TRUE                                   OJRCU003
00247         GO TO P1000-EXIT                                          OJRCU003
00248      END-IF                                                       OJRCU003
00249      SKIP3                                                        OJRCU003
00250 *-----------------------------------------------------            OJRCU003
00251 *    REQUEST TO CLEAR THE SCREEN                                  OJRCU003
00252 *-----------------------------------------------------            OJRCU003
00253      IF LCCM-F12-88                                               OJRCU003
00254         MOVE LOW-VALUES   TO MAP-AREA                             OJRCU003
00255         SET REQ-CLEAR     TO TRUE                                 OJRCU003
00256         GO TO P1000-EXIT                                          OJRCU003
00257      END-IF                                                       OJRCU003
00258      SKIP3                                                        OJRCU003
00259 *-----------------------------------------------------            OJRCU003
00260 *    ALL OTHER PA KEYS ARE NOT ACTIVE                             OJRCU003
00261 *-----------------------------------------------------            OJRCU003
00262      IF LCCM-PA-88                                                OJRCU003
00263        PERFORM S804-INVALID-KEY THRU S804-EXIT                    OJRCU003
00264        SET REQ-ERROR TO TRUE                                      OJRCU003
00265        GO TO P1000-EXIT                                           OJRCU003
00266      END-IF                                                       OJRCU003
00267      SKIP3                                                        OJRCU003
00268 *-----------------------------------------------------            OJRCU003
00269 *    IF EXIT KEY PRESSED, JUMP TO NEXT HIGHER FUNCTION            OJRCU003
00270 *-----------------------------------------------------            OJRCU003
00271      IF LCCM-F03-88                                               OJRCU003
00272         MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                    OJRCU003
00273         SET REQ-JUMP TO TRUE                                      OJRCU003
00274         GO TO P1000-EXIT                                          OJRCU003
00275      END-IF                                                       OJRCU003
00276      SKIP3                                                        OJRCU003
00277 *-----------------------------------------------------            OJRCU003
00278 *    IF ENTER - PROCESS PARM UPDATES                              OJRCU003
00279 *-----------------------------------------------------            OJRCU003
00280      IF LCCM-ENTER-88                                             OJRCU003
00281          SET REQ-INQUIRE TO TRUE                                  OJRCU003
00282          GO TO P1000-EXIT                                         OJRCU003
00283      END-IF                                                       OJRCU003
00284      SKIP3                                                        OJRCU003
00285 *-----------------------------------------------------            OJRCU003
00286 *     ANY OTHER KEY IS INVALID                                    OJRCU003
00287 *-----------------------------------------------------            OJRCU003
00288      PERFORM S804-INVALID-KEY THRU S804-EXIT                      OJRCU003
00289      SET REQ-ERROR TO TRUE.                                       OJRCU003
00290  P1000-EXIT.                                                      OJRCU003
00291      EXIT.                                                        OJRCU003
00292      SKIP3                                                        OJRCU003
00293 /*****************************************************************OJRCU003
00294 * ANALYZE REQUEST HAS DETERMINED AN ERROR THAT MUST BE REPORTED. *OJRCU003
00295 * VERIFY THAT A MESSAGE HAS BEEN FILLED IN.                      *OJRCU003
00296 ******************************************************************OJRCU003
00297      SKIP1                                                        OJRCU003
00298  P2000-REQUEST-ERROR.                                             OJRCU003
00299      IF LCCM-MSG                                                  OJRCU003
00300         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU003
00301      ELSE                                                         OJRCU003
00302         GO TO S899-ABEND                                          OJRCU003
00303      END-IF.                                                      OJRCU003
00304  P2000-EXIT.                                                      OJRCU003
00305      EXIT.                                                        OJRCU003
00306 /*****************************************************************OJRCU003
00307 * JUMP TO A DIFFERENT SCREEN TYPE WAS REQUESTED                  *OJRCU003
00308 ******************************************************************OJRCU003
00309      SKIP1                                                        OJRCU003
00310  P3000-REQUEST-JUMP.                                              OJRCU003
00311 *-----------------------------------------------------            OJRCU003
00312 *    VERIFY THAT THE REQUESTED SCREEN EXISTS AND IS ACCESSIBLE    OJRCU003
00313 *    BY USER                                                      OJRCU003
00314 *-----------------------------------------------------            OJRCU003
00315      PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT                  OJRCU003
00316      SKIP3                                                        OJRCU003
00317 *-----------------------------------------------------            OJRCU003
00318 *    VERIFICATION RETURN LCCM-MSG IF ERROR DETECTED               OJRCU003
00319 *-----------------------------------------------------            OJRCU003
00320      IF LCCM-MSG                                                  OJRCU003
00321         SET RESP-SEND-MSGONLY TO TRUE                             OJRCU003
00322         SET CURSOR-SET-GOTO TO TRUE                               OJRCU003
00323         GO TO P3000-EXIT                                          OJRCU003
00324      END-IF                                                       OJRCU003
00325      SKIP3                                                        OJRCU003
00326 *-----------------------------------------------------            OJRCU003
00327 *    CLEAN UP INDICATORS AND PAGING STORAGE PRIOR TO LEAVING      OJRCU003
00328 *-----------------------------------------------------            OJRCU003
00329      MOVE LOW-VALUES TO LCCM-SCR-STATUS                           OJRCU003
00330                         LCCM-SCR-HOLD-AREA                        OJRCU003
00331      MOVE +0 TO LCCM-SCR-ABSTIME                                  OJRCU003
00332      SET RESP-JUMP TO TRUE.                                       OJRCU003
00333  P3000-EXIT.                                                      OJRCU003
00334      EXIT.                                                        OJRCU003
00335 /*****************************************************************OJRCU003
00336 * CLEAR KEY WAS PRESSED                                          *OJRCU003
00337 ******************************************************************OJRCU003
00338  P4000-REQUEST-CLEAR.                                             OJRCU003
00339      SET LCCM-SCR-CLEAR  TO TRUE                                  OJRCU003
00340      SET RESP-SEND-MAP   TO TRUE.                                 OJRCU003
00341  P4000-EXIT.                                                      OJRCU003
00342      EXIT.                                                        OJRCU003
00343      SKIP1                                                        OJRCU003
00344                                                                   OJRCU003
00345 /*****************************************************************OJRCU003
00346 * INQUIRY WAS REQUESTED                                          *OJRCU003
00347 ******************************************************************OJRCU003
00348                                                                   OJRCU003
00349  P6000-DETERMINE-REQ.                                             OJRCU003
00350      SET LCCM-END-TASK-88 TO TRUE                                 OJRCU003
00351      IF LCCM-SEND-MAP-88                                          OJRCU003
00352         PERFORM P6100-BUILD-MAP THRU P6100-EXIT                   OJRCU003
00353         PERFORM S9300-SEND-MAP  THRU S9300-EXIT                   OJRCU003
00354      ELSE                                                         OJRCU003
00355         PERFORM S9100-RECEIVE    THRU S9100-EXIT                  OJRCU003
00356         PERFORM P6200-BUILD-LCCM THRU P6200-EXIT                  OJRCU003
00357      END-IF.                                                      OJRCU003
00358  P6000-EXIT.                                                      OJRCU003
00359      EXIT.                                                        OJRCU003
00360                                                                   OJRCU003
00361  P6100-BUILD-MAP.                                                 OJRCU003
00362      INITIALIZE OJR-WINDOW-AREA                                   OJRCU003
00363      MOVE CATB-CURSOR                    TO MAP-UID-L             OJRCU003
00364      MOVE LCCM-PARM-VALUE(LCCM-PARM-SUB) TO WRK-PARM              OJRCU003
00365      MOVE WRK-PARM(1:8)                  TO MAP-UID.              OJRCU003
00366  P6100-EXIT.                                                      OJRCU003
00367      EXIT.                                                        OJRCU003
00368                                                                   OJRCU003
00369  P6200-BUILD-LCCM.                                                OJRCU003
00370      INITIALIZE WRK-PARM                                          OJRCU003
00371      MOVE MAP-UID               TO WRK-PARM(1:8)                  OJRCU003
00372      MOVE WRK-PARM              TO LCCM-PARM-VALUE(LCCM-PARM-SUB).OJRCU003
00373  P6200-EXIT.                                                      OJRCU003
00374      EXIT.                                                        OJRCU003
00375                                                                   OJRCU003
00376                                                                   OJRCU003
00377 /*****************************************************************OJRCU003
00378 * LINKS TO UTILITY MODULES                                        OJRCU003
00379 ******************************************************************OJRCU003
00380      SKIP1                                                        OJRCU003
00381  S013-SCREEN-COUNT.                                               OJRCU003
00382      EXEC CICS LINK                                               OJRCU003
00383          PROGRAM  ('DTSCU013')                                    OJRCU003
00384          COMMAREA (L013-COMM-AREA)                                OJRCU003
00385      END-EXEC.                                                    OJRCU003
00386  S013-EXIT.                                                       OJRCU003
00387      EXIT.                                                        OJRCU003
00388      EJECT                                                        OJRCU003
00389  S803-REQ-SCR-ID-EDIT.                                            OJRCU003
00390      EXEC CICS LINK                                               OJRCU003
00391          PROGRAM  ('DTSCU803')                                    OJRCU003
00392          COMMAREA (DFHCOMMAREA)                                   OJRCU003
00393      END-EXEC.                                                    OJRCU003
00394  S803-EXIT.                                                       OJRCU003
00395      EXIT.                                                        OJRCU003
00396      SKIP3                                                        OJRCU003
00397  S804-INVALID-KEY.                                                OJRCU003
00398      EXEC CICS LINK                                               OJRCU003
00399          PROGRAM  ('DTSCU804')                                    OJRCU003
00400          COMMAREA (DFHCOMMAREA)                                   OJRCU003
00401      END-EXEC.                                                    OJRCU003
00402  S804-EXIT.                                                       OJRCU003
00403      EXIT.                                                        OJRCU003
00404      SKIP3                                                        OJRCU003
00405  S851-SCREEN-PROCESSING.                                          OJRCU003
00406      IF LCCM-SEND-MAP-88                                          OJRCU003
00407         IF L851-ALARM-IND = 'N'                                   OJRCU003
00408            EXEC CICS                                              OJRCU003
00409                SEND                                               OJRCU003
00410                    MAP    (WRK-MAP-NAME)                          OJRCU003
00411                    MAPSET (WRK-MAPSET-NAME)                       OJRCU003
00412                    FROM   (OJR-WINDOW-AREA)                       OJRCU003
00413                    CURSOR                                         OJRCU003
00414                    FREEKB                                         OJRCU003
00415                    RESP   (WRK-RESP-CD)                           OJRCU003
00416            END-EXEC                                               OJRCU003
00417         ELSE                                                      OJRCU003
00418             EXEC CICS                                             OJRCU003
00419                 SEND                                              OJRCU003
00420                     MAP    (WRK-MAP-NAME)                         OJRCU003
00421                     MAPSET (WRK-MAPSET-NAME)                      OJRCU003
00422                     FROM   (OJR-WINDOW-AREA)                      OJRCU003
00423                     CURSOR                                        OJRCU003
00424                     FREEKB                                        OJRCU003
00425                     ALARM                                         OJRCU003
00426                     RESP   (WRK-RESP-CD)                          OJRCU003
00427             END-EXEC                                              OJRCU003
00428         END-IF                                                    OJRCU003
00429      ELSE                                                         OJRCU003
00430          INITIALIZE OJR-WINDOW-AREA                               OJRCU003
00431          EXEC CICS                                                OJRCU003
00432              RECEIVE                                              OJRCU003
00433                     MAP    (WRK-MAP-NAME)                         OJRCU003
00434                     MAPSET (WRK-MAPSET-NAME)                      OJRCU003
00435                     INTO   (OJR-WINDOW-AREA)                      OJRCU003
00436                     RESP   (WRK-RESP-CD)                          OJRCU003
00437          END-EXEC                                                 OJRCU003
00438 *        MOVE EIBAID TO LCCM-AID                                  OJRCU003
00439      END-IF                                                       OJRCU003
00440                                                                   OJRCU003
00441      IF WRK-RESP-CD NOT = DFHRESP(NORMAL)                         OJRCU003
00442         GO TO S899-ABEND                                          OJRCU003
00443      END-IF.                                                      OJRCU003
00444  S851-EXIT.                                                       OJRCU003
00445      EXIT.                                                        OJRCU003
00446      SKIP3                                                        OJRCU003
00447  S899-ABEND.                                                      OJRCU003
00448      EXEC CICS ABEND                                              OJRCU003
00449          ABCODE(WRK-ABEND-CD)                                     OJRCU003
00450      END-EXEC.                                                    OJRCU003
00451 *S899-EXIT.                                                       OJRCU003
00452 *    EXIT.                                                        OJRCU003
00453  S1101-ERROR.                                                     OJRCU003
00454      MOVE WRK-MSG-AREA  TO LCCM-MSG-AREA.                         OJRCU003
00455  S1101-EXIT.                                                      OJRCU003
00456      EXIT.                                                        OJRCU003
00457                                                                   OJRCU003
00458                                                                   OJRCU003
00459  S5900-SET-ATTRB.                                                 OJRCU003
00460      MOVE CATB-UNPROT-NORM-AN-MDTON      TO MAP-UID-A.            OJRCU003
00461  S5900-EXIT.                                                      OJRCU003
00462      EXIT.                                                        OJRCU003
00463                                                                   OJRCU003
00464 /*****************************************************************OJRCU003
00465 * MAP ROUTINES                                                   *OJRCU003
00466 ******************************************************************OJRCU003
00467  S9100-RECEIVE.                                                   OJRCU003
00468      SET L851-RECEIVE-88 TO TRUE.                                 OJRCU003
00469      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU003
00470  S9100-EXIT.                                                      OJRCU003
00471      EXIT.                                                        OJRCU003
00472                                                                   OJRCU003
00473  S9300-SEND-MAP.                                                  OJRCU003
00474      PERFORM S5900-SET-ATTRB THRU S5900-EXIT                      OJRCU003
00475      IF NOT LCCM-NO-MSG                                           OJRCU003
00476         MOVE 'INVALID ID'            TO MAP-MSG-TEXT              OJRCU003
00477         MOVE CATB-PROT-BRT-MDTON     TO MAP-MSG-TEXT-A            OJRCU003
00478      ELSE                                                         OJRCU003
00479          MOVE CATB-ASKIP-NORM-MDTOFF TO MAP-MSG-TEXT-A            OJRCU003
00480      END-IF                                                       OJRCU003
00481      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT                   OJRCU003
00482      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               OJRCU003
00483  S9300-EXIT.                                                      OJRCU003
00484      EXIT.                                                        OJRCU003
00485                                                                   OJRCU003
00486                                                                   OJRCU003
00487  S9900-PREPARE-SEND.                                              OJRCU003
00488      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND                     OJRCU003
00489      MOVE LCCM-MSG-TYPE     TO L851-MSG-TYPE.                     OJRCU003
00490  S9900-EXIT.                                                      OJRCU003
00491      EXIT.                                                        OJRCU003
