00001  IDENTIFICATION DIVISION.                                         09/01/16
00002  PROGRAM-ID.             DTSCS82.                                 DTSCS82
00003  AUTHOR.                 TRICOASTAL CONSULTING LTD.                  LV030
00004  DATE-WRITTEN.           SEPTEMBER 1998.                          DTSCS82
00005  DATE-COMPILED.                                                   DTSCS82
00006      SKIP3                                                        DTSCS82
00007 *****                                                             DTSCS82
00008 *                                                                 DTSCS82
00009 *    FUNCTION:  CALENDAR QUARTER INQUIRY/UPDATE                   DTSCS82
00010 *               SCREEN PROCESSOR.                                 DTSCS82
00011 *****                                                             DTSCS82
00012 *                                                                 DTSCS82
00013 *    MODIFICATION LOG:                                            DTSCS82
00014 *                                                                 DTSCS82
00015 *    09/03/1998  INITIAL DEVELOPMENT. MODIFIED FROM MACCS82.      DTSCS82
00016 *                WORK ORDER:                      PROGRAMMER: GD  DTSCS82
00017 *                                                                 DTSCS82
00018 *    05/21/1999  PICKUP MODIFICATIONS.  DO NOT ALLOW ADD          DTSCS82
00019 *                OR MODIFY FOR YRQ <= 19924.                      DTSCS82
00020 *                REFERENCE: PICKUP DIR            PROGRAMMER: EHH DTSCS82
00021 *                                                                 DTSCS82
00022 *    12/18/2099  ADDED NEW FIELD TO SHOW WHEN INTENT TO ESTIMATE  DTSCS82
00023 *                LETTER WAS SENT                                  DTSCS82
00024 *                REFERENCE:                       PROGRAMMER: ZL1 DTSCS82
00025 *                                                                 DTSCS82
00026 *    02/18/2099  ADDED NEW FIELD TO SHOW WHEN 2ND LETTER FOR SI   DTSCS82
00027 *                EMPLOYERS WERE SENT                              DTSCS82
00028 *                REFERENCE:                       PROGRAMMER: ZL1 DTSCS82
00029 *                                                                 DTSCS82
00030 *    10/19/2010  CORRECTED EDIT PROBLEM WITH 2ND LETTER FOR SI    DTSCS82
00031 *                EMPLOYERS                                        DTSCS82
00032 *                REFERENCE:                       PROGRAMMER: GD  DTSCS82
00033 *                                                                 DTSCS82
00034 *                                                                 DTSCS82
00035 *    02/20/2013  ADDED NEW FIELD TO SHOW DATE LATE PENALTY WAS    DTSCS82
00036 *                SENT TO SI EMPLOYERS.REPLACED INTENT TO ESTIMATE DTSCS82
00037 *                DATE                                             DTSCS82
00038 *                REFERENCE:                       PROGRAMMER: ZL1 DTSCS82
00039 *                                                                 DTSCS82
00040 *    XX/XX/XXXX  XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSCS82
00041 *                XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSCS82
00042 *                REFERENCE:                       PROGRAMMER: XXX DTSCS82
00043 *                                                                 DTSCS82
00044 *                                                                 DTSCS82
00045 *  DESCRIPTION:                                                   DTSCS82
00046 *                                                                 DTSCS82
00047 *    CLEAR:                                                       DTSCS82
00048 *                                                                 DTSCS82
00049 *      DATA FIELDS DISPLAYED: NONE.                               DTSCS82
00050 *      MESSAGE: NONE (OTHER THAN "DELETE SUCCESSFUL").            DTSCS82
00051 *      MOVE LOW-VALUES TO LCCM-SCR-KEY-AREA.                      DTSCS82
00052 *                                                                 DTSCS82
00053 *                                                                 DTSCS82
00054 *    INQUIRY:                                                     DTSCS82
00055 *                                                                 DTSCS82
00056 *      CONTROL FIELD(S): MAP-YR, MAP-Q.                           DTSCS82
00057 *                                                                 DTSCS82
00058 *      JUMP IN: USE CLEAR LOGIC.                                  DTSCS82
00059 *                                                                 DTSCS82
00060 *      ENTER: DISPLAY FQTR RECORD ASSOCIATED WITH MAP-YR          DTSCS82
00061 *             AND MAP-Q.                                          DTSCS82
00062 *                                                                 DTSCS82
00063 *      PRIOR: STANDARD PAGING LOGIC, EXCEPT BASED ON USER         DTSCS82
00064 *             MODIFICATION TO MAP-YR AND MAP-Q (RATHER THAN       DTSCS82
00065 *             EMP-NO).                                            DTSCS82
00066 *                                                                 DTSCS82
00067 *      NEXT:  STANDARD PAGING LOGIC, EXCEPT BASED ON USER         DTSCS82
00068 *             MODIFICATION TO MAP-YR AND MAP-Q (RATHER THAN       DTSCS82
00069 *             EMP-NO).                                            DTSCS82
00070 *                                                                 DTSCS82
00071 *      WHILE PAGING, CONSIDER THE BREAK TO BE A BREAK IN REC-TYPE.DTSCS82
00072 *      DO NOT "WRAP" PAGING.                                      DTSCS82
00073 *                                                                 DTSCS82
00074 *      A SUCCESSFUL DISPLAY RESULTS IN STORAGE OF THE             DTSCS82
00075 *      FQTR-KEY-AREA OF THE DISPLAYED FQTR RECORD IN              DTSCS82
00076 *      LCCM-SCR-KEY-AREA.                                         DTSCS82
00077 *                                                                 DTSCS82
00078 *                                                                 DTSCS82
00079 *    UPDATE:                                                      DTSCS82
00080 *                                                                 DTSCS82
00081 *      ADD                                                        DTSCS82
00082 *      MOD                                                        DTSCS82
00083 *      DEL                                                        DTSCS82
00084 *                                                                 DTSCS82
00085 *                                                                 DTSCS82
00086 *    RECORDS READ:                                                DTSCS82
00087 *                                                                 DTSCS82
00088 *      MASTER:                                                    DTSCS82
00089 *                                                                 DTSCS82
00090 *        NONE.                                                    DTSCS82
00091 *                                                                 DTSCS82
00092 *                                                                 DTSCS82
00093 *      ALTERNATE INDEX:                                           DTSCS82
00094 *                                                                 DTSCS82
00095 *        NONE.                                                    DTSCS82
00096 *                                                                 DTSCS82
00097 *                                                                 DTSCS82
00098 *      REFERENCE:                                                 DTSCS82
00099 *                                                                 DTSCS82
00100 *        FQTR.                                                    DTSCS82
00101 *                                                                 DTSCS82
00102 *                                                                 DTSCS82
00103 *      ACCOUNTING TRANSACTION COLLECTION:                         DTSCS82
00104 *                                                                 DTSCS82
00105 *        NONE.                                                    DTSCS82
00106 *                                                                 DTSCS82
00107 *                                                                 DTSCS82
00108 *    RECORDS UPDATED:                                             DTSCS82
00109 *                                                                 DTSCS82
00110 *      MASTER:                                                    DTSCS82
00111 *                                                                 DTSCS82
00112 *        NONE.                                                    DTSCS82
00113 *                                                                 DTSCS82
00114 *                                                                 DTSCS82
00115 *      REFERENCE:                                                 DTSCS82
00116 *                                                                 DTSCS82
00117 *        FQTR (ADD, MOD, DEL).                                    DTSCS82
00118 *                                                                 DTSCS82
00119 *                                                                 DTSCS82
00120 *      ACCOUNTING TRANSACTION COLLECTION:                         DTSCS82
00121 *                                                                 DTSCS82
00122 *        NONE.                                                    DTSCS82
00123 *                                                                 DTSCS82
00124 *                                                                 DTSCS82
00125 *    ON-LINE EVENT FILE RECORDS WRITTEN:                          DTSCS82
00126 *                                                                 DTSCS82
00127 *      NONE.                                                      DTSCS82
00128 *                                                                 DTSCS82
00129 *                                                                 DTSCS82
00130 *    MODULES (OTHER THAN STANDARD SCREEN PROCESSING               DTSCS82
00131 *    UTILITY MODULES) LINKED TO:                                  DTSCS82
00132 *                                                                 DTSCS82
00133 *      DTSCU001 DATE EDIT/CONVERSION.                             DTSCS82
00134 *      DTSCU004 QUARTER EDIT/CONVERSION.                          DTSCS82
00135 *      DTSCU015 DATE FROM SCREEN FORMAT/EDIT.                     DTSCS82
00136 *      DTSCU016 QUARTER FROM SCREEN FORMAT/EDIT.                  DTSCS82
00137 *      DTSCU831 REFERENCE FILE I/O.                               DTSCS82
00138 *                                                                 DTSCS82
00139 *                                                                 DTSCS82
00140 *    MAINTENANCE NOTES:                                           DTSCS82
00141 *                                                                 DTSCS82
00142 *      A NON-KEY FIELD ADDED TO OR REMOVED FROM THE SCREEN        DTSCS82
00143 *      REQUIRES ATTENTION IN THE FOLLOWING AREAS:                 DTSCS82
00144 *        ALTER PARAGRAPHS P6900, P8900, S5900,                    DTSCS82
00145 *        ALTER AS APPROPRIATE PARAGRAPHS LISTED IN S1002,         DTSCS82
00146 *        ALTER THE SEND/RECEIVE AREA DEFINITION (MACIS82),        DTSCS82
00147 *        ALTER THE MAP (MACM82) AND ASSEMBLE THE MAPSET (MACMSET).DTSCS82
00148 *                                                                 DTSCS82
00149 *****                                                             DTSCS82
00150      SKIP3                                                        DTSCS82
00151  ENVIRONMENT DIVISION.                                            DTSCS82
00152      SKIP3                                                        DTSCS82
00153  DATA DIVISION.                                                   DTSCS82
00154      SKIP3                                                        DTSCS82
00155  WORKING-STORAGE SECTION.                                         DTSCS82
001555 77  PAN-VALET PICTURE X(24) VALUE '030DTSCS82   09/01/16'.       DTSCS82
00156  77  PAN-VALET PICTURE X(24) VALUE '004DTSCS82   09/01/16'.       DTSCS82
00157  77  PAN-VALET PICTURE X(24) VALUE '028DTSCS82   04/01/13'.       DTSCS82
00158  77  PAN-VALET PICTURE X(24) VALUE '004DTSCS82   02/21/13'.       DTSCS82
00159  77  PAN-VALET PICTURE X(24) VALUE '026DTSCS82   10/19/10'.       DTSCS82
00160      SKIP3                                                        DTSCS82
00161  01  WRK-AREA.                                                    DTSCS82
00162      05  WRK-ABEND-CD                PIC  X(04)  VALUE 'S82 '.    DTSCS82
00163      SKIP1                                                        DTSCS82
00164      05  WRK-SCR-ID.                                              DTSCS82
00165          10  WRK-SCR-ID-9            PIC  9(02)  VALUE  82.       DTSCS82
00166      05  WRK-F03-SCR-ID              PIC  X(02)  VALUE '80'.      DTSCS82
00167      SKIP1                                                        DTSCS82
00168      05  WRK-KEY-AREA.                                            DTSCS82
00169          10  WRK-REC-TYPE            PIC S9(04)  COMP.            DTSCS82
00170          10  WRK-QTR                 PIC S9(05)  COMP-3.          DTSCS82
00171          10  FILLER                  PIC  X(11).                  DTSCS82
00172      SKIP1                                                        DTSCS82
00173      05  WRK-DISP-DATE               PIC  9(08).                  DTSCS82
00174      05  FILLER   REDEFINES   WRK-DISP-DATE.                      DTSCS82
00175          10  WRK-DISP-CC             PIC  X(02).                  DTSCS82
00176          10  WRK-DISP-YY             PIC  X(02).                  DTSCS82
00177          10  WRK-DISP-MM             PIC  X(02).                  DTSCS82
00178          10  WRK-DISP-DD             PIC  X(02).                  DTSCS82
00179      SKIP1                                                        DTSCS82
00180      05  WRK-NO-ENTRY                PIC S9(09) COMP-3            DTSCS82
00181                                              VALUE +999999999.    DTSCS82
00182      05  WRK-UC30-MASS-MAIL-DATE     PIC S9(09) COMP-3.           DTSCS82
00183      05  WRK-UC30-FIRST-DEL-DATE     PIC S9(09) COMP-3.           DTSCS82
00184      05  WRK-UC30-FINAL-DEL-DATE     PIC S9(09) COMP-3.           DTSCS82
00185      05  WRK-UC30-ESTIMATED-DATE     PIC S9(09) COMP-3.           DTSCS82
00186      05  WRK-DELQ-LTR-SENT-DATE      PIC S9(09) COMP-3.           DTSCS82
00187      05  WRK-SELF-INS-CHG-RUN-DATE   PIC S9(09) COMP-3.           DTSCS82
00188      05  WRK-YRQ-START-DATE          PIC S9(09) COMP-3.           DTSCS82
00189      05  WRK-YRQ-END-DATE            PIC S9(09) COMP-3.           DTSCS82
00190      05  WRK-YRQ-PLUS1-START-DATE    PIC S9(09) COMP-3.           DTSCS82
00191      05  WRK-YRQ-PLUS1-END-DATE      PIC S9(09) COMP-3.           DTSCS82
00192      05  WRK-DEFAULT-LATE-PEN-DATE   PIC S9(09) COMP-3.           DTSCS82
00193      EJECT                                                        DTSCS82
00194  01  SCREEN-PROCESSING.                                           DTSCS82
00195      05  SCR-ACCESS-IND              PIC X(01).                   DTSCS82
00196          88  SCR-ACCESS-INQ                  VALUE '1'.           DTSCS82
00197          88  SCR-ACCESS-UPDATE               VALUE '2'.           DTSCS82
00198      SKIP1                                                        DTSCS82
00199      05  CURSOR-SET-IND              PIC X(01).                   DTSCS82
00200          88  CURSOR-SET-YES                  VALUE 'Y'.           DTSCS82
00201          88  CURSOR-SET-NO                   VALUE 'N'.           DTSCS82
00202          88  CURSOR-SET-GOTO                 VALUE 'G'.           DTSCS82
00203      SKIP1                                                        DTSCS82
00204      05  REQ-IND                     PIC X(01).                   DTSCS82
00205          88  REQ-ERROR                       VALUE 'O'.           DTSCS82
00206          88  REQ-JUMP                        VALUE 'J'.           DTSCS82
00207          88  REQ-INQUIRE                     VALUE 'I'.           DTSCS82
00208          88  REQ-CLEAR                       VALUE 'C'.           DTSCS82
00209          88  REQ-EDIT                        VALUE 'E'.           DTSCS82
00210          88  REQ-UPDATE                      VALUE 'U'.           DTSCS82
00211          88  REQ-CURSOR-TO-GOTO              VALUE 'G'.           DTSCS82
00212      SKIP1                                                        DTSCS82
00213      05  RESP-IND                    PIC X(01).                   DTSCS82
00214          88  RESP-SEND-MSGONLY               VALUE 'O'.           DTSCS82
00215          88  RESP-SEND-MAP                   VALUE 'M'.           DTSCS82
00216          88  RESP-JUMP                       VALUE 'J'.           DTSCS82
00217          88  RESP-CURSOR-TO-GOTO             VALUE 'G'.           DTSCS82
00218      SKIP1                                                        DTSCS82
00219      05  WRK-NEW-KEY-IND             PIC  X(01).                  DTSCS82
00220      SKIP1                                                        DTSCS82
00221      05  WRK-MSG-ID                  PIC  X(04).                  DTSCS82
00222      SKIP1                                                        DTSCS82
00223      05  WRK-ATB-AN               PIC  X(01).                     DTSCS82
00224      05  WRK-ATB-NUM                 PIC  X(01).                  DTSCS82
00225      EJECT                                                        DTSCS82
00226  01  L001-COMM-AREA.                                              DTSCS82
00227  ++INCLUDE DTSIL001                                               DTSCS82
00228      EJECT                                                        DTSCS82
00229  01  L004-COMM-AREA.                                              DTSCS82
00230  ++INCLUDE DTSIL004                                               DTSCS82
00231      EJECT                                                        DTSCS82
00232  01  L015-COMM-AREA.                                              DTSCS82
00233  ++INCLUDE DTSIL015                                               DTSCS82
00234      EJECT                                                        DTSCS82
00235  01  L016-COMM-AREA.                                              DTSCS82
00236  ++INCLUDE DTSIL016                                               DTSCS82
00237      EJECT                                                        DTSCS82
00238 * ERROR MSG MODULE                                                DTSCS82
00239  01  L805-COMM-AREA.                                              DTSCS82
00240  ++INCLUDE DTSIL805                                               DTSCS82
00241      EJECT                                                        DTSCS82
00242 * REFERENCE FILE I-O LINKAGE                                      DTSCS82
00243  01  L831-COMM-AREA.                                              DTSCS82
00244      05  L831-CONTROL-BLOCK.                                      DTSCS82
00245  ++INCLUDE DTSIL831                                               DTSCS82
00246      EJECT                                                        DTSCS82
00247 * COMMON SKELETAL RECORD                                          DTSCS82
00248      05  FCOMM-REC.                                               DTSCS82
00249  ++INCLUDE DTSIFSKL                                               DTSCS82
00250      EJECT                                                        DTSCS82
00251 * CALENDAR YEAR RECORD LAYOUT                                     DTSCS82
00252      05  FQTR-REC REDEFINES FCOMM-REC.                            DTSCS82
00253  ++INCLUDE DTSIFQTR                                               DTSCS82
00254      EJECT                                                        DTSCS82
00255 * MAP DEFINITION                                                  DTSCS82
00256  01  L851-COMM-AREA.                                              DTSCS82
00257  ++INCLUDE DTSIL851                                               DTSCS82
00258      SKIP3                                                        DTSCS82
00259      05  MAP-AREA REDEFINES L851-MAP-AREA.                        DTSCS82
00260  ++INCLUDE DTSIS82                                                DTSCS82
00261      EJECT                                                        DTSCS82
00262 * ATTRIBUTE LITERALS                                              DTSCS82
00263  01  CATB-LITERALS.                                               DTSCS82
00264  ++INCLUDE DTSICATB                                               DTSCS82
00265      SKIP3                                                        DTSCS82
00266 * FUNCTION KEY DESCRIPTION LITERALS                               DTSCS82
00267  01  CFKD-LITERALS.                                               DTSCS82
00268  ++INCLUDE DTSICFKD                                               DTSCS82
00269      SKIP3                                                        DTSCS82
00270 * ERROR CODE MESSAGE LITERALS                                     DTSCS82
00271  01  CECD-LITERALS.                                               DTSCS82
00272  ++INCLUDE DTSICECD                                               DTSCS82
00273      SKIP3                                                        DTSCS82
00274 * PROMPT CODE MESSAGE LITERALS                                    DTSCS82
00275  01  CPCD-LITERALS.                                               DTSCS82
00276  ++INCLUDE DTSICPCD                                               DTSCS82
00277      EJECT                                                        DTSCS82
00278  LINKAGE SECTION.                                                 DTSCS82
00279      SKIP3                                                        DTSCS82
00280  01  DFHCOMMAREA.                                                 DTSCS82
00281  ++INCLUDE DTSILCCM                                               DTSCS82
00282      SKIP3                                                        DTSCS82
00283              15  FILLER REDEFINES LCCM-SCR-HOLD-AREA.             DTSCS82
00284                  20  LCCM-SCR-KEY-AREA   PIC  X(16).              DTSCS82
00285      EJECT                                                        DTSCS82
00286 ******************************************************************DTSCS82
00287 *                                                                *DTSCS82
00288 ******************************************************************DTSCS82
00289      SKIP1                                                        DTSCS82
00290  PROCEDURE DIVISION.                                              DTSCS82
00291      SKIP2                                                        DTSCS82
00292      SET CURSOR-SET-NO TO TRUE.                                   DTSCS82
00293      SKIP1                                                        DTSCS82
00294      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS82
00295      SKIP1                                                        DTSCS82
00296      MOVE LCCM-SCR-NUM-ACCESS-IND (WRK-SCR-ID-9)                  DTSCS82
00297        TO SCR-ACCESS-IND.                                         DTSCS82
00298      SKIP3                                                        DTSCS82
00299      MOVE SPACE TO REQ-IND.                                       DTSCS82
00300      SKIP1                                                        DTSCS82
00301      PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT.               DTSCS82
00302      SKIP1                                                        DTSCS82
00303 *-----------------------------------------------------            DTSCS82
00304 *    P1000-ANALYZE-REQUEST HAS DETERMINED, BASED ON THE           DTSCS82
00305 *    "AID" KEY PRESSED AND THE CONTEXT OF THE CURRENT             DTSCS82
00306 *    REQUEST WITHIN THE PSEUDO CONVERSATION, THE TYPE             DTSCS82
00307 *    OF ACTIVITY THE WORK STATION OPERATOR HAS REQUESTED.         DTSCS82
00308 *                                                                 DTSCS82
00309 *    THE REQUEST, REFLECTED IN REQ-IND WILL NOW BE                DTSCS82
00310 *    PROCESSED.                                                   DTSCS82
00311 *                                                                 DTSCS82
00312 *    THE REQUEST PROCESSING PARAGRAPHS WILL SET RESP-IND,         DTSCS82
00313 *    INDICATING THE TYPE OF RESPONSE TO BE SENT TO THE            DTSCS82
00314 *    WORK STATION OPERATOR.                                       DTSCS82
00315 *-----------------------------------------------------            DTSCS82
00316      SKIP1                                                        DTSCS82
00317      MOVE SPACE TO RESP-IND.                                      DTSCS82
00318      SKIP1                                                        DTSCS82
00319      IF REQ-ERROR                                                 DTSCS82
00320         PERFORM P2000-REQUEST-ERROR THRU P2000-EXIT               DTSCS82
00321      ELSE                                                         DTSCS82
00322      IF REQ-JUMP                                                  DTSCS82
00323         PERFORM P3000-REQUEST-JUMP THRU P3000-EXIT                DTSCS82
00324      ELSE                                                         DTSCS82
00325      IF REQ-CLEAR                                                 DTSCS82
00326         PERFORM P4000-REQUEST-CLEAR THRU P4000-EXIT               DTSCS82
00327      ELSE                                                         DTSCS82
00328      IF REQ-CURSOR-TO-GOTO                                        DTSCS82
00329         PERFORM P5000-CURSOR-TO-GOTO THRU P5000-EXIT              DTSCS82
00330      ELSE                                                         DTSCS82
00331      IF REQ-INQUIRE                                               DTSCS82
00332         PERFORM P6000-REQUEST-INQUIRE THRU P6000-EXIT             DTSCS82
00333      ELSE                                                         DTSCS82
00334      IF REQ-EDIT                                                  DTSCS82
00335         PERFORM P7000-REQUEST-EDIT THRU P7000-EXIT                DTSCS82
00336      ELSE                                                         DTSCS82
00337      IF REQ-UPDATE                                                DTSCS82
00338         PERFORM P8000-REQUEST-UPDATE THRU P8000-EXIT              DTSCS82
00339      ELSE                                                         DTSCS82
00340         PERFORM S899-ABEND THRU S899-EXIT.                        DTSCS82
00341      SKIP3                                                        DTSCS82
00342 *-----------------------------------------------------            DTSCS82
00343 *    THE REQUEST PROCESSING PARAGRAPHS HAVE INDICATED             DTSCS82
00344 *    IN RESP-IND THE TYPE OF RESPONSE TO BE MADE.                 DTSCS82
00345 *-----------------------------------------------------            DTSCS82
00346      SKIP1                                                        DTSCS82
00347      IF RESP-SEND-MAP                                             DTSCS82
00348          PERFORM S9300-SEND-MAP THRU S9300-EXIT                   DTSCS82
00349          SET LCCM-END-TASK-88 TO TRUE                             DTSCS82
00350      ELSE                                                         DTSCS82
00351      IF RESP-SEND-MSGONLY                                         DTSCS82
00352      OR RESP-CURSOR-TO-GOTO                                       DTSCS82
00353          PERFORM S9200-SEND-DATAONLY THRU S9200-EXIT              DTSCS82
00354          SET LCCM-END-TASK-88 TO TRUE                             DTSCS82
00355      ELSE                                                         DTSCS82
00356      IF RESP-JUMP                                                 DTSCS82
00357          SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS82
00358      ELSE                                                         DTSCS82
00359          PERFORM S899-ABEND THRU S899-EXIT.                       DTSCS82
00360      SKIP3                                                        DTSCS82
00361  MAINLINE-EXIT.                                                   DTSCS82
00362      SKIP1                                                        DTSCS82
00363      EXEC CICS                                                    DTSCS82
00364          RETURN                                                   DTSCS82
00365      END-EXEC.                                                    DTSCS82
00366      SKIP2                                                        DTSCS82
00367      GOBACK.                                                      DTSCS82
00368 /*****************************************************************DTSCS82
00369 * DETERMINE CURRENT SCREEN STATE AND REQUEST COMBINATION         *DTSCS82
00370 ******************************************************************DTSCS82
00371  P1000-ANALYZE-REQUEST.                                           DTSCS82
00372      SKIP1                                                        DTSCS82
00373 *-----------------------------------------------------            DTSCS82
00374 *     IF SCREEN IS NOT CURRENTLY DISPLAYED (JUMP TO HERE)         DTSCS82
00375 *     THEN ANY KEY PRESSED WILL BE IGNORED (WILL BE               DTSCS82
00376 *     REPLACED WITH ENTER)                                        DTSCS82
00377 *-----------------------------------------------------            DTSCS82
00378      IF LCCM-SCR-ID NOT = WRK-SCR-ID                              DTSCS82
00379         SET LCCM-ENTER-88 TO TRUE                                 DTSCS82
00380         SET REQ-CLEAR TO TRUE                                     DTSCS82
00381         GO TO P1000-EXIT.                                         DTSCS82
00382      SKIP3                                                        DTSCS82
00383 *-----------------------------------------------------            DTSCS82
00384 *      MAP IS RECEIVED                                            DTSCS82
00385 *-----------------------------------------------------            DTSCS82
00386      PERFORM S9100-RECEIVE THRU S9100-EXIT.                       DTSCS82
00387      SKIP3                                                        DTSCS82
00388 *-----------------------------------------------------            DTSCS82
00389 *    CHECK FOR AID KEYS THAT DO NOT SEND DATA FROM THE            DTSCS82
00390 *    WORK STATION                                                 DTSCS82
00391 *-----------------------------------------------------            DTSCS82
00392      IF LCCM-CLEAR-88                                             DTSCS82
00393         SET REQ-CLEAR TO TRUE                                     DTSCS82
00394         GO TO P1000-EXIT.                                         DTSCS82
00395      SKIP3                                                        DTSCS82
00396 *-----------------------------------------------------            DTSCS82
00397 *    IF IN UPDATE MODE, SPECIFIC KEYS MUST BE CHECKED             DTSCS82
00398 *-----------------------------------------------------            DTSCS82
00399      IF LCCM-SCR-UPDATE-LOCKED                                    DTSCS82
00400         PERFORM P1100-UPDATE-LOCKED THRU P1100-EXIT               DTSCS82
00401         GO TO P1000-EXIT.                                         DTSCS82
00402      SKIP3                                                        DTSCS82
00403 *-----------------------------------------------------            DTSCS82
00404 *    PA2 IS A REQUEST TO POSITION CURSOR AT GO TO:                DTSCS82
00405 *-----------------------------------------------------            DTSCS82
00406      IF LCCM-PA2-88                                               DTSCS82
00407          SET REQ-CURSOR-TO-GOTO TO TRUE                           DTSCS82
00408          GO TO P1000-EXIT.                                        DTSCS82
00409      SKIP3                                                        DTSCS82
00410 *-----------------------------------------------------            DTSCS82
00411 *    ALL OTHER PA KEYS ARE NOT ACTIVE                             DTSCS82
00412 *-----------------------------------------------------            DTSCS82
00413      IF LCCM-PA-88                                                DTSCS82
00414        PERFORM S804-INVALID-KEY THRU S804-EXIT                    DTSCS82
00415        SET REQ-ERROR TO TRUE                                      DTSCS82
00416        GO TO P1000-EXIT.                                          DTSCS82
00417      SKIP3                                                        DTSCS82
00418 *-----------------------------------------------------            DTSCS82
00419 *    IF F12 PRESSED WHEN UPDATE NOT IN PROGRESS IS A              DTSCS82
00420 *    REQUEST TO CLEAR THE SCREEN.                                 DTSCS82
00421 *-----------------------------------------------------            DTSCS82
00422      IF LCCM-F12-88                                               DTSCS82
00423         MOVE LOW-VALUES TO MAP-AREA                               DTSCS82
00424         SET REQ-CLEAR TO TRUE                                     DTSCS82
00425         GO TO P1000-EXIT.                                         DTSCS82
00426      SKIP3                                                        DTSCS82
00427 *-----------------------------------------------------            DTSCS82
00428 *    IF EXIT KEY PRESSED, JUMP TO NEXT HIGHER FUNCTION            DTSCS82
00429 *-----------------------------------------------------            DTSCS82
00430      IF LCCM-F03-88                                               DTSCS82
00431         MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID                    DTSCS82
00432         SET REQ-JUMP TO TRUE                                      DTSCS82
00433         GO TO P1000-EXIT.                                         DTSCS82
00434      SKIP3                                                        DTSCS82
00435 *-----------------------------------------------------            DTSCS82
00436 *    IF PRIOR SCREEN KEY PRESSED, JUMP TO PREVIOUS SCREEN         DTSCS82
00437 *-----------------------------------------------------            DTSCS82
00438      IF LCCM-F04-88                                               DTSCS82
00439         MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID                 DTSCS82
00440         SET REQ-JUMP TO TRUE                                      DTSCS82
00441         GO TO P1000-EXIT.                                         DTSCS82
00442      SKIP3                                                        DTSCS82
00443 *-----------------------------------------------------            DTSCS82
00444 *    IF CORRESPONDENCE SCREEN KEY PRESSED, JUMP TO                DTSCS82
00445 *    CORRESPONDENCE SCREEN                                        DTSCS82
00446 *-----------------------------------------------------            DTSCS82
00447      IF LCCM-F14-88                                               DTSCS82
00448         MOVE LCCM-CORR-SCR-ID TO LCCM-REQ-SCR-ID                  DTSCS82
00449         SET REQ-JUMP TO TRUE                                      DTSCS82
00450         GO TO P1000-EXIT.                                         DTSCS82
00451      SKIP3                                                        DTSCS82
00452 *-----------------------------------------------------            DTSCS82
00453 *    IF DIFFERENT SCREEN TYPE IS REQUESTED, JUMP TO               DTSCS82
00454 *    REQUESTED SCREEN TYPE                                        DTSCS82
00455 *-----------------------------------------------------            DTSCS82
00456      IF MAP-GOTO = SPACES OR LOW-VALUES OR WRK-SCR-ID             DTSCS82
00457         NEXT SENTENCE                                             DTSCS82
00458      ELSE                                                         DTSCS82
00459        MOVE MAP-GOTO TO LCCM-REQ-SCR-ID                           DTSCS82
00460        SET REQ-JUMP TO TRUE                                       DTSCS82
00461        GO TO P1000-EXIT.                                          DTSCS82
00462      SKIP3                                                        DTSCS82
00463 *-----------------------------------------------------            DTSCS82
00464 *    IF REQUEST TO UPDATE THE DATA (ADD, MOD, DEL)                DTSCS82
00465 *          VERIFY USER ACCESS TO PERFORM UPDATE                   DTSCS82
00466 *-----------------------------------------------------            DTSCS82
00467      IF LCCM-F09-88 OR LCCM-F10-88 OR LCCM-F23-88                 DTSCS82
00468         IF SCR-ACCESS-UPDATE                                      DTSCS82
00469            SET REQ-EDIT TO TRUE                                   DTSCS82
00470            GO TO P1000-EXIT                                       DTSCS82
00471         ELSE                                                      DTSCS82
00472            PERFORM S804-INVALID-KEY THRU S804-EXIT                DTSCS82
00473            SET REQ-ERROR TO TRUE                                  DTSCS82
00474            GO TO P1000-EXIT.                                      DTSCS82
00475      SKIP3                                                        DTSCS82
00476 *-----------------------------------------------------            DTSCS82
00477 *    IF INQUIRY TYPE KEY PRESSED (ENTER, PAGE DOWN,               DTSCS82
00478 *          PAGE UP), INDICATE INQUIRY REQUEST                     DTSCS82
00479 *-----------------------------------------------------            DTSCS82
00480      IF LCCM-ENTER-88 OR LCCM-F07-88 OR LCCM-F08-88               DTSCS82
00481          SET REQ-INQUIRE TO TRUE                                  DTSCS82
00482          GO TO P1000-EXIT.                                        DTSCS82
00483      SKIP3                                                        DTSCS82
00484 *-----------------------------------------------------            DTSCS82
00485 *     ANY OTHER KEY IS INVALID                                    DTSCS82
00486 *-----------------------------------------------------            DTSCS82
00487      PERFORM S804-INVALID-KEY THRU S804-EXIT.                     DTSCS82
00488      SET REQ-ERROR TO TRUE.                                       DTSCS82
00489  P1000-EXIT.                                                      DTSCS82
00490      EXIT.                                                        DTSCS82
00491      SKIP3                                                        DTSCS82
00492 ******************************************************************DTSCS82
00493 * THE SCREEN IS LOCKED FOR UPDATE AND THE USER CONFIRMS HIS WISH *DTSCS82
00494 ******************************************************************DTSCS82
00495      SKIP1                                                        DTSCS82
00496  P1100-UPDATE-LOCKED.                                             DTSCS82
00497 *-----------------------------------------------------            DTSCS82
00498 *    IF THE SCREEN IS "LOCKED FOR UPDATE", THEN                   DTSCS82
00499 *    THE ONLY VALID OPERATOR REQUESTS ARE ENTER                   DTSCS82
00500 *    (CONFIRMING UPDATE) OR F12 (CANCELLING UPDATE).              DTSCS82
00501 *-----------------------------------------------------            DTSCS82
00502      IF LCCM-ENTER-88 OR LCCM-F12-88                              DTSCS82
00503         SET REQ-UPDATE TO TRUE                                    DTSCS82
00504      ELSE                                                         DTSCS82
00505         SET REQ-ERROR TO TRUE                                     DTSCS82
00506         IF LCCM-SCR-ADD-LOCKED                                    DTSCS82
00507            MOVE PMSG-ADD-CONFIRM TO LCCM-MSG-ID                   DTSCS82
00508         ELSE                                                      DTSCS82
00509         IF LCCM-SCR-MOD-LOCKED                                    DTSCS82
00510            MOVE PMSG-MOD-CONFIRM TO LCCM-MSG-ID                   DTSCS82
00511         ELSE                                                      DTSCS82
00512         IF LCCM-SCR-DEL-LOCKED                                    DTSCS82
00513            MOVE PMSG-DEL-CONFIRM TO LCCM-MSG-ID                   DTSCS82
00514         ELSE                                                      DTSCS82
00515            PERFORM S899-ABEND THRU S899-EXIT.                     DTSCS82
00516  P1100-EXIT.                                                      DTSCS82
00517      EXIT.                                                        DTSCS82
00518 /*****************************************************************DTSCS82
00519 * ANALYZE REQUEST HAS DETERMINED AN ERROR THAT MUST BE REPORTED. *DTSCS82
00520 * VERIFY THAT A MESSAGE HAS BEEN FILLED IN.                      *DTSCS82
00521 ******************************************************************DTSCS82
00522      SKIP1                                                        DTSCS82
00523  P2000-REQUEST-ERROR.                                             DTSCS82
00524      IF LCCM-MSG                                                  DTSCS82
00525         SET RESP-SEND-MSGONLY TO TRUE                             DTSCS82
00526      ELSE                                                         DTSCS82
00527         PERFORM S899-ABEND THRU S899-EXIT.                        DTSCS82
00528  P2000-EXIT.                                                      DTSCS82
00529      EXIT.                                                        DTSCS82
00530 /*****************************************************************DTSCS82
00531 * JUMP TO A DIFFERENT SCREEN TYPE WAS REQUESTED                  *DTSCS82
00532 ******************************************************************DTSCS82
00533      SKIP1                                                        DTSCS82
00534  P3000-REQUEST-JUMP.                                              DTSCS82
00535 *-----------------------------------------------------            DTSCS82
00536 *    VERIFY THAT THE REQUESTED SCREEN EXISTS AND IS ACCESSIBLE    DTSCS82
00537 *    BY USER                                                      DTSCS82
00538 *-----------------------------------------------------            DTSCS82
00539      PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT.                 DTSCS82
00540      SKIP3                                                        DTSCS82
00541 *-----------------------------------------------------            DTSCS82
00542 *    VERIFICATION RETURN LCCM-MSG IF ERROR DETECTED               DTSCS82
00543 *-----------------------------------------------------            DTSCS82
00544      IF LCCM-MSG                                                  DTSCS82
00545         SET RESP-SEND-MSGONLY TO TRUE                             DTSCS82
00546         SET CURSOR-SET-GOTO TO TRUE                               DTSCS82
00547         GO TO P3000-EXIT.                                         DTSCS82
00548      SKIP3                                                        DTSCS82
00549 *-----------------------------------------------------            DTSCS82
00550 *    CLEAN UP INDICATORS AND PAGING STORAGE PRIOR TO LEAVING      DTSCS82
00551 *-----------------------------------------------------            DTSCS82
00552      MOVE LOW-VALUES TO LCCM-SCR-STATUS                           DTSCS82
00553                         LCCM-SCR-HOLD-AREA.                       DTSCS82
00554      MOVE +0 TO LCCM-SCR-ABSTIME.                                 DTSCS82
00555      SET RESP-JUMP TO TRUE.                                       DTSCS82
00556  P3000-EXIT.                                                      DTSCS82
00557      EXIT.                                                        DTSCS82
00558 /*****************************************************************DTSCS82
00559 * CLEAR KEY WAS PRESSED                                          *DTSCS82
00560 ******************************************************************DTSCS82
00561      SKIP1                                                        DTSCS82
00562  P4000-REQUEST-CLEAR.                                             DTSCS82
00563      IF SCR-ACCESS-UPDATE                                         DTSCS82
00564         PERFORM S5200-SET-UPDATE-ATTRB THRU S5200-EXIT            DTSCS82
00565      ELSE                                                         DTSCS82
00566         PERFORM S5300-SET-INQ-ATTRB THRU S5300-EXIT.              DTSCS82
00567      SKIP3                                                        DTSCS82
00568 *-----------------------------------------------------            DTSCS82
00569 *   CLEAN UP INDICATORS AND PAGING STORAGE.  RESET KEY            DTSCS82
00570 *   FIELDS FROM EARLIER REQUESTS                                  DTSCS82
00571 *-----------------------------------------------------            DTSCS82
00572      MOVE LOW-VALUES TO LCCM-SCR-HOLD-AREA.                       DTSCS82
00573      MOVE LCCM-TASK-START-ABSTIME TO LCCM-SCR-ABSTIME.            DTSCS82
00574      SET LCCM-SCR-CLEAR TO TRUE.                                  DTSCS82
00575      SET RESP-SEND-MAP TO TRUE.                                   DTSCS82
00576  P4000-EXIT.                                                      DTSCS82
00577      EXIT.                                                        DTSCS82
00578 /*****************************************************************DTSCS82
00579 * POSITION CURSOR ON GO TO FIELD WAS REQUESTED                   *DTSCS82
00580 ******************************************************************DTSCS82
00581      SKIP1                                                        DTSCS82
00582  P5000-CURSOR-TO-GOTO.                                            DTSCS82
00583      SET CURSOR-SET-GOTO TO TRUE.                                 DTSCS82
00584      SET RESP-CURSOR-TO-GOTO TO TRUE.                             DTSCS82
00585  P5000-EXIT.                                                      DTSCS82
00586      EXIT.                                                        DTSCS82
00587 /*****************************************************************DTSCS82
00588 * INQUIRY WAS REQUESTED                                          *DTSCS82
00589 ******************************************************************DTSCS82
00590      SKIP1                                                        DTSCS82
00591  P6000-REQUEST-INQUIRE.                                           DTSCS82
00592      MOVE LOW-VALUES TO FQTR-KEY-AREA.                            DTSCS82
00593      SET FQTR-QTR-88 TO TRUE.                                     DTSCS82
00594      SKIP1                                                        DTSCS82
00595      MOVE MAP-YRQ-AREA TO L016-S-YRQ-AREA.                        DTSCS82
00596      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS82
00597      MOVE L016-S-YRQ-AREA TO MAP-YRQ-AREA.                        DTSCS82
00598      PERFORM S016-CHECK-MAP-YR-Q THRU S016-EXIT.                  DTSCS82
00599      IF L016-NO-ENTRY                                             DTSCS82
00600          MOVE +0 TO FQTR-YRQ                                      DTSCS82
00601      ELSE                                                         DTSCS82
00602          IF L016-VALID                                            DTSCS82
00603              MOVE L016-YRQ TO FQTR-YRQ                            DTSCS82
00604          ELSE                                                     DTSCS82
00605              MOVE +0 TO FQTR-YRQ                                  DTSCS82
00606              MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID              DTSCS82
00607              PERFORM S1101-ERROR THRU S1101-EXIT.                 DTSCS82
00608      IF  LCCM-SCR-INQUIRE                                         DTSCS82
00609      AND FQTR-KEY-AREA = LCCM-SCR-KEY-AREA                        DTSCS82
00610          MOVE 'N' TO WRK-NEW-KEY-IND                              DTSCS82
00611      ELSE                                                         DTSCS82
00612          MOVE 'Y' TO WRK-NEW-KEY-IND.                             DTSCS82
00613      SKIP1                                                        DTSCS82
00614      IF SCR-ACCESS-UPDATE                                         DTSCS82
00615          PERFORM S5200-SET-UPDATE-ATTRB THRU S5200-EXIT           DTSCS82
00616      ELSE                                                         DTSCS82
00617          PERFORM S5300-SET-INQ-ATTRB THRU S5300-EXIT.             DTSCS82
00618      SKIP1                                                        DTSCS82
00619      SET LCCM-SCR-CLEAR TO TRUE.                                  DTSCS82
00620      MOVE LOW-VALUES TO LCCM-SCR-KEY-AREA.                        DTSCS82
00621      MOVE LCCM-TASK-START-ABSTIME TO LCCM-SCR-ABSTIME.            DTSCS82
00622      SKIP1                                                        DTSCS82
00623      IF LCCM-MSG                                                  DTSCS82
00624          NEXT SENTENCE                                            DTSCS82
00625      ELSE                                                         DTSCS82
00626      IF LCCM-ENTER-88                                             DTSCS82
00627          PERFORM P6100-NO-PAGE THRU P6100-EXIT                    DTSCS82
00628      ELSE                                                         DTSCS82
00629      IF LCCM-F07-88                                               DTSCS82
00630          PERFORM P6200-PAGE-BACK THRU P6200-EXIT                  DTSCS82
00631      ELSE                                                         DTSCS82
00632      IF LCCM-F08-88                                               DTSCS82
00633          PERFORM P6300-PAGE-NEXT THRU P6300-EXIT                  DTSCS82
00634      ELSE                                                         DTSCS82
00635          PERFORM S899-ABEND THRU S899-EXIT.                       DTSCS82
00636      SKIP1                                                        DTSCS82
00637      SET RESP-SEND-MAP TO TRUE.                                   DTSCS82
00638  P6000-EXIT.                                                      DTSCS82
00639      EXIT.                                                        DTSCS82
00640      EJECT                                                        DTSCS82
00641  P6100-NO-PAGE.                                                   DTSCS82
00642      IF L016-NO-ENTRY                                             DTSCS82
00643          MOVE EMSG-FIELD-REQUIRED TO WRK-MSG-ID                   DTSCS82
00644          PERFORM S1101-ERROR THRU S1101-EXIT                      DTSCS82
00645          GO TO P6100-EXIT.                                        DTSCS82
00646      SKIP1                                                        DTSCS82
00647      PERFORM S831-READ THRU S831-EXIT.                            DTSCS82
00648      IF L831-NO-REC-88                                            DTSCS82
00649          MOVE EMSG-NO-RECORD TO WRK-MSG-ID                        DTSCS82
00650          PERFORM S1101-ERROR THRU S1101-EXIT                      DTSCS82
00651          GO TO P6100-EXIT.                                        DTSCS82
00652      SKIP1                                                        DTSCS82
00653      PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT.              DTSCS82
00654  P6100-EXIT.                                                      DTSCS82
00655      EXIT.                                                        DTSCS82
00656      EJECT                                                        DTSCS82
00657  P6200-PAGE-BACK.                                                 DTSCS82
00658      MOVE FQTR-KEY-AREA TO WRK-KEY-AREA.                          DTSCS82
00659      PERFORM S831-START-BROWSE THRU S831-EXIT.                    DTSCS82
00660      IF L831-NO-REC-88                                            DTSCS82
00661          MOVE EMSG-NO-RECORD TO WRK-MSG-ID                        DTSCS82
00662          PERFORM S1101-ERROR THRU S1101-EXIT                      DTSCS82
00663          GO TO P6200-EXIT.                                        DTSCS82
00664      SKIP1                                                        DTSCS82
00665      IF (WRK-NEW-KEY-IND = 'Y')                                   DTSCS82
00666           AND                                                     DTSCS82
00667         (WRK-KEY-AREA = FQTR-KEY-AREA)                            DTSCS82
00668          PERFORM S831-END-BROWSE THRU S831-EXIT                   DTSCS82
00669          PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT           DTSCS82
00670          GO TO P6200-EXIT.                                        DTSCS82
00671      SKIP1                                                        DTSCS82
00672      PERFORM S831-READ-PREV THRU S831-EXIT.                       DTSCS82
00673      IF L831-NO-REC-88                                            DTSCS82
00674          MOVE EMSG-NO-RECORD TO WRK-MSG-ID                        DTSCS82
00675          PERFORM S1101-ERROR THRU S1101-EXIT                      DTSCS82
00676          GO TO P6200-EXIT.                                        DTSCS82
00677      SKIP1                                                        DTSCS82
00678      PERFORM S831-READ-PREV THRU S831-EXIT.                       DTSCS82
00679      IF L831-NO-REC-88                                            DTSCS82
00680          PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT           DTSCS82
00681          MOVE PMSG-FIRST-PAGE TO LCCM-MSG-ID                      DTSCS82
00682      ELSE                                                         DTSCS82
00683          PERFORM S831-END-BROWSE THRU S831-EXIT                   DTSCS82
00684          PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT.          DTSCS82
00685  P6200-EXIT.                                                      DTSCS82
00686      EXIT.                                                        DTSCS82
00687      EJECT                                                        DTSCS82
00688  P6300-PAGE-NEXT.                                                 DTSCS82
00689      MOVE FQTR-KEY-AREA TO WRK-KEY-AREA.                          DTSCS82
00690      PERFORM S831-START-BROWSE THRU S831-EXIT.                    DTSCS82
00691      IF L831-NO-REC-88                                            DTSCS82
00692          MOVE EMSG-NO-RECORD TO WRK-MSG-ID                        DTSCS82
00693          PERFORM S1101-ERROR THRU S1101-EXIT                      DTSCS82
00694          GO TO P6300-EXIT.                                        DTSCS82
00695      SKIP1                                                        DTSCS82
00696      IF (WRK-NEW-KEY-IND = 'N')                                   DTSCS82
00697           AND                                                     DTSCS82
00698         (WRK-KEY-AREA = FQTR-KEY-AREA)                            DTSCS82
00699          NEXT SENTENCE                                            DTSCS82
00700      ELSE                                                         DTSCS82
00701          PERFORM S831-END-BROWSE THRU S831-EXIT                   DTSCS82
00702          PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT           DTSCS82
00703          GO TO P6300-EXIT.                                        DTSCS82
00704      SKIP1                                                        DTSCS82
00705      PERFORM S831-READ-NEXT THRU S831-EXIT.                       DTSCS82
00706      IF L831-NO-REC-88                                            DTSCS82
00707          PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT           DTSCS82
00708          MOVE PMSG-LAST-PAGE TO LCCM-MSG-ID                       DTSCS82
00709      ELSE                                                         DTSCS82
00710          PERFORM S831-END-BROWSE THRU S831-EXIT                   DTSCS82
00711          PERFORM P6900-CONSTRUCT-SCREEN THRU P6900-EXIT.          DTSCS82
00712  P6300-EXIT.                                                      DTSCS82
00713      EXIT.                                                        DTSCS82
00714 /*****************************************************************DTSCS82
00715 * THE RECORD WAS FOUND SO FORMAT AND PLACE ALL FIELDS            *DTSCS82
00716 ******************************************************************DTSCS82
00717      SKIP1                                                        DTSCS82
00718  P6900-CONSTRUCT-SCREEN.                                          DTSCS82
00719      MOVE FQTR-YRQ TO L004-QTR-5-9.                               DTSCS82
00720      SET L004-FROM-5 TO TRUE.                                     DTSCS82
00721      PERFORM S004-YRQ-CONVERT THROUGH S004-EXIT.                  DTSCS82
00722      IF L004-VALID-QTR                                            DTSCS82
00723          MOVE L004-QTR-3-YR TO MAP-YR                             DTSCS82
00724          MOVE L004-QTR-3-Q  TO MAP-Q                              DTSCS82
00725      ELSE                                                         DTSCS82
00726          GO TO S899-ABEND.                                        DTSCS82
00727      SKIP1                                                        DTSCS82
00728      IF FQTR-UC30-MASS-MAIL-DATE NUMERIC                          DTSCS82
00729       IF FQTR-UC30-MASS-MAIL-DATE  NOT =  +0                      DTSCS82
00730          MOVE FQTR-UC30-MASS-MAIL-DATE TO WRK-DISP-DATE           DTSCS82
00731          MOVE WRK-DISP-MM              TO MAP-UC30-MASS-MAIL-MM   DTSCS82
00732          MOVE WRK-DISP-DD              TO MAP-UC30-MASS-MAIL-DD   DTSCS82
00733          MOVE WRK-DISP-YY              TO MAP-UC30-MASS-MAIL-YY.  DTSCS82
00734      SKIP1                                                        DTSCS82
00735      IF FQTR-LATE-PEN-ASSESSED-DATE NUMERIC                       DTSCS82
00736       IF FQTR-LATE-PEN-ASSESSED-DATE NOT = +0                     DTSCS82
00737          MOVE FQTR-LATE-PEN-ASSESSED-DATE TO WRK-DISP-DATE        DTSCS82
00738          MOVE WRK-DISP-MM            TO MAP-LATE-PEN-ASSESSED-MM  DTSCS82
00739          MOVE WRK-DISP-DD            TO MAP-LATE-PEN-ASSESSED-DD  DTSCS82
00740          MOVE WRK-DISP-YY            TO MAP-LATE-PEN-ASSESSED-YY. DTSCS82
00741      SKIP1                                                        DTSCS82
00742      IF FQTR-UC30-FIRST-DEL-DATE NUMERIC                          DTSCS82
00743        IF FQTR-UC30-FIRST-DEL-DATE NOT =  +0                      DTSCS82
00744          MOVE FQTR-UC30-FIRST-DEL-DATE TO WRK-DISP-DATE           DTSCS82
00745          MOVE WRK-DISP-MM              TO MAP-UC30-FIRST-DEL-MM   DTSCS82
00746          MOVE WRK-DISP-DD              TO MAP-UC30-FIRST-DEL-DD   DTSCS82
00747          MOVE WRK-DISP-YY              TO MAP-UC30-FIRST-DEL-YY.  DTSCS82
00748      SKIP1                                                        DTSCS82
00749      IF FQTR-UC30-FINAL-DEL-DATE NUMERIC                          DTSCS82
00750       IF FQTR-UC30-FINAL-DEL-DATE NOT =  +0                       DTSCS82
00751          MOVE FQTR-UC30-FINAL-DEL-DATE TO WRK-DISP-DATE           DTSCS82
00752          MOVE WRK-DISP-MM              TO MAP-UC30-FINAL-DEL-MM   DTSCS82
00753          MOVE WRK-DISP-DD              TO MAP-UC30-FINAL-DEL-DD   DTSCS82
00754          MOVE WRK-DISP-YY              TO MAP-UC30-FINAL-DEL-YY.  DTSCS82
00755      SKIP1                                                        DTSCS82
00756      IF FQTR-UC30-FINAL-ACTION-DATE NUMERIC                       DTSCS82
00757       IF FQTR-UC30-FINAL-ACTION-DATE  NOT =  +0                   DTSCS82
00758          MOVE FQTR-UC30-FINAL-ACTION-DATE TO WRK-DISP-DATE        DTSCS82
00759          MOVE WRK-DISP-MM             TO MAP-UC30-FINAL-ACTION-MM DTSCS82
00760          MOVE WRK-DISP-DD             TO MAP-UC30-FINAL-ACTION-DD DTSCS82
00761          MOVE WRK-DISP-YY             TO MAP-UC30-FINAL-ACTION-YY.DTSCS82
00762      SKIP1                                                        DTSCS82
00763      IF FQTR-DELQ-LTR-SENT-DATE NUMERIC                           DTSCS82
00764       IF FQTR-DELQ-LTR-SENT-DATE  NOT =  +0                       DTSCS82
00765          MOVE FQTR-DELQ-LTR-SENT-DATE TO WRK-DISP-DATE            DTSCS82
00766          MOVE WRK-DISP-MM            TO MAP-DELQ-LTR-SENT-MM      DTSCS82
00767          MOVE WRK-DISP-DD            TO MAP-DELQ-LTR-SENT-DD      DTSCS82
00768          MOVE WRK-DISP-YY            TO MAP-DELQ-LTR-SENT-YY.     DTSCS82
00769      SKIP1                                                        DTSCS82
00770      IF FQTR-ESTIMATED-DATE NUMERIC                               DTSCS82
00771       IF FQTR-ESTIMATED-DATE  NOT =  +0                           DTSCS82
00772          MOVE FQTR-ESTIMATED-DATE TO WRK-DISP-DATE                DTSCS82
00773          MOVE WRK-DISP-MM             TO MAP-UC30-ESTIMATED-MM    DTSCS82
00774          MOVE WRK-DISP-DD             TO MAP-UC30-ESTIMATED-DD    DTSCS82
00775          MOVE WRK-DISP-YY             TO MAP-UC30-ESTIMATED-YY.   DTSCS82
00776      SKIP1                                                        DTSCS82
00777      IF FQTR-SELF-INS-TAX-DUE-DATE NUMERIC                        DTSCS82
00778       IF FQTR-SELF-INS-TAX-DUE-DATE NOT = +0                      DTSCS82
00779          MOVE FQTR-SELF-INS-TAX-DUE-DATE TO WRK-DISP-DATE         DTSCS82
00780          MOVE WRK-DISP-MM             TO MAP-SELF-INS-TAX-DUE-MM  DTSCS82
00781          MOVE WRK-DISP-DD             TO MAP-SELF-INS-TAX-DUE-DD  DTSCS82
00782          MOVE WRK-DISP-YY             TO MAP-SELF-INS-TAX-DUE-YY. DTSCS82
00783      SKIP1                                                        DTSCS82
00784      IF FQTR-SELF-INS-2ND-LETTER-DATE NUMERIC                     DTSCS82
00785       IF FQTR-SELF-INS-2ND-LETTER-DATE NOT = +0                   DTSCS82
00786          MOVE FQTR-SELF-INS-2ND-LETTER-DATE TO WRK-DISP-DATE      DTSCS82
00787          MOVE WRK-DISP-MM             TO MAP-SELF-INS-2ND-LTR-MM  DTSCS82
00788          MOVE WRK-DISP-DD             TO MAP-SELF-INS-2ND-LTR-DD  DTSCS82
00789          MOVE WRK-DISP-YY             TO MAP-SELF-INS-2ND-LTR-YY. DTSCS82
00790      SKIP1                                                        DTSCS82
00791      IF FQTR-SELF-INS-CHG-RUN-DATE NUMERIC                        DTSCS82
00792          IF FQTR-SELF-INS-CHG-RUN-DATE NOT = +0                   DTSCS82
00793              MOVE FQTR-SELF-INS-CHG-RUN-DATE TO WRK-DISP-DATE     DTSCS82
00794              MOVE WRK-DISP-MM         TO MAP-SELF-INS-CHG-RUN-MM  DTSCS82
00795              MOVE WRK-DISP-DD         TO MAP-SELF-INS-CHG-RUN-DD  DTSCS82
00796              MOVE WRK-DISP-YY         TO MAP-SELF-INS-CHG-RUN-YY. DTSCS82
00797      SKIP1                                                        DTSCS82
00798      IF FQTR-ESTB-DATE  NOT =  +0                                 DTSCS82
00799          MOVE FQTR-ESTB-DATE TO L001-FED-8-DATE-9                 DTSCS82
00800          SET L001-FROM-FED-8 TO TRUE                              DTSCS82
00801          PERFORM S001-DATE THRU S001-EXIT                         DTSCS82
00802          MOVE L001-SLASH-DATE TO MAP-ESTB-DATE.                   DTSCS82
00803      SKIP1                                                        DTSCS82
00804      IF FQTR-CHNG-DATE  NOT =  +0                                 DTSCS82
00805          MOVE FQTR-CHNG-DATE TO L001-FED-8-DATE-9                 DTSCS82
00806          SET L001-FROM-FED-8 TO TRUE                              DTSCS82
00807          PERFORM S001-DATE THRU S001-EXIT                         DTSCS82
00808          MOVE L001-SLASH-DATE TO MAP-CHNG-DATE.                   DTSCS82
00809      SKIP1                                                        DTSCS82
00810      SET LCCM-SCR-INQUIRE TO TRUE.                                DTSCS82
00811      MOVE FQTR-KEY-AREA TO LCCM-SCR-KEY-AREA.                     DTSCS82
00812  P6900-EXIT.                                                      DTSCS82
00813      EXIT.                                                        DTSCS82
00814 /*****************************************************************DTSCS82
00815 * FUNCTION KEY WAS PRESSED TO ADD, MOD OR DEL THE RECORD.        *DTSCS82
00816 ******************************************************************DTSCS82
00817      SKIP1                                                        DTSCS82
00818  P7000-REQUEST-EDIT.                                              DTSCS82
00819      PERFORM S5200-SET-UPDATE-ATTRB THRU S5200-EXIT.              DTSCS82
00820      SKIP1                                                        DTSCS82
00821      IF LCCM-F09-88                                               DTSCS82
00822         PERFORM P7100-EDIT-ADD THRU P7100-EXIT                    DTSCS82
00823      ELSE                                                         DTSCS82
00824      IF LCCM-F10-88                                               DTSCS82
00825         PERFORM P7200-EDIT-MOD THRU P7200-EXIT                    DTSCS82
00826      ELSE                                                         DTSCS82
00827      IF LCCM-F23-88                                               DTSCS82
00828         PERFORM P7300-EDIT-DEL THRU P7300-EXIT                    DTSCS82
00829      ELSE                                                         DTSCS82
00830         PERFORM S899-ABEND THRU S899-EXIT.                        DTSCS82
00831      SKIP3                                                        DTSCS82
00832 *------------------------------------------------------           DTSCS82
00833 *  SCREEN STATUS IS NOT CHANGED IF AN ERROR IS DETECTED.          DTSCS82
00834 *  IN ORDER TO CONTINUE TO ATTEMPT AN ADD THE SCREEN MUST REMAIN  DTSCS82
00835 *  IN A 'CLEAR' STATE.  THE SCREEN MUST BE IN 'INQUIRE' STATUS    DTSCS82
00836 *  IF MOD OR DEL FUNCTIONS ARE BEING REQUESTED.                   DTSCS82
00837 *------------------------------------------------------           DTSCS82
00838      SKIP1                                                        DTSCS82
00839      IF LCCM-MSG                                                  DTSCS82
00840         NEXT SENTENCE                                             DTSCS82
00841      ELSE                                                         DTSCS82
00842         PERFORM S5100-SET-LOCK-ATTRB THRU S5100-EXIT              DTSCS82
00843         IF LCCM-F09-88                                            DTSCS82
00844            SET LCCM-SCR-ADD-LOCKED TO TRUE                        DTSCS82
00845            MOVE PMSG-ADD-CONFIRM TO LCCM-MSG-ID                   DTSCS82
00846         ELSE                                                      DTSCS82
00847         IF LCCM-F10-88                                            DTSCS82
00848            SET LCCM-SCR-MOD-LOCKED TO TRUE                        DTSCS82
00849            MOVE PMSG-MOD-CONFIRM TO LCCM-MSG-ID                   DTSCS82
00850         ELSE                                                      DTSCS82
00851         IF LCCM-F23-88                                            DTSCS82
00852            SET LCCM-SCR-DEL-LOCKED TO TRUE                        DTSCS82
00853            MOVE PMSG-DEL-CONFIRM TO LCCM-MSG-ID.                  DTSCS82
00854      SKIP1                                                        DTSCS82
00855      SET RESP-SEND-MAP TO TRUE.                                   DTSCS82
00856  P7000-EXIT.                                                      DTSCS82
00857      EXIT.                                                        DTSCS82
00858 /*****************************************************************DTSCS82
00859 * ADD FUNCTION WAS REQUESTED                                     *DTSCS82
00860 ******************************************************************DTSCS82
00861      SKIP1                                                        DTSCS82
00862  P7100-EDIT-ADD.                                                  DTSCS82
00863 *------------------------------------------------------           DTSCS82
00864 *     ADD REQUIRES THAT THE SCREEN WAS IN THE CLEAR STATE         DTSCS82
00865 *------------------------------------------------------           DTSCS82
00866      IF NOT LCCM-SCR-CLEAR                                        DTSCS82
00867         MOVE EMSG-ADD-PRECEDED TO LCCM-MSG-ID                     DTSCS82
00868         GO TO P7100-EXIT.                                         DTSCS82
00869      SKIP1                                                        DTSCS82
00870      PERFORM S1001-SCREEN-KEY-EDITS THRU S1001-EXIT.              DTSCS82
00871      SKIP1                                                        DTSCS82
00872      IF LCCM-NO-MSG                                               DTSCS82
00873          PERFORM S8010-READ-FQTR THRU S8010-EXIT                  DTSCS82
00874          IF L831-OK-88                                            DTSCS82
00875              MOVE EMSG-RECORD-EXISTS TO WRK-MSG-ID                DTSCS82
00876              PERFORM S1101-ERROR THRU S1101-EXIT                  DTSCS82
00877          ELSE                                                     DTSCS82
00878              PERFORM S1002-SCREEN-DATA-EDITS THRU S1002-EXIT.     DTSCS82
00879  P7100-EXIT.                                                      DTSCS82
00880      EXIT.                                                        DTSCS82
00881 /*****************************************************************DTSCS82
00882 * MODIFICATION FUNCTION WAS REQUESTED                            *DTSCS82
00883 ******************************************************************DTSCS82
00884      SKIP1                                                        DTSCS82
00885  P7200-EDIT-MOD.                                                  DTSCS82
00886 *-----------------------------------------------------            DTSCS82
00887 *    MODIFICATION REQUIRES THAT A RECORD WAS SUCCESSFULLY         DTSCS82
00888 *    INQUIRED                                                     DTSCS82
00889 *-----------------------------------------------------            DTSCS82
00890      IF NOT LCCM-SCR-INQUIRE                                      DTSCS82
00891         MOVE EMSG-MOD-PRECEDED TO LCCM-MSG-ID                     DTSCS82
00892         GO TO P7200-EXIT.                                         DTSCS82
00893      SKIP3                                                        DTSCS82
00894 *-----------------------------------------------------            DTSCS82
00895 *    CONTROL FIELD(S) MAY NOT BE CHANGED DURING THE MOD           DTSCS82
00896 *-----------------------------------------------------            DTSCS82
00897      MOVE LCCM-SCR-KEY-AREA TO WRK-KEY-AREA.                      DTSCS82
00898      MOVE MAP-YRQ-AREA TO L016-S-YRQ-AREA.                        DTSCS82
00899      PERFORM S016-CHECK-MAP-YR-Q THRU S016-EXIT.                  DTSCS82
00900      IF L016-NOT-VALID                                            DTSCS82
00901      OR L016-YRQ  NOT =  WRK-QTR                                  DTSCS82
00902         MOVE EMSG-NO-FIELD-CHANGE-UPDATE TO WRK-MSG-ID            DTSCS82
00903         PERFORM S1101-ERROR THRU S1101-EXIT                       DTSCS82
00904         GO TO P7200-EXIT.                                         DTSCS82
00905      SKIP1                                                        DTSCS82
00906      PERFORM S1001-SCREEN-KEY-EDITS THRU S1001-EXIT.              DTSCS82
00907      SKIP1                                                        DTSCS82
00908      IF LCCM-NO-MSG                                               DTSCS82
00909          PERFORM S8010-READ-FQTR THRU S8010-EXIT                  DTSCS82
00910          IF L831-NO-REC-88                                        DTSCS82
00911             MOVE EMSG-NO-RECORD TO WRK-MSG-ID                     DTSCS82
00912             PERFORM S1101-ERROR THRU S1101-EXIT                   DTSCS82
00913          ELSE                                                     DTSCS82
00914              PERFORM S1002-SCREEN-DATA-EDITS THRU S1002-EXIT.     DTSCS82
00915  P7200-EXIT.                                                      DTSCS82
00916      EXIT.                                                        DTSCS82
00917 /*****************************************************************DTSCS82
00918 * DELETE FUNCTION WAS REQUESTED                                  *DTSCS82
00919 ******************************************************************DTSCS82
00920      SKIP1                                                        DTSCS82
00921  P7300-EDIT-DEL.                                                  DTSCS82
00922 *-----------------------------------------------------            DTSCS82
00923 *    DELETE REQUIRES THAT A RECORD WAS SUCCESSFULLY               DTSCS82
00924 *    INQUIRED                                                     DTSCS82
00925 *-----------------------------------------------------            DTSCS82
00926      IF NOT LCCM-SCR-INQUIRE                                      DTSCS82
00927         MOVE EMSG-DEL-PRECEDED TO LCCM-MSG-ID                     DTSCS82
00928         GO TO P7300-EXIT.                                         DTSCS82
00929      SKIP3                                                        DTSCS82
00930 *-----------------------------------------------------            DTSCS82
00931 *    CONTROL FIELD(S) MAY NOT BE CHANGED DURING A DELETE          DTSCS82
00932 *-----------------------------------------------------            DTSCS82
00933      MOVE LCCM-SCR-KEY-AREA TO WRK-KEY-AREA.                      DTSCS82
00934      MOVE MAP-YRQ-AREA TO L016-S-YRQ-AREA.                        DTSCS82
00935      PERFORM S016-CHECK-MAP-YR-Q THRU S016-EXIT.                  DTSCS82
00936      IF L016-NOT-VALID                                            DTSCS82
00937      OR L016-YRQ  NOT =  WRK-QTR                                  DTSCS82
00938         MOVE EMSG-NO-FIELD-CHANGE-UPDATE TO WRK-MSG-ID            DTSCS82
00939         PERFORM S1101-ERROR THRU S1101-EXIT.                      DTSCS82
00940      SKIP1                                                        DTSCS82
00941      IF LCCM-NO-MSG                                               DTSCS82
00942          PERFORM S8010-READ-FQTR THRU S8010-EXIT                  DTSCS82
00943          IF L831-NO-REC-88                                        DTSCS82
00944             MOVE EMSG-NO-RECORD TO WRK-MSG-ID                     DTSCS82
00945             PERFORM S1101-ERROR THRU S1101-EXIT.                  DTSCS82
00946  P7300-EXIT.                                                      DTSCS82
00947      EXIT.                                                        DTSCS82
00948 /*****************************************************************DTSCS82
00949 * THE UPDATE/ADD/DELETE FUNCTION WAS CONFIRMED OR CANCELED       *DTSCS82
00950 ******************************************************************DTSCS82
00951      SKIP1                                                        DTSCS82
00952  P8000-REQUEST-UPDATE.                                            DTSCS82
00953      PERFORM S5200-SET-UPDATE-ATTRB THRU S5200-EXIT.              DTSCS82
00954      SKIP1                                                        DTSCS82
00955      IF LCCM-SCR-ADD-LOCKED                                       DTSCS82
00956         PERFORM P8100-ADD THRU P8100-EXIT                         DTSCS82
00957      ELSE                                                         DTSCS82
00958      IF LCCM-SCR-MOD-LOCKED                                       DTSCS82
00959         PERFORM P8200-MOD THRU P8200-EXIT                         DTSCS82
00960      ELSE                                                         DTSCS82
00961      IF LCCM-SCR-DEL-LOCKED                                       DTSCS82
00962         PERFORM P8300-DEL THRU P8300-EXIT                         DTSCS82
00963      ELSE                                                         DTSCS82
00964         PERFORM S899-ABEND THRU S899-EXIT.                        DTSCS82
00965      SKIP1                                                        DTSCS82
00966      SET RESP-SEND-MAP TO TRUE.                                   DTSCS82
00967  P8000-EXIT.                                                      DTSCS82
00968      EXIT.                                                        DTSCS82
00969 /*****************************************************************DTSCS82
00970 *                                                                *DTSCS82
00971 ******************************************************************DTSCS82
00972      SKIP1                                                        DTSCS82
00973  P8100-ADD.                                                       DTSCS82
00974      SET LCCM-SCR-CLEAR TO TRUE.                                  DTSCS82
00975      SKIP1                                                        DTSCS82
00976      IF LCCM-F12-88                                               DTSCS82
00977         MOVE PMSG-ADD-CANCELED TO LCCM-MSG-ID                     DTSCS82
00978         GO TO P8100-EXIT.                                         DTSCS82
00979      SKIP1                                                        DTSCS82
00980      PERFORM S8010-READ-FQTR THRU S8010-EXIT.                     DTSCS82
00981      IF L831-OK-88                                                DTSCS82
00982         MOVE EMSG-RECORD-EXISTS TO WRK-MSG-ID                     DTSCS82
00983         PERFORM S1101-ERROR THRU S1101-EXIT                       DTSCS82
00984         GO TO P8100-EXIT.                                         DTSCS82
00985      SKIP1                                                        DTSCS82
00986      MOVE LOW-VALUES TO FQTR-DATA-AREA.                           DTSCS82
00987      SKIP1                                                        DTSCS82
00988      PERFORM P8900-CONSTRUCT-FQTR THRU P8900-EXIT.                DTSCS82
00989      SKIP1                                                        DTSCS82
00990      MOVE LCCM-CURR-RUN-DATE TO FQTR-ESTB-DATE.                   DTSCS82
00991      MOVE LCCM-CURR-RUN-DATE TO FQTR-CHNG-DATE.                   DTSCS82
00992      SKIP1                                                        DTSCS82
00993      PERFORM S831-WRITE THRU S831-EXIT.                           DTSCS82
00994      SKIP1                                                        DTSCS82
00995      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS82
00996      PERFORM S5200-SET-UPDATE-ATTRB THRU S5200-EXIT.              DTSCS82
00997      MOVE PMSG-ADD-SUCCESSFUL TO LCCM-MSG-ID.                     DTSCS82
00998  P8100-EXIT.                                                      DTSCS82
00999      EXIT.                                                        DTSCS82
01000 /*****************************************************************DTSCS82
01001 * IF ENTER OR CANCEL, MODULE IS SET TO INQUIRY REGARDLESS        *DTSCS82
01002 ******************************************************************DTSCS82
01003      SKIP1                                                        DTSCS82
01004  P8200-MOD.                                                       DTSCS82
01005      SET LCCM-SCR-INQUIRE TO TRUE.                                DTSCS82
01006      SKIP1                                                        DTSCS82
01007      IF LCCM-F12-88                                               DTSCS82
01008         MOVE PMSG-MOD-CANCELED        TO LCCM-MSG-ID              DTSCS82
01009         GO TO P8200-EXIT.                                         DTSCS82
01010      SKIP1                                                        DTSCS82
01011      PERFORM S8010-READ-FQTR THRU S8010-EXIT.                     DTSCS82
01012      IF L831-NO-REC-88                                            DTSCS82
01013         MOVE EMSG-NO-RECORD TO WRK-MSG-ID                         DTSCS82
01014         PERFORM S1101-ERROR THRU S1101-EXIT                       DTSCS82
01015         GO TO P8200-EXIT.                                         DTSCS82
01016      SKIP1                                                        DTSCS82
01017      PERFORM P8900-CONSTRUCT-FQTR THRU P8900-EXIT.                DTSCS82
01018      SKIP1                                                        DTSCS82
01019      MOVE LCCM-CURR-RUN-DATE TO FQTR-CHNG-DATE.                   DTSCS82
01020      SKIP1                                                        DTSCS82
01021      PERFORM S831-REWRITE THRU S831-EXIT.                         DTSCS82
01022      SKIP1                                                        DTSCS82
01023      MOVE FQTR-CHNG-DATE TO L001-FED-8-DATE-9.                    DTSCS82
01024      SET L001-FROM-FED-8 TO TRUE.                                 DTSCS82
01025      PERFORM S001-DATE THRU S001-EXIT.                            DTSCS82
01026      MOVE L001-SLASH-DATE TO MAP-CHNG-DATE.                       DTSCS82
01027      SKIP1                                                        DTSCS82
01028      MOVE PMSG-MOD-SUCCESSFUL TO LCCM-MSG-ID.                     DTSCS82
01029  P8200-EXIT.                                                      DTSCS82
01030      EXIT.                                                        DTSCS82
01031 /*****************************************************************DTSCS82
01032 * IF ENTER OR CANCEL, MODULE IS SET TO INQUIRY REGARDLESS        *DTSCS82
01033 ******************************************************************DTSCS82
01034      SKIP1                                                        DTSCS82
01035  P8300-DEL.                                                       DTSCS82
01036      SET LCCM-SCR-INQUIRE TO TRUE.                                DTSCS82
01037      SKIP1                                                        DTSCS82
01038      IF LCCM-F12-88                                               DTSCS82
01039         MOVE PMSG-DEL-CANCELED TO LCCM-MSG-ID                     DTSCS82
01040         GO TO P8300-EXIT.                                         DTSCS82
01041      SKIP1                                                        DTSCS82
01042      PERFORM S8010-READ-FQTR THRU S8010-EXIT.                     DTSCS82
01043      IF NOT L831-OK-88                                            DTSCS82
01044         MOVE EMSG-NO-RECORD TO WRK-MSG-ID                         DTSCS82
01045         PERFORM S1101-ERROR THRU S1101-EXIT                       DTSCS82
01046         GO TO P8300-EXIT.                                         DTSCS82
01047      SKIP1                                                        DTSCS82
01048      PERFORM S831-DELETE THRU S831-EXIT.                          DTSCS82
01049      SKIP1                                                        DTSCS82
01050      MOVE LOW-VALUES TO LCCM-SCR-KEY-AREA.                        DTSCS82
01051      SET LCCM-SCR-CLEAR TO TRUE.                                  DTSCS82
01052      MOVE LCCM-TASK-START-ABSTIME TO LCCM-SCR-ABSTIME.            DTSCS82
01053      SKIP1                                                        DTSCS82
01054      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS82
01055      PERFORM S5200-SET-UPDATE-ATTRB THRU S5200-EXIT.              DTSCS82
01056      SKIP1                                                        DTSCS82
01057      MOVE FQTR-YRQ TO L004-QTR-5-9.                               DTSCS82
01058      SET L004-FROM-5 TO TRUE.                                     DTSCS82
01059      PERFORM S004-YRQ-CONVERT THRU S004-EXIT.                     DTSCS82
01060      IF L004-VALID-QTR                                            DTSCS82
01061          MOVE L004-QTR-3-YR TO MAP-YR                             DTSCS82
01062          MOVE L004-QTR-3-Q  TO MAP-Q                              DTSCS82
01063      ELSE                                                         DTSCS82
01064          GO TO S899-ABEND.                                        DTSCS82
01065      SKIP1                                                        DTSCS82
01066      MOVE PMSG-DEL-SUCCESSFUL TO LCCM-MSG-ID.                     DTSCS82
01067  P8300-EXIT.                                                      DTSCS82
01068      EXIT.                                                        DTSCS82
01069      EJECT                                                        DTSCS82
01070  P8900-CONSTRUCT-FQTR.                                            DTSCS82
01071      SKIP1                                                        DTSCS82
01072      MOVE MAP-UC30-MASS-MAIL-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01073      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01074      MOVE L015-DATE                   TO FQTR-UC30-MASS-MAIL-DATE.DTSCS82
01075      SKIP1                                                        DTSCS82
01076      MOVE MAP-SELF-INS-TAX-DUE-DATE-AREA TO L015-S-DATE-AREA.     DTSCS82
01077      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01078      MOVE L015-DATE               TO FQTR-SELF-INS-TAX-DUE-DATE.  DTSCS82
01079      SKIP1                                                        DTSCS82
01080      MOVE MAP-SELF-INS-2ND-LTR-DATE-AREA TO L015-S-DATE-AREA.     DTSCS82
01081      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01082      MOVE L015-DATE           TO FQTR-SELF-INS-2ND-LETTER-DATE.   DTSCS82
01083      SKIP1                                                        DTSCS82
01084      MOVE MAP-LATE-PEN-ASSESS-DATE-AREA TO L015-S-DATE-AREA.      DTSCS82
01085      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01086      MOVE L015-DATE              TO FQTR-LATE-PEN-ASSESSED-DATE.  DTSCS82
01087      SKIP1                                                        DTSCS82
01088      MOVE MAP-UC30-FIRST-DEL-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01089      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01090      MOVE L015-DATE                   TO FQTR-UC30-FIRST-DEL-DATE.DTSCS82
01091      SKIP1                                                        DTSCS82
01092      MOVE MAP-UC30-FINAL-DEL-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01093      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01094      MOVE L015-DATE                   TO FQTR-UC30-FINAL-DEL-DATE.DTSCS82
01095      SKIP1                                                        DTSCS82
01096      MOVE MAP-DELQ-LTR-SENT-DATE-AREA TO L015-S-DATE-AREA.        DTSCS82
01097      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01098      MOVE L015-DATE           TO FQTR-DELQ-LTR-SENT-DATE.         DTSCS82
01099      SKIP1                                                        DTSCS82
01100      MOVE MAP-UC30-ESTIMATED-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01101      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01102      MOVE L015-DATE           TO FQTR-ESTIMATED-DATE.             DTSCS82
01103      SKIP1                                                        DTSCS82
01104      MOVE MAP-UC30-FINAL-ACT-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01105      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01106      MOVE L015-DATE           TO FQTR-UC30-FINAL-ACTION-DATE.     DTSCS82
01107      SKIP1                                                        DTSCS82
01108      MOVE MAP-SELF-INS-CHG-RUN-DATE-AREA TO L015-S-DATE-AREA.     DTSCS82
01109      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01110      MOVE L015-DATE               TO FQTR-SELF-INS-CHG-RUN-DATE.  DTSCS82
01111  P8900-EXIT.                                                      DTSCS82
01112      EXIT.                                                        DTSCS82
01113 /*****************************************************************DTSCS82
01114 * LINKS TO UTILITY MODULES                                        DTSCS82
01115 ******************************************************************DTSCS82
01116      SKIP1                                                        DTSCS82
01117  S001-DATE.                                                       DTSCS82
01118      EXEC CICS LINK                                               DTSCS82
01119          PROGRAM  ('DTSCU001')                                    DTSCS82
01120          COMMAREA (L001-COMM-AREA)                                DTSCS82
01121      END-EXEC.                                                    DTSCS82
01122  S001-EXIT.                                                       DTSCS82
01123      EXIT.                                                        DTSCS82
01124      SKIP3                                                        DTSCS82
01125  S004-YRQ-CONVERT.                                                DTSCS82
01126      EXEC CICS LINK                                               DTSCS82
01127          PROGRAM  ('DTSCU004')                                    DTSCS82
01128          COMMAREA (L004-COMM-AREA)                                DTSCS82
01129      END-EXEC.                                                    DTSCS82
01130  S004-EXIT.                                                       DTSCS82
01131      EXIT.                                                        DTSCS82
01132      SKIP3                                                        DTSCS82
01133  S015-DATE-AREA.                                                  DTSCS82
01134      EXEC CICS LINK                                               DTSCS82
01135          PROGRAM  ('DTSCU015')                                    DTSCS82
01136          COMMAREA (L015-COMM-AREA)                                DTSCS82
01137      END-EXEC.                                                    DTSCS82
01138  S015-EXIT.                                                       DTSCS82
01139      EXIT.                                                        DTSCS82
01140      SKIP3                                                        DTSCS82
01141  S016-CHECK-MAP-YR-Q.                                             DTSCS82
01142      EXEC CICS LINK                                               DTSCS82
01143          PROGRAM  ('DTSCU016')                                    DTSCS82
01144          COMMAREA (L016-COMM-AREA)                                DTSCS82
01145      END-EXEC.                                                    DTSCS82
01146  S016-EXIT.                                                       DTSCS82
01147      EXIT.                                                        DTSCS82
01148      EJECT                                                        DTSCS82
01149  S803-REQ-SCR-ID-EDIT.                                            DTSCS82
01150      EXEC CICS LINK                                               DTSCS82
01151          PROGRAM  ('DTSCU803')                                    DTSCS82
01152          COMMAREA (DFHCOMMAREA)                                   DTSCS82
01153      END-EXEC.                                                    DTSCS82
01154  S803-EXIT.                                                       DTSCS82
01155      EXIT.                                                        DTSCS82
01156      SKIP3                                                        DTSCS82
01157  S804-INVALID-KEY.                                                DTSCS82
01158      EXEC CICS LINK                                               DTSCS82
01159          PROGRAM  ('DTSCU804')                                    DTSCS82
01160          COMMAREA (DFHCOMMAREA)                                   DTSCS82
01161      END-EXEC.                                                    DTSCS82
01162  S804-EXIT.                                                       DTSCS82
01163      EXIT.                                                        DTSCS82
01164      SKIP3                                                        DTSCS82
01165  S805-MSG-AREA.                                                   DTSCS82
01166      MOVE LCCM-MSG-AREA TO L805-MSG-AREA                          DTSCS82
01167      SKIP1                                                        DTSCS82
01168      EXEC CICS LINK                                               DTSCS82
01169          PROGRAM  ('DTSCU805')                                    DTSCS82
01170          COMMAREA (L805-COMM-AREA)                                DTSCS82
01171      END-EXEC.                                                    DTSCS82
01172      SKIP1                                                        DTSCS82
01173      MOVE L805-S-MSG-AREA TO MAP-MSG-AREA.                        DTSCS82
01174  S805-EXIT.                                                       DTSCS82
01175      EXIT.                                                        DTSCS82
01176      EJECT                                                        DTSCS82
01177  S831-READ.                                                       DTSCS82
01178      SET L831-READ-88 TO TRUE.                                    DTSCS82
01179      GO TO S831-IO.                                               DTSCS82
01180      SKIP1                                                        DTSCS82
01181  S831-START-BROWSE.                                               DTSCS82
01182      SET L831-START-BROWSE-88 TO TRUE.                            DTSCS82
01183      GO TO S831-IO.                                               DTSCS82
01184      SKIP1                                                        DTSCS82
01185  S831-READ-NEXT.                                                  DTSCS82
01186      SET L831-READ-NEXT-88 TO TRUE.                               DTSCS82
01187      GO TO S831-IO.                                               DTSCS82
01188      SKIP1                                                        DTSCS82
01189  S831-READ-PREV.                                                  DTSCS82
01190      SET L831-READ-PREV-88 TO TRUE.                               DTSCS82
01191      GO TO S831-IO.                                               DTSCS82
01192      SKIP1                                                        DTSCS82
01193  S831-END-BROWSE.                                                 DTSCS82
01194      SET L831-END-BROWSE-88 TO TRUE.                              DTSCS82
01195      GO TO S831-IO.                                               DTSCS82
01196      SKIP1                                                        DTSCS82
01197  S831-REWRITE.                                                    DTSCS82
01198      SET L831-REWRITE-88 TO TRUE.                                 DTSCS82
01199      GO TO S831-IO.                                               DTSCS82
01200      SKIP1                                                        DTSCS82
01201  S831-WRITE.                                                      DTSCS82
01202      SET L831-WRITE-88 TO TRUE.                                   DTSCS82
01203      GO TO S831-IO.                                               DTSCS82
01204      SKIP1                                                        DTSCS82
01205  S831-DELETE.                                                     DTSCS82
01206      SET L831-DELETE-88 TO TRUE.                                  DTSCS82
01207      GO TO S831-IO.                                               DTSCS82
01208      SKIP1                                                        DTSCS82
01209  S831-IO.                                                         DTSCS82
01210      SKIP1                                                        DTSCS82
01211      EXEC CICS LINK                                               DTSCS82
01212          PROGRAM  ('DTSCU831')                                    DTSCS82
01213          COMMAREA (L831-COMM-AREA)                                DTSCS82
01214      END-EXEC.                                                    DTSCS82
01215      SKIP1                                                        DTSCS82
01216      IF L831-FILE-CLOSED-88                                       DTSCS82
01217          MOVE L831-MSG-AREA TO LCCM-MSG-AREA                      DTSCS82
01218          SET LCCM-REQ-SCR-SF-88 TO TRUE                           DTSCS82
01219          SET LCCM-LINK-SCREEN-88 TO TRUE                          DTSCS82
01220          GO TO MAINLINE-EXIT.                                     DTSCS82
01221  S831-EXIT.                                                       DTSCS82
01222      EXIT.                                                        DTSCS82
01223      SKIP3                                                        DTSCS82
01224  S851-SCREEN-PROCESSING.                                          DTSCS82
01225      EXEC CICS LINK                                               DTSCS82
01226          PROGRAM  ('DTSCU851')                                    DTSCS82
01227          COMMAREA (L851-COMM-AREA)                                DTSCS82
01228      END-EXEC.                                                    DTSCS82
01229  S851-EXIT.                                                       DTSCS82
01230      EXIT.                                                        DTSCS82
01231      SKIP3                                                        DTSCS82
01232  S899-ABEND.                                                      DTSCS82
01233      EXEC CICS ABEND                                              DTSCS82
01234          ABCODE(WRK-ABEND-CD)                                     DTSCS82
01235      END-EXEC.                                                    DTSCS82
01236  S899-EXIT.                                                       DTSCS82
01237      EXIT.                                                        DTSCS82
01238 /*****************************************************************DTSCS82
01239 *    EDIT THE INFORMATION ON THE SCREEN.                         *DTSCS82
01240 ******************************************************************DTSCS82
01241      SKIP1                                                        DTSCS82
01242  S1001-SCREEN-KEY-EDITS.                                          DTSCS82
01243      SKIP1                                                        DTSCS82
01244      PERFORM S1100-YR-Q                      THRU S1100-EXIT.     DTSCS82
01245      SKIP1                                                        DTSCS82
01246  S1001-EXIT.                                                      DTSCS82
01247      EXIT.                                                        DTSCS82
01248      SKIP3                                                        DTSCS82
01249  S1002-SCREEN-DATA-EDITS.                                         DTSCS82
01250      SKIP1                                                        DTSCS82
01251      MOVE +0 TO WRK-UC30-MASS-MAIL-DATE                           DTSCS82
01252                 WRK-UC30-FIRST-DEL-DATE                           DTSCS82
01253                 WRK-DELQ-LTR-SENT-DATE                            DTSCS82
01254                 WRK-UC30-ESTIMATED-DATE                           DTSCS82
01255                 WRK-UC30-FINAL-DEL-DATE                           DTSCS82
01256                 WRK-SELF-INS-CHG-RUN-DATE.                        DTSCS82
01257                                                                   DTSCS82
01258      MOVE FQTR-YRQ TO L004-QTR-5-9.                               DTSCS82
01259      SET L004-FROM-5 TO TRUE.                                     DTSCS82
01260      PERFORM S004-YRQ-CONVERT THRU S004-EXIT.                     DTSCS82
01261      MOVE L004-QTR-START-DATE TO WRK-YRQ-START-DATE.              DTSCS82
01262      MOVE L004-QTR-END-DATE   TO WRK-YRQ-END-DATE.                DTSCS82
01263      SKIP1                                                        DTSCS82
01264      ADD +1 TO L004-ABS-QTR.                                      DTSCS82
01265      SET L004-FROM-ABS TO TRUE.                                   DTSCS82
01266      PERFORM S004-YRQ-CONVERT THRU S004-EXIT.                     DTSCS82
01267      MOVE L004-QTR-START-DATE TO WRK-YRQ-PLUS1-START-DATE.        DTSCS82
01268      MOVE L004-QTR-END-DATE   TO WRK-YRQ-PLUS1-END-DATE.          DTSCS82
01269      SKIP1                                                        DTSCS82
01270 ******************************************************************DTSCS82
01271 *    DEFAULT LATE PENALTY DATE IS THE FIRST DAY OF THE SECOND    *DTSCS82
01272 *    MONTH OF THE QUARTER FOLLOWING THE QUARTER FOR WHICH THE    *DTSCS82
01273 *    REPORT WAS DUE.                                              DTSCS82
01274 ******************************************************************DTSCS82
01275      MOVE WRK-YRQ-PLUS1-START-DATE TO L001-FED-8-DATE-9.          DTSCS82
01276      ADD 1 TO L001-FED-8-MO.                                      DTSCS82
01277      MOVE 01 TO L001-FED-8-DA.                                    DTSCS82
01278      SET L001-FROM-FED-8 TO TRUE                                  DTSCS82
01279      PERFORM S001-DATE THRU S001-EXIT                             DTSCS82
01280      IF L001-VALID-DATE                                           DTSCS82
01281          MOVE L001-FED-8-DATE-9 TO WRK-DEFAULT-LATE-PEN-DATE      DTSCS82
01282      ELSE                                                         DTSCS82
01283          MOVE ZERO TO WRK-DEFAULT-LATE-PEN-DATE.                  DTSCS82
01284      SKIP1                                                        DTSCS82
01285      PERFORM S1200-UC30-MASS-MAIL-DATE       THRU S1200-EXIT.     DTSCS82
01286      PERFORM S1300-UC30-FIRST-DEL-DATE       THRU S1300-EXIT.     DTSCS82
01287      PERFORM S1400-UC30-FINAL-DEL-DATE       THRU S1400-EXIT.     DTSCS82
01288      PERFORM S1500-SELF-INS-TAX-DUE-DATE     THRU S1500-EXIT.     DTSCS82
01289      PERFORM S1600-LATE-PEN-ASSESSED-DATE    THRU S1600-EXIT.     DTSCS82
01290      PERFORM S1650-SELF-INS-LATE-PEN-DATE    THRU S1650-EXIT.     DTSCS82
01291      PERFORM S1675-UC30-ESTIMATED-DATE       THRU S1675-EXIT.     DTSCS82
01292      PERFORM S1700-UC30-FINAL-ACTION-DATE    THRU S1700-EXIT.     DTSCS82
01293      PERFORM S1800-SELF-INS-CHG-RUN-DATE     THRU S1800-EXIT.     DTSCS82
01294      PERFORM S1900-SELF-INS-2ND-LTR-DATE     THRU S1900-EXIT.     DTSCS82
01295      SKIP1                                                        DTSCS82
01296  S1002-EXIT.                                                      DTSCS82
01297      EXIT.                                                        DTSCS82
01298      EJECT                                                        DTSCS82
01299  S1100-YR-Q.                                                      DTSCS82
01300      MOVE MAP-YRQ-AREA TO L016-S-YRQ-AREA.                        DTSCS82
01301      PERFORM S016-CHECK-MAP-YR-Q THRU S016-EXIT.                  DTSCS82
01302      IF L016-NO-ENTRY                                             DTSCS82
01303          MOVE EMSG-FIELD-REQUIRED TO WRK-MSG-ID                   DTSCS82
01304          PERFORM S1101-ERROR THRU S1101-EXIT                      DTSCS82
01305      ELSE                                                         DTSCS82
01306          IF (L016-NOT-VALID)                                      DTSCS82
01307                 OR                                                DTSCS82
01308             (L016-YRQ <= LCCM-PICKUP-YRQ)                         DTSCS82
01309              MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID              DTSCS82
01310              PERFORM S1101-ERROR THRU S1101-EXIT.                 DTSCS82
01311  S1100-EXIT.                                                      DTSCS82
01312      EXIT.                                                        DTSCS82
01313      SKIP3                                                        DTSCS82
01314  S1101-ERROR.                                                     DTSCS82
01315      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-YR-A                  DTSCS82
01316                                       MAP-Q-A.                    DTSCS82
01317      IF LCCM-NO-MSG                                               DTSCS82
01318         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01319         MOVE CATB-CURSOR TO MAP-YR-L                              DTSCS82
01320         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01321  S1101-EXIT.                                                      DTSCS82
01322      EXIT.                                                        DTSCS82
01323      EJECT                                                        DTSCS82
01324  S1200-UC30-MASS-MAIL-DATE.                                       DTSCS82
01325      MOVE MAP-UC30-MASS-MAIL-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01326      PERFORM S015-DATE-AREA THRU S015-EXIT.                       DTSCS82
01327      IF L015-NO-ENTRY                                             DTSCS82
01328          MOVE WRK-NO-ENTRY TO WRK-UC30-MASS-MAIL-DATE             DTSCS82
01329          GO TO S1200-EXIT.                                        DTSCS82
01330      IF L015-NOT-VALID                                            DTSCS82
01331          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01332          PERFORM S1201-ERROR THRU S1201-EXIT                      DTSCS82
01333          GO TO S1200-EXIT.                                        DTSCS82
01334      SKIP1                                                        DTSCS82
01335      IF L015-DATE < WRK-YRQ-START-DATE                            DTSCS82
01336      OR L015-DATE > WRK-YRQ-PLUS1-END-DATE                        DTSCS82
01337          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01338          PERFORM S1201-ERROR THRU S1201-EXIT                      DTSCS82
01339      ELSE                                                         DTSCS82
01340          MOVE L015-DATE TO WRK-UC30-MASS-MAIL-DATE.               DTSCS82
01341  S1200-EXIT.                                                      DTSCS82
01342      EXIT.                                                        DTSCS82
01343      SKIP3                                                        DTSCS82
01344  S1201-ERROR.                                                     DTSCS82
01345      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-UC30-MASS-MAIL-MM-A   DTSCS82
01346                                       MAP-UC30-MASS-MAIL-DD-A     DTSCS82
01347                                       MAP-UC30-MASS-MAIL-YY-A.    DTSCS82
01348      IF LCCM-NO-MSG                                               DTSCS82
01349         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01350         MOVE CATB-CURSOR TO MAP-UC30-MASS-MAIL-MM-L               DTSCS82
01351         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01352  S1201-EXIT.                                                      DTSCS82
01353      EXIT.                                                        DTSCS82
01354 /*****************************************************************DTSCS82
01355 *    WORK FIELDS MUST BE SET BY S1200 BEFORE PERFORMING S1300    *DTSCS82
01356 ******************************************************************DTSCS82
01357  S1300-UC30-FIRST-DEL-DATE.                                       DTSCS82
01358      MOVE MAP-UC30-FIRST-DEL-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01359      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01360      IF L015-NO-ENTRY                                             DTSCS82
01361          MOVE WRK-NO-ENTRY TO WRK-UC30-FIRST-DEL-DATE             DTSCS82
01362      ELSE                                                         DTSCS82
01363      IF L015-NOT-VALID                                            DTSCS82
01364          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01365          PERFORM S1301-ERROR THRU S1301-EXIT                      DTSCS82
01366      ELSE                                                         DTSCS82
01367      IF L015-DATE < WRK-YRQ-PLUS1-START-DATE                      DTSCS82
01368          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01369          PERFORM S1301-ERROR THRU S1301-EXIT                      DTSCS82
01370      ELSE                                                         DTSCS82
01371      IF L015-DATE > WRK-UC30-MASS-MAIL-DATE                       DTSCS82
01372          MOVE L015-DATE TO WRK-UC30-FIRST-DEL-DATE                DTSCS82
01373      ELSE                                                         DTSCS82
01374      IF WRK-UC30-MASS-MAIL-DATE = WRK-NO-ENTRY                    DTSCS82
01375          MOVE EMSG-FIELD-NOT-ALLOWED TO WRK-MSG-ID                DTSCS82
01376          PERFORM S1301-ERROR THRU S1301-EXIT                      DTSCS82
01377      ELSE                                                         DTSCS82
01378          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01379          PERFORM S1301-ERROR THRU S1301-EXIT.                     DTSCS82
01380  S1300-EXIT.                                                      DTSCS82
01381      EXIT.                                                        DTSCS82
01382      SKIP3                                                        DTSCS82
01383  S1301-ERROR.                                                     DTSCS82
01384      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-UC30-FIRST-DEL-MM-A   DTSCS82
01385                                       MAP-UC30-FIRST-DEL-DD-A     DTSCS82
01386                                       MAP-UC30-FIRST-DEL-YY-A.    DTSCS82
01387      IF LCCM-NO-MSG                                               DTSCS82
01388         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01389         MOVE CATB-CURSOR TO MAP-UC30-FIRST-DEL-MM-L               DTSCS82
01390         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01391  S1301-EXIT.                                                      DTSCS82
01392      EXIT.                                                        DTSCS82
01393 /*****************************************************************DTSCS82
01394 *    WORK FIELDS MUST BE SET BY S1300 BEFORE PERFORMING S1400    *DTSCS82
01395 ******************************************************************DTSCS82
01396  S1400-UC30-FINAL-DEL-DATE.                                       DTSCS82
01397      MOVE MAP-UC30-FINAL-DEL-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01398      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01399      IF L015-NO-ENTRY                                             DTSCS82
01400          MOVE WRK-NO-ENTRY TO WRK-UC30-FINAL-DEL-DATE             DTSCS82
01401      ELSE                                                         DTSCS82
01402      IF L015-NOT-VALID                                            DTSCS82
01403          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01404          PERFORM S1401-ERROR THRU S1401-EXIT                      DTSCS82
01405      ELSE                                                         DTSCS82
01406      IF L015-DATE > WRK-UC30-FIRST-DEL-DATE                       DTSCS82
01407          MOVE L015-DATE TO WRK-UC30-FINAL-DEL-DATE                DTSCS82
01408      ELSE                                                         DTSCS82
01409      IF WRK-UC30-FIRST-DEL-DATE = WRK-NO-ENTRY                    DTSCS82
01410          MOVE EMSG-FIELD-NOT-ALLOWED TO WRK-MSG-ID                DTSCS82
01411          PERFORM S1401-ERROR THRU S1401-EXIT                      DTSCS82
01412      ELSE                                                         DTSCS82
01413          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01414          PERFORM S1401-ERROR THRU S1401-EXIT.                     DTSCS82
01415  S1400-EXIT.                                                      DTSCS82
01416      EXIT.                                                        DTSCS82
01417      SKIP3                                                        DTSCS82
01418  S1401-ERROR.                                                     DTSCS82
01419      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-UC30-FINAL-DEL-MM-A   DTSCS82
01420                                       MAP-UC30-FINAL-DEL-DD-A     DTSCS82
01421                                       MAP-UC30-FINAL-DEL-YY-A.    DTSCS82
01422      IF LCCM-NO-MSG                                               DTSCS82
01423         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01424         MOVE CATB-CURSOR TO MAP-UC30-FINAL-DEL-MM-L               DTSCS82
01425         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01426  S1401-EXIT.                                                      DTSCS82
01427      EXIT.                                                        DTSCS82
01428 /*****************************************************************DTSCS82
01429 *    WORK FIELDS MUST BE SET BY S1200 BEFORE PERFORMING S1500    *DTSCS82
01430 ******************************************************************DTSCS82
01431  S1500-SELF-INS-TAX-DUE-DATE.                                     DTSCS82
01432      MOVE MAP-SELF-INS-TAX-DUE-DATE-AREA TO L015-S-DATE-AREA.     DTSCS82
01433      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01434      IF L015-NO-ENTRY                                             DTSCS82
01435          NEXT SENTENCE                                            DTSCS82
01436      ELSE                                                         DTSCS82
01437      IF L015-NOT-VALID                                            DTSCS82
01438          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01439          PERFORM S1501-ERROR THRU S1501-EXIT                      DTSCS82
01440      ELSE                                                         DTSCS82
01441      IF WRK-UC30-MASS-MAIL-DATE = WRK-NO-ENTRY                    DTSCS82
01442          MOVE EMSG-FIELD-NOT-ALLOWED TO WRK-MSG-ID                DTSCS82
01443          PERFORM S1501-ERROR THRU S1501-EXIT                      DTSCS82
01444      ELSE                                                         DTSCS82
01445      IF L015-DATE < WRK-UC30-MASS-MAIL-DATE                       DTSCS82
01446          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01447          PERFORM S1501-ERROR THRU S1501-EXIT                      DTSCS82
01448      ELSE                                                         DTSCS82
01449      IF L015-DATE > WRK-YRQ-PLUS1-END-DATE                        DTSCS82
01450          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01451          PERFORM S1501-ERROR THRU S1501-EXIT.                     DTSCS82
01452                                                                   DTSCS82
01453      IF FQTR-SELF-INS-CHG-RUN-DATE NOT NUMERIC                    DTSCS82
01454         MOVE ZERO TO FQTR-SELF-INS-CHG-RUN-DATE                   DTSCS82
01455         GO TO S1500-EXIT.                                         DTSCS82
01456                                                                   DTSCS82
01457      IF FQTR-SELF-INS-CHG-RUN-DATE = ZERO                         DTSCS82
01458         GO TO S1500-EXIT.                                         DTSCS82
01459                                                                   DTSCS82
01460      MOVE FQTR-SELF-INS-CHG-RUN-DATE TO L001-FED-8-DATE-9.        DTSCS82
01461      SET L001-FROM-FED-8 TO TRUE.                                 DTSCS82
01462      PERFORM S001-DATE        THRU S001-EXIT.                     DTSCS82
01463      ADD +7 TO L001-JUL-ABS-DAY.                                  DTSCS82
01464      SET L001-FROM-ABS-DAY TO TRUE.                               DTSCS82
01465      PERFORM S001-DATE        THRU S001-EXIT.                     DTSCS82
01466                                                                   DTSCS82
01467      IF L015-DATE < L001-FED-8-DATE-9                             DTSCS82
01468          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01469          PERFORM S1501-ERROR THRU S1501-EXIT.                     DTSCS82
01470                                                                   DTSCS82
01471  S1500-EXIT.                                                      DTSCS82
01472      EXIT.                                                        DTSCS82
01473      SKIP3                                                        DTSCS82
01474  S1501-ERROR.                                                     DTSCS82
01475      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-SELF-INS-TAX-DUE-MM-A DTSCS82
01476                                       MAP-SELF-INS-TAX-DUE-DD-A   DTSCS82
01477                                       MAP-SELF-INS-TAX-DUE-YY-A.  DTSCS82
01478      IF LCCM-NO-MSG                                               DTSCS82
01479         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01480         MOVE CATB-CURSOR TO MAP-SELF-INS-TAX-DUE-MM-L             DTSCS82
01481         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01482  S1501-EXIT.                                                      DTSCS82
01483      EXIT.                                                        DTSCS82
01484 /*****************************************************************DTSCS82
01485 *    WORK FIELDS MUST BE SET BY S1100 BEFORE PERFORMING S1600    *DTSCS82
01486 ******************************************************************DTSCS82
01487  S1600-LATE-PEN-ASSESSED-DATE.                                    DTSCS82
01488      MOVE MAP-LATE-PEN-ASSESS-DATE-AREA TO L015-S-DATE-AREA.      DTSCS82
01489      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01490      IF L015-NO-ENTRY                                             DTSCS82
01491          NEXT SENTENCE                                            DTSCS82
01492      ELSE                                                         DTSCS82
01493      IF L015-NOT-VALID                                            DTSCS82
01494          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01495          PERFORM S1601-ERROR THRU S1601-EXIT                      DTSCS82
01496      ELSE                                                         DTSCS82
01497      IF WRK-DEFAULT-LATE-PEN-DATE NOT = ZERO                      DTSCS82
01498          IF L015-DATE < WRK-DEFAULT-LATE-PEN-DATE                 DTSCS82
01499              MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID              DTSCS82
01500              PERFORM S1601-ERROR THRU S1601-EXIT.                 DTSCS82
01501  S1600-EXIT.                                                      DTSCS82
01502      EXIT.                                                        DTSCS82
01503      SKIP3                                                        DTSCS82
01504  S1601-ERROR.                                                     DTSCS82
01505      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-LATE-PEN-ASSESSED-MM-ADTSCS82
01506                                       MAP-LATE-PEN-ASSESSED-DD-A  DTSCS82
01507                                       MAP-LATE-PEN-ASSESSED-YY-A. DTSCS82
01508      IF LCCM-NO-MSG                                               DTSCS82
01509         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01510         MOVE CATB-CURSOR TO MAP-LATE-PEN-ASSESSED-MM-L            DTSCS82
01511         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01512  S1601-EXIT.                                                      DTSCS82
01513      EXIT.                                                        DTSCS82
01514 ******************************************************************DTSCS82
01515  S1650-SELF-INS-LATE-PEN-DATE.                                    DTSCS82
01516      MOVE MAP-DELQ-LTR-SENT-DATE-AREA TO L015-S-DATE-AREA.        DTSCS82
01517      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01518      IF L015-NO-ENTRY                                             DTSCS82
01519         MOVE WRK-NO-ENTRY TO WRK-DELQ-LTR-SENT-DATE               DTSCS82
01520      ELSE                                                         DTSCS82
01521      IF L015-NOT-VALID                                            DTSCS82
01522          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01523          PERFORM S1651-ERROR THRU S1651-EXIT.                     DTSCS82
01524 *    ELSE                                                         DTSCS82
01525 *    IF L015-DATE > WRK-UC30-FINAL-DEL-DATE                       DTSCS82
01526 *       MOVE L015-DATE TO WRK-INTENT-2-ESTIM-DATE                 DTSCS82
01527 *    ELSE                                                         DTSCS82
01528 *    IF WRK-UC30-FINAL-DEL-DATE = WRK-NO-ENTRY                    DTSCS82
01529 *        MOVE EMSG-FIELD-NOT-ALLOWED TO WRK-MSG-ID                DTSCS82
01530 *        PERFORM S1651-ERROR THRU S1651-EXIT                      DTSCS82
01531 *    ELSE                                                         DTSCS82
01532 *        MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01533 *        PERFORM S1651-ERROR THRU S1651-EXIT.                     DTSCS82
01534  S1650-EXIT.                                                      DTSCS82
01535      EXIT.                                                        DTSCS82
01536      SKIP3                                                        DTSCS82
01537  S1651-ERROR.                                                     DTSCS82
01538      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-DELQ-LTR-SENT-MM-A    DTSCS82
01539                                       MAP-DELQ-LTR-SENT-DD-A      DTSCS82
01540                                       MAP-DELQ-LTR-SENT-YY-A.     DTSCS82
01541      IF LCCM-NO-MSG                                               DTSCS82
01542         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01543         MOVE CATB-CURSOR TO MAP-DELQ-LTR-SENT-MM-L                DTSCS82
01544         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01545  S1651-EXIT.                                                      DTSCS82
01546      EXIT.                                                        DTSCS82
01547                                                                   DTSCS82
01548 ******************************************************************DTSCS82
01549  S1675-UC30-ESTIMATED-DATE.                                       DTSCS82
01550      MOVE MAP-UC30-ESTIMATED-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01551      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01552      IF L015-NO-ENTRY                                             DTSCS82
01553         MOVE WRK-NO-ENTRY TO WRK-UC30-ESTIMATED-DATE              DTSCS82
01554      ELSE                                                         DTSCS82
01555      IF L015-NOT-VALID                                            DTSCS82
01556          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01557          PERFORM S1676-ERROR THRU S1676-EXIT.                     DTSCS82
01558 *    ELSE                                                         DTSCS82
01559 *    IF L015-DATE > WRK-INTENT-2-ESTIM-DATE                       DTSCS82
01560 *       MOVE L015-DATE TO WRK-UC30-ESTIMATED-DATE                 DTSCS82
01561 *    ELSE                                                         DTSCS82
01562 *    IF WRK-INTENT-2-ESTIM-DATE = WRK-NO-ENTRY                    DTSCS82
01563 *        MOVE EMSG-FIELD-NOT-ALLOWED TO WRK-MSG-ID                DTSCS82
01564 *        PERFORM S1676-ERROR THRU S1676-EXIT                      DTSCS82
01565 *    ELSE                                                         DTSCS82
01566 *        MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01567 *        PERFORM S1676-ERROR THRU S1676-EXIT.                     DTSCS82
01568  S1675-EXIT.                                                      DTSCS82
01569      EXIT.                                                        DTSCS82
01570      SKIP3                                                        DTSCS82
01571  S1676-ERROR.                                                     DTSCS82
01572      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-UC30-ESTIMATED-MM-A   DTSCS82
01573                                       MAP-UC30-ESTIMATED-DD-A     DTSCS82
01574                                       MAP-UC30-ESTIMATED-YY-A.    DTSCS82
01575      IF LCCM-NO-MSG                                               DTSCS82
01576         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01577         MOVE CATB-CURSOR TO MAP-UC30-ESTIMATED-MM-L               DTSCS82
01578         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01579  S1676-EXIT.                                                      DTSCS82
01580      EXIT.                                                        DTSCS82
01581                                                                   DTSCS82
01582 /*****************************************************************DTSCS82
01583 *    WORK FIELDS MUST BE SET BY S1400 BEFORE PERFORMING S1500    *DTSCS82
01584 ******************************************************************DTSCS82
01585  S1700-UC30-FINAL-ACTION-DATE.                                    DTSCS82
01586      MOVE MAP-UC30-FINAL-ACT-DATE-AREA TO L015-S-DATE-AREA.       DTSCS82
01587      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01588      IF L015-NO-ENTRY                                             DTSCS82
01589          NEXT SENTENCE                                            DTSCS82
01590      ELSE                                                         DTSCS82
01591      IF L015-NOT-VALID                                            DTSCS82
01592          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01593          PERFORM S1701-ERROR THRU S1701-EXIT                      DTSCS82
01594      ELSE                                                         DTSCS82
01595      IF L015-DATE > WRK-UC30-FINAL-DEL-DATE                       DTSCS82
01596          NEXT SENTENCE                                            DTSCS82
01597      ELSE                                                         DTSCS82
01598      IF WRK-UC30-FINAL-DEL-DATE = WRK-NO-ENTRY                    DTSCS82
01599          MOVE EMSG-FIELD-NOT-ALLOWED TO WRK-MSG-ID                DTSCS82
01600          PERFORM S1701-ERROR THRU S1701-EXIT                      DTSCS82
01601      ELSE                                                         DTSCS82
01602          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01603          PERFORM S1701-ERROR THRU S1701-EXIT.                     DTSCS82
01604  S1700-EXIT.                                                      DTSCS82
01605      EXIT.                                                        DTSCS82
01606      SKIP3                                                        DTSCS82
01607  S1701-ERROR.                                                     DTSCS82
01608      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-UC30-FINAL-ACTION-MM-ADTSCS82
01609                                       MAP-UC30-FINAL-ACTION-DD-A  DTSCS82
01610                                       MAP-UC30-FINAL-ACTION-YY-A. DTSCS82
01611      IF LCCM-NO-MSG                                               DTSCS82
01612         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01613         MOVE CATB-CURSOR TO MAP-UC30-FINAL-ACTION-MM-L            DTSCS82
01614         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01615  S1701-EXIT.                                                      DTSCS82
01616      EXIT.                                                        DTSCS82
01617                                                                   DTSCS82
01618  S1800-SELF-INS-CHG-RUN-DATE.                                     DTSCS82
01619      MOVE MAP-SELF-INS-CHG-RUN-DATE-AREA TO L015-S-DATE-AREA.     DTSCS82
01620      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01621      IF L015-NO-ENTRY                                             DTSCS82
01622          MOVE WRK-NO-ENTRY    TO WRK-SELF-INS-CHG-RUN-DATE        DTSCS82
01623          GO TO S1800-EXIT                                         DTSCS82
01624      ELSE                                                         DTSCS82
01625      IF L015-DATE = ZERO                                          DTSCS82
01626          NEXT SENTENCE                                            DTSCS82
01627      ELSE                                                         DTSCS82
01628      IF L015-NOT-VALID                                            DTSCS82
01629          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01630          PERFORM S1801-ERROR THRU S1801-EXIT                      DTSCS82
01631      ELSE                                                         DTSCS82
01632      IF L015-DATE < WRK-YRQ-END-DATE                              DTSCS82
01633          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01634          PERFORM S1801-ERROR THRU S1801-EXIT                      DTSCS82
01635      ELSE                                                         DTSCS82
01636          MOVE L015-DATE TO WRK-SELF-INS-CHG-RUN-DATE.             DTSCS82
01637                                                                   DTSCS82
01638                                                                   DTSCS82
01639  S1800-EXIT.                                                      DTSCS82
01640      EXIT.                                                        DTSCS82
01641      SKIP3                                                        DTSCS82
01642  S1801-ERROR.                                                     DTSCS82
01643      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-SELF-INS-CHG-RUN-MM-A DTSCS82
01644                                       MAP-SELF-INS-CHG-RUN-DD-A   DTSCS82
01645                                       MAP-SELF-INS-CHG-RUN-YY-A.  DTSCS82
01646      IF LCCM-NO-MSG                                               DTSCS82
01647         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01648         MOVE CATB-CURSOR TO MAP-SELF-INS-CHG-RUN-MM-L             DTSCS82
01649         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01650  S1801-EXIT.                                                      DTSCS82
01651      EXIT.                                                        DTSCS82
01652 ******************************************************************DTSCS82
01653  S1900-SELF-INS-2ND-LTR-DATE.                                     DTSCS82
01654      MOVE MAP-SELF-INS-2ND-LTR-DATE-AREA TO L015-S-DATE-AREA.     DTSCS82
01655      PERFORM S015-DATE-AREA   THRU S015-EXIT.                     DTSCS82
01656      IF L015-NO-ENTRY                                             DTSCS82
01657         GO TO S1900-EXIT                                          DTSCS82
01658      ELSE                                                         DTSCS82
01659      IF L015-NOT-VALID                                            DTSCS82
01660          MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID                  DTSCS82
01661          PERFORM S1901-ERROR THRU S1901-EXIT                      DTSCS82
01662      ELSE                                                         DTSCS82
01663      IF WRK-SELF-INS-CHG-RUN-DATE = WRK-NO-ENTRY                  DTSCS82
01664          MOVE EMSG-FIELD-NOT-ALLOWED TO WRK-MSG-ID                DTSCS82
01665          PERFORM S1901-ERROR THRU S1901-EXIT                      DTSCS82
01666          GO TO S1900-EXIT.                                        DTSCS82
01667                                                                   DTSCS82
01668       IF FQTR-SELF-INS-TAX-DUE-DATE > +0                          DTSCS82
01669          IF L015-DATE < FQTR-SELF-INS-TAX-DUE-DATE                DTSCS82
01670             MOVE EMSG-FIELD-NOT-VALID TO WRK-MSG-ID               DTSCS82
01671             PERFORM S1901-ERROR THRU S1901-EXIT                   DTSCS82
01672          END-IF                                                   DTSCS82
01673       ELSE                                                        DTSCS82
01674          GO TO S1900-EXIT                                         DTSCS82
01675       END-IF.                                                     DTSCS82
01676                                                                   DTSCS82
01677  S1900-EXIT.                                                      DTSCS82
01678      EXIT.                                                        DTSCS82
01679      SKIP3                                                        DTSCS82
01680  S1901-ERROR.                                                     DTSCS82
01681      MOVE CATB-UNPROT-NORM-NUM-MDTON TO MAP-SELF-INS-2ND-LTR-MM-A DTSCS82
01682                                       MAP-SELF-INS-2ND-LTR-DD-A   DTSCS82
01683                                       MAP-SELF-INS-2ND-LTR-YY-A.  DTSCS82
01684      IF LCCM-NO-MSG                                               DTSCS82
01685         MOVE WRK-MSG-ID TO LCCM-MSG-ID                            DTSCS82
01686         MOVE CATB-CURSOR TO MAP-SELF-INS-2ND-LTR-MM-L             DTSCS82
01687         SET CURSOR-SET-YES TO TRUE.                               DTSCS82
01688  S1901-EXIT.                                                      DTSCS82
01689      EXIT.                                                        DTSCS82
01690                                                                   DTSCS82
01691 ******************************************************************DTSCS82
01692 /*****************************************************************DTSCS82
01693 * LOCK SCREEN FOR UPDATE CONFIRMATION                            *DTSCS82
01694 ******************************************************************DTSCS82
01695  S5100-SET-LOCK-ATTRB.                                            DTSCS82
01696      MOVE CATB-ASKIP-BRT-MDTON TO WRK-ATB-AN                      DTSCS82
01697                                 WRK-ATB-NUM.                      DTSCS82
01698      SKIP1                                                        DTSCS82
01699      PERFORM S5900-SET-ATTRB THRU S5900-EXIT.                     DTSCS82
01700      SKIP1                                                        DTSCS82
01701      MOVE CATB-ASKIP-BRT-MDTON TO MAP-YR-A                        DTSCS82
01702                                 MAP-Q-A                           DTSCS82
01703                                 MAP-GOTO-A.                       DTSCS82
01704  S5100-EXIT.                                                      DTSCS82
01705      EXIT.                                                        DTSCS82
01706      SKIP3                                                        DTSCS82
01707 ******************************************************************DTSCS82
01708 * SET ATTIBUTE BYTES FOR UPDATE ACCESS                           *DTSCS82
01709 ******************************************************************DTSCS82
01710  S5200-SET-UPDATE-ATTRB.                                          DTSCS82
01711      MOVE CATB-UNPROT-BRT-AN-MDTON TO WRK-ATB-AN.                 DTSCS82
01712      MOVE CATB-UNPROT-BRT-NUM-MDTON   TO WRK-ATB-NUM.             DTSCS82
01713      SKIP1                                                        DTSCS82
01714      PERFORM S5900-SET-ATTRB THRU S5900-EXIT.                     DTSCS82
01715  S5200-EXIT.                                                      DTSCS82
01716      EXIT.                                                        DTSCS82
01717      SKIP3                                                        DTSCS82
01718 ******************************************************************DTSCS82
01719 *  SET ATTRIBUTE BYTES FOR INQUIRY STATUS                        *DTSCS82
01720 ******************************************************************DTSCS82
01721  S5300-SET-INQ-ATTRB.                                             DTSCS82
01722      MOVE CATB-ASKIP-BRT-MDTOFF TO WRK-ATB-AN                     DTSCS82
01723                                   WRK-ATB-NUM.                    DTSCS82
01724      SKIP1                                                        DTSCS82
01725      PERFORM S5900-SET-ATTRB THRU S5900-EXIT.                     DTSCS82
01726  S5300-EXIT.                                                      DTSCS82
01727      EXIT.                                                        DTSCS82
01728      SKIP3                                                        DTSCS82
01729 ******************************************************************DTSCS82
01730 *  DO IT                                                         *DTSCS82
01731 ******************************************************************DTSCS82
01732  S5900-SET-ATTRB.                                                 DTSCS82
01733      MOVE CATB-UNPROT-BRT-NUM-MDTON TO MAP-YR-A                   DTSCS82
01734                                      MAP-Q-A.                     DTSCS82
01735      SKIP1                                                        DTSCS82
01736      MOVE WRK-ATB-NUM TO MAP-UC30-MASS-MAIL-MM-A                  DTSCS82
01737                          MAP-UC30-MASS-MAIL-DD-A                  DTSCS82
01738                          MAP-UC30-MASS-MAIL-YY-A                  DTSCS82
01739                          MAP-UC30-FIRST-DEL-MM-A                  DTSCS82
01740                          MAP-UC30-FIRST-DEL-DD-A                  DTSCS82
01741                          MAP-UC30-FIRST-DEL-YY-A                  DTSCS82
01742                          MAP-UC30-FINAL-DEL-MM-A                  DTSCS82
01743                          MAP-UC30-FINAL-DEL-DD-A                  DTSCS82
01744                          MAP-UC30-FINAL-DEL-YY-A                  DTSCS82
01745                          MAP-SELF-INS-2ND-LTR-MM-A                DTSCS82
01746                          MAP-SELF-INS-2ND-LTR-DD-A                DTSCS82
01747                          MAP-SELF-INS-2ND-LTR-YY-A                DTSCS82
01748                          MAP-SELF-INS-TAX-DUE-MM-A                DTSCS82
01749                          MAP-SELF-INS-TAX-DUE-DD-A                DTSCS82
01750                          MAP-SELF-INS-TAX-DUE-YY-A                DTSCS82
01751                          MAP-SELF-INS-CHG-RUN-MM-A                DTSCS82
01752                          MAP-SELF-INS-CHG-RUN-DD-A                DTSCS82
01753                          MAP-SELF-INS-CHG-RUN-YY-A                DTSCS82
01754                          MAP-LATE-PEN-ASSESSED-MM-A               DTSCS82
01755                          MAP-LATE-PEN-ASSESSED-DD-A               DTSCS82
01756                          MAP-LATE-PEN-ASSESSED-YY-A               DTSCS82
01757                          MAP-DELQ-LTR-SENT-MM-A                   DTSCS82
01758                          MAP-DELQ-LTR-SENT-DD-A                   DTSCS82
01759                          MAP-DELQ-LTR-SENT-YY-A                   DTSCS82
01760                          MAP-UC30-ESTIMATED-MM-A                  DTSCS82
01761                          MAP-UC30-ESTIMATED-DD-A                  DTSCS82
01762                          MAP-UC30-ESTIMATED-YY-A                  DTSCS82
01763                          MAP-UC30-FINAL-ACTION-MM-A               DTSCS82
01764                          MAP-UC30-FINAL-ACTION-DD-A               DTSCS82
01765                          MAP-UC30-FINAL-ACTION-YY-A.              DTSCS82
01766      SKIP1                                                        DTSCS82
01767      MOVE CATB-ASKIP-BRT-MDTON TO MAP-ESTB-DATE-A                 DTSCS82
01768                                   MAP-CHNG-DATE-A.                DTSCS82
01769      SKIP1                                                        DTSCS82
01770      MOVE CATB-UNPROT-BRT-AN-MDTON TO MAP-GOTO-A.                 DTSCS82
01771  S5900-EXIT.                                                      DTSCS82
01772      EXIT.                                                        DTSCS82
01773 /*****************************************************************DTSCS82
01774 * READ PREPARATION ROUTINES                                      *DTSCS82
01775 ******************************************************************DTSCS82
01776  S8010-READ-FQTR.                                                 DTSCS82
01777      MOVE MAP-YRQ-AREA TO L016-S-YRQ-AREA.                        DTSCS82
01778      PERFORM S016-CHECK-MAP-YR-Q THRU S016-EXIT.                  DTSCS82
01779      IF L016-VALID                                                DTSCS82
01780          MOVE LOW-VALUES TO FQTR-KEY-AREA                         DTSCS82
01781          SET FQTR-QTR-88 TO TRUE                                  DTSCS82
01782          MOVE L016-YRQ TO FQTR-YRQ                                DTSCS82
01783          PERFORM S831-READ THRU S831-EXIT                         DTSCS82
01784      ELSE                                                         DTSCS82
01785          GO TO S899-ABEND.                                        DTSCS82
01786  S8010-EXIT.                                                      DTSCS82
01787      EXIT.                                                        DTSCS82
01788 /*****************************************************************DTSCS82
01789 * MAP ROUTINES                                                   *DTSCS82
01790 ******************************************************************DTSCS82
01791  S9100-RECEIVE.                                                   DTSCS82
01792      SET L851-RECEIVE-88 TO TRUE.                                 DTSCS82
01793      SKIP1                                                        DTSCS82
01794      MOVE WRK-SCR-ID TO L851-SCR-ID.                              DTSCS82
01795      SKIP1                                                        DTSCS82
01796      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS82
01797      SKIP1                                                        DTSCS82
01798      MOVE L851-AID TO LCCM-AID.                                   DTSCS82
01799      MOVE L851-CURSOR TO LCCM-CURSOR.                             DTSCS82
01800  S9100-EXIT.                                                      DTSCS82
01801      EXIT.                                                        DTSCS82
01802      SKIP3                                                        DTSCS82
01803  S9200-SEND-DATAONLY.                                             DTSCS82
01804      MOVE LOW-VALUES TO MAP-AREA.                                 DTSCS82
01805      SKIP1                                                        DTSCS82
01806      IF LCCM-NO-MSG                                               DTSCS82
01807          NEXT SENTENCE                                            DTSCS82
01808      ELSE                                                         DTSCS82
01809          PERFORM S805-MSG-AREA THRU S805-EXIT.                    DTSCS82
01810      SKIP1                                                        DTSCS82
01811      IF CURSOR-SET-GOTO                                           DTSCS82
01812          MOVE CATB-CURSOR TO MAP-GOTO-L                           DTSCS82
01813      ELSE                                                         DTSCS82
01814          MOVE CATB-CURSOR TO MAP-YR-L.                            DTSCS82
01815      SKIP1                                                        DTSCS82
01816      SET L851-SEND-DATAONLY-88 TO TRUE.                           DTSCS82
01817      SKIP1                                                        DTSCS82
01818      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT.                  DTSCS82
01819      SKIP1                                                        DTSCS82
01820      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS82
01821  S9200-EXIT.                                                      DTSCS82
01822      EXIT.                                                        DTSCS82
01823      SKIP3                                                        DTSCS82
01824  S9300-SEND-MAP.                                                  DTSCS82
01825      MOVE  LCCM-TASK-START-DISP-DATE TO MAP-SYS-DATE.             DTSCS82
01826      MOVE  LCCM-TASK-START-DISP-TIME TO MAP-SYS-TIME.             DTSCS82
01827      MOVE  LCCM-CICS-REGION-NAME TO MAP-CICS-REGION-NAME.         DTSCS82
01828      SKIP1                                                        DTSCS82
01829      IF SCR-ACCESS-UPDATE                                         DTSCS82
01830          PERFORM S9310-UPDATE-FKEYS THRU S9310-EXIT               DTSCS82
01831      ELSE                                                         DTSCS82
01832          PERFORM S9320-INQUIRY-FKEYS THRU S9320-EXIT.             DTSCS82
01833      SKIP1                                                        DTSCS82
01834      PERFORM S805-MSG-AREA THRU S805-EXIT.                        DTSCS82
01835      SKIP1                                                        DTSCS82
01836      IF CURSOR-SET-NO                                             DTSCS82
01837          MOVE CATB-CURSOR TO MAP-YR-L.                            DTSCS82
01838      SKIP1                                                        DTSCS82
01839      SET L851-SEND-88 TO TRUE.                                    DTSCS82
01840      SKIP1                                                        DTSCS82
01841      PERFORM S9900-PREPARE-SEND THRU S9900-EXIT.                  DTSCS82
01842      SKIP1                                                        DTSCS82
01843      PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT.               DTSCS82
01844  S9300-EXIT.                                                      DTSCS82
01845      EXIT.                                                        DTSCS82
01846      SKIP3                                                        DTSCS82
01847  S9310-UPDATE-FKEYS.                                              DTSCS82
01848      MOVE CFKD-BACKWARD TO MAP-KEY-BACK.                          DTSCS82
01849      MOVE CFKD-FORWARD TO MAP-KEY-FWRD.                           DTSCS82
01850      MOVE CFKD-ADD TO MAP-KEY-ADD.                                DTSCS82
01851      MOVE CFKD-MOD TO MAP-KEY-MOD.                                DTSCS82
01852      MOVE CFKD-DEL TO MAP-KEY-DEL.                                DTSCS82
01853      SKIP1                                                        DTSCS82
01854      IF LCCM-SCR-CLEAR                                            DTSCS82
01855          MOVE LOW-VALUES TO MAP-KEY-MOD                           DTSCS82
01856                             MAP-KEY-DEL                           DTSCS82
01857      ELSE                                                         DTSCS82
01858      IF LCCM-SCR-UPDATE-LOCKED                                    DTSCS82
01859          MOVE LOW-VALUES TO MAP-KEY-BACK                          DTSCS82
01860                             MAP-KEY-FWRD                          DTSCS82
01861                             MAP-KEY-ADD                           DTSCS82
01862                             MAP-KEY-MOD                           DTSCS82
01863                             MAP-KEY-DEL                           DTSCS82
01864      ELSE                                                         DTSCS82
01865          MOVE LOW-VALUES TO MAP-KEY-ADD.                          DTSCS82
01866  S9310-EXIT.                                                      DTSCS82
01867      EXIT.                                                        DTSCS82
01868      SKIP3                                                        DTSCS82
01869  S9320-INQUIRY-FKEYS.                                             DTSCS82
01870      MOVE CFKD-BACKWARD TO MAP-KEY-BACK.                          DTSCS82
01871      MOVE CFKD-FORWARD TO MAP-KEY-FWRD.                           DTSCS82
01872      MOVE LOW-VALUES TO MAP-KEY-ADD                               DTSCS82
01873                         MAP-KEY-MOD                               DTSCS82
01874                         MAP-KEY-DEL.                              DTSCS82
01875  S9320-EXIT.                                                      DTSCS82
01876      EXIT.                                                        DTSCS82
01877      SKIP3                                                        DTSCS82
01878  S9900-PREPARE-SEND.                                              DTSCS82
01879      MOVE WRK-SCR-ID TO L851-SCR-ID                               DTSCS82
01880                         LCCM-SCR-ID.                              DTSCS82
01881      MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND.                    DTSCS82
01882      MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE.                         DTSCS82
01883  S9900-EXIT.                                                      DTSCS82
01884      EXIT.                                                        DTSCS82
