DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
192
Batch/DTSBD971.cob
Normal file
192
Batch/DTSBD971.cob
Normal file
@ -0,0 +1,192 @@
|
||||
00001 IDENTIFICATION DIVISION. 09/25/98
|
||||
00002 PROGRAM-ID. DTSBD971. DTSBD971
|
||||
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV002
|
||||
00004 DATE-WRITTEN. NOVEMBER 1997. DTSBD971
|
||||
00005 DATE-COMPILED. DTSBD971
|
||||
00006 SKIP3 DTSBD971
|
||||
00007 ***** DTSBD971
|
||||
00008 * DTSBD971
|
||||
00009 * FUNCTION: FORMAT MAINFRAME PRINT LINES FOR DISPLAY DTSBD971
|
||||
00010 * WITHIN WP 6.1 FOR WINDOWS - STRIP CARRIAGE DTSBD971
|
||||
00011 * CONTROL CHARACTER AND INSERT BLANK LINES. DTSBD971
|
||||
00012 * DTSBD971
|
||||
00013 * DTSBD971
|
||||
00014 * MODIFICATION LOG: DTSBD971
|
||||
00015 * DTSBD971
|
||||
00016 * 11/10/97 INITIAL DEVELOPMENT. DTSBD971
|
||||
00017 * WORK ORDER: PROGRAMMER: TCL DTSBD971
|
||||
00018 * DTSBD971
|
||||
00019 * 08/13/1998 REVIEWED AND MODIFIED FOR DC. DTSBD971
|
||||
00020 * REFERENCE: DC DEVELOPMENT PROGRAMMER: EHH DTSBD971
|
||||
00021 * DTSBD971
|
||||
00022 * MM/DD/YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBD971
|
||||
00023 * REFERENCE: XXXXXXXXXXXXXXX PROGRAMMER: XXX DTSBD971
|
||||
00024 * DTSBD971
|
||||
00025 * DTSBD971
|
||||
00026 * DESCRIPTION: DTSBD971
|
||||
00027 * DTSBD971
|
||||
00028 ***** DTSBD971
|
||||
00029 SKIP3 DTSBD971
|
||||
00030 ENVIRONMENT DIVISION. DTSBD971
|
||||
00031 SKIP2 DTSBD971
|
||||
00032 INPUT-OUTPUT SECTION. DTSBD971
|
||||
00033 SKIP1 DTSBD971
|
||||
00034 FILE-CONTROL. DTSBD971
|
||||
00035 SELECT IN-FILE ASSIGN TO INFILE. DTSBD971
|
||||
00036 SELECT OUT-FILE ASSIGN TO OUTFILE. DTSBD971
|
||||
00037 EJECT DTSBD971
|
||||
00038 DATA DIVISION. DTSBD971
|
||||
00039 SKIP3 DTSBD971
|
||||
00040 FILE SECTION. DTSBD971
|
||||
00041 SKIP2 DTSBD971
|
||||
00042 FD IN-FILE DTSBD971
|
||||
00043 RECORDING MODE IS F DTSBD971
|
||||
00044 BLOCK CONTAINS 0 RECORDS DTSBD971
|
||||
00045 LABEL RECORDS ARE STANDARD. DTSBD971
|
||||
00046 SKIP1 DTSBD971
|
||||
00047 01 IN-REC. DTSBD971
|
||||
00048 05 IN-CC PIC X(01). DTSBD971
|
||||
00049 88 IN-TOP-OF-PAGE-88 VALUE '1'. DTSBD971
|
||||
00050 88 IN-ADVANCE-0-88 VALUE '+'. DTSBD971
|
||||
00051 88 IN-ADVANCE-1-88 VALUE ' '. DTSBD971
|
||||
00052 88 IN-ADVANCE-2-88 VALUE '0'. DTSBD971
|
||||
00053 88 IN-ADVANCE-3-88 VALUE '-'. DTSBD971
|
||||
00054 05 IN-LINE PIC X(132). DTSBD971
|
||||
00055 EJECT DTSBD971
|
||||
00056 FD OUT-FILE DTSBD971
|
||||
00057 RECORDING MODE IS F DTSBD971
|
||||
00058 BLOCK CONTAINS 0 RECORDS DTSBD971
|
||||
00059 LABEL RECORDS ARE STANDARD. DTSBD971
|
||||
00060 SKIP1 DTSBD971
|
||||
00061 01 OUT-REC. DTSBD971
|
||||
00062 05 OUT-LINE PIC X(132). DTSBD971
|
||||
00063 EJECT DTSBD971
|
||||
00064 WORKING-STORAGE SECTION. DTSBD971
|
||||
000645 77 PAN-VALET PICTURE X(24) VALUE '002DTSBD971 09/25/98'. DTSBD971
|
||||
00065 SKIP3 DTSBD971
|
||||
00066 01 WRK-AREA. DTSBD971
|
||||
00067 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +971.DTSBD971
|
||||
00068 DTSBD971
|
||||
00069 05 ABEND-MSG PIC X(60). DTSBD971
|
||||
00070 SKIP3 DTSBD971
|
||||
00071 05 IN-EOF-IND PIC X(01). DTSBD971
|
||||
00072 88 IN-EOF-NO-88 VALUE 'N'. DTSBD971
|
||||
00073 88 IN-EOF-YES-88 VALUE 'Y'. DTSBD971
|
||||
00074 SKIP3 DTSBD971
|
||||
00075 05 WRK-LINE-CNT PIC S9(03) COMP-3. DTSBD971
|
||||
00076 DTSBD971
|
||||
00077 05 WRK-BLANK-LINE-CNT PIC S9(03) COMP-3. DTSBD971
|
||||
00078 EJECT DTSBD971
|
||||
00079 PROCEDURE DIVISION. DTSBD971
|
||||
00080 SKIP2 DTSBD971
|
||||
00081 PERFORM I0000-INITIATE THRU I0000-EXIT. DTSBD971
|
||||
00082 DTSBD971
|
||||
00083 DTSBD971
|
||||
00084 DTSBD971
|
||||
00085 SET IN-EOF-NO-88 TO TRUE. DTSBD971
|
||||
00086 DTSBD971
|
||||
00087 PERFORM P0000-PROCESS THRU P0000-EXIT DTSBD971
|
||||
00088 UNTIL IN-EOF-YES-88. DTSBD971
|
||||
00089 DTSBD971
|
||||
00090 DTSBD971
|
||||
00091 DTSBD971
|
||||
00092 PERFORM T0000-TERMINATE THRU T0000-EXIT. DTSBD971
|
||||
00093 SKIP2 DTSBD971
|
||||
00094 GOBACK. DTSBD971
|
||||
00095 EJECT DTSBD971
|
||||
00096 I0000-INITIATE. DTSBD971
|
||||
00097 OPEN INPUT IN-FILE. DTSBD971
|
||||
00098 DTSBD971
|
||||
00099 OPEN OUTPUT OUT-FILE. DTSBD971
|
||||
00100 DTSBD971
|
||||
00101 MOVE +62 TO WRK-LINE-CNT. CL**2
|
||||
00102 I0000-EXIT. DTSBD971
|
||||
00103 EXIT. DTSBD971
|
||||
00104 EJECT DTSBD971
|
||||
00105 P0000-PROCESS. DTSBD971
|
||||
00106 READ IN-FILE DTSBD971
|
||||
00107 AT END DTSBD971
|
||||
00108 SET IN-EOF-YES-88 TO TRUE DTSBD971
|
||||
00109 GO TO P0000-EXIT. DTSBD971
|
||||
00110 DTSBD971
|
||||
00111 IF IN-ADVANCE-0-88 DTSBD971
|
||||
00112 GO TO P0000-EXIT. DTSBD971
|
||||
00113 DTSBD971
|
||||
00114 IF IN-TOP-OF-PAGE-88 DTSBD971
|
||||
00115 PERFORM P1000-COMPLETE-PAGE THRU P1000-EXIT DTSBD971
|
||||
00116 MOVE IN-LINE TO OUT-LINE DTSBD971
|
||||
00117 PERFORM P9000-WRITE-LINE THRU P9000-EXIT DTSBD971
|
||||
00118 ELSE DTSBD971
|
||||
00119 IF IN-ADVANCE-1-88 DTSBD971
|
||||
00120 IF WRK-LINE-CNT + 1 > 62 CL**2
|
||||
00121 PERFORM P1000-COMPLETE-PAGE THRU P1000-EXIT DTSBD971
|
||||
00122 END-IF DTSBD971
|
||||
00123 MOVE IN-LINE TO OUT-LINE DTSBD971
|
||||
00124 PERFORM P9000-WRITE-LINE THRU P9000-EXIT DTSBD971
|
||||
00125 ELSE DTSBD971
|
||||
00126 IF IN-ADVANCE-2-88 DTSBD971
|
||||
00127 IF WRK-LINE-CNT + 2 > 62 CL**2
|
||||
00128 PERFORM P1000-COMPLETE-PAGE THRU P1000-EXIT DTSBD971
|
||||
00129 END-IF DTSBD971
|
||||
00130 MOVE SPACES TO OUT-LINE DTSBD971
|
||||
00131 PERFORM P9000-WRITE-LINE THRU P9000-EXIT DTSBD971
|
||||
00132 MOVE IN-LINE TO OUT-LINE DTSBD971
|
||||
00133 PERFORM P9000-WRITE-LINE THRU P9000-EXIT DTSBD971
|
||||
00134 ELSE DTSBD971
|
||||
00135 IF IN-ADVANCE-3-88 DTSBD971
|
||||
00136 IF WRK-LINE-CNT + 3 > 62 CL**2
|
||||
00137 PERFORM P1000-COMPLETE-PAGE THRU P1000-EXIT DTSBD971
|
||||
00138 END-IF DTSBD971
|
||||
00139 MOVE SPACES TO OUT-LINE DTSBD971
|
||||
00140 PERFORM P9000-WRITE-LINE THRU P9000-EXIT DTSBD971
|
||||
00141 MOVE SPACES TO OUT-LINE DTSBD971
|
||||
00142 PERFORM P9000-WRITE-LINE THRU P9000-EXIT DTSBD971
|
||||
00143 MOVE IN-LINE TO OUT-LINE DTSBD971
|
||||
00144 PERFORM P9000-WRITE-LINE THRU P9000-EXIT DTSBD971
|
||||
00145 ELSE DTSBD971
|
||||
00146 IF WRK-LINE-CNT + 1 > 62 CL**2
|
||||
00147 PERFORM P1000-COMPLETE-PAGE THRU P1000-EXIT DTSBD971
|
||||
00148 END-IF DTSBD971
|
||||
00149 MOVE IN-LINE TO OUT-LINE DTSBD971
|
||||
00150 PERFORM P9000-WRITE-LINE THRU P9000-EXIT. DTSBD971
|
||||
00151 P0000-EXIT. DTSBD971
|
||||
00152 EXIT. DTSBD971
|
||||
00153 SKIP3 DTSBD971
|
||||
00154 P1000-COMPLETE-PAGE. DTSBD971
|
||||
00155 COMPUTE WRK-BLANK-LINE-CNT = 62 - WRK-LINE-CNT. CL**2
|
||||
00156 DTSBD971
|
||||
00157 IF WRK-BLANK-LINE-CNT > +0 DTSBD971
|
||||
00158 PERFORM P1100-BLANK-LINE THRU P1100-EXIT DTSBD971
|
||||
00159 WRK-BLANK-LINE-CNT TIMES. DTSBD971
|
||||
00160 DTSBD971
|
||||
00161 MOVE +0 TO WRK-LINE-CNT. DTSBD971
|
||||
00162 P1000-EXIT. DTSBD971
|
||||
00163 EXIT. DTSBD971
|
||||
00164 SKIP3 DTSBD971
|
||||
00165 P1100-BLANK-LINE. DTSBD971
|
||||
00166 MOVE SPACES TO OUT-LINE. DTSBD971
|
||||
00167 DTSBD971
|
||||
00168 PERFORM P9000-WRITE-LINE THRU P9000-EXIT. DTSBD971
|
||||
00169 P1100-EXIT. DTSBD971
|
||||
00170 EXIT. DTSBD971
|
||||
00171 SKIP3 DTSBD971
|
||||
00172 P9000-WRITE-LINE. DTSBD971
|
||||
00173 WRITE OUT-REC. DTSBD971
|
||||
00174 DTSBD971
|
||||
00175 ADD +1 TO WRK-LINE-CNT. DTSBD971
|
||||
00176 P9000-EXIT. DTSBD971
|
||||
00177 EXIT. DTSBD971
|
||||
00178 EJECT DTSBD971
|
||||
00179 T0000-TERMINATE. DTSBD971
|
||||
00180 CLOSE IN-FILE DTSBD971
|
||||
00181 OUT-FILE. DTSBD971
|
||||
00182 T0000-EXIT. DTSBD971
|
||||
00183 EXIT. DTSBD971
|
||||
00184 EJECT DTSBD971
|
||||
00185 S999-ABEND. DTSBD971
|
||||
00186 DISPLAY '*** DTSBD971 ABENDING. ABEND REASON: ' DTSBD971
|
||||
00187 ABEND-MSG. DTSBD971
|
||||
00188 DTSBD971
|
||||
00189 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBD971
|
||||
00190 S999-EXIT. DTSBD971
|
||||
00191 EXIT. DTSBD971
|
||||
Reference in New Issue
Block a user