00001  IDENTIFICATION DIVISION.                                         08/29/00
00002  PROGRAM-ID.             DTSBR991.                                DTSBR991
00003  AUTHOR.                 MT DEPT OF LABOR/UI PROGRAMMING SECTION     LV007
00004  DATE-WRITTEN.           NOVEMBER 1994.                           DTSBR991
00005  DATE-COMPILED.                                                   DTSBR991
00006      SKIP3                                                        DTSBR991
00007 *****                                                             DTSBR991
00008 *                                                                 DTSBR991
00009 *    FUNCTION:  GENERATE EXPORT CONTROL REPORT                    DTSBR991
00010 *                                                                 DTSBR991
00011 *    MODIFICATION HISTORY:                                        DTSBR991
00012 *                                                                 DTSBR991
00013 * 08-28-00 XFER FROM REPORTWRITER TO COBOL II                     DTSBR991
00014 *                                         AUTHOR OF CHANGE - JHP  DTSBR991
00015 *                                                                 DTSBR991
00016 * 06-02-00 ADDED DATASET NAMES OF ALL EXPORT FILES                DTSBR991
00017 *                                         AUTHOR OF CHANGE - JHP  DTSBR991
00018 *                                                                 DTSBR991
00019 * 11-12-98 MODIFIED TO CONFORM TO DUTAS PROGRAMMING SPECIFICATIONSDTSBR991
00020 *          REFERENCE RFP #****            AUTHOR OF CHANGE - DVS  DTSBR991
00021 *                                                                 DTSBR991
00022 * 04-07-95 ADDED R991-UNIT-DSCR AND CHANGED THE REPORT ACCORDINGLYDTSBR991
00023 *          PER CHANGE REQUEST 064                                 DTSBR991
00024 *          REFERENCE RFP #RAP             AUTHOR OF CHANGE - SFW  DTSBR991
00025 *                                                                 DTSBR991
00026 * 11-02-94 INITIAL DEVELOPMENT                                    DTSBR991
00027 *          REFERENCE RFP #RAP             AUTHOR OF CHANGE - SFW  DTSBR991
00028 *                                                                 DTSBR991
00029 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR991
00030 *          XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR991
00031 *          REFERENCE RFP #****            AUTHOR OF CHANGE - XXX  DTSBR991
00032 *                                                                 DTSBR991
00033 *    DESCRIPTION:                                                 DTSBR991
00034 *                                                                 DTSBR991
00035 *        THIS MODULE GENERATES AN EXPORT CONTROL REPORT WHEN      DTSBR991
00036 *        CALLED BY THE REPORT MODULE WHICH ACTUALLY GENERATES     DTSBR991
00037 *        THE EXPORT FILE (DEFINED AS A DATASET CREATED BY THE     DTSBR991
00038 *        TAX SYSTEM TO BE USED OUTSIDE THE TAX SYSTEM - OFTEN     DTSBR991
00039 *        FOR DOWNLOADING TO PC SYSTEMS).                          DTSBR991
00040 *                                                                 DTSBR991
00041 *        (BUT PRIMARILY IN THIS SYSTEM EXPORT FILES ARE           DTSBR991
00042 *         CREATED CONTAINING A GIVEN "POPULATION" FROM WHICH      DTSBR991
00043 *         A "SAMPLE" CAN BE TAKEN FOR TPS (OR QC) FUNCTIONS.)     DTSBR991
00044 *                                                                 DTSBR991
00045 *    RECORDS READ:                                                DTSBR991
00046 *                                                                 DTSBR991
00047 *        NONE.                                                    DTSBR991
00048 *                                                                 DTSBR991
00049 *    PRINTED OUTPUTS:                                             DTSBR991
00050 *                                                                 DTSBR991
00051 *        991R1  EXPORT CONTROL REPORT                             DTSBR991
00052 *                                                                 DTSBR991
00053 *    RECORDS WRITTEN:                                             DTSBR991
00054 *                                                                 DTSBR991
00055 *        NONE.                                                    DTSBR991
00056 *                                                                 DTSBR991
00057 *    MODULES CALLED:                                              DTSBR991
00058 *                                                                 DTSBR991
00059 *        NONE.                                                    DTSBR991
00060 *                                                                 DTSBR991
00061 *****                                                             DTSBR991
00062      EJECT                                                        DTSBR991
00063  ENVIRONMENT DIVISION.                                            DTSBR991
00064      SKIP2                                                        DTSBR991
00065  INPUT-OUTPUT SECTION.                                            DTSBR991
00066      SKIP1                                                        DTSBR991
00067  FILE-CONTROL.                                                    DTSBR991
00068      SELECT PRT-FILE ASSIGN TO RPT991R1.                          DTSBR991
00069      SKIP3                                                        DTSBR991
00070  DATA DIVISION.                                                   DTSBR991
00071      SKIP3                                                        DTSBR991
00072  FILE SECTION.                                                    DTSBR991
00073      SKIP2                                                        DTSBR991
00074  FD  PRT-FILE                                                     DTSBR991
00075      LABEL RECORDS ARE OMITTED                                    DTSBR991
00076      RECORDING MODE IS F.                                         DTSBR991
00077  01  PRINT-RECORD                        PIC X(133).              DTSBR991
00078      SKIP3                                                        DTSBR991
00079  WORKING-STORAGE SECTION.                                         DTSBR991
000795 77  PAN-VALET PICTURE X(24) VALUE '007DTSBR991  08/29/00'.       DTSBR991
00080      SKIP3                                                        DTSBR991
00081  01  WRK-AREA.                                                    DTSBR991
00082      05  WRK-ABEND-CD                PIC S9(04)  COMP  VALUE +991.DTSBR991
00083      05  WRK-PAGE-CNT                PIC  9(05)  VALUE ZERO.      DTSBR991
00084      05  WS-STRING-LEFT-JUSTIFY      PIC  X(47)  VALUE SPACE.     DTSBR991
00085      05  WS-STRING-RIGHT-JUSTIFY     PIC  X(47)  VALUE SPACE.     DTSBR991
00086      05  WS-STRING-LENGTH            PIC S9(03)  COMP-3.          DTSBR991
00087                                                                   DTSBR991
00088  01  WRK-PRT-AREA.                                                DTSBR991
00089      05  WRK-PRT-HDR-01.                                          DTSBR991
00090          10  FILLER            PIC X(01) VALUE SPACE.             DTSBR991
00091          10  FILLER            PIC X(06) VALUE '991R1('.          DTSBR991
00092          10  WRK-PRT-SRC-MOD   PIC X(03) VALUE SPACE.             DTSBR991
00093          10  FILLER            PIC X(01) VALUE ')'.               DTSBR991
00094          10  FILLER            PIC X(30) VALUE SPACE.             DTSBR991
00095          10  WRK-PRT-AGNCY-LINE1                                  DTSBR991
00096                                PIC X(50) VALUE SPACE.             DTSBR991
00097          10  FILLER            PIC X(28) VALUE SPACE.             DTSBR991
00098          10  FILLER            PIC X(06) VALUE 'DATE: '.          DTSBR991
00099          10  WRK-PRT-SYS-DATE  PIC X(08) VALUE SPACE.             DTSBR991
00100      05  WRK-PRT-HDR-02.                                          DTSBR991
00101          10  FILLER            PIC X(01) VALUE SPACE.             DTSBR991
00102          10  FILLER            PIC X(40) VALUE SPACE.             DTSBR991
00103          10  WRK-PRT-AGNCY-LINE2                                  DTSBR991
00104                                PIC X(50) VALUE SPACE.             DTSBR991
00105          10  FILLER            PIC X(28) VALUE SPACE.             DTSBR991
00106          10  FILLER            PIC X(06) VALUE 'TIME: '.          DTSBR991
00107          10  WRK-PRT-SYS-TIME  PIC X(08) VALUE SPACE.             DTSBR991
00108      05  WRK-PRT-HDR-03.                                          DTSBR991
00109          10  FILLER            PIC X(01) VALUE SPACE.             DTSBR991
00110          10  FILLER            PIC X(10) VALUE 'ROUTE TO: '.      DTSBR991
00111          10  WRK-PRT-R991-RTE1 PIC X(40) VALUE SPACE.             DTSBR991
00112          10  FILLER            PIC X(68) VALUE SPACE.             DTSBR991
00113          10  FILLER            PIC X(08) VALUE 'PAGE:   '.        DTSBR991
00114          10  WRK-PRT-PAGE      PIC  ZZ,ZZ9.                       DTSBR991
00115      05  WRK-PRT-HDR-04.                                          DTSBR991
00116          10  FILLER            PIC X(01) VALUE SPACE.             DTSBR991
00117          10  FILLER            PIC X(10) VALUE SPACE.             DTSBR991
00118          10  WRK-PRT-R991-RTE2 PIC X(40) VALUE SPACE.             DTSBR991
00119          10  FILLER            PIC X(04) VALUE SPACE.             DTSBR991
00120          10  FILLER            PIC X(55)                          DTSBR991
00121                  VALUE 'EXPORT CONTROL REPORT'.                   DTSBR991
00122      05  WRK-PRT-DETAIL-01.                                       DTSBR991
00123          10  FILLER            PIC X(01) VALUE SPACE.             DTSBR991
00124          10  FILLER            PIC X(36) VALUE SPACE.             DTSBR991
00125          10  FILLER            PIC X(21)                          DTSBR991
00126                  VALUE 'TYPE OF DATA EXPORT: '.                   DTSBR991
00127          10  WRK-PRT-R991-DATA-TYPE                               DTSBR991
00128                                PIC X(60) VALUE SPACE.             DTSBR991
00129      05  WRK-PRT-DETAIL-02.                                       DTSBR991
00130          10  FILLER            PIC X(01) VALUE SPACE.             DTSBR991
00131          10  FILLER            PIC X(09) VALUE SPACE.             DTSBR991
00132          10  WRK-PRT-RGHT-JSTFY PIC X(47) VALUE SPACE.            DTSBR991
00133          10  WRK-PRT-R991-COUNT PIC  ZZ,ZZZ,ZZ9.                  DTSBR991
00134      05  WRK-PRT-DETAIL-03.                                       DTSBR991
00135          10  FILLER            PIC X(01) VALUE SPACE.             DTSBR991
00136          10  FILLER            PIC X(29) VALUE SPACE.             DTSBR991
00137          10  WRK-PRT-DSN-DESCR PIC X(28) VALUE SPACE.             DTSBR991
00138          10  WRK-PRT-DSN       PIC X(45) VALUE SPACE.             DTSBR991
00139      EJECT                                                        DTSBR991
00140  LINKAGE SECTION.                                                 DTSBR991
00141      SKIP3                                                        DTSBR991
00142  01  LRCM-LINK-AREA.                                              DTSBR991
00143  ++INCLUDE DTSILRCM                                               DTSBR991
00144      EJECT                                                        DTSBR991
00145  01  R991-REC.                                                    DTSBR991
00146  ++INCLUDE DTSIR991                                               DTSBR991
00147      EJECT                                                        DTSBR991
00148  PROCEDURE DIVISION USING LRCM-LINK-AREA                          DTSBR991
00149                           R991-REC.                               DTSBR991
00150      OPEN OUTPUT PRT-FILE.                                        DTSBR991
00151                                                                   DTSBR991
00152      MOVE R991-MOD                                                DTSBR991
00153           TO WRK-PRT-SRC-MOD.                                     DTSBR991
00154      MOVE LRCM-AGY-NAME-LINE1                                     DTSBR991
00155           TO WRK-PRT-AGNCY-LINE1.                                 DTSBR991
00156      MOVE LRCM-SYS-DATE                                           DTSBR991
00157           TO WRK-PRT-SYS-DATE.                                    DTSBR991
00158      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00159      WRITE PRINT-RECORD FROM WRK-PRT-HDR-01                       DTSBR991
00160          AFTER ADVANCING PAGE.                                    DTSBR991
00161                                                                   DTSBR991
00162      MOVE LRCM-AGY-NAME-LINE2                                     DTSBR991
00163           TO WRK-PRT-AGNCY-LINE2.                                 DTSBR991
00164      MOVE LRCM-SYS-TIME                                           DTSBR991
00165           TO WRK-PRT-SYS-TIME.                                    DTSBR991
00166      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00167      WRITE PRINT-RECORD FROM WRK-PRT-HDR-02                       DTSBR991
00168          AFTER ADVANCING  1  LINE.                                DTSBR991
00169                                                                   DTSBR991
00170      MOVE R991-ROUTE1                                             DTSBR991
00171           TO WRK-PRT-R991-RTE1.                                   DTSBR991
00172      ADD  1  TO WRK-PAGE-CNT.                                     DTSBR991
00173      MOVE WRK-PAGE-CNT                                            DTSBR991
00174           TO WRK-PRT-PAGE.                                        DTSBR991
00175      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00176      WRITE PRINT-RECORD FROM WRK-PRT-HDR-03                       DTSBR991
00177          AFTER ADVANCING  1  LINE.                                DTSBR991
00178                                                                   DTSBR991
00179      MOVE R991-ROUTE2                                             DTSBR991
00180           TO WRK-PRT-R991-RTE2.                                   DTSBR991
00181      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00182      WRITE PRINT-RECORD FROM WRK-PRT-HDR-04                       DTSBR991
00183          AFTER ADVANCING  1  LINE.                                DTSBR991
00184                                                                   DTSBR991
00185      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00186      WRITE PRINT-RECORD                                           DTSBR991
00187          AFTER ADVANCING  2  LINE.                                DTSBR991
00188                                                                   DTSBR991
00189      MOVE R991-DATA-TYPE                                          DTSBR991
00190           TO WRK-PRT-R991-DATA-TYPE.                              DTSBR991
00191      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00192      WRITE PRINT-RECORD FROM WRK-PRT-DETAIL-01                    DTSBR991
00193          AFTER ADVANCING  2  LINE.                                DTSBR991
00194                                                                   DTSBR991
00195      MOVE SPACES TO WS-STRING-LEFT-JUSTIFY.                       DTSBR991
00196      STRING 'NUMBER OF ' DELIMITED BY SIZE                        DTSBR991
00197             R991-UNIT-DSCR DELIMITED BY '  '                      DTSBR991
00198             ' ADDED TO EXPORT:' DELIMITED BY SIZE                 DTSBR991
00199         INTO                                                      DTSBR991
00200             WS-STRING-LEFT-JUSTIFY.                               DTSBR991
00201                                                                   DTSBR991
00202      MOVE +0 TO WS-STRING-LENGTH.                                 DTSBR991
00203      INSPECT WS-STRING-LEFT-JUSTIFY                               DTSBR991
00204         TALLYING WS-STRING-LENGTH                                 DTSBR991
00205         FOR CHARACTERS BEFORE INITIAL '  '.                       DTSBR991
00206      MOVE WS-STRING-LEFT-JUSTIFY (1:WS-STRING-LENGTH)             DTSBR991
00207         TO WS-STRING-RIGHT-JUSTIFY                                DTSBR991
00208             (48 - WS-STRING-LENGTH:WS-STRING-LENGTH).             DTSBR991
00209                                                                   DTSBR991
00210      MOVE WS-STRING-RIGHT-JUSTIFY                                 DTSBR991
00211         TO WRK-PRT-RGHT-JSTFY.                                    DTSBR991
00212                                                                   DTSBR991
00213      MOVE R991-UNIT-COUNT                                         DTSBR991
00214         TO WRK-PRT-R991-COUNT.                                    DTSBR991
00215      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00216      WRITE PRINT-RECORD FROM WRK-PRT-DETAIL-02                    DTSBR991
00217          AFTER ADVANCING  2  LINE.                                DTSBR991
00218                                                                   DTSBR991
00219      MOVE '       EXPORT DATASET NAME: '                          DTSBR991
00220         TO WRK-PRT-DSN-DESCR.                                     DTSBR991
00221                                                                   DTSBR991
00222      EVALUATE R991-MOD                                            DTSBR991
00223         WHEN '713'                                                DTSBR991
00224           MOVE 'DOESTAX.PROD.RPT713' TO WRK-PRT-DSN               DTSBR991
00225         WHEN '715'                                                DTSBR991
00226           MOVE 'DOESTAX.PROD.RPT715' TO WRK-PRT-DSN               DTSBR991
00227         WHEN '716'                                                DTSBR991
00228           MOVE 'DOESTAX.PROD.RPT716' TO WRK-PRT-DSN               DTSBR991
00229         WHEN '717'                                                DTSBR991
00230           MOVE 'DOESTAX.PROD.RPT717' TO WRK-PRT-DSN               DTSBR991
00231         WHEN '718'                                                DTSBR991
00232           MOVE 'DOESTAX.PROD.RPT718' TO WRK-PRT-DSN               DTSBR991
00233         WHEN '719'                                                DTSBR991
00234           MOVE 'DOESTAX.PROD.RPT719' TO WRK-PRT-DSN               DTSBR991
00235         WHEN '720'                                                DTSBR991
00236           MOVE 'DOESTAX.PROD.RPT720' TO WRK-PRT-DSN               DTSBR991
00237         WHEN '721'                                                DTSBR991
00238           MOVE 'DOESTAX.PROD.RPT721' TO WRK-PRT-DSN               DTSBR991
00239         WHEN '722'                                                DTSBR991
00240           MOVE 'DOESTAX.PROD.RPT722' TO WRK-PRT-DSN               DTSBR991
00241         WHEN '723'                                                DTSBR991
00242           MOVE 'DOESTAX.PROD.RPT723' TO WRK-PRT-DSN               DTSBR991
00243         WHEN '727'                                                DTSBR991
00244           MOVE 'DOESTAX.PROD.RPT727' TO WRK-PRT-DSN               DTSBR991
00245         WHEN OTHER                                                DTSBR991
00246           MOVE '**UNKNOWN DATA SET*' TO WRK-PRT-DSN               DTSBR991
00247      END-EVALUATE.                                                DTSBR991
00248                                                                   DTSBR991
00249      MOVE SPACE TO PRINT-RECORD.                                  DTSBR991
00250      WRITE PRINT-RECORD FROM WRK-PRT-DETAIL-03                    DTSBR991
00251          AFTER ADVANCING  1  LINE.                                DTSBR991
00252                                                                   DTSBR991
00253      CLOSE PRT-FILE.                                              DTSBR991
00254                                                                   DTSBR991
00255      GOBACK.                                                      DTSBR991
00256                                                                   DTSBR991
00257  S999-ABEND.                                                      DTSBR991
00258                                                                   DTSBR991
00259      CALL 'DTSBU999' USING WRK-ABEND-CD.                          DTSBR991
00260                                                                   DTSBR991
00261  S999-EXIT.                                                       DTSBR991
00262      EXIT.                                                        DTSBR991
