DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
940
Batch/DTSBE455.cob
Normal file
940
Batch/DTSBE455.cob
Normal file
@ -0,0 +1,940 @@
|
||||
00001 IDENTIFICATION DIVISION. 07/01/13
|
||||
00002 PROGRAM-ID. DTSBE455. DTSBE455
|
||||
00003 AUTHOR. TRW. LV003
|
||||
00004 DATE-WRITTEN. SEPTEMBER 2002. DTSBE455
|
||||
00005 DATE-COMPILED. DTSBE455
|
||||
00006 SKIP3 DTSBE455
|
||||
00007 ***** DTSBE455
|
||||
00008 * DTSBE455
|
||||
00009 * FUNCTION: ESTIMATED ANNUAL REPORT GENERATION. DTSBE455
|
||||
00010 * DTSBE455
|
||||
00011 * DTSBE455
|
||||
00012 * MODIFICATION LOG: DTSBE455
|
||||
00013 * DTSBE455
|
||||
00014 * 09/05/2002 INITIAL DEVELOPMENT. MODIFIED FROM DTSBE412. DTSBE455
|
||||
00015 * WORK ORDER: HOUSEHODL PROGRAMMER: GD DTSBE455
|
||||
00016 * DTSBE455
|
||||
00017 * MM/DD/YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBE455
|
||||
00018 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBE455
|
||||
00019 * WORK ORDER: XXXXXXXXXXXXXXX PROGRAMMER: XXX DTSBE455
|
||||
00020 * DTSBE455
|
||||
00021 * DTSBE455
|
||||
00022 * DESCRIPTION: DTSBE455
|
||||
00023 * DTSBE455
|
||||
00024 * DTSBE455
|
||||
00025 * INITIATION: DTSBE455
|
||||
00026 * DTSBE455
|
||||
00027 * SET LECM-MST-OPEN-READ-88 TO TRUE. DTSBE455
|
||||
00028 * DTSBE455
|
||||
00029 * SET LECM-REF-OPEN-READ-88 TO TRUE. DTSBE455
|
||||
00030 * DTSBE455
|
||||
00031 * CHECK AND DEFAULT PARAMETERS. DTSBE455
|
||||
00032 * DTSBE455
|
||||
00033 * DTSBE455
|
||||
00034 * PROCESSING: DTSBE455
|
||||
00035 * DTSBE455
|
||||
00036 * SEE PRINTED OUTPUTS DESCRIPTION AND LAYOUTS (455R1). DTSBE455
|
||||
00037 * DTSBE455
|
||||
00038 * DTSBE455
|
||||
00039 * TERMINATION: DTSBE455
|
||||
00040 * DTSBE455
|
||||
00041 * WRITE BATCH HEADER RECORD. DTSBE455
|
||||
00042 * DTSBE455
|
||||
00043 * DTSBE455
|
||||
00044 * RECORDS READ: DTSBE455
|
||||
00045 * DTSBE455
|
||||
00046 * MASTER: DTSBE455
|
||||
00047 * DTSBE455
|
||||
00048 * MHDR DTSBE455
|
||||
00049 * MQTR DTSBE455
|
||||
00050 * MFSC DTSBE455
|
||||
00051 * DTSBE455
|
||||
00052 * DTSBE455
|
||||
00053 * ALTERNATE INDEX: DTSBE455
|
||||
00054 * DTSBE455
|
||||
00055 * NONE. DTSBE455
|
||||
00056 * DTSBE455
|
||||
00057 * DTSBE455
|
||||
00058 * REFERENCE: DTSBE455
|
||||
00059 * DTSBE455
|
||||
00060 * DTSBE455
|
||||
00061 * DTSBE455
|
||||
00062 * DTSBE455
|
||||
00063 * RECORDS UPDATED: DTSBE455
|
||||
00064 * DTSBE455
|
||||
00065 * MHDR DTSBE455
|
||||
00066 * DTSBE455
|
||||
00067 * AHDR (WRITE) DTSBE455
|
||||
00068 * AATX (WRITE) DTSBE455
|
||||
00069 * DTSBE455
|
||||
00070 * DTSBE455
|
||||
00071 * REPORT RECORDS WRITTEN: DTSBE455
|
||||
00072 * DTSBE455
|
||||
00073 * R455 ESTIMATED REPORTS CANDIDATE LIST. DTSBE455
|
||||
00074 * DTSBE455
|
||||
00075 * DTSBE455
|
||||
00076 * BATCH TRANSACTION COLLECTION RECORDS WRITTEN: DTSBE455
|
||||
00077 * DTSBE455
|
||||
00078 * NONE. DTSBE455
|
||||
00079 * DTSBE455
|
||||
00080 * DTSBE455
|
||||
00081 * MODULES CALLED: DTSBE455
|
||||
00082 * DTSBE455
|
||||
00083 * DTSBU001 DATE CONVERSION/EDIT. DTSBE455
|
||||
00084 * DTSBU910 MASTER FILE I/O. DTSBE455
|
||||
00085 * DTSBU923 ACCOUNTING TRANSACTION COLLECTION FILE I/O. DTSBE455
|
||||
00086 * DTSBU946 VARIABLE LENGTH RECORDS SEQUENTIAL OUTPUT 1. DTSBE455
|
||||
00087 * DTSBE455
|
||||
00088 ***** DTSBE455
|
||||
00089 SKIP3 DTSBE455
|
||||
00090 ENVIRONMENT DIVISION. DTSBE455
|
||||
00091 SKIP3 DTSBE455
|
||||
00092 DATA DIVISION. DTSBE455
|
||||
00093 SKIP3 DTSBE455
|
||||
00094 WORKING-STORAGE SECTION. DTSBE455
|
||||
000945 77 PAN-VALET PICTURE X(24) VALUE '003DTSBE455 07/01/13'. DTSBE455
|
||||
00095 77 PAN-VALET PICTURE X(24) VALUE '006DTSBE455 06/27/13'. DTSBE455
|
||||
00096 77 PAN-VALET PICTURE X(24) VALUE '001DTSBE455 01/20/04'. DTSBE455
|
||||
00097 SKIP3 DTSBE455
|
||||
00098 01 WRK-AREA. DTSBE455
|
||||
00099 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +455.DTSBE455
|
||||
00100 DTSBE455
|
||||
00101 05 WRK-MOD-NAME PIC X(08) VALUE 'DTSBE455'.DTSBE455
|
||||
00102 DTSBE455
|
||||
00103 DTSBE455
|
||||
00104 05 ABEND-MSG PIC X(60). DTSBE455
|
||||
00105 DTSBE455
|
||||
00106 DTSBE455
|
||||
00107 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBE455
|
||||
00108 DTSBE455
|
||||
00109 DTSBE455
|
||||
00110 05 WRK-CURR-YR PIC 9(04) VALUE 0. DTSBE455
|
||||
00111 DTSBE455
|
||||
00112 05 WRK-ANN-FILER-CNT PIC 9(05) VALUE 0. DTSBE455
|
||||
00113 05 WRK-QTR-FILER-CNT PIC 9(05) VALUE 0. DTSBE455
|
||||
00114 DTSBE455
|
||||
00115 05 WRK-PARM-START-YRQ PIC S9(05) COMP-3. DTSBE455
|
||||
00116 DTSBE455
|
||||
00117 05 WRK-PARM-END-YRQ PIC S9(05) COMP-3. DTSBE455
|
||||
00118 DTSBE455
|
||||
00119 DTSBE455
|
||||
00120 05 WRK-EST-BASIS-START-YRQ PIC S9(05) COMP-3. DTSBE455
|
||||
00121 DTSBE455
|
||||
00122 05 WRK-EST-BASIS-END-YRQ PIC S9(05) COMP-3. DTSBE455
|
||||
00123 DTSBE455
|
||||
00124 05 WRK-QTR-CNT PIC S9(04) COMP DTSBE455
|
||||
00125 VALUE +0. DTSBE455
|
||||
00126 DTSBE455
|
||||
00127 05 WRK-ESTIM-EXISTS-IND PIC X(01). DTSBE455
|
||||
00128 88 WRK-ESTIM-EXISTS-YES-88 VALUE 'Y'. DTSBE455
|
||||
00129 88 WRK-ESTIM-EXISTS-NO-88 VALUE 'N'. DTSBE455
|
||||
00130 DTSBE455
|
||||
00131 05 WRK-GENERATE-ESTIMATE-IND PIC X(01). DTSBE455
|
||||
00132 88 WRK-GENERATE-ESTIMATE-NO-88 VALUE 'N'. DTSBE455
|
||||
00133 88 WRK-GENERATE-ESTIMATE-YES-88 VALUE 'Y'. DTSBE455
|
||||
00134 DTSBE455
|
||||
00135 DTSBE455
|
||||
00136 05 WRK-EST-TAX-WAGE PIC S9(11)V9(02) COMP-3.DTSBE455
|
||||
00137 DTSBE455
|
||||
00138 05 WRK-EST-TOT-WAGE PIC S9(11)V9(02) COMP-3.DTSBE455
|
||||
00139 DTSBE455
|
||||
00140 05 WRK-SUM-TOT-WAGE PIC S9(11)V9(02) COMP-3 DTSBE455
|
||||
00141 VALUE +0. DTSBE455
|
||||
00142 05 WRK-SUM-TAX-WAGE PIC S9(11)V9(02) COMP-3 DTSBE455
|
||||
00143 VALUE +0. DTSBE455
|
||||
00144 05 WRK-TOT-WAGE PIC S9(11)V9(02) COMP-3 DTSBE455
|
||||
00145 VALUE +0. DTSBE455
|
||||
00146 05 WRK-TAX-WAGE PIC S9(11)V9(02) COMP-3 DTSBE455
|
||||
00147 VALUE +0. DTSBE455
|
||||
00148 DTSBE455
|
||||
00149 05 WRK-OPEN-APPEAL-IND PIC X(01). DTSBE455
|
||||
00150 88 WRK-OPEN-APPEAL-NO-88 VALUE 'N'. DTSBE455
|
||||
00151 88 WRK-OPEN-APPEAL-YES-88 VALUE 'Y'. DTSBE455
|
||||
00152 DTSBE455
|
||||
00153 DTSBE455
|
||||
00154 05 HOLD-LAST-USED-BATCH-NO PIC S9(05) COMP-3.DTSBE455
|
||||
00155 EJECT DTSBE455
|
||||
00156 01 L001-LINK-AREA. DTSBE455
|
||||
00157 ++INCLUDE DTSIL001 DTSBE455
|
||||
00158 EJECT DTSBE455
|
||||
00159 01 L004-LINK-AREA. DTSBE455
|
||||
00160 ++INCLUDE DTSIL004 DTSBE455
|
||||
00161 EJECT DTSBE455
|
||||
00162 01 L061-LINK-AREA. DTSBE455
|
||||
00163 ++INCLUDE DTSIL061 DTSBE455
|
||||
00164 EJECT DTSBE455
|
||||
00165 01 L410-LINK-AREA. DTSBE455
|
||||
00166 ++INCLUDE DTSIL410 DTSBE455
|
||||
00167 EJECT DTSBE455
|
||||
00168 01 L415-LINK-AREA. DTSBE455
|
||||
00169 ++INCLUDE DTSIL415 DTSBE455
|
||||
00170 EJECT DTSBE455
|
||||
00171 01 L910-LINK-AREA. DTSBE455
|
||||
00172 ++INCLUDE DTSIL910 DTSBE455
|
||||
00173 SKIP3 DTSBE455
|
||||
00174 01 MSKL-REC. DTSBE455
|
||||
00175 ++INCLUDE DTSIMSKL DTSBE455
|
||||
00176 SKIP3 DTSBE455
|
||||
00177 01 MHDR-REC. DTSBE455
|
||||
00178 ++INCLUDE DTSIMHDR DTSBE455
|
||||
00179 SKIP3 DTSBE455
|
||||
00180 01 MQTR-REC. DTSBE455
|
||||
00181 ++INCLUDE DTSIMQTR DTSBE455
|
||||
00182 SKIP3 DTSBE455
|
||||
00183 01 MAPL-REC. DTSBE455
|
||||
00184 ++INCLUDE DTSIMAPL DTSBE455
|
||||
00185 EJECT DTSBE455
|
||||
00186 01 L923-LINK-AREA. DTSBE455
|
||||
00187 ++INCLUDE DTSIL923 DTSBE455
|
||||
00188 SKIP3 DTSBE455
|
||||
00189 01 ASKL-REC. DTSBE455
|
||||
00190 ++INCLUDE DTSIASKL DTSBE455
|
||||
00191 SKIP3 DTSBE455
|
||||
00192 01 AHDR-REC. DTSBE455
|
||||
00193 ++INCLUDE DTSIAHDR DTSBE455
|
||||
00194 SKIP3 DTSBE455
|
||||
00195 01 AATX-REC. DTSBE455
|
||||
00196 ++INCLUDE DTSIAATX DTSBE455
|
||||
00197 EJECT DTSBE455
|
||||
00198 01 R455-REC. DTSBE455
|
||||
00199 ++INCLUDE DTSIR455 DTSBE455
|
||||
00200 EJECT DTSBE455
|
||||
00201 LINKAGE SECTION. DTSBE455
|
||||
00202 SKIP3 DTSBE455
|
||||
00203 01 LECM-LINK-AREA. DTSBE455
|
||||
00204 ++INCLUDE DTSILECM DTSBE455
|
||||
00205 SKIP3 DTSBE455
|
||||
00206 10 FILLER REDEFINES LECM-EXTRACT-PARMS. DTSBE455
|
||||
00207 15 LECM-PARM-SUBJECT-YRQ PIC X(03). DTSBE455
|
||||
00208 15 FILLER PIC X(65). DTSBE455
|
||||
00209 EJECT DTSBE455
|
||||
00210 01 MPRF-LINK-REC. DTSBE455
|
||||
00211 ++INCLUDE DTSIMPRF DTSBE455
|
||||
00212 EJECT DTSBE455
|
||||
00213 PROCEDURE DIVISION USING LECM-LINK-AREA DTSBE455
|
||||
00214 MPRF-LINK-REC. DTSBE455
|
||||
00215 DTSBE455
|
||||
00216 DTSBE455
|
||||
00217 IF LECM-PROCESS-88 DTSBE455
|
||||
00218 PERFORM P0000-PROCESS THRU P0000-EXIT DTSBE455
|
||||
00219 ELSE DTSBE455
|
||||
00220 IF LECM-INITIALIZE-88 DTSBE455
|
||||
00221 PERFORM I0000-INITIALIZE THRU I0000-EXIT DTSBE455
|
||||
00222 ELSE DTSBE455
|
||||
00223 IF LECM-TERMINATE-88 DTSBE455
|
||||
00224 PERFORM T0000-TERMINATE THRU T0000-EXIT DTSBE455
|
||||
00225 ELSE DTSBE455
|
||||
00226 MOVE 'INVALID LECM-CALL-TYPE-IND ENCOUNTERED' DTSBE455
|
||||
00227 TO ABEND-MSG DTSBE455
|
||||
00228 PERFORM S999-ABEND THRU S999-EXIT. DTSBE455
|
||||
00229 DTSBE455
|
||||
00230 DTSBE455
|
||||
00231 GOBACK. DTSBE455
|
||||
00232 EJECT DTSBE455
|
||||
00233 I0000-INITIALIZE. DTSBE455
|
||||
00234 MOVE LECM-TRACE-IND TO L910-TRACE-IND DTSBE455
|
||||
00235 L923-TRACE-IND. DTSBE455
|
||||
00236 DTSBE455
|
||||
00237 MOVE WRK-MOD-NAME TO L910-MOD-NAME DTSBE455
|
||||
00238 L923-MOD-NAME. DTSBE455
|
||||
00239 DTSBE455
|
||||
00240 DTSBE455
|
||||
00241 MOVE LENGTH OF R455-REC TO R455-LENGTH. DTSBE455
|
||||
00242 DTSBE455
|
||||
00243 MOVE '455' TO R455-REC-TYPE. DTSBE455
|
||||
00244 DTSBE455
|
||||
00245 DTSBE455
|
||||
00246 PERFORM I1000-EDIT-AND-DEFAULT-PARMS THRU I1000-EXIT. DTSBE455
|
||||
00247 DTSBE455
|
||||
00248 DTSBE455
|
||||
00249 MOVE LOW-VALUES TO MHDR-KEY-AREA. DTSBE455
|
||||
00250 DTSBE455
|
||||
00251 MOVE +0 TO MHDR-EMP-NO. DTSBE455
|
||||
00252 DTSBE455
|
||||
00253 SET MHDR-HDR-88 TO TRUE. DTSBE455
|
||||
00254 DTSBE455
|
||||
00255 MOVE MHDR-KEY-AREA TO MSKL-KEY-AREA. DTSBE455
|
||||
00256 DTSBE455
|
||||
00257 PERFORM S910-READ THRU S910-EXIT. DTSBE455
|
||||
00258 DTSBE455
|
||||
00259 IF L910-NO-REC-88 DTSBE455
|
||||
00260 MOVE 'MHDR RECORD NOT FOUND (I0000)' DTSBE455
|
||||
00261 TO ABEND-MSG DTSBE455
|
||||
00262 PERFORM S999-ABEND THRU S999-EXIT. DTSBE455
|
||||
00263 DTSBE455
|
||||
00264 MOVE MSKL-REC TO MHDR-REC. DTSBE455
|
||||
00265 DTSBE455
|
||||
00266 DTSBE455
|
||||
00267 PERFORM S1000-INITIATE-AHDR THRU S1000-EXIT. DTSBE455
|
||||
00268 DTSBE455
|
||||
00269 DTSBE455
|
||||
00270 SET LECM-MST-OPEN-UPDATE-HDR-88 TO TRUE. DTSBE455
|
||||
00271 DTSBE455
|
||||
00272 SET LECM-REF-OPEN-READ-88 TO TRUE. DTSBE455
|
||||
00273 I0000-EXIT. DTSBE455
|
||||
00274 EXIT. DTSBE455
|
||||
00275 SKIP3 DTSBE455
|
||||
00276 I1000-EDIT-AND-DEFAULT-PARMS. DTSBE455
|
||||
00277 SET L415-MODE-MOST-RECENT-88 TO TRUE. DTSBE455
|
||||
00278 PERFORM S415-HOUSEHOLD-DATES THRU S415-EXIT. DTSBE455
|
||||
00279 IF L415-OK-88 DTSBE455
|
||||
00280 MOVE L415-UC30H-FIRST-DEL-STRT-YRQ DTSBE455
|
||||
00281 TO WRK-PARM-START-YRQ DTSBE455
|
||||
00282 MOVE L415-UC30H-FIRST-DEL-END-YRQ DTSBE455
|
||||
00283 TO WRK-PARM-END-YRQ DTSBE455
|
||||
00284 ELSE DTSBE455
|
||||
00285 MOVE ZEROS TO WRK-PARM-START-YRQ DTSBE455
|
||||
00286 WRK-PARM-END-YRQ. DTSBE455
|
||||
00287 DTSBE455
|
||||
00288 IF WRK-PARM-START-YRQ = ZEROS DTSBE455
|
||||
00289 MOVE 'CANNOT ESTIMATE: YEAR IS NOT YET DELINQUENT' DTSBE455
|
||||
00290 TO ABEND-MSG DTSBE455
|
||||
00291 PERFORM S999-ABEND THRU S999-EXIT. DTSBE455
|
||||
00292 DTSBE455
|
||||
00293 IF LECM-PARM-SUBJECT-YRQ = SPACES DTSBE455
|
||||
00294 NEXT SENTENCE DTSBE455
|
||||
00295 ELSE DTSBE455
|
||||
00296 PERFORM I1100-EDIT-PARM-DATES THRU I1100-EXIT DTSBE455
|
||||
00297 END-IF. DTSBE455
|
||||
00298 DTSBE455
|
||||
00299 DTSBE455
|
||||
00300 MOVE L415-UC30H-FIRST-DEL-DATE TO L001-FED-8-DATE-9. DTSBE455
|
||||
00301 DTSBE455
|
||||
00302 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBE455
|
||||
00303 DTSBE455
|
||||
00304 ADD +30 TO L001-JUL-ABS-DAY. DTSBE455
|
||||
00305 * ADD +10 TO L001-JUL-ABS-DAY. DTSBE455
|
||||
00306 DTSBE455
|
||||
00307 PERFORM S001-FROM-ABS-DAY THRU S001-EXIT. DTSBE455
|
||||
00308 DTSBE455
|
||||
00309 IF L001-FED-8-DATE-9 < LECM-CURR-RUN-DATE DTSBE455
|
||||
00310 NEXT SENTENCE DTSBE455
|
||||
00311 ELSE DTSBE455
|
||||
00312 MOVE '30 DAYS HAVE NOT ELAPSED SINCE DELINQUENT NOTICE' DTSBE455
|
||||
00313 TO ABEND-MSG DTSBE455
|
||||
00314 PERFORM S999-ABEND THRU S999-EXIT. DTSBE455
|
||||
00315 DTSBE455
|
||||
00316 DTSBE455
|
||||
00317 MOVE WRK-PARM-START-YRQ TO L004-QTR-5-9. DTSBE455
|
||||
00318 DTSBE455
|
||||
00319 PERFORM S004-FROM-5 THRU S004-EXIT. DTSBE455
|
||||
00320 DTSBE455
|
||||
00321 SUBTRACT 1 FROM L004-ABS-QTR. DTSBE455
|
||||
00322 DTSBE455
|
||||
00323 PERFORM S004-FROM-ABS THRU S004-EXIT. DTSBE455
|
||||
00324 DTSBE455
|
||||
00325 MOVE L004-QTR-5-9 TO WRK-EST-BASIS-END-YRQ. DTSBE455
|
||||
00326 DTSBE455
|
||||
00327 SUBTRACT 11 FROM L004-ABS-QTR. DTSBE455
|
||||
00328 DTSBE455
|
||||
00329 PERFORM S004-FROM-ABS THRU S004-EXIT. DTSBE455
|
||||
00330 DTSBE455
|
||||
00331 MOVE L004-QTR-5-9 TO WRK-EST-BASIS-START-YRQ. DTSBE455
|
||||
00332 DTSBE455
|
||||
00333 DTSBE455
|
||||
00334 IF WRK-EST-BASIS-START-YRQ > LECM-PICKUP-YRQ DTSBE455
|
||||
00335 NEXT SENTENCE DTSBE455
|
||||
00336 ELSE DTSBE455
|
||||
00337 MOVE 'WRK-EST-BASIS-START-YRQ <= LECM-PICKUP-YRQ' DTSBE455
|
||||
00338 TO ABEND-MSG DTSBE455
|
||||
00339 PERFORM S999-ABEND THRU S999-EXIT. DTSBE455
|
||||
00340 I1000-EXIT. DTSBE455
|
||||
00341 EXIT. DTSBE455
|
||||
00342 DTSBE455
|
||||
00343 I1100-EDIT-PARM-DATES. DTSBE455
|
||||
00344 MOVE LECM-PARM-SUBJECT-YRQ TO L004-QTR-3. DTSBE455
|
||||
00345 PERFORM S004-FROM-3 THRU S004-EXIT. DTSBE455
|
||||
00346 DTSBE455
|
||||
00347 IF L004-INVALID-QTR DTSBE455
|
||||
00348 MOVE 'INVALID LECM-PARM-SUBJECT-YRQ ENCOUNTERED' DTSBE455
|
||||
00349 TO ABEND-MSG DTSBE455
|
||||
00350 PERFORM S999-ABEND THRU S999-EXIT DTSBE455
|
||||
00351 ELSE DTSBE455
|
||||
00352 MOVE 1 TO L004-QTR-5-Q DTSBE455
|
||||
00353 MOVE L004-QTR-5-9 TO WRK-PARM-START-YRQ DTSBE455
|
||||
00354 IF WRK-PARM-START-YRQ > L415-UC30H-FIRST-DEL-STRT-YRQ DTSBE455
|
||||
00355 MOVE 'PARM YRQ > MOST RECENT DELINQUENT YEAR' DTSBE455
|
||||
00356 TO ABEND-MSG DTSBE455
|
||||
00357 PERFORM S999-ABEND THRU S999-EXIT DTSBE455
|
||||
00358 ELSE DTSBE455
|
||||
00359 MOVE 4 TO L004-QTR-5-Q DTSBE455
|
||||
00360 MOVE L004-QTR-5-9 TO WRK-PARM-END-YRQ DTSBE455
|
||||
00361 END-IF DTSBE455
|
||||
00362 END-IF. DTSBE455
|
||||
00363 DTSBE455
|
||||
00364 DTSBE455
|
||||
00365 I1100-EXIT. DTSBE455
|
||||
00366 EXIT. DTSBE455
|
||||
00367 DTSBE455
|
||||
00368 P0000-PROCESS. DTSBE455
|
||||
00369 IF FIRST-TIME-IND = 'Y' DTSBE455
|
||||
00370 PERFORM S923-OPEN-UPDATE THRU S923-EXIT DTSBE455
|
||||
00371 MOVE 'N' TO FIRST-TIME-IND. DTSBE455
|
||||
00372 DTSBE455
|
||||
00373 DTSBE455
|
||||
00374 SET L410-MODE-INPUT-YRQ-88 TO TRUE DTSBE455
|
||||
00375 MOVE MPRF-EMP-NO TO L410-EMP-NO DTSBE455
|
||||
00376 MOVE WRK-PARM-START-YRQ TO L410-YRQ DTSBE455
|
||||
00377 PERFORM S410-FILE-SCHED THRU S410-EXIT DTSBE455
|
||||
00378 IF L410-ANN-SCHED-88 DTSBE455
|
||||
00379 ADD +1 TO WRK-ANN-FILER-CNT DTSBE455
|
||||
00380 ELSE DTSBE455
|
||||
00381 ADD +1 TO WRK-QTR-FILER-CNT DTSBE455
|
||||
00382 GO TO P0000-EXIT. DTSBE455
|
||||
00383 DTSBE455
|
||||
00384 IF MPRF-PURSUED-RPT-CNT > +0 DTSBE455
|
||||
00385 NEXT SENTENCE DTSBE455
|
||||
00386 ELSE DTSBE455
|
||||
00387 GO TO P0000-EXIT. DTSBE455
|
||||
00388 DTSBE455
|
||||
00389 DTSBE455
|
||||
00390 IF MPRF-NOT-WRITTEN-OFF-88 DTSBE455
|
||||
00391 NEXT SENTENCE DTSBE455
|
||||
00392 ELSE DTSBE455
|
||||
00393 GO TO P0000-EXIT. DTSBE455
|
||||
00394 DTSBE455
|
||||
00395 DTSBE455
|
||||
00396 MOVE LOW-VALUES TO MQTR-KEY-AREA. DTSBE455
|
||||
00397 DTSBE455
|
||||
00398 MOVE MPRF-EMP-NO TO MQTR-EMP-NO. DTSBE455
|
||||
00399 DTSBE455
|
||||
00400 SET MQTR-QTR-88 TO TRUE. DTSBE455
|
||||
00401 DTSBE455
|
||||
00402 MOVE WRK-PARM-START-YRQ TO MQTR-YRQ. DTSBE455
|
||||
00403 DTSBE455
|
||||
00404 MOVE MQTR-KEY-AREA TO MSKL-KEY-AREA. DTSBE455
|
||||
00405 DTSBE455
|
||||
00406 PERFORM S910-START-BROWSE THRU S910-EXIT. DTSBE455
|
||||
00407 DTSBE455
|
||||
00408 IF L910-NO-REC-88 DTSBE455
|
||||
00409 GO TO P0000-EXIT. DTSBE455
|
||||
00410 DTSBE455
|
||||
00411 MOVE MSKL-REC TO MQTR-REC. DTSBE455
|
||||
00412 DTSBE455
|
||||
00413 DTSBE455
|
||||
00414 IF MQTR-RPT-IS-PURSUED-88 DTSBE455
|
||||
00415 NEXT SENTENCE DTSBE455
|
||||
00416 ELSE DTSBE455
|
||||
00417 GO TO P0000-EXIT. DTSBE455
|
||||
00418 DTSBE455
|
||||
00419 SET WRK-ESTIM-EXISTS-NO-88 TO TRUE. DTSBE455
|
||||
00420 PERFORM DTSBE455
|
||||
00421 UNTIL L910-NO-REC-88 DTSBE455
|
||||
00422 OR MQTR-YRQ > WRK-PARM-END-YRQ DTSBE455
|
||||
00423 PERFORM S910-READ-NEXT THRU S910-EXIT DTSBE455
|
||||
00424 IF L910-OK-88 DTSBE455
|
||||
00425 MOVE MSKL-REC TO MQTR-REC DTSBE455
|
||||
00426 IF MQTR-CURR-ESTIM-88 DTSBE455
|
||||
00427 SET WRK-ESTIM-EXISTS-YES-88 TO TRUE DTSBE455
|
||||
00428 END-IF DTSBE455
|
||||
00429 END-IF DTSBE455
|
||||
00430 END-PERFORM. DTSBE455
|
||||
00431 DTSBE455
|
||||
00432 * IF WRK-ESTIM-EXISTS-YES-88 DTSBE455
|
||||
00433 * GO TO P0000-EXIT. DTSBE455
|
||||
00434 DTSBE455
|
||||
00435 DTSBE455
|
||||
00436 * DISPLAY ' EMP NO ' MPRF-EMP-NO DTSBE455
|
||||
00437 SET WRK-GENERATE-ESTIMATE-NO-88 TO TRUE. DTSBE455
|
||||
00438 DTSBE455
|
||||
00439 MOVE +0 TO WRK-EST-TAX-WAGE DTSBE455
|
||||
00440 WRK-EST-TOT-WAGE. DTSBE455
|
||||
00441 DTSBE455
|
||||
00442 DTSBE455
|
||||
00443 PERFORM P1000-EVALUATE-FOR-EST-GEN THRU P1000-EXIT. DTSBE455
|
||||
00444 DTSBE455
|
||||
00445 DTSBE455
|
||||
00446 IF WRK-GENERATE-ESTIMATE-YES-88 DTSBE455
|
||||
00447 PERFORM P2000-GENERATE-ESTIMATE THRU P2000-EXIT. DTSBE455
|
||||
00448 DTSBE455
|
||||
00449 DTSBE455
|
||||
00450 IF WRK-GENERATE-ESTIMATE-NO-88 DTSBE455
|
||||
00451 SET R455-ESTIMATE-GENERATED-NO-88 TO TRUE DTSBE455
|
||||
00452 ELSE DTSBE455
|
||||
00453 SET R455-ESTIMATE-GENERATED-YES-88 TO TRUE DTSBE455
|
||||
00454 DISPLAY ' EST RPT GEN ' MPRF-EMP-NO. DTSBE455
|
||||
00455 DTSBE455
|
||||
00456 PERFORM S061-DETERMINE-FLD-REP THRU S061-EXIT. DTSBE455
|
||||
00457 DTSBE455
|
||||
00458 MOVE L061-FLD-REP-ID TO R455-FIELD-REP-ID. DTSBE455
|
||||
00459 DTSBE455
|
||||
00460 MOVE MPRF-EMP-NO TO R455-EMP-NO. DTSBE455
|
||||
00461 DTSBE455
|
||||
00462 MOVE WRK-PARM-START-YRQ TO R455-YRQ. DTSBE455
|
||||
00463 DTSBE455
|
||||
00464 MOVE MPRF-PRIMARY-NAME TO R455-PRIMARY-NAME. DTSBE455
|
||||
00465 DTSBE455
|
||||
00466 MOVE MQTR-RPT-DUE-DATE TO R455-RPT-DUE-DATE. DTSBE455
|
||||
00467 DTSBE455
|
||||
00468 PERFORM S946-WRITE-R455 THRU S946-EXIT. DTSBE455
|
||||
00469 P0000-EXIT. DTSBE455
|
||||
00470 EXIT. DTSBE455
|
||||
00471 EJECT DTSBE455
|
||||
00472 P1000-EVALUATE-FOR-EST-GEN. DTSBE455
|
||||
00473 IF MPRF-CLASS-SELF-INS-88 DTSBE455
|
||||
00474 GO TO P1000-EXIT. DTSBE455
|
||||
00475 DTSBE455
|
||||
00476 DTSBE455
|
||||
00477 IF MPRF-BANKRP-OPEN-88 DTSBE455
|
||||
00478 GO TO P1000-EXIT. DTSBE455
|
||||
00479 DTSBE455
|
||||
00480 DTSBE455
|
||||
00481 MOVE +0 TO WRK-EST-TAX-WAGE DTSBE455
|
||||
00482 WRK-EST-TOT-WAGE DTSBE455
|
||||
00483 WRK-SUM-TAX-WAGE DTSBE455
|
||||
00484 WRK-SUM-TOT-WAGE DTSBE455
|
||||
00485 WRK-CURR-YR DTSBE455
|
||||
00486 WRK-QTR-CNT. DTSBE455
|
||||
00487 DTSBE455
|
||||
00488 DTSBE455
|
||||
00489 MOVE LOW-VALUES TO MQTR-KEY-AREA. DTSBE455
|
||||
00490 DTSBE455
|
||||
00491 MOVE MPRF-EMP-NO TO MQTR-EMP-NO. DTSBE455
|
||||
00492 DTSBE455
|
||||
00493 SET MQTR-QTR-88 TO TRUE. DTSBE455
|
||||
00494 DTSBE455
|
||||
00495 MOVE WRK-EST-BASIS-START-YRQ TO MQTR-YRQ. DTSBE455
|
||||
00496 DTSBE455
|
||||
00497 MOVE MQTR-KEY-AREA TO MSKL-KEY-AREA. DTSBE455
|
||||
00498 DTSBE455
|
||||
00499 PERFORM S910-START-BROWSE THRU S910-EXIT. DTSBE455
|
||||
00500 DTSBE455
|
||||
00501 MOVE MSKL-REC TO MQTR-REC. DTSBE455
|
||||
00502 DTSBE455
|
||||
00503 PERFORM DTSBE455
|
||||
00504 UNTIL (L910-NO-REC-88) DTSBE455
|
||||
00505 OR (MQTR-YRQ > WRK-EST-BASIS-END-YRQ) DTSBE455
|
||||
00506 IF (MQTR-CURR-RCVD-88) DTSBE455
|
||||
00507 MOVE MQTR-YRQ TO L004-QTR-5-9 DTSBE455
|
||||
00508 IF WRK-CURR-YR = ZERO DTSBE455
|
||||
00509 MOVE L004-QTR-5-YR TO WRK-CURR-YR DTSBE455
|
||||
00510 PERFORM P1050-BEGIN-SUM THRU P1050-EXIT DTSBE455
|
||||
00511 PERFORM P1070-CONTINUE-SUM THRU P1070-EXIT DTSBE455
|
||||
00512 ELSE DTSBE455
|
||||
00513 IF L004-QTR-5-YR NOT = WRK-CURR-YR DTSBE455
|
||||
00514 MOVE L004-QTR-5-YR TO WRK-CURR-YR DTSBE455
|
||||
00515 PERFORM P1060-END-SUM THRU P1060-EXIT DTSBE455
|
||||
00516 PERFORM P1050-BEGIN-SUM THRU P1050-EXIT DTSBE455
|
||||
00517 PERFORM P1070-CONTINUE-SUM THRU P1070-EXIT DTSBE455
|
||||
00518 ELSE DTSBE455
|
||||
00519 PERFORM P1070-CONTINUE-SUM THRU P1070-EXIT DTSBE455
|
||||
00520 END-IF DTSBE455
|
||||
00521 END-IF DTSBE455
|
||||
00522 END-IF DTSBE455
|
||||
00523 PERFORM S910-READ-NEXT THRU S910-EXIT DTSBE455
|
||||
00524 IF L910-OK-88 DTSBE455
|
||||
00525 MOVE MSKL-REC TO MQTR-REC DTSBE455
|
||||
00526 END-IF DTSBE455
|
||||
00527 END-PERFORM. DTSBE455
|
||||
00528 DTSBE455
|
||||
00529 IF WRK-QTR-CNT > ZERO DTSBE455
|
||||
00530 PERFORM P1060-END-SUM THRU P1060-EXIT. DTSBE455
|
||||
00531 DTSBE455
|
||||
00532 IF WRK-EST-TOT-WAGE = +0 DTSBE455
|
||||
00533 SET WRK-GENERATE-ESTIMATE-NO-88 TO TRUE DTSBE455
|
||||
00534 GO TO P1000-EXIT. DTSBE455
|
||||
00535 DTSBE455
|
||||
00536 * MOVE LOW-VALUES TO MQTR-KEY-AREA. DTSBE455
|
||||
00537 * DTSBE455
|
||||
00538 * MOVE MPRF-EMP-NO TO MQTR-EMP-NO. DTSBE455
|
||||
00539 * DTSBE455
|
||||
00540 * SET MQTR-QTR-88 TO TRUE. DTSBE455
|
||||
00541 * DTSBE455
|
||||
00542 * DISPLAY ' WRK-PARM-START-YRQ ' WRK-PARM-START-YRQ DTSBE455
|
||||
00543 * MOVE WRK-PARM-START-YRQ TO MQTR-YRQ. DTSBE455
|
||||
00544 * DTSBE455
|
||||
00545 * MOVE MQTR-KEY-AREA TO MSKL-KEY-AREA. DTSBE455
|
||||
00546 * DTSBE455
|
||||
00547 * PERFORM S910-READ THRU S910-EXIT. DTSBE455
|
||||
00548 * DTSBE455
|
||||
00549 * IF L910-NO-REC-88 DTSBE455
|
||||
00550 * DISPLAY 'MQTR KEY ' MQTR-KEY-AREA DTSBE455
|
||||
00551 * MOVE 'UNEXPECTED MQTR RECORD NOT FOUND ENCOUNTERED' DTSBE455
|
||||
00552 * TO ABEND-MSG DTSBE455
|
||||
00553 * PERFORM S999-ABEND THRU S999-EXIT. DTSBE455
|
||||
00554 * DTSBE455
|
||||
00555 * MOVE MSKL-REC TO MQTR-REC. DTSBE455
|
||||
00556 DTSBE455
|
||||
00557 IF WRK-EST-TAX-WAGE = +0 DTSBE455
|
||||
00558 GO TO P1000-EXIT. DTSBE455
|
||||
00559 DTSBE455
|
||||
00560 DTSBE455
|
||||
00561 SET WRK-OPEN-APPEAL-NO-88 TO TRUE. DTSBE455
|
||||
00562 DTSBE455
|
||||
00563 MOVE LOW-VALUES TO MSKL-KEY-AREA. DTSBE455
|
||||
00564 DTSBE455
|
||||
00565 MOVE MPRF-EMP-NO TO MSKL-EMP-NO. DTSBE455
|
||||
00566 DTSBE455
|
||||
00567 SET MSKL-APL-88 TO TRUE. DTSBE455
|
||||
00568 DTSBE455
|
||||
00569 PERFORM S910-START-BROWSE THRU S910-EXIT. DTSBE455
|
||||
00570 DTSBE455
|
||||
00571 PERFORM DTSBE455
|
||||
00572 UNTIL L910-NO-REC-88 DTSBE455
|
||||
00573 MOVE MSKL-REC TO MAPL-REC DTSBE455
|
||||
00574 PERFORM P1100-EXAMINE-MAPL THRU P1100-EXIT DTSBE455
|
||||
00575 PERFORM S910-READ-NEXT THRU S910-EXIT DTSBE455
|
||||
00576 END-PERFORM. DTSBE455
|
||||
00577 DTSBE455
|
||||
00578 IF WRK-OPEN-APPEAL-YES-88 DTSBE455
|
||||
00579 GO TO P1000-EXIT. DTSBE455
|
||||
00580 DTSBE455
|
||||
00581 DTSBE455
|
||||
00582 SET WRK-GENERATE-ESTIMATE-YES-88 TO TRUE. DTSBE455
|
||||
00583 P1000-EXIT. DTSBE455
|
||||
00584 EXIT. DTSBE455
|
||||
00585 SKIP3 DTSBE455
|
||||
00586 P1050-BEGIN-SUM. DTSBE455
|
||||
00587 MOVE ZEROS TO WRK-QTR-CNT DTSBE455
|
||||
00588 WRK-SUM-TAX-WAGE DTSBE455
|
||||
00589 WRK-SUM-TOT-WAGE. DTSBE455
|
||||
00590 P1050-EXIT. DTSBE455
|
||||
00591 EXIT. DTSBE455
|
||||
00592 P1060-END-SUM. DTSBE455
|
||||
00593 DTSBE455
|
||||
00594 IF WRK-QTR-CNT < +4 DTSBE455
|
||||
00595 GO TO P1060-EXIT. DTSBE455
|
||||
00596 DTSBE455
|
||||
00597 COMPUTE WRK-TAX-WAGE = DTSBE455
|
||||
00598 (WRK-SUM-TAX-WAGE / WRK-QTR-CNT). DTSBE455
|
||||
00599 IF WRK-TAX-WAGE > WRK-EST-TAX-WAGE DTSBE455
|
||||
00600 MOVE WRK-TAX-WAGE TO WRK-EST-TAX-WAGE. DTSBE455
|
||||
00601 DTSBE455
|
||||
00602 COMPUTE WRK-TOT-WAGE = DTSBE455
|
||||
00603 (WRK-SUM-TOT-WAGE / WRK-QTR-CNT). DTSBE455
|
||||
00604 IF WRK-TOT-WAGE > WRK-EST-TOT-WAGE DTSBE455
|
||||
00605 MOVE WRK-TOT-WAGE TO WRK-EST-TOT-WAGE. DTSBE455
|
||||
00606 DTSBE455
|
||||
00607 P1060-EXIT. DTSBE455
|
||||
00608 EXIT. DTSBE455
|
||||
00609 P1070-CONTINUE-SUM. DTSBE455
|
||||
00610 ADD +1 TO WRK-QTR-CNT DTSBE455
|
||||
00611 ADD MQTR-TAX-WAGE TO WRK-SUM-TAX-WAGE. DTSBE455
|
||||
00612 ADD MQTR-TOT-WAGE TO WRK-SUM-TOT-WAGE. DTSBE455
|
||||
00613 P1070-EXIT. DTSBE455
|
||||
00614 EXIT. DTSBE455
|
||||
00615 P1100-EXAMINE-MAPL. DTSBE455
|
||||
00616 IF MAPL-STATUS-OPEN-88 DTSBE455
|
||||
00617 NEXT SENTENCE DTSBE455
|
||||
00618 ELSE DTSBE455
|
||||
00619 GO TO P1100-EXIT. DTSBE455
|
||||
00620 DTSBE455
|
||||
00621 PERFORM DTSBE455
|
||||
00622 VARYING MAPL-COV-IDX FROM 1 BY 1 DTSBE455
|
||||
00623 UNTIL MAPL-COV-IDX > MAPL-COVERED-CNT DTSBE455
|
||||
00624 IF MAPL-COVERED-YRQ (MAPL-COV-IDX) DTSBE455
|
||||
00625 >= WRK-PARM-START-YRQ DTSBE455
|
||||
00626 AND MAPL-COVERED-YRQ (MAPL-COV-IDX) DTSBE455
|
||||
00627 <= WRK-PARM-END-YRQ DTSBE455
|
||||
00628 SET WRK-OPEN-APPEAL-YES-88 TO TRUE DTSBE455
|
||||
00629 END-IF DTSBE455
|
||||
00630 END-PERFORM. DTSBE455
|
||||
00631 P1100-EXIT. DTSBE455
|
||||
00632 EXIT. DTSBE455
|
||||
00633 EJECT DTSBE455
|
||||
00634 P2000-GENERATE-ESTIMATE. DTSBE455
|
||||
00635 MOVE LOW-VALUES TO AATX-REC. DTSBE455
|
||||
00636 DTSBE455
|
||||
00637 DTSBE455
|
||||
00638 IF AHDR-ATC-FILE-TRAN-CNT < +999 DTSBE455
|
||||
00639 NEXT SENTENCE DTSBE455
|
||||
00640 ELSE DTSBE455
|
||||
00641 PERFORM S2000-TERMINATE-AHDR THRU S2000-EXIT DTSBE455
|
||||
00642 PERFORM S1000-INITIATE-AHDR THRU S1000-EXIT. DTSBE455
|
||||
00643 DTSBE455
|
||||
00644 MOVE AHDR-BATCH-NO TO AATX-BATCH-NO. DTSBE455
|
||||
00645 DTSBE455
|
||||
00646 ADD +1 TO AHDR-ATC-FILE-TRAN-CNT. DTSBE455
|
||||
00647 DTSBE455
|
||||
00648 MOVE AHDR-ATC-FILE-TRAN-CNT TO AATX-ITEM-NO. DTSBE455
|
||||
00649 DTSBE455
|
||||
00650 SET AATX-ATX-88 TO TRUE. DTSBE455
|
||||
00651 DTSBE455
|
||||
00652 MOVE MPRF-PRIMARY-NAME TO AATX-NAME-CHECK. DTSBE455
|
||||
00653 DTSBE455
|
||||
00654 MOVE MPRF-EMP-NO TO AATX-EMP-NO. DTSBE455
|
||||
00655 DTSBE455
|
||||
00656 SET AATX-ESTIM-88 TO TRUE. DTSBE455
|
||||
00657 DTSBE455
|
||||
00658 MOVE WRK-PARM-START-YRQ TO AATX-YRQ. DTSBE455
|
||||
00659 DTSBE455
|
||||
00660 MOVE WRK-EST-TOT-WAGE TO AATX-TOT-WAGE. DTSBE455
|
||||
00661 DTSBE455
|
||||
00662 MOVE WRK-EST-TAX-WAGE TO AATX-TAX-WAGE. DTSBE455
|
||||
00663 DTSBE455
|
||||
00664 IF AATX-TAX-WAGE > AATX-TOT-WAGE DTSBE455
|
||||
00665 MOVE AATX-TOT-WAGE TO AATX-TAX-WAGE. DTSBE455
|
||||
00666 DTSBE455
|
||||
00667 COMPUTE AATX-EXCESS-WAGE DTSBE455
|
||||
00668 = AATX-TOT-WAGE - AATX-TAX-WAGE. DTSBE455
|
||||
00669 DTSBE455
|
||||
00670 MOVE +0 TO AATX-REMIT-AMT. DTSBE455
|
||||
00671 DTSBE455
|
||||
00672 SET AATX-WAIVE-BOTH-NO-88 DTSBE455
|
||||
00673 AATX-WAIVE-INT-NO-88 DTSBE455
|
||||
00674 AATX-WAIVE-LATE-PEN-NO-88 TO TRUE. DTSBE455
|
||||
00675 DTSBE455
|
||||
00676 SET AATX-TOTAL-NO-ENTRY-88 DTSBE455
|
||||
00677 AATX-JAN-NO-ENTRY-88 DTSBE455
|
||||
00678 AATX-FEB-NO-ENTRY-88 DTSBE455
|
||||
00679 AATX-MAR-NO-ENTRY-88 DTSBE455
|
||||
00680 AATX-APR-NO-ENTRY-88 DTSBE455
|
||||
00681 AATX-MAY-NO-ENTRY-88 DTSBE455
|
||||
00682 AATX-JUN-NO-ENTRY-88 DTSBE455
|
||||
00683 AATX-JUL-NO-ENTRY-88 DTSBE455
|
||||
00684 AATX-AUG-NO-ENTRY-88 DTSBE455
|
||||
00685 AATX-SEP-NO-ENTRY-88 DTSBE455
|
||||
00686 AATX-OCT-NO-ENTRY-88 DTSBE455
|
||||
00687 AATX-NOV-NO-ENTRY-88 DTSBE455
|
||||
00688 AATX-DEC-NO-ENTRY-88 TO TRUE. DTSBE455
|
||||
00689 DTSBE455
|
||||
00690 SET AATX-VERIFIED-NO-88 TO TRUE. DTSBE455
|
||||
00691 DTSBE455
|
||||
00692 MOVE +0 TO AATX-RECEIVED-DATE DTSBE455
|
||||
00693 AATX-DEPOSIT-DATE. DTSBE455
|
||||
00694 DTSBE455
|
||||
00695 MOVE 'SYS' TO AATX-RESPONSIBLE-ACTIVITY. DTSBE455
|
||||
00696 DTSBE455
|
||||
00697 MOVE SPACES TO AATX-RESPONSIBLE-OP-ID. DTSBE455
|
||||
00698 DTSBE455
|
||||
00699 MOVE SPACE TO AATX-DISREGARD-EDITS-IND. DTSBE455
|
||||
00700 DTSBE455
|
||||
00701 SET AATX-PASSED-FULL-EDITS-YES-88 TO TRUE. DTSBE455
|
||||
00702 DTSBE455
|
||||
00703 MOVE +0 TO AATX-PROCESSED-DATE. DTSBE455
|
||||
00704 DTSBE455
|
||||
00705 MOVE AATX-REC TO ASKL-REC. DTSBE455
|
||||
00706 DTSBE455
|
||||
00707 DTSBE455
|
||||
00708 PERFORM S923-WRITE THRU S923-EXIT. DTSBE455
|
||||
00709 P2000-EXIT. DTSBE455
|
||||
00710 EXIT. DTSBE455
|
||||
00711 EJECT DTSBE455
|
||||
00712 T0000-TERMINATE. DTSBE455
|
||||
00713 IF FIRST-TIME-IND = 'Y' DTSBE455
|
||||
00714 GO TO T0000-EXIT. DTSBE455
|
||||
00715 DTSBE455
|
||||
00716 DTSBE455
|
||||
00717 PERFORM S2000-TERMINATE-AHDR THRU S2000-EXIT. DTSBE455
|
||||
00718 DTSBE455
|
||||
00719 DTSBE455
|
||||
00720 PERFORM S923-CLOSE THRU S923-EXIT. DTSBE455
|
||||
00721 DTSBE455
|
||||
00722 DTSBE455
|
||||
00723 MOVE MHDR-LAST-USED-BATCH-NO TO HOLD-LAST-USED-BATCH-NO. DTSBE455
|
||||
00724 DTSBE455
|
||||
00725 DTSBE455
|
||||
00726 MOVE MHDR-KEY-AREA TO MSKL-KEY-AREA. DTSBE455
|
||||
00727 DTSBE455
|
||||
00728 PERFORM S910-READ THRU S910-EXIT. DTSBE455
|
||||
00729 DTSBE455
|
||||
00730 IF L910-NO-REC-88 DTSBE455
|
||||
00731 MOVE 'MHDR RECORD NOT FOUND (T0000)' DTSBE455
|
||||
00732 TO ABEND-MSG DTSBE455
|
||||
00733 PERFORM S999-ABEND THRU S999-EXIT. DTSBE455
|
||||
00734 DTSBE455
|
||||
00735 DISPLAY ' TOTAL ANN-FILERS ' WRK-ANN-FILER-CNT. DTSBE455
|
||||
00736 DISPLAY ' TOTAL QTR-FILERS ' WRK-QTR-FILER-CNT. DTSBE455
|
||||
00737 DTSBE455
|
||||
00738 DTSBE455
|
||||
00739 DTSBE455
|
||||
00740 MOVE MSKL-REC TO MHDR-REC. DTSBE455
|
||||
00741 DTSBE455
|
||||
00742 MOVE HOLD-LAST-USED-BATCH-NO TO MHDR-LAST-USED-BATCH-NO. DTSBE455
|
||||
00743 DTSBE455
|
||||
00744 MOVE LECM-CURR-RUN-DATE TO MHDR-CHNG-DATE. DTSBE455
|
||||
00745 DTSBE455
|
||||
00746 MOVE MHDR-REC TO MSKL-REC. DTSBE455
|
||||
00747 DTSBE455
|
||||
00748 PERFORM S910-REWRITE THRU S910-EXIT. DTSBE455
|
||||
00749 T0000-EXIT. DTSBE455
|
||||
00750 EXIT. DTSBE455
|
||||
00751 EJECT DTSBE455
|
||||
00752 S1000-INITIATE-AHDR. DTSBE455
|
||||
00753 MOVE LOW-VALUES TO AHDR-REC. DTSBE455
|
||||
00754 DTSBE455
|
||||
00755 IF MHDR-LAST-USED-BATCH-NO < +99999 DTSBE455
|
||||
00756 COMPUTE AHDR-BATCH-NO = MHDR-LAST-USED-BATCH-NO + 1 DTSBE455
|
||||
00757 ELSE DTSBE455
|
||||
00758 MOVE +1 TO AHDR-BATCH-NO. DTSBE455
|
||||
00759 DTSBE455
|
||||
00760 MOVE +0 TO AHDR-ITEM-NO. DTSBE455
|
||||
00761 DTSBE455
|
||||
00762 SET AHDR-HDR-88 TO TRUE. DTSBE455
|
||||
00763 DTSBE455
|
||||
00764 SET AHDR-BATCH-BALANCED-YES-88 TO TRUE. DTSBE455
|
||||
00765 DTSBE455
|
||||
00766 SET AHDR-ANNUAL-BATCH-YES-88 TO TRUE. DTSBE455
|
||||
00767 DTSBE455
|
||||
00768 SET AHDR-BATCH-HELD-NO-88 TO TRUE. DTSBE455
|
||||
00769 DTSBE455
|
||||
00770 SET AHDR-ESTB-SYSTEM-88 TO TRUE. DTSBE455
|
||||
00771 DTSBE455
|
||||
00772 MOVE MHDR-CURR-RUN-DATE TO AHDR-ESTB-DATE. DTSBE455
|
||||
00773 DTSBE455
|
||||
00774 MOVE SPACES TO AHDR-CHNG-OP-ID. DTSBE455
|
||||
00775 DTSBE455
|
||||
00776 MOVE +0 TO AHDR-CHNG-DATE. DTSBE455
|
||||
00777 DTSBE455
|
||||
00778 MOVE MHDR-CURR-RUN-DATE TO AHDR-DEPOSIT-DATE. DTSBE455
|
||||
00779 DTSBE455
|
||||
00780 MOVE MHDR-CURR-RUN-DATE TO AHDR-RECEIVED-DATE. DTSBE455
|
||||
00781 DTSBE455
|
||||
00782 MOVE +0 TO AHDR-LAST-USED-ITEM-NO DTSBE455
|
||||
00783 AHDR-CONTROL-TRAN-CNT DTSBE455
|
||||
00784 AHDR-ATC-FILE-TRAN-CNT DTSBE455
|
||||
00785 AHDR-PROC-TRAN-CNT DTSBE455
|
||||
00786 AHDR-CONTROL-REMIT-AMT DTSBE455
|
||||
00787 AHDR-ATC-FILE-REMIT-AMT DTSBE455
|
||||
00788 AHDR-PROC-REMIT-AMT DTSBE455
|
||||
00789 AHDR-BANK-BATCH-NO. DTSBE455
|
||||
00790 S1000-EXIT. DTSBE455
|
||||
00791 EXIT. DTSBE455
|
||||
00792 EJECT DTSBE455
|
||||
00793 S2000-TERMINATE-AHDR. DTSBE455
|
||||
00794 IF AHDR-ATC-FILE-TRAN-CNT = +0 DTSBE455
|
||||
00795 GO TO S2000-EXIT. DTSBE455
|
||||
00796 DTSBE455
|
||||
00797 DTSBE455
|
||||
00798 MOVE AHDR-BATCH-NO TO MHDR-LAST-USED-BATCH-NO. DTSBE455
|
||||
00799 DTSBE455
|
||||
00800 MOVE AHDR-ATC-FILE-TRAN-CNT TO AHDR-LAST-USED-ITEM-NO. DTSBE455
|
||||
00801 DTSBE455
|
||||
00802 MOVE AHDR-ATC-FILE-TRAN-CNT TO AHDR-CONTROL-TRAN-CNT. DTSBE455
|
||||
00803 DTSBE455
|
||||
00804 MOVE AHDR-ATC-FILE-REMIT-AMT TO AHDR-CONTROL-REMIT-AMT. DTSBE455
|
||||
00805 DTSBE455
|
||||
00806 MOVE AHDR-REC TO ASKL-REC. DTSBE455
|
||||
00807 DTSBE455
|
||||
00808 PERFORM S923-WRITE THRU S923-EXIT. DTSBE455
|
||||
00809 S2000-EXIT. DTSBE455
|
||||
00810 EXIT. DTSBE455
|
||||
00811 EJECT DTSBE455
|
||||
00812 S001-FROM-FED-8. DTSBE455
|
||||
00813 SET L001-FROM-FED-8 TO TRUE. DTSBE455
|
||||
00814 GO TO S001-DATE. DTSBE455
|
||||
00815 DTSBE455
|
||||
00816 S001-FROM-CAL-6. DTSBE455
|
||||
00817 SET L001-FROM-CAL-6 TO TRUE. DTSBE455
|
||||
00818 GO TO S001-DATE. DTSBE455
|
||||
00819 DTSBE455
|
||||
00820 S001-FROM-ABS-DAY. DTSBE455
|
||||
00821 SET L001-FROM-ABS-DAY TO TRUE. DTSBE455
|
||||
00822 GO TO S001-DATE. DTSBE455
|
||||
00823 DTSBE455
|
||||
00824 S001-DATE. DTSBE455
|
||||
00825 CALL 'DTSBU001' USING L001-LINK-AREA. DTSBE455
|
||||
00826 S001-EXIT. DTSBE455
|
||||
00827 EXIT. DTSBE455
|
||||
00828 SKIP3 DTSBE455
|
||||
00829 DTSBE455
|
||||
00830 S004-FROM-5. DTSBE455
|
||||
00831 SET L004-FROM-5 TO TRUE. DTSBE455
|
||||
00832 GO TO S004-YRQ. DTSBE455
|
||||
00833 DTSBE455
|
||||
00834 S004-FROM-3. DTSBE455
|
||||
00835 SET L004-FROM-3 TO TRUE. DTSBE455
|
||||
00836 GO TO S004-YRQ. DTSBE455
|
||||
00837 DTSBE455
|
||||
00838 S004-FROM-ABS. DTSBE455
|
||||
00839 SET L004-FROM-ABS TO TRUE. DTSBE455
|
||||
00840 GO TO S004-YRQ. DTSBE455
|
||||
00841 DTSBE455
|
||||
00842 S004-YRQ. DTSBE455
|
||||
00843 CALL 'DTSBU004' USING L004-LINK-AREA. DTSBE455
|
||||
00844 S004-EXIT. DTSBE455
|
||||
00845 EXIT. DTSBE455
|
||||
00846 SKIP3 DTSBE455
|
||||
00847 S061-DETERMINE-FLD-REP. DTSBE455
|
||||
00848 MOVE MPRF-FLD-ZIP-ST TO L061-FLD-ZIP-ST. DTSBE455
|
||||
00849 DTSBE455
|
||||
00850 MOVE MPRF-EMP-NO TO L061-EMP-NO. DTSBE455
|
||||
00851 DTSBE455
|
||||
00852 CALL 'DTSBU061' USING L061-LINK-AREA. DTSBE455
|
||||
00853 S061-EXIT. DTSBE455
|
||||
00854 EXIT. DTSBE455
|
||||
00855 SKIP3 DTSBE455
|
||||
00856 S410-FILE-SCHED. DTSBE455
|
||||
00857 CALL 'DTSBU410' USING L410-LINK-AREA. DTSBE455
|
||||
00858 S410-EXIT. DTSBE455
|
||||
00859 EXIT. DTSBE455
|
||||
00860 DTSBE455
|
||||
00861 S415-HOUSEHOLD-DATES. DTSBE455
|
||||
00862 CALL 'DTSBU415' USING L415-LINK-AREA. DTSBE455
|
||||
00863 S415-EXIT. DTSBE455
|
||||
00864 EXIT. DTSBE455
|
||||
00865 DTSBE455
|
||||
00866 S910-READ. DTSBE455
|
||||
00867 SET L910-READ-88 TO TRUE. DTSBE455
|
||||
00868 GO TO S910-MSTR-IO. DTSBE455
|
||||
00869 DTSBE455
|
||||
00870 S910-START-BROWSE. DTSBE455
|
||||
00871 SET L910-START-BROWSE-88 TO TRUE. DTSBE455
|
||||
00872 GO TO S910-MSTR-IO. DTSBE455
|
||||
00873 DTSBE455
|
||||
00874 S910-READ-NEXT. DTSBE455
|
||||
00875 SET L910-READ-NEXT-88 TO TRUE. DTSBE455
|
||||
00876 GO TO S910-MSTR-IO. DTSBE455
|
||||
00877 DTSBE455
|
||||
00878 S910-REWRITE. DTSBE455
|
||||
00879 SET L910-REWRITE-88 TO TRUE. DTSBE455
|
||||
00880 GO TO S910-MSTR-IO. DTSBE455
|
||||
00881 DTSBE455
|
||||
00882 S910-MSTR-IO. DTSBE455
|
||||
00883 CALL 'DTSBU910' USING L910-LINK-AREA DTSBE455
|
||||
00884 MSKL-REC. DTSBE455
|
||||
00885 S910-EXIT. DTSBE455
|
||||
00886 EXIT. DTSBE455
|
||||
00887 SKIP3 DTSBE455
|
||||
00888 S923-OPEN-UPDATE. DTSBE455
|
||||
00889 SET L923-OPEN-UPDATE-88 TO TRUE. DTSBE455
|
||||
00890 GO TO S923-ATC-IO. DTSBE455
|
||||
00891 DTSBE455
|
||||
00892 S923-READ. DTSBE455
|
||||
00893 SET L923-READ-88 TO TRUE. DTSBE455
|
||||
00894 GO TO S923-ATC-IO. DTSBE455
|
||||
00895 DTSBE455
|
||||
00896 S923-START-BROWSE. DTSBE455
|
||||
00897 SET L923-START-BROWSE-88 TO TRUE. DTSBE455
|
||||
00898 GO TO S923-ATC-IO. DTSBE455
|
||||
00899 DTSBE455
|
||||
00900 S923-READ-NEXT. DTSBE455
|
||||
00901 SET L923-READ-NEXT-88 TO TRUE. DTSBE455
|
||||
00902 GO TO S923-ATC-IO. DTSBE455
|
||||
00903 DTSBE455
|
||||
00904 S923-WRITE. DTSBE455
|
||||
00905 SET L923-WRITE-88 TO TRUE. DTSBE455
|
||||
00906 GO TO S923-ATC-IO. DTSBE455
|
||||
00907 DTSBE455
|
||||
00908 S923-REWRITE. DTSBE455
|
||||
00909 SET L923-REWRITE-88 TO TRUE. DTSBE455
|
||||
00910 GO TO S923-ATC-IO. DTSBE455
|
||||
00911 DTSBE455
|
||||
00912 S923-DELETE. DTSBE455
|
||||
00913 SET L923-DELETE-88 TO TRUE. DTSBE455
|
||||
00914 GO TO S923-ATC-IO. DTSBE455
|
||||
00915 DTSBE455
|
||||
00916 S923-CLOSE. DTSBE455
|
||||
00917 SET L923-CLOSE-88 TO TRUE. DTSBE455
|
||||
00918 GO TO S923-ATC-IO. DTSBE455
|
||||
00919 DTSBE455
|
||||
00920 S923-ATC-IO. DTSBE455
|
||||
00921 CALL 'DTSBU923' USING L923-LINK-AREA DTSBE455
|
||||
00922 ASKL-REC. DTSBE455
|
||||
00923 S923-EXIT. DTSBE455
|
||||
00924 EXIT. DTSBE455
|
||||
00925 SKIP3 DTSBE455
|
||||
00926 S946-WRITE-R455. DTSBE455
|
||||
00927 CALL 'DTSBU946' USING R455-REC. DTSBE455
|
||||
00928 GO TO S946-EXIT. DTSBE455
|
||||
00929 DTSBE455
|
||||
00930 S946-EXIT. DTSBE455
|
||||
00931 EXIT. DTSBE455
|
||||
00932 SKIP3 DTSBE455
|
||||
00933 S999-ABEND. DTSBE455
|
||||
00934 DISPLAY '*** DTSBE455 ABENDING. ' DTSBE455
|
||||
00935 ABEND-MSG. DTSBE455
|
||||
00936 DTSBE455
|
||||
00937 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBE455
|
||||
00938 S999-EXIT. DTSBE455
|
||||
00939 EXIT. DTSBE455
|
||||
Reference in New Issue
Block a user