00001  IDENTIFICATION DIVISION.                                         01/15/14
00002  PROGRAM-ID.             DTSBR102.                                DTSBR102
00003  AUTHOR.                 BDM.                                        LV051
00004  DATE-WRITTEN.           AUGUST 1998.                             DTSBR102
00005  DATE-COMPILED.                                                   DTSBR102
00006      SKIP3                                                        DTSBR102
00007 *****                                                             DTSBR102
00008 *    CALLING SEQUENCE:  DTSBD400 CALLS                            DTSBR102
00009 *                       DTSBD314 WHICH UPDATES DTSIR102           DTSBR102
00010 *                       DTSBR102 READS DTSIR102 RECORDS.          DTSBR102
00011 *                                                                 DTSBR102
00012 *    FUNCTION:  EMPLOYER REGISTRATION CYCLE A (LETTER 1)          DTSBR102
00013 *                                                                 DTSBR102
00014 *                                                                 DTSBR102
00015 *    MODIFICATION HISTORY:                                        DTSBR102
00016 *                                                                 DTSBR102
00017 * 08-06-94 INITIAL DEVELOPMENT                                    DTSBR102
00018 *          REFERENCE RFP #RAP             AUTHOR OF CHANGE - SFW  DTSBR102
00019 *                                                                 DTSBR102
00020 * 01-30-95 CHANGED PRINT LINES FOR ADDRESS AND THE PRINT LINE     DTSBR102
00021 *          AND COLUMN FOR THE DATE (L002-LONG-TEXT-AREA) FOR      DTSBR102
00022 *          BETTER PLACEMENT ON LETTERHEAD MAILED IN WINDOW        DTSBR102
00023 *          ENVELOPES.                                             DTSBR102
00024 *          REFERENCE RFP # RAP                   PROGRAMMER: MJA  DTSBR102
00025 *                                                                 DTSBR102
00026 * 03-03-95 CHANGED PAGE LIMIT FROM 62 LINES TO 60 LINES.          DTSBR102
00027 *          REFERENCE RFP # RAP                   PROGRAMMER: MJA  DTSBR102
00028 *                                                                 DTSBR102
00029 * 04-02-95 HAD TO MOVE PRINT LINES AGAIN TO WORK WITH AGENCY      DTSBR102
00030 *          BLUE LETTERHEAD.                                       DTSBR102
00031 *          REFERENCE RFP # TPR 15                PROGRAMMER: MJA  DTSBR102
00032 *                                                                 DTSBR102
00033 * 09-26-95 NEW WORDING ON LETTER TO ACCOMODATE COMBINED REGISTRA- DTSBR102
00034 *          TION WITH REVENUE AND NEW COMBINED BLUE LETTERHEAD.    DTSBR102
00035 *          CHANGED DATE TO MM/DD/YY AND LEFT JUSTIFIED.           DTSBR102
00036 *          REFERENCE RFP #NONE                   PROGRAMMER: SFW  DTSBR102
00037 *                                                                 DTSBR102
00038 * 11/26/97 INCREASE THE LENGTH OF WS-OPR-UNIT-NAME.  REQUIRED     DTSBR102
00039 *          TO REFLECT THE JULY 1, 1997 MOVE OF UI TAX FUNCTIONS   DTSBR102
00040 *          FROM DLI TO DOR.                                       DTSBR102
00041 *                                                                 DTSBR102
00042 * 12/13/97 MOVE AND REFORMAT DISPLAY OF R102-MAIL-DATE            DTSBR102
00043 *          AS REQUIRED FOR COMPUTER GENERATED DOR LETTERHEAD.     DTSBR102
00044 *          REFERENCE: TCL 217                    PROGRAMMER: EHH  DTSBR102
00045 *                                                                 DTSBR102
00046 * 10-27-98 MODIFIED TO MEET DUTAS CONVERSION SPECIFICATIONS.      DTSBR102
00047 *          REPORT RPT102R3 ELIMINATED IN EXTERNAL DESIGN DOCU-    DTSBR102
00048 *          MENTATION. DELETED REFERENCE TO REPORT #3. REPORT      DTSBR102
00049 *          ELIMINATED IN EXTERNAL DESIGN DOCUMENTATION.           DTSBR102
00050 *                                                                 DTSBR102
00051 * 08/13/99 MODIFIED TO MEET DUTAS REQUIRMENTS FOR LAZER PRINTING  DTSBR102
00052 *          REFERENCE:                            PROGRAMMER: ZL1  DTSBR102
00053 *                                                                 DTSBR102
00054 * 05/26/00 MODIFIED TO DTSBR102 REPORT WRITER PROGRAM TO COBOL II DTSBR102
00055 *          REPORT PGM.                           PROGRAMMER: RW1  DTSBR102
00056 *                                                                 DTSBR102
00057 * 01/14/14 MODIFIED TO DTSBR102 REPORT FOR COPYBOOK CHANGES       DTSBR102
00058 *          REPORT PGM.                           PROGRAMMER: ZL1  DTSBR102
00059 *                                                                 DTSBR102
00060 *    DESCRIPTION:                                                 DTSBR102
00061 *                                                                 DTSBR102
00062 *        THIS MODULE PRINTS LETTERS TO EMPLOYERS FOR EMPLOYER     DTSBR102
00063 *        REGISTRATION CYCLE A (LETTER 1).                         DTSBR102
00064 *                                                                 DTSBR102
00065 *                                                                 DTSBR102
00066 *    RECORDS READ:                                                DTSBR102
00067 *                                                                 DTSBR102
00068 *        NONE.                                                    DTSBR102
00069 *                                                                 DTSBR102
00070 *                                                                 DTSBR102
00071 *    PRINTED OUTPUTS:                                             DTSBR102
00072 *                                                                 DTSBR102
00073 *        102R1  CYCLE A (LETTER 1):                               DTSBR102
00074 *               GENERIC 1ST LETTER                                DTSBR102
00075 *               EMPLOYER REQUESTED 1ST LETTER                     DTSBR102
00076 *               UI-5 RECEIVED, RATE UNKNOWN, 1ST LETTER           DTSBR102
00077 *               UI-5 RECEIVED, RATE KNOWN, 1ST LETTER             DTSBR102
00078 *               CLAIMANT WAGES 1ST LETTER                         DTSBR102
00079 *                                                                 DTSBR102
00080 *                                                                 DTSBR102
00081 *    RECORDS WRITTEN:                                             DTSBR102
00082 *                                                                 DTSBR102
00083 *        NONE.                                                    DTSBR102
00084 *                                                                 DTSBR102
00085 *                                                                 DTSBR102
00086 *    MODULES CALLED:                                              DTSBR102
00087 *                                                                 DTSBR102
00088 *        DTSBU001 DATE CONVERSION MODULE                          DTSBR102
00089 *        DTSBU071 NAME EDIT/CONVERSION MODULE                     DTSBR102
00090 *        DTSBU082 OPERATOR ID EDIT/LOOKUP MODULE                  DTSBR102
00091 *                                                                 DTSBR102
00092 *                                                                 DTSBR102
00093 *****                                                             DTSBR102
00094      EJECT                                                        DTSBR102
00095  ENVIRONMENT DIVISION.                                            DTSBR102
00096      SKIP2                                                        DTSBR102
00097  CONFIGURATION SECTION.                                           DTSBR102
00098  SPECIAL-NAMES. C01 IS TOP-OF-PAGE.                               DTSBR102
00099      SKIP1                                                        DTSBR102
00100  INPUT-OUTPUT SECTION.                                            DTSBR102
00101      SKIP1                                                        DTSBR102
00102  FILE-CONTROL.                                                    DTSBR102
00103      SELECT PRT-FILE ASSIGN TO RPT102R1.                          DTSBR102
00104      SKIP3                                                        DTSBR102
00105  DATA DIVISION.                                                   DTSBR102
00106      SKIP3                                                        DTSBR102
00107  FILE SECTION.                                                    DTSBR102
00108      SKIP2                                                        DTSBR102
00109  FD  PRT-FILE                                                     DTSBR102
00110      RECORDING MODE IS F                                          DTSBR102
00111      BLOCK CONTAINS 0 RECORDS                                     DTSBR102
00112      LABEL RECORDS ARE OMITTED.                                   DTSBR102
00113  01  XEROX-REPORT.                                                DTSBR102
00114      05  FILLER                      PIC X(1).                    DTSBR102
00115      05  XEROX-RPT                   PIC X(132).                  DTSBR102
00116      EJECT                                                        DTSBR102
00117  WORKING-STORAGE SECTION.                                         DTSBR102
001175 77  PAN-VALET PICTURE X(24) VALUE '051DTSBR102  01/15/14'.       DTSBR102
00118  77  PAN-VALET PICTURE X(24) VALUE '002DTSBR102  01/15/14'.       DTSBR102
00119  77  PAN-VALET PICTURE X(24) VALUE '049DTSBR102  10/08/13'.       DTSBR102
00120  77  PAN-VALET PICTURE X(24) VALUE '002DTSBR102  09/18/13'.       DTSBR102
00121  77  PAN-VALET PICTURE X(24) VALUE '005DTSBR102  08/19/11'.       DTSBR102
00122      SKIP3                                                        DTSBR102
00123  01  WRK-AREA.                                                    DTSBR102
00124      05  WRK-ABEND-CD                PIC S9(04)  COMP  VALUE +102.DTSBR102
00125      05  ABEND-MSG                   PIC  X(60)  VALUE SPACES.    DTSBR102
00126      05  FIRST-TIME-IND              PIC  X(01)  VALUE 'Y'.       DTSBR102
00127      05  WS-OPR-NAME                 PIC  X(32)  VALUE SPACES.    DTSBR102
00128      05  WS-OPR-UNIT-NAME            PIC  X(50)  VALUE SPACES.    DTSBR102
00129      05  WS-OPR-VOICE.                                            DTSBR102
00130          10  WS-OPR-VOICE-AREA       PIC  X(03)  VALUE SPACES.    DTSBR102
00131          10  WS-OPR-VOICE-1          PIC  X(03)  VALUE SPACES.    DTSBR102
00132          10  WS-OPR-VOICE-2          PIC  X(04)  VALUE SPACES.    DTSBR102
00133          10  WS-OPR-VOICE-EXT        PIC  X(04)  VALUE SPACES.    DTSBR102
00134      05  WS-SSN-NO                   PIC  9(09)  VALUE ZEROS.     DTSBR102
00135      05  WS-SSN-NUMBER.                                           DTSBR102
00136          10  WS-SSN-PT1              PIC 9(03).                   DTSBR102
00137          10  FILLER                  PIC X(01) VALUE '|'.         DTSBR102
00138          10  WS-SSN-PT2              PIC 9(02).                   DTSBR102
00139          10  FILLER                  PIC X(01) VALUE '|'.         DTSBR102
00140          10  WS-SSN-PT3              PIC 9(04).                   DTSBR102
00141                                                                   DTSBR102
00142  01  VSCA-LINE.                                                   DTSBR102
00143      05  VSCA-DATA                   PIC X(133) VALUE SPACES.     DTSBR102
00144                                                                   DTSBR102
00145      EJECT                                                        DTSBR102
00146  01  L001-LINK-AREA.                                              DTSBR102
00147  ++INCLUDE DTSIL001                                               DTSBR102
00148      EJECT                                                        DTSBR102
00149  01  L002-LINK-AREA.                                              DTSBR102
00150  ++INCLUDE DTSIL002                                               DTSBR102
00151      EJECT                                                        DTSBR102
00152  01  L071-LINK-AREA.                                              DTSBR102
00153  ++INCLUDE DTSIL071                                               DTSBR102
00154      EJECT                                                        DTSBR102
00155  01  L082-LINK-AREA.                                              DTSBR102
00156  ++INCLUDE DTSIL082                                               DTSBR102
00157      EJECT                                                        DTSBR102
00158  ++INCLUDE DTSXLRQI                                               DTSBR102
00159                                                                   DTSBR102
00160  01  LETTER-HEADING.                                              DTSBR102
00161      05  LTH-LINE-1.                                              DTSBR102
00162          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR102
00163          10  WS-LONG-TEXT-AREA       PIC  X(18).                  DTSBR102
00164      05  LTH-LINE-2.                                              DTSBR102
00165          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR102
00166          10  WS-FMT-LINE-1           PIC  X(40).                  DTSBR102
00167      05  LTH-LINE-3.                                              DTSBR102
00168          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR102
00169          10  WS-FMT-LINE-2           PIC  X(40).                  DTSBR102
00170      05  LTH-LINE-4.                                              DTSBR102
00171          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR102
00172          10  WS-FMT-LINE-3           PIC  X(40).                  DTSBR102
00173      05  LTH-LINE-5.                                              DTSBR102
00174          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR102
00175          10  WS-FMT-LINE-4           PIC  X(40).                  DTSBR102
00176      05  LTH-LINE-6.                                              DTSBR102
00177          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR102
00178          10  WS-FMT-LINE-5           PIC  X(40).                  DTSBR102
00179      05  LTH-LINE-7                  PIC  X(133) VALUE SPACES.    DTSBR102
00180      05  LTH-LINE-8.                                              DTSBR102
00181          10  FILLER                  PIC  X(10) VALUE SPACES.     DTSBR102
00182          10  WS-ACCOUNT-NO           PIC  X(13) VALUE             DTSBR102
00183                       'ACCOUNT NO:  '.                            DTSBR102
00184          10  WS-EMP-NO               PIC  999B999.                DTSBR102
00185      SKIP2                                                        DTSBR102
00186  ++INCLUDE DTSIZ102                                               DTSBR102
00187      EJECT                                                        DTSBR102
00188  LINKAGE SECTION.                                                 DTSBR102
00189      SKIP3                                                        DTSBR102
00190  01  LRCM-LINK-AREA.                                              DTSBR102
00191  ++INCLUDE DTSILRCM                                               DTSBR102
00192      EJECT                                                        DTSBR102
00193  01  R102-REC.                                                    DTSBR102
00194  ++INCLUDE DTSIR102                                               DTSBR102
00195      EJECT                                                        DTSBR102
00196  PROCEDURE DIVISION USING LRCM-LINK-AREA                          DTSBR102
00197                           R102-REC.                               DTSBR102
00198      SKIP2                                                        DTSBR102
00199      IF FIRST-TIME-IND = 'Y'                                      DTSBR102
00200          PERFORM I1000-INITIATE THRU I1000-EXIT                   DTSBR102
00201          MOVE 'N' TO FIRST-TIME-IND.                              DTSBR102
00202      SKIP1                                                        DTSBR102
00203      IF LRCM-EOR-88                                               DTSBR102
00204          PERFORM T1000-TERMINATE THRU T1000-EXIT                  DTSBR102
00205      ELSE                                                         DTSBR102
00206          PERFORM P1000-PROCESS THRU P1000-EXIT.                   DTSBR102
00207      SKIP2                                                        DTSBR102
00208      GOBACK.                                                      DTSBR102
00209      EJECT                                                        DTSBR102
00210  I1000-INITIATE.                                                  DTSBR102
00211      SKIP1                                                        DTSBR102
00212      OPEN OUTPUT PRT-FILE.                                        DTSBR102
00213      MOVE SPACES TO XEROX-REPORT.                                 DTSBR102
00214                                                                   DTSBR102
00215      MOVE 'RPT102R1' TO REPORT-NUMBER.                            DTSBR102
00216      WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE1                 DTSBR102
00217          AFTER ADVANCING TOP-OF-PAGE.                             DTSBR102
00218      WRITE XEROX-REPORT     FROM XEROX-CNTL-LINE2.                DTSBR102
00219      WRITE XEROX-REPORT     FROM VSCA-LINE AFTER ADVANCING 15.    DTSBR102
00220      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE1.                DTSBR102
00221      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE2.                DTSBR102
00222      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE3.                DTSBR102
00223      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE4.                DTSBR102
00224      WRITE XEROX-REPORT     FROM ROUTE-INFO-LINE5.                DTSBR102
00225                                                                   DTSBR102
00226      SKIP2                                                        DTSBR102
00227  I1000-EXIT.                                                      DTSBR102
00228      EXIT.                                                        DTSBR102
00229      EJECT                                                        DTSBR102
00230  P1000-PROCESS.                                                   DTSBR102
00231      SKIP1                                                        DTSBR102
00232      MOVE R102-CLAIMANT-SSN TO WS-SSN-NO.                         DTSBR102
00233      MOVE WS-SSN-NO (1:3)   TO WS-SSN-PT1.                        DTSBR102
00234      MOVE WS-SSN-NO (4:2)   TO WS-SSN-PT2.                        DTSBR102
00235      MOVE WS-SSN-NO (6:4)   TO WS-SSN-PT3.                        DTSBR102
00236      MOVE R102-OP-ID        TO L082-OP-ID.                        DTSBR102
00237      PERFORM S082-OP-ID-INFO THRU S082-EXIT.                      DTSBR102
00238      IF L082-NOT-VALID-OP OR L082-INTERNAL-88                     DTSBR102
00239          MOVE SPACES TO WS-OPR-NAME                               DTSBR102
00240          MOVE LRCM-DEFAULT-NAME TO WS-OPR-UNIT-NAME               DTSBR102
00241          MOVE LRCM-DEFAULT-VOICE TO WS-OPR-VOICE                  DTSBR102
00242      ELSE                                                         DTSBR102
00243          MOVE L082-UNIT-NAME TO WS-OPR-UNIT-NAME                  DTSBR102
00244          MOVE L082-VOICE-1 TO WS-OPR-VOICE                        DTSBR102
00245          MOVE L082-NAME TO L071-NAM                               DTSBR102
00246          MOVE 2 TO L071-NAME-FORMAT                               DTSBR102
00247          PERFORM S071-DESLASH-NAME THRU S071-EXIT                 DTSBR102
00248          MOVE L071-NAM TO WS-OPR-NAME.                            DTSBR102
00249      SKIP1                                                        DTSBR102
00250 *****MOVE R102-MAIL-DATE TO L001-FED-8-DATE-9.                    DTSBR102
00251 *****SET L001-FROM-FED-8 TO TRUE.                                 DTSBR102
00252 *****PERFORM S001-DATE-CONVERT THRU S001-EXIT.                    DTSBR102
00253      SKIP1                                                        DTSBR102
00254      MOVE R102-MAIL-DATE TO L002-DATE.                            DTSBR102
00255      SET L002-MIXED-CASE TO TRUE.                                 DTSBR102
00256      PERFORM S002-DATE-ALPHA THRU S002-EXIT.                      DTSBR102
00257      SKIP1                                                        DTSBR102
00258      PERFORM P2000-PRINT-HEADER THRU P2000-EXIT.                  DTSBR102
00259      SKIP1                                                        DTSBR102
00260      IF R102-GENERIC-88                                           DTSBR102
00261          PERFORM P3000-PRINT-GENERIC THRU P3000-EXIT              DTSBR102
00262      ELSE                                                         DTSBR102
00263      IF R102-EMP-REQUEST-88                                       DTSBR102
00264          PERFORM P4000-PRINT-REQUEST THRU P4000-EXIT              DTSBR102
00265 *****REPORT RPT102R3 DELETED                                      DTSBR102
00266      ELSE                                                         DTSBR102
00267      IF R102-UC30-RCVD-88                                         DTSBR102
00268          PERFORM P5000-PRINT-UC30 THRU P5000-EXIT                 DTSBR102
00269      ELSE                                                         DTSBR102
00270      IF R102-CLAIMANT-WGS-88                                      DTSBR102
00271          PERFORM P6000-PRINT-CLAIMANT THRU P6000-EXIT             DTSBR102
00272      ELSE                                                         DTSBR102
00273           MOVE ' INVALID LETTER TYPE '                            DTSBR102
00274             TO ABEND-MSG                                          DTSBR102
00275          PERFORM S999-ABEND THRU S999-EXIT.                       DTSBR102
00276      SKIP1                                                        DTSBR102
00277      PERFORM P7000-PRINT-FOOTER THRU P7000-EXIT.                  DTSBR102
00278      SKIP2                                                        DTSBR102
00279  P1000-EXIT.                                                      DTSBR102
00280      EXIT.                                                        DTSBR102
00281      EJECT                                                        DTSBR102
00282                                                                   DTSBR102
00283  P2000-PRINT-HEADER.                                              DTSBR102
00284      MOVE L002-LONG-TEXT-AREA TO WS-LONG-TEXT-AREA.               DTSBR102
00285      MOVE R102-FMT-LINE (1) TO WS-FMT-LINE-1.                     DTSBR102
00286      MOVE R102-FMT-LINE (2) TO WS-FMT-LINE-2.                     DTSBR102
00287      MOVE R102-FMT-LINE (3) TO WS-FMT-LINE-3.                     DTSBR102
00288      MOVE R102-FMT-LINE (4) TO WS-FMT-LINE-4.                     DTSBR102
00289      MOVE R102-FMT-LINE (5) TO WS-FMT-LINE-5.                     DTSBR102
00290      MOVE R102-EMP-NO       TO WS-EMP-NO.                         DTSBR102
00291      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING TOP-OF-PAGEDTSBR102
00292      WRITE XEROX-REPORT FROM VSCA-LINE AFTER ADVANCING 8 LINE.    DTSBR102
00293      WRITE XEROX-REPORT FROM LTH-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR102
00294      WRITE XEROX-REPORT FROM LTH-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR102
00295      WRITE XEROX-REPORT FROM LTH-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR102
00296      WRITE XEROX-REPORT FROM LTH-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR102
00297      WRITE XEROX-REPORT FROM LTH-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR102
00298      WRITE XEROX-REPORT FROM LTH-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR102
00299      WRITE XEROX-REPORT FROM LTH-LINE-7 AFTER ADVANCING 1 LINE    DTSBR102
00300      WRITE XEROX-REPORT FROM LTH-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR102
00301                                                                   DTSBR102
00302  P2000-EXIT.                                                      DTSBR102
00303      EXIT.                                                        DTSBR102
00304                                                                   DTSBR102
00305  P3000-PRINT-GENERIC.                                             DTSBR102
00306      WRITE XEROX-REPORT FROM GEN-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR102
00307      WRITE XEROX-REPORT FROM GEN-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR102
00308      WRITE XEROX-REPORT FROM GEN-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR102
00309      WRITE XEROX-REPORT FROM GEN-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR102
00310 *    WRITE XEROX-REPORT FROM GEN-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR102
00311      WRITE XEROX-REPORT FROM GEN-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR102
00312      WRITE XEROX-REPORT FROM GEN-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR102
00313      WRITE XEROX-REPORT FROM GEN-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR102
00314      WRITE XEROX-REPORT FROM GEN-LINE-10 AFTER ADVANCING 1 LINE.  DTSBR102
00315      WRITE XEROX-REPORT FROM GEN-LINE-11 AFTER ADVANCING 1 LINE.  DTSBR102
00316      WRITE XEROX-REPORT FROM GEN-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR102
00317      WRITE XEROX-REPORT FROM GEN-LINE-13 AFTER ADVANCING 1 LINE.  DTSBR102
00318      WRITE XEROX-REPORT FROM GEN-LINE-14 AFTER ADVANCING 1 LINE.  DTSBR102
00319      WRITE XEROX-REPORT FROM GEN-LINE-15 AFTER ADVANCING 1 LINE.  DTSBR102
00320                                                                   DTSBR102
00321  P3000-EXIT.                                                      DTSBR102
00322      EXIT.                                                        DTSBR102
00323                                                                   DTSBR102
00324  P4000-PRINT-REQUEST.                                             DTSBR102
00325      WRITE XEROX-REPORT FROM ERD-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR102
00326      WRITE XEROX-REPORT FROM ERD-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR102
00327      WRITE XEROX-REPORT FROM ERD-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR102
00328      WRITE XEROX-REPORT FROM ERD-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR102
00329      WRITE XEROX-REPORT FROM ERD-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR102
00330      WRITE XEROX-REPORT FROM ERD-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR102
00331      WRITE XEROX-REPORT FROM ERD-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR102
00332      WRITE XEROX-REPORT FROM ERD-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR102
00333      WRITE XEROX-REPORT FROM ERD-LINE-9 AFTER ADVANCING 1 LINE.   DTSBR102
00334      WRITE XEROX-REPORT FROM ERD-LINE-11 AFTER ADVANCING 1 LINE.  DTSBR102
00335 *    WRITE XEROX-REPORT FROM ERD-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR102
00336 *    WRITE XEROX-REPORT FROM ERD-LINE-13 AFTER ADVANCING 1 LINE.  DTSBR102
00337 *    WRITE XEROX-REPORT FROM ERD-LINE-14 AFTER ADVANCING 1 LINE.  DTSBR102
00338 *    WRITE XEROX-REPORT FROM ERD-LINE-15 AFTER ADVANCING 1 LINE.  DTSBR102
00339 *    WRITE XEROX-REPORT FROM ERD-LINE-16 AFTER ADVANCING 1 LINE.  DTSBR102
00340                                                                   DTSBR102
00341  P4000-EXIT.                                                      DTSBR102
00342      EXIT.                                                        DTSBR102
00343                                                                   DTSBR102
00344  P5000-PRINT-UC30.                                                DTSBR102
00345      WRITE XEROX-REPORT FROM URD-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR102
00346      WRITE XEROX-REPORT FROM URD-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR102
00347      WRITE XEROX-REPORT FROM URD-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR102
00348      WRITE XEROX-REPORT FROM URD-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR102
00349      WRITE XEROX-REPORT FROM URD-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR102
00350      WRITE XEROX-REPORT FROM URD-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR102
00351      WRITE XEROX-REPORT FROM URD-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR102
00352      WRITE XEROX-REPORT FROM URD-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR102
00353                                                                   DTSBR102
00354  P5000-EXIT.                                                      DTSBR102
00355      EXIT.                                                        DTSBR102
00356                                                                   DTSBR102
00357  P6000-PRINT-CLAIMANT.                                            DTSBR102
00358      MOVE WS-SSN-NUMBER       TO WS-SSN-NUM.                      DTSBR102
00359      MOVE R102-CLAIMANT-NAME  TO WS-CLAIMANT-NAME.                DTSBR102
00360      WRITE XEROX-REPORT FROM CLM-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR102
00361      WRITE XEROX-REPORT FROM CLM-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR102
00362      WRITE XEROX-REPORT FROM CLM-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR102
00363      WRITE XEROX-REPORT FROM CLM-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR102
00364      WRITE XEROX-REPORT FROM CLM-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR102
00365      WRITE XEROX-REPORT FROM CLM-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR102
00366 *    WRITE XEROX-REPORT FROM CLM-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR102
00367      WRITE XEROX-REPORT FROM CLM-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR102
00368      WRITE XEROX-REPORT FROM CLM-LINE-9 AFTER ADVANCING 1 LINE.   DTSBR102
00369      WRITE XEROX-REPORT FROM CLM-LINE-10 AFTER ADVANCING 1 LINE.  DTSBR102
00370      WRITE XEROX-REPORT FROM CLM-LINE-11 AFTER ADVANCING 1 LINE.  DTSBR102
00371      WRITE XEROX-REPORT FROM CLM-LINE-12 AFTER ADVANCING 1 LINE.  DTSBR102
00372      WRITE XEROX-REPORT FROM CLM-LINE-13 AFTER ADVANCING 1 LINE.  DTSBR102
00373      WRITE XEROX-REPORT FROM CLM-LINE-14 AFTER ADVANCING 1 LINE.  DTSBR102
00374      WRITE XEROX-REPORT FROM CLM-LINE-15 AFTER ADVANCING 1 LINE.  DTSBR102
00375      WRITE XEROX-REPORT FROM CLM-LINE-16 AFTER ADVANCING 1 LINE.  DTSBR102
00376 *    WRITE XEROX-REPORT FROM CLM-LINE-17 AFTER ADVANCING 1 LINE.  DTSBR102
00377 *    WRITE XEROX-REPORT FROM CLM-LINE-18 AFTER ADVANCING 1 LINE.  DTSBR102
00378                                                                   DTSBR102
00379  P6000-EXIT.                                                      DTSBR102
00380      EXIT.                                                        DTSBR102
00381                                                                   DTSBR102
00382  P7000-PRINT-FOOTER.                                              DTSBR102
00383      MOVE WS-OPR-VOICE-1      TO WS-OPR-VOICE-ONE.                DTSBR102
00384      MOVE WS-OPR-VOICE-2      TO WS-OPR-VOICE-TWO.                DTSBR102
00385      MOVE WS-OPR-NAME         TO WS-OPR-NAME-FOOTER.              DTSBR102
00386      WRITE XEROX-REPORT FROM LTF-LINE-1 AFTER ADVANCING 1 LINE.   DTSBR102
00387      WRITE XEROX-REPORT FROM LTF-LINE-2 AFTER ADVANCING 1 LINE.   DTSBR102
00388      WRITE XEROX-REPORT FROM LTF-LINE-3 AFTER ADVANCING 1 LINE.   DTSBR102
00389      WRITE XEROX-REPORT FROM LTF-LINE-4 AFTER ADVANCING 1 LINE.   DTSBR102
00390      WRITE XEROX-REPORT FROM LTF-LINE-5 AFTER ADVANCING 1 LINE.   DTSBR102
00391      WRITE XEROX-REPORT FROM LTF-LINE-6 AFTER ADVANCING 1 LINE.   DTSBR102
00392      WRITE XEROX-REPORT FROM LTF-LINE-7 AFTER ADVANCING 1 LINE.   DTSBR102
00393      WRITE XEROX-REPORT FROM LTF-LINE-8 AFTER ADVANCING 1 LINE.   DTSBR102
00394                                                                   DTSBR102
00395  P7000-EXIT.                                                      DTSBR102
00396      EXIT.                                                        DTSBR102
00397                                                                   DTSBR102
00398  T1000-TERMINATE.                                                 DTSBR102
00399      SKIP1                                                        DTSBR102
00400      CLOSE PRT-FILE.                                              DTSBR102
00401      SKIP2                                                        DTSBR102
00402  T1000-EXIT.                                                      DTSBR102
00403      EXIT.                                                        DTSBR102
00404      EJECT                                                        DTSBR102
00405  S001-DATE-CONVERT.                                               DTSBR102
00406      SKIP1                                                        DTSBR102
00407      CALL 'DTSBU001' USING L001-LINK-AREA.                        DTSBR102
00408      SKIP2                                                        DTSBR102
00409  S001-EXIT.                                                       DTSBR102
00410      EXIT.                                                        DTSBR102
00411      SKIP3                                                        DTSBR102
00412  S002-DATE-ALPHA.                                                 DTSBR102
00413      SKIP1                                                        DTSBR102
00414      CALL 'DTSBU002' USING L002-LINK-AREA.                        DTSBR102
00415      SKIP2                                                        DTSBR102
00416  S002-EXIT.                                                       DTSBR102
00417      EXIT.                                                        DTSBR102
00418      SKIP3                                                        DTSBR102
00419  S071-DESLASH-NAME.                                               DTSBR102
00420      SKIP1                                                        DTSBR102
00421      CALL 'DTSBU071' USING L071-LINK-AREA.                        DTSBR102
00422      SKIP2                                                        DTSBR102
00423  S071-EXIT.                                                       DTSBR102
00424      EXIT.                                                        DTSBR102
00425      SKIP3                                                        DTSBR102
00426  S082-OP-ID-INFO.                                                 DTSBR102
00427      SKIP1                                                        DTSBR102
00428      CALL 'DTSBU082' USING L082-LINK-AREA.                        DTSBR102
00429      SKIP2                                                        DTSBR102
00430  S082-EXIT.                                                       DTSBR102
00431      EXIT.                                                        DTSBR102
00432      SKIP3                                                        DTSBR102
00433  S999-ABEND.                                                      DTSBR102
00434      SKIP1                                                        DTSBR102
00435      CALL 'DTSBU999' USING WRK-ABEND-CD.                          DTSBR102
00436      SKIP2                                                        DTSBR102
00437  S999-EXIT.                                                       DTSBR102
00438      EXIT.                                                        DTSBR102
