00001  IDENTIFICATION DIVISION.                                         09/03/98
00002  PROGRAM-ID.             DTSCSSF.                                 DTSCSSF
00003  AUTHOR.                 TRICOASTAL CONSULTING LTD.                  LV006
00004  DATE-WRITTEN.           NOVEMBER 1991.                           DTSCSSF
00005  DATE-COMPILED.                                                   DTSCSSF
00006      SKIP3                                                        DTSCSSF
00007 *****                                                             DTSCSSF
00008 *                                                                 DTSCSSF
00009 *    FUNCTION:  SIGN OFF SCREEN PROCESSOR.                        DTSCSSF
00010 *                                                                 DTSCSSF
00011 *                                                                 DTSCSSF
00012 *    MODIFICATION LOG:                                            DTSCSSF
00013 *                                                                 DTSCSSF
00014 *    11/06/91  INITIAL DEVELOPMENT.                               DTSCSSF
00015 *              WORK ORDER:                      PROGRAMMER: TCL   DTSCSSF
00016 *                                                                 DTSCSSF
00017 *    04/06/94  MODIFIED FOR MONTANA.                              DTSCSSF
00018 *              WORK ORDER:                      PROGRAMMER: EHH   DTSCSSF
00019 *                                                                 DTSCSSF
00020 *    08/12/1998  REVIEWED AND MODIFIED FOR DC.                       CL**2
00021 *                REFERENCE: DC DEVELOPMENT      PROGRAMMER: EHH      CL**2
00022 *                                                                    CL**2
00023 *    MM/DD/YYYY  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX      CL**2
00024 *                XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX      CL**2
00025 *                REFERENCE: XXXXXXXXXXXXXXX     PROGRAMMER: XXX      CL**2
00026 *                                                                 DTSCSSF
00027 *                                                                 DTSCSSF
00028 *    DESCRIPTION:                                                 DTSCSSF
00029 *                                                                 DTSCSSF
00030 *        IF LCCM-NO-MSG                                           DTSCSSF
00031 *            MOVE PMSG-SIGNOFF-COMPLETE TO LCCM-MSG-AREA.         DTSCSSF
00032 *                                                                 DTSCSSF
00033 *        DELETE ALL TEMPORARY STORAGE AREAS ASSOCIATED WITH       DTSCSSF
00034 *        THE PSEUDO CONVERSATION (VIA LINK TO DTSCU898).             CL**2
00035 *                                                                 DTSCSSF
00036 *        SEND THE SF SCREEN (WITH THE MESSAGE FROM LCCM-MSG-AREA).DTSCSSF
00037 *                                                                 DTSCSSF
00038 *        LINK TO 'UCTRAN', TURNING THE WORK STATION UPPER CASE    DTSCSSF
00039 *        TRANSLATION INDICATOR TO 'ON'.                           DTSCSSF
00040 *                                                                 DTSCSSF
00041 *        RETURN TO CICS, ENDING THE PSEUDO CONVERSATION.          DTSCSSF
00042 *                                                                 DTSCSSF
00043 *                                                                 DTSCSSF
00044 *****                                                             DTSCSSF
00045      SKIP3                                                        DTSCSSF
00046  ENVIRONMENT DIVISION.                                            DTSCSSF
00047      SKIP3                                                        DTSCSSF
00048  DATA DIVISION.                                                   DTSCSSF
00049      SKIP3                                                        DTSCSSF
00050  WORKING-STORAGE SECTION.                                         DTSCSSF
000505 77  PAN-VALET PICTURE X(24) VALUE '006DTSCSSF   09/03/98'.       DTSCSSF
00051      SKIP3                                                        DTSCSSF
00052  01  WRK-AREA.                                                    DTSCSSF
00053      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'SSF '.    DTSCSSF
00054      05  WRK-RESP-CD                 PIC S9(08)  COMP.            DTSCSSF
00055                                                                   DTSCSSF
00056      05  WRK-SCR-ID                  PIC  X(02)  VALUE 'SF'.      DTSCSSF
00057                                                                   DTSCSSF
00058      05  WRK-THANK-YOU-IND           PIC  X(01).                  DTSCSSF
00059                                                                   DTSCSSF
00060      05  UCPARM                      PIC  X(01)  VALUE 'U'.          CL**4
00061      EJECT                                                        DTSCSSF
00062  01  PMSG-LITERALS.                                               DTSCSSF
00063      05  PMSG-THANK-YOU.                                          DTSCSSF
00064          10  FILLER                      PIC  X(04)  VALUE 'P999'.DTSCSSF
00065          10  PMSG-THANK-YOU-MESSAGE.                              DTSCSSF
00066              15  FILLER                  PIC  X(30)               DTSCSSF
00067                VALUE 'DTS (UI TAX SYSTEM) SIGN OFF C'.               CL**2
00068              15  FILLER                  PIC  X(30)               DTSCSSF
00069                VALUE 'OMPLETED                      '.            DTSCSSF
00070      EJECT                                                        DTSCSSF
00071  01  L831-COMM-AREA.                                              DTSCSSF
00072  ++INCLUDE DTSIL831                                                  CL**2
00073      SKIP3                                                        DTSCSSF
00074      05  FSKL-REC.                                                DTSCSSF
00075  ++INCLUDE DTSIFSKL                                                  CL**2
00076      SKIP3                                                        DTSCSSF
00077      05  FOPR-REC REDEFINES FSKL-REC.                             DTSCSSF
00078  ++INCLUDE DTSIFOPR                                                  CL**2
00079      EJECT                                                        DTSCSSF
00080  01  L851-COMM-AREA.                                              DTSCSSF
00081  ++INCLUDE DTSIL851                                                  CL**2
00082      SKIP3                                                        DTSCSSF
00083      05  MAP-AREA REDEFINES L851-MAP-AREA.                        DTSCSSF
00084  ++INCLUDE DTSISSF                                                   CL**2
00085      EJECT                                                        DTSCSSF
00086  01  L805-COMM-AREA.                                              DTSCSSF
00087  ++INCLUDE DTSIL805                                                  CL**2
00088      EJECT                                                        DTSCSSF
00089  01  CATB-LITERALS.                                               DTSCSSF
00090  ++INCLUDE DTSICATB                                                  CL**2
00091      EJECT                                                        DTSCSSF
00092  LINKAGE SECTION.                                                 DTSCSSF
00093      SKIP3                                                        DTSCSSF
00094  01  DFHCOMMAREA.                                                 DTSCSSF
00095  ++INCLUDE DTSILCCM                                                  CL**2
00096      EJECT                                                        DTSCSSF
00097  PROCEDURE DIVISION.                                              DTSCSSF
00098      SKIP2                                                        DTSCSSF
00099      IF LCCM-NO-MSG                                               DTSCSSF
00100          PERFORM P1000-FOPR-UPDATE THRU P1000-EXIT.               DTSCSSF
00101                                                                   DTSCSSF
00102      PERFORM S898-TS-DELETE THRU S898-EXIT.                       DTSCSSF
00103                                                                   DTSCSSF
00104      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCSSF
00105                                                                   DTSCSSF
00106      IF LCCM-NO-MSG                                               DTSCSSF
00107          MOVE PMSG-THANK-YOU TO LCCM-MSG-AREA.                    DTSCSSF
00108                                                                   DTSCSSF
00109      PERFORM S805-MSG-AREA THRU S805-EXIT.                        DTSCSSF
00110                                                                   DTSCSSF
00111      PERFORM S2100-SEND THRU S2100-EXIT.                          DTSCSSF
00112                                                                   DTSCSSF
00113      PERFORM SUCTRAN-ON THRU SUCTRAN-EXIT.                        DTSCSSF
00114                                                                   DTSCSSF
00115      SET LCCM-END-CONVERSATION-88 TO TRUE.                        DTSCSSF
00116                                                                   DTSCSSF
00117      EXEC CICS                                                    DTSCSSF
00118          RETURN                                                   DTSCSSF
00119      END-EXEC.                                                    DTSCSSF
00120      SKIP2                                                        DTSCSSF
00121      GOBACK.                                                      DTSCSSF
00122      EJECT                                                        DTSCSSF
00123  P1000-FOPR-UPDATE.                                               DTSCSSF
00124      MOVE LOW-VALUES TO FOPR-KEY-AREA.                            DTSCSSF
00125      SET FOPR-OPR-88 TO TRUE.                                     DTSCSSF
00126      MOVE LCCM-OP-ID TO FOPR-OP-ID.                               DTSCSSF
00127                                                                   DTSCSSF
00128      PERFORM S831-REF-READ THRU S831-EXIT.                        DTSCSSF
00129      IF L831-OK-88                                                DTSCSSF
00130          NEXT SENTENCE                                            DTSCSSF
00131      ELSE                                                         DTSCSSF
00132          GO TO P1000-EXIT.                                        DTSCSSF
00133                                                                   DTSCSSF
00134      IF LCCM-OP-ALARM-IND = SPACES OR LOW-VALUES                  DTSCSSF
00135          NEXT SENTENCE                                            DTSCSSF
00136      ELSE                                                         DTSCSSF
00137          MOVE LCCM-OP-ALARM-IND TO FOPR-ALARM-IND.                DTSCSSF
00138                                                                   DTSCSSF
00139      IF LCCM-OP-ARPT-EDIT-MINIMAL-88                                 CL**2
00140             OR                                                       CL**2
00141         LCCM-OP-ARPT-EDIT-FULL-88                                    CL**2
00142          MOVE LCCM-OP-ARPT-EDIT-MODE TO FOPR-ARPT-EDIT-MODE.         CL**2
00143                                                                      CL**2
00144      IF LCCM-PRINTER-ID = SPACES OR LOW-VALUES                    DTSCSSF
00145          NEXT SENTENCE                                            DTSCSSF
00146      ELSE                                                         DTSCSSF
00147          MOVE LCCM-PRINTER-ID TO FOPR-PRINTER-ID.                 DTSCSSF
00148                                                                   DTSCSSF
00149      IF LCCM-BATCH-NO NUMERIC                                     DTSCSSF
00150          MOVE LCCM-BATCH-NO TO FOPR-BATCH-NO.                     DTSCSSF
00151                                                                   DTSCSSF
00152      PERFORM S831-REF-REWRITE THRU S831-EXIT.                     DTSCSSF
00153  P1000-EXIT.                                                      DTSCSSF
00154      EXIT.                                                        DTSCSSF
00155      EJECT                                                        DTSCSSF
00156  S805-MSG-AREA.                                                   DTSCSSF
00157      MOVE LCCM-MSG-AREA TO L805-MSG-AREA.                         DTSCSSF
00158                                                                   DTSCSSF
00159      EXEC CICS                                                    DTSCSSF
00160          LINK                                                     DTSCSSF
00161              PROGRAM ('DTSCU805')                                    CL**2
00162              COMMAREA (L805-COMM-AREA)                            DTSCSSF
00163      END-EXEC.                                                    DTSCSSF
00164                                                                   DTSCSSF
00165      MOVE L805-S-MSG-AREA TO MAP-MSG-AREA.                        DTSCSSF
00166                                                                   DTSCSSF
00167      MOVE SPACES TO MAP-MSG-ID (1:3).                             DTSCSSF
00168  S805-EXIT.                                                       DTSCSSF
00169      EXIT.                                                        DTSCSSF
00170      SKIP3                                                        DTSCSSF
00171  S831-REF-READ.                                                   DTSCSSF
00172      SET L831-READ-88 TO TRUE.                                    DTSCSSF
00173      GO TO S831-REF-IO.                                           DTSCSSF
00174                                                                   DTSCSSF
00175  S831-REF-REWRITE.                                                DTSCSSF
00176      SET L831-REWRITE-88 TO TRUE.                                 DTSCSSF
00177      GO TO S831-REF-IO.                                           DTSCSSF
00178                                                                   DTSCSSF
00179  S831-REF-IO.                                                     DTSCSSF
00180                                                                   DTSCSSF
00181      EXEC CICS                                                    DTSCSSF
00182          LINK                                                     DTSCSSF
00183              PROGRAM ('DTSCU831')                                    CL**2
00184              COMMAREA (L831-COMM-AREA)                            DTSCSSF
00185      END-EXEC.                                                    DTSCSSF
00186                                                                   DTSCSSF
00187  S831-EXIT.                                                       DTSCSSF
00188      EXIT.                                                        DTSCSSF
00189      SKIP3                                                        DTSCSSF
00190  S898-TS-DELETE.                                                  DTSCSSF
00191      EXEC CICS                                                    DTSCSSF
00192          LINK                                                     DTSCSSF
00193              PROGRAM ('DTSCU898')                                    CL**2
00194      END-EXEC.                                                    DTSCSSF
00195  S898-EXIT.                                                       DTSCSSF
00196      EXIT.                                                        DTSCSSF
00197      SKIP3                                                        DTSCSSF
00198  SUCTRAN-ON.                                                      DTSCSSF
00199                                                                      CL**2
00200 *****                                                                CL**2
00201 *                                                                    CL**2
00202 *    UCTRAN VERSION 4.1                                              CL**4
00203 *                                                                    CL**2
00204 *****                                                                CL**2
00205                                                                      CL**2
00206      EXEC CICS                                                       CL**3
00207          LINK                                                        CL**3
00208              PROGRAM ('UCTRAN41')                                    CL**6
00209              COMMAREA (UCPARM)                                       CL**4
00210      END-EXEC.                                                       CL**3
00211                                                                   DTSCSSF
00212      GO TO SUCTRAN-EXIT.                                          DTSCSSF
00213                                                                   DTSCSSF
00214  SUCTRAN-EXIT.                                                    DTSCSSF
00215      EXIT.                                                        DTSCSSF
00216      EJECT                                                        DTSCSSF
00217  S2100-SEND.                                                      DTSCSSF
00218      MOVE CATB-CURSOR TO MAP-CURSOR-FIELD-L.                      DTSCSSF
00219                                                                   DTSCSSF
00220      SET L851-SEND-88 TO TRUE.                                    DTSCSSF
00221                                                                      CL**2
00222      MOVE WRK-SCR-ID TO L851-SCR-ID                               DTSCSSF
00223                         LCCM-SCR-ID.                              DTSCSSF
00224                                                                   DTSCSSF
00225      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND.                    DTSCSSF
00226                                                                      CL**2
00227      MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE.                         DTSCSSF
00228                                                                      CL**2
00229      EXEC CICS                                                    DTSCSSF
00230          LINK                                                     DTSCSSF
00231              PROGRAM ('DTSCU851')                                    CL**2
00232              COMMAREA (L851-COMM-AREA)                            DTSCSSF
00233      END-EXEC.                                                    DTSCSSF
00234                                                                   DTSCSSF
00235  S2100-EXIT.                                                      DTSCSSF
00236      EXIT.                                                        DTSCSSF
