00001  IDENTIFICATION DIVISION.                                         06/27/01
00002  PROGRAM-ID.             DTSBR302.                                DTSBR302
00003  AUTHOR.                 MT DEPT OF LABOR/UI PROGRAMMING SECTION     LV047
00004  DATE-WRITTEN.           SEPTEMBER 1994.                          DTSBR302
00005                          MODIFIED DECEMBER, 1998 BDM/TRW          DTSBR302
00006  DATE-COMPILED.                                                   DTSBR302
00007      SKIP3                                                        DTSBR302
00008 *****                                                             DTSBR302
00009 * CALLING SEQUENCE:  DTSBD300 WRITES DTSIR302 RECORDS             DTSBR302
00010 *                    DTSBD800 CALLS DTSBR302 WHICH                DTSBR302
00011 *                       READS DTSIR302 RECORDS                    DTSBR302
00012 *                                                                 DTSBR302
00013 *    FUNCTION:  ACCOUNTING DETAIL REPORT.                         DTSBR302
00014 *                                                                 DTSBR302
00015 *    MODIFICATION HISTORY:                                        DTSBR302
00016 *                                                                 DTSBR302
00017 * 10-02-94 VERMONT TAX MODULE TXBR112 MODIFIED TO MEET MONTANA    DTSBR302
00018 *          TAX BUREAU NEEDS.                                      DTSBR302
00019 *          REFERENCE RFP #RAP             AUTHOR OF CHANGE - SFW  DTSBR302
00020 *                                                                 DTSBR302
00021 * 03-23-95 PUT "?" IN TWO PLACES ON HDR-1 SO USERS WILL KNOW      DTSBR302
00022 *          WHERE TO PUNCH HOLES SO REPORT CAN BE STORED IN A      DTSBR302
00023 *          TWO-HOLE BINDER...                                     DTSBR302
00024 *          REFERENCE RFP # TPR 15                PROGRAMMER: MJA  DTSBR302
00025 *                                                                 DTSBR302
00026 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR302
00027 *          XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX  DTSBR302
00028 *          REFERENCE RFP #****                   PROGRAMMER: XXX  DTSBR302
00029 *                                                                 DTSBR302
00030 *                                                                 DTSBR302
00031 *  DESCRIPTION:                                                   DTSBR302
00032 *                                                                 DTSBR302
00033 *      THIS MODULE DETAILS ALL BATCHES OF LIABILITY ACCOUNTING    DTSBR302
00034 *      TRANSACTIONS ON THE TRANSACTION COLLECTION FILE PROCESSED  DTSBR302
00035 *      BY THE SYSTEM DURING THE NIGHTLY UPDATE PROCESS.           DTSBR302
00036 *                                                                 DTSBR302
00037 *                                                                 DTSBR302
00038 *  PROCESSING:                                                    DTSBR302
00039 *                                                                 DTSBR302
00040 *      DETAIL:                                                    DTSBR302
00041 *                                                                 DTSBR302
00042 *        THIS REPORT IS A "SUMMARY" TYPE REPORT (NO DETAIL        DTSBR302
00043 *        PRINTING).                                               DTSBR302
00044 *                                                                 DTSBR302
00045 *        R302-BATCH-NO AND R302-ITEM-NO IDENTIFY A GIVEN          DTSBR302
00046 *        ACCOUNTING TRANSACTION.  FROM 1 TO N R302 RECORDS ARE    DTSBR302
00047 *        GENERATED FOR EACH ACCOUNTING TRANSACTION PROCESSED BY   DTSBR302
00048 *        THE DAILY UPDATE STEP.  ALL R302 RECORDS ASSOCIATED WITH DTSBR302
00049 *        A GIVEN TRANSACTION HAVE IDENTICAL VALUES IN THE         DTSBR302
00050 *        FOLLOWING FIELDS:                                        DTSBR302
00051 *                                                                 DTSBR302
00052 *          R302-DEPOSIT-DATE                                      DTSBR302
00053 *          R302-BATCH-NO                                          DTSBR302
00054 *          R302-EMP-NO                                            DTSBR302
00055 *          R302-ITEM-NO                                           DTSBR302
00056 *          R302-ACCT-REC-TYPE                                     DTSBR302
00057 *          R302-TRANS-TYPE                                        DTSBR302
00058 *          R302-APPLIC-YRQ                                        DTSBR302
00059 *          R302-APPLIC-ACCT-IND                                   DTSBR302
00060 *          R302-APPLIC-DOC-NO                                     DTSBR302
00061 *          R302-REMIT-AMT                                         DTSBR302
00062 *          R302-TOT-WAGE-CHNG                                     DTSBR302
00063 *          R302-TAX-WAGE-CHNG                                     DTSBR302
00064 *          R302-RESULT-IND.                                       DTSBR302
00065 *                                                                 DTSBR302
00066 *        WITH R302-REMIT-AMT REPLICATED ON MULTIPLE RECORDS       DTSBR302
00067 *        ASSOCIATED WITH A TRANSACTION, GREAT CARE MUST BE TAKEN  DTSBR302
00068 *        WHEN SUMMING R302-REMIT-AMT INTO THE "REMIT AMOUNT"      DTSBR302
00069 *        COLUMN TOTAL AND "REMITTANCE SUMMARY" AMOUNTS.           DTSBR302
00070 *                                                                 DTSBR302
00071 *      CONTROL BREAKS:                                            DTSBR302
00072 *                                                                 DTSBR302
00073 *      => R302-SORT-YRQ-ACCT-SEQ-IND:                             DTSBR302
00074 *                                                                 DTSBR302
00075 *          IF R302-OK-88                                          DTSBR302
00076 *              PRINT AN "AMOUNT" DETAIL LINE                      DTSBR302
00077 *          ELSE                                                   DTSBR302
00078 *              PRINT AN "ERROR" DETAIL LINE.                      DTSBR302
00079 *                                                                 DTSBR302
00080 *          THE REPORT COLUMNS ARE DERIVED AS FOLLOWS:             DTSBR302
00081 *                                                                 DTSBR302
00082 *            EMP NO           R302-EMP-NO                         DTSBR302
00083 *            ITEM             R302-ITEM-NO                        DTSBR302
00084 *            TRANS/TYPE       R302-ACCT-REC-TYPE,                 DTSBR302
00085 *                             R302-TRANS-TYPE                     DTSBR302
00086 *            REC DATE         R302-RECEIVED-DATE                  DTSBR302
00087 *            YR/Q             R302-APPLIC-YRQ (SPACES IF ZERO)    DTSBR302
00088 *            REMIT AMOUNT     R302-REMIT-AMT                      DTSBR302
00089 *            TOT WAGE CHANGE  R302-TOT-WAGE-CHNG                  DTSBR302
00090 *            TAX WAGE CHANGE  R302-TAX-WAGE-CHNG                  DTSBR302
00091 *            YR/Q             R302-YRQ (SPACES IF ALL '9')        DTSBR302
00092 *            D                R302-ACCT-IND                       DTSBR302
00093 *            CHARGED          R302-CHARGED-AMT                    DTSBR302
00094 *            PAID             R302-PAID-AMT                       DTSBR302
00095 *            WAIVED           R302-WAIVED-AMT                     DTSBR302
00096 *            WRITE OFF        R302-WRITTEN-OFF-AMT                DTSBR302
00097 *            TOLERANCE        R302-TOLER-AMT                      DTSBR302
00098 *                                                                 DTSBR302
00099 *            PMT/ADJ APPLIC   R302-APPLIC-YRQ (SPACES IF ZERO),   DTSBR302
00100 *                             R302-APPLIC-ACCT-IND,               DTSBR302
00101 *                             R302-APPLIC-BATCH-NO,               DTSBR302
00102 *                             R302-APPLIC-ITEM-NO                 DTSBR302
00103 *                                                                 DTSBR302
00104 *          EMP NO, ITEM, TRANS/TYPE, REC DATE, YR/Q (APPLIC),     DTSBR302
00105 *          REMIT AMOUNT, TOT WAGE CHANGE, TAX WAGE CHANGE, AND    DTSBR302
00106 *          PMT/ADJ APPLIC ARE PRINTED ONLY ON A CHANGE IN         DTSBR302
00107 *          R302-ITEM-NO.                                          DTSBR302
00108 *                                                                 DTSBR302
00109 *      => R302-ITEM-NO:                                           DTSBR302
00110 *                                                                 DTSBR302
00111 *          NEXT GROUP PLUS 2.                                     DTSBR302
00112 *                                                                 DTSBR302
00113 *      => R302-BATCH-NO:                                          DTSBR302
00114 *                                                                 DTSBR302
00115 *          NEXT GROUP NEXT PAGE.                                  DTSBR302
00116 *                                                                 DTSBR302
00117 *          "REMIT AMOUNT" COLUMN TOTAL IS PRINTED.                DTSBR302
00118 *                                                                 DTSBR302
00119 *          ONE PAGE OF SUMMARY INFORMATION IS PRINTED.  SEE THE   DTSBR302
00120 *          REPORT LAYOUT AND THE FOLLOWING FOR DETAILS.           DTSBR302
00121 *                                                                 DTSBR302
00122 *          DEFINITION OF "REMITTANCE SUMMARY" IS:                 DTSBR302
00123 *                                                                 DTSBR302
00124 *            IF FIRST RECORD ENCOUNTERED FOR R302-BATCH-NO        DTSBR302
00125 *                                        AND R302-ITEM-NO         DTSBR302
00126 *             IF R302-OK-88 AND (R302-REMIT-AMT > +0)             DTSBR302
00127 *              IF R302-TRANS-TYPE = 'PA'                          DTSBR302
00128 *                         OR                                      DTSBR302
00129 *                 R302-REC-TYPE-RPT-88                            DTSBR302
00130 *               ADD R302-REMIT-AMT TO "CASH PROCESSED"            DTSBR302
00131 *              ELSE                                               DTSBR302
00132 *              IF R302-TRANS-TYPE = 'PR'                          DTSBR302
00133 *               ADD R302-REMIT-AMT TO "PAYMENTS REVERSED"         DTSBR302
00134 *              ELSE                                               DTSBR302
00135 *              IF R302-TRANS-TYPE = 'NG'                          DTSBR302
00136 *               ADD R302-REMIT-AMT TO "NO GOOD CHECKS PROCESSED"  DTSBR302
00137 *              ELSE                                               DTSBR302
00138 *              IF R302-TRANS-TYPE = 'RF'                          DTSBR302
00139 *               ADD R302-REMIT-AMT TO "REFUND REQUESTS PROCESSED" DTSBR302
00140 *              ELSE                                               DTSBR302
00141 *              IF R302-TRANS-TYPE = 'RR'                          DTSBR302
00142 *               ADD R302-REMIT-AMT TO "REFUND REQUESTS REVERSED"  DTSBR302
00143 *              ELSE                                               DTSBR302
00144 *               ADD R302-REMIT-AMT TO "OTHER REMITTANCE".         DTSBR302
00145 *                                                                 DTSBR302
00146 *            DISPLAY "OTHER REMITTANCE" ONLY IF IT IS NON-ZERO.   DTSBR302
00147 *                                                                 DTSBR302
00148 *          DEFINITION OF "ACCOUNT SUMMARY" IS:                    DTSBR302
00149 *                                                                 DTSBR302
00150 *            IF R302-OK-88                                        DTSBR302
00151 *             IF R302-ACCT-IND = 'UI'                             DTSBR302
00152 *              ADD R302-CHARGED-AMT TO "CHARGED  " COLUMN         DTSBR302
00153 *                                  FOR "UI TAX"                   DTSBR302
00154 *              ADD R302-PAID-AMT    TO "PAID     " COLUMN         DTSBR302
00155 *                                  FOR "UI TAX"                   DTSBR302
00156 *              ADD R302-WAIVED-AMT  TO "WAIVED   " COLUMN         DTSBR302
00157 *                                  FOR "UI TAX"                   DTSBR302
00158 *              ADD R302-WRITTEN-OFF-AMT    TO "WRITTEN OFF" COLUMNDTSBR302
00159 *                                  FOR "UI TAX"                   DTSBR302
00160 *              ADD R302-TOLER-AMT   TO "TOLERANCE" COLUMN         DTSBR302
00161 *                                  FOR "UI TAX"                   DTSBR302
00162 *             ELSE                                                DTSBR302
00163 *             IF R302-ACCT-IND = 'SU'                             DTSBR302
00164 *              .........           FOR "SUR TAX"                  DTSBR302
00165 *             ELSE                                                DTSBR302
00166 *             IF R302-ACCT-IND = 'I '                             DTSBR302
00167 *              .........           FOR "INTEREST"                 DTSBR302
00168 *             ELSE                                                DTSBR302
00169 *             IF R302-ACCT-IND = 'LP'                             DTSBR302
00170 *              .........           FOR "LATE PENALTY"             DTSBR302
00171 *             ELSE                                                DTSBR302
00172 *             IF R302-ACCT-IND = 'NP'                             DTSBR302
00173 *              .........           FOR "NSF PENALTY"              DTSBR302
00174 *             ELSE                                                DTSBR302
00175 *             IF R302-ACCT-IND = 'MP'                             DTSBR302
00176 *              .........           FOR "MISCELLANEOUS PENALTY"    DTSBR302
00177 *             ELSE                                                DTSBR302
00178 *             IF R302-ACCT-IND = 'CR'                             DTSBR302
00179 *              .........           FOR "CREDIT"                   DTSBR302
00180 *             ELSE                                                DTSBR302
00181 *              .........           FOR "OTHER".                   DTSBR302
00182 *                                                                 DTSBR302
00183 *            THE "NET CHANGED" COLUMN IS A SUMMARY COLUMN         DTSBR302
00184 *            ("NET CHANGED" = "CHARGED" - "PAID" - "WAIVED"       DTSBR302
00185 *                               - "WRITTEN OFF" - "TOLERANCE").   DTSBR302
00186 *                                                                 DTSBR302
00187 *            ALL R302 RECORDS (WITH R302-OK-88) - NOT JUST THE    DTSBR302
00188 *            FIRST RECORD ENCOUNTERED FOR R302-BATCH-NO AND       DTSBR302
00189 *            R302-ITEM-NO - CONTRIBUTE TO THE "ACCOUNT SUMMARY".  DTSBR302
00190 *                                                                 DTSBR302
00191 *            DISPLAY "OTHER" LINE ONLY IF "OTHER" LINE IS NOT     DTSBR302
00192 *            EQUAL TO ZEROS.                                      DTSBR302
00193 *                                                                 DTSBR302
00194 *      => R302-DEPOSIT-DATE:                                      DTSBR302
00195 *                                                                 DTSBR302
00196 *          NEXT GROUP NEXT PAGE.                                  DTSBR302
00197 *                                                                 DTSBR302
00198 *          TWO PAGES OF CONTROL TOTALS ARE DISPLAYED AT A BREAK   DTSBR302
00199 *          IN R302-DEPOSIT-DATE.                                  DTSBR302
00200 *                                                                 DTSBR302
00201 *          THE FIRST PAGE IS IDENTICAL TO THE SUMMARY PAGE        DTSBR302
00202 *          DESCRIBED ABOVE FOR A BREAK IN R302-BATCH-NO EXCEPT    DTSBR302
00203 *          THAT "BATCH NUMBER" (AT THE TOP OF THE PAGE) BECOMES   DTSBR302
00204 *          SPACES AND ONLY THE DATE IS DISPLAYED.                 DTSBR302
00205 *                                                                 DTSBR302
00206 *          THE SECOND CONTROL TOTALS PAGE IS TRANSACTION SUMMARY  DTSBR302
00207 *          DATA.  THE TRANSACTION SUMMARY LINES COUNT THE NUMBER  DTSBR302
00208 *          OF R302-OK-88 TRANSACTIONS FOR THAT DATE.  INCREMENT   DTSBR302
00209 *          THE COUNTERS AT R302-ITEM-NO BREAK - THAT IS, WE ARE   DTSBR302
00210 *          COUNTING TRANSACTIONS, NOT R302 RECORDS.  THE COUNTS   DTSBR302
00211 *          ARE BASED ON R302-ACCT-REC-TYPE AND R302-TRANS-TYPE.   DTSBR302
00212 *          THE EXPECTED R302-ACCT-REC-TYPE AND R302-TRANS-TYPE    DTSBR302
00213 *          VALUES ARE AS FOLLOWS:                                 DTSBR302
00214 *                                                                 DTSBR302
00215 *            R302-ACCT-REC-TYPE   R302-TRANS-TYPE                 DTSBR302
00216 *                                                                 DTSBR302
00217 *                  R                   OR                         DTSBR302
00218 *                  R                   EA                         DTSBR302
00219 *                  R                   AU                         DTSBR302
00220 *                  R                   FS                         DTSBR302
00221 *                  R                   AC                         DTSBR302
00222 *                  R                   ES                         DTSBR302
00223 *                  R                   WD                         DTSBR302
00224 *                                                                 DTSBR302
00225 *                  P                   PA                         DTSBR302
00226 *                  P                   PR                         DTSBR302
00227 *                  P                   NG                         DTSBR302
00228 *                  P                   RF                         DTSBR302
00229 *                  P                   RR                         DTSBR302
00230 *                                                                 DTSBR302
00231 *                  A                   CH                         DTSBR302
00232 *                  A                   AB                         DTSBR302
00233 *                  A                   TL                         DTSBR302
00234 *                  A                   CA                         DTSBR302
00235 *                  A                   CM                         DTSBR302
00236 *                  A                   QD                         DTSBR302
00237 *                  A                   AD                         DTSBR302
00238 *                  A                   ID                         DTSBR302
00239 *                  A                   SP                         DTSBR302
00240 *                  A                   SR                         DTSBR302
00241 *                                                                 DTSBR302
00242 *            BE ABLE TO COUNT RECORDS WITH UNEXPECTED             DTSBR302
00243 *            R302-ACCT-REC-TYPE AND R302-TRANS-TYPE VALUES        DTSBR302
00244 *            IN AN "OTHER" BUCKET.  DISPLAY THE "OTHER" BUCKET    DTSBR302
00245 *            ONLY WHEN NOT ZERO.                                  DTSBR302
00246 *                                                                 DTSBR302
00247 *      => FINAL:                                                  DTSBR302
00248 *                                                                 DTSBR302
00249 *          TWO PAGES OF CONTROL TOTALS ARE DISPLAYED.  THE TOTALS DTSBR302
00250 *          ARE IDENTICAL TO THOSE TOTALS DESCRIBED ABOVE FOR A    DTSBR302
00251 *          BREAK IN R302-DEPOSIT-DATE EXCEPT THAT "ACCOUNTING     DTSBR302
00252 *          DATE" (AT THE TOP OF THE PAGE) BECOMES "GRAND TOTALS". DTSBR302
00253 *                                                                 DTSBR302
00254 *                                                                 DTSBR302
00255 *    RECORDS READ:                                                DTSBR302
00256 *                                                                 DTSBR302
00257 *        NONE.                                                    DTSBR302
00258 *                                                                 DTSBR302
00259 *                                                                 DTSBR302
00260 *    PRINTED OUTPUTS:                                             DTSBR302
00261 *                                                                 DTSBR302
00262 *        302R1  ACCOUNTING DETAIL REPORT                          DTSBR302
00263 *                                                                 DTSBR302
00264 *                                                                 DTSBR302
00265 *    RECORDS WRITTEN:                                             DTSBR302
00266 *                                                                 DTSBR302
00267 *        NONE.                                                    DTSBR302
00268 *                                                                 DTSBR302
00269 *                                                                 DTSBR302
00270 *    MODULES CALLED:                                              DTSBR302
00271 *                                                                 DTSBR302
00272 *        DTSBU001  DATE EDIT/CONVERSION MODULE                    DTSBR302
00273 *        DTSBU004  QUARTER EDIT/CONVERSION MODULE                 DTSBR302
00274 *                                                                 DTSBR302
00275 *                                                                 DTSBR302
00276 *****                                                             DTSBR302
00277      EJECT                                                        DTSBR302
00278  ENVIRONMENT DIVISION.                                            DTSBR302
00279      SKIP2                                                        DTSBR302
00280  INPUT-OUTPUT SECTION.                                            DTSBR302
00281      SKIP1                                                        DTSBR302
00282  FILE-CONTROL.                                                    DTSBR302
00283      SELECT PRT-FILE  ASSIGN TO RPT302R1.                         DTSBR302
00284      SKIP3                                                        DTSBR302
00285  DATA DIVISION.                                                   DTSBR302
00286      SKIP3                                                        DTSBR302
00287  FILE SECTION.                                                    DTSBR302
00288      SKIP3                                                        DTSBR302
00289  FD  PRT-FILE                                                     DTSBR302
00290      LABEL RECORDS ARE OMITTED                                    DTSBR302
00291      RECORD CONTAINS 180 CHARACTERS                               DTSBR302
00292      DATA RECORD IS PRT-REC                                       DTSBR302
00293      RECORDING MODE IS F.                                         DTSBR302
00294  01  PRT-REC.                                                     DTSBR302
00295      05 FILLER                     PIC  X(180).                   DTSBR302
00296      EJECT                                                        DTSBR302
00297  WORKING-STORAGE SECTION.                                         DTSBR302
002975 77  PAN-VALET PICTURE X(24) VALUE '047DTSBR302  06/27/01'.       DTSBR302
00298      SKIP3                                                        DTSBR302
00299  01  WRK-AREA-CONSTANTS.                                          DTSBR302
00300      05 WRK-ABEND-CD               PIC S9(04)  COMP   VALUE +302. DTSBR302
00301      05 FIRST-TIME-IND             PIC  X(01)         VALUE 'Y'.  DTSBR302
00302      05 MAX-LINE-CNT               PIC S9(03)  COMP-3 VALUE +60.  DTSBR302
00303      05 TRAN-YRQ-ACCT-SEQ-IND.                                    DTSBR302
00304         10 TRAN-YRQ                PIC S9(05)  COMP-3 VALUE +0.   DTSBR302
00305         10 TRAN-ACCT-SEQ           PIC S9(04)  COMP   VALUE +0.   DTSBR302
00306         10 TRAN-ACCT-IND           PIC  X(02)         VALUE '  '. DTSBR302
00307      SKIP3                                                        DTSBR302
00308  01  WRK-AREA.                                                    DTSBR302
00309      05 LINE-CNT                  PIC S9(03)  COMP-3.             DTSBR302
00310      05 PAGE-CNT                  PIC S9(05)  COMP-3.             DTSBR302
00311      SKIP1                                                        DTSBR302
00312      05 WS-PAGE-TRUNCATE          PIC  9(01).                     DTSBR302
00313          88 WS-ODD-PAGE-88                    VALUE 1 3 5 7 9.    DTSBR302
00314      05 WS-ADVANCE-LINE-IND       PIC  X(01).                     DTSBR302
00315          88 WS-ADVANCE-0LINES-88              VALUE '0'.          DTSBR302
00316          88 WS-ADVANCE-1LINE-88               VALUE '1'.          DTSBR302
00317          88 WS-ADVANCE-2LINES-88              VALUE '2'.          DTSBR302
00318          88 WS-ADVANCE-3LINES-88              VALUE '3'.          DTSBR302
00319          88 WS-ADVANCE-6LINES-88              VALUE '6'.          DTSBR302
00320          88 WS-ADVANCE-PAGE-88                VALUE 'P'.          DTSBR302
00321      SKIP1                                                        DTSBR302
00322      05 WRK-TRANS-TYPE            PIC  X(02)  VALUE SPACE.        DTSBR302
00323      SKIP1                                                        DTSBR302
00324      05 WRK-TBL-SUB               PIC S9(04)  COMP VALUE ZERO.    DTSBR302
00325      05 WRK-TBL-SUB1              PIC S9(04)  COMP VALUE ZERO.    DTSBR302
00326      05 WRK-TBL-SUB2              PIC S9(04)  COMP VALUE ZERO.    DTSBR302
00327      SKIP3                                                        DTSBR302
00328      05 HOLD-AREA.                                                DTSBR302
00329         10 HOLD-ACCOUNTING-DATE   PIC S9(09)  COMP-3 VALUE ZERO.  DTSBR302
00330         10 HOLD-DOC-NO.                                           DTSBR302
00331            15 HOLD-BATCH-NO       PIC S9(05)  COMP-3 VALUE ZERO.  DTSBR302
00332            15 HOLD-ITEM-NO        PIC S9(03)  COMP-3 VALUE ZERO.  DTSBR302
00333         10 HOLD-SORT-YRQ-ACCT-SEQ-IND.                            DTSBR302
00334            15 HOLD-SORT-YRQ       PIC S9(05)  COMP-3 VALUE ZERO.  DTSBR302
00335            15 HOLD-SORT-ACCT-SEQ  PIC S9(04)  COMP   VALUE ZERO.  DTSBR302
00336            15 HOLD-SORT-ACCT-IND  PIC  X(02)         VALUE SPACE. DTSBR302
00337      SKIP1                                                        DTSBR302
00338         10 HOLD-EMP-NO            PIC S9(07)  COMP-3 VALUE ZERO.  DTSBR302
00339         10 HOLD-RECEIVED-DATE     PIC S9(09)  COMP-3 VALUE ZERO.  DTSBR302
00340         10 HOLD-ACCT-REC-TYPE     PIC  X(01)         VALUE SPACE. DTSBR302
00341         10 HOLD-TRANS-TYPE        PIC  X(02)         VALUE SPACE. DTSBR302
00342         10 HOLD-APPLIC-YRQ        PIC S9(05)  COMP-3 VALUE ZERO.  DTSBR302
00343         10 HOLD-APPLIC-ACCT-IND   PIC  X(02)         VALUE SPACE. DTSBR302
00344         10 HOLD-APPLIC-DOC-NO.                                    DTSBR302
00345            15 HOLD-APPLIC-BATCH-NO                                DTSBR302
00346                                   PIC S9(05)  COMP-3 VALUE ZERO.  DTSBR302
00347            15 HOLD-APPLIC-ITEM-NO PIC S9(03)  COMP-3 VALUE ZERO.  DTSBR302
00348         10 HOLD-WAIVE-INT-IND     PIC  X(01)         VALUE SPACE. DTSBR302
00349         10 HOLD-WAIVE-PEN-IND     PIC  X(01)         VALUE SPACE. DTSBR302
00350         10 HOLD-REMIT-AMT         PIC S9(09)V9(02) COMP-3 VALUE 0.DTSBR302
00351         10 HOLD-TOT-WAGE-CHNG     PIC S9(11)V9(02) COMP-3 VALUE 0.DTSBR302
00352         10 HOLD-TAX-WAGE-CHNG     PIC S9(11)V9(02) COMP-3 VALUE 0.DTSBR302
00353         10 HOLD-RESULT-IND        PIC  X(01).                     DTSBR302
00354            88 HOLD-OK-88                 VALUE '0'.               DTSBR302
00355            88 HOLD-NOT-OK-88             VALUE '1'.               DTSBR302
00356      SKIP1                                                        DTSBR302
00357         10 HOLD-ERROR-AREA.                                       DTSBR302
00358            15 HOLD-ERROR-MSG-ID   PIC  X(03)         VALUE SPACE. DTSBR302
00359            15 HOLD-ERROR-MSG-TEXT PIC  X(60)         VALUE SPACE. DTSBR302
00360            15 HOLD-ERROR-MOD-NAME PIC  X(08)         VALUE SPACE. DTSBR302
00361      SKIP1                                                        DTSBR302
00362         10 HOLD-YRQ               PIC S9(05)  COMP-3 VALUE ZERO.  DTSBR302
00363         10 HOLD-ACCT-IND          PIC  X(02)         VALUE SPACE. DTSBR302
00364      SKIP1                                                        DTSBR302
00365         10 HOLD-CHARGED-AMT       PIC S9(09)V9(02) COMP-3 VALUE 0.DTSBR302
00366         10 HOLD-PAID-AMT          PIC S9(09)V9(02) COMP-3 VALUE 0.DTSBR302
00367         10 HOLD-WAIVED-AMT        PIC S9(09)V9(02) COMP-3 VALUE 0.DTSBR302
00368         10 HOLD-WRITEOFF-AMT      PIC S9(09)V9(02) COMP-3 VALUE 0.DTSBR302
00369         10 HOLD-TOLER-AMT         PIC S9(09)V9(02) COMP-3 VALUE 0.DTSBR302
00370      EJECT                                                        DTSBR302
00371  01  TBL-AREA.                                                    DTSBR302
00372      05 REMIT-LITERALS.                                           DTSBR302
00373         10 FILLER                 PIC  X(27)                      DTSBR302
00374               VALUE 'PACASH PROCESSED           '.                DTSBR302
00375         10 FILLER                 PIC  X(27)                      DTSBR302
00376               VALUE 'PRPAYMENTS REVERSED        '.                DTSBR302
00377         10 FILLER                 PIC  X(27)                      DTSBR302
00378               VALUE 'NGNO GOOD CHECKS PROCESSED '.                DTSBR302
00379         10 FILLER                 PIC  X(27)                      DTSBR302
00380               VALUE 'RFREFUND REQUESTS PROCESSED'.                DTSBR302
00381         10 FILLER                 PIC  X(27)                      DTSBR302
00382               VALUE 'RRREFUND REQUESTS REVERSED '.                DTSBR302
00383         10 FILLER                 PIC  X(27)                      DTSBR302
00384               VALUE '  OTHER                    '.                DTSBR302
00385         10 FILLER                 PIC  X(27)                      DTSBR302
00386               VALUE '        TOTAL              '.                DTSBR302
00387      05 FILLER REDEFINES REMIT-LITERALS.                          DTSBR302
00388         10 REMIT-LITERAL OCCURS 7 TIMES                           DTSBR302
00389                           INDEXED BY REMIT-LIT-IDX.               DTSBR302
00390            15 REMIT-LIT-ID       PIC  X(02).                      DTSBR302
00391            15 REMIT-LIT-NAME     PIC  X(25).                      DTSBR302
00392      SKIP1                                                        DTSBR302
00393      05 REMIT-WRK-SUB            PIC S9(04)  COMP    VALUE +0.    DTSBR302
00394      05 REMIT-ITEM-MAX           PIC S9(04)  COMP    VALUE +5.    DTSBR302
00395      05 REMIT-OTHER-SLOT         PIC S9(04)  COMP    VALUE +6.    DTSBR302
00396      05 REMIT-TOTAL-SLOT         PIC S9(04)  COMP    VALUE +7.    DTSBR302
00397      SKIP1                                                        DTSBR302
00398      05 REMIT-WRK-AREA-05.                                        DTSBR302
00399         10 FILLER                PIC S9(09)V9(02)    VALUE +0.    DTSBR302
00400         10 REMIT-WRK-AREA.                                        DTSBR302
00401            15 REMIT-WRK-AMT OCCURS 7 TIMES                        DTSBR302
00402                                  PIC S9(09)V9(02).                DTSBR302
00403      SKIP1                                                        DTSBR302
00404      05 REMIT-TBL-AREA-05.                                        DTSBR302
00405         10 FILLER                PIC S9(09)V9(02)    VALUE +0.    DTSBR302
00406         10 REMIT-TBL-AREAS.                                       DTSBR302
00407            15 REMIT-TBL-AREA   OCCURS 3 TIMES.                    DTSBR302
00408               20 REMIT-TBL-AMT OCCURS 7 TIMES                     DTSBR302
00409                                  PIC S9(09)V9(02).                DTSBR302
00410      SKIP3                                                        DTSBR302
00411      05 ACCT-LITERALS.                                            DTSBR302
00412         10 FILLER                 PIC  X(27)                      DTSBR302
00413               VALUE 'UIUI TAX            '.                       DTSBR302
00414         10 FILLER                 PIC  X(27)                      DTSBR302
00415               VALUE 'SUSUR TAX                  '.                DTSBR302
00416         10 FILLER                 PIC  X(27)                      DTSBR302
00417               VALUE 'I INTEREST                 '.                DTSBR302
00418         10 FILLER                 PIC  X(27)                      DTSBR302
00419               VALUE 'LPLATE PENALTY             '.                DTSBR302
00420         10 FILLER                 PIC  X(27)                      DTSBR302
00421               VALUE 'NPNSF PENALTY              '.                DTSBR302
00422         10 FILLER                 PIC  X(27)                      DTSBR302
00423               VALUE 'MPMISCELLANEOUS PENALTY    '.                DTSBR302
00424         10 FILLER                 PIC  X(27)                      DTSBR302
00425               VALUE 'CRCREDIT                   '.                DTSBR302
00426         10 FILLER                 PIC  X(27)                      DTSBR302
00427               VALUE '  OTHER                    '.                DTSBR302
00428         10 FILLER                 PIC  X(27)                      DTSBR302
00429               VALUE '       TOTAL               '.                DTSBR302
00430      05 FILLER REDEFINES ACCT-LITERALS.                           DTSBR302
00431         10 ACCT-LITERAL OCCURS 09 TIMES                           DTSBR302
00432                          INDEXED BY ACCT-LIT-IDX.                 DTSBR302
00433            15 ACCT-LIT-ID        PIC  X(02).                      DTSBR302
00434            15 ACCT-LIT-NAME      PIC  X(25).                      DTSBR302
00435      SKIP1                                                        DTSBR302
00436      05 ACCT-WRK-SUB             PIC S9(04)   COMP   VALUE +0.    DTSBR302
00437      05 ACCT-ITEM-MAX            PIC S9(04)   COMP   VALUE +7.    DTSBR302
00438      05 ACCT-OTHER-SLOT          PIC S9(04)   COMP   VALUE +8.    DTSBR302
00439      05 ACCT-TOTAL-SLOT          PIC S9(04)   COMP   VALUE +9.    DTSBR302
00440      SKIP1                                                        DTSBR302
00441      05 ACCT-WRK-AREA-05.                                         DTSBR302
00442         10 FILLER               PIC S9(09)V9(02) COMP-3 VALUE +0. DTSBR302
00443         10 ACCT-WRK-AREA.                                         DTSBR302
00444            15 ACCT-WRK-AMTS OCCURS 10 TIMES.                      DTSBR302
00445               20 ACCT-WRK-CHARGED-AMT    PIC S9(09)V9(02) COMP-3. DTSBR302
00446               20 ACCT-WRK-PAID-AMT       PIC S9(09)V9(02) COMP-3. DTSBR302
00447               20 ACCT-WRK-WAIVED-AMT     PIC S9(09)V9(02) COMP-3. DTSBR302
00448               20 ACCT-WRK-WRITEOFF-AMT   PIC S9(09)V9(02) COMP-3. DTSBR302
00449               20 ACCT-WRK-TOLER-AMT      PIC S9(09)V9(02) COMP-3. DTSBR302
00450               20 ACCT-WRK-NET-CHANGE-AMT PIC S9(09)V9(02) COMP-3. DTSBR302
00451      SKIP1                                                        DTSBR302
00452      05 ACCT-TBL-AREA-05.                                         DTSBR302
00453         10 FILLER               PIC S9(09)V9(02) COMP-3 VALUE +0. DTSBR302
00454         10 ACCT-TBL-AREAS.                                        DTSBR302
00455            15 ACCT-TBL-AREA OCCURS  3 TIMES.                      DTSBR302
00456               20 ACCT-TBL-AMTS OCCURS 10 TIMES.                   DTSBR302
00457                  25 ACCT-TBL-CHARGED-AMT                          DTSBR302
00458                                 PIC S9(09)V9(02) COMP-3.          DTSBR302
00459                  25 ACCT-TBL-PAID-AMT                             DTSBR302
00460                                 PIC S9(09)V9(02) COMP-3.          DTSBR302
00461                  25 ACCT-TBL-WAIVED-AMT                           DTSBR302
00462                                 PIC S9(09)V9(02) COMP-3.          DTSBR302
00463                  25 ACCT-TBL-WRITEOFF-AMT                         DTSBR302
00464                                 PIC S9(09)V9(02) COMP-3.          DTSBR302
00465                  25 ACCT-TBL-TOLER-AMT                            DTSBR302
00466                                 PIC S9(09)V9(02) COMP-3.          DTSBR302
00467                  25 ACCT-TBL-NET-CHANGE-AMT                       DTSBR302
00468                                 PIC S9(09)V9(02) COMP-3.          DTSBR302
00469      SKIP3                                                        DTSBR302
00470      05 TRAN-LITERALS.                                            DTSBR302
00471         10 FILLER              PIC  X(10)  VALUE '  R   OR  '.    DTSBR302
00472         10 FILLER              PIC  X(10)  VALUE '  R   EA  '.    DTSBR302
00473         10 FILLER              PIC  X(10)  VALUE '  R   AU  '.    DTSBR302
00474         10 FILLER              PIC  X(10)  VALUE '  R   FS  '.    DTSBR302
00475         10 FILLER              PIC  X(10)  VALUE '  R   AC  '.    DTSBR302
00476         10 FILLER              PIC  X(10)  VALUE '  R   ES  '.    DTSBR302
00477         10 FILLER              PIC  X(10)  VALUE '  R   WD  '.    DTSBR302
00478         10 FILLER              PIC  X(10)  VALUE '  R  OTHER'.    DTSBR302
00479         10 FILLER              PIC  X(10)  VALUE '  R  TOTAL'.    DTSBR302
00480         10 FILLER              PIC  X(10)  VALUE '  P   PA  '.    DTSBR302
00481         10 FILLER              PIC  X(10)  VALUE '  P   PR  '.    DTSBR302
00482         10 FILLER              PIC  X(10)  VALUE '  P   NG  '.    DTSBR302
00483         10 FILLER              PIC  X(10)  VALUE '  P   RF  '.    DTSBR302
00484         10 FILLER              PIC  X(10)  VALUE '  P   RR  '.    DTSBR302
00485         10 FILLER              PIC  X(10)  VALUE '  P  OTHER'.    DTSBR302
00486         10 FILLER              PIC  X(10)  VALUE '  P  TOTAL'.    DTSBR302
00487         10 FILLER              PIC  X(10)  VALUE '  A   CH  '.    DTSBR302
00488         10 FILLER              PIC  X(10)  VALUE '  A   AB  '.    DTSBR302
00489         10 FILLER              PIC  X(10)  VALUE '  A   TL  '.    DTSBR302
00490         10 FILLER              PIC  X(10)  VALUE '  A   CA  '.    DTSBR302
00491         10 FILLER              PIC  X(10)  VALUE '  A   CM  '.    DTSBR302
00492         10 FILLER              PIC  X(10)  VALUE '  A   QD  '.    DTSBR302
00493         10 FILLER              PIC  X(10)  VALUE '  A   AD  '.    DTSBR302
00494         10 FILLER              PIC  X(10)  VALUE '  A   ID  '.    DTSBR302
00495         10 FILLER              PIC  X(10)  VALUE '  A   SP  '.    DTSBR302
00496         10 FILLER              PIC  X(10)  VALUE '  A   SR  '.    DTSBR302
00497         10 FILLER              PIC  X(10)  VALUE '  A  OTHER'.    DTSBR302
00498         10 FILLER              PIC  X(10)  VALUE '  A  TOTAL'.    DTSBR302
00499         10 FILLER              PIC  X(10)  VALUE 'OTHER     '.    DTSBR302
00500         10 FILLER              PIC  X(10)  VALUE 'TOTAL     '.    DTSBR302
00501      SKIP1                                                        DTSBR302
00502      05 FILLER REDEFINES TRAN-LITERALS.                           DTSBR302
00503         10 TRAN-LITERAL OCCURS 30 TIMES                           DTSBR302
00504                         INDEXED BY TRAN-LIT-IDX.                  DTSBR302
00505            15 TRAN-LIT-REC-TYPE-5   PIC  X(05).                   DTSBR302
00506            15 TRAN-LIT-TYPE-5       PIC  X(05).                   DTSBR302
00507            15 FILLER REDEFINES TRAN-LIT-TYPE-5.                   DTSBR302
00508               20 FILLER             PIC  X(01).                   DTSBR302
00509               20 TRAN-LIT-TYPE      PIC  X(02).                   DTSBR302
00510               20 FILLER             PIC  X(02).                   DTSBR302
00511      SKIP1                                                        DTSBR302
00512      05 TRAN-WRK-SUB                PIC S9(04)  COMP  VALUE +0.   DTSBR302
00513      SKIP1                                                        DTSBR302
00514      05 TRAN-R-ITEM-MIN             PIC S9(04)  COMP  VALUE +1.   DTSBR302
00515      05 TRAN-R-ITEM-MAX             PIC S9(04)  COMP  VALUE +7.   DTSBR302
00516      05 TRAN-R-OTHER-SLOT           PIC S9(04)  COMP  VALUE +8.   DTSBR302
00517      05 TRAN-R-TOTAL-SLOT           PIC S9(04)  COMP  VALUE +9.   DTSBR302
00518      SKIP1                                                        DTSBR302
00519      05 TRAN-P-ITEM-MIN             PIC S9(04)  COMP  VALUE +10.  DTSBR302
00520      05 TRAN-P-ITEM-MAX             PIC S9(04)  COMP  VALUE +14.  DTSBR302
00521      05 TRAN-P-OTHER-SLOT           PIC S9(04)  COMP  VALUE +15.  DTSBR302
00522      05 TRAN-P-TOTAL-SLOT           PIC S9(04)  COMP  VALUE +16.  DTSBR302
00523      SKIP1                                                        DTSBR302
00524      05 TRAN-A-ITEM-MIN             PIC S9(04)  COMP  VALUE +17.  DTSBR302
00525      05 TRAN-A-ITEM-MAX             PIC S9(04)  COMP  VALUE +26.  DTSBR302
00526      05 TRAN-A-OTHER-SLOT           PIC S9(04)  COMP  VALUE +27.  DTSBR302
00527      05 TRAN-A-TOTAL-SLOT           PIC S9(04)  COMP  VALUE +28.  DTSBR302
00528      SKIP1                                                        DTSBR302
00529      05 TRAN-OTHER-OTHER-SLOT       PIC S9(04)  COMP  VALUE +29.  DTSBR302
00530      05 TRAN-TOTAL-TOTAL-SLOT       PIC S9(04)  COMP  VALUE +30.  DTSBR302
00531      SKIP1                                                        DTSBR302
00532      05 TRAN-WRK-AREA-05.                                         DTSBR302
00533         10 FILLER                   PIC S9(05) COMP-3 VALUE +0.   DTSBR302
00534         10 TRAN-WRK-AREA.                                         DTSBR302
00535            15 TRAN-WRK-UPDATED-CNT      OCCURS 30 TIMES           DTSBR302
00536                                     PIC S9(05) COMP-3.            DTSBR302
00537            15 TRAN-WRK-REJECTED-CNT     OCCURS 30 TIMES           DTSBR302
00538                                     PIC S9(05) COMP-3.            DTSBR302
00539      SKIP1                                                        DTSBR302
00540      05 TRAN-TBL-AREA-05.                                         DTSBR302
00541         10 FILLER                   PIC S9(05) COMP-3 VALUE +0.   DTSBR302
00542         10 TRAN-TBL-AREAS.                                        DTSBR302
00543            15 TRAN-TBL-AREA             OCCURS  3 TIMES.          DTSBR302
00544               20 TRAN-TBL-UPDATED-CNT   OCCURS 30 TIMES           DTSBR302
00545                                     PIC S9(05) COMP-3.            DTSBR302
00546               20 TRAN-TBL-REJECTED-CNT  OCCURS 30 TIMES           DTSBR302
00547                                     PIC S9(05) COMP-3.            DTSBR302
00548      EJECT                                                        DTSBR302
00549  01  HDR-LINES.                                                   DTSBR302
00550      05  HDR-1.                                                   DTSBR302
00551          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00552          10  FILLER                  PIC  X(05)  VALUE '302R1'.   DTSBR302
00553          10  FILLER                  PIC  X(17)  VALUE SPACES.    DTSBR302
00554          10  FILLER                  PIC  X(01)  VALUE '?'.       DTSBR302
00555          10  FILLER                  PIC  X(40)  VALUE SPACES.    DTSBR302
00556          10  HDR-1-AGY-NAME-LINE1    PIC  X(50).                  DTSBR302
00557          10  FILLER                  PIC  X(44)  VALUE SPACES.    DTSBR302
00558          10  FILLER                  PIC  X(01)  VALUE '?'.       DTSBR302
00559          10  FILLER                  PIC  X(06)  VALUE SPACES.    DTSBR302
00560          10  FILLER                  PIC  X(06)                   DTSBR302
00561                 VALUE 'DATE: '.                                   DTSBR302
00562          10  HDR-1-SYS-DATE          PIC  X(08).                  DTSBR302
00563          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00564      05  HDR-2.                                                   DTSBR302
00565          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00566          10  FILLER                  PIC  X(63)  VALUE SPACES.    DTSBR302
00567          10  HDR-2-AGY-NAME-LINE2    PIC  X(50).                  DTSBR302
00568          10  FILLER                  PIC  X(51)  VALUE SPACES.    DTSBR302
00569          10  FILLER                  PIC  X(06)                   DTSBR302
00570                 VALUE 'TIME: '.                                   DTSBR302
00571          10  HDR-2-SYS-TIME          PIC  X(08).                  DTSBR302
00572          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00573      05  HDR-3.                                                   DTSBR302
00574          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00575          10  FILLER                  PIC  X(25)                   DTSBR302
00576                 VALUE 'ROUTE TO:  TAX ACCOUNTING'.                DTSBR302
00577          10  FILLER                  PIC  X(139) VALUE SPACES.    DTSBR302
00578          10  FILLER                  PIC  X(08)                   DTSBR302
00579                 VALUE 'PAGE:   '.                                 DTSBR302
00580          10  HDR-2-PAGE              PIC  ZZ,ZZ9.                 DTSBR302
00581          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00582      05  HDR-4.                                                   DTSBR302
00583          10  FILLER                  PIC  X(65)  VALUE SPACES.    DTSBR302
00584          10  HDR-4-LITERAL           PIC  X(50).                  DTSBR302
00585      05  HDR-6.                                                   DTSBR302
00586          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00587          10  HDR-6-PAGE-LABEL        PIC  X(15).                  DTSBR302
00588          10  HDR-6-DEPOSIT-DATE      PIC  X(10).                  DTSBR302
00589          10  FILLER                  PIC  X(156) VALUE SPACES.    DTSBR302
00590      05  HDR-7.                                                   DTSBR302
00591          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00592          10  HDR-7-BATCH-LABEL       PIC  X(15).                  DTSBR302
00593          10  HDR-7-BATCH-NO          PIC  9(05).                  DTSBR302
00594          10  HDR-7-BATCH-NO-X REDEFINES HDR-7-BATCH-NO            DTSBR302
00595                                      PIC  X(05).                  DTSBR302
00596          10  FILLER                  PIC  X(159) VALUE SPACES.    DTSBR302
00597      SKIP3                                                        DTSBR302
00598      05  HDR-DET-COLUMNS1.                                        DTSBR302
00599          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00600          10  FILLER                  PIC  X(16)  VALUE SPACES.    DTSBR302
00601          10  FILLER                  PIC  X(40)                   DTSBR302
00602                 VALUE 'TRANS            APPLIC      REMIT      '. DTSBR302
00603          10  FILLER                  PIC  X(27)                   DTSBR302
00604                 VALUE '   TOT WAGE        TAX WAGE'.              DTSBR302
00605          10  FILLER                  PIC  X(80)  VALUE SPACES.    DTSBR302
00606          10  FILLER                  PIC  X(16)                   DTSBR302
00607                 VALUE 'PMT/ADJ APPLIC  '.                         DTSBR302
00608      05  HDR-DET-COLUMNS2.                                        DTSBR302
00609          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00610          10  FILLER                  PIC  X(40)                   DTSBR302
00611                 VALUE 'EMP NO   ITEM   /TYPE  REC DATE  YR/QTR '. DTSBR302
00612          10  FILLER                  PIC  X(40)                   DTSBR302
00613                 VALUE '     AMOUNT          CHANGE          CHA'. DTSBR302
00614          10  FILLER                  PIC  X(40)                   DTSBR302
00615                 VALUE 'NGE  YR/QTR  D       CHARGED         PAI'. DTSBR302
00616          10  FILLER                  PIC  X(40)                   DTSBR302
00617                 VALUE 'D       WAIVED  WRITTEN OFF   TOLERANCE '. DTSBR302
00618          10  FILLER                  PIC  X(19)                   DTSBR302
00619                 VALUE '  AC BATCH ITM I P '.                      DTSBR302
00620      SKIP3                                                        DTSBR302
00621      05  HDR-REMIT-1.                                             DTSBR302
00622          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00623          10  FILLER                  PIC  X(15)  VALUE SPACES.    DTSBR302
00624          10  FILLER                  PIC  X(27)                   DTSBR302
00625                 VALUE 'REMITTANCE SUMMARY         '.              DTSBR302
00626          10  FILLER                  PIC  X(07)  VALUE SPACES.    DTSBR302
00627          10  FILLER                  PIC  X(15)                   DTSBR302
00628                 VALUE '         AMOUNT'.                          DTSBR302
00629          10  FILLER                  PIC  X(115) VALUE SPACES.    DTSBR302
00630      05  HDR-REMIT-2.                                             DTSBR302
00631          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00632          10  FILLER                  PIC  X(15)  VALUE SPACES.    DTSBR302
00633          10  HDR-REMIT-2-DASH-1      PIC  X(27).                  DTSBR302
00634          10  FILLER                  PIC  X(07)  VALUE SPACES.    DTSBR302
00635          10  FILLER                  PIC  X(15)  VALUE ALL '-'.   DTSBR302
00636          10  FILLER                  PIC  X(115) VALUE SPACES.    DTSBR302
00637      SKIP3                                                        DTSBR302
00638      05  HDR-ACCT-1.                                              DTSBR302
00639          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00640          10  FILLER                  PIC  X(40)                   DTSBR302
00641                 VALUE '               ACCOUNT SUMMARY          '. DTSBR302
00642          10  FILLER                  PIC  X(40)                   DTSBR302
00643                 VALUE '   D           CHARGED                PA'. DTSBR302
00644          10  FILLER                  PIC  X(40)                   DTSBR302
00645                 VALUE 'ID              WAIVED       WRITTEN OFF'. DTSBR302
00646          10  FILLER                  PIC  X(40)                   DTSBR302
00647                 VALUE '         TOLERANCE          NET CHANGE  '. DTSBR302
00648          10  FILLER                  PIC  X(19)  VALUE SPACES.    DTSBR302
00649      05  HDR-ACCT-2.                                              DTSBR302
00650          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00651          10  FILLER                  PIC  X(40)                   DTSBR302
00652                 VALUE '               ------------------------ '. DTSBR302
00653          10  FILLER                  PIC  X(40)                   DTSBR302
00654                 VALUE '  ---   ---------------     ------------'. DTSBR302
00655          10  FILLER                  PIC  X(40)                   DTSBR302
00656                 VALUE '---     ---------------     ------------'. DTSBR302
00657          10  FILLER                  PIC  X(40)                   DTSBR302
00658                 VALUE '         ----------     --------------- '. DTSBR302
00659          10  FILLER                  PIC  X(19)  VALUE SPACES.    DTSBR302
00660      SKIP3                                                        DTSBR302
00661      05  HDR-TRAN-1.                                              DTSBR302
00662          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00663          10  FILLER                  PIC  X(78)  VALUE SPACES.    DTSBR302
00664          10  FILLER                  PIC  X(35)                   DTSBR302
00665                 VALUE 'TRAN          TRAN             TRAN'.      DTSBR302
00666          10  FILLER                  PIC  X(12)                   DTSBR302
00667                 VALUE '    CNT     '.                             DTSBR302
00668          10  FILLER                  PIC  X(54)  VALUE SPACES.    DTSBR302
00669      05  HDR-TRAN-2.                                              DTSBR302
00670          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00671          10  FILLER                  PIC  X(46)  VALUE SPACES.    DTSBR302
00672          10  FILLER                  PIC  X(19)                   DTSBR302
00673                 VALUE 'TRANSACTION SUMMARY'.                      DTSBR302
00674          10  FILLER                  PIC  X(13)  VALUE SPACES.    DTSBR302
00675          10  FILLER                  PIC  X(35)                   DTSBR302
00676                 VALUE ' CAT          TYPE          UPDATED'.      DTSBR302
00677          10  FILLER                  PIC  X(12)                   DTSBR302
00678                 VALUE '    REJECTED'.                             DTSBR302
00679          10  FILLER                  PIC  X(54)  VALUE SPACES.    DTSBR302
00680      05  HDR-TRAN-3.                                              DTSBR302
00681          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00682          10  FILLER                  PIC  X(46)  VALUE SPACES.    DTSBR302
00683          10  FILLER                  PIC  X(19)                   DTSBR302
00684                 VALUE '-------------------'.                      DTSBR302
00685          10  FILLER                  PIC  X(13)  VALUE SPACES.    DTSBR302
00686          10  FILLER                  PIC  X(35)                   DTSBR302
00687                 VALUE '----          ----          -------'.      DTSBR302
00688          10  FILLER                  PIC  X(12)                   DTSBR302
00689                 VALUE '------------'.                             DTSBR302
00690          10  FILLER                  PIC  X(54)  VALUE SPACES.    DTSBR302
00691      EJECT                                                        DTSBR302
00692  01  DET-LINES.                                                   DTSBR302
00693      05  DET-LINE.                                                DTSBR302
00694          10  FILLER                  PIC  X(01).                  DTSBR302
00695          10  DET-EMP-NO              PIC  999B999.                DTSBR302
00696          10  DET-EMP-NO-X REDEFINES DET-EMP-NO                    DTSBR302
00697                                      PIC  X(07).                  DTSBR302
00698          10  FILLER                  PIC  X(03).                  DTSBR302
00699          10  DET-ITEM-NO             PIC  9(03).                  DTSBR302
00700          10  FILLER                  PIC  X(03).                  DTSBR302
00701          10  DET-ACCT-REC-TYPE       PIC  X(01).                  DTSBR302
00702          10  FILLER                  PIC  X(01).                  DTSBR302
00703          10  DET-TRANS-TYPE          PIC  X(02).                  DTSBR302
00704          10  FILLER                  PIC  X(02).                  DTSBR302
00705          10  DET-OK-AREA.                                         DTSBR302
00706              15  DET-RECEIVED-DATE   PIC  X(10).                  DTSBR302
00707              15  FILLER              PIC  X(01).                  DTSBR302
00708              15  DET-APPLIC-YRQ      PIC  X(06).                  DTSBR302
00709              15  FILLER              PIC  X(01).                  DTSBR302
00710              15  DET-REMIT-AMT       PIC  -----,--9.99.           DTSBR302
00711              15  FILLER              PIC  X(01).                  DTSBR302
00712              15  DET-TOT-WAGE-CHNG   PIC  ----,---,--9.99.        DTSBR302
00713              15  FILLER              PIC  X(01).                  DTSBR302
00714              15  DET-TAX-WAGE-CHNG   PIC  ----,---,--9.99.        DTSBR302
00715              15  FILLER              PIC  X(01).                  DTSBR302
00716              15  DET-YRQ             PIC  X(06).                  DTSBR302
00717              15  FILLER              PIC  X(01).                  DTSBR302
00718              15  DET-ACCT-IND        PIC  X(02).                  DTSBR302
00719              15  FILLER              PIC  X(02).                  DTSBR302
00720              15  DET-CHARGED-AMT     PIC  ------,--9.99.          DTSBR302
00721              15  DET-PAID-AMT        PIC  ------,--9.99.          DTSBR302
00722              15  DET-WAIVED-AMT      PIC  ------,--9.99.          DTSBR302
00723              15  DET-WRITEOFF-AMT    PIC  ------,--9.99.          DTSBR302
00724              15  FILLER              PIC  X(02).                  DTSBR302
00725              15  DET-TOLER-AMT       PIC  ---,--9.99.             DTSBR302
00726              15  FILLER              PIC  X(02).                  DTSBR302
00727              15  DET-APPLIC-FIELDS.                               DTSBR302
00728                  20  DET-APPLIC-ACCT-IND PIC  X(02).              DTSBR302
00729                  20  FILLER              PIC  X(01).              DTSBR302
00730                  20  DET-APPLIC-BATCH-NO PIC  9(05).              DTSBR302
00731                  20  FILLER              PIC  X(01).              DTSBR302
00732                  20  DET-APPLIC-ITEM-NO  PIC  9(03).              DTSBR302
00733                  20  FILLER              PIC  X(01).              DTSBR302
00734                  20  DET-WAIVE-INT-IND   PIC  X(01).              DTSBR302
00735                  20  FILLER              PIC  X(01).              DTSBR302
00736                  20  DET-WAIVE-PEN-IND   PIC  X(01).              DTSBR302
00737                  20  FILLER              PIC  X(01).              DTSBR302
00738          10  DET-NOT-OK-AREA REDEFINES DET-OK-AREA.               DTSBR302
00739              15  FILLER              PIC  X(09).                  DTSBR302
00740              15  DET-ASTERISKS-1     PIC  X(25).                  DTSBR302
00741              15  FILLER              PIC  X(04).                  DTSBR302
00742              15  DET-ERROR-MSG-ID    PIC  X(03).                  DTSBR302
00743              15  FILLER              PIC  X(04).                  DTSBR302
00744              15  DET-ERROR-MSG-TEXT  PIC  X(60).                  DTSBR302
00745              15  FILLER              PIC  X(04).                  DTSBR302
00746              15  DET-ERROR-MOD-NAME  PIC  X(08).                  DTSBR302
00747              15  FILLER              PIC  X(04).                  DTSBR302
00748              15  DET-ASTERISKS-2     PIC  X(25).                  DTSBR302
00749              15  FILLER              PIC  X(10).                  DTSBR302
00750      SKIP3                                                        DTSBR302
00751      05  DET-BATCH-TOT-LINE.                                      DTSBR302
00752          10  FILLER                  PIC  X(01)  VALUE SPACE.     DTSBR302
00753          10  FILLER                  PIC  X(27)  VALUE SPACES.    DTSBR302
00754          10  FILLER                  PIC  X(10)                   DTSBR302
00755                 VALUE 'TOTAL     '.                               DTSBR302
00756          10  DET-BATCH-REMIT-TOT     PIC  ----,---,--9.99.        DTSBR302
00757          10  FILLER                  PIC  X(127) VALUE SPACES.    DTSBR302
00758      SKIP3                                                        DTSBR302
00759      05  DET-REMIT.                                               DTSBR302
00760          10  FILLER                  PIC  X(01).                  DTSBR302
00761          10  FILLER                  PIC  X(15).                  DTSBR302
00762          10  DET-REMIT-LINE-NAME     PIC  X(25).                  DTSBR302
00763          10  FILLER                  PIC  X(09).                  DTSBR302
00764          10  DET-REMIT-REMIT-AMT     PIC  ----,---,--9.99.        DTSBR302
00765          10  FILLER                  PIC  X(115).                 DTSBR302
00766      SKIP3                                                        DTSBR302
00767      05  DET-ACCT.                                                DTSBR302
00768          10  FILLER                  PIC  X(01).                  DTSBR302
00769          10  FILLER                  PIC  X(15).                  DTSBR302
00770          10  DET-ACCT-LINE-NAME      PIC  X(25).                  DTSBR302
00771          10  FILLER                  PIC  X(03).                  DTSBR302
00772          10  DET-ACCT-LINE-ID        PIC  X(02).                  DTSBR302
00773          10  FILLER                  PIC  X(04).                  DTSBR302
00774          10  DET-ACCT-CHARGED-AMT    PIC  ----,---,--9.99.        DTSBR302
00775          10  FILLER                  PIC  X(05).                  DTSBR302
00776          10  DET-ACCT-PAID-AMT       PIC  ----,---,--9.99.        DTSBR302
00777          10  FILLER                  PIC  X(05).                  DTSBR302
00778          10  DET-ACCT-WAIVED-AMT     PIC  ----,---,--9.99.        DTSBR302
00779          10  FILLER                  PIC  X(05).                  DTSBR302
00780          10  DET-ACCT-WRITEOFF-AMT   PIC  ----,---,--9.99.        DTSBR302
00781          10  FILLER                  PIC  X(05).                  DTSBR302
00782          10  DET-ACCT-TOLER-AMT      PIC  ----,--9.99.            DTSBR302
00783          10  FILLER                  PIC  X(05).                  DTSBR302
00784          10  DET-ACCT-NET-CHANGE-AMT PIC  ----,---,--9.99.        DTSBR302
00785          10  FILLER                  PIC  X(19).                  DTSBR302
00786      SKIP3                                                        DTSBR302
00787      05  DET-TRAN.                                                DTSBR302
00788          10  FILLER                  PIC  X(01).                  DTSBR302
00789          10  FILLER                  PIC  X(78).                  DTSBR302
00790          10  DET-TRAN-ACCT-REC-TYPE  PIC  X(05).                  DTSBR302
00791          10  FILLER                  PIC  X(09).                  DTSBR302
00792          10  DET-TRAN-TRANS-TYPE     PIC  X(05).                  DTSBR302
00793          10  FILLER                  PIC  X(10).                  DTSBR302
00794          10  DET-TRAN-UPDATED-CNT    PIC  ZZ,ZZ9.                 DTSBR302
00795          10  FILLER                  PIC  X(05).                  DTSBR302
00796          10  DET-TRAN-REJECTED-CNT   PIC  ZZ,ZZ9.                 DTSBR302
00797          10  FILLER                  PIC  X(55).                  DTSBR302
00798      EJECT                                                        DTSBR302
00799  01  L001-LINK-AREA.                                              DTSBR302
00800  ++INCLUDE DTSIL001                                               DTSBR302
00801      EJECT                                                        DTSBR302
00802  01  L004-LINK-AREA.                                              DTSBR302
00803  ++INCLUDE DTSIL004                                               DTSBR302
00804      EJECT                                                        DTSBR302
00805  ++INCLUDE DTSXL302                                               DTSBR302
00806      EJECT                                                        DTSBR302
00807  LINKAGE SECTION.                                                 DTSBR302
00808      SKIP3                                                        DTSBR302
00809  01  LRCM-LINK-AREA.                                              DTSBR302
00810  ++INCLUDE DTSILRCM                                               DTSBR302
00811      EJECT                                                        DTSBR302
00812  01  R302-REC.                                                    DTSBR302
00813  ++INCLUDE DTSIR302                                               DTSBR302
00814      EJECT                                                        DTSBR302
00815  PROCEDURE DIVISION USING LRCM-LINK-AREA                          DTSBR302
00816                           R302-REC.                               DTSBR302
00817      SKIP2                                                        DTSBR302
00818      IF FIRST-TIME-IND = 'Y'                                      DTSBR302
00819          PERFORM I1000-INITIATE THRU I1000-EXIT                   DTSBR302
00820          MOVE 'N' TO FIRST-TIME-IND.                              DTSBR302
00821      SKIP1                                                        DTSBR302
00822      IF LRCM-EOR-88                                               DTSBR302
00823          PERFORM T1000-TERMINATE THRU T1000-EXIT                  DTSBR302
00824      ELSE                                                         DTSBR302
00825          PERFORM P1000-PROCESS THRU P1000-EXIT.                   DTSBR302
00826      SKIP2                                                        DTSBR302
00827      GOBACK.                                                      DTSBR302
00828      EJECT                                                        DTSBR302
00829  I1000-INITIATE.                                                  DTSBR302
00830      SKIP1                                                        DTSBR302
00831      MOVE REMIT-WRK-AREA-05 TO REMIT-WRK-AREA.                    DTSBR302
00832      MOVE REMIT-TBL-AREA-05 TO REMIT-TBL-AREAS.                   DTSBR302
00833      MOVE ACCT-WRK-AREA-05  TO ACCT-WRK-AREA.                     DTSBR302
00834      MOVE ACCT-TBL-AREA-05  TO ACCT-TBL-AREAS.                    DTSBR302
00835      MOVE TRAN-WRK-AREA-05  TO TRAN-WRK-AREA.                     DTSBR302
00836      MOVE TRAN-TBL-AREA-05  TO TRAN-TBL-AREAS.                    DTSBR302
00837      OPEN OUTPUT PRT-FILE.                                        DTSBR302
00838      WRITE PRT-REC FROM XF-CA-CNTL-LIN0 AFTER PAGE.               DTSBR302
00839      WRITE PRT-REC FROM XF-PMODE-LIN0.                            DTSBR302
00840      WRITE PRT-REC FROM XF-CA-CNTL-LINE.                          DTSBR302
00841      WRITE PRT-REC FROM X2-CA-CNTL-LINE.                          DTSBR302
00842      WRITE PRT-REC FROM X3-CA-CNTL-LINE.                          DTSBR302
00843      WRITE PRT-REC FROM LINE-13 AFTER 13 LINES.                   DTSBR302
00844      WRITE PRT-REC FROM LINE-14.                                  DTSBR302
00845      WRITE PRT-REC FROM LINE-15.                                  DTSBR302
00846      WRITE PRT-REC FROM LINE-16.                                  DTSBR302
00847      WRITE PRT-REC FROM LINE-17.                                  DTSBR302
00848      MOVE SPACES TO PRT-REC.                                      DTSBR302
00849      WRITE PRT-REC FROM BLANK-LINE AFTER ADVANCING PAGE.          DTSBR302
00850      SKIP1                                                        DTSBR302
00851      MOVE +0 TO PAGE-CNT.                                         DTSBR302
00852      MOVE +0 TO LINE-CNT.                                         DTSBR302
00853      MOVE LRCM-AGY-NAME-LINE1 TO HDR-1-AGY-NAME-LINE1.            DTSBR302
00854      MOVE LRCM-AGY-NAME-LINE2 TO HDR-2-AGY-NAME-LINE2.            DTSBR302
00855      MOVE LRCM-SYS-DATE TO HDR-1-SYS-DATE.                        DTSBR302
00856      MOVE LRCM-SYS-TIME TO HDR-2-SYS-TIME.                        DTSBR302
00857      SKIP1                                                        DTSBR302
00858      MOVE 'DEPOSIT DATE:' TO HDR-6-PAGE-LABEL.                    DTSBR302
00859      PERFORM S2100-ACCOUNTING-DATE-INIT THRU S2100-EXIT.          DTSBR302
00860      SKIP1                                                        DTSBR302
00861      MOVE REMIT-TBL-AREA (2) TO REMIT-TBL-AREA (3).               DTSBR302
00862      MOVE ACCT-TBL-AREA (2)  TO ACCT-TBL-AREA (3).                DTSBR302
00863      MOVE TRAN-TBL-AREA (2)  TO TRAN-TBL-AREA (3).                DTSBR302
00864      SKIP2                                                        DTSBR302
00865  I1000-EXIT.                                                      DTSBR302
00866      EXIT.                                                        DTSBR302
00867      EJECT                                                        DTSBR302
00868  P1000-PROCESS.                                                   DTSBR302
00869      SKIP1                                                        DTSBR302
00870      IF R302-DEPOSIT-DATE NOT = HOLD-ACCOUNTING-DATE              DTSBR302
00871          PERFORM S1100-ACCOUNTING-DATE-BREAK THRU S1100-EXIT      DTSBR302
00872          PERFORM S2100-ACCOUNTING-DATE-INIT THRU S2100-EXIT       DTSBR302
00873      ELSE                                                         DTSBR302
00874      IF R302-BATCH-NO NOT = HOLD-BATCH-NO                         DTSBR302
00875          PERFORM S1200-BATCH-NO-BREAK THRU S1200-EXIT             DTSBR302
00876          PERFORM S2200-BATCH-NO-INIT THRU S2200-EXIT              DTSBR302
00877      ELSE                                                         DTSBR302
00878      IF R302-ITEM-NO NOT = HOLD-ITEM-NO                           DTSBR302
00879          PERFORM S1300-ITEM-NO-BREAK THRU S1300-EXIT              DTSBR302
00880          PERFORM S2300-ITEM-NO-INIT THRU S2300-EXIT               DTSBR302
00881      ELSE                                                         DTSBR302
00882      IF R302-SORT-YRQ-ACCT-SEQ-IND                                DTSBR302
00883         NOT = HOLD-SORT-YRQ-ACCT-SEQ-IND                          DTSBR302
00884          PERFORM S1400-YRQ-ACCT-IND-BREAK THRU S1400-EXIT         DTSBR302
00885          PERFORM S2400-YRQ-ACCT-IND-INIT THRU S2400-EXIT.         DTSBR302
00886      SKIP1                                                        DTSBR302
00887      IF (HOLD-OK-88) AND (R302-ACCT-DATA-88)                      DTSBR302
00888          ADD R302-CHARGED-AMT TO HOLD-CHARGED-AMT                 DTSBR302
00889          ADD R302-PAID-AMT TO HOLD-PAID-AMT                       DTSBR302
00890          ADD R302-WAIVED-AMT TO HOLD-WAIVED-AMT                   DTSBR302
00891          ADD R302-WRITTEN-OFF-AMT TO HOLD-WRITEOFF-AMT            DTSBR302
00892          ADD R302-TOLER-AMT TO HOLD-TOLER-AMT.                    DTSBR302
00893      SKIP2                                                        DTSBR302
00894  P1000-EXIT.                                                      DTSBR302
00895      EXIT.                                                        DTSBR302
00896      EJECT                                                        DTSBR302
00897  T1000-TERMINATE.                                                 DTSBR302
00898      SKIP1                                                        DTSBR302
00899      PERFORM S1100-ACCOUNTING-DATE-BREAK THRU S1100-EXIT.         DTSBR302
00900      SKIP1                                                        DTSBR302
00901      MOVE 'GRAND TOTALS      ' TO HDR-6-PAGE-LABEL.               DTSBR302
00902      MOVE SPACES TO HDR-6-DEPOSIT-DATE.                           DTSBR302
00903      MOVE +3 TO WRK-TBL-SUB.                                      DTSBR302
00904      MOVE SPACES TO HDR-4-LITERAL.                                DTSBR302
00905      PERFORM S6000-SUMMARY-PRINT-PAGE1 THRU S6000-EXIT.           DTSBR302
00906      PERFORM S7000-SUMMARY-PRINT-PAGE2 THRU S7000-EXIT.           DTSBR302
00907      SKIP1                                                        DTSBR302
00908      CLOSE PRT-FILE.                                              DTSBR302
00909      SKIP2                                                        DTSBR302
00910  T1000-EXIT.                                                      DTSBR302
00911      EXIT.                                                        DTSBR302
00912      EJECT                                                        DTSBR302
00913  S1100-ACCOUNTING-DATE-BREAK.                                     DTSBR302
00914      SKIP1                                                        DTSBR302
00915      PERFORM S1200-BATCH-NO-BREAK THRU S1200-EXIT.                DTSBR302
00916      SKIP1                                                        DTSBR302
00917      MOVE PAGE-CNT TO WS-PAGE-TRUNCATE.                           DTSBR302
00918      IF WS-ODD-PAGE-88                                            DTSBR302
00919          ADD +1 TO PAGE-CNT                                       DTSBR302
00920          SET WS-ADVANCE-PAGE-88 TO TRUE                           DTSBR302
00921          MOVE SPACES TO PRT-REC                                   DTSBR302
00922          PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                 DTSBR302
00923      SKIP1                                                        DTSBR302
00924      MOVE SPACE TO HDR-7-BATCH-LABEL HDR-7-BATCH-NO-X.            DTSBR302
00925      MOVE +2 TO WRK-TBL-SUB.                                      DTSBR302
00926      PERFORM S6000-SUMMARY-PRINT-PAGE1 THRU S6000-EXIT.           DTSBR302
00927      PERFORM S7000-SUMMARY-PRINT-PAGE2 THRU S7000-EXIT.           DTSBR302
00928      SKIP1                                                        DTSBR302
00929      MOVE +2 TO WRK-TBL-SUB1.                                     DTSBR302
00930      MOVE +3 TO WRK-TBL-SUB2.                                     DTSBR302
00931      PERFORM S8000-SUM-TABLES THRU S8000-EXIT.                    DTSBR302
00932      SKIP2                                                        DTSBR302
00933  S1100-EXIT.                                                      DTSBR302
00934      EXIT.                                                        DTSBR302
00935      EJECT                                                        DTSBR302
00936  S1200-BATCH-NO-BREAK.                                            DTSBR302
00937      SKIP1                                                        DTSBR302
00938      PERFORM S1300-ITEM-NO-BREAK THRU S1300-EXIT.                 DTSBR302
00939      SKIP1                                                        DTSBR302
00940      IF LINE-CNT >= (MAX-LINE-CNT - 2)                            DTSBR302
00941          PERFORM S1410-PAGE-BREAK THRU S1410-EXIT.                DTSBR302
00942      SKIP1                                                        DTSBR302
00943      MOVE REMIT-WRK-AMT (REMIT-TOTAL-SLOT)                        DTSBR302
00944         TO DET-BATCH-REMIT-TOT.                                   DTSBR302
00945      SET WS-ADVANCE-3LINES-88 TO TRUE.                            DTSBR302
00946      MOVE DET-BATCH-TOT-LINE TO PRT-REC.                          DTSBR302
00947      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
00948      SKIP1                                                        DTSBR302
00949      MOVE +1 TO WRK-TBL-SUB.                                      DTSBR302
00950      PERFORM S6000-SUMMARY-PRINT-PAGE1 THRU S6000-EXIT.           DTSBR302
00951      SKIP1                                                        DTSBR302
00952      MOVE +1 TO WRK-TBL-SUB1.                                     DTSBR302
00953      MOVE +2 TO WRK-TBL-SUB2.                                     DTSBR302
00954      PERFORM S8000-SUM-TABLES THRU S8000-EXIT.                    DTSBR302
00955      SKIP2                                                        DTSBR302
00956  S1200-EXIT.                                                      DTSBR302
00957      EXIT.                                                        DTSBR302
00958      EJECT                                                        DTSBR302
00959  S1300-ITEM-NO-BREAK.                                             DTSBR302
00960      SKIP1                                                        DTSBR302
00961      PERFORM S1330-INCR-TRAN-TBL THRU S1330-EXIT.                 DTSBR302
00962      IF HOLD-NOT-OK-88                                            DTSBR302
00963          PERFORM S1310-NOT-OK THRU S1310-EXIT                     DTSBR302
00964          GO TO S1300-EXIT.                                        DTSBR302
00965      PERFORM S1320-INCR-REMIT-TBL THRU S1320-EXIT.                DTSBR302
00966      IF HOLD-SORT-YRQ-ACCT-SEQ-IND = TRAN-YRQ-ACCT-SEQ-IND        DTSBR302
00967          PERFORM S1340-TRAN-ONLY THRU S1340-EXIT                  DTSBR302
00968          GO TO S1300-EXIT.                                        DTSBR302
00969      PERFORM S1400-YRQ-ACCT-IND-BREAK THRU S1400-EXIT.            DTSBR302
00970      SKIP2                                                        DTSBR302
00971  S1300-EXIT.                                                      DTSBR302
00972      EXIT.                                                        DTSBR302
00973      SKIP3                                                        DTSBR302
00974  S1310-NOT-OK.                                                    DTSBR302
00975      SKIP1                                                        DTSBR302
00976      IF LINE-CNT >= (MAX-LINE-CNT - 1)                            DTSBR302
00977          PERFORM S1410-PAGE-BREAK THRU S1410-EXIT.                DTSBR302
00978      SKIP1                                                        DTSBR302
00979      MOVE SPACE TO DET-NOT-OK-AREA.                               DTSBR302
00980      MOVE ALL '*' TO DET-ASTERISKS-1                              DTSBR302
00981                      DET-ASTERISKS-2.                             DTSBR302
00982      MOVE HOLD-ERROR-MSG-ID TO DET-ERROR-MSG-ID.                  DTSBR302
00983      MOVE HOLD-ERROR-MSG-TEXT TO DET-ERROR-MSG-TEXT.              DTSBR302
00984      MOVE HOLD-ERROR-MOD-NAME TO DET-ERROR-MOD-NAME.              DTSBR302
00985      SKIP1                                                        DTSBR302
00986      SET WS-ADVANCE-2LINES-88 TO TRUE.                            DTSBR302
00987      MOVE DET-LINE TO PRT-REC.                                    DTSBR302
00988      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
00989      SKIP2                                                        DTSBR302
00990  S1310-EXIT.                                                      DTSBR302
00991      EXIT.                                                        DTSBR302
00992      SKIP3                                                        DTSBR302
00993  S1320-INCR-REMIT-TBL.                                            DTSBR302
00994      SKIP1                                                        DTSBR302
00995      IF HOLD-REMIT-AMT = +0                                       DTSBR302
00996          GO TO S1320-EXIT.                                        DTSBR302
00997      SKIP1                                                        DTSBR302
00998      IF HOLD-ACCT-REC-TYPE = 'R'                                  DTSBR302
00999          MOVE 'PA' TO WRK-TRANS-TYPE                              DTSBR302
01000      ELSE                                                         DTSBR302
01001          MOVE HOLD-TRANS-TYPE TO WRK-TRANS-TYPE.                  DTSBR302
01002      SKIP1                                                        DTSBR302
01003      MOVE +0 TO REMIT-WRK-SUB.                                    DTSBR302
01004      PERFORM S1321-REMIT-LIT-LOOP                                 DTSBR302
01005         THRU S1321-EXIT                                           DTSBR302
01006           VARYING REMIT-LIT-IDX FROM 1 BY 1                       DTSBR302
01007             UNTIL REMIT-LIT-IDX > REMIT-ITEM-MAX                  DTSBR302
01008               OR  REMIT-WRK-SUB NOT = +0.                         DTSBR302
01009      IF REMIT-WRK-SUB = +0                                        DTSBR302
01010          MOVE REMIT-OTHER-SLOT TO REMIT-WRK-SUB.                  DTSBR302
01011      SKIP1                                                        DTSBR302
01012      MOVE REMIT-TBL-AREA (1) TO REMIT-WRK-AREA.                   DTSBR302
01013      SKIP1                                                        DTSBR302
01014      ADD HOLD-REMIT-AMT TO REMIT-WRK-AMT (REMIT-WRK-SUB)          DTSBR302
01015                            REMIT-WRK-AMT (REMIT-TOTAL-SLOT).      DTSBR302
01016      SKIP1                                                        DTSBR302
01017      MOVE REMIT-WRK-AREA TO REMIT-TBL-AREA (1).                   DTSBR302
01018      SKIP2                                                        DTSBR302
01019  S1320-EXIT.                                                      DTSBR302
01020      EXIT.                                                        DTSBR302
01021      SKIP3                                                        DTSBR302
01022  S1321-REMIT-LIT-LOOP.                                            DTSBR302
01023      SKIP1                                                        DTSBR302
01024      IF WRK-TRANS-TYPE = REMIT-LIT-ID (REMIT-LIT-IDX)             DTSBR302
01025          SET REMIT-WRK-SUB TO REMIT-LIT-IDX.                      DTSBR302
01026      SKIP2                                                        DTSBR302
01027  S1321-EXIT.                                                      DTSBR302
01028      EXIT.                                                        DTSBR302
01029      SKIP3                                                        DTSBR302
01030  S1330-INCR-TRAN-TBL.                                             DTSBR302
01031      SKIP1                                                        DTSBR302
01032      MOVE TRAN-TBL-AREA (1) TO TRAN-WRK-AREA.                     DTSBR302
01033      SKIP1                                                        DTSBR302
01034      IF HOLD-ACCT-REC-TYPE = 'R'                                  DTSBR302
01035          PERFORM S1331-R-TRAN-CNT THRU S1331-EXIT                 DTSBR302
01036      ELSE                                                         DTSBR302
01037      IF HOLD-ACCT-REC-TYPE = 'P'                                  DTSBR302
01038          PERFORM S1333-P-TRAN-CNT THRU S1333-EXIT                 DTSBR302
01039      ELSE                                                         DTSBR302
01040      IF HOLD-ACCT-REC-TYPE = 'A'                                  DTSBR302
01041          PERFORM S1335-A-TRAN-CNT THRU S1335-EXIT                 DTSBR302
01042      ELSE                                                         DTSBR302
01043      IF HOLD-NOT-OK-88                                            DTSBR302
01044          ADD +1 TO TRAN-WRK-REJECTED-CNT (TRAN-OTHER-OTHER-SLOT)  DTSBR302
01045                    TRAN-WRK-REJECTED-CNT (TRAN-TOTAL-TOTAL-SLOT)  DTSBR302
01046      ELSE                                                         DTSBR302
01047          ADD +1 TO TRAN-WRK-UPDATED-CNT (TRAN-OTHER-OTHER-SLOT)   DTSBR302
01048                    TRAN-WRK-UPDATED-CNT (TRAN-TOTAL-TOTAL-SLOT).  DTSBR302
01049      SKIP1                                                        DTSBR302
01050      MOVE TRAN-WRK-AREA TO TRAN-TBL-AREA (1).                     DTSBR302
01051      SKIP2                                                        DTSBR302
01052  S1330-EXIT.                                                      DTSBR302
01053      EXIT.                                                        DTSBR302
01054      SKIP3                                                        DTSBR302
01055  S1331-R-TRAN-CNT.                                                DTSBR302
01056      SKIP1                                                        DTSBR302
01057      MOVE +0 TO TRAN-WRK-SUB.                                     DTSBR302
01058      PERFORM S1339-TRAN-LIT-LOOP                                  DTSBR302
01059         THRU S1339-EXIT                                           DTSBR302
01060           VARYING TRAN-LIT-IDX FROM TRAN-R-ITEM-MIN BY 1          DTSBR302
01061             UNTIL TRAN-LIT-IDX > TRAN-R-ITEM-MAX                  DTSBR302
01062               OR  TRAN-WRK-SUB NOT = +0.                          DTSBR302
01063      SKIP1                                                        DTSBR302
01064      IF TRAN-WRK-SUB = +0                                         DTSBR302
01065          MOVE TRAN-R-OTHER-SLOT TO TRAN-WRK-SUB.                  DTSBR302
01066      SKIP1                                                        DTSBR302
01067      IF HOLD-NOT-OK-88                                            DTSBR302
01068          ADD +1 TO TRAN-WRK-REJECTED-CNT (TRAN-WRK-SUB)           DTSBR302
01069                    TRAN-WRK-REJECTED-CNT (TRAN-R-TOTAL-SLOT)      DTSBR302
01070                    TRAN-WRK-REJECTED-CNT (TRAN-TOTAL-TOTAL-SLOT)  DTSBR302
01071      ELSE                                                         DTSBR302
01072          ADD +1 TO TRAN-WRK-UPDATED-CNT (TRAN-WRK-SUB)            DTSBR302
01073                    TRAN-WRK-UPDATED-CNT (TRAN-R-TOTAL-SLOT)       DTSBR302
01074                    TRAN-WRK-UPDATED-CNT (TRAN-TOTAL-TOTAL-SLOT).  DTSBR302
01075      SKIP2                                                        DTSBR302
01076  S1331-EXIT.                                                      DTSBR302
01077      EXIT.                                                        DTSBR302
01078      SKIP3                                                        DTSBR302
01079  S1333-P-TRAN-CNT.                                                DTSBR302
01080      SKIP1                                                        DTSBR302
01081      MOVE +0 TO TRAN-WRK-SUB.                                     DTSBR302
01082      PERFORM S1339-TRAN-LIT-LOOP                                  DTSBR302
01083         THRU S1339-EXIT                                           DTSBR302
01084           VARYING TRAN-LIT-IDX FROM TRAN-P-ITEM-MIN BY 1          DTSBR302
01085             UNTIL TRAN-LIT-IDX > TRAN-P-ITEM-MAX                  DTSBR302
01086               OR  TRAN-WRK-SUB NOT = +0.                          DTSBR302
01087      SKIP1                                                        DTSBR302
01088      IF TRAN-WRK-SUB = +0                                         DTSBR302
01089          MOVE TRAN-P-OTHER-SLOT TO TRAN-WRK-SUB.                  DTSBR302
01090      SKIP1                                                        DTSBR302
01091      IF HOLD-NOT-OK-88                                            DTSBR302
01092          ADD +1 TO TRAN-WRK-REJECTED-CNT (TRAN-WRK-SUB)           DTSBR302
01093                    TRAN-WRK-REJECTED-CNT (TRAN-P-TOTAL-SLOT)      DTSBR302
01094                    TRAN-WRK-REJECTED-CNT (TRAN-TOTAL-TOTAL-SLOT)  DTSBR302
01095      ELSE                                                         DTSBR302
01096          ADD +1 TO TRAN-WRK-UPDATED-CNT (TRAN-WRK-SUB)            DTSBR302
01097                    TRAN-WRK-UPDATED-CNT (TRAN-P-TOTAL-SLOT)       DTSBR302
01098                    TRAN-WRK-UPDATED-CNT (TRAN-TOTAL-TOTAL-SLOT).  DTSBR302
01099      SKIP2                                                        DTSBR302
01100  S1333-EXIT.                                                      DTSBR302
01101      EXIT.                                                        DTSBR302
01102      SKIP3                                                        DTSBR302
01103  S1335-A-TRAN-CNT.                                                DTSBR302
01104      SKIP1                                                        DTSBR302
01105      MOVE +0 TO TRAN-WRK-SUB.                                     DTSBR302
01106      PERFORM S1339-TRAN-LIT-LOOP                                  DTSBR302
01107         THRU S1339-EXIT                                           DTSBR302
01108           VARYING TRAN-LIT-IDX FROM TRAN-A-ITEM-MIN BY 1          DTSBR302
01109             UNTIL TRAN-LIT-IDX   >  TRAN-A-ITEM-MAX               DTSBR302
01110               OR  TRAN-WRK-SUB NOT = +0.                          DTSBR302
01111      SKIP1                                                        DTSBR302
01112      IF TRAN-WRK-SUB = +0                                         DTSBR302
01113          MOVE TRAN-A-OTHER-SLOT TO TRAN-WRK-SUB.                  DTSBR302
01114      SKIP1                                                        DTSBR302
01115      IF HOLD-NOT-OK-88                                            DTSBR302
01116          ADD +1 TO TRAN-WRK-REJECTED-CNT (TRAN-WRK-SUB)           DTSBR302
01117                    TRAN-WRK-REJECTED-CNT (TRAN-A-TOTAL-SLOT)      DTSBR302
01118                    TRAN-WRK-REJECTED-CNT (TRAN-TOTAL-TOTAL-SLOT)  DTSBR302
01119      ELSE                                                         DTSBR302
01120          ADD +1 TO TRAN-WRK-UPDATED-CNT (TRAN-WRK-SUB)            DTSBR302
01121                    TRAN-WRK-UPDATED-CNT (TRAN-A-TOTAL-SLOT)       DTSBR302
01122                    TRAN-WRK-UPDATED-CNT (TRAN-TOTAL-TOTAL-SLOT).  DTSBR302
01123      SKIP2                                                        DTSBR302
01124  S1335-EXIT.                                                      DTSBR302
01125      EXIT.                                                        DTSBR302
01126      SKIP3                                                        DTSBR302
01127  S1339-TRAN-LIT-LOOP.                                             DTSBR302
01128      SKIP1                                                        DTSBR302
01129      IF TRAN-LIT-TYPE (TRAN-LIT-IDX) = HOLD-TRANS-TYPE            DTSBR302
01130          SET TRAN-WRK-SUB TO TRAN-LIT-IDX.                        DTSBR302
01131      SKIP2                                                        DTSBR302
01132  S1339-EXIT.                                                      DTSBR302
01133      EXIT.                                                        DTSBR302
01134      SKIP3                                                        DTSBR302
01135  S1340-TRAN-ONLY.                                                 DTSBR302
01136      SKIP1                                                        DTSBR302
01137      IF LINE-CNT >= (MAX-LINE-CNT - 1)                            DTSBR302
01138          PERFORM S1410-PAGE-BREAK THRU S1410-EXIT.                DTSBR302
01139      SKIP1                                                        DTSBR302
01140      SET WS-ADVANCE-2LINES-88 TO TRUE.                            DTSBR302
01141      MOVE DET-LINE TO PRT-REC.                                    DTSBR302
01142      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01143      SKIP2                                                        DTSBR302
01144  S1340-EXIT.                                                      DTSBR302
01145      EXIT.                                                        DTSBR302
01146      SKIP3                                                        DTSBR302
01147  S1400-YRQ-ACCT-IND-BREAK.                                        DTSBR302
01148      SKIP1                                                        DTSBR302
01149      IF HOLD-NOT-OK-88                                            DTSBR302
01150      OR HOLD-SORT-YRQ-ACCT-SEQ-IND = TRAN-YRQ-ACCT-SEQ-IND        DTSBR302
01151          GO TO S1400-EXIT.                                        DTSBR302
01152      SKIP1                                                        DTSBR302
01153      IF DET-EMP-NO-X = SPACES                                     DTSBR302
01154          IF LINE-CNT >= MAX-LINE-CNT                              DTSBR302
01155              PERFORM S1410-PAGE-BREAK THRU S1410-EXIT             DTSBR302
01156          ELSE                                                     DTSBR302
01157              NEXT SENTENCE                                        DTSBR302
01158      ELSE                                                         DTSBR302
01159          IF LINE-CNT >= (MAX-LINE-CNT - 1)                        DTSBR302
01160              PERFORM S1410-PAGE-BREAK THRU S1410-EXIT             DTSBR302
01161          ELSE                                                     DTSBR302
01162              NEXT SENTENCE.                                       DTSBR302
01163      SKIP1                                                        DTSBR302
01164      PERFORM S1420-BUILD-DET-LINE THRU S1420-EXIT.                DTSBR302
01165      IF DET-EMP-NO-X = SPACES                                     DTSBR302
01166          SET WS-ADVANCE-1LINE-88 TO TRUE                          DTSBR302
01167      ELSE                                                         DTSBR302
01168          SET WS-ADVANCE-2LINES-88 TO TRUE.                        DTSBR302
01169      MOVE DET-LINE TO PRT-REC.                                    DTSBR302
01170      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01171      MOVE SPACES TO DET-LINE.                                     DTSBR302
01172      SKIP1                                                        DTSBR302
01173      PERFORM S1440-INCR-ACCT-TBL THRU S1440-EXIT.                 DTSBR302
01174      SKIP2                                                        DTSBR302
01175  S1400-EXIT.                                                      DTSBR302
01176      EXIT.                                                        DTSBR302
01177      SKIP3                                                        DTSBR302
01178  S1410-PAGE-BREAK.                                                DTSBR302
01179      SKIP1                                                        DTSBR302
01180      MOVE '            ACCOUNTING DETAIL REPORT' TO HDR-4-LITERAL.DTSBR302
01181      PERFORM S9800-COMMON-HEADING THRU S9800-EXIT.                DTSBR302
01182      SKIP1                                                        DTSBR302
01183      SET WS-ADVANCE-2LINES-88 TO TRUE.                            DTSBR302
01184      MOVE HDR-DET-COLUMNS1 TO PRT-REC.                            DTSBR302
01185      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01186      SKIP1                                                        DTSBR302
01187      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01188      MOVE HDR-DET-COLUMNS2 TO PRT-REC.                            DTSBR302
01189      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01190      SKIP1                                                        DTSBR302
01191      MOVE HOLD-EMP-NO TO DET-EMP-NO.                              DTSBR302
01192      MOVE HOLD-ITEM-NO TO DET-ITEM-NO.                            DTSBR302
01193      MOVE HOLD-ACCT-REC-TYPE TO DET-ACCT-REC-TYPE.                DTSBR302
01194      MOVE HOLD-TRANS-TYPE TO DET-TRANS-TYPE.                      DTSBR302
01195      SKIP2                                                        DTSBR302
01196  S1410-EXIT.                                                      DTSBR302
01197      EXIT.                                                        DTSBR302
01198      SKIP3                                                        DTSBR302
01199  S1420-BUILD-DET-LINE.                                            DTSBR302
01200      SKIP1                                                        DTSBR302
01201      MOVE HOLD-ACCT-IND TO DET-ACCT-IND.                          DTSBR302
01202      MOVE HOLD-CHARGED-AMT TO DET-CHARGED-AMT.                    DTSBR302
01203      MOVE HOLD-PAID-AMT TO DET-PAID-AMT.                          DTSBR302
01204      MOVE HOLD-WAIVED-AMT TO DET-WAIVED-AMT.                      DTSBR302
01205      MOVE HOLD-WRITEOFF-AMT TO DET-WRITEOFF-AMT.                  DTSBR302
01206      MOVE HOLD-TOLER-AMT TO DET-TOLER-AMT.                        DTSBR302
01207                                                                   DTSBR302
01208      MOVE SPACES  TO DET-YRQ.                                     DTSBR302
01209      IF LRCM-PICKUP-YRQ = HOLD-YRQ                                DTSBR302
01210         MOVE 'PU' TO DET-YRQ                                      DTSBR302
01211         GO TO S1420-EXIT.                                         DTSBR302
01212      SKIP1                                                        DTSBR302
01213      MOVE '1' TO L004-OPTION.                                     DTSBR302
01214      MOVE HOLD-YRQ TO L004-QTR-5-9.                               DTSBR302
01215      PERFORM S004-QTR THRU S004-EXIT.                             DTSBR302
01216      IF L004-VALID-QTR                                            DTSBR302
01217          MOVE L004-SLASH-5-QTR TO DET-YRQ                         DTSBR302
01218      ELSE                                                         DTSBR302
01219          MOVE SPACES TO DET-YRQ.                                  DTSBR302
01220      SKIP2                                                        DTSBR302
01221  S1420-EXIT.                                                      DTSBR302
01222      EXIT.                                                        DTSBR302
01223      SKIP3                                                        DTSBR302
01224  S1440-INCR-ACCT-TBL.                                             DTSBR302
01225      SKIP1                                                        DTSBR302
01226      MOVE +0 TO ACCT-WRK-SUB.                                     DTSBR302
01227      PERFORM S1441-ACCT-LIT-LOOP                                  DTSBR302
01228         THRU S1441-EXIT                                           DTSBR302
01229           VARYING ACCT-LIT-IDX FROM 1 BY 1                        DTSBR302
01230             UNTIL ACCT-WRK-SUB NOT = 0                            DTSBR302
01231               OR  ACCT-LIT-IDX > ACCT-ITEM-MAX.                   DTSBR302
01232      SKIP1                                                        DTSBR302
01233      IF ACCT-WRK-SUB = +0                                         DTSBR302
01234          MOVE ACCT-OTHER-SLOT TO ACCT-WRK-SUB.                    DTSBR302
01235      SKIP1                                                        DTSBR302
01236      MOVE ACCT-TBL-AREA (1) TO ACCT-WRK-AREA.                     DTSBR302
01237      SKIP1                                                        DTSBR302
01238      ADD HOLD-CHARGED-AMT                                         DTSBR302
01239         TO ACCT-WRK-CHARGED-AMT (ACCT-WRK-SUB)                    DTSBR302
01240            ACCT-WRK-CHARGED-AMT (ACCT-TOTAL-SLOT)                 DTSBR302
01241            ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB)                 DTSBR302
01242            ACCT-WRK-NET-CHANGE-AMT (ACCT-TOTAL-SLOT).             DTSBR302
01243      SKIP1                                                        DTSBR302
01244      ADD HOLD-PAID-AMT                                            DTSBR302
01245         TO ACCT-WRK-PAID-AMT (ACCT-WRK-SUB)                       DTSBR302
01246            ACCT-WRK-PAID-AMT (ACCT-TOTAL-SLOT).                   DTSBR302
01247      SUBTRACT HOLD-PAID-AMT                                       DTSBR302
01248         FROM ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB)               DTSBR302
01249              ACCT-WRK-NET-CHANGE-AMT (ACCT-TOTAL-SLOT).           DTSBR302
01250      SKIP1                                                        DTSBR302
01251      ADD HOLD-WAIVED-AMT                                          DTSBR302
01252         TO ACCT-WRK-WAIVED-AMT (ACCT-WRK-SUB)                     DTSBR302
01253            ACCT-WRK-WAIVED-AMT (ACCT-TOTAL-SLOT).                 DTSBR302
01254      SUBTRACT HOLD-WAIVED-AMT                                     DTSBR302
01255         FROM ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB)               DTSBR302
01256              ACCT-WRK-NET-CHANGE-AMT (ACCT-TOTAL-SLOT).           DTSBR302
01257      SKIP1                                                        DTSBR302
01258      ADD HOLD-WRITEOFF-AMT                                        DTSBR302
01259         TO ACCT-WRK-WRITEOFF-AMT (ACCT-WRK-SUB)                   DTSBR302
01260            ACCT-WRK-WRITEOFF-AMT (ACCT-TOTAL-SLOT).               DTSBR302
01261      SUBTRACT HOLD-WRITEOFF-AMT                                   DTSBR302
01262         FROM ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB)               DTSBR302
01263              ACCT-WRK-NET-CHANGE-AMT (ACCT-TOTAL-SLOT).           DTSBR302
01264      SKIP1                                                        DTSBR302
01265      ADD HOLD-TOLER-AMT                                           DTSBR302
01266         TO ACCT-WRK-TOLER-AMT (ACCT-WRK-SUB)                      DTSBR302
01267            ACCT-WRK-TOLER-AMT (ACCT-TOTAL-SLOT).                  DTSBR302
01268      SUBTRACT HOLD-TOLER-AMT                                      DTSBR302
01269         FROM ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB)               DTSBR302
01270              ACCT-WRK-NET-CHANGE-AMT (ACCT-TOTAL-SLOT).           DTSBR302
01271      SKIP1                                                        DTSBR302
01272      MOVE ACCT-WRK-AREA TO ACCT-TBL-AREA (1).                     DTSBR302
01273      SKIP2                                                        DTSBR302
01274  S1440-EXIT.                                                      DTSBR302
01275      EXIT.                                                        DTSBR302
01276      SKIP3                                                        DTSBR302
01277  S1441-ACCT-LIT-LOOP.                                             DTSBR302
01278      SKIP1                                                        DTSBR302
01279      IF HOLD-ACCT-IND = ACCT-LIT-ID (ACCT-LIT-IDX)                DTSBR302
01280          SET ACCT-WRK-SUB TO ACCT-LIT-IDX.                        DTSBR302
01281      SKIP2                                                        DTSBR302
01282  S1441-EXIT.                                                      DTSBR302
01283      EXIT.                                                        DTSBR302
01284      EJECT                                                        DTSBR302
01285  S2100-ACCOUNTING-DATE-INIT.                                      DTSBR302
01286      SKIP1                                                        DTSBR302
01287      MOVE R302-DEPOSIT-DATE TO HOLD-ACCOUNTING-DATE.              DTSBR302
01288      SKIP1                                                        DTSBR302
01289      PERFORM S2200-BATCH-NO-INIT THRU S2200-EXIT.                 DTSBR302
01290      SKIP1                                                        DTSBR302
01291      MOVE HOLD-ACCOUNTING-DATE TO L001-FED-8-DATE-9.              DTSBR302
01292      SET L001-FROM-FED-8 TO TRUE.                                 DTSBR302
01293      PERFORM S001-DATE THRU S001-EXIT.                            DTSBR302
01294      MOVE L001-SLASH-8-DATE TO HDR-6-DEPOSIT-DATE.                DTSBR302
01295      SKIP1                                                        DTSBR302
01296      MOVE REMIT-TBL-AREA (1) TO REMIT-TBL-AREA (2).               DTSBR302
01297      MOVE ACCT-TBL-AREA (1) TO ACCT-TBL-AREA (2).                 DTSBR302
01298      MOVE TRAN-TBL-AREA (1) TO TRAN-TBL-AREA (2).                 DTSBR302
01299      SKIP2                                                        DTSBR302
01300  S2100-EXIT.                                                      DTSBR302
01301      EXIT.                                                        DTSBR302
01302      SKIP3                                                        DTSBR302
01303  S2200-BATCH-NO-INIT.                                             DTSBR302
01304      SKIP1                                                        DTSBR302
01305      MOVE PAGE-CNT TO WS-PAGE-TRUNCATE.                           DTSBR302
01306      IF WS-ODD-PAGE-88                                            DTSBR302
01307          ADD +1 TO PAGE-CNT                                       DTSBR302
01308          SET WS-ADVANCE-PAGE-88 TO TRUE                           DTSBR302
01309          MOVE SPACES TO PRT-REC                                   DTSBR302
01310          PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                 DTSBR302
01311      SKIP1                                                        DTSBR302
01312      MOVE R302-BATCH-NO TO HOLD-BATCH-NO.                         DTSBR302
01313      SKIP1                                                        DTSBR302
01314      PERFORM S2300-ITEM-NO-INIT THRU S2300-EXIT.                  DTSBR302
01315      SKIP1                                                        DTSBR302
01316      PERFORM S2210-ZERO-REMIT-WRK THRU S2210-EXIT                 DTSBR302
01317         VARYING REMIT-WRK-SUB FROM 1 BY 1 UNTIL                   DTSBR302
01318         REMIT-WRK-SUB > REMIT-TOTAL-SLOT.                         DTSBR302
01319      MOVE REMIT-WRK-AREA TO REMIT-TBL-AREA (1).                   DTSBR302
01320      SKIP1                                                        DTSBR302
01321      PERFORM S2230-ZERO-ACCT-WRK THRU S2230-EXIT                  DTSBR302
01322         VARYING ACCT-WRK-SUB FROM 1 BY 1 UNTIL                    DTSBR302
01323         ACCT-WRK-SUB > ACCT-TOTAL-SLOT.                           DTSBR302
01324      MOVE ACCT-WRK-AREA TO ACCT-TBL-AREA (1).                     DTSBR302
01325      SKIP1                                                        DTSBR302
01326      PERFORM S2240-ZERO-TRAN-WRK THRU S2240-EXIT                  DTSBR302
01327         VARYING TRAN-WRK-SUB FROM 1 BY 1 UNTIL                    DTSBR302
01328         TRAN-WRK-SUB > TRAN-TOTAL-TOTAL-SLOT.                     DTSBR302
01329      MOVE TRAN-WRK-AREA TO TRAN-TBL-AREA (1).                     DTSBR302
01330      SKIP1                                                        DTSBR302
01331      MOVE 'BATCH NUMBER:  ' TO HDR-7-BATCH-LABEL.                 DTSBR302
01332      MOVE HOLD-BATCH-NO TO HDR-7-BATCH-NO.                        DTSBR302
01333      SKIP1                                                        DTSBR302
01334      COMPUTE LINE-CNT = MAX-LINE-CNT + 1.                         DTSBR302
01335      SKIP2                                                        DTSBR302
01336  S2200-EXIT.                                                      DTSBR302
01337      EXIT.                                                        DTSBR302
01338      SKIP3                                                        DTSBR302
01339  S2210-ZERO-REMIT-WRK.                                            DTSBR302
01340      SKIP1                                                        DTSBR302
01341      MOVE +0 TO REMIT-WRK-AMT (REMIT-WRK-SUB).                    DTSBR302
01342      SKIP2                                                        DTSBR302
01343  S2210-EXIT.                                                      DTSBR302
01344      EXIT.                                                        DTSBR302
01345      SKIP3                                                        DTSBR302
01346  S2230-ZERO-ACCT-WRK.                                             DTSBR302
01347      SKIP1                                                        DTSBR302
01348      MOVE +0 TO ACCT-WRK-CHARGED-AMT (ACCT-WRK-SUB)               DTSBR302
01349                 ACCT-WRK-PAID-AMT (ACCT-WRK-SUB)                  DTSBR302
01350                 ACCT-WRK-WAIVED-AMT (ACCT-WRK-SUB)                DTSBR302
01351                 ACCT-WRK-WRITEOFF-AMT (ACCT-WRK-SUB)              DTSBR302
01352                 ACCT-WRK-TOLER-AMT (ACCT-WRK-SUB)                 DTSBR302
01353                 ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB).           DTSBR302
01354      SKIP2                                                        DTSBR302
01355  S2230-EXIT.                                                      DTSBR302
01356      EXIT.                                                        DTSBR302
01357      SKIP3                                                        DTSBR302
01358  S2240-ZERO-TRAN-WRK.                                             DTSBR302
01359      SKIP1                                                        DTSBR302
01360      MOVE +0 TO TRAN-WRK-UPDATED-CNT (TRAN-WRK-SUB)               DTSBR302
01361                 TRAN-WRK-REJECTED-CNT (TRAN-WRK-SUB).             DTSBR302
01362      SKIP2                                                        DTSBR302
01363  S2240-EXIT.                                                      DTSBR302
01364      EXIT.                                                        DTSBR302
01365      EJECT                                                        DTSBR302
01366  S2300-ITEM-NO-INIT.                                              DTSBR302
01367      SKIP1                                                        DTSBR302
01368      PERFORM S2400-YRQ-ACCT-IND-INIT THRU S2400-EXIT.             DTSBR302
01369      SKIP1                                                        DTSBR302
01370      IF R302-TRAN-DATA-88                                         DTSBR302
01371          MOVE R302-EMP-NO TO HOLD-EMP-NO                          DTSBR302
01372          MOVE R302-ITEM-NO TO HOLD-ITEM-NO                        DTSBR302
01373          MOVE R302-RECEIVED-DATE TO HOLD-RECEIVED-DATE            DTSBR302
01374          MOVE R302-ACCT-REC-TYPE TO HOLD-ACCT-REC-TYPE            DTSBR302
01375          MOVE R302-TRANS-TYPE TO HOLD-TRANS-TYPE                  DTSBR302
01376          MOVE R302-APPLIC-YRQ TO HOLD-APPLIC-YRQ                  DTSBR302
01377          MOVE R302-APPLIC-ACCT-IND TO HOLD-APPLIC-ACCT-IND        DTSBR302
01378          MOVE R302-APPLIC-BATCH-NO TO HOLD-APPLIC-BATCH-NO        DTSBR302
01379          MOVE R302-APPLIC-ITEM-NO TO HOLD-APPLIC-ITEM-NO          DTSBR302
01380          MOVE R302-WAIVE-INT-IND TO HOLD-WAIVE-INT-IND            DTSBR302
01381          MOVE R302-WAIVE-LATE-PEN-IND TO HOLD-WAIVE-PEN-IND       DTSBR302
01382          MOVE R302-REMIT-AMT TO HOLD-REMIT-AMT                    DTSBR302
01383          MOVE R302-TOT-WAGE-CHNG TO HOLD-TOT-WAGE-CHNG            DTSBR302
01384          MOVE R302-TAX-WAGE-CHNG TO HOLD-TAX-WAGE-CHNG            DTSBR302
01385          MOVE R302-RESULT-IND TO HOLD-RESULT-IND                  DTSBR302
01386          IF R302-OK-88                                            DTSBR302
01387              MOVE SPACE TO HOLD-ERROR-AREA                        DTSBR302
01388          ELSE                                                     DTSBR302
01389              MOVE R302-ERROR-AREA TO HOLD-ERROR-AREA              DTSBR302
01390      ELSE                                                         DTSBR302
01391          MOVE R302-EMP-NO TO HOLD-EMP-NO                          DTSBR302
01392          MOVE R302-ITEM-NO TO HOLD-ITEM-NO                        DTSBR302
01393          MOVE +0 TO HOLD-RECEIVED-DATE                            DTSBR302
01394          MOVE SPACE TO HOLD-ACCT-REC-TYPE                         DTSBR302
01395                        HOLD-TRANS-TYPE                            DTSBR302
01396          MOVE +0 TO HOLD-APPLIC-YRQ                               DTSBR302
01397          MOVE SPACE TO HOLD-APPLIC-ACCT-IND                       DTSBR302
01398          MOVE +0 TO HOLD-APPLIC-BATCH-NO                          DTSBR302
01399                     HOLD-APPLIC-ITEM-NO                           DTSBR302
01400          MOVE SPACE TO HOLD-WAIVE-INT-IND                         DTSBR302
01401                        HOLD-WAIVE-PEN-IND                         DTSBR302
01402          MOVE +0 TO HOLD-REMIT-AMT                                DTSBR302
01403                     HOLD-TOT-WAGE-CHNG                            DTSBR302
01404                     HOLD-TAX-WAGE-CHNG                            DTSBR302
01405          SET HOLD-NOT-OK-88 TO TRUE                               DTSBR302
01406          MOVE SPACES TO HOLD-ERROR-AREA                           DTSBR302
01407          MOVE                                                     DTSBR302
01408          'R302-TRAN-DATA-88 RECORD MISSING - INFORM PROGRAMMING'  DTSBR302
01409             TO HOLD-ERROR-MSG-TEXT.                               DTSBR302
01410      SKIP1                                                        DTSBR302
01411      MOVE SPACE TO DET-LINE.                                      DTSBR302
01412      MOVE HOLD-EMP-NO TO DET-EMP-NO.                              DTSBR302
01413      MOVE HOLD-ITEM-NO TO DET-ITEM-NO.                            DTSBR302
01414      SKIP1                                                        DTSBR302
01415      MOVE HOLD-RECEIVED-DATE TO L001-FED-8-DATE-9.                DTSBR302
01416      SET L001-FROM-FED-8 TO TRUE.                                 DTSBR302
01417      PERFORM S001-DATE THRU S001-EXIT.                            DTSBR302
01418      IF L001-INVALID-DATE                                         DTSBR302
01419          MOVE SPACES TO DET-RECEIVED-DATE                         DTSBR302
01420      ELSE                                                         DTSBR302
01421          MOVE L001-SLASH-8-DATE TO DET-RECEIVED-DATE.             DTSBR302
01422      SKIP1                                                        DTSBR302
01423      MOVE HOLD-ACCT-REC-TYPE TO DET-ACCT-REC-TYPE.                DTSBR302
01424      MOVE HOLD-TRANS-TYPE TO DET-TRANS-TYPE.                      DTSBR302
01425      SKIP1                                                        DTSBR302
01426      PERFORM S2310-PICKUP-DATE THRU S2310-EXIT.                   DTSBR302
01427      MOVE HOLD-REMIT-AMT TO DET-REMIT-AMT.                        DTSBR302
01428      MOVE HOLD-TOT-WAGE-CHNG TO DET-TOT-WAGE-CHNG.                DTSBR302
01429      MOVE HOLD-TAX-WAGE-CHNG TO DET-TAX-WAGE-CHNG.                DTSBR302
01430      PERFORM S9100-APPLIC-AREA THRU S9100-EXIT.                   DTSBR302
01431      SKIP2                                                        DTSBR302
01432  S2300-EXIT.                                                      DTSBR302
01433      EXIT.                                                        DTSBR302
01434      EJECT                                                        DTSBR302
01435  S2310-PICKUP-DATE.                                               DTSBR302
01436      IF LRCM-PICKUP-YRQ = HOLD-APPLIC-YRQ                         DTSBR302
01437         MOVE 'PU  ' TO DET-APPLIC-YRQ                             DTSBR302
01438         GO TO S2310-EXIT.                                         DTSBR302
01439                                                                   DTSBR302
01440      MOVE '1' TO L004-OPTION.                                     DTSBR302
01441      MOVE HOLD-APPLIC-YRQ TO L004-QTR-5-9.                        DTSBR302
01442      PERFORM S004-QTR THRU S004-EXIT.                             DTSBR302
01443      IF L004-VALID-QTR                                            DTSBR302
01444          MOVE L004-SLASH-5-QTR TO DET-APPLIC-YRQ                  DTSBR302
01445      ELSE                                                         DTSBR302
01446          MOVE SPACES TO DET-APPLIC-YRQ.                           DTSBR302
01447      SKIP1                                                        DTSBR302
01448  S2310-EXIT.                                                      DTSBR302
01449      EXIT.                                                        DTSBR302
01450      EJECT                                                        DTSBR302
01451  S2400-YRQ-ACCT-IND-INIT.                                         DTSBR302
01452      SKIP1                                                        DTSBR302
01453      IF R302-TRAN-DATA-88                                         DTSBR302
01454          MOVE TRAN-YRQ-ACCT-SEQ-IND                               DTSBR302
01455             TO HOLD-SORT-YRQ-ACCT-SEQ-IND                         DTSBR302
01456          MOVE +0 TO HOLD-YRQ                                      DTSBR302
01457          MOVE SPACE TO HOLD-ACCT-IND                              DTSBR302
01458      ELSE                                                         DTSBR302
01459          MOVE R302-SORT-YRQ-ACCT-SEQ-IND                          DTSBR302
01460             TO HOLD-SORT-YRQ-ACCT-SEQ-IND                         DTSBR302
01461          MOVE R302-YRQ TO HOLD-YRQ                                DTSBR302
01462          MOVE R302-ACCT-IND TO HOLD-ACCT-IND.                     DTSBR302
01463      MOVE +0 TO HOLD-CHARGED-AMT                                  DTSBR302
01464                 HOLD-PAID-AMT                                     DTSBR302
01465                 HOLD-WAIVED-AMT                                   DTSBR302
01466                 HOLD-WRITEOFF-AMT                                 DTSBR302
01467                 HOLD-TOLER-AMT.                                   DTSBR302
01468      SKIP2                                                        DTSBR302
01469  S2400-EXIT.                                                      DTSBR302
01470      EXIT.                                                        DTSBR302
01471      EJECT                                                        DTSBR302
01472  S6000-SUMMARY-PRINT-PAGE1.                                       DTSBR302
01473      SKIP1                                                        DTSBR302
01474      IF HDR-7-BATCH-NO GREATER SPACES                             DTSBR302
01475         MOVE '   ACCOUNTING SUMMARY  BY BATCH NUMBER REPORT' TO   DTSBR302
01476              HDR-4-LITERAL                                        DTSBR302
01477      ELSE                                                         DTSBR302
01478         MOVE '   ACCOUNTING SUMMARY  BY DEPOSIT DATE REPORT' TO   DTSBR302
01479              HDR-4-LITERAL.                                       DTSBR302
01480 * I INSERTED A LINE TO CHECK IF HDR-6-PAGE-LABEL IS 'GRAND TOTAL' DTSBR302
01481 * IF SO,WE WANT TO PRINT THE GRAND TOTAL HEADING FOR THE 3RD REPORDTSBR302
01482      IF HDR-6-PAGE-LABEL EQUAL  'GRAND TOTALS      '              DTSBR302
01483         MOVE '           ACCOUNTING SUMMARY REPORT '              DTSBR302
01484                          TO HDR-4-LITERAL.                        DTSBR302
01485      PERFORM S9800-COMMON-HEADING THRU S9800-EXIT.                DTSBR302
01486      SKIP1                                                        DTSBR302
01487      SET WS-ADVANCE-3LINES-88 TO TRUE.                            DTSBR302
01488      MOVE HDR-REMIT-1 TO PRT-REC.                                 DTSBR302
01489      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01490      SKIP1                                                        DTSBR302
01491      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01492      MOVE ALL '-' TO HDR-REMIT-2-DASH-1.                          DTSBR302
01493      MOVE HDR-REMIT-2 TO PRT-REC.                                 DTSBR302
01494      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01495      SKIP1                                                        DTSBR302
01496      MOVE SPACE TO DET-REMIT.                                     DTSBR302
01497      MOVE REMIT-TBL-AREA (WRK-TBL-SUB) TO REMIT-WRK-AREA.         DTSBR302
01498      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01499      PERFORM S6100-REMIT-LOOP                                     DTSBR302
01500         THRU S6100-EXIT                                           DTSBR302
01501           VARYING REMIT-WRK-SUB FROM 1 BY 1                       DTSBR302
01502             UNTIL REMIT-WRK-SUB > REMIT-TOTAL-SLOT.               DTSBR302
01503      SKIP1                                                        DTSBR302
01504      SET WS-ADVANCE-6LINES-88 TO TRUE.                            DTSBR302
01505      MOVE HDR-ACCT-1 TO PRT-REC.                                  DTSBR302
01506      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01507      SKIP1                                                        DTSBR302
01508      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01509      MOVE HDR-ACCT-2 TO PRT-REC.                                  DTSBR302
01510      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01511      SKIP1                                                        DTSBR302
01512      MOVE SPACE TO DET-ACCT.                                      DTSBR302
01513      MOVE ACCT-TBL-AREA (WRK-TBL-SUB) TO ACCT-WRK-AREA.           DTSBR302
01514      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01515      PERFORM S6300-ACCT-LOOP                                      DTSBR302
01516         THRU S6300-EXIT                                           DTSBR302
01517           VARYING ACCT-WRK-SUB FROM 1 BY 1                        DTSBR302
01518             UNTIL ACCT-WRK-SUB > ACCT-TOTAL-SLOT.                 DTSBR302
01519      SKIP2                                                        DTSBR302
01520  S6000-EXIT.                                                      DTSBR302
01521      EXIT.                                                        DTSBR302
01522      SKIP3                                                        DTSBR302
01523  S6100-REMIT-LOOP.                                                DTSBR302
01524      SKIP1                                                        DTSBR302
01525      IF REMIT-WRK-SUB = REMIT-OTHER-SLOT                          DTSBR302
01526          IF REMIT-WRK-AMT (REMIT-WRK-SUB) = +0                    DTSBR302
01527              GO TO S6100-EXIT.                                    DTSBR302
01528      SKIP1                                                        DTSBR302
01529      IF REMIT-WRK-SUB = REMIT-TOTAL-SLOT                          DTSBR302
01530          SET WS-ADVANCE-1LINE-88 TO TRUE                          DTSBR302
01531          MOVE SPACES TO HDR-REMIT-2-DASH-1                        DTSBR302
01532          MOVE HDR-REMIT-2 TO PRT-REC                              DTSBR302
01533          PERFORM S9900-WRITE-PRT THRU S9900-EXIT                  DTSBR302
01534          SET WS-ADVANCE-1LINE-88 TO TRUE.                         DTSBR302
01535      SKIP1                                                        DTSBR302
01536      MOVE REMIT-LIT-NAME (REMIT-WRK-SUB) TO DET-REMIT-LINE-NAME.  DTSBR302
01537      MOVE REMIT-WRK-AMT (REMIT-WRK-SUB) TO DET-REMIT-REMIT-AMT.   DTSBR302
01538      MOVE DET-REMIT TO PRT-REC.                                   DTSBR302
01539      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01540      SET WS-ADVANCE-2LINES-88 TO TRUE.                            DTSBR302
01541      SKIP2                                                        DTSBR302
01542  S6100-EXIT.                                                      DTSBR302
01543      EXIT.                                                        DTSBR302
01544      SKIP3                                                        DTSBR302
01545  S6300-ACCT-LOOP.                                                 DTSBR302
01546      SKIP1                                                        DTSBR302
01547      IF ACCT-WRK-SUB = ACCT-OTHER-SLOT                            DTSBR302
01548          IF  ACCT-WRK-CHARGED-AMT (ACCT-WRK-SUB) = 0              DTSBR302
01549          AND ACCT-WRK-PAID-AMT (ACCT-WRK-SUB) = 0                 DTSBR302
01550          AND ACCT-WRK-WAIVED-AMT (ACCT-WRK-SUB) = 0               DTSBR302
01551          AND ACCT-WRK-WRITEOFF-AMT (ACCT-WRK-SUB) = 0             DTSBR302
01552          AND ACCT-WRK-TOLER-AMT (ACCT-WRK-SUB) = 0                DTSBR302
01553          AND ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB) = 0           DTSBR302
01554              GO TO S6300-EXIT.                                    DTSBR302
01555      SKIP1                                                        DTSBR302
01556      IF ACCT-WRK-SUB = ACCT-TOTAL-SLOT                            DTSBR302
01557          SET WS-ADVANCE-1LINE-88 TO TRUE                          DTSBR302
01558          MOVE HDR-ACCT-2 TO PRT-REC                               DTSBR302
01559          PERFORM S9900-WRITE-PRT THRU S9900-EXIT                  DTSBR302
01560          SET WS-ADVANCE-2LINES-88 TO TRUE.                        DTSBR302
01561      SKIP1                                                        DTSBR302
01562      MOVE ACCT-LIT-NAME (ACCT-WRK-SUB) TO DET-ACCT-LINE-NAME.     DTSBR302
01563      MOVE ACCT-LIT-ID (ACCT-WRK-SUB) TO DET-ACCT-LINE-ID.         DTSBR302
01564      MOVE ACCT-WRK-CHARGED-AMT (ACCT-WRK-SUB)                     DTSBR302
01565         TO DET-ACCT-CHARGED-AMT.                                  DTSBR302
01566      MOVE ACCT-WRK-PAID-AMT (ACCT-WRK-SUB)                        DTSBR302
01567         TO DET-ACCT-PAID-AMT.                                     DTSBR302
01568      MOVE ACCT-WRK-WAIVED-AMT (ACCT-WRK-SUB)                      DTSBR302
01569         TO DET-ACCT-WAIVED-AMT.                                   DTSBR302
01570      MOVE ACCT-WRK-WRITEOFF-AMT (ACCT-WRK-SUB)                    DTSBR302
01571         TO DET-ACCT-WRITEOFF-AMT.                                 DTSBR302
01572      MOVE ACCT-WRK-TOLER-AMT (ACCT-WRK-SUB)                       DTSBR302
01573         TO DET-ACCT-TOLER-AMT.                                    DTSBR302
01574      MOVE ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB)                  DTSBR302
01575         TO DET-ACCT-NET-CHANGE-AMT.                               DTSBR302
01576      MOVE DET-ACCT TO PRT-REC.                                    DTSBR302
01577      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01578      SET WS-ADVANCE-2LINES-88 TO TRUE.                            DTSBR302
01579      SKIP2                                                        DTSBR302
01580  S6300-EXIT.                                                      DTSBR302
01581      EXIT.                                                        DTSBR302
01582      EJECT                                                        DTSBR302
01583  S7000-SUMMARY-PRINT-PAGE2.                                       DTSBR302
01584      SKIP1                                                        DTSBR302
01585      MOVE 'ACCOUNTING SUMMARY BY TRANSACTION CATEGORY REPORT' TO  DTSBR302
01586           HDR-4-LITERAL.                                          DTSBR302
01587      PERFORM S9800-COMMON-HEADING THRU S9800-EXIT.                DTSBR302
01588      SKIP1                                                        DTSBR302
01589      SET WS-ADVANCE-2LINES-88 TO TRUE.                            DTSBR302
01590      MOVE HDR-TRAN-1 TO PRT-REC.                                  DTSBR302
01591      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01592      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01593      MOVE HDR-TRAN-2 TO PRT-REC.                                  DTSBR302
01594      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01595      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01596      MOVE HDR-TRAN-3 TO PRT-REC.                                  DTSBR302
01597      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01598      SKIP1                                                        DTSBR302
01599      MOVE SPACE TO DET-TRAN.                                      DTSBR302
01600      MOVE TRAN-TBL-AREA (WRK-TBL-SUB) TO TRAN-WRK-AREA.           DTSBR302
01601      PERFORM S7100-TRAN-LOOP                                      DTSBR302
01602         THRU S7100-EXIT                                           DTSBR302
01603           VARYING TRAN-WRK-SUB FROM 1 BY 1                        DTSBR302
01604             UNTIL TRAN-WRK-SUB > TRAN-TOTAL-TOTAL-SLOT.           DTSBR302
01605      SKIP2                                                        DTSBR302
01606  S7000-EXIT.                                                      DTSBR302
01607      EXIT.                                                        DTSBR302
01608      SKIP3                                                        DTSBR302
01609  S7100-TRAN-LOOP.                                                 DTSBR302
01610      SKIP1                                                        DTSBR302
01611      IF TRAN-WRK-SUB = TRAN-R-OTHER-SLOT                          DTSBR302
01612      OR TRAN-WRK-SUB = TRAN-P-OTHER-SLOT                          DTSBR302
01613      OR TRAN-WRK-SUB = TRAN-A-OTHER-SLOT                          DTSBR302
01614      OR TRAN-WRK-SUB = TRAN-OTHER-OTHER-SLOT                      DTSBR302
01615          IF  TRAN-WRK-UPDATED-CNT (TRAN-WRK-SUB) = +0             DTSBR302
01616          AND TRAN-WRK-REJECTED-CNT (TRAN-WRK-SUB) = +0            DTSBR302
01617              GO TO S7100-EXIT.                                    DTSBR302
01618      SKIP1                                                        DTSBR302
01619      IF TRAN-WRK-SUB = TRAN-R-ITEM-MIN                            DTSBR302
01620      OR TRAN-WRK-SUB = TRAN-P-ITEM-MIN                            DTSBR302
01621      OR TRAN-WRK-SUB = TRAN-A-ITEM-MIN                            DTSBR302
01622      OR TRAN-WRK-SUB = TRAN-OTHER-OTHER-SLOT                      DTSBR302
01623      OR TRAN-WRK-SUB = TRAN-TOTAL-TOTAL-SLOT                      DTSBR302
01624          MOVE TRAN-LIT-REC-TYPE-5 (TRAN-WRK-SUB)                  DTSBR302
01625             TO DET-TRAN-ACCT-REC-TYPE                             DTSBR302
01626      ELSE                                                         DTSBR302
01627          MOVE SPACE TO DET-TRAN-ACCT-REC-TYPE.                    DTSBR302
01628      SKIP1                                                        DTSBR302
01629      MOVE TRAN-LIT-TYPE-5 (TRAN-WRK-SUB) TO DET-TRAN-TRANS-TYPE.  DTSBR302
01630      SKIP1                                                        DTSBR302
01631      IF TRAN-WRK-SUB = TRAN-R-TOTAL-SLOT                          DTSBR302
01632      OR TRAN-WRK-SUB = TRAN-P-TOTAL-SLOT                          DTSBR302
01633      OR TRAN-WRK-SUB = TRAN-A-TOTAL-SLOT                          DTSBR302
01634      OR TRAN-WRK-SUB = TRAN-TOTAL-TOTAL-SLOT                      DTSBR302
01635          SET WS-ADVANCE-2LINES-88 TO TRUE                         DTSBR302
01636      ELSE                                                         DTSBR302
01637          IF TRAN-WRK-SUB = TRAN-P-ITEM-MIN                        DTSBR302
01638          OR TRAN-WRK-SUB = TRAN-A-ITEM-MIN                        DTSBR302
01639          OR TRAN-WRK-SUB = TRAN-OTHER-OTHER-SLOT                  DTSBR302
01640              SET WS-ADVANCE-3LINES-88 TO TRUE                     DTSBR302
01641          ELSE                                                     DTSBR302
01642              SET WS-ADVANCE-1LINE-88 TO TRUE.                     DTSBR302
01643      SKIP1                                                        DTSBR302
01644      MOVE TRAN-WRK-UPDATED-CNT (TRAN-WRK-SUB)                     DTSBR302
01645         TO DET-TRAN-UPDATED-CNT.                                  DTSBR302
01646      MOVE TRAN-WRK-REJECTED-CNT (TRAN-WRK-SUB)                    DTSBR302
01647         TO DET-TRAN-REJECTED-CNT.                                 DTSBR302
01648      MOVE DET-TRAN TO PRT-REC.                                    DTSBR302
01649      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01650      SKIP2                                                        DTSBR302
01651  S7100-EXIT.                                                      DTSBR302
01652      EXIT.                                                        DTSBR302
01653      EJECT                                                        DTSBR302
01654  S8000-SUM-TABLES.                                                DTSBR302
01655      SKIP1                                                        DTSBR302
01656      MOVE REMIT-TBL-AREA (WRK-TBL-SUB1) TO REMIT-WRK-AREA.        DTSBR302
01657      PERFORM S8100-SUM-REMIT                                      DTSBR302
01658         THRU S8100-EXIT                                           DTSBR302
01659           VARYING REMIT-WRK-SUB FROM 1 BY 1                       DTSBR302
01660             UNTIL REMIT-WRK-SUB > REMIT-TOTAL-SLOT.               DTSBR302
01661      SKIP1                                                        DTSBR302
01662      MOVE ACCT-TBL-AREA (WRK-TBL-SUB1) TO ACCT-WRK-AREA.          DTSBR302
01663      PERFORM S8300-SUM-ACCT                                       DTSBR302
01664         THRU S8300-EXIT                                           DTSBR302
01665           VARYING ACCT-WRK-SUB FROM 1 BY 1                        DTSBR302
01666             UNTIL ACCT-WRK-SUB > ACCT-TOTAL-SLOT.                 DTSBR302
01667      SKIP1                                                        DTSBR302
01668      MOVE TRAN-TBL-AREA (WRK-TBL-SUB1) TO TRAN-WRK-AREA.          DTSBR302
01669      PERFORM S8400-SUM-TRAN                                       DTSBR302
01670         THRU S8400-EXIT                                           DTSBR302
01671           VARYING TRAN-WRK-SUB FROM 1 BY 1                        DTSBR302
01672             UNTIL TRAN-WRK-SUB > TRAN-TOTAL-TOTAL-SLOT.           DTSBR302
01673      SKIP2                                                        DTSBR302
01674  S8000-EXIT.                                                      DTSBR302
01675      EXIT.                                                        DTSBR302
01676      SKIP3                                                        DTSBR302
01677  S8100-SUM-REMIT.                                                 DTSBR302
01678      SKIP1                                                        DTSBR302
01679      ADD REMIT-WRK-AMT (REMIT-WRK-SUB)                            DTSBR302
01680         TO REMIT-TBL-AMT (WRK-TBL-SUB2 REMIT-WRK-SUB).            DTSBR302
01681      SKIP2                                                        DTSBR302
01682  S8100-EXIT.                                                      DTSBR302
01683      EXIT.                                                        DTSBR302
01684      SKIP3                                                        DTSBR302
01685  S8300-SUM-ACCT.                                                  DTSBR302
01686      SKIP1                                                        DTSBR302
01687      ADD ACCT-WRK-CHARGED-AMT (ACCT-WRK-SUB)                      DTSBR302
01688         TO ACCT-TBL-CHARGED-AMT (WRK-TBL-SUB2 ACCT-WRK-SUB).      DTSBR302
01689      ADD ACCT-WRK-PAID-AMT (ACCT-WRK-SUB)                         DTSBR302
01690         TO ACCT-TBL-PAID-AMT (WRK-TBL-SUB2 ACCT-WRK-SUB).         DTSBR302
01691      ADD ACCT-WRK-WAIVED-AMT (ACCT-WRK-SUB)                       DTSBR302
01692         TO ACCT-TBL-WAIVED-AMT (WRK-TBL-SUB2 ACCT-WRK-SUB).       DTSBR302
01693      ADD ACCT-WRK-WRITEOFF-AMT (ACCT-WRK-SUB)                     DTSBR302
01694         TO ACCT-TBL-WRITEOFF-AMT (WRK-TBL-SUB2 ACCT-WRK-SUB).     DTSBR302
01695      ADD ACCT-WRK-TOLER-AMT (ACCT-WRK-SUB)                        DTSBR302
01696         TO ACCT-TBL-TOLER-AMT (WRK-TBL-SUB2 ACCT-WRK-SUB).        DTSBR302
01697      ADD ACCT-WRK-NET-CHANGE-AMT (ACCT-WRK-SUB)                   DTSBR302
01698         TO ACCT-TBL-NET-CHANGE-AMT (WRK-TBL-SUB2 ACCT-WRK-SUB).   DTSBR302
01699      SKIP2                                                        DTSBR302
01700  S8300-EXIT.                                                      DTSBR302
01701      EXIT.                                                        DTSBR302
01702      SKIP3                                                        DTSBR302
01703  S8400-SUM-TRAN.                                                  DTSBR302
01704      SKIP1                                                        DTSBR302
01705      ADD TRAN-WRK-UPDATED-CNT (TRAN-WRK-SUB)                      DTSBR302
01706         TO TRAN-TBL-UPDATED-CNT (WRK-TBL-SUB2 TRAN-WRK-SUB).      DTSBR302
01707      ADD TRAN-WRK-REJECTED-CNT (TRAN-WRK-SUB)                     DTSBR302
01708         TO TRAN-TBL-REJECTED-CNT (WRK-TBL-SUB2 TRAN-WRK-SUB).     DTSBR302
01709      SKIP2                                                        DTSBR302
01710  S8400-EXIT.                                                      DTSBR302
01711      EXIT.                                                        DTSBR302
01712      EJECT                                                        DTSBR302
01713  S9100-APPLIC-AREA.                                               DTSBR302
01714      SKIP1                                                        DTSBR302
01715      MOVE HOLD-APPLIC-ACCT-IND TO DET-APPLIC-ACCT-IND.            DTSBR302
01716      IF HOLD-APPLIC-BATCH-NO NOT = +0                             DTSBR302
01717          MOVE HOLD-APPLIC-BATCH-NO                                DTSBR302
01718             TO DET-APPLIC-BATCH-NO.                               DTSBR302
01719      IF HOLD-APPLIC-ITEM-NO NOT = +0                              DTSBR302
01720          MOVE HOLD-APPLIC-ITEM-NO                                 DTSBR302
01721             TO DET-APPLIC-ITEM-NO.                                DTSBR302
01722      MOVE HOLD-WAIVE-INT-IND TO DET-WAIVE-INT-IND.                DTSBR302
01723      MOVE HOLD-WAIVE-PEN-IND TO DET-WAIVE-PEN-IND.                DTSBR302
01724      SKIP2                                                        DTSBR302
01725  S9100-EXIT.                                                      DTSBR302
01726      EXIT.                                                        DTSBR302
01727      EJECT                                                        DTSBR302
01728  S9800-COMMON-HEADING.                                            DTSBR302
01729      SKIP1                                                        DTSBR302
01730      ADD +1 TO PAGE-CNT.                                          DTSBR302
01731      MOVE PAGE-CNT TO HDR-2-PAGE.                                 DTSBR302
01732      SKIP1                                                        DTSBR302
01733      SET WS-ADVANCE-PAGE-88 TO TRUE.                              DTSBR302
01734      MOVE HDR-1 TO PRT-REC.                                       DTSBR302
01735      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01736      SKIP1                                                        DTSBR302
01737      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01738      MOVE HDR-2 TO PRT-REC.                                       DTSBR302
01739      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01740      SKIP1                                                        DTSBR302
01741      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01742      MOVE HDR-3 TO PRT-REC.                                       DTSBR302
01743      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01744      SKIP1                                                        DTSBR302
01745      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01746      MOVE HDR-4 TO PRT-REC.                                       DTSBR302
01747      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01748      SKIP1                                                        DTSBR302
01749      SET WS-ADVANCE-2LINES-88 TO TRUE.                            DTSBR302
01750      MOVE HDR-6 TO PRT-REC.                                       DTSBR302
01751      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01752      SKIP1                                                        DTSBR302
01753      SET WS-ADVANCE-1LINE-88 TO TRUE.                             DTSBR302
01754      MOVE HDR-7 TO PRT-REC.                                       DTSBR302
01755      PERFORM S9900-WRITE-PRT THRU S9900-EXIT.                     DTSBR302
01756      SKIP2                                                        DTSBR302
01757  S9800-EXIT.                                                      DTSBR302
01758      EXIT.                                                        DTSBR302
01759      EJECT                                                        DTSBR302
01760  S9900-WRITE-PRT.                                                 DTSBR302
01761      SKIP1                                                        DTSBR302
01762      IF WS-ADVANCE-1LINE-88                                       DTSBR302
01763          WRITE PRT-REC AFTER ADVANCING 1 LINE                     DTSBR302
01764          ADD +1 TO LINE-CNT                                       DTSBR302
01765      ELSE                                                         DTSBR302
01766      IF WS-ADVANCE-2LINES-88                                      DTSBR302
01767          WRITE PRT-REC AFTER ADVANCING 2 LINES                    DTSBR302
01768          ADD +2 TO LINE-CNT                                       DTSBR302
01769      ELSE                                                         DTSBR302
01770      IF WS-ADVANCE-PAGE-88                                        DTSBR302
01771 *       WRITE PRT-REC FROM X1-CA-CNTL-LINE                        DTSBR302
01772         WRITE PRT-REC FROM X2-CA-CNTL-LINE                        DTSBR302
01773         WRITE PRT-REC FROM X3-CA-CNTL-LINE                        DTSBR302
01774         MOVE SPACES TO PRT-REC                                    DTSBR302
01775         MOVE HDR-1 TO PRT-REC                                     DTSBR302
01776         WRITE PRT-REC AFTER ADVANCING PAGE                        DTSBR302
01777         MOVE +1 TO LINE-CNT                                       DTSBR302
01778      ELSE                                                         DTSBR302
01779      IF WS-ADVANCE-3LINES-88                                      DTSBR302
01780          WRITE PRT-REC AFTER ADVANCING 3 LINES                    DTSBR302
01781          ADD +3 TO LINE-CNT                                       DTSBR302
01782      ELSE                                                         DTSBR302
01783      IF WS-ADVANCE-6LINES-88                                      DTSBR302
01784          WRITE PRT-REC AFTER ADVANCING 6 LINES                    DTSBR302
01785          ADD +6 TO LINE-CNT                                       DTSBR302
01786      ELSE                                                         DTSBR302
01787      IF WS-ADVANCE-0LINES-88                                      DTSBR302
01788          WRITE PRT-REC AFTER ADVANCING 0 LINES                    DTSBR302
01789          ADD +0 TO LINE-CNT                                       DTSBR302
01790      ELSE                                                         DTSBR302
01791          WRITE PRT-REC AFTER ADVANCING 1 LINE                     DTSBR302
01792          ADD +1 TO LINE-CNT.                                      DTSBR302
01793      SKIP2                                                        DTSBR302
01794  S9900-EXIT.                                                      DTSBR302
01795      EXIT.                                                        DTSBR302
01796      EJECT                                                        DTSBR302
01797  S001-DATE.                                                       DTSBR302
01798      SKIP1                                                        DTSBR302
01799      CALL 'DTSBU001' USING L001-LINK-AREA.                        DTSBR302
01800      SKIP2                                                        DTSBR302
01801  S001-EXIT.                                                       DTSBR302
01802      EXIT.                                                        DTSBR302
01803      SKIP3                                                        DTSBR302
01804  S004-QTR.                                                        DTSBR302
01805      SKIP1                                                        DTSBR302
01806      CALL 'DTSBU004' USING L004-LINK-AREA.                        DTSBR302
01807      SKIP2                                                        DTSBR302
01808  S004-EXIT.                                                       DTSBR302
01809      EXIT.                                                        DTSBR302
01810      SKIP3                                                        DTSBR302
01811  S999-ABEND.                                                      DTSBR302
01812      SKIP1                                                        DTSBR302
01813      CALL 'DTSBU999' USING WRK-ABEND-CD.                          DTSBR302
01814      SKIP2                                                        DTSBR302
01815  S999-EXIT.                                                       DTSBR302
01816      EXIT.                                                        DTSBR302
