464 lines
37 KiB
COBOL
464 lines
37 KiB
COBOL
00001 IDENTIFICATION DIVISION. 09/22/99
|
|
00002 PROGRAM-ID. DTSBE312. DTSBE312
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD LV021
|
|
00004 MODIFIED BY TRW S&ITG. CL**5
|
|
00005 DATE-WRITTEN. AUGUST 1994. DTSBE312
|
|
00006 DATE-COMPILED. DTSBE312
|
|
00007 SKIP3 DTSBE312
|
|
00008 ***** DTSBE312
|
|
00009 * DTSBE312
|
|
00010 * CALLING SEQUENCE: DTSBE312 CREATES DTSIR312 RECORDS. CL**2
|
|
00011 * DTSBD800 CALLS DTSBR312 WHICH CL**2
|
|
00012 * PRODUCES THE REPORT LIST. CL**2
|
|
00013 * CL**2
|
|
00014 * FUNCTION: FIELD REPRESENTATIVE REPORT TRANSACTION LIST. DTSBE312
|
|
00015 * DTSBE312
|
|
00016 * DTSBE312
|
|
00017 * MODIFICATION LOG: DTSBE312
|
|
00018 * DTSBE312
|
|
00019 * XX/XX/XX XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBE312
|
|
00020 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBE312
|
|
00021 * WORK ORDER: PROGRAMMER: XXX DTSBE312
|
|
00022 * DTSBE312
|
|
00023 * DTSBE312
|
|
00024 * DESCRIPTION: DTSBE312
|
|
00025 * DTSBE312
|
|
00026 * DTSBE312
|
|
00027 * INITIATION: DTSBE312
|
|
00028 * DTSBE312
|
|
00029 * SET LECM-MST-OPEN-READ-88 TO TRUE. DTSBE312
|
|
00030 * SET LECM-REF-OPEN-READ-88 TO TRUE. DTSBE312
|
|
00031 * DTSBE312
|
|
00032 * EDIT AND DEFAULT PARAMETERS. SEE PRINTED OUTPUTS DTSBE312
|
|
00033 * DESCRIPTIONS AND LAYOUTS (312R1). DTSBE312
|
|
00034 * DTSBE312
|
|
00035 * SCAN THE FFID RECORDS, CONSTRUCTING TBL-FLD-REP. DTSBE312
|
|
00036 * DTSBE312
|
|
00037 * DTSBE312
|
|
00038 * PROCESSING: DTSBE312
|
|
00039 * DTSBE312
|
|
00040 * SEE PRINTED OUTPUTS DESCRIPTION AND LAYOUTS (312R1). DTSBE312
|
|
00041 * DTSBE312
|
|
00042 * HOW CAN ONE DETERMINE WHETHER OR NOT THE OPERATOR ID DTSBE312
|
|
00043 * VALUE IN MRPT-RESPONSIBLE-OP-ID REPRESENTS A FIELD REP? DTSBE312
|
|
00044 * DTSBE312
|
|
00045 * DURING THE INITIALIZATION PROCESS, SCAN THE FFID RECORDS DTSBE312
|
|
00046 * AND CONSTRUCT A TABLE OF ALL FLD-REP-ID VALUES AND THE DTSBE312
|
|
00047 * OP-ID VALUE RELATED TO THE FIELD REP ID. DTSBE312
|
|
00048 * DTSBE312
|
|
00049 * THEN DURING THE SCAN IF MRPT RECORDS: IF DTSBE312
|
|
00050 * MRPT-RESPONSIBLE-OP-ID IS EQUAL TO SPACES, THEN BYPASS DTSBE312
|
|
00051 * THE MRPT RECORD IMMEDIATELY; OTHERWISE COMPARE DTSBE312
|
|
00052 * MRPT-RESPONSIBLE-OP-ID TO THE ENTRIES IN WRK-OP-ID. A DTSBE312
|
|
00053 * HIT INDICATES MRPT-RESPONSIBLE-OP-ID IS A FIELD REP. DTSBE312
|
|
00054 * DTSBE312
|
|
00055 * DTSBE312
|
|
00056 * TERMINATION: DTSBE312
|
|
00057 * DTSBE312
|
|
00058 * NONE. DTSBE312
|
|
00059 * DTSBE312
|
|
00060 * DTSBE312
|
|
00061 * RECORDS READ: DTSBE312
|
|
00062 * DTSBE312
|
|
00063 * MASTER: DTSBE312
|
|
00064 * DTSBE312
|
|
00065 * MRPT DTSBE312
|
|
00066 * DTSBE312
|
|
00067 * DTSBE312
|
|
00068 * ALTERNATE INDEX: DTSBE312
|
|
00069 * DTSBE312
|
|
00070 * NONE. DTSBE312
|
|
00071 * DTSBE312
|
|
00072 * DTSBE312
|
|
00073 * REFERENCE: DTSBE312
|
|
00074 * DTSBE312
|
|
00075 * FFID DTSBE312
|
|
00076 * DTSBE312
|
|
00077 * DTSBE312
|
|
00078 * RECORDS UPDATED: DTSBE312
|
|
00079 * DTSBE312
|
|
00080 * NONE. DTSBE312
|
|
00081 * DTSBE312
|
|
00082 * DTSBE312
|
|
00083 * REPORT RECORDS WRITTEN: DTSBE312
|
|
00084 * DTSBE312
|
|
00085 * R312 FIELD REPRESENTATIVE REPORT TRANSACTION LIST. DTSBE312
|
|
00086 * DTSBE312
|
|
00087 * DTSBE312
|
|
00088 * BATCH TRANSACTION COLLECTION RECORDS WRITTEN: DTSBE312
|
|
00089 * DTSBE312
|
|
00090 * NONE. DTSBE312
|
|
00091 * DTSBE312
|
|
00092 * DTSBE312
|
|
00093 * MODULES CALLED: DTSBE312
|
|
00094 * DTSBE312
|
|
00095 * DTSBU001 DATE CONVERSION/EDIT. CL**2
|
|
00096 * DTSBU910 MASTER FILE I/O. CL**2
|
|
00097 * DTSBU931 REFERENCE FILE I/O. CL**2
|
|
00098 * DTSBU946 VARIABLE LENGTH RECORDS SEQUENTIAL OUTPUT 1. CL**2
|
|
00099 * DTSBE312
|
|
00100 * DTSBE312
|
|
00101 * VERMONT REFERENCE: DTSBE312
|
|
00102 * DTSBE312
|
|
00103 * NONE. DTSBE312
|
|
00104 * DTSBE312
|
|
00105 ***** DTSBE312
|
|
00106 SKIP3 DTSBE312
|
|
00107 ENVIRONMENT DIVISION. DTSBE312
|
|
00108 SKIP3 DTSBE312
|
|
00109 DATA DIVISION. DTSBE312
|
|
00110 SKIP3 DTSBE312
|
|
00111 WORKING-STORAGE SECTION. DTSBE312
|
|
001115 77 PAN-VALET PICTURE X(24) VALUE '021DTSBE312 09/22/99'. DTSBE312
|
|
00112 SKIP3 DTSBE312
|
|
00113 01 WRK-AREA. DTSBE312
|
|
00114 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +312.DTSBE312
|
|
00115 SKIP1 DTSBE312
|
|
00116 05 WRK-MOD-NAME PIC X(08) VALUE 'DTSBE312'. CL**2
|
|
00117 SKIP3 DTSBE312
|
|
00118 05 ABEND-MSG PIC X(60). DTSBE312
|
|
00119 SKIP3 DTSBE312
|
|
00120 05 WRK-PARM-PERIOD-START-DATE PIC S9(09) COMP-3. DTSBE312
|
|
00121 SKIP1 DTSBE312
|
|
00122 05 WRK-PARM-PERIOD-END-DATE PIC S9(09) COMP-3. DTSBE312
|
|
00123 SKIP3 DTSBE312
|
|
00124 05 TBL-SUB PIC S9(04) COMP. CL**4
|
|
00125 SKIP3 DTSBE312
|
|
00126 05 TBL-CNT PIC S9(04) COMP. DTSBE312
|
|
00127 05 TBL-ENTRY OCCURS 100 TIMES DTSBE312
|
|
00128 INDEXED BY TBL-IDX. DTSBE312
|
|
00129 10 TBL-FLD-REP-ID PIC X(02). DTSBE312
|
|
00130 10 TBL-OP-ID PIC X(08). DTSBE312
|
|
00131 EJECT DTSBE312
|
|
00132 01 L001-LINK-AREA. DTSBE312
|
|
00133 ++INCLUDE DTSIL001 CL**2
|
|
00134 EJECT DTSBE312
|
|
00135 01 L910-LINK-AREA. DTSBE312
|
|
00136 ++INCLUDE DTSIL910 CL**2
|
|
00137 SKIP3 DTSBE312
|
|
00138 01 MSKL-REC. DTSBE312
|
|
00139 ++INCLUDE DTSIMSKL CL**2
|
|
00140 SKIP3 DTSBE312
|
|
00141 01 MRPT-REC. DTSBE312
|
|
00142 ++INCLUDE DTSIMRPT CL**2
|
|
00143 EJECT DTSBE312
|
|
00144 01 L931-LINK-AREA. DTSBE312
|
|
00145 ++INCLUDE DTSIL931 CL**2
|
|
00146 SKIP3 DTSBE312
|
|
00147 01 FSKL-REC. DTSBE312
|
|
00148 ++INCLUDE DTSIFSKL CL**2
|
|
00149 SKIP3 DTSBE312
|
|
00150 01 FFID-REC. DTSBE312
|
|
00151 ++INCLUDE DTSIFFID CL**2
|
|
00152 EJECT DTSBE312
|
|
00153 01 R312-REC. DTSBE312
|
|
00154 ++INCLUDE DTSIR312 CL**2
|
|
00155 EJECT DTSBE312
|
|
00156 LINKAGE SECTION. DTSBE312
|
|
00157 SKIP3 DTSBE312
|
|
00158 01 LECM-LINK-AREA. CL*10
|
|
00159 ++INCLUDE DTSILECM CL**4
|
|
00160 SKIP3 DTSBE312
|
|
00161 10 LECM-PARM-AREA REDEFINES LECM-EXTRACT-PARMS. DTSBE312
|
|
00162 15 LECM-PARM-PERIOD-START-DATE PIC X(06). DTSBE312
|
|
00163 15 FILLER PIC X(01). DTSBE312
|
|
00164 15 LECM-PARM-PERIOD-END-DATE PIC X(06). DTSBE312
|
|
00165 15 FILLER PIC X(55). DTSBE312
|
|
00166 EJECT DTSBE312
|
|
00167 01 MPRF-LINK-REC. DTSBE312
|
|
00168 ++INCLUDE DTSIMPRF CL**2
|
|
00169 EJECT DTSBE312
|
|
00170 PROCEDURE DIVISION USING LECM-LINK-AREA DTSBE312
|
|
00171 MPRF-LINK-REC. DTSBE312
|
|
00172 SKIP2 DTSBE312
|
|
00173 IF LECM-PROCESS-88 DTSBE312
|
|
00174 PERFORM P0000-PROCESS THRU P0000-EXIT DTSBE312
|
|
00175 ELSE DTSBE312
|
|
00176 IF LECM-INITIALIZE-88 DTSBE312
|
|
00177 PERFORM I0000-INITIALIZE THRU I0000-EXIT DTSBE312
|
|
00178 ELSE DTSBE312
|
|
00179 IF LECM-TERMINATE-88 DTSBE312
|
|
00180 PERFORM T0000-TERMINATE THRU T0000-EXIT DTSBE312
|
|
00181 ELSE DTSBE312
|
|
00182 MOVE 'INVALID LECM-CALL-TYPE-IND ENCOUNTERED' DTSBE312
|
|
00183 TO ABEND-MSG DTSBE312
|
|
00184 PERFORM S999-ABEND THRU S999-EXIT. DTSBE312
|
|
00185 SKIP2 DTSBE312
|
|
00186 GOBACK. DTSBE312
|
|
00187 EJECT DTSBE312
|
|
00188 I0000-INITIALIZE. DTSBE312
|
|
00189 SKIP2 DTSBE312
|
|
00190 MOVE LENGTH OF R312-REC TO R312-LENGTH. CL**4
|
|
00191 MOVE '312' TO R312-REC-TYPE. CL**4
|
|
00192 MOVE LECM-TRACE-IND TO L910-TRACE-IND CL**4
|
|
00193 L931-TRACE-IND. CL**4
|
|
00194 MOVE WRK-MOD-NAME TO L910-MOD-NAME CL**4
|
|
00195 L931-MOD-NAME. CL**4
|
|
00196 DTSBE312
|
|
00197 PERFORM I1000-EDIT-AND-DEFAULT-PARMS THRU I1000-EXIT. DTSBE312
|
|
00198 SKIP1 DTSBE312
|
|
00199 PERFORM I2000-TBL-FLD-REP-ID THRU I2000-EXIT. DTSBE312
|
|
00200 SKIP1 DTSBE312
|
|
00201 SET LECM-MST-OPEN-READ-88 TO TRUE. DTSBE312
|
|
00202 SET LECM-REF-OPEN-READ-88 TO TRUE. DTSBE312
|
|
00203 SKIP2 DTSBE312
|
|
00204 I0000-EXIT. DTSBE312
|
|
00205 EXIT. DTSBE312
|
|
00206 SKIP3 DTSBE312
|
|
00207 I1000-EDIT-AND-DEFAULT-PARMS. DTSBE312
|
|
00208 PERFORM I1100-PERIOD-START-DATE THRU I1100-EXIT. DTSBE312
|
|
00209 DTSBE312
|
|
00210 PERFORM I1200-PERIOD-END-DATE THRU I1200-EXIT. DTSBE312
|
|
00211 I1000-EXIT. DTSBE312
|
|
00212 EXIT. DTSBE312
|
|
00213 SKIP3 DTSBE312
|
|
00214 I1100-PERIOD-START-DATE. DTSBE312
|
|
00215 IF LECM-PARM-PERIOD-START-DATE = SPACES DTSBE312
|
|
00216 IF LECM-PERIOD-START-DATE > +0 DTSBE312
|
|
00217 MOVE LECM-PERIOD-START-DATE DTSBE312
|
|
00218 TO WRK-PARM-PERIOD-START-DATE DTSBE312
|
|
00219 ELSE DTSBE312
|
|
00220 MOVE 'PERIOD-START-DATE MISSING' DTSBE312
|
|
00221 TO ABEND-MSG DTSBE312
|
|
00222 PERFORM S999-ABEND THRU S999-EXIT DTSBE312
|
|
00223 ELSE DTSBE312
|
|
00224 MOVE LECM-PARM-PERIOD-START-DATE TO L001-CAL-6-DATE-X DTSBE312
|
|
00225 PERFORM S001-FROM-CAL-6 THRU S001-EXIT DTSBE312
|
|
00226 IF L001-VALID-DATE DTSBE312
|
|
00227 MOVE L001-FED-8-DATE-9 TO WRK-PARM-PERIOD-START-DATE DTSBE312
|
|
00228 ELSE DTSBE312
|
|
00229 MOVE 'PERIOD-START-DATE NOT VALID' DTSBE312
|
|
00230 TO ABEND-MSG DTSBE312
|
|
00231 PERFORM S999-ABEND THRU S999-EXIT. DTSBE312
|
|
00232 I1100-EXIT. DTSBE312
|
|
00233 EXIT. DTSBE312
|
|
00234 SKIP3 DTSBE312
|
|
00235 I1200-PERIOD-END-DATE. DTSBE312
|
|
00236 IF LECM-PARM-PERIOD-END-DATE = SPACES DTSBE312
|
|
00237 IF LECM-PERIOD-END-DATE > +0 DTSBE312
|
|
00238 MOVE LECM-PERIOD-END-DATE DTSBE312
|
|
00239 TO WRK-PARM-PERIOD-END-DATE DTSBE312
|
|
00240 ELSE DTSBE312
|
|
00241 MOVE 'PERIOD-END-DATE MISSING' DTSBE312
|
|
00242 TO ABEND-MSG DTSBE312
|
|
00243 PERFORM S999-ABEND THRU S999-EXIT DTSBE312
|
|
00244 ELSE DTSBE312
|
|
00245 MOVE LECM-PARM-PERIOD-END-DATE TO L001-CAL-6-DATE-X DTSBE312
|
|
00246 PERFORM S001-FROM-CAL-6 THRU S001-EXIT DTSBE312
|
|
00247 IF L001-VALID-DATE DTSBE312
|
|
00248 MOVE L001-FED-8-DATE-9 TO WRK-PARM-PERIOD-END-DATE DTSBE312
|
|
00249 ELSE DTSBE312
|
|
00250 MOVE 'PERIOD-END-DATE NOT VALID' DTSBE312
|
|
00251 TO ABEND-MSG DTSBE312
|
|
00252 PERFORM S999-ABEND THRU S999-EXIT. DTSBE312
|
|
00253 DTSBE312
|
|
00254 IF WRK-PARM-PERIOD-START-DATE > WRK-PARM-PERIOD-END-DATE DTSBE312
|
|
00255 MOVE 'PERIOD START DATE IS GREATER THAN PERIOD END DATE' DTSBE312
|
|
00256 TO ABEND-MSG DTSBE312
|
|
00257 PERFORM S999-ABEND THRU S999-EXIT. DTSBE312
|
|
00258 I1200-EXIT. DTSBE312
|
|
00259 EXIT. DTSBE312
|
|
00260 EJECT DTSBE312
|
|
00261 I2000-TBL-FLD-REP-ID. DTSBE312
|
|
00262 MOVE +0 TO TBL-CNT. DTSBE312
|
|
00263 DTSBE312
|
|
00264 MOVE LOW-VALUES TO FFID-KEY-AREA. DTSBE312
|
|
00265 SET FFID-FID-88 TO TRUE. DTSBE312
|
|
00266 MOVE FFID-KEY-AREA TO FSKL-KEY-AREA. DTSBE312
|
|
00267 PERFORM S931-START-BROWSE THRU S931-EXIT. DTSBE312
|
|
00268 PERFORM I2100-FFID-SCAN THRU I2100-EXIT DTSBE312
|
|
00269 UNTIL L931-NO-REC-88. DTSBE312
|
|
00270 I2000-EXIT. DTSBE312
|
|
00271 EXIT. DTSBE312
|
|
00272 SKIP3 DTSBE312
|
|
00273 I2100-FFID-SCAN. DTSBE312
|
|
00274 MOVE FSKL-REC TO FFID-REC. DTSBE312
|
|
00275 DTSBE312
|
|
00276 IF TBL-CNT < +100 DTSBE312
|
|
00277 ADD +1 TO TBL-CNT DTSBE312
|
|
00278 MOVE FFID-FLD-REP-ID TO TBL-FLD-REP-ID (TBL-CNT) DTSBE312
|
|
00279 MOVE FFID-OP-ID TO TBL-OP-ID (TBL-CNT) DTSBE312
|
|
00280 ELSE DTSBE312
|
|
00281 MOVE 'MORE THAN 100 FIELD REPRESENTATIVES ENCOUNTERED' DTSBE312
|
|
00282 TO ABEND-MSG DTSBE312
|
|
00283 PERFORM S999-ABEND THRU S999-EXIT. DTSBE312
|
|
00284 DTSBE312
|
|
00285 PERFORM S931-READ-NEXT THRU S931-EXIT. DTSBE312
|
|
00286 I2100-EXIT. DTSBE312
|
|
00287 EXIT. DTSBE312
|
|
00288 EJECT DTSBE312
|
|
00289 ************************************************************** DTSBE312
|
|
00290 * THIS IS THE PROCESS PARAGRAPH FOR DTSBE312. CL**2
|
|
00291 ************************************************************** DTSBE312
|
|
00292 DTSBE312
|
|
00293 P0000-PROCESS. DTSBE312
|
|
00294 DTSBE312
|
|
00295 MOVE LOW-VALUES TO MRPT-KEY-AREA. DTSBE312
|
|
00296 MOVE MPRF-EMP-NO TO MRPT-EMP-NO. DTSBE312
|
|
00297 SET MRPT-RPT-88 TO TRUE. CL*13
|
|
00298 MOVE MRPT-KEY-AREA TO MSKL-KEY-AREA. DTSBE312
|
|
00299 DTSBE312
|
|
00300 PERFORM S910-START-BROWSE THRU S910-EXIT. DTSBE312
|
|
00301 DTSBE312
|
|
00302 PERFORM P1000-SCAN-MRPT THRU P1000-EXIT DTSBE312
|
|
00303 UNTIL L910-NO-REC-88. DTSBE312
|
|
00304 DTSBE312
|
|
00305 P0000-EXIT. DTSBE312
|
|
00306 EXIT. DTSBE312
|
|
00307 EJECT DTSBE312
|
|
00308 ************************************************************** DTSBE312
|
|
00309 * THIS PARAGRAPH SCANS THE MRPT RECORDS. DTSBE312
|
|
00310 ************************************************************** DTSBE312
|
|
00311 DTSBE312
|
|
00312 P1000-SCAN-MRPT. DTSBE312
|
|
00313 DTSBE312
|
|
00314 MOVE MSKL-REC TO MRPT-REC. DTSBE312
|
|
00315 DTSBE312
|
|
00316 IF MRPT-RESPONSIBLE-OP-ID EQUAL SPACES CL*19
|
|
00317 NEXT SENTENCE CL*19
|
|
00318 ELSE CL*19
|
|
00319 IF MRPT-ORIG-88 DTSBE312
|
|
00320 PERFORM P1100-PROCESS-MRPT THRU P1100-EXIT. DTSBE312
|
|
00321 DTSBE312
|
|
00322 PERFORM S910-READ-NEXT THRU S910-EXIT. DTSBE312
|
|
00323 DTSBE312
|
|
00324 P1000-EXIT. DTSBE312
|
|
00325 EXIT. DTSBE312
|
|
00326 EJECT DTSBE312
|
|
00327 ************************************************************** DTSBE312
|
|
00328 * THIS PARAGRAPH PROCESSES THE MRPT RECORDS. DTSBE312
|
|
00329 ************************************************************** DTSBE312
|
|
00330 DTSBE312
|
|
00331 P1100-PROCESS-MRPT. DTSBE312
|
|
00332 DTSBE312
|
|
00333 IF MRPT-ESTB-DATE LESS THAN WRK-PARM-PERIOD-START-DATE DTSBE312
|
|
00334 GO TO P1100-EXIT. DTSBE312
|
|
00335 DTSBE312
|
|
00336 IF MRPT-ESTB-DATE GREATER THAN WRK-PARM-PERIOD-END-DATE DTSBE312
|
|
00337 GO TO P1100-EXIT. DTSBE312
|
|
00338 DTSBE312
|
|
00339 MOVE +0 TO TBL-SUB. DTSBE312
|
|
00340 DTSBE312
|
|
00341 PERFORM P1110-DETER-FIELD-REP THRU P1110-EXIT DTSBE312
|
|
00342 VARYING TBL-IDX FROM 1 BY 1 DTSBE312
|
|
00343 UNTIL TBL-SUB NOT EQUAL +0 OR DTSBE312
|
|
00344 TBL-IDX GREATER THAN TBL-CNT. DTSBE312
|
|
00345 DTSBE312
|
|
00346 IF TBL-SUB EQUAL ZERO CL*20
|
|
00347 GO TO P1100-EXIT CL*20
|
|
00348 ELSE CL*20
|
|
00349 PERFORM P1120-SETUP-R312 THRU P1120-EXIT CL*20
|
|
00350 PERFORM S946-WRITE-R312 THRU S946-EXIT. CL*20
|
|
00351 DTSBE312
|
|
00352 P1100-EXIT. DTSBE312
|
|
00353 EXIT. DTSBE312
|
|
00354 EJECT DTSBE312
|
|
00355 ************************************************************** DTSBE312
|
|
00356 * THIS PARAGRAPH READS THE FIELD REP TABLE IN WORKING STORAGE DTSBE312
|
|
00357 * TO DETERMINE IF THE RESPONSIBLE ID IS A FIELD REP. DTSBE312
|
|
00358 ************************************************************** DTSBE312
|
|
00359 DTSBE312
|
|
00360 P1110-DETER-FIELD-REP. DTSBE312
|
|
00361 DTSBE312
|
|
00362 IF TBL-OP-ID (TBL-IDX) EQUAL MRPT-RESPONSIBLE-OP-ID DTSBE312
|
|
00363 SET TBL-SUB TO TBL-IDX. DTSBE312
|
|
00364 DTSBE312
|
|
00365 P1110-EXIT. DTSBE312
|
|
00366 EXIT. DTSBE312
|
|
00367 EJECT DTSBE312
|
|
00368 ************************************************************** DTSBE312
|
|
00369 * THIS PARAGRAPH SETS UP THE R312 REPORT EXTRACT RECORD. DTSBE312
|
|
00370 ************************************************************** DTSBE312
|
|
00371 DTSBE312
|
|
00372 P1120-SETUP-R312. DTSBE312
|
|
00373 DTSBE312
|
|
00374 MOVE TBL-FLD-REP-ID (TBL-SUB) TO R312-FLD-REP-ID. CL*21
|
|
00375 * MOVE 'TESTTEST' TO R312-FLD-REP-ID. CL*21
|
|
00376 MOVE MPRF-EMP-NO TO R312-EMP-NO. CL**6
|
|
00377 MOVE WRK-PARM-PERIOD-START-DATE TO R312-PERIOD-START-DATE. CL**6
|
|
00378 MOVE WRK-PARM-PERIOD-END-DATE TO R312-PERIOD-END-DATE. CL**6
|
|
00379 MOVE MRPT-DOC-NO TO R312-DOC-NO. CL**6
|
|
00380 MOVE MRPT-YRQ TO R312-YRQ. CL**6
|
|
00381 MOVE MRPT-RESPONSIBLE-ACTIVITY TO CL**8
|
|
00382 R312-RESPONSIBLE-ACTIVITY. CL**8
|
|
00383 P1120-EXIT. DTSBE312
|
|
00384 EXIT. DTSBE312
|
|
00385 EJECT DTSBE312
|
|
00386 T0000-TERMINATE. DTSBE312
|
|
00387 SKIP2 DTSBE312
|
|
00388 SKIP2 DTSBE312
|
|
00389 T0000-EXIT. DTSBE312
|
|
00390 EXIT. DTSBE312
|
|
00391 EJECT DTSBE312
|
|
00392 *BOS001-FROM-FED-8. CL*12
|
|
00393 * SET L001-FROM-FED-8 TO TRUE. CL*12
|
|
00394 * GO TO S001-DATE. CL*12
|
|
00395 *BO SKIP1 CL*12
|
|
00396 S001-FROM-CAL-6. DTSBE312
|
|
00397 SET L001-FROM-CAL-6 TO TRUE. DTSBE312
|
|
00398 GO TO S001-DATE. DTSBE312
|
|
00399 SKIP1 DTSBE312
|
|
00400 *BOS001-FROM-ABS-DAY. CL*11
|
|
00401 * SET L001-FROM-ABS-DAY TO TRUE. CL*11
|
|
00402 * GO TO S001-DATE. CL*11
|
|
00403 *BO SKIP1 CL*11
|
|
00404 S001-DATE. DTSBE312
|
|
00405 CALL 'DTSBU001' USING L001-LINK-AREA. CL**2
|
|
00406 S001-EXIT. DTSBE312
|
|
00407 EXIT. DTSBE312
|
|
00408 SKIP3 DTSBE312
|
|
00409 *BOS910-READ. CL*11
|
|
00410 * SET L910-READ-88 TO TRUE. CL*11
|
|
00411 * GO TO S910-MSTR-IO. CL*11
|
|
00412 *BO SKIP1 CL*11
|
|
00413 S910-START-BROWSE. DTSBE312
|
|
00414 SET L910-START-BROWSE-88 TO TRUE. DTSBE312
|
|
00415 GO TO S910-MSTR-IO. DTSBE312
|
|
00416 SKIP1 DTSBE312
|
|
00417 S910-READ-NEXT. DTSBE312
|
|
00418 SET L910-READ-NEXT-88 TO TRUE. DTSBE312
|
|
00419 GO TO S910-MSTR-IO. DTSBE312
|
|
00420 SKIP1 DTSBE312
|
|
00421 *BOS910-COUNT. CL*11
|
|
00422 * SET L910-COUNT-88 TO TRUE. CL*11
|
|
00423 * GO TO S910-MSTR-IO. CL*11
|
|
00424 * SKIP1 CL*11
|
|
00425 S910-MSTR-IO. DTSBE312
|
|
00426 CALL 'DTSBU910' USING L910-LINK-AREA CL**2
|
|
00427 MSKL-REC. DTSBE312
|
|
00428 S910-EXIT. DTSBE312
|
|
00429 EXIT. DTSBE312
|
|
00430 SKIP3 DTSBE312
|
|
00431 *BOS931-READ. CL*11
|
|
00432 * SET L931-READ-88 TO TRUE. CL*11
|
|
00433 * GO TO S931-REF-I. CL*11
|
|
00434 *BO SKIP1 CL*11
|
|
00435 S931-START-BROWSE. DTSBE312
|
|
00436 SET L931-START-BROWSE-88 TO TRUE. DTSBE312
|
|
00437 GO TO S931-REF-I. DTSBE312
|
|
00438 SKIP1 DTSBE312
|
|
00439 S931-READ-NEXT. DTSBE312
|
|
00440 SET L931-READ-NEXT-88 TO TRUE. DTSBE312
|
|
00441 GO TO S931-REF-I. DTSBE312
|
|
00442 SKIP1 DTSBE312
|
|
00443 S931-REF-I. DTSBE312
|
|
00444 CALL 'DTSBU931' USING L931-LINK-AREA CL**2
|
|
00445 FSKL-REC. DTSBE312
|
|
00446 S931-EXIT. DTSBE312
|
|
00447 EXIT. DTSBE312
|
|
00448 SKIP3 DTSBE312
|
|
00449 S946-WRITE-R312. DTSBE312
|
|
00450 CALL 'DTSBU946' USING R312-REC. CL**2
|
|
00451 GO TO S946-EXIT. DTSBE312
|
|
00452 SKIP1 DTSBE312
|
|
00453 S946-EXIT. DTSBE312
|
|
00454 EXIT. DTSBE312
|
|
00455 SKIP3 DTSBE312
|
|
00456 S999-ABEND. DTSBE312
|
|
00457 DISPLAY '*** DTSBE312 ABENDING. ' CL**2
|
|
00458 ABEND-MSG. DTSBE312
|
|
00459 SKIP1 DTSBE312
|
|
00460 CALL 'DTSBU999' USING WRK-ABEND-CD. CL**2
|
|
00461 S999-EXIT. DTSBE312
|
|
00462 EXIT. DTSBE312
|