00001  IDENTIFICATION DIVISION.                                         01/02/06
00002  PROGRAM-ID.             DTSCS22.                                 DTSCS22
00003  AUTHOR.                 TRICOASTAL CONSULTING LTD.                  LV013
00004  DATE-WRITTEN.           NOVEMBER 1991.                           DTSCS22
00005  DATE-COMPILED.                                                   DTSCS22
00006      SKIP3                                                        DTSCS22
00007 *****                                                             DTSCS22
00008 *                                                                 DTSCS22
00009 *    FUNCTION:  BATCH CORRECTION INQUIRY SCREEN PROCESSOR.        DTSCS22
00010 *                                                                 DTSCS22
00011 *                                                                 DTSCS22
00012 *    MODIFICATION LOG:                                            DTSCS22
00013 *                                                                 DTSCS22
00014 *    05/11/95  AHDR-*-ITEM-CNT  WERE CHANGED TO  AHDR-*-TRAN-CNT. DTSCS22
00015 *              THEY NO LONGER INCLUDE THE CHECKS IN THE COUNTS.   DTSCS22
00016 *              WORK ORDER: CR076                PROGRAMMER: RHC   DTSCS22
00017 *                                                                 DTSCS22
00018 *    12/31/96  ADDED 88 LEVEL TO DTSIAHDR FOR ELECTRONIC FILER    DTSCS22
00019 *              BATCHES.  ONLY USED IN DTSBD140, SO TO SAVE MONEY  DTSCS22
00020 *              THIS PROGRAM WASN'T RECOMPILED.                    DTSCS22
00021 *              WORK ORDER:                      PROGRAMMER: MJA   DTSCS22
00022 *                                                                 DTSCS22
00023 *    01/08/1999  REVIEWED AND MODIFIED FOR DC.                    DTSCS22
00024 *                REFERENCE: DC DEVELOPMENT      PROGRAMMER: EHH   DTSCS22
00025 *                                                                 DTSCS22
00026 *    12/19/2005  RECOMPILED WITH NEW VERSION OF AHDR.             DTSCS22
00027 *                REFERENCE:                     PROGRAMMER: GD    DTSCS22
00028 *                                                                 DTSCS22
00029 *    MM/DD/YYYY  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   DTSCS22
00030 *                XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX   DTSCS22
00031 *                REFERENCE: XXXXXXXXXXXXXXX     PROGRAMMER: XXX   DTSCS22
00032 *                                                                 DTSCS22
00033 *                                                                 DTSCS22
00034 *  DESCRIPTION:                                                   DTSCS22
00035 *                                                                 DTSCS22
00036 *                                                                 DTSCS22
00037 *    CLEAR:                                                       DTSCS22
00038 *                                                                 DTSCS22
00039 *      FIELD DISPLAYED: MAP-BATCH-NO (FROM LCCM-BATCH-NO).        DTSCS22
00040 *                                                                 DTSCS22
00041 *                                                                 DTSCS22
00042 *    JUMP:                                                        DTSCS22
00043 *                                                                 DTSCS22
00044 *      STANDARD                                                   DTSCS22
00045 *                                                                 DTSCS22
00046 *                                                                 DTSCS22
00047 *    INQUIRY:                                                     DTSCS22
00048 *                                                                 DTSCS22
00049 *      CONTROL FIELDS: MAP-BATCH-NO.                              DTSCS22
00050 *                                                                 DTSCS22
00051 *      JUMP IN: IF LCCM-ITEM-NO IS NOT EQUAL TO ZERO              DTSCS22
00052 *                 START A SEARCH AT THE ACCT TRAN RECORD WHOSE    DTSCS22
00053 *                   KEY IS IN LCCM-DOC-NO                         DTSCS22
00054 *               ELSE                                              DTSCS22
00055 *               IF LCCM-BATCH-NO IS NOT EQUAL TO ZERO             DTSCS22
00056 *                 START A SEARCH AT FIRST ACCT TRAN RECORD        DTSCS22
00057 *                   IN LCCM-BATCH-NO                              DTSCS22
00058 *               ELSE                                              DTSCS22
00059 *                 CLEAR.                                          DTSCS22
00060 *                                                                 DTSCS22
00061 *      ENTER:  REDISPLAY SAME STUFF.                              DTSCS22
00062 *                                                                 DTSCS22
00063 *      F07, F08:  DO NOT BOTHER TO 'WRAP' PAGING.  'BREAK' AT     DTSCS22
00064 *                 A*-BATCH-NO.                                    DTSCS22
00065 *                                                                 DTSCS22
00066 *      JUMP OUT:  IF A LINE NO IS BEING SELECTED:                 DTSCS22
00067 *                   UPDATE LCCM-EMP-NO                            DTSCS22
00068 *                   UPDATE LCCM-DOC-NO.                           DTSCS22
00069 *                                                                 DTSCS22
00070 *      PROTECT THE 'CONTROL' FIELD (MAP-BATCH-NO DURING A SEARCH, DTSCS22
00071 *      LEAVING THE USER SPECIFIED MAP-BATCH-NO DISPLAYED.  TO     DTSCS22
00072 *      RESTART A SEARCH, THE USER MUST PRESS THE CLEAR KEY OR     DTSCS22
00073 *      THE F12 KEY.                                               DTSCS22
00074 *                                                                 DTSCS22
00075 *      STORE INFORMATION IN LCCM-SCR-HOLD-AREA TO CONTROL PAGING  DTSCS22
00076 *      AND FOR USE IN DETERMINING WHICH ACCT TRAN RECORD WAS      DTSCS22
00077 *      SELECTED FOR INQUIRY.                                      DTSCS22
00078 *                                                                 DTSCS22
00079 *      NOTE:  A AHDR RECORD WITH NO ASSOCIATED ARPT, APAY, OR     DTSCS22
00080 *             AADJ RECORDS MAY EXIST.  DTSCS22 MUST BE ABLE       DTSCS22
00081 *             TO COPE WITH THIS POSSIBILITY.                      DTSCS22
00082 *                                                                 DTSCS22
00083 *                                                                 DTSCS22
00084 *    UPDATE:                                                      DTSCS22
00085 *                                                                 DTSCS22
00086 *      NONE.                                                      DTSCS22
00087 *                                                                 DTSCS22
00088 *                                                                 DTSCS22
00089 *                                                                 DTSCS22
00090 *    RECORDS READ:                                                DTSCS22
00091 *                                                                 DTSCS22
00092 *      MASTER:                                                    DTSCS22
00093 *                                                                 DTSCS22
00094 *        NONE.                                                    DTSCS22
00095 *                                                                 DTSCS22
00096 *                                                                 DTSCS22
00097 *      ALTERNATE INDEX:                                           DTSCS22
00098 *                                                                 DTSCS22
00099 *        NONE.                                                    DTSCS22
00100 *                                                                 DTSCS22
00101 *                                                                 DTSCS22
00102 *      REFERENCE:                                                 DTSCS22
00103 *                                                                 DTSCS22
00104 *        NONE.                                                    DTSCS22
00105 *                                                                 DTSCS22
00106 *                                                                 DTSCS22
00107 *      ACCOUNTING TRANSACTION COLLECTION:                         DTSCS22
00108 *                                                                 DTSCS22
00109 *        AHDR                                                     DTSCS22
00110 *        ARPT                                                     DTSCS22
00111 *        APAY                                                     DTSCS22
00112 *        AADJ                                                     DTSCS22
00113 *                                                                 DTSCS22
00114 *                                                                 DTSCS22
00115 *    RECORDS UPDATED:                                             DTSCS22
00116 *                                                                 DTSCS22
00117 *      MASTER:                                                    DTSCS22
00118 *                                                                 DTSCS22
00119 *        NONE.                                                    DTSCS22
00120 *                                                                 DTSCS22
00121 *                                                                 DTSCS22
00122 *      REFERENCE:                                                 DTSCS22
00123 *                                                                 DTSCS22
00124 *        NONE.                                                    DTSCS22
00125 *                                                                 DTSCS22
00126 *                                                                 DTSCS22
00127 *      ACCOUNTING TRANSACTION COLLECTION:                         DTSCS22
00128 *                                                                 DTSCS22
00129 *        NONE.                                                    DTSCS22
00130 *                                                                 DTSCS22
00131 *                                                                 DTSCS22
00132 *    ON-LINE ACTIVITY FILE RECORDS WRITTEN:                       DTSCS22
00133 *                                                                 DTSCS22
00134 *      NONE.                                                      DTSCS22
00135 *                                                                 DTSCS22
00136 *                                                                 DTSCS22
00137 *    TEMPORARY STORAGE USAGE:                                     DTSCS22
00138 *                                                                 DTSCS22
00139 *      NONE.                                                      DTSCS22
00140 *                                                                 DTSCS22
00141 *                                                                 DTSCS22
00142 *    MODULES LINKED TO:                                           DTSCS22
00143 *                                                                 DTSCS22
00144 *      DTSCU013  COUNT (INTEGER) FROM SCREEN FORMAT/EDIT.         DTSCS22
00145 *      DTSCU019  DOCUMENT NO FROM SCREEN FORMAT/EDIT.             DTSCS22
00146 *      DTSCU823  ACCOUNTING TRANSACTION FILE INPUT/OUTPUT.        DTSCS22
00147 *                                                                 DTSCS22
00148 *****                                                             DTSCS22
00149      EJECT                                                        DTSCS22
00150  ENVIRONMENT DIVISION.                                            DTSCS22
00151                                                                   DTSCS22
00152  DATA DIVISION.                                                   DTSCS22
00153                                                                   DTSCS22
00154  WORKING-STORAGE SECTION.                                         DTSCS22
001545 77  PAN-VALET PICTURE X(24) VALUE '013DTSCS22   01/02/06'.       DTSCS22
00155                                                                   DTSCS22
00156  01  WRK-HOLD-AREA.                                               DTSCS22
00157      05  WRK-HOLD-SCREEN-22-IND          PIC  X(02).              DTSCS22
00158          88  WRK-HOLD-SCREEN-22-YES    VALUE '22'.                DTSCS22
00159                                                                   DTSCS22
00160                                                                   DTSCS22
00161      05  WRK-HOLD-CTR                    PIC S9(04) COMP.         DTSCS22
00162                                                                   DTSCS22
00163                                                                   DTSCS22
00164      05  WRK-HOLD-KEY-AREA               PIC  X(87).              DTSCS22
00165                                                                   DTSCS22
00166      05  FILLER REDEFINES WRK-HOLD-KEY-AREA.                      DTSCS22
00167          10  WRK-HOLD-BATCH-NO           PIC S9(05) COMP-3.       DTSCS22
00168          10  WRK-HOLD-KEY OCCURS 12 TIMES.                        DTSCS22
00169              15  WRK-HOLD-ITEM-NO        PIC S9(03) COMP-3.       DTSCS22
00170              15  WRK-HOLD-EMP-NO         PIC S9(07) COMP-3.       DTSCS22
00171              15  WRK-HOLD-REC-TYPE       PIC  X(01).              DTSCS22
00172                                                                   DTSCS22
00173                                                                   DTSCS22
00174                                                                   DTSCS22
00175  01  WRK-AREA.                                                    DTSCS22
00176      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'S22 '.    DTSCS22
00177                                                                   DTSCS22
00178      05  WRK-SCR-ID.                                              DTSCS22
00179          10  WRK-SCR-ID-N            PIC  9(02)  VALUE 22.        DTSCS22
00180                                                                   DTSCS22
00181      05  WRK-F03-SCR-ID              PIC  X(02)  VALUE '20'.      DTSCS22
00182                                                                   DTSCS22
00183      05  SCR-ACCESS-IND              PIC X(01).                   DTSCS22
00184          88  SCR-ACCESS-INQ                  VALUE '1'.           DTSCS22
00185          88  SCR-ACCESS-UPDATE               VALUE '2'.           DTSCS22
00186                                                                   DTSCS22
00187      05  CURSOR-SET-IND              PIC X(01).                   DTSCS22
00188          88  CURSOR-SET-YES                  VALUE 'Y'.           DTSCS22
00189          88  CURSOR-SET-NO                   VALUE 'N'.           DTSCS22
00190          88  CURSOR-SET-GOTO                 VALUE 'G'.           DTSCS22
00191                                                                   DTSCS22
00192      05  REQ-IND                     PIC X(01).                   DTSCS22
00193          88  REQ-CURSOR-TO-GOTO              VALUE 'G'.           DTSCS22
00194          88  REQ-ERROR                       VALUE 'O'.           DTSCS22
00195          88  REQ-JUMP                        VALUE 'J'.           DTSCS22
00196          88  REQ-UPDATE                      VALUE 'U'.           DTSCS22
00197          88  REQ-INQUIRE                     VALUE 'I'.           DTSCS22
00198          88  REQ-CLEAR                       VALUE 'C'.           DTSCS22
00199          88  REQ-EDIT                        VALUE 'E'.           DTSCS22
00200                                                                   DTSCS22
00201      05  RESP-IND                    PIC X(01).                   DTSCS22
00202          88  RESP-SEND-MSGONLY               VALUE 'O'.           DTSCS22
00203          88  RESP-SEND-MAP                   VALUE 'M'.           DTSCS22
00204          88  RESP-JUMP                       VALUE 'J'.           DTSCS22
00205          88  RESP-CURSOR-TO-GOTO             VALUE 'G'.           DTSCS22
00206                                                                   DTSCS22
00207      05  WRK-MSG-AREA                PIC  X(64).                  DTSCS22
00208                                                                   DTSCS22
00209      05  WRK-BATCH-NO                PIC  9(05) COMP-3.           DTSCS22
00210                                                                   DTSCS22
00211      05  WRK-ITEM-NO                 PIC  9(03) COMP-3.           DTSCS22
00212                                                                   DTSCS22
00213      05  WRK-ATB-AN                  PIC  X(01).                  DTSCS22
00214                                                                   DTSCS22
00215      05  WRK-ATB-NUM                 PIC  X(01).                  DTSCS22
00216                                                                   DTSCS22
00217      05  WRK-HOLD-FOUND-IND          PIC  X(01).                  DTSCS22
00218          88  WRK-HOLD-FOUND-YES      VALUE 'Y'.                   DTSCS22
00219          88  WRK-HOLD-FOUND-NO       VALUE 'N'.                   DTSCS22
00220                                                                   DTSCS22
00221      05  WRK-CTR                     PIC S9(04)  COMP.            DTSCS22
00222                                                                   DTSCS22
00223      05  WRK-CTR2                    PIC S9(04)  COMP.            DTSCS22
00224                                                                   DTSCS22
00225      05  WRK-SUB                     PIC S9(04)  COMP.            DTSCS22
00226                                                                   DTSCS22
00227      05  WRK-TRAN-CNT                PIC S9(03) COMP-3.           DTSCS22
00228      EJECT                                                        DTSCS22
00229 *01  MSG-LITERALS.                                                DTSCS22
00230                                                                   DTSCS22
00231 *****05  MSG-E221-AREA.                                           DTSCS22
00232 *********10  FILLER                  PIC  X(04)  VALUE 'E221'.    DTSCS22
00233 *********10  FILLER                  PIC  X(30)                   DTSCS22
00234 ***************VALUE 'UPDATES TO THIS BATCH ARE ACTI'.            DTSCS22
00235 *********10  FILLER                  PIC  X(30)                   DTSCS22
00236 ***************VALUE 'VE. CLEAR AND TRY AGAIN.      '.            DTSCS22
00237      EJECT                                                        DTSCS22
00238  01  L001-COMM-AREA.                                              DTSCS22
00239  ++INCLUDE DTSIL001                                               DTSCS22
00240      EJECT                                                        DTSCS22
00241  01  L013-COMM-AREA.                                              DTSCS22
00242  ++INCLUDE DTSIL013                                               DTSCS22
00243      EJECT                                                        DTSCS22
00244  01  L019-COMM-AREA.                                              DTSCS22
00245  ++INCLUDE DTSIL019                                               DTSCS22
00246      EJECT                                                        DTSCS22
00247  01  L805-COMM-AREA.                                              DTSCS22
00248  ++INCLUDE DTSIL805                                               DTSCS22
00249      EJECT                                                        DTSCS22
00250  01  L823-COMM-AREA.                                              DTSCS22
00251      05  L823-CONTROL-BLOCK.                                      DTSCS22
00252  ++INCLUDE DTSIL823                                               DTSCS22
00253      EJECT                                                        DTSCS22
00254      05  ASKL-REC.                                                DTSCS22
00255  ++INCLUDE DTSIASKL                                               DTSCS22
00256      EJECT                                                        DTSCS22
00257  01  AHDR-REC.                                                    DTSCS22
00258  ++INCLUDE DTSIAHDR                                               DTSCS22
00259      EJECT                                                        DTSCS22
00260  01  AADJ-REC.                                                    DTSCS22
00261  ++INCLUDE DTSIAADJ                                               DTSCS22
00262      EJECT                                                        DTSCS22
00263  01  APAY-REC.                                                    DTSCS22
00264  ++INCLUDE DTSIAPAY                                               DTSCS22
00265      EJECT                                                        DTSCS22
00266  01  ARPT-REC.                                                    DTSCS22
00267  ++INCLUDE DTSIARPT                                               DTSCS22
00268      EJECT                                                        DTSCS22
00269  01  AATX-REC.                                                    DTSCS22
00270  ++INCLUDE DTSIAATX                                               DTSCS22
00271      EJECT                                                        DTSCS22
00272  01  L851-COMM-AREA.                                              DTSCS22
00273  ++INCLUDE DTSIL851                                               DTSCS22
00274                                                                   DTSCS22
00275      05  MAP-AREA REDEFINES L851-MAP-AREA.                        DTSCS22
00276  ++INCLUDE DTSIS22                                                DTSCS22
00277      EJECT                                                        DTSCS22
00278  01  CATB-LITERALS.                                               DTSCS22
00279  ++INCLUDE DTSICATB                                               DTSCS22
00280                                                                   DTSCS22
00281                                                                   DTSCS22
00282                                                                   DTSCS22
00283  01  CFKD-LITERALS.                                               DTSCS22
00284  ++INCLUDE DTSICFKD                                               DTSCS22
00285                                                                   DTSCS22
00286                                                                   DTSCS22
00287                                                                   DTSCS22
00288  01  CECD-LITERALS.                                               DTSCS22
00289  ++INCLUDE DTSICECD                                               DTSCS22
00290                                                                   DTSCS22
00291                                                                   DTSCS22
00292                                                                   DTSCS22
00293  01  CPCD-LITERALS.                                               DTSCS22
00294  ++INCLUDE DTSICPCD                                               DTSCS22
00295      EJECT                                                        DTSCS22
00296  LINKAGE SECTION.                                                 DTSCS22
00297                                                                   DTSCS22
00298  01  DFHCOMMAREA.                                                 DTSCS22
00299  ++INCLUDE DTSILCCM                                               DTSCS22
00300      EJECT                                                        DTSCS22
00301 ******************************************************************DTSCS22
00302 *                                                                *DTSCS22
00303 ******************************************************************DTSCS22
00304                                                                   DTSCS22
00305  PROCEDURE DIVISION.                                              DTSCS22
00306                                                                   DTSCS22
00307                                                                   DTSCS22
00308      MOVE +0 TO WRK-BATCH-NO.                                     DTSCS22
00309                                                                   DTSCS22
00310      MOVE +0 TO WRK-ITEM-NO.                                      DTSCS22
00311                                                                   DTSCS22
00312      MOVE +0 TO WRK-HOLD-CTR.                                     DTSCS22
00313                                                                   DTSCS22
00314      MOVE LOW-VALUES      TO MAP-AREA.                            DTSCS22
00315                                                                   DTSCS22
00316      SET CURSOR-SET-NO    TO TRUE.                                DTSCS22
00317                                                                   DTSCS22
00318      MOVE LCCM-SCR-NUM-ACCESS-IND (WRK-SCR-ID-N)                  DTSCS22
00319        TO SCR-ACCESS-IND.                                         DTSCS22
00320                                                                   DTSCS22
00321                                                                   DTSCS22
00322      MOVE SPACE TO REQ-IND.                                       DTSCS22
00323                                                                   DTSCS22
00324      PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT.               DTSCS22
00325                                                                   DTSCS22
00326                                                                   DTSCS22
00327 *-----------------------------------------------------            DTSCS22
00328 *    P1000-ANALYZE-REQUEST HAS DETERMINED, BASED ON THE           DTSCS22
00329 *    "AID" KEY PRESSED AND THE CONTEXT OF THE CURRENT             DTSCS22
00330 *    REQUEST WITHIN THE PSEUDO CONVERSATION, THE TYPE             DTSCS22
00331 *    OF ACTIVITY THE WORK STATION OPERATOR HAS REQUESTED.         DTSCS22
00332 *                                                                 DTSCS22
00333 *    THE REQUEST, REFLECTED IN REQ-IND WILL NOW BE                DTSCS22
00334 *    PROCESSED.                                                   DTSCS22
00335 *                                                                 DTSCS22
00336 *    THE REQUEST PROCESSING PARAGRAPHS WILL SET RESP-IND,         DTSCS22
00337 *    INDICATING THE TYPE OF RESPONSE TO BE SENT TO THE            DTSCS22
00338 *    WORK STATION OPERATOR.                                       DTSCS22
00339 *-----------------------------------------------------            DTSCS22
00340                                                                   DTSCS22
00341      MOVE SPACE TO RESP-IND.                                      DTSCS22
00342                                                                   DTSCS22
00343      IF REQ-ERROR                                                 DTSCS22
00344         PERFORM P2000-REQUEST-ERROR THRU P2000-EXIT               DTSCS22
00345      ELSE                                                         DTSCS22
00346      IF REQ-JUMP                                                  DTSCS22
00347         PERFORM P3000-REQUEST-JUMP THRU P3000-EXIT                DTSCS22
00348      ELSE                                                         DTSCS22
00349      IF REQ-CLEAR                                                 DTSCS22
00350         PERFORM P4000-REQUEST-CLEAR THRU P4000-EXIT               DTSCS22
00351      ELSE                                                         DTSCS22
00352      IF REQ-CURSOR-TO-GOTO                                        DTSCS22
00353         PERFORM P5000-CURSOR-TO-GOTO THRU P5000-EXIT              DTSCS22
00354      ELSE                                                         DTSCS22
00355      IF REQ-INQUIRE                                               DTSCS22
00356         PERFORM P6000-REQUEST-INQUIRE THRU P6000-EXIT             DTSCS22
00357      ELSE                                                         DTSCS22
00358         GO TO S899-ABEND.                                         DTSCS22
00359                                                                   DTSCS22
00360                                                                   DTSCS22
00361 *-----------------------------------------------------            DTSCS22
00362 *    THE REQUEST PROCESSING PARAGRAPHS HAVE INDICATED             DTSCS22
00363 *    IN RESP-IND THE TYPE OF RESPONSE TO BE MADE.                 DTSCS22
00364 *-----------------------------------------------------            DTSCS22
00365                                                                   DTSCS22
00366      IF RESP-SEND-MAP                                             DTSCS22
00367          PERFORM S9300-SEND-MAP THRU S9300-EXIT                   DTSCS22
00368          SET LCCM-END-TASK-88 TO TRUE                             DTSCS22
00369      ELSE                                                         DTSCS22
00370      IF RESP-SEND-MSGONLY                                         DTSCS22
00371          PERFORM S9200-SEND-DATAONLY THRU S9200-EXIT              DTSCS22
00372          SET LCCM-END-TASK-88 TO TRUE                             DTSCS22
00373      ELSE                                                         DTSCS22
00374      IF RESP-JUMP                                                 DTSCS22
00375          SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS22
00376      ELSE                                                         DTSCS22
00377      IF RESP-CURSOR-TO-GOTO                                       DTSCS22
00378          PERFORM S9200-SEND-DATAONLY THRU S9200-EXIT              DTSCS22
00379          SET LCCM-END-TASK-88 TO TRUE                             DTSCS22
00380      ELSE                                                         DTSCS22
00381          GO TO S899-ABEND.                                        DTSCS22
00382                                                                   DTSCS22
00383                                                                   DTSCS22
00384  MAINLINE-EXIT.                                                   DTSCS22
00385                                                                   DTSCS22
00386                                                                   DTSCS22
00387      EXEC CICS                                                    DTSCS22
00388          RETURN                                                   DTSCS22
00389      END-EXEC.                                                    DTSCS22
00390                                                                   DTSCS22
00391                                                                   DTSCS22
00392      GOBACK.                                                      DTSCS22
00393 /*****************************************************************DTSCS22
00394 * DETERMINE CURRENT SCREEN STATE AND REQUEST COMBINATION         *DTSCS22
00395 ******************************************************************DTSCS22
00396                                                                   DTSCS22
00397  P1000-ANALYZE-REQUEST.                                           DTSCS22
00398                                                                   DTSCS22
00399 *-----------------------------------------------------            DTSCS22
00400 *     IF SCREEN IS NOT CURRENTLY DISPLAYED (JUMP TO HERE)         DTSCS22
00401 *     THEN ANY KEY PRESSED WILL BE IGNORED (WILL BE               DTSCS22
00402 *     REPLACED WITH ENTER)                                        DTSCS22
00403 *     ASSUME THAT ITEM-NO IS IN SYNC WITH BATCH-NO                DTSCS22
00404 *-----------------------------------------------------            DTSCS22
00405                                                                   DTSCS22
00406      IF LCCM-SCR-ID NOT = WRK-SCR-ID                              DTSCS22
00407         MOVE LOW-VALUES TO LCCM-SCR-HOLD-AREA                     DTSCS22
00408         SET LCCM-ENTER-88 TO TRUE                                 DTSCS22
00409         IF LCCM-BATCH-NO = 0                                      DTSCS22
00410            MOVE +0 TO LCCM-ITEM-NO                                DTSCS22
00411                       WRK-ITEM-NO                                 DTSCS22
00412                       WRK-BATCH-NO                                DTSCS22
00413            SET REQ-CLEAR TO TRUE                                  DTSCS22
00414         ELSE                                                      DTSCS22
00415            MOVE +1 TO WRK-HOLD-CTR                                DTSCS22
00416            MOVE LCCM-BATCH-NO TO WRK-BATCH-NO                     DTSCS22
00417            MOVE LCCM-BATCH-NO TO MAP-BATCH-NO-N                   DTSCS22
00418                                  WRK-HOLD-BATCH-NO                DTSCS22
00419            IF LCCM-ITEM-NO = +0                                   DTSCS22
00420               MOVE +0 TO WRK-HOLD-ITEM-NO (1)                     DTSCS22
00421               SET REQ-INQUIRE TO TRUE                             DTSCS22
00422            ELSE                                                   DTSCS22
00423               MOVE LCCM-ITEM-NO TO WRK-HOLD-ITEM-NO (1)           DTSCS22
00424               SET REQ-INQUIRE TO TRUE                             DTSCS22
00425            END-IF                                                 DTSCS22
00426         END-IF                                                    DTSCS22
00427         GO TO P1000-EXIT.                                         DTSCS22
00428                                                                   DTSCS22
00429                                                                   DTSCS22
00430 *-----------------------------------------------------            DTSCS22
00431 *  RECOVER INFORMATION FROM PREVIOUS INQUIRE                      DTSCS22
00432 *-----------------------------------------------------            DTSCS22
00433                                                                   DTSCS22
00434      MOVE LCCM-SCR-HOLD-AREA TO WRK-HOLD-AREA.                    DTSCS22
00435                                                                   DTSCS22
00436      IF WRK-HOLD-SCREEN-22-YES                                    DTSCS22
00437         SET WRK-HOLD-FOUND-YES TO TRUE                            DTSCS22
00438         MOVE WRK-HOLD-BATCH-NO TO WRK-BATCH-NO                    DTSCS22
00439      ELSE                                                         DTSCS22
00440         MOVE +0 TO WRK-HOLD-CTR                                   DTSCS22
00441         SET WRK-HOLD-FOUND-NO TO TRUE.                            DTSCS22
00442                                                                   DTSCS22
00443                                                                   DTSCS22
00444 *-----------------------------------------------------            DTSCS22
00445 *      MAP IS RECEIVED                                            DTSCS22
00446 *-----------------------------------------------------            DTSCS22
00447                                                                   DTSCS22
00448      PERFORM S9100-RECEIVE THRU S9100-EXIT.                       DTSCS22
00449                                                                   DTSCS22
00450                                                                   DTSCS22
00451 *-----------------------------------------------------            DTSCS22
00452 *    CHECK FOR AID KEYS THAT DO NOT SEND DATA FROM THE            DTSCS22
00453 *    WORK STATION                                                 DTSCS22
00454 *-----------------------------------------------------            DTSCS22
00455                                                                   DTSCS22
00456      IF LCCM-CLEAR-88                                             DTSCS22
00457         SET REQ-CLEAR TO TRUE                                     DTSCS22
00458         GO TO P1000-EXIT.                                         DTSCS22
00459                                                                   DTSCS22
00460                                                                   DTSCS22
00461 *-----------------------------------------------------            DTSCS22
00462 *    PA2 IS A REQUEST TO POSITION CURSOR AT GO TO:                DTSCS22
00463 *-----------------------------------------------------            DTSCS22
00464                                                                   DTSCS22
00465      IF LCCM-PA2-88                                               DTSCS22
00466          SET REQ-CURSOR-TO-GOTO TO TRUE                           DTSCS22
00467          GO TO P1000-EXIT.                                        DTSCS22
00468                                                                   DTSCS22
00469                                                                   DTSCS22
00470 *-----------------------------------------------------            DTSCS22
00471 *    ALL OTHER PA KEYS ARE NOT ACTIVE                             DTSCS22
00472 *-----------------------------------------------------            DTSCS22
00473                                                                   DTSCS22
00474      IF LCCM-PA-88                                                DTSCS22
00475        PERFORM S804-INVALID-KEY THRU S804-EXIT                    DTSCS22
00476        SET REQ-ERROR TO TRUE                                      DTSCS22
00477        GO TO P1000-EXIT.                                          DTSCS22
00478                                                                   DTSCS22
00479                                                                   DTSCS22
00480 *-----------------------------------------------------            DTSCS22
00481 *    F12 IS TREATED AS A "CLEAR".                                 DTSCS22
00482 *-----------------------------------------------------            DTSCS22
00483                                                                   DTSCS22
00484      IF LCCM-F12-88                                               DTSCS22
00485         MOVE LOW-VALUES TO MAP-AREA                               DTSCS22
00486         SET REQ-CLEAR TO TRUE                                     DTSCS22
00487         GO TO P1000-EXIT.                                         DTSCS22
00488                                                                   DTSCS22
00489                                                                   DTSCS22
00490 *-----------------------------------------------------            DTSCS22
00491 *    IF EXIT KEY PRESSED, GO TO THE NEXT HIGHER LEVEL             DTSCS22
00492 *-----------------------------------------------------            DTSCS22
00493                                                                   DTSCS22
00494      IF LCCM-F03-88                                               DTSCS22
00495         MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                    DTSCS22
00496         SET REQ-JUMP TO TRUE                                      DTSCS22
00497         GO TO P1000-EXIT.                                         DTSCS22
00498                                                                   DTSCS22
00499                                                                   DTSCS22
00500 *-----------------------------------------------------            DTSCS22
00501 *    IF PRIOR SCREEN KEY PRESSED, JUMP TO PREVIOUS SCREEN         DTSCS22
00502 *-----------------------------------------------------            DTSCS22
00503                                                                   DTSCS22
00504      IF LCCM-F04-88                                               DTSCS22
00505         MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID                 DTSCS22
00506         SET REQ-JUMP TO TRUE                                      DTSCS22
00507         GO TO P1000-EXIT.                                         DTSCS22
00508                                                                   DTSCS22
00509                                                                   DTSCS22
00510 *---------------------------------------------------------        DTSCS22
00511 *    IF CORRESPONDENCE SCREEN KEY PRESSED, JUMP TO                DTSCS22
00512 *    CORRESPONDENCE SCREEN.                                       DTSCS22
00513 *---------------------------------------------------------        DTSCS22
00514                                                                   DTSCS22
00515      IF LCCM-F14-88                                               DTSCS22
00516         MOVE LCCM-CORR-SCR-ID TO LCCM-REQ-SCR-ID                  DTSCS22
00517         SET REQ-JUMP TO TRUE                                      DTSCS22
00518         GO TO P1000-EXIT.                                         DTSCS22
00519                                                                   DTSCS22
00520                                                                   DTSCS22
00521 *-----------------------------------------------------            DTSCS22
00522 *    IF DIFFERENT SCREEN TYPE IS REQUESTED, JUMP TO               DTSCS22
00523 *    REQUESTED SCREEN TYPE                                        DTSCS22
00524 *-----------------------------------------------------            DTSCS22
00525                                                                   DTSCS22
00526      IF MAP-GOTO = SPACES OR LOW-VALUES OR WRK-SCR-ID             DTSCS22
00527         NEXT SENTENCE                                             DTSCS22
00528      ELSE                                                         DTSCS22
00529         MOVE MAP-GOTO TO LCCM-REQ-SCR-ID                          DTSCS22
00530         SET REQ-JUMP TO TRUE                                      DTSCS22
00531         GO TO P1000-EXIT.                                         DTSCS22
00532                                                                   DTSCS22
00533                                                                   DTSCS22
00534 *-----------------------------------------------------            DTSCS22
00535 *    A LINE OF DETAIL WAS SELECTED WHICH MEANS TO JUMP            DTSCS22
00536 *-----------------------------------------------------            DTSCS22
00537                                                                   DTSCS22
00538      MOVE MAP-SELECT-LINE-NO-AREA TO L013-S-CNT-AREA.             DTSCS22
00539                                                                   DTSCS22
00540      PERFORM S013-COUNT-FROM-SCREEN THRU S013-EXIT.               DTSCS22
00541                                                                   DTSCS22
00542      IF L013-NO-ENTRY                                             DTSCS22
00543         NEXT SENTENCE                                             DTSCS22
00544      ELSE                                                         DTSCS22
00545         SET REQ-JUMP TO TRUE                                      DTSCS22
00546         GO TO P1000-EXIT.                                         DTSCS22
00547                                                                   DTSCS22
00548                                                                   DTSCS22
00549 *-----------------------------------------------------            DTSCS22
00550 *    IF INQUIRY TYPE KEY PRESSED (ENTER, F7, OR F8),              DTSCS22
00551 *    INDICATES INQUIRY REQUEST                                    DTSCS22
00552 *-----------------------------------------------------            DTSCS22
00553                                                                   DTSCS22
00554      IF LCCM-ENTER-88                                             DTSCS22
00555            OR LCCM-F07-88                                         DTSCS22
00556            OR LCCM-F08-88                                         DTSCS22
00557          SET REQ-INQUIRE TO TRUE                                  DTSCS22
00558          GO TO P1000-EXIT.                                        DTSCS22
00559                                                                   DTSCS22
00560                                                                   DTSCS22
00561 *-----------------------------------------------------            DTSCS22
00562 *     ANY OTHER KEY IS INVALID                                    DTSCS22
00563 *-----------------------------------------------------            DTSCS22
00564                                                                   DTSCS22
00565      PERFORM S804-INVALID-KEY THRU S804-EXIT.                     DTSCS22
00566                                                                   DTSCS22
00567      SET REQ-ERROR TO TRUE.                                       DTSCS22
00568  P1000-EXIT.                                                      DTSCS22
00569      EXIT.                                                        DTSCS22
00570 /*****************************************************************DTSCS22
00571 * ANALYZE REQUEST HAS DETERMINED AN ERROR THAT MUST BE REPORTED. *DTSCS22
00572 * VERIFY THAT A MESSAGE HAS BEEN FILLED IN.                      *DTSCS22
00573 ******************************************************************DTSCS22
00574                                                                   DTSCS22
00575  P2000-REQUEST-ERROR.                                             DTSCS22
00576      IF LCCM-MSG                                                  DTSCS22
00577         SET RESP-SEND-MSGONLY TO TRUE                             DTSCS22
00578      ELSE                                                         DTSCS22
00579         GO TO S899-ABEND.                                         DTSCS22
00580  P2000-EXIT.                                                      DTSCS22
00581      EXIT.                                                        DTSCS22
00582 /*****************************************************************DTSCS22
00583 * JUMP TO A DIFFERENT SCREEN TYPE WAS REQUESTED                  *DTSCS22
00584 ******************************************************************DTSCS22
00585                                                                   DTSCS22
00586  P3000-REQUEST-JUMP.                                              DTSCS22
00587      PERFORM P3001-SELECTION-LINE-EDIT THRU P3001-EXIT            DTSCS22
00588                                                                   DTSCS22
00589                                                                   DTSCS22
00590 *-----------------------------------------------------            DTSCS22
00591 *    VERIFY THAT THE REQUESTED SCREEN EXISTS AND IS ACCESSIBLE    DTSCS22
00592 *    BY USER                                                      DTSCS22
00593 *-----------------------------------------------------            DTSCS22
00594                                                                   DTSCS22
00595      PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT.                 DTSCS22
00596                                                                   DTSCS22
00597                                                                   DTSCS22
00598 *-----------------------------------------------------            DTSCS22
00599 *    VERIFICATION RETURN LCCM-MSG IF ERROR DETECTED               DTSCS22
00600 *-----------------------------------------------------            DTSCS22
00601                                                                   DTSCS22
00602      IF LCCM-MSG                                                  DTSCS22
00603         SET RESP-SEND-MSGONLY TO TRUE                             DTSCS22
00604         IF L013-NO-ENTRY                                          DTSCS22
00605            SET CURSOR-SET-GOTO TO TRUE                            DTSCS22
00606         ELSE                                                      DTSCS22
00607            PERFORM S1201-SELECT-LINE-ERROR THRU S1201-EXIT        DTSCS22
00608         END-IF                                                    DTSCS22
00609         GO TO P3000-EXIT                                          DTSCS22
00610      END-IF.                                                      DTSCS22
00611                                                                   DTSCS22
00612                                                                   DTSCS22
00613      MOVE MAP-DOC-NO-AREA TO L019-S-DOC-NO.                       DTSCS22
00614                                                                   DTSCS22
00615      PERFORM S019-BATCH-NO-FROM-SCREEN THRU S019-EXIT.            DTSCS22
00616                                                                   DTSCS22
00617      IF L019-VALID                                                DTSCS22
00618          IF L019-BATCH-NO = LCCM-BATCH-NO                         DTSCS22
00619              NEXT SENTENCE                                        DTSCS22
00620          ELSE                                                     DTSCS22
00621              MOVE L019-BATCH-NO TO LCCM-BATCH-NO                  DTSCS22
00622              MOVE +0 TO LCCM-ITEM-NO.                             DTSCS22
00623                                                                   DTSCS22
00624                                                                   DTSCS22
00625 *-----------------------------------------------------            DTSCS22
00626 *    CLEAN UP INDICATORS AND PAGING STORAGE PRIOR TO LEAVING      DTSCS22
00627 *-----------------------------------------------------            DTSCS22
00628                                                                   DTSCS22
00629      MOVE LOW-VALUES TO LCCM-SCR-HOLD-AREA.                       DTSCS22
00630                                                                   DTSCS22
00631      MOVE LOW-VALUES TO LCCM-SCR-STATUS                           DTSCS22
00632                         LCCM-SCR-HOLD-AREA.                       DTSCS22
00633                                                                   DTSCS22
00634      MOVE +0 TO LCCM-SCR-ABSTIME.                                 DTSCS22
00635                                                                   DTSCS22
00636      SET RESP-JUMP TO TRUE.                                       DTSCS22
00637  P3000-EXIT.                                                      DTSCS22
00638      EXIT.                                                        DTSCS22
00639                                                                   DTSCS22
00640                                                                   DTSCS22
00641                                                                   DTSCS22
00642 ******************************************************************DTSCS22
00643 * IF A LINE NUMBER WAS ENTERED IT MUST EXIST ON THE SCREEN        DTSCS22
00644 ******************************************************************DTSCS22
00645                                                                   DTSCS22
00646  P3001-SELECTION-LINE-EDIT.                                       DTSCS22
00647      MOVE MAP-SELECT-LINE-NO-AREA TO L013-S-CNT-AREA.             DTSCS22
00648                                                                   DTSCS22
00649      PERFORM S013-COUNT-FROM-SCREEN THRU S013-EXIT.               DTSCS22
00650                                                                   DTSCS22
00651      IF L013-NO-ENTRY                                             DTSCS22
00652         GO TO P3001-EXIT                                          DTSCS22
00653      END-IF.                                                      DTSCS22
00654                                                                   DTSCS22
00655      IF L013-NOT-VALID                                            DTSCS22
00656           OR (L013-CNT > WRK-HOLD-CTR)                            DTSCS22
00657         PERFORM S5300-SET-INQ-ATTRB THRU S5300-EXIT               DTSCS22
00658         MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-AREA                 DTSCS22
00659         PERFORM S1201-SELECT-LINE-ERROR THRU S1201-EXIT           DTSCS22
00660         GO TO P3001-EXIT                                          DTSCS22
00661      END-IF.                                                      DTSCS22
00662                                                                   DTSCS22
00663                                                                   DTSCS22
00664      MOVE WRK-HOLD-BATCH-NO                                       DTSCS22
00665        TO LCCM-BATCH-NO.                                          DTSCS22
00666                                                                   DTSCS22
00667      MOVE WRK-HOLD-ITEM-NO (L013-CNT)                             DTSCS22
00668        TO LCCM-ITEM-NO.                                           DTSCS22
00669                                                                   DTSCS22
00670      MOVE WRK-HOLD-EMP-NO (L013-CNT)                              DTSCS22
00671        TO LCCM-EMP-NO.                                            DTSCS22
00672                                                                   DTSCS22
00673                                                                   DTSCS22
00674 * NOW DETERMINE WHICH SCREEN TO JUMP TO                           DTSCS22
00675                                                                   DTSCS22
00676      IF LCCM-REQ-SCR-ID = LOW-VALUES OR SPACES OR WRK-SCR-ID      DTSCS22
00677          NEXT SENTENCE                                            DTSCS22
00678      ELSE                                                         DTSCS22
00679          GO TO P3001-EXIT.                                        DTSCS22
00680                                                                   DTSCS22
00681      IF MAP-GOTO = SPACES OR LOW-VALUES OR WRK-SCR-ID             DTSCS22
00682         NEXT SENTENCE                                             DTSCS22
00683      ELSE                                                         DTSCS22
00684         GO TO P3001-EXIT.                                         DTSCS22
00685                                                                   DTSCS22
00686      MOVE WRK-HOLD-REC-TYPE (L013-CNT)                            DTSCS22
00687        TO ASKL-REC-TYPE.                                          DTSCS22
00688                                                                   DTSCS22
00689      IF ASKL-ADJ-88                                               DTSCS22
00690         MOVE '26' TO LCCM-REQ-SCR-ID                              DTSCS22
00691      ELSE                                                         DTSCS22
00692      IF ASKL-PAY-88                                               DTSCS22
00693         MOVE '25' TO LCCM-REQ-SCR-ID                              DTSCS22
00694      ELSE                                                         DTSCS22
00695      IF ASKL-RPT-88                                               DTSCS22
00696         MOVE '24' TO LCCM-REQ-SCR-ID                              DTSCS22
00697      ELSE                                                         DTSCS22
00698      IF ASKL-ATX-88                                               DTSCS22
00699         MOVE '27' TO LCCM-REQ-SCR-ID                              DTSCS22
00700      ELSE                                                         DTSCS22
00701         GO TO S899-ABEND.                                         DTSCS22
00702  P3001-EXIT.                                                      DTSCS22
00703      EXIT.                                                        DTSCS22
00704 /*****************************************************************DTSCS22
00705 *    CLEAR KEY OR F12 KEY WAS PRESSED.                           *DTSCS22
00706 ******************************************************************DTSCS22
00707                                                                   DTSCS22
00708  P4000-REQUEST-CLEAR.                                             DTSCS22
00709                                                                   DTSCS22
00710 *-----------------------------------------------------            DTSCS22
00711 *   CLEAN UP INDICATORS AND PAGING STORAGE.  RESET KEY            DTSCS22
00712 *   FIELDS FROM EARLIER REQUESTS                                  DTSCS22
00713 *-----------------------------------------------------            DTSCS22
00714                                                                   DTSCS22
00715      MOVE +0 TO LCCM-BATCH-NO.                                    DTSCS22
00716                                                                   DTSCS22
00717      MOVE +0 TO LCCM-ITEM-NO.                                     DTSCS22
00718                                                                   DTSCS22
00719      MOVE LOW-VALUES TO LCCM-SCR-HOLD-AREA.                       DTSCS22
00720                                                                   DTSCS22
00721      MOVE LCCM-TASK-START-ABSTIME TO LCCM-SCR-ABSTIME.            DTSCS22
00722                                                                   DTSCS22
00723      SET LCCM-SCR-CLEAR TO TRUE.                                  DTSCS22
00724                                                                   DTSCS22
00725      PERFORM S5300-SET-INQ-ATTRB THRU S5300-EXIT.                 DTSCS22
00726                                                                   DTSCS22
00727      SET RESP-SEND-MAP TO TRUE.                                   DTSCS22
00728  P4000-EXIT.                                                      DTSCS22
00729      EXIT.                                                        DTSCS22
00730 /*****************************************************************DTSCS22
00731 * POSITION CURSOR ON GO TO FIELD WAS REQUESTED                   *DTSCS22
00732 ******************************************************************DTSCS22
00733                                                                   DTSCS22
00734  P5000-CURSOR-TO-GOTO.                                            DTSCS22
00735      SET CURSOR-SET-GOTO TO TRUE.                                 DTSCS22
00736                                                                   DTSCS22
00737      SET RESP-CURSOR-TO-GOTO TO TRUE.                             DTSCS22
00738  P5000-EXIT.                                                      DTSCS22
00739      EXIT.                                                        DTSCS22
00740 /*****************************************************************DTSCS22
00741 * INQUIRY WAS REQUESTED                                          *DTSCS22
00742 ******************************************************************DTSCS22
00743                                                                   DTSCS22
00744  P6000-REQUEST-INQUIRE.                                           DTSCS22
00745      MOVE SPACES TO WRK-MSG-AREA.                                 DTSCS22
00746                                                                   DTSCS22
00747      MOVE MAP-DOC-NO-AREA TO L019-S-DOC-NO.                       DTSCS22
00748                                                                   DTSCS22
00749      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS22
00750                                                                   DTSCS22
00751      MOVE L019-S-DOC-NO TO MAP-DOC-NO-AREA.                       DTSCS22
00752                                                                   DTSCS22
00753      SET LCCM-SCR-CLEAR TO TRUE.                                  DTSCS22
00754                                                                   DTSCS22
00755      MOVE LCCM-TASK-START-ABSTIME TO LCCM-SCR-ABSTIME.            DTSCS22
00756                                                                   DTSCS22
00757      SET RESP-SEND-MAP TO TRUE.                                   DTSCS22
00758                                                                   DTSCS22
00759      PERFORM S5300-SET-INQ-ATTRB THRU S5300-EXIT.                 DTSCS22
00760                                                                   DTSCS22
00761      PERFORM S1100-EDIT-KEY THRU S1100-EXIT.                      DTSCS22
00762                                                                   DTSCS22
00763      IF LCCM-ERROR-MSG                                            DTSCS22
00764          GO TO P6000-EXIT.                                        DTSCS22
00765                                                                   DTSCS22
00766                                                                   DTSCS22
00767      PERFORM P6100-LOCATE-REC THRU P6100-EXIT.                    DTSCS22
00768                                                                   DTSCS22
00769      IF LCCM-ERROR-MSG                                            DTSCS22
00770          GO TO P6000-EXIT.                                        DTSCS22
00771                                                                   DTSCS22
00772                                                                   DTSCS22
00773      PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT               DTSCS22
00774                                                                   DTSCS22
00775                                                                   DTSCS22
00776      SET LCCM-SCR-INQUIRE TO TRUE.                                DTSCS22
00777                                                                   DTSCS22
00778      IF WRK-HOLD-CTR > 0                                          DTSCS22
00779         MOVE CATB-UNPROT-BRT-NUM-MDTON TO MAP-SELECT-LINE-NO-A    DTSCS22
00780         MOVE CATB-CURSOR TO MAP-SELECT-LINE-NO-L                  DTSCS22
00781         MOVE CATB-ASKIP-BRT-MDTON TO MAP-BATCH-NO-A               DTSCS22
00782         SET CURSOR-SET-YES TO TRUE                                DTSCS22
00783      END-IF.                                                      DTSCS22
00784                                                                   DTSCS22
00785                                                                   DTSCS22
00786      SET  WRK-HOLD-SCREEN-22-YES TO TRUE.                         DTSCS22
00787                                                                   DTSCS22
00788      MOVE WRK-HOLD-AREA TO LCCM-SCR-HOLD-AREA.                    DTSCS22
00789  P6000-EXIT.                                                      DTSCS22
00790      EXIT.                                                        DTSCS22
00791      EJECT                                                        DTSCS22
00792  P6100-LOCATE-REC.                                                DTSCS22
00793                                                                   DTSCS22
00794 *------------------------------------------------------------     DTSCS22
00795 *    IF, AT THE LAST USE OF THIS SCREEN, A RECORD FOR             DTSCS22
00796 *    BATCH NUMBER LCCM-BATCH-NO WAS DISPLAYED ON THE              DTSCS22
00797 *    SCREEN, THEN BASE THE PAGING LOGIC ON THE LAST RECORD        DTSCS22
00798 *    DISPLAYED ON THIS SCREEN; OTHERWISE, CLEAR                   DTSCS22
00799 *------------------------------------------------------------     DTSCS22
00800                                                                   DTSCS22
00801      MOVE LOW-VALUES TO ASKL-KEY-AREA.                            DTSCS22
00802                                                                   DTSCS22
00803      MOVE WRK-HOLD-BATCH-NO TO ASKL-BATCH-NO                      DTSCS22
00804                                                                   DTSCS22
00805      IF LCCM-F08-88                                               DTSCS22
00806         MOVE WRK-HOLD-ITEM-NO (WRK-HOLD-CTR) TO ASKL-ITEM-NO      DTSCS22
00807      ELSE                                                         DTSCS22
00808         MOVE WRK-HOLD-ITEM-NO (1) TO ASKL-ITEM-NO.                DTSCS22
00809                                                                   DTSCS22
00810      MOVE ASKL-BATCH-NO TO WRK-BATCH-NO.                          DTSCS22
00811                                                                   DTSCS22
00812      MOVE ASKL-ITEM-NO TO WRK-ITEM-NO.                            DTSCS22
00813                                                                   DTSCS22
00814      IF WRK-ITEM-NO = 0                                           DTSCS22
00815         MOVE +1 TO WRK-ITEM-NO                                    DTSCS22
00816         MOVE PMSG-FIRST-PAGE TO LCCM-MSG-AREA.                    DTSCS22
00817                                                                   DTSCS22
00818                                                                   DTSCS22
00819 *                         :---------------------------------------DTSCS22
00820 * ------------------------: READ THE HEADER RECORD FOR THE BATCH  DTSCS22
00821 *                         :---------------------------------------DTSCS22
00822                                                                   DTSCS22
00823      MOVE 0 TO ASKL-ITEM-NO                                       DTSCS22
00824                                                                   DTSCS22
00825      PERFORM S823-READ THRU S823-EXIT.                            DTSCS22
00826                                                                   DTSCS22
00827 *                        :--------------------------------------- DTSCS22
00828 * -----------------------: NO REC MEANS THERE IS NOT ANY RECORDS  DTSCS22
00829 *                        : FOR THE BATCH.                         DTSCS22
00830 *                        :--------------------------------------- DTSCS22
00831                                                                   DTSCS22
00832      IF L823-NO-REC-88                                            DTSCS22
00833         MOVE EMSG-NO-RECORD TO WRK-MSG-AREA                       DTSCS22
00834         PERFORM S1111-ERROR THRU S1111-EXIT                       DTSCS22
00835         GO TO P6100-EXIT.                                         DTSCS22
00836                                                                   DTSCS22
00837                                                                   DTSCS22
00838 *                        :--------------------------------------- DTSCS22
00839 * -----------------------: OK THE BATCH DOES EXIST ON THE FILE    DTSCS22
00840 *                        : BUT IF AHDR-ATC-FILE-TRAN-CNT = 0, THENDTSCS22
00841 *                        : THERE ARE NO RECORDS (ADJ,PAY,RPT)     DTSCS22
00842 *                        : TO BE SEEN.                            DTSCS22
00843 *                        :--------------------------------------- DTSCS22
00844                                                                   DTSCS22
00845      MOVE ASKL-REC TO AHDR-REC.                                   DTSCS22
00846                                                                   DTSCS22
00847      PERFORM P6930-FROM-HDR THRU P6930-EXIT.                      DTSCS22
00848                                                                   DTSCS22
00849      IF AHDR-ATC-FILE-TRAN-CNT = +0                               DTSCS22
00850         MOVE EMSG-NO-RECORD TO WRK-MSG-AREA                       DTSCS22
00851         PERFORM S1111-ERROR THRU S1111-EXIT                       DTSCS22
00852         GO TO P6100-EXIT.                                         DTSCS22
00853                                                                   DTSCS22
00854 *                        :--------------------------------------- DTSCS22
00855 * -----------------------: OK THE BATCH DOES EXIST ON THE FILE    DTSCS22
00856 *                        : AND THERE ARE ITEMS TO BE SEEN.  TRY   DTSCS22
00857 *                        : STARTING AT THE ITEM NO DETERMINED     DTSCS22
00858 *                        : ABOVE.                                 DTSCS22
00859 *                        :--------------------------------------- DTSCS22
00860                                                                   DTSCS22
00861      MOVE WRK-ITEM-NO TO ASKL-ITEM-NO.                            DTSCS22
00862                                                                   DTSCS22
00863      PERFORM S823-START-BROWSE THRU S823-EXIT.                    DTSCS22
00864                                                                   DTSCS22
00865 *                        :--------------------------------------- DTSCS22
00866 * -----------------------: THE ITEM NO REQUESTED IS > THAN THE    DTSCS22
00867 *                        : LAST RECORD ON THE FILE.  IF WE TRIED  DTSCS22
00868 *                        : TO GET THE THEORETICAL FIRST ITEM THEN DTSCS22
00869 *                        : THERE ARE NO RECORDS AND THE BATCH HDR DTSCS22
00870 *                        : HAS AN ERROR.                          DTSCS22
00871 *                        :--------------------------------------- DTSCS22
00872                                                                   DTSCS22
00873      IF (L823-NO-REC-88                                           DTSCS22
00874           OR ASKL-HDR-88)                                         DTSCS22
00875             AND WRK-ITEM-NO NOT GREATER THAN 1                    DTSCS22
00876          GO TO S899-ABEND.                                        DTSCS22
00877                                                                   DTSCS22
00878                                                                   DTSCS22
00879 *                        :--------------------------------------- DTSCS22
00880 *                        : BECAUSE I CAN'T START ANYWHERE ELSE    DTSCS22
00881 *                        : IF IT IS > LAST RECORD ON FILE (AND    DTSCS22
00882 *                        : TO BE CONSISTENT)                      DTSCS22
00883 *                        : I WILL TRY TO WRAP PAGING. I KNOW      DTSCS22
00884 * -----------------------: THE PROGRAM NOTES SAID NOT TO BUT TO   DTSCS22
00885 *                        : SEND A REAL GOOD MESSAGE I NEED TO     DTSCS22
00886 *                        : KNOW MORE.                             DTSCS22
00887 *                        :--------------------------------------- DTSCS22
00888 *                        :                                        DTSCS22
00889 * -----------------------: MUST TERMINATE THE LAST BROWSE         DTSCS22
00890 *                        : IF THE BROWSE WAS OK                   DTSCS22
00891                                                                   DTSCS22
00892      IF L823-NO-REC-88                                            DTSCS22
00893           OR ASKL-HDR-88                                          DTSCS22
00894         IF L823-OK-88                                             DTSCS22
00895            PERFORM S823-END-BROWSE THRU S823-EXIT                 DTSCS22
00896         END-IF                                                    DTSCS22
00897         MOVE WRK-BATCH-NO TO ASKL-BATCH-NO                        DTSCS22
00898         MOVE +1 TO WRK-ITEM-NO                                    DTSCS22
00899                    ASKL-ITEM-NO                                   DTSCS22
00900         PERFORM S823-START-BROWSE THRU S823-EXIT                  DTSCS22
00901         IF L823-NO-REC-88                                         DTSCS22
00902              OR ASKL-HDR-88                                       DTSCS22
00903            GO TO S899-ABEND                                       DTSCS22
00904         ELSE                                                      DTSCS22
00905            MOVE PMSG-FIRST-PAGE TO LCCM-MSG-AREA                  DTSCS22
00906            GO TO P6100-EXIT.                                      DTSCS22
00907                                                                   DTSCS22
00908                                                                   DTSCS22
00909 *                        :--------------------------------------- DTSCS22
00910 *                        : IF I GOT THIS FAR THEN THINGS SHOULD   DTSCS22
00911 * -----------------------: PROCEED NORMALLY                       DTSCS22
00912 *                        :--------------------------------------- DTSCS22
00913                                                                   DTSCS22
00914      IF LCCM-ENTER-88                                             DTSCS22
00915         GO TO P6100-EXIT.                                         DTSCS22
00916                                                                   DTSCS22
00917                                                                   DTSCS22
00918      MOVE ASKL-BATCH-NO TO WRK-BATCH-NO.                          DTSCS22
00919                                                                   DTSCS22
00920      MOVE ASKL-ITEM-NO  TO WRK-ITEM-NO.                           DTSCS22
00921                                                                   DTSCS22
00922      IF LCCM-F07-88                                               DTSCS22
00923          PERFORM P6120-PREV-REC THRU P6120-EXIT                   DTSCS22
00924          GO TO P6100-EXIT.                                        DTSCS22
00925                                                                   DTSCS22
00926      IF LCCM-F08-88                                               DTSCS22
00927         PERFORM P6130-NEXT-REC THRU P6130-EXIT                    DTSCS22
00928         GO TO P6100-EXIT.                                         DTSCS22
00929                                                                   DTSCS22
00930      GO TO S899-ABEND.                                            DTSCS22
00931  P6100-EXIT.                                                      DTSCS22
00932      EXIT.                                                        DTSCS22
00933      EJECT                                                        DTSCS22
00934  P6120-PREV-REC.                                                  DTSCS22
00935      PERFORM S823-READ-PREV THRU S823-EXIT.                       DTSCS22
00936                                                                   DTSCS22
00937      PERFORM S823-READ-PREV THRU S823-EXIT.                       DTSCS22
00938                                                                   DTSCS22
00939 *                        :--------------------------------------- DTSCS22
00940 *                        : ACTUALLY NO REC HERE WOULD IMPLY BIG   DTSCS22
00941 * -----------------------: TROUBLE.                               DTSCS22
00942 *                        :                                        DTSCS22
00943 *                        :--------------------------------------- DTSCS22
00944                                                                   DTSCS22
00945      IF L823-NO-REC-88                                            DTSCS22
00946         MOVE WRK-BATCH-NO TO ASKL-BATCH-NO                        DTSCS22
00947         MOVE WRK-ITEM-NO TO ASKL-ITEM-NO                          DTSCS22
00948         MOVE PMSG-FIRST-PAGE TO LCCM-MSG-AREA                     DTSCS22
00949         GO TO P6120-EXIT.                                         DTSCS22
00950                                                                   DTSCS22
00951                                                                   DTSCS22
00952 *                        :--------------------------------------- DTSCS22
00953 *                        : OOPS! I FOUND THE HEADER. RESTORE THE  DTSCS22
00954 * -----------------------: KEY INFO FROM THE LAST START BROWSE    DTSCS22
00955 *                        : AND GO THE OTHER DIRECTION             DTSCS22
00956 *                        :--------------------------------------- DTSCS22
00957                                                                   DTSCS22
00958      IF ASKL-HDR-88                                               DTSCS22
00959         PERFORM S823-END-BROWSE THRU S823-EXIT                    DTSCS22
00960         MOVE WRK-BATCH-NO TO ASKL-BATCH-NO                        DTSCS22
00961         MOVE WRK-ITEM-NO TO ASKL-ITEM-NO                          DTSCS22
00962         PERFORM S823-START-BROWSE THRU S823-EXIT                  DTSCS22
00963         SET LCCM-F08-88 TO TRUE                                   DTSCS22
00964         MOVE PMSG-FIRST-PAGE TO LCCM-MSG-AREA                     DTSCS22
00965         GO TO P6120-EXIT.                                         DTSCS22
00966  P6120-EXIT.                                                      DTSCS22
00967      EXIT.                                                        DTSCS22
00968                                                                   DTSCS22
00969                                                                   DTSCS22
00970                                                                   DTSCS22
00971  P6130-NEXT-REC.                                                  DTSCS22
00972      PERFORM S823-READ-NEXT THRU S823-EXIT.                       DTSCS22
00973                                                                   DTSCS22
00974 *                        :--------------------------------------- DTSCS22
00975 *                        : OOPS! I FOUND THE THE NEXT HEADER.     DTSCS22
00976 * -----------------------: RESTORE INFO FROM THE LAST START BROWSEDTSCS22
00977 *                        : AND GO THE OTHER DIRECTION             DTSCS22
00978 *                        :--------------------------------------- DTSCS22
00979                                                                   DTSCS22
00980      IF L823-NO-REC-88                                            DTSCS22
00981           OR ASKL-HDR-88                                          DTSCS22
00982         PERFORM S823-END-BROWSE THRU S823-EXIT                    DTSCS22
00983         MOVE WRK-BATCH-NO TO ASKL-BATCH-NO                        DTSCS22
00984         MOVE WRK-ITEM-NO TO ASKL-ITEM-NO                          DTSCS22
00985         PERFORM S823-START-BROWSE THRU S823-EXIT                  DTSCS22
00986         PERFORM S823-READ-PREV THRU S823-EXIT                     DTSCS22
00987         SET LCCM-F07-88 TO TRUE                                   DTSCS22
00988         MOVE PMSG-LAST-PAGE TO LCCM-MSG-AREA                      DTSCS22
00989         GO TO P6130-EXIT.                                         DTSCS22
00990  P6130-EXIT.                                                      DTSCS22
00991      EXIT.                                                        DTSCS22
00992 /*****************************************************************DTSCS22
00993 * THE RECORD WAS FOUND SO FORMAT AND PLACE ALL FIELDS            *DTSCS22
00994 ******************************************************************DTSCS22
00995                                                                   DTSCS22
00996  P6900-CONSTRUCT-SCREEN.                                          DTSCS22
00997      MOVE +0 TO WRK-TRAN-CNT.                                     DTSCS22
00998                                                                   DTSCS22
00999      MOVE +0 TO WRK-HOLD-CTR.                                     DTSCS22
01000                                                                   DTSCS22
01001      PERFORM P6910-CONSTRUCT-SCREEN THRU P6910-EXIT               DTSCS22
01002         VARYING WRK-SUB FROM 1 BY 1                               DTSCS22
01003           UNTIL WRK-SUB > 12                                      DTSCS22
01004             OR L823-NO-REC-88.                                    DTSCS22
01005                                                                   DTSCS22
01006      IF L823-OK-88                                                DTSCS22
01007         PERFORM S823-END-BROWSE THRU S823-EXIT                    DTSCS22
01008      ELSE                                                         DTSCS22
01009      IF LCCM-F07-88                                               DTSCS22
01010         AND WRK-HOLD-CTR < 12                                     DTSCS22
01011         PERFORM P6901-REVERSE-FLOW THRU P6901-EXIT                DTSCS22
01012      ELSE                                                         DTSCS22
01013         MOVE PMSG-LAST-PAGE TO LCCM-MSG-AREA.                     DTSCS22
01014                                                                   DTSCS22
01015      IF  AHDR-ATC-FILE-TRAN-CNT = WRK-TRAN-CNT                    DTSCS22
01016         MOVE PMSG-ONLY-PAGE TO LCCM-MSG-AREA.                     DTSCS22
01017  P6900-EXIT.                                                      DTSCS22
01018      EXIT.                                                        DTSCS22
01019                                                                   DTSCS22
01020                                                                   DTSCS22
01021                                                                   DTSCS22
01022  P6901-REVERSE-FLOW.                                              DTSCS22
01023      MOVE PMSG-FIRST-PAGE TO LCCM-MSG-ID                          DTSCS22
01024                                                                   DTSCS22
01025      IF WRK-HOLD-CTR = 0                                          DTSCS22
01026         MOVE WRK-HOLD-BATCH-NO TO ASKL-BATCH-NO                   DTSCS22
01027         MOVE WRK-HOLD-ITEM-NO (1) TO ASKL-ITEM-NO                 DTSCS22
01028      ELSE                                                         DTSCS22
01029         MOVE WRK-HOLD-BATCH-NO TO ASKL-BATCH-NO                   DTSCS22
01030         MOVE WRK-HOLD-ITEM-NO (WRK-HOLD-CTR) TO ASKL-ITEM-NO      DTSCS22
01031      END-IF.                                                      DTSCS22
01032                                                                   DTSCS22
01033      PERFORM S823-START-BROWSE THRU S823-EXIT                     DTSCS22
01034                                                                   DTSCS22
01035      IF L823-OK-88                                                DTSCS22
01036         PERFORM S823-READ-NEXT THRU S823-EXIT                     DTSCS22
01037         SET LCCM-F08-88 TO TRUE                                   DTSCS22
01038         PERFORM P6910-CONSTRUCT-SCREEN THRU P6910-EXIT            DTSCS22
01039         VARYING WRK-SUB FROM WRK-SUB BY 1                         DTSCS22
01040           UNTIL WRK-SUB > 12                                      DTSCS22
01041              OR L823-NO-REC-88                                    DTSCS22
01042              OR ASKL-HDR-88                                       DTSCS22
01043         IF L823-OK-88                                             DTSCS22
01044            PERFORM S823-END-BROWSE THRU S823-EXIT.                DTSCS22
01045  P6901-EXIT.                                                      DTSCS22
01046      EXIT.                                                        DTSCS22
01047                                                                   DTSCS22
01048                                                                   DTSCS22
01049                                                                   DTSCS22
01050  P6910-CONSTRUCT-SCREEN.                                          DTSCS22
01051      ADD 1 TO WRK-HOLD-CTR.                                       DTSCS22
01052                                                                   DTSCS22
01053      IF LCCM-F07-88                                               DTSCS22
01054         PERFORM P6920-PUSH-STACK THRU P6920-EXIT                  DTSCS22
01055          VARYING WRK-CTR FROM WRK-SUB BY -1                       DTSCS22
01056          UNTIL WRK-CTR < 2.                                       DTSCS22
01057                                                                   DTSCS22
01058      IF LCCM-F07-88                                               DTSCS22
01059         COMPUTE WRK-CTR = 1                                       DTSCS22
01060      ELSE                                                         DTSCS22
01061         COMPUTE WRK-CTR = WRK-SUB.                                DTSCS22
01062                                                                   DTSCS22
01063      MOVE SPACES TO MAP-LINE-DATA (WRK-CTR)                       DTSCS22
01064                                                                   DTSCS22
01065      IF ASKL-ADJ-88                                               DTSCS22
01066         PERFORM P6911-FROM-ADJ THRU P6911-EXIT                    DTSCS22
01067 *****ELSE                                                         DTSCS22
01068 *****IF ASKL-CHK-88                                               DTSCS22
01069 ********PERFORM P6912-FROM-CHK THRU P6912-EXIT                    DTSCS22
01070      ELSE                                                         DTSCS22
01071      IF ASKL-PAY-88                                               DTSCS22
01072         PERFORM P6913-FROM-PAY THRU P6913-EXIT                    DTSCS22
01073      ELSE                                                         DTSCS22
01074      IF ASKL-RPT-88                                               DTSCS22
01075         PERFORM P6914-FROM-RPT THRU P6914-EXIT                    DTSCS22
01076      ELSE                                                         DTSCS22
01077      IF ASKL-ATX-88                                               DTSCS22
01078         PERFORM P6915-FROM-ATX THRU P6915-EXIT                    DTSCS22
01079      ELSE                                                         DTSCS22
01080         GO TO S899-ABEND.                                         DTSCS22
01081                                                                   DTSCS22
01082      MOVE WRK-CTR TO MAP-LINE-NO (WRK-CTR).                       DTSCS22
01083                                                                   DTSCS22
01084      IF LCCM-F07-88                                               DTSCS22
01085         MOVE ASKL-ITEM-NO TO WRK-HOLD-ITEM-NO (1)                 DTSCS22
01086         MOVE ASKL-REC-TYPE TO WRK-HOLD-REC-TYPE (1)               DTSCS22
01087         PERFORM S823-READ-PREV THRU S823-EXIT                     DTSCS22
01088      ELSE                                                         DTSCS22
01089         MOVE ASKL-ITEM-NO TO WRK-HOLD-ITEM-NO (WRK-HOLD-CTR)      DTSCS22
01090         MOVE ASKL-REC-TYPE TO WRK-HOLD-REC-TYPE (WRK-HOLD-CTR)    DTSCS22
01091         PERFORM S823-READ-NEXT THRU S823-EXIT.                    DTSCS22
01092                                                                   DTSCS22
01093      IF L823-OK-88                                                DTSCS22
01094         IF ASKL-HDR-88                                            DTSCS22
01095            PERFORM S823-END-BROWSE THRU S823-EXIT                 DTSCS22
01096            SET L823-NO-REC-88 TO TRUE.                            DTSCS22
01097  P6910-EXIT.                                                      DTSCS22
01098      EXIT.                                                        DTSCS22
01099      EJECT                                                        DTSCS22
01100  P6911-FROM-ADJ.                                                  DTSCS22
01101      MOVE ASKL-REC TO AADJ-REC.                                   DTSCS22
01102                                                                   DTSCS22
01103      MOVE AADJ-ITEM-NO TO MAP-ITEM-NO (WRK-CTR).                  DTSCS22
01104                                                                   DTSCS22
01105      MOVE AADJ-REC-TYPE TO MAP-REC-TYPE (WRK-CTR).                DTSCS22
01106                                                                   DTSCS22
01107      MOVE AADJ-ADJ-TYPE TO MAP-TYPE-TYPE (WRK-CTR).               DTSCS22
01108                                                                   DTSCS22
01109      MOVE AADJ-EMP-NO TO MAP-EMP-NO (WRK-CTR).                    DTSCS22
01110                                                                   DTSCS22
01111      IF AADJ-PROCESSED-DATE > +0                                  DTSCS22
01112          MOVE AADJ-PROCESSED-DATE TO L001-FED-8-DATE-9            DTSCS22
01113          PERFORM S001-FROM-FED-8 THRU S001-EXIT                   DTSCS22
01114          MOVE L001-SLASH-DATE TO MAP-PROCESSED-DATE (WRK-CTR).    DTSCS22
01115                                                                   DTSCS22
01116      MOVE AADJ-EMP-NO TO WRK-HOLD-EMP-NO (WRK-CTR).               DTSCS22
01117                                                                   DTSCS22
01118      ADD +1 TO WRK-TRAN-CNT.                                      DTSCS22
01119  P6911-EXIT.                                                      DTSCS22
01120      EXIT.                                                        DTSCS22
01121                                                                   DTSCS22
01122                                                                   DTSCS22
01123                                                                   DTSCS22
01124 *P6912-FROM-CHK.                                                  DTSCS22
01125 *****MOVE ASKL-REC TO ACHK-REC.                                   DTSCS22
01126 *****MOVE ACHK-ITEM-NO    TO  MAP-ITEM-NO(WRK-CTR).               DTSCS22
01127 *****MOVE ACHK-REC-TYPE   TO  MAP-REC-TYPE(WRK-CTR).              DTSCS22
01128 *****MOVE ACHK-EMP-NO     TO  MAP-EMP-NO(WRK-CTR).                DTSCS22
01129 *****MOVE ACHK-CHECK-AMT  TO  MAP-CHECK-AMT(WRK-CTR).             DTSCS22
01130 *****ADD +1 TO WRK-CHECK-CNT.                                     DTSCS22
01131                                                                   DTSCS22
01132 *****MOVE ACHK-EMP-NO     TO  WRK-HOLD-EMP-NO(WRK-CTR).           DTSCS22
01133 *P6912-EXIT.                                                      DTSCS22
01134 *****EXIT.                                                        DTSCS22
01135                                                                   DTSCS22
01136                                                                   DTSCS22
01137                                                                   DTSCS22
01138  P6913-FROM-PAY.                                                  DTSCS22
01139      MOVE ASKL-REC TO APAY-REC.                                   DTSCS22
01140                                                                   DTSCS22
01141      MOVE APAY-ITEM-NO TO MAP-ITEM-NO (WRK-CTR).                  DTSCS22
01142                                                                   DTSCS22
01143      MOVE APAY-REC-TYPE TO MAP-REC-TYPE (WRK-CTR).                DTSCS22
01144                                                                   DTSCS22
01145      MOVE APAY-PAY-TYPE TO MAP-TYPE-TYPE (WRK-CTR).               DTSCS22
01146                                                                   DTSCS22
01147      MOVE APAY-EMP-NO TO MAP-EMP-NO (WRK-CTR).                    DTSCS22
01148                                                                   DTSCS22
01149      MOVE APAY-REMIT-AMT TO MAP-REMIT-AMT (WRK-CTR)               DTSCS22
01150                                                                   DTSCS22
01151      IF APAY-PROCESSED-DATE > +0                                  DTSCS22
01152          MOVE APAY-PROCESSED-DATE TO L001-FED-8-DATE-9            DTSCS22
01153          PERFORM S001-FROM-FED-8 THRU S001-EXIT                   DTSCS22
01154          MOVE L001-SLASH-DATE TO MAP-PROCESSED-DATE (WRK-CTR).    DTSCS22
01155                                                                   DTSCS22
01156                                                                   DTSCS22
01157      MOVE APAY-EMP-NO TO  WRK-HOLD-EMP-NO(WRK-CTR).               DTSCS22
01158                                                                   DTSCS22
01159      ADD +1 TO WRK-TRAN-CNT.                                      DTSCS22
01160  P6913-EXIT.                                                      DTSCS22
01161      EXIT.                                                        DTSCS22
01162                                                                   DTSCS22
01163                                                                   DTSCS22
01164                                                                   DTSCS22
01165  P6914-FROM-RPT.                                                  DTSCS22
01166      MOVE ASKL-REC TO ARPT-REC.                                   DTSCS22
01167                                                                   DTSCS22
01168      MOVE ARPT-ITEM-NO TO MAP-ITEM-NO (WRK-CTR).                  DTSCS22
01169                                                                   DTSCS22
01170      MOVE ARPT-REC-TYPE TO MAP-REC-TYPE (WRK-CTR).                DTSCS22
01171                                                                   DTSCS22
01172      MOVE ARPT-RPT-TYPE TO MAP-TYPE-TYPE (WRK-CTR).               DTSCS22
01173                                                                   DTSCS22
01174      MOVE ARPT-EMP-NO TO MAP-EMP-NO (WRK-CTR).                    DTSCS22
01175                                                                   DTSCS22
01176      MOVE ARPT-REMIT-AMT TO MAP-REMIT-AMT (WRK-CTR).              DTSCS22
01177                                                                   DTSCS22
01178      IF ARPT-PROCESSED-DATE > +0                                  DTSCS22
01179          MOVE ARPT-PROCESSED-DATE TO L001-FED-8-DATE-9            DTSCS22
01180          PERFORM S001-FROM-FED-8 THRU S001-EXIT                   DTSCS22
01181          MOVE L001-SLASH-DATE TO MAP-PROCESSED-DATE (WRK-CTR).    DTSCS22
01182                                                                   DTSCS22
01183                                                                   DTSCS22
01184      ADD +1 TO WRK-TRAN-CNT.                                      DTSCS22
01185                                                                   DTSCS22
01186      MOVE ARPT-EMP-NO TO WRK-HOLD-EMP-NO (WRK-CTR).               DTSCS22
01187  P6914-EXIT.                                                      DTSCS22
01188      EXIT.                                                        DTSCS22
01189                                                                   DTSCS22
01190  P6915-FROM-ATX.                                                  DTSCS22
01191      MOVE ASKL-REC TO AATX-REC.                                   DTSCS22
01192                                                                   DTSCS22
01193      MOVE AATX-ITEM-NO TO MAP-ITEM-NO (WRK-CTR).                  DTSCS22
01194                                                                   DTSCS22
01195      MOVE AATX-REC-TYPE TO MAP-REC-TYPE (WRK-CTR).                DTSCS22
01196                                                                   DTSCS22
01197      MOVE AATX-RPT-TYPE TO MAP-TYPE-TYPE (WRK-CTR).               DTSCS22
01198                                                                   DTSCS22
01199      MOVE AATX-EMP-NO TO MAP-EMP-NO (WRK-CTR).                    DTSCS22
01200                                                                   DTSCS22
01201      MOVE AATX-REMIT-AMT TO MAP-REMIT-AMT (WRK-CTR).              DTSCS22
01202                                                                   DTSCS22
01203      IF AATX-PROCESSED-DATE > +0                                  DTSCS22
01204          MOVE AATX-PROCESSED-DATE TO L001-FED-8-DATE-9            DTSCS22
01205          PERFORM S001-FROM-FED-8 THRU S001-EXIT                   DTSCS22
01206          MOVE L001-SLASH-DATE TO MAP-PROCESSED-DATE (WRK-CTR).    DTSCS22
01207                                                                   DTSCS22
01208                                                                   DTSCS22
01209      ADD +1 TO WRK-TRAN-CNT.                                      DTSCS22
01210                                                                   DTSCS22
01211      MOVE AATX-EMP-NO TO WRK-HOLD-EMP-NO (WRK-CTR).               DTSCS22
01212  P6915-EXIT.                                                      DTSCS22
01213      EXIT.                                                        DTSCS22
01214                                                                   DTSCS22
01215                                                                   DTSCS22
01216  P6920-PUSH-STACK.                                                DTSCS22
01217      COMPUTE WRK-CTR2 = WRK-CTR - 1.                              DTSCS22
01218                                                                   DTSCS22
01219      MOVE MAP-LINE (WRK-CTR2) TO MAP-LINE (WRK-CTR).              DTSCS22
01220                                                                   DTSCS22
01221      MOVE WRK-HOLD-KEY (WRK-CTR2) TO WRK-HOLD-KEY (WRK-CTR).      DTSCS22
01222                                                                   DTSCS22
01223      MOVE WRK-CTR TO MAP-LINE-NO (WRK-CTR).                       DTSCS22
01224  P6920-EXIT.                                                      DTSCS22
01225      EXIT.                                                        DTSCS22
01226                                                                   DTSCS22
01227                                                                   DTSCS22
01228  P6930-FROM-HDR.                                                  DTSCS22
01229      MOVE AHDR-CONTROL-REMIT-AMT TO MAP-CONTROL-REMIT-AMT-N.      DTSCS22
01230                                                                   DTSCS22
01231      MOVE AHDR-CONTROL-TRAN-CNT TO MAP-CONTROL-TRAN-CNT-N.        DTSCS22
01232                                                                   DTSCS22
01233      COMPUTE MAP-BALANCE-REMIT-AMT-N                              DTSCS22
01234        = AHDR-CONTROL-REMIT-AMT - AHDR-ATC-FILE-REMIT-AMT.        DTSCS22
01235                                                                   DTSCS22
01236      COMPUTE MAP-BALANCE-TRAN-CNT-N                               DTSCS22
01237        = AHDR-CONTROL-TRAN-CNT - AHDR-ATC-FILE-TRAN-CNT.          DTSCS22
01238                                                                   DTSCS22
01239      IF AHDR-BATCH-BALANCED-YES-88                                DTSCS22
01240         MOVE 'BALANCED' TO MAP-BATCH-STATUS-DSCR-1                DTSCS22
01241      ELSE                                                         DTSCS22
01242         MOVE 'NOT BALANCED' TO MAP-BATCH-STATUS-DSCR-1.           DTSCS22
01243                                                                   DTSCS22
01244      IF AHDR-BATCH-HELD-YES-88                                    DTSCS22
01245         MOVE 'HELD' TO MAP-BATCH-STATUS-DSCR-2                    DTSCS22
01246      ELSE                                                         DTSCS22
01247         MOVE SPACES TO MAP-BATCH-STATUS-DSCR-2.                   DTSCS22
01248                                                                   DTSCS22
01249      IF AHDR-PROC-TRAN-CNT > +0                                   DTSCS22
01250         MOVE 'PART PROCESSED' TO MAP-BATCH-STATUS-DSCR-3          DTSCS22
01251      ELSE                                                         DTSCS22
01252         MOVE SPACES TO MAP-BATCH-STATUS-DSCR-3.                   DTSCS22
01253  P6930-EXIT.                                                      DTSCS22
01254      EXIT.                                                        DTSCS22
01255      EJECT                                                        DTSCS22
01256 /*****************************************************************DTSCS22
01257 * LINKS TO UTILITY MODULES                                        DTSCS22
01258 ******************************************************************DTSCS22
01259                                                                   DTSCS22
01260  S001-FROM-FED-8.                                                 DTSCS22
01261      SET L001-FROM-FED-8 TO TRUE.                                 DTSCS22
01262      GO TO S001-DATE.                                             DTSCS22
01263                                                                   DTSCS22
01264  S001-DATE.                                                       DTSCS22
01265      EXEC CICS LINK                                               DTSCS22
01266          PROGRAM('DTSCU001')                                      DTSCS22
01267          COMMAREA(L001-COMM-AREA)                                 DTSCS22
01268      END-EXEC.                                                    DTSCS22
01269  S001-EXIT.                                                       DTSCS22
01270      EXIT.                                                        DTSCS22
01271                                                                   DTSCS22
01272                                                                   DTSCS22
01273                                                                   DTSCS22
01274  S013-COUNT-FROM-SCREEN.                                          DTSCS22
01275      MOVE +1 TO L013-MIN-CNT.                                     DTSCS22
01276                                                                   DTSCS22
01277      MOVE WRK-HOLD-CTR TO L013-MAX-CNT.                           DTSCS22
01278                                                                   DTSCS22
01279      EXEC CICS LINK                                               DTSCS22
01280          PROGRAM('DTSCU013')                                      DTSCS22
01281          COMMAREA(L013-COMM-AREA)                                 DTSCS22
01282      END-EXEC.                                                    DTSCS22
01283  S013-EXIT.                                                       DTSCS22
01284      EXIT.                                                        DTSCS22
01285                                                                   DTSCS22
01286                                                                   DTSCS22
01287                                                                   DTSCS22
01288  S019-BATCH-NO-FROM-SCREEN.                                       DTSCS22
01289      EXEC CICS LINK                                               DTSCS22
01290          PROGRAM('DTSCU019')                                      DTSCS22
01291          COMMAREA(L019-COMM-AREA)                                 DTSCS22
01292      END-EXEC.                                                    DTSCS22
01293  S019-EXIT.                                                       DTSCS22
01294      EXIT.                                                        DTSCS22
01295                                                                   DTSCS22
01296                                                                   DTSCS22
01297                                                                   DTSCS22
01298  S803-REQ-SCR-ID-EDIT.                                            DTSCS22
01299      EXEC CICS LINK                                               DTSCS22
01300          PROGRAM ('DTSCU803')                                     DTSCS22
01301          COMMAREA (DFHCOMMAREA)                                   DTSCS22
01302      END-EXEC.                                                    DTSCS22
01303  S803-EXIT.                                                       DTSCS22
01304      EXIT.                                                        DTSCS22
01305                                                                   DTSCS22
01306                                                                   DTSCS22
01307                                                                   DTSCS22
01308  S804-INVALID-KEY.                                                DTSCS22
01309      EXEC CICS LINK                                               DTSCS22
01310          PROGRAM ('DTSCU804')                                     DTSCS22
01311          COMMAREA (DFHCOMMAREA)                                   DTSCS22
01312      END-EXEC.                                                    DTSCS22
01313  S804-EXIT.                                                       DTSCS22
01314      EXIT.                                                        DTSCS22
01315                                                                   DTSCS22
01316                                                                   DTSCS22
01317                                                                   DTSCS22
01318  S805-MSG-AREA.                                                   DTSCS22
01319      MOVE LCCM-MSG-AREA TO L805-MSG-AREA                          DTSCS22
01320                                                                   DTSCS22
01321      EXEC CICS LINK                                               DTSCS22
01322          PROGRAM ('DTSCU805')                                     DTSCS22
01323          COMMAREA (L805-COMM-AREA)                                DTSCS22
01324      END-EXEC.                                                    DTSCS22
01325                                                                   DTSCS22
01326      MOVE L805-S-MSG-AREA TO MAP-MSG-AREA.                        DTSCS22
01327  S805-EXIT.                                                       DTSCS22
01328      EXIT.                                                        DTSCS22
01329                                                                   DTSCS22
01330                                                                   DTSCS22
01331                                                                   DTSCS22
01332  S823-READ.                                                       DTSCS22
01333      SET L823-READ-88 TO TRUE.                                    DTSCS22
01334      GO TO S823-IO.                                               DTSCS22
01335                                                                   DTSCS22
01336  S823-START-BROWSE.                                               DTSCS22
01337      SET L823-START-BROWSE-88 TO TRUE.                            DTSCS22
01338      GO TO S823-IO.                                               DTSCS22
01339                                                                   DTSCS22
01340  S823-READ-NEXT.                                                  DTSCS22
01341      SET L823-READ-NEXT-88 TO TRUE.                               DTSCS22
01342      GO TO S823-IO.                                               DTSCS22
01343                                                                   DTSCS22
01344  S823-READ-PREV.                                                  DTSCS22
01345      SET L823-READ-PREV-88 TO TRUE.                               DTSCS22
01346      GO TO S823-IO.                                               DTSCS22
01347                                                                   DTSCS22
01348  S823-END-BROWSE.                                                 DTSCS22
01349      SET L823-END-BROWSE-88 TO TRUE.                              DTSCS22
01350      GO TO S823-IO.                                               DTSCS22
01351                                                                   DTSCS22
01352  S823-IO.                                                         DTSCS22
01353      EXEC CICS LINK                                               DTSCS22
01354          PROGRAM ('DTSCU823')                                     DTSCS22
01355          COMMAREA (L823-COMM-AREA)                                DTSCS22
01356      END-EXEC.                                                    DTSCS22
01357                                                                   DTSCS22
01358      IF L823-FILE-CLOSED-88                                       DTSCS22
01359          MOVE L823-MSG-AREA TO LCCM-MSG-AREA                      DTSCS22
01360          SET LCCM-REQ-SCR-SF-88 TO TRUE                           DTSCS22
01361          SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS22
01362          GO TO MAINLINE-EXIT.                                     DTSCS22
01363  S823-EXIT.                                                       DTSCS22
01364      EXIT.                                                        DTSCS22
01365                                                                   DTSCS22
01366                                                                   DTSCS22
01367                                                                   DTSCS22
01368  S851-SCREEN-PROCESSING.                                          DTSCS22
01369      EXEC CICS LINK                                               DTSCS22
01370          PROGRAM ('DTSCU851')                                     DTSCS22
01371          COMMAREA (L851-COMM-AREA)                                DTSCS22
01372      END-EXEC.                                                    DTSCS22
01373  S851-EXIT.                                                       DTSCS22
01374      EXIT.                                                        DTSCS22
01375                                                                   DTSCS22
01376                                                                   DTSCS22
01377                                                                   DTSCS22
01378  S899-ABEND.                                                      DTSCS22
01379      EXEC CICS ABEND                                              DTSCS22
01380          ABCODE(WRK-ABEND-CD)                                     DTSCS22
01381      END-EXEC.                                                    DTSCS22
01382  S899-EXIT.                                                       DTSCS22
01383      EXIT.                                                        DTSCS22
01384 /*****************************************************************DTSCS22
01385 *    EDIT THE INFORMATION ON THE SCREEN.                         *DTSCS22
01386 ******************************************************************DTSCS22
01387                                                                   DTSCS22
01388  S1100-EDIT-KEY.                                                  DTSCS22
01389      PERFORM S1110-BATCH-NO THRU S1110-EXIT.                      DTSCS22
01390  S1100-EXIT. EXIT.                                                DTSCS22
01391 /*****************************************************************DTSCS22
01392 *                                                                 DTSCS22
01393 ******************************************************************DTSCS22
01394                                                                   DTSCS22
01395  S1110-BATCH-NO.                                                  DTSCS22
01396      MOVE MAP-DOC-NO-AREA TO L019-S-DOC-NO.                       DTSCS22
01397                                                                   DTSCS22
01398      PERFORM S019-BATCH-NO-FROM-SCREEN THRU S019-EXIT.            DTSCS22
01399                                                                   DTSCS22
01400      IF L019-NO-ENTRY                                             DTSCS22
01401         IF WRK-BATCH-NO > 0                                       DTSCS22
01402            MOVE WRK-BATCH-NO TO MAP-BATCH-NO-N                    DTSCS22
01403            GO TO S1110-EXIT                                       DTSCS22
01404         ELSE                                                      DTSCS22
01405            MOVE EMSG-FIELD-REQUIRED TO WRK-MSG-AREA               DTSCS22
01406            PERFORM S1111-ERROR THRU S1111-EXIT                    DTSCS22
01407            GO TO S1110-EXIT.                                      DTSCS22
01408                                                                   DTSCS22
01409      IF L019-NOT-VALID                                            DTSCS22
01410         MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-AREA                 DTSCS22
01411         PERFORM S1111-ERROR THRU S1111-EXIT                       DTSCS22
01412         GO TO S1110-EXIT.                                         DTSCS22
01413                                                                   DTSCS22
01414      IF L019-BATCH-NO NOT = WRK-BATCH-NO                          DTSCS22
01415         MOVE +1 TO WRK-HOLD-CTR                                   DTSCS22
01416         MOVE L019-BATCH-NO TO WRK-HOLD-BATCH-NO                   DTSCS22
01417                               LCCM-BATCH-NO                       DTSCS22
01418         MOVE L019-ITEM-NO TO WRK-HOLD-ITEM-NO (1)                 DTSCS22
01419         MOVE PMSG-FIRST-PAGE TO LCCM-MSG-AREA.                    DTSCS22
01420  S1110-EXIT.                                                      DTSCS22
01421      EXIT.                                                        DTSCS22
01422                                                                   DTSCS22
01423                                                                   DTSCS22
01424                                                                   DTSCS22
01425  S1111-ERROR.                                                     DTSCS22
01426      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-BATCH-NO-A.           DTSCS22
01427                                                                   DTSCS22
01428      IF NOT LCCM-ERROR-MSG                                        DTSCS22
01429         MOVE WRK-MSG-AREA TO LCCM-MSG-AREA                        DTSCS22
01430         MOVE CATB-CURSOR TO MAP-BATCH-NO-L                        DTSCS22
01431         SET CURSOR-SET-YES TO TRUE.                               DTSCS22
01432  S1111-EXIT.                                                      DTSCS22
01433      EXIT.                                                        DTSCS22
01434 /*****************************************************************DTSCS22
01435 *                                                                 DTSCS22
01436 ******************************************************************DTSCS22
01437                                                                   DTSCS22
01438  S1201-SELECT-LINE-ERROR.                                         DTSCS22
01439      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-SELECT-LINE-NO-A      DTSCS22
01440                                                                   DTSCS22
01441      IF LCCM-NO-MSG                                               DTSCS22
01442         MOVE WRK-MSG-AREA TO LCCM-MSG-AREA                        DTSCS22
01443         MOVE CATB-CURSOR TO MAP-SELECT-LINE-NO-L                  DTSCS22
01444         SET CURSOR-SET-YES TO TRUE.                               DTSCS22
01445  S1201-EXIT.                                                      DTSCS22
01446      EXIT.                                                        DTSCS22
01447 /*****************************************************************DTSCS22
01448 *  SET ATTRIBUTE BYTES FOR INQUIRY STATUS                        *DTSCS22
01449 ******************************************************************DTSCS22
01450                                                                   DTSCS22
01451  S5300-SET-INQ-ATTRB.                                             DTSCS22
01452      MOVE CATB-UNPROT-BRT-NUM-MDTON TO MAP-BATCH-NO-A             DTSCS22
01453                                                                   DTSCS22
01454      MOVE CATB-ASKIP-BRT-MDTOFF TO WRK-ATB-AN                     DTSCS22
01455                                    WRK-ATB-NUM.                   DTSCS22
01456                                                                   DTSCS22
01457      PERFORM S5900-SET-ATTRB THRU S5900-EXIT.                     DTSCS22
01458  S5300-EXIT.                                                      DTSCS22
01459      EXIT.                                                        DTSCS22
01460                                                                   DTSCS22
01461                                                                   DTSCS22
01462                                                                   DTSCS22
01463  S5900-SET-ATTRB.                                                 DTSCS22
01464      MOVE WRK-ATB-NUM                                             DTSCS22
01465        TO MAP-SELECT-LINE-NO-A.                                   DTSCS22
01466                                                                   DTSCS22
01467      MOVE CATB-ASKIP-BRT-MDTOFF                                   DTSCS22
01468        TO MAP-CONTROL-REMIT-AMT-A                                 DTSCS22
01469           MAP-CONTROL-TRAN-CNT-A                                  DTSCS22
01470           MAP-BALANCE-REMIT-AMT-A                                 DTSCS22
01471           MAP-BALANCE-TRAN-CNT-A                                  DTSCS22
01472           MAP-BATCH-STATUS-DSCR-1-A                               DTSCS22
01473           MAP-BATCH-STATUS-DSCR-2-A                               DTSCS22
01474           MAP-BATCH-STATUS-DSCR-3-A.                              DTSCS22
01475                                                                   DTSCS22
01476      PERFORM                                                      DTSCS22
01477        VARYING WRK-SUB FROM 1 BY 1                                DTSCS22
01478        UNTIL WRK-SUB > 12                                         DTSCS22
01479          MOVE CATB-ASKIP-BRT-MDTOFF                               DTSCS22
01480            TO MAP-LINE-A (WRK-SUB)                                DTSCS22
01481      END-PERFORM.                                                 DTSCS22
01482                                                                   DTSCS22
01483      MOVE CATB-UNPROT-BRT-AN-MDTON TO MAP-GOTO-A.                 DTSCS22
01484  S5900-EXIT.                                                      DTSCS22
01485      EXIT.                                                        DTSCS22
01486      EJECT                                                        DTSCS22
01487 /*****************************************************************DTSCS22
01488 * MAP ROUTINES                                                   *DTSCS22
01489 ******************************************************************DTSCS22
01490                                                                   DTSCS22
01491  S9100-RECEIVE.                                                   DTSCS22
01492      SET L851-RECEIVE-88 TO TRUE.                                 DTSCS22
01493                                                                   DTSCS22
01494      MOVE WRK-SCR-ID TO L851-SCR-ID.                              DTSCS22
01495                                                                   DTSCS22
01496      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS22
01497                                                                   DTSCS22
01498      MOVE L851-AID TO LCCM-AID.                                   DTSCS22
01499                                                                   DTSCS22
01500      MOVE L851-CURSOR TO LCCM-CURSOR.                             DTSCS22
01501  S9100-EXIT.                                                      DTSCS22
01502      EXIT.                                                        DTSCS22
01503                                                                   DTSCS22
01504                                                                   DTSCS22
01505                                                                   DTSCS22
01506  S9200-SEND-DATAONLY.                                             DTSCS22
01507      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS22
01508                                                                   DTSCS22
01509      IF LCCM-NO-MSG                                               DTSCS22
01510          NEXT SENTENCE                                            DTSCS22
01511      ELSE                                                         DTSCS22
01512          PERFORM S805-MSG-AREA THRU S805-EXIT.                    DTSCS22
01513                                                                   DTSCS22
01514      IF CURSOR-SET-GOTO                                           DTSCS22
01515          MOVE CATB-CURSOR TO MAP-GOTO-L                           DTSCS22
01516      ELSE                                                         DTSCS22
01517      IF LCCM-SCR-INQUIRE                                          DTSCS22
01518          MOVE CATB-CURSOR TO MAP-SELECT-LINE-NO-L                 DTSCS22
01519      ELSE                                                         DTSCS22
01520          MOVE CATB-CURSOR TO MAP-BATCH-NO-L.                      DTSCS22
01521                                                                   DTSCS22
01522      SET L851-SEND-DATAONLY-88 TO TRUE.                           DTSCS22
01523                                                                   DTSCS22
01524      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT.                  DTSCS22
01525                                                                   DTSCS22
01526      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS22
01527  S9200-EXIT.                                                      DTSCS22
01528      EXIT.                                                        DTSCS22
01529                                                                   DTSCS22
01530                                                                   DTSCS22
01531                                                                   DTSCS22
01532  S9300-SEND-MAP.                                                  DTSCS22
01533      MOVE  LCCM-TASK-START-DISP-DATE TO MAP-SYS-DATE.             DTSCS22
01534                                                                   DTSCS22
01535      MOVE  LCCM-TASK-START-DISP-TIME TO MAP-SYS-TIME.             DTSCS22
01536                                                                   DTSCS22
01537      MOVE  LCCM-CICS-REGION-NAME TO MAP-CICS-REGION-NAME.         DTSCS22
01538                                                                   DTSCS22
01539      PERFORM S9320-INQUIRY-FKEYS THRU S9320-EXIT.                 DTSCS22
01540                                                                   DTSCS22
01541 *****PERFORM S9330-DSCR-FIELDS THRU S9330-EXIT.                   DTSCS22
01542                                                                   DTSCS22
01543      PERFORM S805-MSG-AREA THRU S805-EXIT.                        DTSCS22
01544                                                                   DTSCS22
01545      IF CURSOR-SET-NO                                             DTSCS22
01546          MOVE CATB-CURSOR TO MAP-BATCH-NO-L.                      DTSCS22
01547                                                                   DTSCS22
01548      SET L851-SEND-88 TO TRUE.                                    DTSCS22
01549                                                                   DTSCS22
01550      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT.                  DTSCS22
01551                                                                   DTSCS22
01552      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS22
01553  S9300-EXIT.                                                      DTSCS22
01554      EXIT.                                                        DTSCS22
01555                                                                   DTSCS22
01556                                                                   DTSCS22
01557                                                                   DTSCS22
01558  S9320-INQUIRY-FKEYS.                                             DTSCS22
01559      MOVE CFKD-BACKWARD TO MAP-KEY-BACK.                          DTSCS22
01560                                                                   DTSCS22
01561      MOVE CFKD-FORWARD TO MAP-KEY-FWRD.                           DTSCS22
01562                                                                   DTSCS22
01563      MOVE 'F12=CLEAR' TO MAP-KEY-CLEAR.                           DTSCS22
01564  S9320-EXIT.                                                      DTSCS22
01565      EXIT.                                                        DTSCS22
01566                                                                   DTSCS22
01567                                                                   DTSCS22
01568                                                                   DTSCS22
01569 *S9330-DSCR-FIELDS.                                               DTSCS22
01570 *S9330-EXIT.                                                      DTSCS22
01571 *****EXIT.                                                        DTSCS22
01572                                                                   DTSCS22
01573                                                                   DTSCS22
01574                                                                   DTSCS22
01575  S9900-PREPARE-SEND.                                              DTSCS22
01576      MOVE WRK-SCR-ID TO L851-SCR-ID                               DTSCS22
01577                         LCCM-SCR-ID.                              DTSCS22
01578                                                                   DTSCS22
01579      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND.                    DTSCS22
01580                                                                   DTSCS22
01581      MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE.                         DTSCS22
01582  S9900-EXIT.                                                      DTSCS22
01583      EXIT.                                                        DTSCS22
