DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
354
Batch/DTSBR708.cob
Normal file
354
Batch/DTSBR708.cob
Normal file
@ -0,0 +1,354 @@
|
||||
00001 IDENTIFICATION DIVISION. 11/29/01
|
||||
00002 PROGRAM-ID. DTSBR708. DTSBR708
|
||||
00003 AUTHOR. MT DEPT OF LABOR/UI PROGRAMMING SECTION LV014
|
||||
00004 DATE-WRITTEN. DECEMBER 1994. DTSBR708
|
||||
00005 DATE-COMPILED. DTSBR708
|
||||
00006 DTSBR708
|
||||
00007 ***** DTSBR708
|
||||
00008 * DTSBR708
|
||||
00009 * FUNCTION: FUTA POTENTIAL NON-FEDERAL FILERS. DTSBR708
|
||||
00010 * DTSBR708
|
||||
00011 * DTSBR708
|
||||
00012 * MODIFICATION HISTORY: DTSBR708
|
||||
00013 * DTSBR708
|
||||
00014 * 12-09-94 INITIAL DEVELOPMENT DTSBR708
|
||||
00015 * REFERENCE RFP #RAP AUTHOR OF CHANGE - SFW DTSBR708
|
||||
00016 * DTSBR708
|
||||
00017 * 11-13-97 TAX YEAR 1996 MODIFICATIONS. FOUR DIGIT YEAR. DTSBR708
|
||||
00018 * REFERENCE RFP #TCL 222 AUTHOR OF CHANGE - EHH DTSBR708
|
||||
00019 * DTSBR708
|
||||
00020 * 10/19/1998 ADD TWO NEW "PAYMENT" DATA ELEMENTS ('THRU 4/15' DTSBR708
|
||||
00021 * & 'AFTER 4/15'). USED 'COBOL FOR MVS' COMPILE. DTSBR708
|
||||
00022 * REFERENCE: TCL 237 PROGRAMMER: KDN DTSBR708
|
||||
00023 * DTSBR708
|
||||
00024 * MM-DD-YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR708
|
||||
00025 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR708
|
||||
00026 * REFERENCE: XXX PROGRAMMER: XXX DTSBR708
|
||||
00027 * DTSBR708
|
||||
00028 * DTSBR708
|
||||
00029 * DESCRIPTION: DTSBR708
|
||||
00030 * DTSBR708
|
||||
00031 * THIS MODULE GENERATES A DETAIL LINE FOR EVERY EMPLOYER DTSBR708
|
||||
00032 * ON THE MONTANA TAX SYSTEM MASTER FILE WITH WAGES IN ONE DTSBR708
|
||||
00033 * OR MORE QUARTERS OF THE PROCESSING YEAR BUT NO MATCH ON DTSBR708
|
||||
00034 * THE IRS FORM 940 IDENTIFICATION TAPE DURING YEARLY FUTA DTSBR708
|
||||
00035 * PROCESSING. DTSBR708
|
||||
00036 * DTSBR708
|
||||
00037 * DTSBR708
|
||||
00038 * RECORDS READ: DTSBR708
|
||||
00039 * DTSBR708
|
||||
00040 * NONE. DTSBR708
|
||||
00041 * DTSBR708
|
||||
00042 * DTSBR708
|
||||
00043 * PRINTED OUTPUTS: DTSBR708
|
||||
00044 * DTSBR708
|
||||
00045 * 708R1 FUTA POTENTIAL NON-FEDERAL FILERS DTSBR708
|
||||
00046 * DTSBR708
|
||||
00047 * DTSBR708
|
||||
00048 * RECORDS WRITTEN: DTSBR708
|
||||
00049 * DTSBR708
|
||||
00050 * NONE. DTSBR708
|
||||
00051 * DTSBR708
|
||||
00052 * DTSBR708
|
||||
00053 * MODULES CALLED: DTSBR708
|
||||
00054 * DTSBR708
|
||||
00055 * DTSBU056 RATE DISPLAY MODULE DTSBR708
|
||||
00056 * DTSBR708
|
||||
00057 * DTSBR708
|
||||
00058 ***** DTSBR708
|
||||
00059 DTSBR708
|
||||
00060 ENVIRONMENT DIVISION. DTSBR708
|
||||
00061 DTSBR708
|
||||
00062 CONFIGURATION SECTION. DTSBR708
|
||||
00063 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. DTSBR708
|
||||
00064 DTSBR708
|
||||
00065 INPUT-OUTPUT SECTION. DTSBR708
|
||||
00066 DTSBR708
|
||||
00067 FILE-CONTROL. DTSBR708
|
||||
00068 SELECT PRT-FILE ASSIGN TO RPT708R1. DTSBR708
|
||||
00069 DTSBR708
|
||||
00070 DATA DIVISION. DTSBR708
|
||||
00071 DTSBR708
|
||||
00072 FILE SECTION. DTSBR708
|
||||
00073 DTSBR708
|
||||
00074 FD PRT-FILE DTSBR708
|
||||
00075 RECORDING MODE IS F. DTSBR708
|
||||
00076 01 REPORT-LISTING1 PIC X(133). DTSBR708
|
||||
00077 DTSBR708
|
||||
00078 WORKING-STORAGE SECTION. DTSBR708
|
||||
000785 77 PAN-VALET PICTURE X(24) VALUE '014DTSBR708 11/29/01'. DTSBR708
|
||||
00079 DTSBR708
|
||||
00080 01 WRK-AREA. DTSBR708
|
||||
00081 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +708.DTSBR708
|
||||
00082 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR708
|
||||
00083 05 WS-SUB PIC S9(04) COMP. DTSBR708
|
||||
00084 05 WS-TAX-PERIOD PIC 9(07). DTSBR708
|
||||
00085 05 WS-NUMBER-ONE PIC S9(05) COMP-3 VALUE +0. DTSBR708
|
||||
00086 DTSBR708
|
||||
00087 05 WS-LINE-CNT PIC S9(02) COMP-3 VALUE 60. DTSBR708
|
||||
00088 05 WS-LINE-CNT2 PIC S9(02) COMP-3 VALUE +0. DTSBR708
|
||||
00089 05 WS-PAGE-CNT PIC S9(03) COMP-3 VALUE +0. DTSBR708
|
||||
00090 DTSBR708
|
||||
00091 05 WS-WAGE-RATE-DISPLAY-TABLE. DTSBR708
|
||||
00092 10 WS-DISPLAY-OCCURS OCCURS 4 TIMES. DTSBR708
|
||||
00093 15 WS-TAX-WAGE-DISPLAY DTSBR708
|
||||
00094 PIC X(16). DTSBR708
|
||||
00095 15 WS-TAX-WAGE-EDIT DTSBR708
|
||||
00096 REDEFINES WS-TAX-WAGE-DISPLAY DTSBR708
|
||||
00097 PIC ZZZZZ,ZZZ,ZZ9.99. DTSBR708
|
||||
00098 15 WS-RATE-DISPLAY PIC X(07). DTSBR708
|
||||
00099 DTSBR708
|
||||
00100 01 L056-LINK-AREA. DTSBR708
|
||||
00101 ++INCLUDE DTSIL056 DTSBR708
|
||||
00102 EJECT DTSBR708
|
||||
00103 DTSBR708
|
||||
00104 01 PAGE-HEADING. DTSBR708
|
||||
00105 05 HDR-LINE-1. DTSBR708
|
||||
00106 10 FILLER PIC X(01) VALUE SPACE. DTSBR708
|
||||
00107 10 FILLER PIC X(05) DTSBR708
|
||||
00108 VALUE '708R1'. DTSBR708
|
||||
00109 10 FILLER PIC X(35) VALUE SPACES. DTSBR708
|
||||
00110 10 HDR-AGY-NAME-LINE1 PIC X(50). DTSBR708
|
||||
00111 10 FILLER PIC X(28) VALUE SPACES. DTSBR708
|
||||
00112 10 FILLER PIC X(05) DTSBR708
|
||||
00113 VALUE 'DATE:'. DTSBR708
|
||||
00114 10 FILLER PIC X(01) VALUE SPACE. DTSBR708
|
||||
00115 10 HDR-SYS-DATE PIC X(08). DTSBR708
|
||||
00116 DTSBR708
|
||||
00117 05 HDR-LINE-2. DTSBR708
|
||||
00118 10 FILLER PIC X(41) VALUE SPACES. DTSBR708
|
||||
00119 10 HDR-AGY-NAME-LINE2 PIC X(50). DTSBR708
|
||||
00120 10 FILLER PIC X(28) VALUE SPACES. DTSBR708
|
||||
00121 10 FILLER PIC X(05) DTSBR708
|
||||
00122 VALUE 'TIME:'. DTSBR708
|
||||
00123 10 FILLER PIC X(01) VALUE SPACE. DTSBR708
|
||||
00124 10 HDR-SYS-TIME PIC X(08). DTSBR708
|
||||
00125 DTSBR708
|
||||
00126 05 HDR-LINE-3. DTSBR708
|
||||
00127 10 FILLER PIC X(01) VALUE SPACE. DTSBR708
|
||||
00128 10 FILLER PIC X(29) DTSBR708
|
||||
00129 VALUE 'ROUTE TO: CHIEF, TAX DIVISION'. DTSBR708
|
||||
00130 10 FILLER PIC X(89) VALUE SPACES. DTSBR708
|
||||
00131 10 FILLER PIC X(05) DTSBR708
|
||||
00132 VALUE 'PAGE:'. DTSBR708
|
||||
00133 10 FILLER PIC X(03) VALUE SPACES. DTSBR708
|
||||
00134 10 HDR-PAGE-CNT PIC ZZ,ZZ9. DTSBR708
|
||||
00135 DTSBR708
|
||||
00136 05 HDR-LINE-4. DTSBR708
|
||||
00137 10 FILLER PIC X(12) VALUE SPACES. DTSBR708
|
||||
00138 10 FILLER PIC X(20) DTSBR708
|
||||
00139 VALUE ' '. DTSBR708
|
||||
00140 10 FILLER PIC X(18) VALUE SPACES. DTSBR708
|
||||
00141 10 FILLER PIC X(33) DTSBR708
|
||||
00142 VALUE 'FUTA POTENTIAL NON-FEDERAL FILERS'. DTSBR708
|
||||
00143 DTSBR708
|
||||
00144 05 HDR-LINE-5 PIC X(133) VALUE SPACES. DTSBR708
|
||||
00145 05 HDR-LINE-6 PIC X(133) VALUE SPACES. DTSBR708
|
||||
00146 05 HDR-LINE-7. DTSBR708
|
||||
00147 10 FILLER PIC X(24) VALUE SPACES. DTSBR708
|
||||
00148 10 FILLER PIC X(03) DTSBR708
|
||||
00149 VALUE 'TAX'. DTSBR708
|
||||
00150 10 FILLER PIC X(08) VALUE SPACES. DTSBR708
|
||||
00151 10 FILLER PIC X(08) DTSBR708
|
||||
00152 VALUE 'PAYMENTS'. DTSBR708
|
||||
00153 10 FILLER PIC X(07) VALUE SPACES. DTSBR708
|
||||
00154 10 FILLER PIC X(08) DTSBR708
|
||||
00155 VALUE 'PAYMENTS'. DTSBR708
|
||||
00156 10 FILLER PIC X(07) VALUE SPACES. DTSBR708
|
||||
00157 10 FILLER PIC X(08) DTSBR708
|
||||
00158 VALUE 'PAYMENTS'. DTSBR708
|
||||
00159 10 FILLER PIC X(07) VALUE SPACES. DTSBR708
|
||||
00160 10 FILLER PIC X(17) DTSBR708
|
||||
00161 VALUE 'TAX WAGES @ RTE 1'. DTSBR708
|
||||
00162 10 FILLER PIC X(05) VALUE SPACES. DTSBR708
|
||||
00163 10 FILLER PIC X(17) DTSBR708
|
||||
00164 VALUE 'TAX WAGES @ RTE 2'. DTSBR708
|
||||
00165 DTSBR708
|
||||
00166 05 HDR-LINE-8. DTSBR708
|
||||
00167 10 FILLER PIC X(01) VALUE SPACE. DTSBR708
|
||||
00168 10 FILLER PIC X(26) DTSBR708
|
||||
00169 VALUE ' EMP NO FEIN PER'. DTSBR708
|
||||
00170 10 FILLER PIC X(05) VALUE SPACES. DTSBR708
|
||||
00171 10 FILLER PIC X(11) DTSBR708
|
||||
00172 VALUE 'PRIOR 02/01'. DTSBR708
|
||||
00173 10 FILLER PIC X(04) VALUE SPACES. DTSBR708
|
||||
00174 10 FILLER PIC X(11) DTSBR708
|
||||
00175 VALUE '02/01-02/10'. DTSBR708
|
||||
00176 10 FILLER PIC X(04) VALUE SPACES. DTSBR708
|
||||
00177 10 FILLER PIC X(11) DTSBR708
|
||||
00178 VALUE 'AFTER 02/10'. DTSBR708
|
||||
00179 10 FILLER PIC X(07) VALUE SPACES. DTSBR708
|
||||
00180 10 FILLER PIC X(17) DTSBR708
|
||||
00181 VALUE 'TAX WAGES @ RTE 3'. DTSBR708
|
||||
00182 10 FILLER PIC X(05) VALUE SPACES. DTSBR708
|
||||
00183 10 FILLER PIC X(17) DTSBR708
|
||||
00184 VALUE 'TAX WAGES @ RTE 4'. DTSBR708
|
||||
00185 DTSBR708
|
||||
00186 01 DETAIL-LINE1. DTSBR708
|
||||
00187 05 DTL1-LINE-2. DTSBR708
|
||||
00188 10 FILLER PIC X(01) VALUE SPACE. DTSBR708
|
||||
00189 10 DTL1-EMP-NO PIC 999B999. DTSBR708
|
||||
00190 10 FILLER PIC X(02) VALUE SPACES. DTSBR708
|
||||
00191 10 DTL1-FEIN PIC 99B9(07). DTSBR708
|
||||
00192 10 FILLER PIC X(03) VALUE SPACES. DTSBR708
|
||||
00193 10 DTL1-TAX-PERIOD-4 PIC 9(04). DTSBR708
|
||||
00194 10 FILLER PIC X(03) VALUE SPACES. DTSBR708
|
||||
00195 10 DTL1-ONTIME PIC ZZ,ZZZ,ZZ9.99. DTSBR708
|
||||
00196 10 FILLER PIC X(02) VALUE SPACES. DTSBR708
|
||||
00197 10 DTL1-GRACE PIC ZZ,ZZZ,ZZ9.99. DTSBR708
|
||||
00198 10 FILLER PIC X(02) VALUE SPACES. DTSBR708
|
||||
00199 10 DTL1-LATE PIC ZZ,ZZZ,ZZ9.99. DTSBR708
|
||||
00200 10 FILLER PIC X(03) VALUE SPACES. DTSBR708
|
||||
00201 10 DTL1-TAX-WAGE-DIS-1 PIC X(16). DTSBR708
|
||||
00202 10 FILLER PIC X(02) VALUE SPACES. DTSBR708
|
||||
00203 10 DTL1-RATE-DIS-1 PIC X(04). DTSBR708
|
||||
00204 10 DTL1-TAX-WAGE-DIS-2 PIC X(16). DTSBR708
|
||||
00205 10 FILLER PIC X(02) VALUE SPACES. DTSBR708
|
||||
00206 10 DTL1-RATE-DIS-2 PIC X(04). DTSBR708
|
||||
00207 DTSBR708
|
||||
00208 01 DETAIL-LINE2. DTSBR708
|
||||
00209 05 DTL2-LINE-1. DTSBR708
|
||||
00210 10 FILLER PIC X(76) VALUE SPACES. DTSBR708
|
||||
00211 10 DTL2-TAX-WAGE-DIS-3 PIC X(16). DTSBR708
|
||||
00212 10 FILLER PIC X(02) VALUE SPACES. DTSBR708
|
||||
00213 10 DTL2-RATE-DIS-3 PIC X(04). DTSBR708
|
||||
00214 10 DTL2-TAX-WAGE-DIS-4 PIC X(16). DTSBR708
|
||||
00215 10 FILLER PIC X(02) VALUE SPACES. DTSBR708
|
||||
00216 10 DTL2-RATE-DIS-4 PIC X(04). DTSBR708
|
||||
00217 DTSBR708
|
||||
00218 01 CONTROL-FOOTING-FINAL. DTSBR708
|
||||
00219 05 CFF-LINE-4. DTSBR708
|
||||
00220 10 FILLER PIC X(11) VALUE SPACES. DTSBR708
|
||||
00221 10 CFF-NUMBER-ONE PIC ZZZZ,ZZ9. DTSBR708
|
||||
00222 10 FILLER PIC X(01) VALUE SPACE. DTSBR708
|
||||
00223 10 FILLER PIC X(28) DTSBR708
|
||||
00224 VALUE 'POTENTIAL NON-FEDERAL FILERS'. DTSBR708
|
||||
00225 DTSBR708
|
||||
00226 EJECT DTSBR708
|
||||
00227 LINKAGE SECTION. DTSBR708
|
||||
00228 DTSBR708
|
||||
00229 01 LRCM-LINK-AREA. DTSBR708
|
||||
00230 ++INCLUDE DTSILRCM DTSBR708
|
||||
00231 EJECT DTSBR708
|
||||
00232 01 R708-REC. DTSBR708
|
||||
00233 ++INCLUDE DTSIR708 DTSBR708
|
||||
00234 EJECT DTSBR708
|
||||
00235 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR708
|
||||
00236 R708-REC. DTSBR708
|
||||
00237 DTSBR708
|
||||
00238 IF FIRST-TIME-IND = 'Y' DTSBR708
|
||||
00239 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR708
|
||||
00240 MOVE 'N' TO FIRST-TIME-IND. DTSBR708
|
||||
00241 DTSBR708
|
||||
00242 IF LRCM-EOR-88 DTSBR708
|
||||
00243 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR708
|
||||
00244 ELSE DTSBR708
|
||||
00245 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR708
|
||||
00246 DTSBR708
|
||||
00247 GOBACK. DTSBR708
|
||||
00248 DTSBR708
|
||||
00249 I1000-INITIATE. DTSBR708
|
||||
00250 DTSBR708
|
||||
00251 OPEN OUTPUT PRT-FILE. DTSBR708
|
||||
00252 MOVE LRCM-SYS-DATE TO HDR-SYS-DATE. DTSBR708
|
||||
00253 MOVE LRCM-SYS-TIME TO HDR-SYS-TIME. DTSBR708
|
||||
00254 MOVE LRCM-AGY-NAME-LINE1 TO HDR-AGY-NAME-LINE1. DTSBR708
|
||||
00255 MOVE LRCM-AGY-NAME-LINE2 TO HDR-AGY-NAME-LINE2. DTSBR708
|
||||
00256 MOVE SPACES TO REPORT-LISTING1. DTSBR708
|
||||
00257 DTSBR708
|
||||
00258 I1000-EXIT. DTSBR708
|
||||
00259 EXIT. DTSBR708
|
||||
00260 DTSBR708
|
||||
00261 P1000-PROCESS. DTSBR708
|
||||
00262 DTSBR708
|
||||
00263 MOVE R708-TAX-PERIOD TO WS-TAX-PERIOD. DTSBR708
|
||||
00264 DTSBR708
|
||||
00265 PERFORM DTSBR708
|
||||
00266 VARYING WS-SUB FROM +1 BY +1 DTSBR708
|
||||
00267 UNTIL WS-SUB > R708-WAGE-RATE-CNT DTSBR708
|
||||
00268 MOVE R708-TAX-WAGE (WS-SUB) DTSBR708
|
||||
00269 TO WS-TAX-WAGE-EDIT (WS-SUB) DTSBR708
|
||||
00270 MOVE R708-RATE (WS-SUB) TO L056-RATE DTSBR708
|
||||
00271 SET L056-DISP1-LEFT-88 TO TRUE DTSBR708
|
||||
00272 PERFORM S056-RATE-DISPLAY THRU S056-EXIT DTSBR708
|
||||
00273 MOVE L056-DISP-RATE TO WS-RATE-DISPLAY (WS-SUB) DTSBR708
|
||||
00274 END-PERFORM. DTSBR708
|
||||
00275 DTSBR708
|
||||
00276 MOVE R708-EMP-NO TO DTL1-EMP-NO. DTSBR708
|
||||
00277 MOVE R708-FEIN TO DTL1-FEIN. DTSBR708
|
||||
00278 MOVE WS-TAX-PERIOD (2:4) TO DTL1-TAX-PERIOD-4. DTSBR708
|
||||
00279 MOVE R708-ONTIME TO DTL1-ONTIME. DTSBR708
|
||||
00280 MOVE R708-GRACE TO DTL1-GRACE. DTSBR708
|
||||
00281 MOVE R708-LATE TO DTL1-LATE. DTSBR708
|
||||
00282 MOVE WS-TAX-WAGE-EDIT (1) TO DTL1-TAX-WAGE-DIS-1. DTSBR708
|
||||
00283 MOVE WS-RATE-DISPLAY (1) (1:4) TO DTL1-RATE-DIS-1. DTSBR708
|
||||
00284 MOVE WS-TAX-WAGE-EDIT (2) TO DTL1-TAX-WAGE-DIS-2. DTSBR708
|
||||
00285 MOVE WS-RATE-DISPLAY (2) (1:4) TO DTL1-RATE-DIS-2. DTSBR708
|
||||
00286 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR708
|
||||
00287 WRITE REPORT-LISTING1 FROM DTL1-LINE-2 AFTER 2. DTSBR708
|
||||
00288 ADD +2 TO WS-LINE-CNT2. DTSBR708
|
||||
00289 ADD +1 TO WS-NUMBER-ONE. DTSBR708
|
||||
00290 DTSBR708
|
||||
00291 IF WS-TAX-WAGE-EDIT (3) > 0 OR DTSBR708
|
||||
00292 WS-TAX-WAGE-EDIT (4) > 0 DTSBR708
|
||||
00293 MOVE WS-TAX-WAGE-EDIT (3) TO DTL2-TAX-WAGE-DIS-3 DTSBR708
|
||||
00294 MOVE WS-RATE-DISPLAY (3) (1:4) TO DTL2-RATE-DIS-3 DTSBR708
|
||||
00295 MOVE WS-TAX-WAGE-EDIT (4) TO DTL2-TAX-WAGE-DIS-4 DTSBR708
|
||||
00296 MOVE WS-RATE-DISPLAY (4) (1:4) TO DTL2-RATE-DIS-4 DTSBR708
|
||||
00297 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR708
|
||||
00298 WRITE REPORT-LISTING1 FROM DTL2-LINE-1 AFTER 1 DTSBR708
|
||||
00299 ADD +1 TO WS-LINE-CNT2. DTSBR708
|
||||
00300 DTSBR708
|
||||
00301 P1000-EXIT. DTSBR708
|
||||
00302 EXIT. DTSBR708
|
||||
00303 DTSBR708
|
||||
00304 P2000-PRINT-HEADER. DTSBR708
|
||||
00305 DTSBR708
|
||||
00306 IF WS-LINE-CNT GREATER 58 OR DTSBR708
|
||||
00307 WS-LINE-CNT2 GREATER 58 DTSBR708
|
||||
00308 MOVE +0 TO WS-LINE-CNT DTSBR708
|
||||
00309 MOVE +0 TO WS-LINE-CNT2 DTSBR708
|
||||
00310 ADD +1 TO WS-PAGE-CNT DTSBR708
|
||||
00311 MOVE WS-PAGE-CNT TO HDR-PAGE-CNT DTSBR708
|
||||
00312 WRITE REPORT-LISTING1 FROM HDR-LINE-1 DTSBR708
|
||||
00313 AFTER TOP-OF-PAGE DTSBR708
|
||||
00314 WRITE REPORT-LISTING1 FROM HDR-LINE-2 AFTER 1 DTSBR708
|
||||
00315 WRITE REPORT-LISTING1 FROM HDR-LINE-3 AFTER 1 DTSBR708
|
||||
00316 WRITE REPORT-LISTING1 FROM HDR-LINE-4 AFTER 1 DTSBR708
|
||||
00317 WRITE REPORT-LISTING1 FROM HDR-LINE-5 AFTER 1 DTSBR708
|
||||
00318 WRITE REPORT-LISTING1 FROM HDR-LINE-6 AFTER 1 DTSBR708
|
||||
00319 WRITE REPORT-LISTING1 FROM HDR-LINE-7 AFTER 1 DTSBR708
|
||||
00320 WRITE REPORT-LISTING1 FROM HDR-LINE-8 AFTER 1 DTSBR708
|
||||
00321 ADD +8 TO WS-LINE-CNT2. DTSBR708
|
||||
00322 DTSBR708
|
||||
00323 P2000-EXIT. DTSBR708
|
||||
00324 EXIT. DTSBR708
|
||||
00325 DTSBR708
|
||||
00326 T1000-TERMINATE. DTSBR708
|
||||
00327 DTSBR708
|
||||
00328 IF WS-LINE-CNT2 > 52 DTSBR708
|
||||
00329 MOVE +60 TO WS-LINE-CNT2 DTSBR708
|
||||
00330 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR708
|
||||
00331 DTSBR708
|
||||
00332 MOVE WS-NUMBER-ONE TO CFF-NUMBER-ONE. DTSBR708
|
||||
00333 WRITE REPORT-LISTING1 FROM CFF-LINE-4 AFTER 4. DTSBR708
|
||||
00334 DTSBR708
|
||||
00335 CLOSE PRT-FILE. DTSBR708
|
||||
00336 DTSBR708
|
||||
00337 T1000-EXIT. DTSBR708
|
||||
00338 EXIT. DTSBR708
|
||||
00339 EJECT DTSBR708
|
||||
00340 S056-RATE-DISPLAY. DTSBR708
|
||||
00341 DTSBR708
|
||||
00342 CALL 'DTSBU056' USING L056-LINK-AREA. DTSBR708
|
||||
00343 DTSBR708
|
||||
00344 S056-EXIT. DTSBR708
|
||||
00345 EXIT. DTSBR708
|
||||
00346 DTSBR708
|
||||
00347 *S999-ABEND. DTSBR708
|
||||
00348 * SKIP1 DTSBR708
|
||||
00349 * CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR708
|
||||
00350 * SKIP2 DTSBR708
|
||||
00351 *S999-EXIT. DTSBR708
|
||||
00352 * EXIT. DTSBR708
|
||||
00353 DTSBR708
|
||||
Reference in New Issue
Block a user