DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
972
Batch/CHGBR110.cob
Normal file
972
Batch/CHGBR110.cob
Normal file
@ -0,0 +1,972 @@
|
||||
00001 IDENTIFICATION DIVISION. 04/05/24
|
||||
00002 PROGRAM-ID. CHGBR110. CHGBR110
|
||||
00003 *AUTHOR. TCL. LV004
|
||||
00004 *DATE-WRITTEN. FEBRUARY 1999. CHGBR110
|
||||
00005 DATE-COMPILED. CHGBR110
|
||||
00006 CHGBR110
|
||||
00007 ***** CHGBR110
|
||||
00008 * CALLING SEQUENCE: CHGBD300 CALLS CHGBR110
|
||||
00009 * CHGBR110 READS CHGIM004 RECORDS CHGBR110
|
||||
00010 * CHGBR110 PRINTS SELF-INSURED REPORT CHGBR110
|
||||
00011 * AND BILLS CHGBR110
|
||||
00012 ***** CHGBR110
|
||||
00013 * CHGBR110
|
||||
00014 * FUNCTION: CHGBR110
|
||||
00015 * CHGBR110
|
||||
00016 * (1) FOR QUARTERLY RUN: CHGBR110
|
||||
00017 * THIS MODULE WILL GENERATE A LETTER OF SELF-INSURED CHGBR110
|
||||
00018 * BILL AND A QUARTERLY BENEFIT REPORT. CHGBR110
|
||||
00019 * (2) FOR SPECIAL RUN: CHGBR110
|
||||
00020 * THIS MODULE WILL GENERATE A BENEFIT CHARGE REPORT ONLY CHGBR110
|
||||
00021 * (2) FOR ANNUAL RUN: CHGBR110
|
||||
00022 * THIS MODULE WILL GENERATE NEITHER SELF-INSURED BILL OR CHGBR110
|
||||
00023 * BENEFIT CHARGE REPORT. CHGBR110
|
||||
00024 * CHGBR110
|
||||
00025 * RECORDS READ: CHGBR110
|
||||
00026 * CHGBR110
|
||||
00027 * NONE. CHGBR110
|
||||
00028 * CHGBR110
|
||||
00029 * INPUT: CHGBR110
|
||||
00030 * CHGBR110
|
||||
00031 * CHGIM004 RECORD PASSED FROM CHGBD300 CHGBR110
|
||||
00032 * CHGBR110
|
||||
00033 * OUTPUT: CHGBR110
|
||||
00034 * CHGBR110
|
||||
00035 * RPC100R1 - SELF-INSURANCE LETTER CHGBR110
|
||||
00036 * RPC100R2 - SELF-INSURANCE BENEFIT CHARGE REPORT CHGBR110
|
||||
00037 * CHGBR110
|
||||
00038 * RECORDS WRITTEN ON DISK: CHGBR110
|
||||
00039 * CHGBR110
|
||||
00040 * NONE CHGBR110
|
||||
00041 * CHGBR110
|
||||
00042 * MODULES CALLED: CHGBR110
|
||||
00043 * CHGBR110
|
||||
00044 * DTSBU001 DATE EDIT/CONVERSION MODULE CHGBR110
|
||||
00045 * DTSBU071 NAME CONVERSION MODULE CHGBR110
|
||||
00046 * CHGBR110
|
||||
00047 ***** CHGBR110
|
||||
00048 CHGBR110
|
||||
00049 ******************************************************************CHGBR110
|
||||
00050 * MODIFICATION HISTORY: *CHGBR110
|
||||
00051 * *CHGBR110
|
||||
00052 * 02-08-2001 ADDED A HDR TO 'GRAND TOTALS' PAGE, AND WILL NOW *CHGBR110
|
||||
00053 * PRINT IT ONLY IF MORE THAN ONE EMPLOYER HAS BEEN *CHGBR110
|
||||
00054 * REPORTED - JHP *CHGBR110
|
||||
00055 * *CHGBR110
|
||||
00056 * 02-02-1999 MODIFIED FROM MT CHG100D *CHGBR110
|
||||
00057 * REFERENCE RFP # AUTHOR OF CHANGE - GD *CHGBR110
|
||||
00058 * *CHGBR110
|
||||
00059 * 04-29-2004 MODIFIED TO HANDLE EMPLOYER CREDITS CORRECTLY. *CHGBR110
|
||||
00060 * THE PROGRAM FINDS THE MQTR BALANCE DUE (WHICH HAS *CHGBR110
|
||||
00061 * BEEN ADJUSTED FOR CREDITS DURING THE ACCOUNTING *CHGBR110
|
||||
00062 * UPDATE), AND PRINTS THIS AMOUNT ON THE BILL RATHER *CHGBR110
|
||||
00063 * THAN THE RAW TOTAL CHARGED. WHEN THE MQTR BALANCE *CHGBR110
|
||||
00064 * IS LESS THAN THE TOTAL CHARGED, IT PRINTS A MESSAGE *CHGBR110
|
||||
00065 * ON THE BILL (BILL-LINE10) INDICATING THAT A CREDIT *CHGBR110
|
||||
00066 * HAS BEEN APPLIED. *CHGBR110
|
||||
00067 * REFERENCE DIR 105 AUTHOR OF CHANGE - GD *CHGBR110
|
||||
00068 * *CHGBR110
|
||||
00069 * 01-11-2005 MODIFIED P2200 TO BYPASS PRINTING OF BILL IF AMOUNT *CHGBR110
|
||||
00070 * CHARGED FOR THE QUARTER IS NEGATIVE. *CHGBR110
|
||||
00071 * REFERENCE: PROD PROBLEM AUTHOR OF CHANGE - GD *CHGBR110
|
||||
00072 * *CHGBR110
|
||||
00073 * 07-28-2008 REMOVED F ORLANDO NAME FROM REPORT - ZL1 *CHGBR110
|
||||
00074 * *CHGBR110
|
||||
00075 * 04-03-2009 MODIFIED FOR NEW PROGRAM CODES - GD *CHGBR110
|
||||
00076 * *CHGBR110
|
||||
00077 * 05-04-2010 MODIFIED FOR NEW PROGRAM CODES - ZL1 *CHGBR110
|
||||
00078 * *CHGBR110
|
||||
00079 * 01-06-2017 NEW REPORT LISTING EMPLOYERS RECEIVING BILL - ZL1 *CHGBR110
|
||||
00080 * *CHGBR110
|
||||
00081 * MM-DD-YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *CHGBR110
|
||||
00082 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *CHGBR110
|
||||
00083 * REFERENCE RFP #**** AUTHOR OF CHANGE - *** *CHGBR110
|
||||
00084 ******************************************************************CHGBR110
|
||||
00085 CHGBR110
|
||||
00086 ENVIRONMENT DIVISION. CHGBR110
|
||||
00087 CONFIGURATION SECTION. CHGBR110
|
||||
00088 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. CHGBR110
|
||||
00089 CHGBR110
|
||||
00090 INPUT-OUTPUT SECTION. CHGBR110
|
||||
00091 FILE-CONTROL. CHGBR110
|
||||
00092 *** LETTERS (I) CHGBR110
|
||||
00093 SELECT SELF-INS-BILL ASSIGN TO RPC110R1. CHGBR110
|
||||
00094 *** BEN.CHG. RPT (O) CHGBR110
|
||||
00095 SELECT SELF-INS-RPT ASSIGN TO RPC110R2. CHGBR110
|
||||
00096 *** BEN.CHG. RPT (O) CHGBR110
|
||||
00097 SELECT SELF-INS-DET ASSIGN TO RPC110R3. CHGBR110
|
||||
00098 EJECT CHGBR110
|
||||
00099 DATA DIVISION. CHGBR110
|
||||
00100 CHGBR110
|
||||
00101 FILE SECTION. CHGBR110
|
||||
00102 FD SELF-INS-BILL CHGBR110
|
||||
00103 RECORDING MODE IS F CHGBR110
|
||||
00104 BLOCK CONTAINS 0 RECORDS CHGBR110
|
||||
00105 LABEL RECORDS ARE OMITTED. CHGBR110
|
||||
00106 CHGBR110
|
||||
00107 01 SELF-BILL-REC PIC X(133). CHGBR110
|
||||
00108 CHGBR110
|
||||
00109 FD SELF-INS-RPT CHGBR110
|
||||
00110 RECORDING MODE IS F CHGBR110
|
||||
00111 RECORD CONTAINS 133 CHARACTERS CHGBR110
|
||||
00112 BLOCK CONTAINS 0 RECORDS CHGBR110
|
||||
00113 LABEL RECORDS ARE OMITTED. CHGBR110
|
||||
00114 CHGBR110
|
||||
00115 01 SELF-RPT-REC PIC X(133). CHGBR110
|
||||
00116 CHGBR110
|
||||
00117 FD SELF-INS-DET CHGBR110
|
||||
00118 RECORDING MODE IS F CHGBR110
|
||||
00119 RECORD CONTAINS 133 CHARACTERS CHGBR110
|
||||
00120 BLOCK CONTAINS 0 RECORDS CHGBR110
|
||||
00121 LABEL RECORDS ARE OMITTED. CHGBR110
|
||||
00122 CHGBR110
|
||||
00123 01 SELF-DET-REC PIC X(133). CHGBR110
|
||||
00124 CHGBR110
|
||||
00125 WORKING-STORAGE SECTION. CHGBR110
|
||||
001255 77 PAN-VALET PICTURE X(24) VALUE '004CHGBR110 04/05/24'. CHGBR110
|
||||
00126 77 PAN-VALET PICTURE X(24) VALUE '169CHGBR110 01/06/17'. CHGBR110
|
||||
00127 77 PAN-VALET PICTURE X(24) VALUE '004CHGBR110 01/06/17'. CHGBR110
|
||||
00128 77 PAN-VALET PICTURE X(24) VALUE '167CHGBR110 01/06/17'. CHGBR110
|
||||
00129 77 PAN-VALET PICTURE X(24) VALUE '002CHGBR110 01/06/17'. CHGBR110
|
||||
00130 77 PAN-VALET PICTURE X(24) VALUE '165CHGBR110 05/28/13'. CHGBR110
|
||||
00131 77 PAN-VALET PICTURE X(24) VALUE '002CHGBR110 05/28/13'. CHGBR110
|
||||
00132 77 PAN-VALET PICTURE X(24) VALUE '163CHGBR110 04/10/13'. CHGBR110
|
||||
00133 77 PAN-VALET PICTURE X(24) VALUE '009CHGBR110 04/10/13'. CHGBR110
|
||||
00134 CHGBR110
|
||||
00135 01 WRK-AREA. CHGBR110
|
||||
00136 05 WRK-ABEND-CODE PIC S9(04) COMP CHGBR110
|
||||
00137 VALUE +110. CHGBR110
|
||||
00138 05 ABEND-MSG PIC X(60) VALUE SPACE. CHGBR110
|
||||
00139 CHGBR110
|
||||
00140 05 NEW-PAGE-SW PIC X VALUE 'N'. CHGBR110
|
||||
00141 CHGBR110
|
||||
00142 05 WRK-REG-BENEFITS PIC X(25) CHGBR110
|
||||
00143 VALUE ' REGULAR BENEFIT PAYMENT '. CHGBR110
|
||||
00144 05 WRK-EXT-BENEFITS PIC X(25) CHGBR110
|
||||
00145 VALUE ' EXTENDED BENEFIT PAYMENT'. CHGBR110
|
||||
00146 05 WRK-TEUC-BENEFITS PIC X(25) CHGBR110
|
||||
00147 VALUE ' TEUC BENEFIT PAYMENT '. CHGBR110
|
||||
00148 05 WRK-TEUCA-BEN-PAYMENT PIC X(25) CHGBR110
|
||||
00149 VALUE ' TEUCA BENEFIT PAYMENT '. CHGBR110
|
||||
00150 05 WRK-FAC-BEN-PAYMENT PIC X(25) CHGBR110
|
||||
00151 VALUE ' FED ADDL COMP PAYMENT '. CHGBR110
|
||||
00152 05 WRK-ADJUSTMENTS PIC X(25) CHGBR110
|
||||
00153 VALUE ' ADJUSTMENTS '. CHGBR110
|
||||
00154 05 WRK-RPT-TYPE1 PIC X(26) CHGBR110
|
||||
00155 VALUE 'QUARTERLY CHARGE SUMMARY'. CHGBR110
|
||||
00156 05 WRK-RPT-TYPE2 PIC X(26) CHGBR110
|
||||
00157 VALUE ' BENEFIT CHARGE SPECIAL '. CHGBR110
|
||||
00158 CHGBR110
|
||||
00159 05 WRK-LINE-CNT PIC S9(02) COMP-3 VALUE +0. CHGBR110
|
||||
00160 05 WRK-PAGE-CNT PIC S9(05) COMP-3 VALUE +0. CHGBR110
|
||||
00161 05 WRK-EMPLYR-CNT PIC 9(07) COMP-3 VALUE 0. CHGBR110
|
||||
00162 CHGBR110
|
||||
00163 05 WRK-SSN PIC 9(09) VALUE 0. CHGBR110
|
||||
00164 05 FILLER REDEFINES WRK-SSN. CHGBR110
|
||||
00165 10 WRK-SSN1 PIC 9(03). CHGBR110
|
||||
00166 10 WRK-SSN2 PIC 9(02). CHGBR110
|
||||
00167 10 WRK-SSN3 PIC 9(04). CHGBR110
|
||||
00168 CHGBR110
|
||||
00169 05 WRK-MAIL-DATE. CHGBR110
|
||||
00170 10 WRK-MAIL-YY PIC 9(04). CHGBR110
|
||||
00171 10 WRK-MAIL-MM PIC 9(02). CHGBR110
|
||||
00172 10 WRK-MAIL-DD PIC 9(02). CHGBR110
|
||||
00173 CHGBR110
|
||||
00174 05 WRK-CURR-EMP PIC S9(07) COMP-3 VALUE +0. CHGBR110
|
||||
00175 CHGBR110
|
||||
00176 05 WRK-TOT-AMT PIC S9(09)V99 VALUE +0. CHGBR110
|
||||
00177 05 WRK-CURR-AMT PIC S9(09)V99 VALUE +0. CHGBR110
|
||||
00178 05 WRK-EMP-TOT-CHG PIC S9(09)V99 VALUE +0. CHGBR110
|
||||
00179 05 WRK-EMP-ACCT-CHG PIC S9(09)V99 VALUE +0. CHGBR110
|
||||
00180 05 WRK-RPT-TOT-CHG PIC S9(10)V99 VALUE +0. CHGBR110
|
||||
00181 05 WRK-RPT-ACCT-CHG PIC S9(10)V99 VALUE +0. CHGBR110
|
||||
00182 05 WS-OVPY-RECOVER PIC S9(09)V99 VALUE +0. CHGBR110
|
||||
00183 05 WRK-MQTR-BAL PIC S9(11)V99 VALUE +0. CHGBR110
|
||||
00184 CHGBR110
|
||||
00185 05 AMT-DISP1 PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00186 05 AMT-DISP2 PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00187 CHGBR110
|
||||
00188 01 ADDRESSES. CHGBR110
|
||||
00189 05 WS-ADDR-LINE PIC X(40) OCCURS 5 CHGBR110
|
||||
00190 INDEXED BY ADDRX. CHGBR110
|
||||
00191 CHGBR110
|
||||
00192 01 VSCA-LINE. CHGBR110
|
||||
00193 05 VSCA-DATA PIC X(133) VALUE SPACES. CHGBR110
|
||||
00194 CHGBR110
|
||||
00195 01 XF-CA-CNTL-LINE. CHGBR110
|
||||
00196 * 05 XF-CA-FILLER PIC X(01) VALUE SPACE. CHGBR110
|
||||
00197 05 X1-CA-DJDE PIC X(12) VALUE '$X9700$DJDE '. CHGBR110
|
||||
00198 05 X1-CA-JDL PIC X(09) VALUE 'JDL=XMOM,'. CHGBR110
|
||||
00199 05 X1-CA-JDE PIC X(11) VALUE 'JDE=SWORKS,'. CHGBR110
|
||||
00200 05 X1-CA-LINE-END PIC X(01) VALUE ';'. CHGBR110
|
||||
00201 CHGBR110
|
||||
00202 01 X1-CA-CNTL-LINE. CHGBR110
|
||||
00203 * 05 X1-CA-FILLER PIC X(01) VALUE SPACE. CHGBR110
|
||||
00204 05 X1-CA-DJDE PIC X(12) VALUE '$X9700$DJDE '. CHGBR110
|
||||
00205 05 X1-CA-FORMS PIC X(13) VALUE 'FORMS=UC244A,'. CHGBR110
|
||||
00206 05 X1-CA-BFORM PIC X(11) VALUE 'BFORM=NONE,'. CHGBR110
|
||||
00207 05 X1-CA-OTEXT PIC X(37) VALUE CHGBR110
|
||||
00208 'OTEXT=(''LOAD NO HOLE WHITE PARER''),;'. CHGBR110
|
||||
00209 CHGBR110
|
||||
00210 01 X2-CA-CNTL-LINE. CHGBR110
|
||||
00211 * 05 X2-CA-FILLER PIC X(01) VALUE SPACE. CHGBR110
|
||||
00212 05 X2-CA-DJDE PIC X(12) VALUE '$X9700$DJDE '. CHGBR110
|
||||
00213 05 X2-CA-DUPLEX PIC X(10) VALUE 'DUPLEX=NO,'. CHGBR110
|
||||
00214 05 X2-CA-FORMAT PIC X(12) VALUE 'FORMAT=FMT7,'. CHGBR110
|
||||
00215 05 X2-CA-FONTS PIC X(13) VALUE 'FONTS=UN210E,'. CHGBR110
|
||||
00216 05 X2-CA-LINE-END PIC X(01) VALUE ';'. CHGBR110
|
||||
00217 CHGBR110
|
||||
00218 01 X3-CA-CNTL-LINE. CHGBR110
|
||||
00219 * 05 X3-CA-FILLER PIC X(01) VALUE SPACE. CHGBR110
|
||||
00220 05 X3-CA-DJDE PIC X(12) VALUE '$X9700$DJDE '. CHGBR110
|
||||
00221 05 X3-CA-DATA PIC X(13) VALUE 'DATA=(0,131),'. CHGBR110
|
||||
00222 05 X3-CA-ASSIGN PIC X(13) VALUE 'ASSIGN=(1,1),'. CHGBR110
|
||||
00223 05 X3-CA-BEGIN PIC X(18) VALUE 'BEGIN=(1.00,0.50),'.CHGBR110
|
||||
00224 05 X3-CA-TOF PIC X(07) VALUE 'TOF=05,'. CHGBR110
|
||||
00225 05 X3-CA-BOF PIC X(07) VALUE 'TOF=62,'. CHGBR110
|
||||
00226 05 X3-CA-LINE-END PIC X(04) VALUE 'END;'. CHGBR110
|
||||
00227 CHGBR110
|
||||
00228 01 BILL-LINE1. CHGBR110
|
||||
00229 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00230 05 FILLER PIC X(29) VALUE SPACES. CHGBR110
|
||||
00231 05 FILLER PIC X(58) VALUE SPACES. CHGBR110
|
||||
00232 05 BILL-END-OF-QTR PIC X(10) VALUE SPACE. CHGBR110
|
||||
00233 CHGBR110
|
||||
00234 01 BILL-LINE2. CHGBR110
|
||||
00235 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00236 05 FILLER PIC X(22) VALUE SPACES. CHGBR110
|
||||
00237 05 BILL-EMP-NO-1 PIC 999B999. CHGBR110
|
||||
00238 05 FILLER PIC X(58) VALUE SPACES. CHGBR110
|
||||
00239 05 BILL-MAILED-DATE PIC X(10) VALUE SPACE. CHGBR110
|
||||
00240 CHGBR110
|
||||
00241 01 BILL-LINE3. CHGBR110
|
||||
00242 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00243 05 BILL-ADDR-LINE1 PIC X(40) VALUE SPACES. CHGBR110
|
||||
00244 CHGBR110
|
||||
00245 01 BILL-LINE4. CHGBR110
|
||||
00246 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00247 05 BILL-ADDR-LINE2 PIC X(40) VALUE SPACES. CHGBR110
|
||||
00248 CHGBR110
|
||||
00249 01 BILL-LINE5. CHGBR110
|
||||
00250 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00251 05 BILL-ADDR-LINE3 PIC X(40) VALUE SPACES. CHGBR110
|
||||
00252 CHGBR110
|
||||
00253 01 BILL-LINE6. CHGBR110
|
||||
00254 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00255 05 BILL-ADDR-LINE4 PIC X(40) VALUE SPACES. CHGBR110
|
||||
00256 CHGBR110
|
||||
00257 01 BILL-LINE7. CHGBR110
|
||||
00258 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00259 05 BILL-ADDR-LINE5 PIC X(40) VALUE SPACES. CHGBR110
|
||||
00260 CHGBR110
|
||||
00261 01 BILL-LINE8. CHGBR110
|
||||
00262 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00263 05 FILLER PIC X(30) VALUE SPACES. CHGBR110
|
||||
00264 05 BILL-TOTAL-DUE PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00265 CHGBR110
|
||||
00266 01 BILL-LINE9. CHGBR110
|
||||
00267 05 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00268 05 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00269 05 BILL-NAME-CHK PIC X(04) VALUE SPACE. CHGBR110
|
||||
00270 05 FILLER PIC X(06) VALUE SPACES. CHGBR110
|
||||
00271 05 BILL-EMP-NO-2 PIC 999B999. CHGBR110
|
||||
00272 05 FILLER PIC X(32) VALUE SPACES. CHGBR110
|
||||
00273 05 BILL-YRQ PIC X(06) VALUE SPACE. CHGBR110
|
||||
00274 CHGBR110
|
||||
00275 01 BILL-LINE10. CHGBR110
|
||||
00276 05 FILLER PIC X(15) VALUE SPACES. CHGBR110
|
||||
00277 05 FILLER PIC X(50) VALUE CHGBR110
|
||||
00278 'YOUR CREDIT HAS BEEN APPLIED TO THE BALANCE DUE'. CHGBR110
|
||||
00279 CHGBR110
|
||||
00280 EJECT CHGBR110
|
||||
00281 01 CHG-DETAIL-HEADER-AREA. CHGBR110
|
||||
00282 05 CHG-DETAIL-HDR1. CHGBR110
|
||||
00283 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00284 10 FILLER PIC X(08) CHGBR110
|
||||
00285 VALUE 'CHGBR110'. CHGBR110
|
||||
00286 10 FILLER PIC X(47) VALUE SPACES. CHGBR110
|
||||
00287 10 FILLER PIC X(20) CHGBR110
|
||||
00288 VALUE 'DISTRICT OF COLUMBIA'. CHGBR110
|
||||
00289 10 FILLER PIC X(43) VALUE SPACES. CHGBR110
|
||||
00290 10 FILLER PIC X(09) CHGBR110
|
||||
00291 VALUE 'PAGE NO.:'. CHGBR110
|
||||
00292 10 CHG-DTL-PAGE-NO PIC ZZZ99. CHGBR110
|
||||
00293 CHGBR110
|
||||
00294 05 CHG-EETAIL-HDR1. CHGBR110
|
||||
00295 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00296 10 FILLER PIC X(08) CHGBR110
|
||||
00297 VALUE 'CHGBR110'. CHGBR110
|
||||
00298 10 FILLER PIC X(04) VALUE SPACES. CHGBR110
|
||||
00299 10 FILLER PIC X(20) CHGBR110
|
||||
00300 VALUE 'DISTRICT OF COLUMBIA'. CHGBR110
|
||||
00301 10 FILLER PIC X(53) VALUE SPACES. CHGBR110
|
||||
00302 05 CHG-EETAIL-HDR2. CHGBR110
|
||||
00303 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00304 10 FILLER PIC X(09) VALUE SPACES. CHGBR110
|
||||
00305 10 E2-RPT-TYPE PIC X(26) CHGBR110
|
||||
00306 VALUE 'SI QUARTLY CHARGE SUMMARY'. CHGBR110
|
||||
00307 10 FILLER PIC X(49) VALUE SPACES. CHGBR110
|
||||
00308 CHGBR110
|
||||
00309 05 CHG-DETAIL-HDR2. CHGBR110
|
||||
00310 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00311 10 FILLER PIC X(10) CHGBR110
|
||||
00312 VALUE ' '. CHGBR110
|
||||
00313 10 FILLER PIC X(42) VALUE SPACES. CHGBR110
|
||||
00314 10 H2-RPT-TYPE PIC X(26) VALUE SPACES. CHGBR110
|
||||
00315 * VALUE 'QUARTERLY CHARGE SUMMARY'. CHGBR110
|
||||
00316 10 FILLER PIC X(49) VALUE SPACES. CHGBR110
|
||||
00317 10 FILLER PIC X(02) VALUE 'TT'. CHGBR110
|
||||
00318 10 CHG-DTL-EMP-TYPE PIC 9(02) VALUE 0. CHGBR110
|
||||
00319 CHGBR110
|
||||
00320 05 CHG-DETAIL-HDR3. CHGBR110
|
||||
00321 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00322 10 FILLER PIC X(08) CHGBR110
|
||||
00323 VALUE 'ROOM 425'. CHGBR110
|
||||
00324 10 FILLER PIC X(37) VALUE SPACES. CHGBR110
|
||||
00325 10 FILLER PIC X(39) CHGBR110
|
||||
00326 VALUE 'DEPARTMENT OF EMPLOYMENT SERVICES'. CHGBR110
|
||||
00327 CHGBR110
|
||||
00328 05 CHG-DETAIL-HDR4. CHGBR110
|
||||
00329 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00330 10 FILLER PIC X(49) VALUE SPACES. CHGBR110
|
||||
00331 10 FILLER PIC X(24) CHGBR110
|
||||
00332 VALUE 'EMPLOYER ACCOUNT NUMBER '. CHGBR110
|
||||
00333 10 CHG-DTL-EMP-NO PIC 9(06) VALUE 0. CHGBR110
|
||||
00334 CHGBR110
|
||||
00335 05 CHG-DETAIL-HDR5. CHGBR110
|
||||
00336 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00337 10 FILLER PIC X(39) VALUE SPACES. CHGBR110
|
||||
00338 10 FILLER PIC X(28) CHGBR110
|
||||
00339 VALUE 'REPORT INCLUDES PERIOD FROM '. CHGBR110
|
||||
00340 10 CHG-DTL-START-DT PIC X(10) VALUE SPACE. CHGBR110
|
||||
00341 10 FILLER PIC X(04) VALUE ' TO '. CHGBR110
|
||||
00342 10 CHG-DTL-END-DT PIC X(10) VALUE SPACE. CHGBR110
|
||||
00343 CHGBR110
|
||||
00344 05 CHG-DETAIL-HDR6. CHGBR110
|
||||
00345 10 FILLER PIC X VALUE SPACE. CHGBR110
|
||||
00346 10 FILLER PIC X(05) VALUE SPACES. CHGBR110
|
||||
00347 10 FILLER PIC X(03) VALUE 'SSN'. CHGBR110
|
||||
00348 10 FILLER PIC X(09) VALUE SPACES. CHGBR110
|
||||
00349 10 FILLER PIC X(03) VALUE 'BYE'. CHGBR110
|
||||
00350 10 FILLER PIC X(09) VALUE SPACES. CHGBR110
|
||||
00351 10 FILLER PIC X(18) CHGBR110
|
||||
00352 VALUE 'NAME OF CLAIMANT'. CHGBR110
|
||||
00353 10 FILLER PIC X(19) VALUE SPACES. CHGBR110
|
||||
00354 10 FILLER PIC X(14) VALUE 'TOTAL BENEFITS'. CHGBR110
|
||||
00355 10 FILLER PIC X(07) VALUE SPACES. CHGBR110
|
||||
00356 10 FILLER PIC X(15) VALUE 'ACCOUNT CHARGES'. CHGBR110
|
||||
00357 10 FILLER PIC X(08) VALUE SPACES. CHGBR110
|
||||
00358 10 FILLER PIC X(11) VALUE 'SOURCE TYPE'. CHGBR110
|
||||
00359 CHGBR110
|
||||
00360 01 CHG-DETAIL-LINE. CHGBR110
|
||||
00361 05 FILLER PIC X(04) VALUE SPACES. CHGBR110
|
||||
00362 05 CHG-DTL-SSN1 PIC X(03) VALUE SPACE. CHGBR110
|
||||
00363 05 FILLER PIC X(01) VALUE '-'. CHGBR110
|
||||
00364 05 CHG-DTL-SSN2 PIC X(02) VALUE SPACE. CHGBR110
|
||||
00365 05 FILLER PIC X(01) VALUE '-'. CHGBR110
|
||||
00366 05 CHG-DTL-SSN3 PIC X(04) VALUE SPACE. CHGBR110
|
||||
00367 05 FILLER PIC X(02) VALUE SPACES. CHGBR110
|
||||
00368 05 CHG-DTL-BYE PIC X(10) VALUE SPACE. CHGBR110
|
||||
00369 05 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00370 05 CHG-DTL-NAME PIC X(32) VALUE SPACE. CHGBR110
|
||||
00371 05 FILLER PIC X(02) VALUE SPACES. CHGBR110
|
||||
00372 05 CHG-DTL-TOT-AMT PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00373 05 FILLER PIC X(04) VALUE SPACES. CHGBR110
|
||||
00374 05 CHG-DTL-CURR-AMT PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00375 05 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00376 05 CHG-DTL-SOURCE PIC X(25) VALUE SPACE. CHGBR110
|
||||
00377 CHGBR110
|
||||
00378 01 CHG-DETAIL-EMP-FOOTER-AREA. CHGBR110
|
||||
00379 05 CHG-DETAIL-EMP-FOOTER1. CHGBR110
|
||||
00380 10 FILLER PIC X(34) VALUE SPACES. CHGBR110
|
||||
00381 10 FILLER PIC X(20) CHGBR110
|
||||
00382 VALUE 'GRAND TOTAL CHARGED:'. CHGBR110
|
||||
00383 10 FILLER PIC X(10) VALUE SPACES. CHGBR110
|
||||
00384 10 CHG-DTL-EMP-TOT-CHG PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00385 10 FILLER PIC X(25) VALUE SPACES. CHGBR110
|
||||
00386 10 FILLER PIC X(25) CHGBR110
|
||||
00387 VALUE ' ************ '. CHGBR110
|
||||
00388 CHGBR110
|
||||
00389 05 CHG-DETAIL-EMP-FOOTER2. CHGBR110
|
||||
00390 10 FILLER PIC X(41) VALUE SPACES. CHGBR110
|
||||
00391 10 FILLER PIC X(28) CHGBR110
|
||||
00392 VALUE 'GRAND TOTAL ACCOUNT CHARGED:'. CHGBR110
|
||||
00393 10 FILLER PIC X(17) VALUE SPACES. CHGBR110
|
||||
00394 10 CHG-DTL-EMP-ACCT-CHG PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00395 10 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00396 10 FILLER PIC X(25) CHGBR110
|
||||
00397 VALUE ' ************ '. CHGBR110
|
||||
00398 CHGBR110
|
||||
00399 01 CHG-DETAIL-RPT-FOOTER-AREA. CHGBR110
|
||||
00400 05 CHG-DETAIL-RPT-FOOTER1. CHGBR110
|
||||
00401 10 FILLER PIC X(65) VALUE SPACES. CHGBR110
|
||||
00402 10 FILLER PIC X(41) CHGBR110
|
||||
00403 VALUE '-----------------------------------------'. CHGBR110
|
||||
00404 CHGBR110
|
||||
00405 05 CHG-DETAIL-RPT-FOOTER2. CHGBR110
|
||||
00406 10 FILLER PIC X(15) VALUE SPACES. CHGBR110
|
||||
00407 10 FILLER PIC X(37) CHGBR110
|
||||
00408 VALUE 'TOTAL AMOUNT CHARGED FOR THE PERIOD: '. CHGBR110
|
||||
00409 10 FILLER PIC X(12) VALUE SPACES. CHGBR110
|
||||
00410 10 CHG-DTL-RPT-TOT-CHG PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00411 10 FILLER PIC X(04) VALUE SPACES. CHGBR110
|
||||
00412 10 CHG-DTL-RPT-ACCT-CHG PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00413 10 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00414 10 FILLER PIC X(25) CHGBR110
|
||||
00415 VALUE ' ************ '. CHGBR110
|
||||
00416 EJECT CHGBR110
|
||||
00417 01 CHG-DETAIL-REC. CHGBR110
|
||||
00418 10 FILLER PIC X(01) VALUE SPACES. CHGBR110
|
||||
00419 10 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00420 10 DET-EMP-NO-1 PIC 999999. CHGBR110
|
||||
00421 10 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00422 10 DET-NAME-CHK PIC X(15) VALUE SPACE. CHGBR110
|
||||
00423 10 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00424 10 DET-YRQ PIC X(06) VALUE SPACE. CHGBR110
|
||||
00425 10 FILLER PIC X(03) VALUE SPACES. CHGBR110
|
||||
00426 10 DET-TOTAL-DUE PIC $$,$$$,$$$,$$9.99-. CHGBR110
|
||||
00427 10 FILLER PIC X(72) VALUE SPACES. CHGBR110
|
||||
00428 CHGBR110
|
||||
00429 01 L001-LINK-AREA. CHGBR110
|
||||
00430 ++INCLUDE DTSIL001 CHGBR110
|
||||
00431 EJECT CHGBR110
|
||||
00432 01 L003-LINK-AREA. CHGBR110
|
||||
00433 ++INCLUDE DTSIL003 CHGBR110
|
||||
00434 EJECT CHGBR110
|
||||
00435 01 L004-LINK-AREA. CHGBR110
|
||||
00436 ++INCLUDE DTSIL004 CHGBR110
|
||||
00437 EJECT CHGBR110
|
||||
00438 01 L005-LINK-AREA. CHGBR110
|
||||
00439 ++INCLUDE DTSIL005 CHGBR110
|
||||
00440 EJECT CHGBR110
|
||||
00441 01 L910-LINK-AREA. CHGBR110
|
||||
00442 ++INCLUDE DTSIL910 CHGBR110
|
||||
00443 CHGBR110
|
||||
00444 01 MSKL-REC. CHGBR110
|
||||
00445 ++INCLUDE DTSIMSKL CHGBR110
|
||||
00446 CHGBR110
|
||||
00447 01 MQTR-REC. CHGBR110
|
||||
00448 ++INCLUDE DTSIMQTR CHGBR110
|
||||
00449 CHGBR110
|
||||
00450 LINKAGE SECTION. CHGBR110
|
||||
00451 01 CHG-LINK-REC. CHGBR110
|
||||
00452 ++INCLUDE CHGIL001 CHGBR110
|
||||
00453 EJECT CHGBR110
|
||||
00454 01 BD210-CHG-REC. CHGBR110
|
||||
00455 ++INCLUDE CHGIM004 CHGBR110
|
||||
00456 EJECT CHGBR110
|
||||
00457 PROCEDURE DIVISION USING CHG-LINK-REC CHGBR110
|
||||
00458 BD210-CHG-REC. CHGBR110
|
||||
00459 CHGBR110
|
||||
00460 CHGBR110-MAIN. CHGBR110
|
||||
00461 IF CHG-LINK1-CMD-INIT-88 CHGBR110
|
||||
00462 PERFORM I0000-INITIATE THRU I0000-EXIT CHGBR110
|
||||
00463 ELSE CHGBR110
|
||||
00464 IF CHG-LINK1-CMD-PROCESS-88 CHGBR110
|
||||
00465 PERFORM P0000-PROCESS THRU P0000-EXIT CHGBR110
|
||||
00466 ELSE CHGBR110
|
||||
00467 IF CHG-LINK1-CMD-CLOSE-88 CHGBR110
|
||||
00468 PERFORM T0000-TERMINATE THRU T0000-EXIT CHGBR110
|
||||
00469 ELSE CHGBR110
|
||||
00470 MOVE 'INVALID CHG-LINK1-COMMAND VALUE' CHGBR110
|
||||
00471 TO ABEND-MSG CHGBR110
|
||||
00472 PERFORM S999-ABEND THRU S999-EXIT CHGBR110
|
||||
00473 END-IF CHGBR110
|
||||
00474 END-IF CHGBR110
|
||||
00475 END-IF. CHGBR110
|
||||
00476 CHGBR110
|
||||
00477 GOBACK. CHGBR110
|
||||
00478 EJECT CHGBR110
|
||||
00479 I0000-INITIATE. CHGBR110
|
||||
00480 *& CHGBR110
|
||||
00481 * DISPLAY 'BR110 INIT - STEP = ' CHG-LINK1-SELF-INS-STEP. CHGBR110
|
||||
00482 *& CHGBR110
|
||||
00483 MOVE ZERO TO CHGBR110
|
||||
00484 CHGBR110
|
||||
00485 WRK-PAGE-CNT CHGBR110
|
||||
00486 WRK-EMP-TOT-CHG CHGBR110
|
||||
00487 WRK-EMP-ACCT-CHG CHGBR110
|
||||
00488 WRK-RPT-TOT-CHG CHGBR110
|
||||
00489 WRK-RPT-ACCT-CHG. CHGBR110
|
||||
00490 CHGBR110
|
||||
00491 IF CHG-LINK1-RUN-TYPE-SPC-88 CHGBR110
|
||||
00492 OR CHG-LINK1-RUN-TYPE-RPTS-88 CHGBR110
|
||||
00493 OR CHG-LINK1-RUN-TYPE-AGTS-88 CHGBR110
|
||||
00494 MOVE WRK-RPT-TYPE2 TO H2-RPT-TYPE CHGBR110
|
||||
00495 ELSE MOVE WRK-RPT-TYPE1 TO H2-RPT-TYPE CHGBR110
|
||||
00496 END-IF. CHGBR110
|
||||
00497 CHGBR110
|
||||
00498 MOVE CHG-LINK1-PERIOD-BEGIN TO L001-FED-8-DATE-9. CHGBR110
|
||||
00499 SET L001-FROM-FED-8 TO TRUE. CHGBR110
|
||||
00500 CALL 'DTSBU001' USING L001-LINK-AREA. CHGBR110
|
||||
00501 MOVE L001-SLASH-8-DATE TO CHG-DTL-START-DT. CHGBR110
|
||||
00502 CHGBR110
|
||||
00503 MOVE CHG-LINK1-PERIOD-END TO L001-FED-8-DATE-9. CHGBR110
|
||||
00504 SET L001-FROM-FED-8 TO TRUE. CHGBR110
|
||||
00505 CALL 'DTSBU001' USING L001-LINK-AREA. CHGBR110
|
||||
00506 MOVE L001-SLASH-8-DATE TO CHG-DTL-END-DT CHGBR110
|
||||
00507 BILL-END-OF-QTR. CHGBR110
|
||||
00508 CHGBR110
|
||||
00509 MOVE CHG-LINK1-PERIOD-END TO L004-DATE. CHGBR110
|
||||
00510 SET L004-FROM-DATE TO TRUE. CHGBR110
|
||||
00511 CALL 'DTSBU004' USING L004-LINK-AREA. CHGBR110
|
||||
00512 MOVE L004-SLASH-5-QTR TO BILL-YRQ DET-YRQ. CHGBR110
|
||||
00513 CHGBR110
|
||||
00514 SET L005-FROM-SYS TO TRUE. CHGBR110
|
||||
00515 CALL 'DTSBU005' USING L005-LINK-AREA. CHGBR110
|
||||
00516 CHGBR110
|
||||
00517 MOVE L005-DATE-8-YR TO WRK-MAIL-YY. CHGBR110
|
||||
00518 MOVE L005-DATE-8-MO TO WRK-MAIL-MM. CHGBR110
|
||||
00519 MOVE L005-DATE-8-DA TO WRK-MAIL-DD. CHGBR110
|
||||
00520 CHGBR110
|
||||
00521 MOVE WRK-MAIL-DATE TO L001-FED-8-DATE-9 CHGBR110
|
||||
00522 CHGBR110
|
||||
00523 SET L001-FROM-FED-8 TO TRUE. CHGBR110
|
||||
00524 CALL 'DTSBU001' USING L001-LINK-AREA. CHGBR110
|
||||
00525 CHGBR110
|
||||
00526 ADD +4 TO L001-JUL-ABS-DAY CHGBR110
|
||||
00527 CHGBR110
|
||||
00528 SET L001-FROM-ABS-DAY TO TRUE. CHGBR110
|
||||
00529 CALL 'DTSBU001' USING L001-LINK-AREA. CHGBR110
|
||||
00530 CHGBR110
|
||||
00531 IF L001-VALID-DATE CHGBR110
|
||||
00532 MOVE L001-FED-8-DATE-9 TO L003-DATE CHGBR110
|
||||
00533 SET L003-AGENCY-DAY TO TRUE CHGBR110
|
||||
00534 CALL 'DTSBU003' USING L003-LINK-AREA CHGBR110
|
||||
00535 PERFORM P2110-DATE-LOOP THRU P2110-EXIT CHGBR110
|
||||
00536 UNTIL L003-IS-WORK-DAY CHGBR110
|
||||
00537 MOVE L001-SLASH-8-DATE TO BILL-MAILED-DATE. CHGBR110
|
||||
00538 CHGBR110
|
||||
00539 IF CHG-LINK1-SELF-INS-STEP2-88 CHGBR110
|
||||
00540 PERFORM S910-OPEN-READ THRU S910-EXIT CHGBR110
|
||||
00541 END-IF. CHGBR110
|
||||
00542 CHGBR110
|
||||
00543 OPEN OUTPUT SELF-INS-RPT. CHGBR110
|
||||
00544 OPEN OUTPUT SELF-INS-DET. CHGBR110
|
||||
00545 WRITE SELF-DET-REC FROM CHG-EETAIL-HDR1 AFTER CHGBR110
|
||||
00546 ADVANCING TOP-OF-PAGE. CHGBR110
|
||||
00547 WRITE SELF-DET-REC FROM CHG-EETAIL-HDR2 AFTER 1. CHGBR110
|
||||
00548 CHGBR110
|
||||
00549 IF CHG-LINK1-RUN-TYPE-SPC-88 CHGBR110
|
||||
00550 OR CHG-LINK1-RUN-TYPE-RPTS-88 CHGBR110
|
||||
00551 OR CHG-LINK1-RUN-TYPE-AGTS-88 CHGBR110
|
||||
00552 NEXT SENTENCE CHGBR110
|
||||
00553 ELSE CHGBR110
|
||||
00554 OPEN OUTPUT SELF-INS-BILL CHGBR110
|
||||
00555 WRITE SELF-BILL-REC FROM XF-CA-CNTL-LINE CHGBR110
|
||||
00556 AFTER ADVANCING TOP-OF-PAGE CHGBR110
|
||||
00557 WRITE SELF-BILL-REC FROM X1-CA-CNTL-LINE CHGBR110
|
||||
00558 WRITE SELF-BILL-REC FROM X2-CA-CNTL-LINE CHGBR110
|
||||
00559 WRITE SELF-BILL-REC FROM X3-CA-CNTL-LINE CHGBR110
|
||||
00560 END-IF. CHGBR110
|
||||
00561 CHGBR110
|
||||
00562 I0000-EXIT. CHGBR110
|
||||
00563 EXIT. CHGBR110
|
||||
00564 EJECT CHGBR110
|
||||
00565 P2110-DATE-LOOP. CHGBR110
|
||||
00566 MOVE L001-FED-8-DATE-9 TO L003-DATE. CHGBR110
|
||||
00567 CHGBR110
|
||||
00568 SET L003-AGENCY-DAY TO TRUE CHGBR110
|
||||
00569 CALL 'DTSBU003' USING L003-LINK-AREA CHGBR110
|
||||
00570 IF L003-IS-WORK-DAY CHGBR110
|
||||
00571 GO TO P2110-EXIT. CHGBR110
|
||||
00572 CHGBR110
|
||||
00573 ADD +1 TO L001-JUL-ABS-DAY. CHGBR110
|
||||
00574 SET L001-FROM-ABS-DAY TO TRUE. CHGBR110
|
||||
00575 CALL 'DTSBU001' USING L001-LINK-AREA. CHGBR110
|
||||
00576 CHGBR110
|
||||
00577 P2110-EXIT. CHGBR110
|
||||
00578 EXIT. CHGBR110
|
||||
00579 P0000-PROCESS. CHGBR110
|
||||
00580 IF CHG4-EMP-NO = 318633 AND CHG4-SSN = 171629741 OR CL**2
|
||||
00581 CHG4-SSN = 239632420 OR CL**2
|
||||
00582 CHG4-SSN = 577197421 CL**2
|
||||
00583 DISPLAY ' FAKE SSN ' CHG4-SSN CL**2
|
||||
00584 GO TO P0000-EXIT. CL**2
|
||||
00585 IF CHG4-EMP-NO NOT = WRK-CURR-EMP CL**2
|
||||
00586 IF WRK-CURR-EMP = ZERO CHGBR110
|
||||
00587 *** 1ST TIME CHGBR110
|
||||
00588 MOVE CHG4-EMP-NO TO WRK-CURR-EMP CHGBR110
|
||||
00589 CHG-DTL-EMP-NO CHGBR110
|
||||
00590 MOVE CHG4-EMP-TYPE TO CHG-DTL-EMP-TYPE CHGBR110
|
||||
00591 ADD 1 TO WRK-EMPLYR-CNT CHGBR110
|
||||
00592 PERFORM P1000-PRINT-HEADER THRU P1000-EXIT CHGBR110
|
||||
00593 PERFORM P4000-INIT-BILL THRU P4000-EXIT CHGBR110
|
||||
00594 ELSE CHGBR110
|
||||
00595 *** NEW ONE CHGBR110
|
||||
00596 PERFORM P2000-EMP-COMPLETE THRU P2000-EXIT CHGBR110
|
||||
00597 MOVE CHG4-EMP-NO TO WRK-CURR-EMP CHGBR110
|
||||
00598 CHG-DTL-EMP-NO CHGBR110
|
||||
00599 MOVE CHG4-EMP-TYPE TO CHG-DTL-EMP-TYPE CHGBR110
|
||||
00600 ADD 1 TO WRK-EMPLYR-CNT CHGBR110
|
||||
00601 PERFORM P1000-PRINT-HEADER THRU P1000-EXIT CHGBR110
|
||||
00602 PERFORM P4000-INIT-BILL THRU P4000-EXIT CHGBR110
|
||||
00603 END-IF CHGBR110
|
||||
00604 ELSE CHGBR110
|
||||
00605 *** SAME ONE CHGBR110
|
||||
00606 IF WRK-LINE-CNT > +54 CHGBR110
|
||||
00607 PERFORM P1000-PRINT-HEADER THRU P1000-EXIT CHGBR110
|
||||
00608 END-IF CHGBR110
|
||||
00609 END-IF. CHGBR110
|
||||
00610 CHGBR110
|
||||
00611 PERFORM P3000-BUILD-CHG-DETAIL THRU P3000-EXIT. CHGBR110
|
||||
00612 CHGBR110
|
||||
00613 *& IF CHG4-OP-RECOVER-AMT > +0 CHGBR110
|
||||
00614 *& MOVE SPACES TO EI-SPACES CHGBR110
|
||||
00615 *& MOVE CHG4-OP-RECOVER-AMT TO EI-CURR-AMT CHGBR110
|
||||
00616 *& MOVE ' OVERPAYMENTS COLLECTED' TO EI-BENNIE CHGBR110
|
||||
00617 *& PERFORM P2000-WRITE-RPT CHGBR110
|
||||
00618 *& THRU P2000-EXIT. CHGBR110
|
||||
00619 CHGBR110
|
||||
00620 P0000-EXIT. CHGBR110
|
||||
00621 EXIT. CHGBR110
|
||||
00622 EJECT CHGBR110
|
||||
00623 P1000-PRINT-HEADER. CHGBR110
|
||||
00624 ADD +1 TO WRK-PAGE-CNT. CHGBR110
|
||||
00625 MOVE WRK-PAGE-CNT TO CHG-DTL-PAGE-NO. CHGBR110
|
||||
00626 CHGBR110
|
||||
00627 WRITE SELF-RPT-REC FROM CHG-DETAIL-HDR1 CHGBR110
|
||||
00628 AFTER ADVANCING TOP-OF-PAGE. CHGBR110
|
||||
00629 WRITE SELF-RPT-REC FROM CHG-DETAIL-HDR2 CHGBR110
|
||||
00630 AFTER ADVANCING 1 LINE. CHGBR110
|
||||
00631 WRITE SELF-RPT-REC FROM CHG-DETAIL-HDR3 CHGBR110
|
||||
00632 AFTER ADVANCING 1 LINE. CHGBR110
|
||||
00633 WRITE SELF-RPT-REC FROM CHG-DETAIL-HDR4 CHGBR110
|
||||
00634 AFTER ADVANCING 2 LINES. CHGBR110
|
||||
00635 WRITE SELF-RPT-REC FROM CHG-DETAIL-HDR5 CHGBR110
|
||||
00636 AFTER ADVANCING 2 LINES. CHGBR110
|
||||
00637 WRITE SELF-RPT-REC FROM CHG-DETAIL-HDR6 CHGBR110
|
||||
00638 AFTER ADVANCING 2 LINES. CHGBR110
|
||||
00639 MOVE SPACE TO SELF-RPT-REC. CHGBR110
|
||||
00640 WRITE SELF-RPT-REC AFTER ADVANCING 1 LINES. CHGBR110
|
||||
00641 CHGBR110
|
||||
00642 MOVE +10 TO WRK-LINE-CNT. CHGBR110
|
||||
00643 P1000-EXIT. CHGBR110
|
||||
00644 EXIT. CHGBR110
|
||||
00645 CHGBR110
|
||||
00646 P2000-EMP-COMPLETE. CHGBR110
|
||||
00647 PERFORM P2100-CHG-DTL-FOOTER THRU P2100-EXIT. CHGBR110
|
||||
00648 PERFORM P2200-GENERATE-BILL THRU P2200-EXIT. CHGBR110
|
||||
00649 CHGBR110
|
||||
00650 MOVE ZERO TO WRK-EMP-TOT-CHG CHGBR110
|
||||
00651 WRK-EMP-ACCT-CHG. CHGBR110
|
||||
00652 CHGBR110
|
||||
00653 P2000-EXIT. CHGBR110
|
||||
00654 EXIT. CHGBR110
|
||||
00655 CHGBR110
|
||||
00656 P2100-CHG-DTL-FOOTER. CHGBR110
|
||||
00657 IF WRK-PAGE-CNT > +48 CHGBR110
|
||||
00658 PERFORM P1000-PRINT-HEADER THRU P1000-EXIT CHGBR110
|
||||
00659 END-IF. CHGBR110
|
||||
00660 CHGBR110
|
||||
00661 MOVE WRK-EMP-TOT-CHG TO CHG-DTL-EMP-TOT-CHG. CHGBR110
|
||||
00662 MOVE WRK-EMP-ACCT-CHG TO CHG-DTL-EMP-ACCT-CHG. CHGBR110
|
||||
00663 MOVE +0 TO WRK-PAGE-CNT. CHGBR110
|
||||
00664 CHGBR110
|
||||
00665 WRITE SELF-RPT-REC FROM CHG-DETAIL-EMP-FOOTER1 CHGBR110
|
||||
00666 AFTER ADVANCING 4 LINES. CHGBR110
|
||||
00667 CHGBR110
|
||||
00668 WRITE SELF-RPT-REC FROM CHG-DETAIL-EMP-FOOTER2 CHGBR110
|
||||
00669 AFTER ADVANCING 2 LINES. CHGBR110
|
||||
00670 CHGBR110
|
||||
00671 P2100-EXIT. CHGBR110
|
||||
00672 EXIT. CHGBR110
|
||||
00673 CHGBR110
|
||||
00674 P2200-GENERATE-BILL. CHGBR110
|
||||
00675 CHGBR110
|
||||
00676 IF CHG-LINK1-RUN-TYPE-SPC-88 CHGBR110
|
||||
00677 OR CHG-LINK1-RUN-TYPE-RPTS-88 CHGBR110
|
||||
00678 OR CHG-LINK1-RUN-TYPE-AGTS-88 CHGBR110
|
||||
00679 GO TO P2200-EXIT. CHGBR110
|
||||
00680 CHGBR110
|
||||
00681 IF CHG-LINK1-SELF-INS-STEP2-88 CHGBR110
|
||||
00682 IF WRK-EMP-ACCT-CHG < ZERO CHGBR110
|
||||
00683 GO TO P2200-EXIT CHGBR110
|
||||
00684 END-IF CHGBR110
|
||||
00685 END-IF. CHGBR110
|
||||
00686 CHGBR110
|
||||
00687 MOVE SPACES TO VSCA-DATA. CHGBR110
|
||||
00688 WRITE SELF-BILL-REC FROM VSCA-DATA CHGBR110
|
||||
00689 AFTER ADVANCING TOP-OF-PAGE. CHGBR110
|
||||
00690 CHGBR110
|
||||
00691 MOVE BILL-LINE1 TO VSCA-DATA. CHGBR110
|
||||
00692 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00693 AFTER ADVANCING 11 LINES. CHGBR110
|
||||
00694 CHGBR110
|
||||
00695 MOVE BILL-LINE2 TO VSCA-DATA. CHGBR110
|
||||
00696 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00697 AFTER ADVANCING 02 LINES. CHGBR110
|
||||
00698 CHGBR110
|
||||
00699 MOVE BILL-LINE3 TO VSCA-DATA. CHGBR110
|
||||
00700 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00701 AFTER ADVANCING 03 LINES. CHGBR110
|
||||
00702 CHGBR110
|
||||
00703 MOVE BILL-LINE4 TO VSCA-DATA. CHGBR110
|
||||
00704 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00705 AFTER ADVANCING 1 LINES. CHGBR110
|
||||
00706 CHGBR110
|
||||
00707 MOVE BILL-LINE5 TO VSCA-DATA. CHGBR110
|
||||
00708 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00709 AFTER ADVANCING 1 LINES. CHGBR110
|
||||
00710 CHGBR110
|
||||
00711 MOVE BILL-LINE6 TO VSCA-DATA. CHGBR110
|
||||
00712 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00713 AFTER ADVANCING 1 LINES. CHGBR110
|
||||
00714 CHGBR110
|
||||
00715 MOVE BILL-LINE7 TO VSCA-DATA. CHGBR110
|
||||
00716 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00717 AFTER ADVANCING 1 LINE. CHGBR110
|
||||
00718 CHGBR110
|
||||
00719 IF CHG-LINK1-SELF-INS-STEP1-88 CHGBR110
|
||||
00720 MOVE WRK-EMP-ACCT-CHG TO BILL-TOTAL-DUE CHGBR110
|
||||
00721 DET-TOTAL-DUE CHGBR110
|
||||
00722 ELSE CHGBR110
|
||||
00723 ** IF WRK-EMP-ACCT-CHG < ZERO CHGBR110
|
||||
00724 ** MOVE WRK-EMP-ACCT-CHG TO BILL-TOTAL-DUE CHGBR110
|
||||
00725 ** ELSE CHGBR110
|
||||
00726 PERFORM P2210-READ-TAX THRU P2210-EXIT CHGBR110
|
||||
00727 MOVE WRK-MQTR-BAL TO BILL-TOTAL-DUE CHGBR110
|
||||
00728 DET-TOTAL-DUE CHGBR110
|
||||
00729 ** END-IF CHGBR110
|
||||
00730 END-IF. CHGBR110
|
||||
00731 MOVE BILL-LINE8 TO VSCA-DATA. CHGBR110
|
||||
00732 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00733 AFTER ADVANCING 13 LINES. CHGBR110
|
||||
00734 CHGBR110
|
||||
00735 MOVE BILL-LINE9 TO VSCA-DATA. CHGBR110
|
||||
00736 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00737 AFTER ADVANCING 20 LINES. CHGBR110
|
||||
00738 CHGBR110
|
||||
00739 IF WRK-EMP-ACCT-CHG > WRK-MQTR-BAL CHGBR110
|
||||
00740 MOVE BILL-LINE10 TO VSCA-DATA CHGBR110
|
||||
00741 WRITE SELF-BILL-REC FROM VSCA-LINE CHGBR110
|
||||
00742 AFTER ADVANCING 03 LINES CHGBR110
|
||||
00743 END-IF. CHGBR110
|
||||
00744 CHGBR110
|
||||
00745 WRITE SELF-DET-REC FROM CHG-DETAIL-REC. CHGBR110
|
||||
00746 CHGBR110
|
||||
00747 P2200-EXIT. CHGBR110
|
||||
00748 EXIT. CHGBR110
|
||||
00749 CHGBR110
|
||||
00750 P2210-READ-TAX. CHGBR110
|
||||
00751 *& CHGBR110
|
||||
00752 * MOVE WRK-EMP-ACCT-CHG TO AMT-DISP1. CHGBR110
|
||||
00753 * DISPLAY 'BR110 ' WRK-CURR-EMP ' ' BILL-EMP-NO-1 CHGBR110
|
||||
00754 * ' WRK ' AMT-DISP1. CHGBR110
|
||||
00755 *& CHGBR110
|
||||
00756 MOVE ZERO TO WRK-MQTR-BAL. CHGBR110
|
||||
00757 MOVE LOW-VALUES TO MQTR-KEY-AREA. CHGBR110
|
||||
00758 CHGBR110
|
||||
00759 MOVE CHG-LINK1-PERIOD-BEGIN TO L004-DATE. CHGBR110
|
||||
00760 PERFORM S004-FROM-DATE THRU S004-EXIT. CHGBR110
|
||||
00761 CHGBR110
|
||||
00762 MOVE WRK-CURR-EMP TO MQTR-EMP-NO. CHGBR110
|
||||
00763 SET MQTR-QTR-88 TO TRUE. CHGBR110
|
||||
00764 MOVE L004-QTR-5-9 TO MQTR-YRQ. CHGBR110
|
||||
00765 MOVE MQTR-KEY-AREA TO MSKL-KEY-AREA. CHGBR110
|
||||
00766 PERFORM S910-READ THRU S910-EXIT. CHGBR110
|
||||
00767 IF L910-OK-88 CHGBR110
|
||||
00768 MOVE MSKL-REC TO MQTR-REC CHGBR110
|
||||
00769 PERFORM CHGBR110
|
||||
00770 VARYING MQTR-ACCT-IDX FROM +1 BY +1 CHGBR110
|
||||
00771 UNTIL MQTR-ACCT-IDX > MQTR-ACCT-CNT CHGBR110
|
||||
00772 IF MQTR-ACCT-UI-88 (MQTR-ACCT-IDX) CHGBR110
|
||||
00773 ADD MQTR-BALANCE-AMT (MQTR-ACCT-IDX) CHGBR110
|
||||
00774 TO WRK-MQTR-BAL CHGBR110
|
||||
00775 END-IF CHGBR110
|
||||
00776 END-PERFORM CHGBR110
|
||||
00777 END-IF. CHGBR110
|
||||
00778 CHGBR110
|
||||
00779 *& CHGBR110
|
||||
00780 * MOVE WRK-MQTR-BAL TO AMT-DISP2. CHGBR110
|
||||
00781 * DISPLAY 'BR110 MQTR ' AMT-DISP2 CHGBR110
|
||||
00782 * ' ' MQTR-YRQ. CHGBR110
|
||||
00783 *& CHGBR110
|
||||
00784 P2210-EXIT. CHGBR110
|
||||
00785 EXIT. CHGBR110
|
||||
00786 CHGBR110
|
||||
00787 P3000-BUILD-CHG-DETAIL. CHGBR110
|
||||
00788 MOVE CHG4-SSN TO WRK-SSN. CHGBR110
|
||||
00789 * MOVE WRK-SSN1 TO CHG-DTL-SSN1. CL**3
|
||||
00790 * MOVE WRK-SSN2 TO CHG-DTL-SSN2. CL**3
|
||||
00791 MOVE WRK-SSN3 TO CHG-DTL-SSN3. CHGBR110
|
||||
00792 MOVE '###' TO CHG-DTL-SSN1. CL**3
|
||||
00793 MOVE '**' TO CHG-DTL-SSN2. CL**3
|
||||
00794 CHGBR110
|
||||
00795 MOVE CHG4-CLMNT-NAME TO CHG-DTL-NAME. CHGBR110
|
||||
00796 CHGBR110
|
||||
00797 MOVE CHG4-BYE TO L001-FED-8-DATE-9. CHGBR110
|
||||
00798 SET L001-FROM-FED-8 TO TRUE. CHGBR110
|
||||
00799 CALL 'DTSBU001' USING L001-LINK-AREA. CHGBR110
|
||||
00800 MOVE L001-SLASH-8-DATE TO CHG-DTL-BYE. CHGBR110
|
||||
00801 CHGBR110
|
||||
00802 EVALUATE TRUE CHGBR110
|
||||
00803 WHEN CHG4-PROG-UI CHGBR110
|
||||
00804 MOVE WRK-REG-BENEFITS TO CHG-DTL-SOURCE CHGBR110
|
||||
00805 CHGBR110
|
||||
00806 WHEN CHG4-PROG-EB CHGBR110
|
||||
00807 MOVE WRK-EXT-BENEFITS TO CHG-DTL-SOURCE CHGBR110
|
||||
00808 CHGBR110
|
||||
00809 WHEN CHG4-PROG-TEUC CHGBR110
|
||||
00810 MOVE WRK-TEUC-BENEFITS TO CHG-DTL-SOURCE CHGBR110
|
||||
00811 CHGBR110
|
||||
00812 WHEN CHG4-PROG-TEUCA CHGBR110
|
||||
00813 MOVE WRK-TEUCA-BEN-PAYMENT TO CHG-DTL-SOURCE CHGBR110
|
||||
00814 CHGBR110
|
||||
00815 WHEN CHG4-PROG-FAC CHGBR110
|
||||
00816 MOVE WRK-FAC-BEN-PAYMENT TO CHG-DTL-SOURCE CHGBR110
|
||||
00817 CHGBR110
|
||||
00818 WHEN OTHER CHGBR110
|
||||
00819 MOVE ' UNKNOWN ' TO CHG-DTL-SOURCE CHGBR110
|
||||
00820 END-EVALUATE. CHGBR110
|
||||
00821 CHGBR110
|
||||
00822 COMPUTE WRK-TOT-AMT = CHGBR110
|
||||
00823 CHG4-TOT-BEN-AMT + CHGBR110
|
||||
00824 CHG4-TOT-ADJ-AMT. CHGBR110
|
||||
00825 MOVE WRK-TOT-AMT TO CHG-DTL-TOT-AMT. CHGBR110
|
||||
00826 CHGBR110
|
||||
00827 COMPUTE WRK-CURR-AMT = CHGBR110
|
||||
00828 CHG4-CURR-BEN-AMT + CHGBR110
|
||||
00829 CHG4-CURR-ADJ-AMT. CHGBR110
|
||||
00830 MOVE WRK-CURR-AMT TO CHG-DTL-CURR-AMT. CHGBR110
|
||||
00831 CHGBR110
|
||||
00832 IF WRK-CURR-AMT NOT = ZEROS CHGBR110
|
||||
00833 WRITE SELF-RPT-REC FROM CHG-DETAIL-LINE CHGBR110
|
||||
00834 AFTER ADVANCING 1 LINE CHGBR110
|
||||
00835 ADD +1 TO WRK-LINE-CNT CHGBR110
|
||||
00836 PERFORM P3900-TOTALS THRU P3900-EXIT CHGBR110
|
||||
00837 END-IF. CHGBR110
|
||||
00838 CHGBR110
|
||||
00839 P3000-EXIT. CHGBR110
|
||||
00840 EXIT. CHGBR110
|
||||
00841 CHGBR110
|
||||
00842 P3900-TOTALS. CHGBR110
|
||||
00843 COMPUTE WRK-EMP-ACCT-CHG = CHGBR110
|
||||
00844 WRK-EMP-ACCT-CHG + CHGBR110
|
||||
00845 CHG4-CURR-BEN-AMT + CHGBR110
|
||||
00846 CHG4-CURR-ADJ-AMT. CHGBR110
|
||||
00847 CHGBR110
|
||||
00848 COMPUTE WRK-RPT-ACCT-CHG = CHGBR110
|
||||
00849 WRK-RPT-ACCT-CHG + CHGBR110
|
||||
00850 CHG4-CURR-BEN-AMT + CHGBR110
|
||||
00851 CHG4-CURR-ADJ-AMT. CHGBR110
|
||||
00852 CHGBR110
|
||||
00853 COMPUTE WRK-EMP-TOT-CHG = CHGBR110
|
||||
00854 WRK-EMP-TOT-CHG + CHGBR110
|
||||
00855 CHG4-TOT-BEN-AMT + CHGBR110
|
||||
00856 CHG4-TOT-ADJ-AMT. CHGBR110
|
||||
00857 CHGBR110
|
||||
00858 COMPUTE WRK-RPT-TOT-CHG = CHGBR110
|
||||
00859 WRK-RPT-TOT-CHG + CHGBR110
|
||||
00860 CHG4-TOT-BEN-AMT + CHGBR110
|
||||
00861 CHG4-TOT-ADJ-AMT. CHGBR110
|
||||
00862 CHGBR110
|
||||
00863 P3900-EXIT. CHGBR110
|
||||
00864 EXIT. CHGBR110
|
||||
00865 CHGBR110
|
||||
00866 P4000-INIT-BILL. CHGBR110
|
||||
00867 MOVE CHG4-EMP-NO TO BILL-EMP-NO-1 CHGBR110
|
||||
00868 BILL-EMP-NO-2 CHGBR110
|
||||
00869 DET-EMP-NO-1. CHGBR110
|
||||
00870 CHGBR110
|
||||
00871 MOVE CHG4-FMT-LINE (1) TO BILL-ADDR-LINE1. CHGBR110
|
||||
00872 MOVE CHG4-FMT-LINE (2) TO BILL-ADDR-LINE2. CHGBR110
|
||||
00873 MOVE CHG4-FMT-LINE (3) TO BILL-ADDR-LINE3. CHGBR110
|
||||
00874 MOVE CHG4-FMT-LINE (4) TO BILL-ADDR-LINE4. CHGBR110
|
||||
00875 MOVE CHG4-FMT-LINE (5) TO BILL-ADDR-LINE5. CHGBR110
|
||||
00876 CHGBR110
|
||||
00877 CHGBR110
|
||||
00878 IF CHG4-FMT-LINE (1) > SPACES CHGBR110
|
||||
00879 MOVE CHG4-FMT-LINE (1) TO DET-NAME-CHK CHGBR110
|
||||
00880 ELSE CHGBR110
|
||||
00881 IF CHG4-FMT-LINE (2) > SPACES CHGBR110
|
||||
00882 MOVE CHG4-FMT-LINE (2) TO DET-NAME-CHK CHGBR110
|
||||
00883 ELSE CHGBR110
|
||||
00884 IF CHG4-FMT-LINE (3) > SPACES CHGBR110
|
||||
00885 MOVE CHG4-FMT-LINE (3) TO DET-NAME-CHK CHGBR110
|
||||
00886 ELSE CHGBR110
|
||||
00887 MOVE CHG4-EMP-NAME-CHK TO BILL-NAME-CHK. CHGBR110
|
||||
00888 CHGBR110
|
||||
00889 CHGBR110
|
||||
00890 P4000-EXIT. CHGBR110
|
||||
00891 EXIT. CHGBR110
|
||||
00892 CHGBR110
|
||||
00893 EJECT CHGBR110
|
||||
00894 T0000-TERMINATE. CHGBR110
|
||||
00895 IF WRK-EMPLYR-CNT > 0 CHGBR110
|
||||
00896 PERFORM P2000-EMP-COMPLETE THRU P2000-EXIT CHGBR110
|
||||
00897 END-IF CHGBR110
|
||||
00898 CHGBR110
|
||||
00899 IF WRK-EMPLYR-CNT > 1 CHGBR110
|
||||
00900 PERFORM T1000-FINAL-TOTALS THRU T1000-EXIT CHGBR110
|
||||
00901 END-IF CHGBR110
|
||||
00902 CHGBR110
|
||||
00903 CLOSE SELF-INS-RPT. CHGBR110
|
||||
00904 CLOSE SELF-INS-DET. CHGBR110
|
||||
00905 CHGBR110
|
||||
00906 IF CHG-LINK1-RUN-TYPE-SPC-88 CHGBR110
|
||||
00907 OR CHG-LINK1-RUN-TYPE-RPTS-88 CHGBR110
|
||||
00908 OR CHG-LINK1-RUN-TYPE-AGTS-88 CHGBR110
|
||||
00909 GO TO T0000-EXIT CHGBR110
|
||||
00910 ELSE CHGBR110
|
||||
00911 CLOSE SELF-INS-BILL CHGBR110
|
||||
00912 END-IF. CHGBR110
|
||||
00913 CHGBR110
|
||||
00914 IF CHG-LINK1-SELF-INS-STEP2-88 CHGBR110
|
||||
00915 PERFORM S910-CLOSE THRU S910-EXIT CHGBR110
|
||||
00916 END-IF. CHGBR110
|
||||
00917 CHGBR110
|
||||
00918 T0000-EXIT. CHGBR110
|
||||
00919 EXIT. CHGBR110
|
||||
00920 CHGBR110
|
||||
00921 T1000-FINAL-TOTALS. CHGBR110
|
||||
00922 MOVE SPACE TO CHG-DETAIL-HDR4. CHGBR110
|
||||
00923 PERFORM P1000-PRINT-HEADER THRU P1000-EXIT. CHGBR110
|
||||
00924 CHGBR110
|
||||
00925 MOVE WRK-RPT-TOT-CHG TO CHG-DTL-RPT-TOT-CHG. CHGBR110
|
||||
00926 MOVE WRK-RPT-ACCT-CHG TO CHG-DTL-RPT-ACCT-CHG. CL**4
|
||||
00927 CHGBR110
|
||||
00928 WRITE SELF-RPT-REC FROM CHG-DETAIL-RPT-FOOTER2 CHGBR110
|
||||
00929 AFTER ADVANCING 3 LINES. CHGBR110
|
||||
00930 CHGBR110
|
||||
00931 WRITE SELF-RPT-REC FROM CHG-DETAIL-RPT-FOOTER1 CHGBR110
|
||||
00932 AFTER ADVANCING 2 LINES. CHGBR110
|
||||
00933 CHGBR110
|
||||
00934 T1000-EXIT. CHGBR110
|
||||
00935 EXIT. CHGBR110
|
||||
00936 CHGBR110
|
||||
00937 S004-FROM-DATE. CHGBR110
|
||||
00938 SET L004-FROM-DATE TO TRUE. CHGBR110
|
||||
00939 GO TO S004-YRQ. CHGBR110
|
||||
00940 CHGBR110
|
||||
00941 S004-YRQ. CHGBR110
|
||||
00942 CALL 'DTSBU004' USING L004-LINK-AREA. CHGBR110
|
||||
00943 S004-EXIT. EXIT. CHGBR110
|
||||
00944 CHGBR110
|
||||
00945 S910-OPEN-READ. CHGBR110
|
||||
00946 SET L910-OPEN-READ-88 TO TRUE. CHGBR110
|
||||
00947 GO TO S910-MSTR-IO. CHGBR110
|
||||
00948 CHGBR110
|
||||
00949 S910-READ. CHGBR110
|
||||
00950 SET L910-READ-88 TO TRUE. CHGBR110
|
||||
00951 GO TO S910-MSTR-IO. CHGBR110
|
||||
00952 CHGBR110
|
||||
00953 S910-CLOSE. CHGBR110
|
||||
00954 SET L910-CLOSE-88 TO TRUE. CHGBR110
|
||||
00955 GO TO S910-MSTR-IO. CHGBR110
|
||||
00956 CHGBR110
|
||||
00957 S910-MSTR-IO. CHGBR110
|
||||
00958 CALL 'DTSBU910' USING L910-LINK-AREA CHGBR110
|
||||
00959 MSKL-REC. CHGBR110
|
||||
00960 CHGBR110
|
||||
00961 S910-EXIT. CHGBR110
|
||||
00962 EXIT. CHGBR110
|
||||
00963 CHGBR110
|
||||
00964 S999-ABEND. CHGBR110
|
||||
00965 DISPLAY '**** CHGBR110 ABENDING ' CHGBR110
|
||||
00966 ABEND-MSG. CHGBR110
|
||||
00967 CHGBR110
|
||||
00968 CALL 'DTSBU999' USING WRK-ABEND-CODE. CHGBR110
|
||||
00969 CHGBR110
|
||||
00970 S999-EXIT. CHGBR110
|
||||
00971 EXIT. CHGBR110
|
||||
Reference in New Issue
Block a user