DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
253
Batch/DTSBU934.cob
Normal file
253
Batch/DTSBU934.cob
Normal file
@ -0,0 +1,253 @@
|
||||
00001 IDENTIFICATION DIVISION. 03/30/04
|
||||
00002 PROGRAM-ID. DTSBU934. DTSBU934
|
||||
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV005
|
||||
00004 DATE-WRITTEN. SEPTEMBER 1998. DTSBU934
|
||||
00005 DATE-COMPILED. DTSBU934
|
||||
00006 SKIP3 DTSBU934
|
||||
00007 ***** DTSBU934
|
||||
00008 * DTSBU934
|
||||
00009 * FUNCTION: NAICS FILE INPUT. DTSBU934
|
||||
00010 * DTSBU934
|
||||
00011 * DTSBU934
|
||||
00012 * MODIFICATION LOG: DTSBU934
|
||||
00013 * DTSBU934
|
||||
00014 * 09/30/1998 CLONED FROM DTSBU933. DTSBU934
|
||||
00015 * REFERENCE: DC DEVELOPMENT PROGRAMMER: EHH DTSBU934
|
||||
00016 * DTSBU934
|
||||
00017 * 03/26/2004 REVISED FOR NEW VERSION OF VSAM NAICS FILE DTSBU934
|
||||
00018 * REFERENCE: PROGRAMMER: GD DTSBU934
|
||||
00019 * DTSBU934
|
||||
00020 * MM/DD/YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBU934
|
||||
00021 * REFERENCE: XXXXXXXXXXXXXXX PROGRAMMER: XXX DTSBU934
|
||||
00022 * DTSBU934
|
||||
00023 * DTSBU934
|
||||
00024 * DESCRIPTION: DTSBU934
|
||||
00025 * DTSBU934
|
||||
00026 * DTSBU934 PERFORMS ALL REQUIRED NAICS FILE INPUT. DTSBU934
|
||||
00027 * DTSBU934
|
||||
00028 * DTSBU934
|
||||
00029 * GENERAL SPECIFICATIONS: DTSBU934
|
||||
00030 * DTSBU934
|
||||
00031 * ALL COMMANDS ARE VALID. DTSBU934
|
||||
00032 * DTSBU934
|
||||
00033 * IF AN INVALID COMMAND IS REQUESTED, THEN ABEND THE DTSBU934
|
||||
00034 * MODULE. DTSBU934
|
||||
00035 * DTSBU934
|
||||
00036 * IF A FILE-STATUS OF OTHER THAN '00', '10', OR '23' IS DTSBU934
|
||||
00037 * ENCOUNTERED, THEN ABEND PROCESSING (TOLERATE A DTSBU934
|
||||
00038 * FILE-STATUS OF '97' FROM AN OPEN COMMAND). DTSBU934
|
||||
00039 * DTSBU934
|
||||
00040 * DTSBU934
|
||||
00041 * COMMAND SPECIFIC SPECIFICATIONS: DTSBU934
|
||||
00042 * DTSBU934
|
||||
00043 * OPEN-READ DTSBU934
|
||||
00044 * OPEN INPUT. DTSBU934
|
||||
00045 * DTSBU934
|
||||
00046 * CLOSE DTSBU934
|
||||
00047 * DTSBU934
|
||||
00048 * READ DTSBU934
|
||||
00049 * DTSBU934
|
||||
00050 * START BROWSE DTSBU934
|
||||
00051 * DTSBU934
|
||||
00052 * READ NEXT DTSBU934
|
||||
00053 * DTSBU934
|
||||
00054 ***** DTSBU934
|
||||
00055 SKIP3 DTSBU934
|
||||
00056 ENVIRONMENT DIVISION. DTSBU934
|
||||
00057 SKIP2 DTSBU934
|
||||
00058 INPUT-OUTPUT SECTION. DTSBU934
|
||||
00059 DTSBU934
|
||||
00060 FILE-CONTROL. DTSBU934
|
||||
00061 SELECT NAICS-FILE ASSIGN TO DTSFNAIC DTSBU934
|
||||
00062 ORGANIZATION IS INDEXED DTSBU934
|
||||
00063 RECORD KEY IS XNIC-KEY-AREA OF FILE-REC DTSBU934
|
||||
00064 FILE STATUS IS FILE-STATUS DTSBU934
|
||||
00065 ACCESS IS DYNAMIC. DTSBU934
|
||||
00066 SKIP3 DTSBU934
|
||||
00067 DATA DIVISION. DTSBU934
|
||||
00068 SKIP3 DTSBU934
|
||||
00069 FILE SECTION. DTSBU934
|
||||
00070 SKIP3 DTSBU934
|
||||
00071 FD NAICS-FILE. DTSBU934
|
||||
00072 DTSBU934
|
||||
00073 01 FILE-REC. DTSBU934
|
||||
00074 ++INCLUDE DTSIXNIC DTSBU934
|
||||
00075 EJECT DTSBU934
|
||||
00076 WORKING-STORAGE SECTION. DTSBU934
|
||||
000765 77 PAN-VALET PICTURE X(24) VALUE '005DTSBU934 03/30/04'. DTSBU934
|
||||
00077 SKIP3 DTSBU934
|
||||
00078 01 WRK-AREA. DTSBU934
|
||||
00079 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +934.DTSBU934
|
||||
00080 DTSBU934
|
||||
00081 05 VAR-CHAR-CNT PIC S9(04) COMP. DTSBU934
|
||||
00082 DTSBU934
|
||||
00083 05 FILE-STATUS PIC X(02). DTSBU934
|
||||
00084 88 FILE-OK-88 VALUE '00'. DTSBU934
|
||||
00085 88 FILE-NO-REC-88 VALUE '10' '23'. DTSBU934
|
||||
00086 88 FILE-VERIFY-88 VALUE '97'. DTSBU934
|
||||
00087 EJECT DTSBU934
|
||||
00088 LINKAGE SECTION. DTSBU934
|
||||
00089 SKIP3 DTSBU934
|
||||
00090 01 L934-LINK-AREA. DTSBU934
|
||||
00091 ++INCLUDE DTSIL934 DTSBU934
|
||||
00092 EJECT DTSBU934
|
||||
00093 01 LINK-REC. DTSBU934
|
||||
00094 ++INCLUDE DTSIXNIC DTSBU934
|
||||
00095 EJECT DTSBU934
|
||||
00096 PROCEDURE DIVISION USING L934-LINK-AREA DTSBU934
|
||||
00097 LINK-REC. DTSBU934
|
||||
00098 DTSBU934
|
||||
00099 DTSBU934
|
||||
00100 SET L934-OK-88 TO TRUE. DTSBU934
|
||||
00101 DTSBU934
|
||||
00102 IF L934-TRACE-88 DTSBU934
|
||||
00103 PERFORM S9100-PRE-DISPLAY THRU S9100-EXIT. DTSBU934
|
||||
00104 DTSBU934
|
||||
00105 IF L934-READ-NEXT-88 DTSBU934
|
||||
00106 PERFORM P2300-READ-NEXT THRU P2300-EXIT DTSBU934
|
||||
00107 ELSE DTSBU934
|
||||
00108 IF L934-READ-88 DTSBU934
|
||||
00109 PERFORM P2100-READ THRU P2100-EXIT DTSBU934
|
||||
00110 ELSE DTSBU934
|
||||
00111 IF L934-START-BROWSE-88 DTSBU934
|
||||
00112 PERFORM P2200-START-BROWSE THRU P2200-EXIT DTSBU934
|
||||
00113 ELSE DTSBU934
|
||||
00114 IF L934-OPEN-READ-88 DTSBU934
|
||||
00115 PERFORM P1100-OPEN THRU P1100-EXIT DTSBU934
|
||||
00116 ELSE DTSBU934
|
||||
00117 IF L934-CLOSE-88 DTSBU934
|
||||
00118 PERFORM P1200-CLOSE THRU P1200-EXIT DTSBU934
|
||||
00119 ELSE DTSBU934
|
||||
00120 PERFORM S999-ABEND THRU S999-EXIT. DTSBU934
|
||||
00121 DTSBU934
|
||||
00122 IF L934-TRACE-88 DTSBU934
|
||||
00123 PERFORM S9200-POST-DISPLAY THRU S9200-EXIT. DTSBU934
|
||||
00124 DTSBU934
|
||||
00125 DTSBU934
|
||||
00126 GOBACK. DTSBU934
|
||||
00127 EJECT DTSBU934
|
||||
00128 P1100-OPEN. DTSBU934
|
||||
00129 OPEN INPUT NAICS-FILE. DTSBU934
|
||||
00130 DTSBU934
|
||||
00131 IF FILE-OK-88 OR FILE-VERIFY-88 DTSBU934
|
||||
00132 NEXT SENTENCE DTSBU934
|
||||
00133 ELSE DTSBU934
|
||||
00134 PERFORM S999-ABEND THRU S999-EXIT. DTSBU934
|
||||
00135 P1100-EXIT. DTSBU934
|
||||
00136 EXIT. DTSBU934
|
||||
00137 SKIP3 DTSBU934
|
||||
00138 P1200-CLOSE. DTSBU934
|
||||
00139 CLOSE NAICS-FILE. DTSBU934
|
||||
00140 DTSBU934
|
||||
00141 IF FILE-OK-88 DTSBU934
|
||||
00142 NEXT SENTENCE DTSBU934
|
||||
00143 ELSE DTSBU934
|
||||
00144 PERFORM S999-ABEND THRU S999-EXIT. DTSBU934
|
||||
00145 P1200-EXIT. DTSBU934
|
||||
00146 EXIT. DTSBU934
|
||||
00147 EJECT DTSBU934
|
||||
00148 P2100-READ. DTSBU934
|
||||
00149 MOVE XNIC-KEY-AREA OF LINK-REC TO XNIC-KEY-AREA OF FILE-REC. DTSBU934
|
||||
00150 DTSBU934
|
||||
00151 READ NAICS-FILE. DTSBU934
|
||||
00152 DTSBU934
|
||||
00153 IF FILE-OK-88 DTSBU934
|
||||
00154 PERFORM S2200-FILE-TO-LINK THRU S2200-EXIT DTSBU934
|
||||
00155 ELSE DTSBU934
|
||||
00156 IF FILE-NO-REC-88 DTSBU934
|
||||
00157 PERFORM S1100-NO-REC THRU S1100-EXIT DTSBU934
|
||||
00158 ELSE DTSBU934
|
||||
00159 PERFORM S999-ABEND THRU S999-EXIT. DTSBU934
|
||||
00160 P2100-EXIT. DTSBU934
|
||||
00161 EXIT. DTSBU934
|
||||
00162 EJECT DTSBU934
|
||||
00163 P2200-START-BROWSE. DTSBU934
|
||||
00164 MOVE XNIC-KEY-AREA OF LINK-REC TO XNIC-KEY-AREA OF FILE-REC. DTSBU934
|
||||
00165 DTSBU934
|
||||
00166 START NAICS-FILE DTSBU934
|
||||
00167 KEY IS NOT < XNIC-KEY-AREA OF FILE-REC. DTSBU934
|
||||
00168 DTSBU934
|
||||
00169 IF FILE-OK-88 DTSBU934
|
||||
00170 PERFORM P2300-READ-NEXT THRU P2300-EXIT DTSBU934
|
||||
00171 ELSE DTSBU934
|
||||
00172 IF FILE-NO-REC-88 DTSBU934
|
||||
00173 PERFORM S1100-NO-REC THRU S1100-EXIT DTSBU934
|
||||
00174 ELSE DTSBU934
|
||||
00175 PERFORM S999-ABEND THRU S999-EXIT. DTSBU934
|
||||
00176 P2200-EXIT. DTSBU934
|
||||
00177 EXIT. DTSBU934
|
||||
00178 EJECT DTSBU934
|
||||
00179 P2300-READ-NEXT. DTSBU934
|
||||
00180 READ NAICS-FILE NEXT. DTSBU934
|
||||
00181 DTSBU934
|
||||
00182 IF FILE-OK-88 DTSBU934
|
||||
00183 PERFORM S2200-FILE-TO-LINK THRU S2200-EXIT DTSBU934
|
||||
00184 ELSE DTSBU934
|
||||
00185 IF FILE-NO-REC-88 DTSBU934
|
||||
00186 PERFORM S1100-NO-REC THRU S1100-EXIT DTSBU934
|
||||
00187 ELSE DTSBU934
|
||||
00188 PERFORM S999-ABEND THRU S999-EXIT. DTSBU934
|
||||
00189 P2300-EXIT. DTSBU934
|
||||
00190 EXIT. DTSBU934
|
||||
00191 EJECT DTSBU934
|
||||
00192 S1100-NO-REC. DTSBU934
|
||||
00193 SET L934-NO-REC-88 TO TRUE. DTSBU934
|
||||
00194 S1100-EXIT. DTSBU934
|
||||
00195 EXIT. DTSBU934
|
||||
00196 EJECT DTSBU934
|
||||
00197 S2200-FILE-TO-LINK. DTSBU934
|
||||
00198 MOVE FILE-REC TO LINK-REC. DTSBU934
|
||||
00199 S2200-EXIT. DTSBU934
|
||||
00200 EXIT. DTSBU934
|
||||
00201 EJECT DTSBU934
|
||||
00202 S9100-PRE-DISPLAY. DTSBU934
|
||||
00203 DISPLAY ' '. DTSBU934
|
||||
00204 DTSBU934
|
||||
00205 DISPLAY ' '. DTSBU934
|
||||
00206 DTSBU934
|
||||
00207 DISPLAY '*** DTSBU934 PRE TRACE DISPLAY ***'. DTSBU934
|
||||
00208 DTSBU934
|
||||
00209 DISPLAY L934-MOD-NAME DTSBU934
|
||||
00210 ' = L934-MOD-NAME'. DTSBU934
|
||||
00211 DTSBU934
|
||||
00212 DISPLAY L934-CMND-CD DTSBU934
|
||||
00213 ' = L934-CMND-CD'. DTSBU934
|
||||
00214 DTSBU934
|
||||
00215 PERFORM S9300-REC-DISPLAY THRU S9300-EXIT. DTSBU934
|
||||
00216 S9100-EXIT. DTSBU934
|
||||
00217 EXIT. DTSBU934
|
||||
00218 SKIP3 DTSBU934
|
||||
00219 S9200-POST-DISPLAY. DTSBU934
|
||||
00220 DISPLAY ' '. DTSBU934
|
||||
00221 DTSBU934
|
||||
00222 DISPLAY ' '. DTSBU934
|
||||
00223 DTSBU934
|
||||
00224 DISPLAY '*** DTSBU934 POST TRACE DISPLAY ***'. DTSBU934
|
||||
00225 DTSBU934
|
||||
00226 DISPLAY L934-RESULT-IND DTSBU934
|
||||
00227 ' = L934-RESULT-IND'. DTSBU934
|
||||
00228 DTSBU934
|
||||
00229 PERFORM S9300-REC-DISPLAY THRU S9300-EXIT. DTSBU934
|
||||
00230 S9200-EXIT. DTSBU934
|
||||
00231 EXIT. DTSBU934
|
||||
00232 SKIP3 DTSBU934
|
||||
00233 S9300-REC-DISPLAY. DTSBU934
|
||||
00234 DISPLAY ' '. DTSBU934
|
||||
00235 DTSBU934
|
||||
00236 DISPLAY XNIC-KEY-AREA OF LINK-REC DTSBU934
|
||||
00237 ' = XNIC-KEY-AREA'. DTSBU934
|
||||
00238 S9300-EXIT. DTSBU934
|
||||
00239 EXIT. DTSBU934
|
||||
00240 EJECT DTSBU934
|
||||
00241 S999-ABEND. DTSBU934
|
||||
00242 DISPLAY '*** I/O MODULE ABENDING'. DTSBU934
|
||||
00243 DTSBU934
|
||||
00244 DISPLAY '*** CMND-CD = ' L934-CMND-CD. DTSBU934
|
||||
00245 DTSBU934
|
||||
00246 DISPLAY '*** FILE-STATUS = ' FILE-STATUS. DTSBU934
|
||||
00247 DTSBU934
|
||||
00248 PERFORM S9300-REC-DISPLAY THRU S9300-EXIT. DTSBU934
|
||||
00249 DTSBU934
|
||||
00250 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBU934
|
||||
00251 S999-EXIT. DTSBU934
|
||||
00252 EXIT. DTSBU934
|
||||
Reference in New Issue
Block a user