DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
902
Batch/CHGBD206.cob
Normal file
902
Batch/CHGBD206.cob
Normal file
@ -0,0 +1,902 @@
|
||||
00001 IDENTIFICATION DIVISION. 05/25/10
|
||||
00002 PROGRAM-ID. CHGBD206. CHGBD206
|
||||
00003 *AUTHOR. TRW. LV020
|
||||
00004 *DATE-WRITTEN. JULY 2002. CHGBD206
|
||||
00005 DATE-COMPILED. CHGBD206
|
||||
00006 SKIP3 CHGBD206
|
||||
00007 ***** CHGBD206
|
||||
00008 * CHGBD206
|
||||
00009 * FUNCTION: CHGBD206
|
||||
00010 * CHGBD206
|
||||
00011 * SELECT CHARGE RECORDS TO INCLUDE IN TOTAL BENEFIT CHGBD206
|
||||
00012 * CHARGE FILE, LISTING CHARGES TO EACH CLAIMANT CHGBD206
|
||||
00013 * BY BENEFIT YEAR AND DATE OF PAYMENT OR ADJUSTMENT. CHGBD206
|
||||
00014 * OF PAYMENT OR ADJUSTMENT. CHGBD206
|
||||
00015 * CHGBD206
|
||||
00016 * WRITE BD206CHG OUTPUT RECORD. CHGBD206
|
||||
00017 * CHGBD206
|
||||
00018 * INPUT: CHGBD206
|
||||
00019 * CHGBD206
|
||||
00020 * BD200CHG - CHARGE REPORT RECORDS GENERATED BY CHGBD206
|
||||
00021 * CHGBD200. CHGBD206
|
||||
00022 * CHGPARM - EXTRACT PARAMETERS CHGBD206
|
||||
00023 * CHGBD206
|
||||
00024 * OUTPUT: CHGBD206
|
||||
00025 * CHGBD206
|
||||
00026 * BD206CHG - CHARGE RECORDS SELECTED IN CHGBD206
|
||||
00027 * CHGBD206. CHGBD206
|
||||
00028 * CHGBD206
|
||||
00029 * CHGBD206
|
||||
00030 * PARAMETERS: CHGBD206
|
||||
00031 * CHGBD206
|
||||
00032 * RUN TYPE - CHGBD206
|
||||
00033 * QUARTERLY ('QTR') - REGULAR QUARTERLY REPORTING CHGBD206
|
||||
00034 * ANNUAL ('ANN') - ANNUAL REPORTING CHGBD206
|
||||
00035 * EMPLOYER ('EMP') - SPECIAL REPORT FOR A SINGLE CHGBD206
|
||||
00036 * EMPLOYER CHGBD206
|
||||
00037 * REPORTS ('RPT') - SPECIAL REPORT TO REPRINT CHGBD206
|
||||
00038 * REPORTS. USE THE REPORT TYPE CHGBD206
|
||||
00039 * PARM TO INDICATE WHICH TYPES CHGBD206
|
||||
00040 * OF REPORTS TO INCLUDE. CHGBD206
|
||||
00041 * FISCAL AGENTS CHGBD206
|
||||
00042 * ('AGT') - RERUN FISCAL AGENT TAPES. CHGBD206
|
||||
00043 * CHGBD206
|
||||
00044 * >> WHEN RUN TYPE IS 'QTR' THE SYSTEM WILL CHGBD206
|
||||
00045 * >> GENERATE T026 BENEFIT CHARGE ACCOUNTING CHGBD206
|
||||
00046 * >> TRANSACTIONS AND TPS RECORDS. CHGBD206
|
||||
00047 * CHGBD206
|
||||
00048 * BEGIN DATE - DATE FROM WHICH TO BEGIN SELECTION CHGBD206
|
||||
00049 * OF CHARGE RECORDS. CHGBD206
|
||||
00050 * REQUIRED FOR ALL RUN TYPES. CHGBD206
|
||||
00051 * CHGBD206
|
||||
00052 * END DATE - DATE AT WHICH TO END SELECTION CHGBD206
|
||||
00053 * OF CHARGE RECORDS. CHGBD206
|
||||
00054 * REQUIRED FOR ALL RUN TYPES. CHGBD206
|
||||
00055 * CHGBD206
|
||||
00056 * CHGBD206
|
||||
00057 ***** CHGBD206
|
||||
00058 CHGBD206
|
||||
00059 ******************************************************************CHGBD206
|
||||
00060 * MODIFICATION HISTORY: *CHGBD206
|
||||
00061 * *CHGBD206
|
||||
00062 * 02-02-1999 INITIAL DEVELOPMENT *CHGBD206
|
||||
00063 * REFERENCE RFP # AUTHOR OF CHANGE - GD *CHGBD206
|
||||
00064 * *CHGBD206
|
||||
00065 * 06-21-2001 MODIFIED FOR NEW CHARGE PROCESS CHGBD206
|
||||
00066 * REFERENCE RFP #**** AUTHOR OF CHANGE - GD *CHGBD206
|
||||
00067 * *CHGBD206
|
||||
00068 * 04-23-2002 MODIFIED TO OUTPUT TEUC RPC150R1 REPORT CHGBD206
|
||||
00069 * REFERENCE RFP #**** AUTHOR OF CHANGE - RW1 *CHGBD206
|
||||
00070 * *CHGBD206
|
||||
00071 * 06-29-2004 ADD EMP-TYPE 17 - DOMESTIC VIOLENCE. CHGBD206
|
||||
00072 * REFERENCE RFP #**** AUTHOR OF CHANGE - GD *CHGBD206
|
||||
00073 * *CHGBD206
|
||||
00074 * 01-11-2006 REMOVE CODE IN P1000 THAT EXCLUDED POTENTIALLY CHGBD206
|
||||
00075 * INCORRECT CHARGES. THE PROBLEM IN THE BENEFITS CHGBD206
|
||||
00076 * SYSTEM HAS BEEN FIXED. CHGBD206
|
||||
00077 * REFERENCE: AUTHOR OF CHANGE - GD *CHGBD206
|
||||
00078 * CHGBD206
|
||||
00079 * *CHGBD206
|
||||
00080 * 12-04-2009 MODIFIED FOR NEW CODES. CHGBD206
|
||||
00081 * REFERENCE RFP #**** AUTHOR OF CHANGE - ZL1 *CHGBD206
|
||||
00082 * *CHGBD206
|
||||
00083 * *CHGBD206
|
||||
00084 * 05-04-2010 MODIFIED FOR NEW CODES. CHGBD206
|
||||
00085 * REFERENCE RFP #**** AUTHOR OF CHANGE - ZL1 *CHGBD206
|
||||
00086 * *CHGBD206
|
||||
00087 * MM-DD-YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *CHGBD206
|
||||
00088 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *CHGBD206
|
||||
00089 * REFERENCE RFP #**** AUTHOR OF CHANGE - *** *CHGBD206
|
||||
00090 ******************************************************************CHGBD206
|
||||
00091 CHGBD206
|
||||
00092 SKIP3 CHGBD206
|
||||
00093 ENVIRONMENT DIVISION. CHGBD206
|
||||
00094 SKIP3 CHGBD206
|
||||
00095 INPUT-OUTPUT SECTION. CHGBD206
|
||||
00096 SKIP3 CHGBD206
|
||||
00097 FILE-CONTROL. CHGBD206
|
||||
00098 SELECT INPUT-PARM ASSIGN TO SYSIN CHGBD206
|
||||
00099 FILE STATUS IS INPUT-PARM-STATUS. CHGBD206
|
||||
00100 CHGBD206
|
||||
00101 SELECT BD200-CHG-FILE-IN ASSIGN TO BD200CHG CHGBD206
|
||||
00102 ORGANIZATION IS INDEXED CHGBD206
|
||||
00103 ACCESS MODE IS DYNAMIC CHGBD206
|
||||
00104 RECORD KEY IS CHG2-KEY-AREA CHGBD206
|
||||
00105 FILE STATUS IS BD200-CHG-STATUS. CHGBD206
|
||||
00106 CHGBD206
|
||||
00107 SELECT BD206-CHG-FILE-OUT ASSIGN TO BD206CHG CHGBD206
|
||||
00108 FILE STATUS IS BD206-CHG-STATUS. CHGBD206
|
||||
00109 CHGBD206
|
||||
00110 EJECT CHGBD206
|
||||
00111 DATA DIVISION. CHGBD206
|
||||
00112 CHGBD206
|
||||
00113 FILE SECTION. CHGBD206
|
||||
00114 FD INPUT-PARM CHGBD206
|
||||
00115 LABEL RECORDS ARE STANDARD CHGBD206
|
||||
00116 BLOCK CONTAINS 0 CHARACTERS. CHGBD206
|
||||
00117 SKIP1 CHGBD206
|
||||
00118 01 INPUT-PARM-REC. CHGBD206
|
||||
00119 05 PARM-RUN-TYPE PIC X(03). CHGBD206
|
||||
00120 05 FILLER PIC X(01). CHGBD206
|
||||
00121 05 PARM-BEGIN-DATE PIC 9(06). CHGBD206
|
||||
00122 05 FILLER PIC X(01). CHGBD206
|
||||
00123 05 PARM-END-DATE PIC 9(06). CHGBD206
|
||||
00124 05 FILLER PIC X(01). CHGBD206
|
||||
00125 05 PARM-REPORT-TYPES. CHGBD206
|
||||
00126 10 PARM-RPT-TYPE-RATED PIC X(01). CHGBD206
|
||||
00127 10 PARM-RPT-TYPE-SELF-IND PIC X(01). CHGBD206
|
||||
00128 10 PARM-RPT-TYPE-CWC PIC X(01). CHGBD206
|
||||
00129 10 PARM-RPT-TYPE-FED PIC X(01). CHGBD206
|
||||
00130 10 PARM-RPT-TYPE-TEUC PIC X(01). CHGBD206
|
||||
00131 10 PARM-RPT-TYPE-TEUCA PIC X(01). CHGBD206
|
||||
00132 05 FILLER PIC X(01). CHGBD206
|
||||
00133 05 PARM-EMP-NO PIC 9(06). CHGBD206
|
||||
00134 05 FILLER PIC X(50). CHGBD206
|
||||
00135 CHGBD206
|
||||
00136 FD BD200-CHG-FILE-IN CHGBD206
|
||||
00137 RECORD CONTAINS 64 CHARACTERS CHGBD206
|
||||
00138 DATA RECORD IS BD200-CHG-REC. CHGBD206
|
||||
00139 01 BD200-CHG-REC. CHGBD206
|
||||
00140 ++INCLUDE CHGIM002 CHGBD206
|
||||
00141 CHGBD206
|
||||
00142 FD BD206-CHG-FILE-OUT CHGBD206
|
||||
00143 LABEL RECORDS ARE STANDARD CHGBD206
|
||||
00144 BLOCK CONTAINS 0 CHARACTERS. CHGBD206
|
||||
00145 SKIP1 CHGBD206
|
||||
00146 01 BD206-CHG-REC PIC X(64). CHGBD206
|
||||
00147 CHGBD206
|
||||
00148 EJECT CHGBD206
|
||||
00149 WORKING-STORAGE SECTION. CHGBD206
|
||||
001495 77 PAN-VALET PICTURE X(24) VALUE '020CHGBD206 05/25/10'. CHGBD206
|
||||
00150 CHGBD206
|
||||
00151 01 WRK-AREA. CHGBD206
|
||||
00152 *& CHGBD206
|
||||
00153 05 WRK-DISP-AREA. CHGBD206
|
||||
00154 10 WRK-DATE PIC 9999B99B99. CHGBD206
|
||||
00155 10 FILLER PIC X(02) VALUE SPACES. CHGBD206
|
||||
00156 10 WRK-EMP-DISP PIC 9(06). CHGBD206
|
||||
00157 10 FILLER PIC X(02) VALUE SPACES. CHGBD206
|
||||
00158 10 WRK-SSN-DISP PIC 9(10). CHGBD206
|
||||
00159 10 FILLER PIC X(02) VALUE SPACES. CHGBD206
|
||||
00160 10 WRK-CHG-AMT-DISP PIC Z(07)9.99-. CHGBD206
|
||||
00161 CHGBD206
|
||||
00162 05 WRK-SSN PIC 9(10). CHGBD206
|
||||
00163 05 FILLER REDEFINES WRK-SSN. CHGBD206
|
||||
00164 10 WRK-SSN9 PIC 9(09). CHGBD206
|
||||
00165 10 WRK-SSN0 PIC 9(01). CHGBD206
|
||||
00166 CHGBD206
|
||||
00167 05 WRK-TOT-CHG PIC S9(11)V99 COMP-3 CHGBD206
|
||||
00168 VALUE +0. CHGBD206
|
||||
00169 05 WRK-TOT-CHG-DISP PIC Z(10)9.99-. CHGBD206
|
||||
00170 05 ABEND-CODE PIC S9(04) COMP CHGBD206
|
||||
00171 VALUE +206. CHGBD206
|
||||
00172 05 ABEND-MOD PIC X(08) CHGBD206
|
||||
00173 VALUE 'DTSBU999'. CHGBD206
|
||||
00174 05 ABEND-MSG PIC X(60). CHGBD206
|
||||
00175 CHGBD206
|
||||
00176 05 INPUT-PARM-STATUS PIC X(02) VALUE SPACES. CHGBD206
|
||||
00177 88 INPUT-PARM-OK-88 VALUE ZERO. CHGBD206
|
||||
00178 88 INPUT-PARM-EOF-88 VALUE '10'. CHGBD206
|
||||
00179 CHGBD206
|
||||
00180 05 BD200-CHG-STATUS PIC X(02) VALUE SPACES. CHGBD206
|
||||
00181 88 BD200-FILE-OK-88 VALUE ZERO. CHGBD206
|
||||
00182 88 BD200-FILE-EOF-88 VALUE '10'. CHGBD206
|
||||
00183 CHGBD206
|
||||
00184 05 BD206-CHG-STATUS PIC X(02) VALUE SPACES. CHGBD206
|
||||
00185 88 BD206-FILE-OK-88 VALUE ZERO. CHGBD206
|
||||
00186 88 BD206-FILE-EOF-88 VALUE '10'. CHGBD206
|
||||
00187 CHGBD206
|
||||
00188 05 WRK-ERROR-IND PIC X(01). CHGBD206
|
||||
00189 88 WRK-ERROR-YES-88 VALUE 'Y'. CHGBD206
|
||||
00190 88 WRK-ERROR-NO-88 VALUE 'N'. CHGBD206
|
||||
00191 CHGBD206
|
||||
00192 05 WRK-EMP-VALID-IND PIC X(01). CHGBD206
|
||||
00193 88 WRK-EMP-VALID-YES-88 VALUE 'Y'. CHGBD206
|
||||
00194 88 WRK-EMP-VALID-NO-88 VALUE 'N'. CHGBD206
|
||||
00195 CHGBD206
|
||||
00196 05 WRK-BEGIN-DATE PIC S9(09) COMP-3. CHGBD206
|
||||
00197 05 WRK-END-DATE PIC S9(09) COMP-3. CHGBD206
|
||||
00198 CHGBD206
|
||||
00199 05 WRK-BEGIN-DATE-DISP PIC 9(08). CHGBD206
|
||||
00200 05 FILLER REDEFINES WRK-BEGIN-DATE-DISP. CHGBD206
|
||||
00201 10 WRK-BEGIN-YR PIC 9(04). CHGBD206
|
||||
00202 10 WRK-BEGIN-MO PIC 9(02). CHGBD206
|
||||
00203 10 WRK-BEGIN-DA PIC 9(02). CHGBD206
|
||||
00204 CHGBD206
|
||||
00205 05 WRK-END-DATE-DISP PIC 9(08). CHGBD206
|
||||
00206 05 FILLER REDEFINES WRK-END-DATE-DISP. CHGBD206
|
||||
00207 10 WRK-END-YR PIC 9(04). CHGBD206
|
||||
00208 10 WRK-END-MO PIC 9(02). CHGBD206
|
||||
00209 10 WRK-END-DA PIC 9(02). CHGBD206
|
||||
00210 CHGBD206
|
||||
00211 05 WRK-EMP-NO PIC S9(07) COMP-3. CHGBD206
|
||||
00212 88 WRK-POOL-ACCT-88 VALUE +028411, CHGBD206
|
||||
00213 +999000 THRU +999992. CHGBD206
|
||||
00214 88 WRK-FED-ACCT-88 VALUE +1 THRU +1999. CHGBD206
|
||||
00215 CHGBD206
|
||||
00216 05 WRK-EMP-TYPE PIC 9(02). CHGBD206
|
||||
00217 88 WRK-EMP-TYPE-CONTRIB-88 VALUE 00. CHGBD206
|
||||
00218 88 WRK-EMP-TYPE-UCX-88 VALUE 01. CHGBD206
|
||||
00219 88 WRK-EMP-TYPE-UCFE-88 VALUE 02. CHGBD206
|
||||
00220 88 WRK-EMP-TYPE-FED-88 VALUE 01, 02. CHGBD206
|
||||
00221 88 WRK-EMP-TYPE-CWC-88 VALUE 04. CHGBD206
|
||||
00222 88 WRK-EMP-TYPE-SELF-INS-88 VALUE 08. CHGBD206
|
||||
00223 88 WRK-EMP-TYPE-DC-GOV-88 VALUE 10. CHGBD206
|
||||
00224 88 WRK-EMP-TYPE-NOT-LIAB-88 VALUE 13. CHGBD206
|
||||
00225 88 WRK-EMP-TYPE-TEUC-88 VALUE 16. CHGBD206
|
||||
00226 88 WRK-EMP-TYPE-DOM-VIOLENC-88 VALUE 17. CHGBD206
|
||||
00227 88 WRK-EMP-TYPE-POOL-88 VALUE CHGBD206
|
||||
00228 03, 05, 06, 07, 09, 11, CHGBD206
|
||||
00229 12, 15, 17, 18, 19, 20 CHGBD206
|
||||
00230 21, 22, 23, 24, 25, 26, 27. CHGBD206
|
||||
00231 88 WRK-EMP-TYPE-VALID-88 VALUE CHGBD206
|
||||
00232 00, 01, 02, 03, 04, 05, CHGBD206
|
||||
00233 06, 07, 08, 09, 10, 11, CHGBD206
|
||||
00234 12, 13, 15, 16, 17, 18, CHGBD206
|
||||
00235 19, 20, 21, 22, 23, 24, 25, 26, 27. CHGBD206
|
||||
00236 CHGBD206
|
||||
00237 05 WRK-RPT-TYPE PIC 9(02) VALUE ZERO. CHGBD206
|
||||
00238 88 WRK-RPT-TYPE-RATED-88 VALUE 00. CHGBD206
|
||||
00239 88 WRK-RPT-TYPE-FED-88 VALUE 01, 02. CHGBD206
|
||||
00240 88 WRK-RPT-TYPE-CWC-88 VALUE 04. CHGBD206
|
||||
00241 88 WRK-RPT-TYPE-SELF-INS-88 VALUE 08, 10. CHGBD206
|
||||
00242 88 WRK-RPT-TYPE-EMP-88 VALUE 00, 01, 02, CHGBD206
|
||||
00243 04, 08, 10. CHGBD206
|
||||
00244 CHGBD206
|
||||
00245 05 WRK-REC-SELECTED-IND PIC X(01) VALUE SPACE. CHGBD206
|
||||
00246 88 WRK-REC-SELECTED-YES VALUE 'Y'. CHGBD206
|
||||
00247 88 WRK-REC-SELECTED-NO VALUE 'N'. CHGBD206
|
||||
00248 CHGBD206
|
||||
00249 05 WRK-BD200-CHG-READ PIC 9(09) COMP-3 VALUE 0. CHGBD206
|
||||
00250 05 WRK-BD206-WRITE PIC 9(09) COMP-3 VALUE 0. CHGBD206
|
||||
00251 05 WRK-BD200-CHG-DELETE PIC 9(09) COMP-3 VALUE 0. CHGBD206
|
||||
00252 05 WRK-BD200-NOT-LIAB-CNT PIC 9(09) COMP-3 VALUE 0. CHGBD206
|
||||
00253 05 WRK-INV-CHRG-ERR-CNT PIC 9(09) COMP-3 VALUE 0. CHGBD206
|
||||
00254 05 WRK-CNT-DISP PIC Z(08)9. CHGBD206
|
||||
00255 CHGBD206
|
||||
00256 01 WRK-PARM-AREA. CHGBD206
|
||||
00257 ++INCLUDE CHGIM003 CHGBD206
|
||||
00258 CHGBD206
|
||||
00259 01 L910-LINK-AREA. CHGBD206
|
||||
00260 ++INCLUDE DTSIL910 CHGBD206
|
||||
00261 CHGBD206
|
||||
00262 01 MSKL-REC. CHGBD206
|
||||
00263 ++INCLUDE DTSIMSKL CHGBD206
|
||||
00264 CHGBD206
|
||||
00265 01 MHDR-REC. CHGBD206
|
||||
00266 ++INCLUDE DTSIMHDR CHGBD206
|
||||
00267 CHGBD206
|
||||
00268 01 L001-LINK-AREA. CHGBD206
|
||||
00269 ++INCLUDE DTSIL001 CHGBD206
|
||||
00270 CHGBD206
|
||||
00271 01 L004-LINK-AREA. CHGBD206
|
||||
00272 ++INCLUDE DTSIL004 CHGBD206
|
||||
00273 CHGBD206
|
||||
00274 EJECT CHGBD206
|
||||
00275 PROCEDURE DIVISION. CHGBD206
|
||||
00276 SKIP2 CHGBD206
|
||||
00277 CHGBD206-MAIN. CHGBD206
|
||||
00278 PERFORM I0000-INITIATE THRU I0000-EXIT. CHGBD206
|
||||
00279 IF WRK-ERROR-YES-88 CHGBD206
|
||||
00280 GO TO CHGBD206-EXIT. CHGBD206
|
||||
00281 CHGBD206
|
||||
00282 PERFORM P0000-PROCESS THRU P0000-EXIT. CHGBD206
|
||||
00283 CHGBD206
|
||||
00284 PERFORM T0000-TERMINATE THRU T0000-EXIT. CHGBD206
|
||||
00285 CHGBD206
|
||||
00286 CHGBD206-EXIT. CHGBD206
|
||||
00287 STOP RUN. CHGBD206
|
||||
00288 EJECT CHGBD206
|
||||
00289 I0000-INITIATE. CHGBD206
|
||||
00290 CHGBD206
|
||||
00291 MOVE ZERO TO WRK-BD200-CHG-READ CHGBD206
|
||||
00292 WRK-BD200-NOT-LIAB-CNT CHGBD206
|
||||
00293 WRK-BD206-WRITE CHGBD206
|
||||
00294 WRK-BD200-CHG-DELETE. CHGBD206
|
||||
00295 CHGBD206
|
||||
00296 SET WRK-ERROR-NO-88 TO TRUE. CHGBD206
|
||||
00297 CHGBD206
|
||||
00298 PERFORM I1000-OPEN-FILES THRU I1000-EXIT. CHGBD206
|
||||
00299 CHGBD206
|
||||
00300 PERFORM I2000-PROCESS-PARMS THRU I2000-EXIT. CHGBD206
|
||||
00301 CHGBD206
|
||||
00302 I0000-EXIT. CHGBD206
|
||||
00303 EXIT. CHGBD206
|
||||
00304 CHGBD206
|
||||
00305 I1000-OPEN-FILES. CHGBD206
|
||||
00306 CHGBD206
|
||||
00307 OPEN INPUT BD200-CHG-FILE-IN. CHGBD206
|
||||
00308 IF NOT BD200-FILE-OK-88 CHGBD206
|
||||
00309 DISPLAY 'BD200 FILE OPEN ERROR: ' BD200-CHG-STATUS CHGBD206
|
||||
00310 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00311 CHGBD206
|
||||
00312 OPEN OUTPUT BD206-CHG-FILE-OUT. CHGBD206
|
||||
00313 IF NOT BD206-FILE-OK-88 CHGBD206
|
||||
00314 DISPLAY 'BD206 FILE OPEN ERROR: ' BD206-CHG-STATUS CHGBD206
|
||||
00315 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00316 CHGBD206
|
||||
00317 PERFORM S910-OPEN-READ THRU S910-EXIT. CHGBD206
|
||||
00318 CHGBD206
|
||||
00319 I1000-EXIT. CHGBD206
|
||||
00320 EXIT. CHGBD206
|
||||
00321 CHGBD206
|
||||
00322 I2000-PROCESS-PARMS. CHGBD206
|
||||
00323 OPEN INPUT INPUT-PARM. CHGBD206
|
||||
00324 IF NOT INPUT-PARM-OK-88 CHGBD206
|
||||
00325 DISPLAY 'INPUT PARM FILE OPEN ERROR: ' CHGBD206
|
||||
00326 INPUT-PARM-STATUS CHGBD206
|
||||
00327 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00328 CHGBD206
|
||||
00329 READ INPUT-PARM. CHGBD206
|
||||
00330 IF NOT INPUT-PARM-OK-88 CHGBD206
|
||||
00331 DISPLAY 'INPUT PARM FILE READ ERROR: ' CHGBD206
|
||||
00332 INPUT-PARM-STATUS CHGBD206
|
||||
00333 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00334 CHGBD206
|
||||
00335 DISPLAY '***** CHGBD206 PARM RECORD *****'. CHGBD206
|
||||
00336 DISPLAY INPUT-PARM-REC. CHGBD206
|
||||
00337 DISPLAY SPACE. CHGBD206
|
||||
00338 CHGBD206
|
||||
00339 DISPLAY '***** CHGBD206 EDITED PARMS *****'. CHGBD206
|
||||
00340 *** DISPLAY SPACE. CHGBD206
|
||||
00341 CHGBD206
|
||||
00342 PERFORM I2100-PARM-RUN-TYPE THRU I2100-EXIT. CHGBD206
|
||||
00343 CHGBD206
|
||||
00344 PERFORM I2200-PARM-DATES THRU I2200-EXIT. CHGBD206
|
||||
00345 CHGBD206
|
||||
00346 PERFORM I2300-PARM-RPT-TYPES THRU I2300-EXIT. CHGBD206
|
||||
00347 CHGBD206
|
||||
00348 PERFORM I2400-PARM-EMP-NO THRU I2400-EXIT. CHGBD206
|
||||
00349 CHGBD206
|
||||
00350 I2000-EXIT. CHGBD206
|
||||
00351 EXIT. CHGBD206
|
||||
00352 CHGBD206
|
||||
00353 I2100-PARM-RUN-TYPE. CHGBD206
|
||||
00354 MOVE PARM-RUN-TYPE TO CHG3-RUN-TYPE. CHGBD206
|
||||
00355 IF CHG3-RUN-TYPE-VALID-88 CHGBD206
|
||||
00356 NEXT SENTENCE CHGBD206
|
||||
00357 ELSE CHGBD206
|
||||
00358 MOVE 'PARM RUN TYPE INVALID ' TO ABEND-MSG CHGBD206
|
||||
00359 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00360 CHGBD206
|
||||
00361 DISPLAY 'RUN TYPE : ' CHG3-RUN-TYPE. CHGBD206
|
||||
00362 *** DISPLAY SPACE. CHGBD206
|
||||
00363 CHGBD206
|
||||
00364 I2100-EXIT. CHGBD206
|
||||
00365 EXIT. CHGBD206
|
||||
00366 CHGBD206
|
||||
00367 I2200-PARM-DATES. CHGBD206
|
||||
00368 MOVE ZERO TO WRK-BEGIN-DATE CHGBD206
|
||||
00369 WRK-END-DATE. CHGBD206
|
||||
00370 CHGBD206
|
||||
00371 IF (PARM-BEGIN-DATE = SPACES OR LOW-VALUES) CHGBD206
|
||||
00372 AND (PARM-END-DATE = SPACES OR LOW-VALUES) CHGBD206
|
||||
00373 PERFORM I2230-DEFAULT-DATES THRU I2230-EXIT CHGBD206
|
||||
00374 ELSE CHGBD206
|
||||
00375 PERFORM I2210-BEGIN-DATE THRU I2210-EXIT CHGBD206
|
||||
00376 PERFORM I2220-END-DATE THRU I2220-EXIT. CHGBD206
|
||||
00377 CHGBD206
|
||||
00378 IF WRK-END-DATE < WRK-BEGIN-DATE CHGBD206
|
||||
00379 MOVE 'PERIOD END LESS THAN PERIOD BEGIN' CHGBD206
|
||||
00380 TO ABEND-MSG CHGBD206
|
||||
00381 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00382 CHGBD206
|
||||
00383 MOVE WRK-BEGIN-DATE TO CHG3-BEGIN-DATE. CHGBD206
|
||||
00384 MOVE WRK-END-DATE TO CHG3-END-DATE. CHGBD206
|
||||
00385 CHGBD206
|
||||
00386 DISPLAY 'START DATE : ' WRK-BEGIN-DATE. CHGBD206
|
||||
00387 DISPLAY 'END DATE : ' WRK-END-DATE. CHGBD206
|
||||
00388 DISPLAY SPACE. CHGBD206
|
||||
00389 CHGBD206
|
||||
00390 I2200-EXIT. CHGBD206
|
||||
00391 EXIT. CHGBD206
|
||||
00392 CHGBD206
|
||||
00393 I2210-BEGIN-DATE. CHGBD206
|
||||
00394 MOVE PARM-BEGIN-DATE TO L001-CAL-6-DATE-X. CHGBD206
|
||||
00395 PERFORM S001-FROM-CAL-6 THRU S001-EXIT. CHGBD206
|
||||
00396 IF L001-VALID-DATE CHGBD206
|
||||
00397 MOVE L001-FED-8-DATE-9 TO WRK-BEGIN-DATE CHGBD206
|
||||
00398 ELSE CHGBD206
|
||||
00399 MOVE 'INVALID PERIOD BEGIN DATE' TO ABEND-MSG CHGBD206
|
||||
00400 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00401 CHGBD206
|
||||
00402 IF CHG3-RUN-TYPE-QTRLY-88 CHGBD206
|
||||
00403 PERFORM I2211-QTR-BEGIN-DATE THRU I2211-EXIT CHGBD206
|
||||
00404 ELSE CHGBD206
|
||||
00405 IF CHG3-RUN-TYPE-ANNUAL-88 CHGBD206
|
||||
00406 PERFORM I2212-ANN-BEGIN-DATE THRU I2212-EXIT CHGBD206
|
||||
00407 ELSE CHGBD206
|
||||
00408 IF CHG3-RUN-TYPE-MONTHLY-88 CHGBD206
|
||||
00409 PERFORM I2213-MON-BEGIN-DATE THRU I2213-EXIT CHGBD206
|
||||
00410 ELSE CHGBD206
|
||||
00411 IF CHG3-RUN-TYPE-WEEKLY-88 CHGBD206
|
||||
00412 PERFORM I2214-WKLY-BEGIN-DATE THRU I2214-EXIT. CHGBD206
|
||||
00413 CHGBD206
|
||||
00414 I2210-EXIT. CHGBD206
|
||||
00415 EXIT. CHGBD206
|
||||
00416 CHGBD206
|
||||
00417 I2211-QTR-BEGIN-DATE. CHGBD206
|
||||
00418 MOVE WRK-BEGIN-DATE TO L004-DATE. CHGBD206
|
||||
00419 PERFORM S004-FROM-DATE THRU S004-EXIT. CHGBD206
|
||||
00420 IF WRK-BEGIN-DATE NOT = L004-QTR-START-DATE CHGBD206
|
||||
00421 MOVE 'PERIOD BEGIN NOT START OF QTR' CHGBD206
|
||||
00422 TO ABEND-MSG CHGBD206
|
||||
00423 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00424 END-IF. CHGBD206
|
||||
00425 CHGBD206
|
||||
00426 I2211-EXIT. CHGBD206
|
||||
00427 EXIT. CHGBD206
|
||||
00428 CHGBD206
|
||||
00429 I2212-ANN-BEGIN-DATE. CHGBD206
|
||||
00430 MOVE WRK-BEGIN-DATE TO WRK-BEGIN-DATE-DISP. CHGBD206
|
||||
00431 IF WRK-BEGIN-MO = 07 CHGBD206
|
||||
00432 AND WRK-BEGIN-DA = 01 CHGBD206
|
||||
00433 NEXT SENTENCE CHGBD206
|
||||
00434 ELSE CHGBD206
|
||||
00435 MOVE 'ANNUAL START DATE MUST BE JULY 1' CHGBD206
|
||||
00436 TO ABEND-MSG CHGBD206
|
||||
00437 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00438 END-IF. CHGBD206
|
||||
00439 CHGBD206
|
||||
00440 I2212-EXIT. CHGBD206
|
||||
00441 EXIT. CHGBD206
|
||||
00442 CHGBD206
|
||||
00443 I2213-MON-BEGIN-DATE. CHGBD206
|
||||
00444 MOVE WRK-BEGIN-DATE TO WRK-BEGIN-DATE-DISP. CHGBD206
|
||||
00445 IF WRK-BEGIN-DA = 01 CHGBD206
|
||||
00446 NEXT SENTENCE CHGBD206
|
||||
00447 ELSE CHGBD206
|
||||
00448 MOVE 'MONTHLY START DATE MUST BE FIRST DAY OF MONTH' CHGBD206
|
||||
00449 TO ABEND-MSG CHGBD206
|
||||
00450 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00451 END-IF. CHGBD206
|
||||
00452 CHGBD206
|
||||
00453 I2213-EXIT. CHGBD206
|
||||
00454 EXIT. CHGBD206
|
||||
00455 CHGBD206
|
||||
00456 I2214-WKLY-BEGIN-DATE. CHGBD206
|
||||
00457 IF L001-SUNDAY CHGBD206
|
||||
00458 OR L001-SUNDAY CHGBD206
|
||||
00459 NEXT SENTENCE CHGBD206
|
||||
00460 ELSE CHGBD206
|
||||
00461 MOVE 'WEEKLY START DATE MUST BE SUNDAY OR MONDAY' CHGBD206
|
||||
00462 TO ABEND-MSG CHGBD206
|
||||
00463 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00464 END-IF. CHGBD206
|
||||
00465 CHGBD206
|
||||
00466 I2214-EXIT. CHGBD206
|
||||
00467 EXIT. CHGBD206
|
||||
00468 CHGBD206
|
||||
00469 I2220-END-DATE. CHGBD206
|
||||
00470 MOVE PARM-END-DATE TO L001-CAL-6-DATE-X. CHGBD206
|
||||
00471 PERFORM S001-FROM-CAL-6 THRU S001-EXIT. CHGBD206
|
||||
00472 IF L001-VALID-DATE CHGBD206
|
||||
00473 MOVE L001-FED-8-DATE-9 TO WRK-END-DATE CHGBD206
|
||||
00474 ELSE CHGBD206
|
||||
00475 MOVE 'INVALID PERIOD END DATE' TO ABEND-MSG CHGBD206
|
||||
00476 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00477 CHGBD206
|
||||
00478 IF CHG3-RUN-TYPE-QTRLY-88 CHGBD206
|
||||
00479 PERFORM I2221-QTR-END-DATE THRU I2221-EXIT CHGBD206
|
||||
00480 ELSE CHGBD206
|
||||
00481 IF CHG3-RUN-TYPE-ANNUAL-88 CHGBD206
|
||||
00482 PERFORM I2222-ANN-END-DATE THRU I2222-EXIT CHGBD206
|
||||
00483 ELSE CHGBD206
|
||||
00484 IF CHG3-RUN-TYPE-MONTHLY-88 CHGBD206
|
||||
00485 PERFORM I2223-MON-END-DATE THRU I2223-EXIT CHGBD206
|
||||
00486 ELSE CHGBD206
|
||||
00487 IF CHG3-RUN-TYPE-WEEKLY-88 CHGBD206
|
||||
00488 PERFORM I2224-WKLY-END-DATE THRU I2224-EXIT. CHGBD206
|
||||
00489 CHGBD206
|
||||
00490 I2220-EXIT. CHGBD206
|
||||
00491 EXIT. CHGBD206
|
||||
00492 CHGBD206
|
||||
00493 I2221-QTR-END-DATE. CHGBD206
|
||||
00494 MOVE WRK-END-DATE TO L004-DATE. CHGBD206
|
||||
00495 PERFORM S004-FROM-DATE THRU S004-EXIT. CHGBD206
|
||||
00496 IF WRK-END-DATE NOT = L004-QTR-END-DATE CHGBD206
|
||||
00497 MOVE 'PERIOD END NOT END OF QTR' CHGBD206
|
||||
00498 TO ABEND-MSG CHGBD206
|
||||
00499 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00500 END-IF. CHGBD206
|
||||
00501 CHGBD206
|
||||
00502 I2221-EXIT. CHGBD206
|
||||
00503 EXIT. CHGBD206
|
||||
00504 CHGBD206
|
||||
00505 I2222-ANN-END-DATE. CHGBD206
|
||||
00506 MOVE WRK-END-DATE TO WRK-END-DATE-DISP. CHGBD206
|
||||
00507 IF WRK-END-MO = 06 CHGBD206
|
||||
00508 AND WRK-END-DA = 30 CHGBD206
|
||||
00509 NEXT SENTENCE CHGBD206
|
||||
00510 ELSE CHGBD206
|
||||
00511 MOVE 'ANNUAL END DATE MUST BE JUNE 30' CHGBD206
|
||||
00512 TO ABEND-MSG CHGBD206
|
||||
00513 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00514 END-IF. CHGBD206
|
||||
00515 CHGBD206
|
||||
00516 IF (WRK-BEGIN-YR + 1) = WRK-END-YR CHGBD206
|
||||
00517 NEXT SENTENCE CHGBD206
|
||||
00518 ELSE CHGBD206
|
||||
00519 MOVE 'START DATE NOT 1 YEAR PRIOR TO END DATE' CHGBD206
|
||||
00520 TO ABEND-MSG CHGBD206
|
||||
00521 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00522 END-IF. CHGBD206
|
||||
00523 CHGBD206
|
||||
00524 I2222-EXIT. CHGBD206
|
||||
00525 EXIT. CHGBD206
|
||||
00526 CHGBD206
|
||||
00527 I2223-MON-END-DATE. CHGBD206
|
||||
00528 MOVE WRK-END-DATE TO L001-FED-8-DATE-9. CHGBD206
|
||||
00529 PERFORM S001-FROM-FED-8 THRU S001-EXIT. CHGBD206
|
||||
00530 ADD +1 TO L001-JUL-ABS-DAY. CHGBD206
|
||||
00531 PERFORM S001-FROM-ABS THRU S001-EXIT. CHGBD206
|
||||
00532 IF L001-FED-8-DA = 01 CHGBD206
|
||||
00533 NEXT SENTENCE CHGBD206
|
||||
00534 ELSE CHGBD206
|
||||
00535 MOVE 'END DATE MUST BE END OF MONTH' CHGBD206
|
||||
00536 TO ABEND-MSG CHGBD206
|
||||
00537 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00538 END-IF. CHGBD206
|
||||
00539 CHGBD206
|
||||
00540 IF (WRK-END-DATE - WRK-BEGIN-DATE) > 30 CHGBD206
|
||||
00541 MOVE 'BEGIN AND END DATES NOT IN SAME MONTH' CHGBD206
|
||||
00542 TO ABEND-MSG CHGBD206
|
||||
00543 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00544 END-IF. CHGBD206
|
||||
00545 CHGBD206
|
||||
00546 I2223-EXIT. CHGBD206
|
||||
00547 EXIT. CHGBD206
|
||||
00548 CHGBD206
|
||||
00549 I2224-WKLY-END-DATE. CHGBD206
|
||||
00550 IF L001-FRIDAY CHGBD206
|
||||
00551 OR L001-SATURDAY CHGBD206
|
||||
00552 NEXT SENTENCE CHGBD206
|
||||
00553 ELSE CHGBD206
|
||||
00554 MOVE 'WEEKLY END DATE MUST BE FRIDAY OR SATURDAY' CHGBD206
|
||||
00555 TO ABEND-MSG CHGBD206
|
||||
00556 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00557 END-IF. CHGBD206
|
||||
00558 CHGBD206
|
||||
00559 I2224-EXIT. CHGBD206
|
||||
00560 EXIT. CHGBD206
|
||||
00561 CHGBD206
|
||||
00562 I2230-DEFAULT-DATES. CHGBD206
|
||||
00563 IF CHG3-RUN-TYPE-SPECIAL-88 CHGBD206
|
||||
00564 MOVE 'DATES REQUIRED FOR SPECIAL REQUEST' CHGBD206
|
||||
00565 TO ABEND-MSG CHGBD206
|
||||
00566 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00567 CHGBD206
|
||||
00568 MOVE LOW-VALUES TO MSKL-KEY-AREA. CHGBD206
|
||||
00569 MOVE +0 TO MSKL-EMP-NO. CHGBD206
|
||||
00570 SET MSKL-HDR-88 TO TRUE. CHGBD206
|
||||
00571 PERFORM S910-READ THRU S910-EXIT. CHGBD206
|
||||
00572 CHGBD206
|
||||
00573 IF L910-NO-REC-88 CHGBD206
|
||||
00574 MOVE 'MHDR RECORD IS MISSING' CHGBD206
|
||||
00575 TO ABEND-MSG CHGBD206
|
||||
00576 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00577 CHGBD206
|
||||
00578 MOVE MSKL-REC TO MHDR-REC. CHGBD206
|
||||
00579 CHGBD206
|
||||
00580 IF CHG3-RUN-TYPE-QTRLY-88 CHGBD206
|
||||
00581 PERFORM I2231-DEFAULT-QTR-DATES THRU I2231-EXIT CHGBD206
|
||||
00582 ELSE CHGBD206
|
||||
00583 IF CHG3-RUN-TYPE-ANNUAL-88 CHGBD206
|
||||
00584 PERFORM I2232-DEFAULT-ANN-DATES THRU I2232-EXIT CHGBD206
|
||||
00585 ELSE CHGBD206
|
||||
00586 IF CHG3-RUN-TYPE-MONTHLY-88 CHGBD206
|
||||
00587 PERFORM I2233-DEFAULT-MON-DATES THRU I2233-EXIT CHGBD206
|
||||
00588 ELSE CHGBD206
|
||||
00589 IF CHG3-RUN-TYPE-WEEKLY-88 CHGBD206
|
||||
00590 PERFORM I2234-DEFAULT-WKLY-DATES THRU I2234-EXIT. CHGBD206
|
||||
00591 CHGBD206
|
||||
00592 I2230-EXIT. CHGBD206
|
||||
00593 EXIT. CHGBD206
|
||||
00594 CHGBD206
|
||||
00595 I2231-DEFAULT-QTR-DATES. CHGBD206
|
||||
00596 MOVE MHDR-CMPL-QTR-BEGIN-DATE CHGBD206
|
||||
00597 TO WRK-BEGIN-DATE. CHGBD206
|
||||
00598 MOVE MHDR-CMPL-QTR-END-DATE CHGBD206
|
||||
00599 TO WRK-END-DATE. CHGBD206
|
||||
00600 CHGBD206
|
||||
00601 I2231-EXIT. CHGBD206
|
||||
00602 EXIT. CHGBD206
|
||||
00603 CHGBD206
|
||||
00604 I2232-DEFAULT-ANN-DATES. CHGBD206
|
||||
00605 MOVE MHDR-LAST-RATE-END-YRQ TO L004-QTR-5-9. CHGBD206
|
||||
00606 MOVE L004-QTR-5-YR TO WRK-END-YR. CHGBD206
|
||||
00607 MOVE 06 TO WRK-END-MO. CHGBD206
|
||||
00608 MOVE 30 TO WRK-END-DA. CHGBD206
|
||||
00609 MOVE WRK-END-DATE-DISP TO WRK-END-DATE. CHGBD206
|
||||
00610 CHGBD206
|
||||
00611 COMPUTE WRK-BEGIN-YR = (WRK-END-YR - 1). CHGBD206
|
||||
00612 MOVE 07 TO WRK-BEGIN-MO. CHGBD206
|
||||
00613 MOVE 01 TO WRK-BEGIN-DA. CHGBD206
|
||||
00614 MOVE WRK-BEGIN-DATE-DISP TO WRK-BEGIN-DATE. CHGBD206
|
||||
00615 CHGBD206
|
||||
00616 IF WRK-END-DATE >= MHDR-CURR-RUN-DATE CHGBD206
|
||||
00617 MOVE 'ANNUAL RPT CAN NOT RUN UNTIL AFTER JUNE 30' CHGBD206
|
||||
00618 TO ABEND-MSG CHGBD206
|
||||
00619 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00620 CHGBD206
|
||||
00621 I2232-EXIT. CHGBD206
|
||||
00622 EXIT. CHGBD206
|
||||
00623 CHGBD206
|
||||
00624 I2233-DEFAULT-MON-DATES. CHGBD206
|
||||
00625 MOVE MHDR-CMPL-MONTH-BEGIN-DATE CHGBD206
|
||||
00626 TO WRK-BEGIN-DATE. CHGBD206
|
||||
00627 MOVE MHDR-CMPL-MONTH-END-DATE CHGBD206
|
||||
00628 TO WRK-END-DATE. CHGBD206
|
||||
00629 CHGBD206
|
||||
00630 I2233-EXIT. CHGBD206
|
||||
00631 EXIT. CHGBD206
|
||||
00632 CHGBD206
|
||||
00633 I2234-DEFAULT-WKLY-DATES. CHGBD206
|
||||
00634 MOVE MHDR-CMPL-WEEK-BEGIN-DATE CHGBD206
|
||||
00635 TO WRK-BEGIN-DATE. CHGBD206
|
||||
00636 MOVE MHDR-CMPL-WEEK-END-DATE CHGBD206
|
||||
00637 TO WRK-END-DATE. CHGBD206
|
||||
00638 CHGBD206
|
||||
00639 I2234-EXIT. CHGBD206
|
||||
00640 EXIT. CHGBD206
|
||||
00641 CHGBD206
|
||||
00642 I2300-PARM-RPT-TYPES. CHGBD206
|
||||
00643 IF CHG3-RUN-TYPE-RPTS-88 CHGBD206
|
||||
00644 NEXT SENTENCE CHGBD206
|
||||
00645 ELSE CHGBD206
|
||||
00646 PERFORM I2310-DEFAULT-RPTS THRU I2310-EXIT CHGBD206
|
||||
00647 GO TO I2300-EXIT. CHGBD206
|
||||
00648 CHGBD206
|
||||
00649 MOVE PARM-REPORT-TYPES TO CHG3-RPT-TYPES. CHGBD206
|
||||
00650 CHGBD206
|
||||
00651 IF CHG3-RPT-TYPE-RATED-88 CHGBD206
|
||||
00652 OR CHG3-RPT-TYPE-SELF-INS-88 CHGBD206
|
||||
00653 OR CHG3-RPT-TYPE-CWC-88 CHGBD206
|
||||
00654 OR CHG3-RPT-TYPE-FED-88 CHGBD206
|
||||
00655 OR CHG3-RPT-TYPE-TEUC-88 CHGBD206
|
||||
00656 OR CHG3-RPT-TYPE-DC-88 CHGBD206
|
||||
00657 NEXT SENTENCE CHGBD206
|
||||
00658 ELSE CHGBD206
|
||||
00659 MOVE 'AT LEAST ONE RPT TYPE MUST SET TO Y ' TO ABEND-MSG CHGBD206
|
||||
00660 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00661 CHGBD206
|
||||
00662 IF CHG3-RPT-TYPE-RATED-88 CHGBD206
|
||||
00663 DISPLAY 'SELECT RATED EMPLOYERS'. CHGBD206
|
||||
00664 IF CHG3-RPT-TYPE-SELF-INS-88 CHGBD206
|
||||
00665 DISPLAY 'SELECT SELF-INSURED EMPLOYERS'. CHGBD206
|
||||
00666 IF CHG3-RPT-TYPE-CWC-88 CHGBD206
|
||||
00667 DISPLAY 'SELECT CWC EMPLOYERS'. CHGBD206
|
||||
00668 IF CHG3-RPT-TYPE-FED-88 CHGBD206
|
||||
00669 DISPLAY 'SELECT FEDERAL EMPLOYERS'. CHGBD206
|
||||
00670 IF CHG3-RPT-TYPE-TEUC-88 CHGBD206
|
||||
00671 DISPLAY 'SELECT TEUC EMPLOYERS'. CHGBD206
|
||||
00672 IF CHG3-RPT-TYPE-DC-88 CHGBD206
|
||||
00673 DISPLAY 'SELECT DC GOV EMPLOYERS'. CHGBD206
|
||||
00674 DISPLAY SPACE. CHGBD206
|
||||
00675 CHGBD206
|
||||
00676 I2300-EXIT. CHGBD206
|
||||
00677 EXIT. CHGBD206
|
||||
00678 CHGBD206
|
||||
00679 I2310-DEFAULT-RPTS. CHGBD206
|
||||
00680 IF CHG3-RUN-TYPE-QTRLY-88 CHGBD206
|
||||
00681 OR CHG3-RUN-TYPE-EMP-88 CHGBD206
|
||||
00682 OR CHG3-RUN-TYPE-MONTHLY-88 CHGBD206
|
||||
00683 OR CHG3-RUN-TYPE-WEEKLY-88 CHGBD206
|
||||
00684 SET CHG3-RPT-TYPE-RATED-88 TO TRUE CHGBD206
|
||||
00685 SET CHG3-RPT-TYPE-SELF-INS-88 TO TRUE CHGBD206
|
||||
00686 SET CHG3-RPT-TYPE-CWC-88 TO TRUE CHGBD206
|
||||
00687 SET CHG3-RPT-TYPE-FED-88 TO TRUE CHGBD206
|
||||
00688 SET CHG3-RPT-TYPE-DC-88 TO TRUE CHGBD206
|
||||
00689 ELSE CHGBD206
|
||||
00690 IF CHG3-RUN-TYPE-ANNUAL-88 CHGBD206
|
||||
00691 OR CHG3-RUN-TYPE-AGENT-88 CHGBD206
|
||||
00692 SET CHG3-RPT-TYPE-RATED-88 TO TRUE CHGBD206
|
||||
00693 ELSE CHGBD206
|
||||
00694 IF CHG3-RUN-TYPE-TEUC-88 CHGBD206
|
||||
00695 SET CHG3-RPT-TYPE-TEUC-88 TO TRUE. CHGBD206
|
||||
00696 CHGBD206
|
||||
00697 I2310-EXIT. CHGBD206
|
||||
00698 EXIT. CHGBD206
|
||||
00699 CHGBD206
|
||||
00700 I2400-PARM-EMP-NO. CHGBD206
|
||||
00701 IF CHG3-RUN-TYPE-EMP-88 CHGBD206
|
||||
00702 OR CHG3-RUN-TYPE-ANN-EMP-88 CHGBD206
|
||||
00703 OR CHG3-RUN-TYPE-MON-EMP-88 CHGBD206
|
||||
00704 OR CHG3-RUN-TYPE-WK-EMP-88 CHGBD206
|
||||
00705 NEXT SENTENCE CHGBD206
|
||||
00706 ELSE CHGBD206
|
||||
00707 MOVE ZERO TO CHG3-EMP-NO CHGBD206
|
||||
00708 GO TO I2400-EXIT. CHGBD206
|
||||
00709 CHGBD206
|
||||
00710 IF PARM-EMP-NO NUMERIC CHGBD206
|
||||
00711 IF PARM-EMP-NO > ZERO CHGBD206
|
||||
00712 NEXT SENTENCE CHGBD206
|
||||
00713 ELSE CHGBD206
|
||||
00714 MOVE 'PARM EMP NO MUST BE > ZERO' TO ABEND-MSG CHGBD206
|
||||
00715 PERFORM S999-ABEND THRU S999-EXIT CHGBD206
|
||||
00716 END-IF CHGBD206
|
||||
00717 ELSE CHGBD206
|
||||
00718 MOVE 'PARM EMP NO NOT NUMERIC' TO ABEND-MSG CHGBD206
|
||||
00719 PERFORM S999-ABEND THRU S999-EXIT. CHGBD206
|
||||
00720 CHGBD206
|
||||
00721 MOVE PARM-EMP-NO TO CHG3-EMP-NO. CHGBD206
|
||||
00722 CHGBD206
|
||||
00723 DISPLAY 'EMPLOYER SELECTED: ' CHG3-EMP-NO. CHGBD206
|
||||
00724 CHGBD206
|
||||
00725 I2400-EXIT. CHGBD206
|
||||
00726 EXIT. CHGBD206
|
||||
00727 CHGBD206
|
||||
00728 P0000-PROCESS. CHGBD206
|
||||
00729 CHGBD206
|
||||
00730 MOVE WRK-BEGIN-DATE TO CHG2-CHARGE-DATE. CHGBD206
|
||||
00731 MOVE +0 TO CHG2-EMP-NO CHGBD206
|
||||
00732 CHG2-SSN CHGBD206
|
||||
00733 CHG2-BYE. CHGBD206
|
||||
00734 MOVE 0 TO CHG2-PROGRAM. CHGBD206
|
||||
00735 START BD200-CHG-FILE-IN CHGBD206
|
||||
00736 KEY IS >= CHG2-KEY-AREA. CHGBD206
|
||||
00737 CHGBD206
|
||||
00738 IF NOT BD200-FILE-OK-88 CHGBD206
|
||||
00739 DISPLAY 'BD200 FIRST READ ERROR: ' BD200-CHG-STATUS CHGBD206
|
||||
00740 PERFORM P0100-NO-RECS THRU P0100-EXIT CHGBD206
|
||||
00741 GO TO P0000-EXIT. CHGBD206
|
||||
00742 CHGBD206
|
||||
00743 PERFORM P1000-READ-CHARGES THRU P1000-EXIT CHGBD206
|
||||
00744 UNTIL BD200-FILE-EOF-88 CHGBD206
|
||||
00745 OR CHG2-CHARGE-DATE > WRK-END-DATE CHGBD206
|
||||
00746 OR WRK-ERROR-YES-88. CHGBD206
|
||||
00747 CHGBD206
|
||||
00748 P0000-EXIT. CHGBD206
|
||||
00749 EXIT. CHGBD206
|
||||
00750 CHGBD206
|
||||
00751 P0100-NO-RECS. CHGBD206
|
||||
00752 DISPLAY '*** NO RECORDS FOUND FOR PARM ***'. CHGBD206
|
||||
00753 DISPLAY '*** RUN ENDING ***'. CHGBD206
|
||||
00754 CHGBD206
|
||||
00755 P0100-EXIT. CHGBD206
|
||||
00756 EXIT. CHGBD206
|
||||
00757 CHGBD206
|
||||
00758 P1000-READ-CHARGES. CHGBD206
|
||||
00759 READ BD200-CHG-FILE-IN NEXT. CHGBD206
|
||||
00760 CHGBD206
|
||||
00761 IF BD200-FILE-EOF-88 CHGBD206
|
||||
00762 OR CHG2-CHARGE-DATE > WRK-END-DATE CHGBD206
|
||||
00763 GO TO P1000-EXIT CHGBD206
|
||||
00764 ELSE CHGBD206
|
||||
00765 IF NOT BD200-FILE-OK-88 CHGBD206
|
||||
00766 DISPLAY 'BD200 FILE READ ERROR: ' BD200-CHG-STATUS CHGBD206
|
||||
00767 SET WRK-ERROR-YES-88 TO TRUE CHGBD206
|
||||
00768 GO TO P1000-EXIT. CHGBD206
|
||||
00769 CHGBD206
|
||||
00770 ADD 1 TO WRK-BD200-CHG-READ. CHGBD206
|
||||
00771 CHGBD206
|
||||
00772 MOVE CHG2-EMP-TYPE TO WRK-EMP-TYPE. CHGBD206
|
||||
00773 *& IF WRK-EMP-TYPE-POOL-88 CHGBD206
|
||||
00774 * ADD +1 TO WRK-BD200-CHG-DELETE CHGBD206
|
||||
00775 *& GO TO P1000-EXIT. CHGBD206
|
||||
00776 CHGBD206
|
||||
00777 MOVE CHG2-EMP-NO TO WRK-EMP-NO. CHGBD206
|
||||
00778 *& IF WRK-POOL-ACCT-88 CHGBD206
|
||||
00779 * ADD +1 TO WRK-BD200-CHG-DELETE CHGBD206
|
||||
00780 *& GO TO P1000-EXIT. CHGBD206
|
||||
00781 CHGBD206
|
||||
00782 *& EXCLUDE RECORDS WITH BYE PRIOR TO 1/1/2001 CHGBD206
|
||||
00783 *& FOR EMPLOYER TYPE = UCX, UCFE, SELF-INSURED, CHGBD206
|
||||
00784 *& DC GOVERNMENT. PER FRANK ORLANDO 2/21/2002 - GD. CHGBD206
|
||||
00785 CHGBD206
|
||||
00786 IF (CHG2-BYE = ZERO) OR (CHG2-CHARGE-DATE < 20010101) CHGBD206
|
||||
00787 NEXT SENTENCE CHGBD206
|
||||
00788 ELSE CHGBD206
|
||||
00789 IF CHG2-BYE < 20010101 CHGBD206
|
||||
00790 IF WRK-EMP-TYPE-UCX-88 CHGBD206
|
||||
00791 OR WRK-EMP-TYPE-UCFE-88 CHGBD206
|
||||
00792 OR WRK-EMP-TYPE-SELF-INS-88 CHGBD206
|
||||
00793 OR WRK-EMP-TYPE-DC-GOV-88 CHGBD206
|
||||
00794 OR (WRK-EMP-TYPE-CWC-88 AND WRK-FED-ACCT-88) CHGBD206
|
||||
00795 ADD +1 TO WRK-INV-CHRG-ERR-CNT CHGBD206
|
||||
00796 GO TO P1000-EXIT. CHGBD206
|
||||
00797 CHGBD206
|
||||
00798 PERFORM S1100-WRITE-BD206 THRU S1100-EXIT CHGBD206
|
||||
00799 COMPUTE WRK-TOT-CHG = WRK-TOT-CHG + CHGBD206
|
||||
00800 (CHG2-CURR-BEN-AMT + CHG2-CURR-ADJ-AMT). CHGBD206
|
||||
00801 CHGBD206
|
||||
00802 P1000-EXIT. CHGBD206
|
||||
00803 EXIT. CHGBD206
|
||||
00804 CHGBD206
|
||||
00805 S1100-WRITE-BD206. CHGBD206
|
||||
00806 WRITE BD206-CHG-REC FROM BD200-CHG-REC. CHGBD206
|
||||
00807 IF BD206-FILE-OK-88 CHGBD206
|
||||
00808 ADD 1 TO WRK-BD206-WRITE. CHGBD206
|
||||
00809 CHGBD206
|
||||
00810 S1100-EXIT. CHGBD206
|
||||
00811 EXIT. CHGBD206
|
||||
00812 CHGBD206
|
||||
00813 S001-FROM-CAL-6. CHGBD206
|
||||
00814 SET L001-FROM-CAL-6 TO TRUE. CHGBD206
|
||||
00815 GO TO S001-DATE. CHGBD206
|
||||
00816 CHGBD206
|
||||
00817 S001-FROM-FED-8. CHGBD206
|
||||
00818 SET L001-FROM-FED-8 TO TRUE. CHGBD206
|
||||
00819 GO TO S001-DATE. CHGBD206
|
||||
00820 CHGBD206
|
||||
00821 S001-FROM-ABS. CHGBD206
|
||||
00822 SET L001-FROM-ABS-DAY TO TRUE. CHGBD206
|
||||
00823 GO TO S001-DATE. CHGBD206
|
||||
00824 CHGBD206
|
||||
00825 S001-DATE. CHGBD206
|
||||
00826 CALL 'DTSBU001' USING L001-LINK-AREA. CHGBD206
|
||||
00827 S001-EXIT. EXIT. CHGBD206
|
||||
00828 CHGBD206
|
||||
00829 S004-FROM-DATE. CHGBD206
|
||||
00830 SET L004-FROM-DATE TO TRUE. CHGBD206
|
||||
00831 GO TO S004-YRQ. CHGBD206
|
||||
00832 CHGBD206
|
||||
00833 S004-YRQ. CHGBD206
|
||||
00834 CALL 'DTSBU004' USING L004-LINK-AREA. CHGBD206
|
||||
00835 S004-EXIT. EXIT. CHGBD206
|
||||
00836 CHGBD206
|
||||
00837 S910-OPEN-READ. CHGBD206
|
||||
00838 SET L910-OPEN-READ-88 TO TRUE. CHGBD206
|
||||
00839 GO TO S910-MSTR-IO. CHGBD206
|
||||
00840 CHGBD206
|
||||
00841 S910-READ. CHGBD206
|
||||
00842 SET L910-READ-88 TO TRUE. CHGBD206
|
||||
00843 GO TO S910-MSTR-IO. CHGBD206
|
||||
00844 CHGBD206
|
||||
00845 S910-CLOSE. CHGBD206
|
||||
00846 SET L910-CLOSE-88 TO TRUE. CHGBD206
|
||||
00847 GO TO S910-MSTR-IO. CHGBD206
|
||||
00848 CHGBD206
|
||||
00849 S910-MSTR-IO. CHGBD206
|
||||
00850 CALL 'DTSBU910' USING L910-LINK-AREA CHGBD206
|
||||
00851 MSKL-REC. CHGBD206
|
||||
00852 CHGBD206
|
||||
00853 S910-EXIT. CHGBD206
|
||||
00854 EXIT. CHGBD206
|
||||
00855 CHGBD206
|
||||
00856 T0000-TERMINATE. CHGBD206
|
||||
00857 CLOSE BD200-CHG-FILE-IN CHGBD206
|
||||
00858 BD206-CHG-FILE-OUT. CHGBD206
|
||||
00859 CHGBD206
|
||||
00860 PERFORM S910-CLOSE THRU S910-EXIT. CHGBD206
|
||||
00861 CHGBD206
|
||||
00862 DISPLAY '************** CHGBD206 COUNTS **************'. CHGBD206
|
||||
00863 DISPLAY '*** ***'. CHGBD206
|
||||
00864 CHGBD206
|
||||
00865 MOVE WRK-BD200-CHG-READ TO WRK-CNT-DISP. CHGBD206
|
||||
00866 DISPLAY 'CHARGE RECORDS READ: ' CHGBD206
|
||||
00867 WRK-CNT-DISP. CHGBD206
|
||||
00868 CHGBD206
|
||||
00869 MOVE WRK-BD206-WRITE TO WRK-CNT-DISP. CHGBD206
|
||||
00870 DISPLAY 'CHARGE RECORDS WRITTEN: ' CHGBD206
|
||||
00871 WRK-CNT-DISP. CHGBD206
|
||||
00872 CHGBD206
|
||||
00873 MOVE WRK-BD200-CHG-DELETE TO WRK-CNT-DISP. CHGBD206
|
||||
00874 DISPLAY 'POOL ACCOUNTS EXCLUDED: ' CHGBD206
|
||||
00875 WRK-CNT-DISP. CHGBD206
|
||||
00876 CHGBD206
|
||||
00877 DISPLAY SPACE. CHGBD206
|
||||
00878 CHGBD206
|
||||
00879 MOVE WRK-TOT-CHG TO WRK-TOT-CHG-DISP. CHGBD206
|
||||
00880 *** DISPLAY SPACE. CHGBD206
|
||||
00881 DISPLAY 'CHGBD206 TOTAL CHARGE: ' WRK-TOT-CHG-DISP. CHGBD206
|
||||
00882 CHGBD206
|
||||
00883 MOVE WRK-INV-CHRG-ERR-CNT TO WRK-CNT-DISP. CHGBD206
|
||||
00884 DISPLAY SPACE. CHGBD206
|
||||
00885 DISPLAY 'PRE-2001 CHARGES EXCLUDED: ' CHGBD206
|
||||
00886 WRK-CNT-DISP. CHGBD206
|
||||
00887 CHGBD206
|
||||
00888 DISPLAY '***********************************************'. CHGBD206
|
||||
00889 CHGBD206
|
||||
00890 T0000-EXIT. CHGBD206
|
||||
00891 EXIT. CHGBD206
|
||||
00892 EJECT CHGBD206
|
||||
00893 CHGBD206
|
||||
00894 S999-ABEND. CHGBD206
|
||||
00895 DISPLAY '**** CHGBD206 ABENDING ' CHGBD206
|
||||
00896 ABEND-MSG. CHGBD206
|
||||
00897 CALL ABEND-MOD USING ABEND-CODE. CHGBD206
|
||||
00898 CHGBD206
|
||||
00899 S999-EXIT. CHGBD206
|
||||
00900 EXIT. CHGBD206
|
||||
00901 CHGBD206
|
||||
Reference in New Issue
Block a user