DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
413
Batch/DTSBR204.cob
Normal file
413
Batch/DTSBR204.cob
Normal file
@ -0,0 +1,413 @@
|
||||
00001 IDENTIFICATION DIVISION. 09/29/10
|
||||
00002 PROGRAM-ID. DTSBR204. DTSBR204
|
||||
00003 AUTHOR. NORTHROP GRUMMAN. LV005
|
||||
00004 DATE-WRITTEN. JULY 2004. DTSBR204
|
||||
00005 DATE-COMPILED. DTSBR204
|
||||
00006 SKIP3 DTSBR204
|
||||
00007 ***** DTSBR204
|
||||
00008 * DTSBR204
|
||||
00009 * FUNCTION: ACCOUNT NUMBER CHANGES ON SCREEN 24 REPORT. DTSBR204
|
||||
00010 * DTSBR204
|
||||
00011 * CALLING SEQUENCE: CICS SCREEN CREATED DTSIR204 RECORDS. DTSBR204
|
||||
00012 * DTSBD800 CALLS DTSBR204 USING DTSIR204 DTSBR204
|
||||
00013 * WHICH PRODUCES THE REPORTS. DTSBR204
|
||||
00014 * DTSBR204
|
||||
00015 * MODIFICATION HISTORY: DTSBR204
|
||||
00016 * DTSBR204
|
||||
00017 * 05-19-2004 INITIAL DEVELOPMENT DTSBR204
|
||||
00018 * REFERENCE RFP #RAP AUTHOR OF CHANGE - RW1DTSBR204
|
||||
00019 * DTSBR204
|
||||
00020 * 08-17-2010 MODIFIED TO UPDATE WG2 FILE TO SAVE ACCOUNT NUMBER DTSBR204
|
||||
00021 * CHANGES DTSBR204
|
||||
00022 * REFERENCE RFP AUTHOR OF CHANGE - GD DTSBR204
|
||||
00023 * DTSBR204
|
||||
00024 * MM-DD-YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXDTSBR204
|
||||
00025 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXDTSBR204
|
||||
00026 * REFERENCE RFP #**** PROGRAMMER: XXXDTSBR204
|
||||
00027 * DTSBR204
|
||||
00028 * DTSBR204
|
||||
00029 * DESCRIPTION: DTSBR204
|
||||
00030 * DTSBR204
|
||||
00031 * THIS MODULE PRODUCES A REPORT FOR THE ACCOUNT CHANGES DTSBR204
|
||||
00032 * FROM SCREEN 24. DTSBR204
|
||||
00033 * DTSBR204
|
||||
00034 * DTSBR204
|
||||
00035 * RECORDS READ: DTSBR204
|
||||
00036 * DTSBR204
|
||||
00037 * NONE. DTSBR204
|
||||
00038 * DTSBR204
|
||||
00039 * DTSBR204
|
||||
00040 * PRINTED OUTPUTS: DTSBR204
|
||||
00041 * DTSBR204
|
||||
00042 * 204R1 ACCOUNT CHANGES FROM SCREEN REPORT. DTSBR204
|
||||
00043 * DTSBR204
|
||||
00044 * DTSBR204
|
||||
00045 * RECORDS WRITTEN: DTSBR204
|
||||
00046 * DTSBR204
|
||||
00047 * NONE. DTSBR204
|
||||
00048 * DTSBR204
|
||||
00049 * DTSBR204
|
||||
00050 * MODULES CALLED: DTSBR204
|
||||
00051 * DTSBR204
|
||||
00052 * DTSBU001 DATE EDIT/CONVERSION MODULE DTSBR204
|
||||
00053 * DTSBU002 DATE ALPHA CONVERSION MODULE DTSBR204
|
||||
00054 * DTSBU004 YEAR/QUARTER CONVERSION. DTSBR204
|
||||
00055 * DTSBR204
|
||||
00056 ***** DTSBR204
|
||||
00057 DTSBR204
|
||||
00058 ENVIRONMENT DIVISION. DTSBR204
|
||||
00059 CONFIGURATION SECTION. DTSBR204
|
||||
00060 DTSBR204
|
||||
00061 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. DTSBR204
|
||||
00062 DTSBR204
|
||||
00063 INPUT-OUTPUT SECTION. DTSBR204
|
||||
00064 DTSBR204
|
||||
00065 FILE-CONTROL. DTSBR204
|
||||
00066 SELECT PRT-FILE1 ASSIGN TO RPT204R1. DTSBR204
|
||||
00067 DTSBR204
|
||||
00068 SELECT WG2-FILE ASSIGN TO DTSFWG2 DTSBR204
|
||||
00069 ORGANIZATION IS INDEXED DTSBR204
|
||||
00070 RECORD KEY IS WWG2-KEY-AREA OF WG2-REC DTSBR204
|
||||
00071 FILE STATUS IS WG2-STATUS DTSBR204
|
||||
00072 ACCESS IS DYNAMIC. DTSBR204
|
||||
00073 DTSBR204
|
||||
00074 DATA DIVISION. DTSBR204
|
||||
00075 DTSBR204
|
||||
00076 FILE SECTION. DTSBR204
|
||||
00077 DTSBR204
|
||||
00078 FD PRT-FILE1 DTSBR204
|
||||
00079 RECORDING MODE IS F DTSBR204
|
||||
00080 BLOCK CONTAINS 0 RECORDS DTSBR204
|
||||
00081 LABEL RECORDS ARE OMITTED. DTSBR204
|
||||
00082 DTSBR204
|
||||
00083 01 PRT-RECORD1. DTSBR204
|
||||
00084 05 FILLER PIC X(1). DTSBR204
|
||||
00085 05 PRT-RPT1 PIC X(132). DTSBR204
|
||||
00086 DTSBR204
|
||||
00087 FD WG2-FILE. DTSBR204
|
||||
00088 DTSBR204
|
||||
00089 01 WG2-REC. DTSBR204
|
||||
00090 ++INCLUDE DTSIWWG2 DTSBR204
|
||||
00091 DTSBR204
|
||||
00092 WORKING-STORAGE SECTION. DTSBR204
|
||||
000925 77 PAN-VALET PICTURE X(24) VALUE '005DTSBR204 09/29/10'. DTSBR204
|
||||
00093 DTSBR204
|
||||
00094 01 WRK-AREA. DTSBR204
|
||||
00095 DTSBR204
|
||||
00096 05 WG2-STATUS PIC X(02). DTSBR204
|
||||
00097 88 WG2-OK-88 VALUE '00'. DTSBR204
|
||||
00098 DTSBR204
|
||||
00099 05 WS-LINE-CNT PIC S9(03) COMP-3 VALUE 60. DTSBR204
|
||||
00100 05 WS-LINE-CNT2 PIC S9(03) COMP-3 VALUE +0. DTSBR204
|
||||
00101 05 WS-PAGE-CNT PIC S9(05) COMP-3 VALUE +0. DTSBR204
|
||||
00102 05 WS-SUM-FOOT-CNT1 PIC S9(07) COMP-3 VALUE +0. DTSBR204
|
||||
00103 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +204.DTSBR204
|
||||
00104 05 WRK-ABEND-MSG PIC X(60) VALUE SPACES. DTSBR204
|
||||
00105 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR204
|
||||
00106 05 WRK-DIFF-EMPL-CNT PIC S9(07) COMP-3 VALUE +0. DTSBR204
|
||||
00107 05 WRK-CALCULATE-PERCENT PIC 9(03)V9 VALUE ZEROS. DTSBR204
|
||||
00108 05 WRK-ERROR-TYPE PIC X(02) VALUE SPACES. DTSBR204
|
||||
00109 DTSBR204
|
||||
00110 01 HEADER-1. DTSBR204
|
||||
00111 05 FILLER PIC X(01) VALUE SPACE. DTSBR204
|
||||
00112 05 HDR1-RPT-NO PIC X(05) VALUE '204R1'. DTSBR204
|
||||
00113 05 FILLER PIC X(34) VALUE SPACES. DTSBR204
|
||||
00114 05 WS-AGY-NAME-LINE1 PIC X(50) VALUE SPACE. DTSBR204
|
||||
00115 05 FILLER PIC X(28) VALUE SPACES. DTSBR204
|
||||
00116 05 FILLER PIC X(05) DTSBR204
|
||||
00117 VALUE 'DATE:'. DTSBR204
|
||||
00118 05 FILLER PIC X(01) VALUE SPACE. DTSBR204
|
||||
00119 05 WS-SYS-DATE PIC X(08) VALUE SPACE. DTSBR204
|
||||
00120 DTSBR204
|
||||
00121 01 HEADER-2. DTSBR204
|
||||
00122 05 FILLER PIC X(40) VALUE SPACES. DTSBR204
|
||||
00123 05 WS-AGY-NAME-LINE2 PIC X(50) VALUE SPACE. DTSBR204
|
||||
00124 05 FILLER PIC X(28) VALUE SPACES. DTSBR204
|
||||
00125 05 FILLER PIC X(05) DTSBR204
|
||||
00126 VALUE 'TIME:'. DTSBR204
|
||||
00127 05 FILLER PIC X(01) VALUE SPACE. DTSBR204
|
||||
00128 05 WS-SYS-TIME PIC X(08) VALUE SPACE. DTSBR204
|
||||
00129 DTSBR204
|
||||
00130 01 HEADER-3. DTSBR204
|
||||
00131 05 FILLER PIC X(01) VALUE SPACE. DTSBR204
|
||||
00132 05 FILLER PIC X(27) DTSBR204
|
||||
00133 VALUE 'ROUTE TO: TAX PROGRAMMER '. DTSBR204
|
||||
00134 05 FILLER PIC X(90) VALUE SPACES. DTSBR204
|
||||
00135 05 FILLER PIC X(05) DTSBR204
|
||||
00136 VALUE 'PAGE:'. DTSBR204
|
||||
00137 05 FILLER PIC X(03) VALUE SPACES. DTSBR204
|
||||
00138 05 HDR3-PAGE-CNT PIC ZZ,ZZ9. DTSBR204
|
||||
00139 DTSBR204
|
||||
00140 01 HEADER-4. DTSBR204
|
||||
00141 05 FILLER PIC X(01) VALUE SPACE. DTSBR204
|
||||
00142 05 FILLER PIC X(46) VALUE SPACE. DTSBR204
|
||||
00143 05 FILLER PIC X(35) DTSBR204
|
||||
00144 VALUE 'ACCOUNT NUMBER CHANGES ON 24 SCREEN'. DTSBR204
|
||||
00145 05 FILLER PIC X(53) VALUE SPACE. DTSBR204
|
||||
00146 DTSBR204
|
||||
00147 01 HEADER-5 PIC X(133) VALUE SPACES. DTSBR204
|
||||
00148 DTSBR204
|
||||
00149 01 HEADER-6. DTSBR204
|
||||
00150 05 FILLER PIC X(01) VALUE SPACE. DTSBR204
|
||||
00151 05 FILLER PIC X(02) VALUE SPACES. DTSBR204
|
||||
00152 05 FILLER PIC X(11) DTSBR204
|
||||
00153 VALUE 'ORIG EMP NO'. DTSBR204
|
||||
00154 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00155 05 FILLER PIC X(10) DTSBR204
|
||||
00156 VALUE 'NEW EMP NO'. DTSBR204
|
||||
00157 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00158 05 FILLER PIC X(07) DTSBR204
|
||||
00159 VALUE 'QUARTER'. DTSBR204
|
||||
00160 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00161 05 FILLER PIC X(05) DTSBR204
|
||||
00162 VALUE 'BATCH'. DTSBR204
|
||||
00163 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00164 05 FILLER PIC X(04) DTSBR204
|
||||
00165 VALUE 'ITEM'. DTSBR204
|
||||
00166 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00167 05 FILLER PIC X(10) DTSBR204
|
||||
00168 VALUE 'TOTAL WAGE'. DTSBR204
|
||||
00169 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00170 05 FILLER PIC X(06) DTSBR204
|
||||
00171 VALUE 'OP ID'. DTSBR204
|
||||
00172 05 FILLER PIC X(06) VALUE SPACES. DTSBR204
|
||||
00173 05 FILLER PIC X(11) DTSBR204
|
||||
00174 VALUE 'CHANGE DATE'. DTSBR204
|
||||
00175 05 FILLER PIC X(36) VALUE SPACES. DTSBR204
|
||||
00176 DTSBR204
|
||||
00177 01 HEADER-7 PIC X(133) VALUE SPACES. DTSBR204
|
||||
00178 DTSBR204
|
||||
00179 01 DETAIL-LINE. DTSBR204
|
||||
00180 05 FILLER PIC X(01) VALUE SPACE. DTSBR204
|
||||
00181 05 FILLER PIC X(02) VALUE SPACES. DTSBR204
|
||||
00182 05 WS-ORIG-EMP-NO PIC 999B999 BLANK WHEN ZERO.DTSBR204
|
||||
00183 05 FILLER PIC X(08) VALUE SPACE. DTSBR204
|
||||
00184 05 WS-NEW-EMP-NO PIC 999B999 BLANK WHEN ZERO.DTSBR204
|
||||
00185 05 FILLER PIC X(07) VALUE SPACE. DTSBR204
|
||||
00186 05 WS-QUARTER PIC X(06). DTSBR204
|
||||
00187 05 FILLER PIC X(05) VALUE SPACE. DTSBR204
|
||||
00188 05 WS-BATCH-NO PIC X(05). DTSBR204
|
||||
00189 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00190 05 WS-ITEM-NO PIC X(03). DTSBR204
|
||||
00191 05 FILLER PIC X(02) VALUE SPACES. DTSBR204
|
||||
00192 05 WS-TOTAL-WAGE PIC $$,$$$,$$9.99. DTSBR204
|
||||
00193 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00194 05 WS-OP-ID PIC X(08). DTSBR204
|
||||
00195 05 FILLER PIC X(04) VALUE SPACES. DTSBR204
|
||||
00196 05 WS-CHANGE-DATE PIC X(10). DTSBR204
|
||||
00197 05 WS-MSG PIC X(37) VALUE SPACES. DTSBR204
|
||||
00198 DTSBR204
|
||||
00199 01 CONTROL-SUM-FOOTING. DTSBR204
|
||||
00200 DTSBR204
|
||||
00201 05 SUM-LINE-5 PIC X(133) VALUE SPACES. DTSBR204
|
||||
00202 05 SUM-LINE-6. DTSBR204
|
||||
00203 10 FILLER PIC X(28) VALUE SPACES. DTSBR204
|
||||
00204 10 FILLER PIC X(37) DTSBR204
|
||||
00205 VALUE 'NUMBER OF EMPLOYER ACCOUNTS CHANGED: '. DTSBR204
|
||||
00206 10 WS-SUM-FOOT-NUMBER PIC ZZ,ZZ9. DTSBR204
|
||||
00207 10 FILLER PIC X(25) VALUE SPACES. DTSBR204
|
||||
00208 05 SUM-ASTR-7. DTSBR204
|
||||
00209 10 FILLER PIC X(26) VALUE SPACES. DTSBR204
|
||||
00210 10 FILLER PIC X(26) DTSBR204
|
||||
00211 VALUE ' *** END OF REPORT '. DTSBR204
|
||||
00212 10 FILLER PIC X(81) VALUE SPACES. DTSBR204
|
||||
00213 DTSBR204
|
||||
00214 01 L001-LINK-AREA. DTSBR204
|
||||
00215 ++INCLUDE DTSIL001 DTSBR204
|
||||
00216 EJECT DTSBR204
|
||||
00217 01 L002-LINK-AREA. DTSBR204
|
||||
00218 ++INCLUDE DTSIL002 DTSBR204
|
||||
00219 DTSBR204
|
||||
00220 01 L004-LINK-AREA. DTSBR204
|
||||
00221 ++INCLUDE DTSIL004 DTSBR204
|
||||
00222 DTSBR204
|
||||
00223 DTSBR204
|
||||
00224 LINKAGE SECTION. DTSBR204
|
||||
00225 DTSBR204
|
||||
00226 01 LRCM-LINK-AREA. DTSBR204
|
||||
00227 ++INCLUDE DTSILRCM DTSBR204
|
||||
00228 DTSBR204
|
||||
00229 01 R204-REC. DTSBR204
|
||||
00230 ++INCLUDE DTSIR204 DTSBR204
|
||||
00231 EJECT DTSBR204
|
||||
00232 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR204
|
||||
00233 R204-REC. DTSBR204
|
||||
00234 DTSBR204
|
||||
00235 IF FIRST-TIME-IND = 'Y' DTSBR204
|
||||
00236 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR204
|
||||
00237 MOVE 'N' TO FIRST-TIME-IND. DTSBR204
|
||||
00238 DTSBR204
|
||||
00239 IF LRCM-EOR-88 DTSBR204
|
||||
00240 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR204
|
||||
00241 ELSE DTSBR204
|
||||
00242 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR204
|
||||
00243 DTSBR204
|
||||
00244 GOBACK. DTSBR204
|
||||
00245 DTSBR204
|
||||
00246 I1000-INITIATE. DTSBR204
|
||||
00247 OPEN OUTPUT PRT-FILE1. DTSBR204
|
||||
00248 OPEN I-O WG2-FILE. DTSBR204
|
||||
00249 IF WG2-OK-88 DTSBR204
|
||||
00250 NEXT SENTENCE DTSBR204
|
||||
00251 ELSE DTSBR204
|
||||
00252 MOVE 'CANNOT OPEN WG2 FILE ' TO WRK-ABEND-MSG DTSBR204
|
||||
00253 PERFORM S999-ABEND THRU S999-EXIT DTSBR204
|
||||
00254 END-IF. DTSBR204
|
||||
00255 DTSBR204
|
||||
00256 MOVE LRCM-SYS-DATE TO WS-SYS-DATE. DTSBR204
|
||||
00257 MOVE LRCM-SYS-TIME TO WS-SYS-TIME. DTSBR204
|
||||
00258 MOVE LRCM-AGY-NAME-LINE1 TO WS-AGY-NAME-LINE1. DTSBR204
|
||||
00259 MOVE LRCM-AGY-NAME-LINE2 TO WS-AGY-NAME-LINE2. DTSBR204
|
||||
00260 MOVE SPACES TO PRT-RECORD1. DTSBR204
|
||||
00261 DTSBR204
|
||||
00262 I1000-EXIT. DTSBR204
|
||||
00263 EXIT. DTSBR204
|
||||
00264 DTSBR204
|
||||
00265 P1000-PROCESS. DTSBR204
|
||||
00266 DTSBR204
|
||||
00267 PERFORM P3000-PRINT-HEADER THRU P3000-EXIT. DTSBR204
|
||||
00268 MOVE R204-ORIG-EMP-NO TO WS-ORIG-EMP-NO. DTSBR204
|
||||
00269 MOVE R204-NEW-EMP-NO TO WS-NEW-EMP-NO. DTSBR204
|
||||
00270 DTSBR204
|
||||
00271 MOVE R204-YRQ TO L004-QTR-5-9 DTSBR204
|
||||
00272 PERFORM S004-FROM-5 THRU S004-EXIT DTSBR204
|
||||
00273 IF L004-INVALID-QTR DTSBR204
|
||||
00274 MOVE 'INVALID SECURED YEAR/QTR ' TO WRK-ABEND-MSG DTSBR204
|
||||
00275 PERFORM S999-ABEND THRU S999-EXIT DTSBR204
|
||||
00276 ELSE DTSBR204
|
||||
00277 MOVE L004-SLASH-5-QTR TO WS-QUARTER DTSBR204
|
||||
00278 END-IF. DTSBR204
|
||||
00279 MOVE SPACES TO WS-MSG. DTSBR204
|
||||
00280 MOVE R204-BATCH-NO TO WS-BATCH-NO. DTSBR204
|
||||
00281 MOVE R204-ITEM-NO TO WS-ITEM-NO. DTSBR204
|
||||
00282 MOVE R204-TOT-WAGE TO WS-TOTAL-WAGE. DTSBR204
|
||||
00283 MOVE R204-OP-ID TO WS-OP-ID. DTSBR204
|
||||
00284 DTSBR204
|
||||
00285 MOVE R204-CHANGE-DATE TO L001-FED-8-DATE-9. DTSBR204
|
||||
00286 SET L001-FROM-FED-8 TO TRUE. DTSBR204
|
||||
00287 PERFORM S001-DATE THRU S001-EXIT. DTSBR204
|
||||
00288 IF L001-CAL-8-DATE-9 = ZEROS DTSBR204
|
||||
00289 MOVE SPACES TO WS-CHANGE-DATE DTSBR204
|
||||
00290 ELSE DTSBR204
|
||||
00291 MOVE L001-SLASH-8-DATE TO WS-CHANGE-DATE. DTSBR204
|
||||
00292 DTSBR204
|
||||
00293 PERFORM P1100-WRITE-WG2 THRU P1100-EXIT. DTSBR204
|
||||
00294 DTSBR204
|
||||
00295 IF WG2-STATUS = '22' DTSBR204
|
||||
00296 MOVE '**** ERROR ** DTSBR204 DUPLICATE WG2 REC' TO WS-MSG DTSBR204
|
||||
00297 ELSE DTSBR204
|
||||
00298 MOVE SPACES TO WS-MSG. DTSBR204
|
||||
00299 DTSBR204
|
||||
00300 WRITE PRT-RECORD1 FROM DETAIL-LINE AFTER 1. DTSBR204
|
||||
00301 ADD +1 TO WS-LINE-CNT2 DTSBR204
|
||||
00302 ADD +1 TO WS-SUM-FOOT-CNT1. DTSBR204
|
||||
00303 DTSBR204
|
||||
00304 P1000-EXIT. DTSBR204
|
||||
00305 EXIT. DTSBR204
|
||||
00306 DTSBR204
|
||||
00307 P1100-WRITE-WG2. DTSBR204
|
||||
00308 MOVE R204-ORIG-EMP-NO TO WWG2-ORIG-EMP-NO. DTSBR204
|
||||
00309 MOVE R204-NEW-EMP-NO TO WWG2-RPT-EMP-NO. DTSBR204
|
||||
00310 MOVE R204-YRQ TO WWG2-YRQ. DTSBR204
|
||||
00311 MOVE R204-BATCH-NO TO WWG2-BATCH-NO. DTSBR204
|
||||
00312 MOVE R204-ITEM-NO TO WWG2-ITEM-NO. DTSBR204
|
||||
00313 MOVE R204-TOT-WAGE TO WWG2-WAGES. DTSBR204
|
||||
00314 MOVE R204-OP-ID TO WWG2-CHANGE-OPID. DTSBR204
|
||||
00315 MOVE R204-CHANGE-DATE TO WWG2-PROCESS-DT. DTSBR204
|
||||
00316 DTSBR204
|
||||
00317 WRITE WG2-REC. DTSBR204
|
||||
00318 IF WG2-OK-88 DTSBR204
|
||||
00319 NEXT SENTENCE DTSBR204
|
||||
00320 ELSE DTSBR204
|
||||
00321 IF WG2-STATUS = '22' DTSBR204
|
||||
00322 DISPLAY 'DTSBR204 DUP WG2 REC ' DTSBR204
|
||||
00323 DISPLAY DETAIL-LINE DTSBR204
|
||||
00324 ELSE DTSBR204
|
||||
00325 MOVE 'CANNOT WRITE WG2 REC ' TO WRK-ABEND-MSG DTSBR204
|
||||
00326 PERFORM S999-ABEND THRU S999-EXIT DTSBR204
|
||||
00327 END-IF DTSBR204
|
||||
00328 END-IF. DTSBR204
|
||||
00329 DTSBR204
|
||||
00330 P1100-EXIT. DTSBR204
|
||||
00331 EXIT. DTSBR204
|
||||
00332 DTSBR204
|
||||
00333 P3000-PRINT-HEADER. DTSBR204
|
||||
00334 IF WS-LINE-CNT GREATER 56 OR DTSBR204
|
||||
00335 WS-LINE-CNT2 GREATER 56 DTSBR204
|
||||
00336 MOVE +0 TO WS-LINE-CNT DTSBR204
|
||||
00337 MOVE +0 TO WS-LINE-CNT2 DTSBR204
|
||||
00338 ADD +1 TO WS-PAGE-CNT DTSBR204
|
||||
00339 MOVE WS-PAGE-CNT TO HDR3-PAGE-CNT DTSBR204
|
||||
00340 WRITE PRT-RECORD1 FROM HEADER-1 AFTER TOP-OF-PAGE DTSBR204
|
||||
00341 WRITE PRT-RECORD1 FROM HEADER-2 AFTER 1 DTSBR204
|
||||
00342 WRITE PRT-RECORD1 FROM HEADER-3 AFTER 1 DTSBR204
|
||||
00343 WRITE PRT-RECORD1 FROM HEADER-4 AFTER 1 DTSBR204
|
||||
00344 WRITE PRT-RECORD1 FROM HEADER-5 AFTER 1 DTSBR204
|
||||
00345 WRITE PRT-RECORD1 FROM HEADER-6 AFTER 1 DTSBR204
|
||||
00346 WRITE PRT-RECORD1 FROM HEADER-7 AFTER 1 DTSBR204
|
||||
00347 ADD +7 TO WS-LINE-CNT2. DTSBR204
|
||||
00348 DTSBR204
|
||||
00349 P3000-EXIT. DTSBR204
|
||||
00350 EXIT. DTSBR204
|
||||
00351 DTSBR204
|
||||
00352 T1000-TERMINATE. DTSBR204
|
||||
00353 * PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR204
|
||||
00354 DTSBR204
|
||||
00355 IF WS-LINE-CNT2 > 56 OR WS-LINE-CNT > 56 DTSBR204
|
||||
00356 PERFORM P3000-PRINT-HEADER THRU P3000-EXIT DTSBR204
|
||||
00357 END-IF. DTSBR204
|
||||
00358 DTSBR204
|
||||
00359 MOVE WS-SUM-FOOT-CNT1 TO WS-SUM-FOOT-NUMBER. DTSBR204
|
||||
00360 WRITE PRT-RECORD1 FROM SUM-LINE-5 AFTER 1. DTSBR204
|
||||
00361 WRITE PRT-RECORD1 FROM SUM-LINE-6 AFTER 2. DTSBR204
|
||||
00362 WRITE PRT-RECORD1 FROM SUM-ASTR-7 AFTER 2. DTSBR204
|
||||
00363 DTSBR204
|
||||
00364 CLOSE PRT-FILE1 DTSBR204
|
||||
00365 WG2-FILE. DTSBR204
|
||||
00366 DTSBR204
|
||||
00367 T1000-EXIT. DTSBR204
|
||||
00368 EXIT. DTSBR204
|
||||
00369 DTSBR204
|
||||
00370 S001-DATE. DTSBR204
|
||||
00371 CALL 'DTSBU001' USING L001-LINK-AREA. DTSBR204
|
||||
00372 DTSBR204
|
||||
00373 S001-EXIT. DTSBR204
|
||||
00374 EXIT. DTSBR204
|
||||
00375 DTSBR204
|
||||
00376 S002-DATE-ALPHA. DTSBR204
|
||||
00377 CALL 'DTSBU002' USING L002-LINK-AREA. DTSBR204
|
||||
00378 DTSBR204
|
||||
00379 S002-EXIT. DTSBR204
|
||||
00380 EXIT. DTSBR204
|
||||
00381 DTSBR204
|
||||
00382 S004-FROM-DATE. DTSBR204
|
||||
00383 SET L004-FROM-DATE TO TRUE. DTSBR204
|
||||
00384 GO TO S004-YRQ. DTSBR204
|
||||
00385 DTSBR204
|
||||
00386 S004-FROM-3. DTSBR204
|
||||
00387 SET L004-FROM-3 TO TRUE. DTSBR204
|
||||
00388 GO TO S004-YRQ. DTSBR204
|
||||
00389 DTSBR204
|
||||
00390 S004-FROM-5. DTSBR204
|
||||
00391 SET L004-FROM-5 TO TRUE. DTSBR204
|
||||
00392 GO TO S004-YRQ. DTSBR204
|
||||
00393 DTSBR204
|
||||
00394 S004-FROM-ABS. DTSBR204
|
||||
00395 SET L004-FROM-ABS TO TRUE. DTSBR204
|
||||
00396 GO TO S004-YRQ. DTSBR204
|
||||
00397 DTSBR204
|
||||
00398 S004-YRQ. DTSBR204
|
||||
00399 CALL 'DTSBU004' USING L004-LINK-AREA. DTSBR204
|
||||
00400 DTSBR204
|
||||
00401 S004-EXIT. DTSBR204
|
||||
00402 EXIT. DTSBR204
|
||||
00403 DTSBR204
|
||||
00404 S999-ABEND. DTSBR204
|
||||
00405 DISPLAY '*** DTSBR427 ABENDING. ' DTSBR204
|
||||
00406 WRK-ABEND-MSG. DTSBR204
|
||||
00407 DTSBR204
|
||||
00408 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR204
|
||||
00409 DTSBR204
|
||||
00410 S999-EXIT. DTSBR204
|
||||
00411 EXIT. DTSBR204
|
||||
00412 DTSBR204
|
||||
Reference in New Issue
Block a user