DUTAS re-platformed to Raincode - Initial Source Code
This commit is contained in:
Neeraj Kumar
483
Batch/EFTBD130.cob
Normal file
483
Batch/EFTBD130.cob
Normal file
@ -0,0 +1,483 @@
|
||||
00001 IDENTIFICATION DIVISION. 01/08/04
|
||||
00002 PROGRAM-ID. EFTBD130. EFTBD130
|
||||
00003 AUTHOR. NORTHROP GRUMMAN. LV171
|
||||
00004 DATE-WRITTEN. APRIL 2002. CL240
|
||||
00005 DATE-COMPILED. EFTBD130
|
||||
00006 SKIP3 EFTBD130
|
||||
00007 ***** EFTBD130
|
||||
00008 * EFTBD130
|
||||
00009 * FUNCTION: READ THE ELETRONIC PAYMENT FILE FROM EFTBI100, CL133
|
||||
00010 * THEN MATCHES EMPLOYER NUMBER WITH THE MPRF CL133
|
||||
00011 * MASTER FILE TO OUTPUT AN ELECTRONIC PAYMENT CL133
|
||||
00012 * TRANSACTION FILE FROM THE DTSIT025 RECORD CL134
|
||||
00013 * FORMAT. CL134
|
||||
00014 * CL134
|
||||
00015 * MODIFICATION LOG: EFTBD130
|
||||
00016 * EFTBD130
|
||||
00017 * 04/14/02 INITIAL DEVELOPMENT CL*74
|
||||
00018 * WORK ORDER: PROGRAMMER: RW1 CL**3
|
||||
00019 * CL**3
|
||||
00020 * 99/99/99 XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX CL**3
|
||||
00021 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX CL**3
|
||||
00022 * WORK ORDER: PROGRAMMER: XXX CL**3
|
||||
00023 * EFTBD130
|
||||
00024 * DESCRIPTION: EFTBD130
|
||||
00025 * EFTBD130
|
||||
00026 * INITIATION: EFTBD130
|
||||
00027 * NONE CL*91
|
||||
00028 * EFTBD130
|
||||
00029 * PARAMETERS INPUT: CL*50
|
||||
00030 * NONE CL*91
|
||||
00031 * CL*50
|
||||
00032 * PROCESSING: EFTBD130
|
||||
00033 * SEE PRINTED OUTPUTS DESCRIPTION AND LAYOUTS (T025). CL*91
|
||||
00034 * EFTBD130
|
||||
00035 * TERMINATION: EFTBD130
|
||||
00036 * OUTPUT STATISTICAL RECORDS COUNT. CL*50
|
||||
00037 * EFTBD130
|
||||
00038 * RECORDS READ: EFTBD130
|
||||
00039 * MASTER: CL**3
|
||||
00040 * VSAM WAGES FILE CL*38
|
||||
00041 * CL**3
|
||||
00042 * ALTERNATE INDEX: EFTBD130
|
||||
00043 * NONE. EFTBD130
|
||||
00044 * EFTBD130
|
||||
00045 * REFERENCE: EFTBD130
|
||||
00046 * NONE. EFTBD130
|
||||
00047 * EFTBD130
|
||||
00048 * RECORDS UPDATED: CL**3
|
||||
00049 * NONE CL249
|
||||
00050 * EFTBD130
|
||||
00051 * REPORT RECORDS WRITTEN: EFTBD130
|
||||
00052 * R907 ERROR PAYMENT RECORD FROM EDITING FOR REPORTING. CL167
|
||||
00053 * CL*50
|
||||
00054 * BATCH TRANSACTION COLLECTION RECORDS WRITTEN: CL241
|
||||
00055 * T025 RECORDS CL*96
|
||||
00056 * EFTBD130
|
||||
00057 * MODULES CALLED: EFTBD130
|
||||
00058 * DTSBU001 DATE CONVERSION/EDIT. EFTBD130
|
||||
00059 * DTSBU004 QUARERLY SUMMARY REPORT REC. CL*47
|
||||
00060 * DTSBU910 VSAM MASTER FILES I/O. CL*74
|
||||
00061 * DTSBU941 VARIABLE LENGTH RECORDS INPUT 1. CL131
|
||||
00062 * DTSBU927 VARIABLE LENGTH RECORDS BTC OUTPUT. CL131
|
||||
00063 * DTSBU947 VARIABLE LENGTH RECORDS SEQUENTIAL OUTPUT 2. CL*91
|
||||
00064 * EFTBD130
|
||||
00065 * VERMONT REFERENCE: EFTBD130
|
||||
00066 * NONE. EFTBD130
|
||||
00067 * EFTBD130
|
||||
00068 ***** EFTBD130
|
||||
00069 SKIP3 CL*13
|
||||
00070 ENVIRONMENT DIVISION. EFTBD130
|
||||
00071 CL*58
|
||||
00072 INPUT-OUTPUT SECTION. CL*58
|
||||
00073 CL*58
|
||||
00074 CL*70
|
||||
00075 DATA DIVISION. CL*13
|
||||
00076 CL*58
|
||||
00077 CL*58
|
||||
00078 WORKING-STORAGE SECTION. EFTBD130
|
||||
000785 77 PAN-VALET PICTURE X(24) VALUE '171EFTBD130 01/08/04'. EFTBD130
|
||||
00079 CL*40
|
||||
00080 01 WRK-AREA. EFTBD130
|
||||
00081 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +130. CL135
|
||||
00082 05 WRK-MOD-NAME PIC X(08) VALUE 'EFTBD130'. CL135
|
||||
00083 05 WRK-ABEND-MSG PIC X(60). CL*83
|
||||
00084 CL*69
|
||||
00085 05 EFT-STATUS PIC X(02). CL*58
|
||||
00086 88 EFT-STATUS-OK-88 VALUE '00'. CL*58
|
||||
00087 CL*90
|
||||
00088 05 WRK-EFT-EOF-IND PIC X(01). CL*90
|
||||
00089 05 WRK-TRACE-IND PIC X(01) VALUE SPACES. CL*90
|
||||
00090 CL*58
|
||||
00091 05 WRK-NUMBER-ONE PIC S9(03) COMP-3 VALUE +0. CL*59
|
||||
00092 05 WRK-SUM-SSN-WAGES-AMT PIC S9(07)V99 VALUE +0. CL*59
|
||||
00093 05 WRK-TOTAL-WAGES-AMT PIC S9(09)V99 VALUE +0. CL*59
|
||||
00094 05 WRK-SSN-HOLD PIC S9(09) COMP-3 VALUE +0. CL*58
|
||||
00095 CL101
|
||||
00096 05 WRK-PRIMARY-NAME. CL*98
|
||||
00097 10 WRK-FIRST4-NAME PIC X(04). CL101
|
||||
00098 10 WRK-REST-NAME PIC X(36). CL101
|
||||
00099 CL*98
|
||||
00100 05 DISP-DATE PIC X(10) VALUE SPACES. CL*92
|
||||
00101 05 DISP-TIME PIC X(08) VALUE SPACES. CL*92
|
||||
00102 05 WRK-SYS-TIME PIC X(06) VALUE SPACES. CL*92
|
||||
00103 05 WRK-SYS-DATE PIC X(08) VALUE SPACES. CL*92
|
||||
00104 05 WRK-CURR-YR PIC 9(04) VALUE ZEROS. CL*92
|
||||
00105 CL*89
|
||||
00106 05 WRK-EMP-NO PIC 9(06) VALUE 0. CL*77
|
||||
00107 05 WRK-MPRF-READ-CNT PIC S9(07) COMP-3 VALUE +0. CL101
|
||||
00108 05 WRK-EFT-READ-CNT PIC S9(07) COMP-3 VALUE +0. CL101
|
||||
00109 05 WRK-BTC-WRITE-CNT PIC S9(07) COMP-3 VALUE +0. CL*75
|
||||
00110 05 WRK-ERROR-WRITE-CNT PIC S9(07) COMP-3 VALUE +0. CL*78
|
||||
00111 05 WRK-R907-REC-CNT PIC S9(07) COMP-3 VALUE +0. CL*80
|
||||
00112 05 WRK-PAYMENT-AMOUNT PIC S9(07)V99 VALUE +0. CL108
|
||||
00113 CL112
|
||||
00114 05 WRK-MSG-TEXT. CL112
|
||||
00115 10 WRK-MSG-LINE PIC X(32). CL116
|
||||
00116 10 FILLER PIC X(02) VALUE SPACES. CL112
|
||||
00117 10 FILLER PIC X(12) VALUE CL112
|
||||
00118 'THE FIELD = '. CL112
|
||||
00119 * 10 WRK-ERR-PAY-AMT PIC 9(06)9.99. CL124
|
||||
00120 10 WRK-ERR-PAY-AMT PIC X(10). CL124
|
||||
00121 10 WRK-ERR-EMP-NO-X REDEFINES WRK-ERR-PAY-AMT. CL115
|
||||
00122 15 WRK-ERR-EMP-NO PIC X(06). CL112
|
||||
00123 15 FIL-EMP-NO PIC X(04). CL114
|
||||
00124 10 WRK-ERR-PAY-TRACE-NO-X REDEFINES WRK-ERR-PAY-AMT. CL115
|
||||
00125 15 WRK-ERR-PAY-TRACE-NO PIC X(05). CL114
|
||||
00126 15 FIL-PAY-TRACE-NO PIC X(05). CL115
|
||||
00127 10 WRK-ERR-PAY-DATE-X REDEFINES WRK-ERR-PAY-AMT. CL115
|
||||
00128 15 WRK-ERR-PAY-DATE PIC X(08). CL112
|
||||
00129 15 FIL-PAY-DATE PIC X(02). CL114
|
||||
00130 10 WRK-ERR-PAY-TIME-X REDEFINES WRK-ERR-PAY-AMT. CL115
|
||||
00131 15 WRK-ERR-PAY-TIME PIC X(06). CL112
|
||||
00132 15 FIL-PAY-TIME PIC X(04). CL114
|
||||
00133 CL112
|
||||
00134 05 WRK-ERROR-IND PIC X(01). CL*37
|
||||
00135 88 WRK-ERROR-YES-88 VALUE 'Y'. CL*37
|
||||
00136 88 WRK-ERROR-NO-88 VALUE 'N'. CL*37
|
||||
00137 CL*76
|
||||
00138 05 WRK-EMP-NO-IND PIC X(01). CL*76
|
||||
00139 88 WRK-EMP-NO-VALID-88 VALUE 'Y'. CL*76
|
||||
00140 88 WRK-EMP-NO-INVALID-88 VALUE 'N'. CL*76
|
||||
00141 CL*16
|
||||
00142 01 WRK-PAYMENT-DATE PIC X(08). CL*85
|
||||
00143 01 WRK-PAYMENT-DATE-9 REDEFINES WRK-PAYMENT-DATE CL*85
|
||||
00144 PIC 9(08). CL*85
|
||||
00145 01 WRK-PAYMENT-CCYYMMDD REDEFINES WRK-PAYMENT-DATE. CL*85
|
||||
00146 10 WRK-DATE-CCYY PIC 9(04). CL*90
|
||||
00147 10 WRK-DATE-MM PIC 9(02). CL*90
|
||||
00148 10 WRK-DATE-DD PIC 9(02). CL*90
|
||||
00149 CL*84
|
||||
00150 01 WRK-PAYMENT-TIME PIC X(06). CL*85
|
||||
00151 01 WRK-PAYMENT-TIME-9 REDEFINES WRK-PAYMENT-TIME CL*85
|
||||
00152 PIC 9(06). CL*85
|
||||
00153 01 WRK-PAYMENT-HHMMSS REDEFINES WRK-PAYMENT-TIME. CL101
|
||||
00154 10 WRK-TIME-HH PIC 9(02). CL*90
|
||||
00155 10 WRK-TIME-MM PIC 9(02). CL*90
|
||||
00156 10 WRK-TIME-SS PIC 9(02). CL*90
|
||||
00157 CL*74
|
||||
00158 01 L001-LINK-AREA. EFTBD130
|
||||
00159 ++INCLUDE DTSIL001 EFTBD130
|
||||
00160 EJECT EFTBD130
|
||||
00161 01 L004-LINK-AREA. CL*24
|
||||
00162 ++INCLUDE DTSIL004 CL*24
|
||||
00163 EJECT CL*24
|
||||
00164 01 L005-COMM-AREA. CL*61
|
||||
00165 ++INCLUDE DTSIL005 CL*61
|
||||
00166 EJECT CL100
|
||||
00167 01 L927-LINK-AREA. CL*94
|
||||
00168 ++INCLUDE DTSIL927 CL*94
|
||||
00169 EJECT CL100
|
||||
00170 01 TSKL-REC. CL*94
|
||||
00171 ++INCLUDE DTSITSKL CL*94
|
||||
00172 EJECT CL*94
|
||||
00173 01 FDPT-REC. CL141
|
||||
00174 ++INCLUDE EFTIFDPT CL141
|
||||
00175 EJECT CL141
|
||||
00176 01 L910-LINK-AREA. CL*94
|
||||
00177 ++INCLUDE DTSIL910 CL*94
|
||||
00178 EJECT CL*94
|
||||
00179 01 MSKL-REC. CL*70
|
||||
00180 ++INCLUDE DTSIMSKL CL*70
|
||||
00181 EJECT CL*70
|
||||
00182 01 MPRF-REC. CL*70
|
||||
00183 ++INCLUDE DTSIMPRF CL*70
|
||||
00184 EJECT CL*70
|
||||
00185 01 L941-LINK-AREA. CL125
|
||||
00186 ++INCLUDE DTSIL941 CL125
|
||||
00187 EJECT CL125
|
||||
00188 01 WRK-REC. CL125
|
||||
00189 ++INCLUDE DTSIRSK3 CL125
|
||||
00190 SKIP3 CL125
|
||||
00191 01 T025-REC. CL155
|
||||
00192 ++INCLUDE DTSIT025 CL155
|
||||
00193 01 R907-REC. CL155
|
||||
00194 ++INCLUDE EFTIF907 CL166
|
||||
00195 EJECT CL155
|
||||
00196 01 EFT-ERROR-MSGS. CL165
|
||||
00197 ++INCLUDE EFTERMSG CL165
|
||||
00198 EJECT CL165
|
||||
00199 CL155
|
||||
00200 LINKAGE SECTION. CL138
|
||||
00201 CL146
|
||||
00202 01 FILLER PIC X(100). CL146
|
||||
00203 CL146
|
||||
00204 01 EFT-REC-TYPE-LINK-AREA. CL146
|
||||
00205 ++INCLUDE EFTIL100 CL138
|
||||
00206 CL138
|
||||
00207 01 RSKL-REC. CL141
|
||||
00208 ++INCLUDE EFTIRSKL CL141
|
||||
00209 CL155
|
||||
00210 PROCEDURE DIVISION USING CL147
|
||||
00211 EFT-REC-TYPE-LINK-AREA CL139
|
||||
00212 RSKL-REC. CL155
|
||||
00213 CL153
|
||||
00214 MOVE RSKL-REC TO FDPT-REC. CL151
|
||||
00215 CL153
|
||||
00216 IF EFT-L100-COMMAND-CODE = '0' CL146
|
||||
00217 PERFORM I0000-INITIALIZE THRU I0000-EXIT CL136
|
||||
00218 ELSE CL136
|
||||
00219 IF EFT-L100-COMMAND-CODE = '1' CL146
|
||||
00220 PERFORM P0000-PROCESS THRU P0000-EXIT CL136
|
||||
00221 ELSE CL136
|
||||
00222 IF EFT-L100-COMMAND-CODE = '2' CL146
|
||||
00223 PERFORM T0000-TERMINATE THRU T0000-EXIT CL136
|
||||
00224 ELSE CL136
|
||||
00225 DISPLAY 'INVLAID CALL FROM BD100 ' CL136
|
||||
00226 PERFORM S999-ABEND THRU S999-EXIT. CL136
|
||||
00227 CL*62
|
||||
00228 PROC0000-EXIT. CL136
|
||||
00229 GOBACK. EFTBD130
|
||||
00230 EJECT EFTBD130
|
||||
00231 I0000-INITIALIZE. EFTBD130
|
||||
00232 CL*72
|
||||
00233 MOVE ZERO TO WRK-EFT-READ-CNT. CL*74
|
||||
00234 CL*72
|
||||
00235 PERFORM I1000-SYS-DATE THRU I1000-EXIT. CL*74
|
||||
00236 PERFORM I2000-OPEN-FILES THRU I2000-EXIT. CL*74
|
||||
00237 MOVE WRK-MOD-NAME TO F907-MODULE-NAME. CL171
|
||||
00238 CL*63
|
||||
00239 I0000-EXIT. EFTBD130
|
||||
00240 EXIT. EFTBD130
|
||||
00241 CL107
|
||||
00242 I1000-SYS-DATE. CL*72
|
||||
00243 SET L005-FROM-SYS TO TRUE. CL*72
|
||||
00244 PERFORM S005-SYS-DATE THRU S005-EXIT. CL*72
|
||||
00245 MOVE L005-DATE TO DISP-DATE. CL*99
|
||||
00246 MOVE L005-TIME TO DISP-TIME. CL*99
|
||||
00247 MOVE L005-SLASH-DATE TO WRK-SYS-DATE. CL*89
|
||||
00248 MOVE L005-DISPLAY-TIME TO WRK-SYS-TIME. CL*89
|
||||
00249 MOVE L005-SLASH-8-YR TO WRK-CURR-YR. CL*89
|
||||
00250 CL*72
|
||||
00251 DISPLAY ' '. CL*72
|
||||
00252 * DISPLAY 'L005-DATE ' DISP-DATE ' L005-TIME ' DISP-TIME CL153
|
||||
00253 * 'WRK-CURR-YR ' WRK-CURR-YR. CL153
|
||||
00254 I1000-EXIT. CL*72
|
||||
00255 EXIT. CL*72
|
||||
00256 CL**1
|
||||
00257 I2000-OPEN-FILES. CL*72
|
||||
00258 CL*58
|
||||
00259 MOVE LENGTH OF T025-REC TO T025-LENGTH. CL*72
|
||||
00260 MOVE LENGTH OF R907-REC TO F907-LENGTH. CL165
|
||||
00261 CL125
|
||||
00262 I2000-EXIT. CL*72
|
||||
00263 EXIT. CL*58
|
||||
00264 CL*58
|
||||
00265 ************************************************************** EFTBD130
|
||||
00266 * READ THE ELECTRONIC PAYMENT FILE FROM GOVONE AND CHECK * CL*90
|
||||
00267 * THE HEADER AND TRAILER RECORDS. * CL*90
|
||||
00268 ************************************************************** EFTBD130
|
||||
00269 EFTBD130
|
||||
00270 P0000-PROCESS. EFTBD130
|
||||
00271 *************************************************************** CL130
|
||||
00272 * TERMINATE PROCESSING IF DUMMY RECORD FOUND. THE IMPORT CL130
|
||||
00273 * PROGRAM (EFTBI100) WILL WRITE A DUMMY RECORD IF THE IMPORT CL130
|
||||
00274 * FILE IS EMPTY. CL130
|
||||
00275 *************************************************************** CL130
|
||||
00276 IF FDPT-TYPE-DUMMY-88 CL130
|
||||
00277 MOVE 'Y' TO WRK-EFT-EOF-IND CL130
|
||||
00278 GO TO P0000-EXIT. CL130
|
||||
00279 CL100
|
||||
00280 ADD +1 TO WRK-EFT-READ-CNT. CL100
|
||||
00281 MOVE FDPT-EMP-NO TO WRK-EMP-NO. CL128
|
||||
00282 PERFORM P2000-READ-MPRF THRU P2000-EXIT. CL125
|
||||
00283 CL119
|
||||
00284 IF WRK-EMP-NO-VALID-88 CL119
|
||||
00285 PERFORM P3000-WRITE-T025 THRU P3000-EXIT. CL119
|
||||
00286 CL**8
|
||||
00287 P0000-EXIT. EFTBD130
|
||||
00288 EXIT. EFTBD130
|
||||
00289 CL*72
|
||||
00290 ************************************************************** EFTBD130
|
||||
00291 * SELECT MASTER MPRF RECORD USING THE FDPT-EMP-NO TO * CL103
|
||||
00292 * OBTAIN VARIOUS INFORMATIONS FOR THE OUTPUT RECORD. * CL*81
|
||||
00293 ************************************************************** EFTBD130
|
||||
00294 EFTBD130
|
||||
00295 P2000-READ-MPRF. CL*72
|
||||
00296 SET WRK-EMP-NO-VALID-88 TO TRUE. CL119
|
||||
00297 CL119
|
||||
00298 MOVE LOW-VALUE TO MSKL-KEY-AREA. CL*77
|
||||
00299 CL*72
|
||||
00300 MOVE WRK-EMP-NO TO MSKL-EMP-NO. CL*77
|
||||
00301 CL*77
|
||||
00302 SET MSKL-PRF-88 TO TRUE. CL*77
|
||||
00303 CL*72
|
||||
00304 PERFORM S910-READ THRU S910-EXIT. CL*72
|
||||
00305 CL*72
|
||||
00306 IF L910-NO-REC-88 CL155
|
||||
00307 SET WRK-EMP-NO-INVALID-88 TO TRUE CL119
|
||||
00308 MOVE '100' TO F907-MSG-ID CL165
|
||||
00309 MOVE 'EMP-NO INVALID OR NOT ON FILE : ' TO CL116
|
||||
00310 WRK-MSG-LINE CL114
|
||||
00311 MOVE WRK-EMP-NO TO WRK-ERR-EMP-NO CL114
|
||||
00312 MOVE SPACES TO FIL-EMP-NO CL114
|
||||
00313 PERFORM P5000-EDIT-ERROR-OUTPUT THRU P5000-EXIT CL*78
|
||||
00314 GO TO P2000-EXIT. CL120
|
||||
00315 CL*72
|
||||
00316 ADD +1 TO WRK-MPRF-READ-CNT. CL*72
|
||||
00317 MOVE MSKL-REC TO MPRF-REC. CL*72
|
||||
00318 CL*72
|
||||
00319 MOVE MPRF-PRIMARY-NAME TO WRK-PRIMARY-NAME. CL*98
|
||||
00320 CL164
|
||||
00321 IF MPRF-EFT-ENROLLED-NO-88 CL164
|
||||
00322 MOVE '036' TO F907-MSG-ID CL164
|
||||
00323 MOVE EFT036 TO F907-MSG-TEXT CL164
|
||||
00324 MOVE FDPT-EMP-NO TO F907-EMP-NO CL164
|
||||
00325 MOVE RSKL-REC-TYPE TO F907-GOV1-RECID CL164
|
||||
00326 PERFORM S946-WRITE-R907 THRU S946-EXIT. CL167
|
||||
00327 CL164
|
||||
00328 CL*72
|
||||
00329 P2000-EXIT. CL*72
|
||||
00330 EXIT. CL*72
|
||||
00331 CL*72
|
||||
00332 ************************************************************** CL*37
|
||||
00333 * FORMAT AND WRITE THE T025 RECORDS. * CL*99
|
||||
00334 ************************************************************** CL*37
|
||||
00335 CL*37
|
||||
00336 P3000-WRITE-T025. CL*97
|
||||
00337 MOVE FDPT-EMP-NO TO T025-EMP-NO. CL103
|
||||
00338 MOVE 'IVRPAYMT' TO T025-ORIGIN. CL*97
|
||||
00339 MOVE L005-DATE TO T025-SYS-DATE. CL*97
|
||||
00340 MOVE L005-TIME TO T025-SYS-TIME. CL*97
|
||||
00341 SET T025-PA-PAY-88 TO TRUE. CL*97
|
||||
00342 MOVE WRK-FIRST4-NAME TO T025-NAME-CHECK. CL*98
|
||||
00343 MOVE FDPT-PAYMENT-AMOUNT TO T025-REMIT-AMT. CL103
|
||||
00344 MOVE FDPT-PAYMENT-TRACE-NO TO T025-TRACE-NO. CL103
|
||||
00345 MOVE ZEROS TO T025-APPLIC-YRQ. CL100
|
||||
00346 MOVE SPACES TO T025-APPLIC-IND. CL100
|
||||
00347 MOVE ZEROS TO T025-APPLIC-BATCH-NO. CL100
|
||||
00348 MOVE ZEROS TO T025-APPLIC-ITEM-NO. CL*99
|
||||
00349 MOVE SPACES TO T025-RESPONSIBLE-ACTIVITY. CL*99
|
||||
00350 MOVE SPACES TO T025-RESPONSIBLE-OP-ID. CL*99
|
||||
00351 CL137
|
||||
00352 MOVE T025-REC TO TSKL-REC. CL155
|
||||
00353 CL164
|
||||
00354 PERFORM S927-WRITE-BTC THRU S927-EXIT. CL155
|
||||
00355 ADD 1 TO WRK-BTC-WRITE-CNT. CL101
|
||||
00356 CL164
|
||||
00357 CL*72
|
||||
00358 P3000-EXIT. CL*97
|
||||
00359 EXIT. CL*72
|
||||
00360 CL101
|
||||
00361 P5000-EDIT-ERROR-OUTPUT. CL*78
|
||||
00362 MOVE FDPT-EMP-NO TO F907-EMP-NO. CL165
|
||||
00363 MOVE WRK-MOD-NAME TO F907-MODULE-NAME. CL165
|
||||
00364 MOVE WRK-MSG-TEXT TO F907-MSG-TEXT. CL165
|
||||
00365 PERFORM S946-WRITE-R907 THRU S946-EXIT. CL156
|
||||
00366 ADD +1 TO WRK-R907-REC-CNT. CL*80
|
||||
00367 CL*93
|
||||
00368 P5000-EXIT. CL*78
|
||||
00369 EXIT. CL*78
|
||||
00370 CL*78
|
||||
00371 T0000-TERMINATE. EFTBD130
|
||||
00372 CL*59
|
||||
00373 DISPLAY ' '. CL221
|
||||
00374 CL*71
|
||||
00375 DISPLAY '*** EFTBD130 TERMINATION STATISTICS ***'. CL135
|
||||
00376 CL*71
|
||||
00377 DISPLAY ' '. CL237
|
||||
00378 DISPLAY ' VSAM MASTR PROFILE RECORDS READ COUNT :' CL*98
|
||||
00379 WRK-MPRF-READ-CNT. CL*98
|
||||
00380 CL223
|
||||
00381 DISPLAY ' '. CL*98
|
||||
00382 DISPLAY ' EFT PAYMENT INPUT RECORDS READ COUNT :' CL*98
|
||||
00383 WRK-EFT-READ-CNT. CL*98
|
||||
00384 CL*98
|
||||
00385 DISPLAY ' T025 - BTC PAYMENT OUTPUT RECS WRITTEN CNT :' CL168
|
||||
00386 WRK-BTC-WRITE-CNT. CL*75
|
||||
00387 CL*96
|
||||
00388 DISPLAY ' R907 ERRORS OUTPUT RECORDS WRITTEN COUNT :' CL168
|
||||
00389 WRK-R907-REC-CNT. CL*96
|
||||
00390 CL**5
|
||||
00391 CL*93
|
||||
00392 T0000-EXIT. EFTBD130
|
||||
00393 EXIT. EFTBD130
|
||||
00394 EJECT EFTBD130
|
||||
00395 CL*59
|
||||
00396 S001-FROM-FED-8. CL108
|
||||
00397 SET L001-FROM-FED-8 TO TRUE. CL108
|
||||
00398 GO TO S001-DATE. CL108
|
||||
00399 CL108
|
||||
00400 S001-FROM-ABS-DAY. CL108
|
||||
00401 SET L001-FROM-ABS-DAY TO TRUE. CL108
|
||||
00402 GO TO S001-DATE. CL108
|
||||
00403 CL108
|
||||
00404 S001-FROM-CAL-6. CL108
|
||||
00405 SET L001-FROM-CAL-6 TO TRUE. CL108
|
||||
00406 GO TO S001-DATE. CL108
|
||||
00407 CL108
|
||||
00408 S001-DATE. CL108
|
||||
00409 CALL 'DTSBU001' USING L001-LINK-AREA. CL108
|
||||
00410 S001-EXIT. CL108
|
||||
00411 EXIT. CL108
|
||||
00412 CL*15
|
||||
00413 S004-FROM-3. CL*24
|
||||
00414 SET L004-FROM-3 TO TRUE. CL*24
|
||||
00415 GO TO S004-YRQ. CL*24
|
||||
00416 CL*24
|
||||
00417 S004-YRQ. CL*24
|
||||
00418 CALL 'DTSBU004' USING L004-LINK-AREA. CL*24
|
||||
00419 CL*24
|
||||
00420 S004-EXIT. CL*24
|
||||
00421 EXIT. CL*24
|
||||
00422 CL*24
|
||||
00423 S005-SYS-DATE. CL*61
|
||||
00424 CALL 'DTSBU005' USING L005-COMM-AREA. CL*61
|
||||
00425 CL*61
|
||||
00426 S005-EXIT. CL*61
|
||||
00427 EXIT. CL*61
|
||||
00428 CL*78
|
||||
00429 CL*70
|
||||
00430 S910-READ. CL*70
|
||||
00431 SET L910-READ-88 TO TRUE. CL*70
|
||||
00432 GO TO S910-MSTR-IO. CL*70
|
||||
00433 CL*70
|
||||
00434 S910-START-BROWSE. CL*70
|
||||
00435 SET L910-START-BROWSE-88 TO TRUE. CL*70
|
||||
00436 GO TO S910-MSTR-IO. CL*70
|
||||
00437 CL*13
|
||||
00438 S910-READ-NEXT. CL*70
|
||||
00439 SET L910-READ-NEXT-88 TO TRUE. CL*70
|
||||
00440 GO TO S910-MSTR-IO. CL*70
|
||||
00441 CL*70
|
||||
00442 S910-COUNT. CL*70
|
||||
00443 SET L910-COUNT-88 TO TRUE. CL*70
|
||||
00444 GO TO S910-MSTR-IO. CL*70
|
||||
00445 CL*70
|
||||
00446 S910-WRITE. CL*70
|
||||
00447 SET L910-WRITE-88 TO TRUE. CL*70
|
||||
00448 GO TO S910-MSTR-IO. CL*70
|
||||
00449 CL*70
|
||||
00450 S910-REWRITE. CL*70
|
||||
00451 SET L910-REWRITE-88 TO TRUE. CL*70
|
||||
00452 GO TO S910-MSTR-IO. CL*70
|
||||
00453 CL*70
|
||||
00454 S910-MSTR-IO. CL*70
|
||||
00455 CALL 'DTSBU910' USING L910-LINK-AREA CL*70
|
||||
00456 MSKL-REC. CL*70
|
||||
00457 S910-EXIT. CL*70
|
||||
00458 EXIT. CL*70
|
||||
00459 CL*93
|
||||
00460 CL*93
|
||||
00461 S927-WRITE-BTC. CL155
|
||||
00462 SET L927-WRITE-88 TO TRUE. CL161
|
||||
00463 CALL 'DTSBU927' USING L927-LINK-AREA CL160
|
||||
00464 TSKL-REC. CL160
|
||||
00465 S927-EXIT. CL155
|
||||
00466 EXIT. CL155
|
||||
00467 CL155
|
||||
00468 CL155
|
||||
00469 S946-WRITE-R907. CL155
|
||||
00470 CALL 'DTSBU946' USING R907-REC. CL171
|
||||
00471 CL155
|
||||
00472 S946-EXIT. CL155
|
||||
00473 EXIT. CL*80
|
||||
00474 CL*80
|
||||
00475 CL125
|
||||
00476 S999-ABEND. EFTBD130
|
||||
00477 DISPLAY '*** EFTBD130 ABENDING : ' CL135
|
||||
00478 WRK-ABEND-MSG. CL*83
|
||||
00479 EFTBD130
|
||||
00480 CALL 'DTSBU999' USING WRK-ABEND-CD. EFTBD130
|
||||
00481 S999-EXIT. EFTBD130
|
||||
00482 EXIT. EFTBD130
|
||||
Reference in New Issue
Block a user