397 lines
31 KiB
COBOL
397 lines
31 KiB
COBOL
00001 IDENTIFICATION DIVISION. 08/30/12
|
|
00002 PROGRAM-ID. DTSBR116. DTSBR116
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV032
|
|
00004 MODIFIED BY TRW/BDM OCT 1998. DTSBR116
|
|
00005 DATE-WRITTEN. AUGUST 1998. DTSBR116
|
|
00006 DATE-COMPILED. DTSBR116
|
|
00007 DTSBR116
|
|
00008 ***** DTSBR116
|
|
00009 * DTSBR116
|
|
00010 * FUNCTION: NEW, REACTIVATED, INACTIVATED EMPLOYERS LIST. DTSBR116
|
|
00011 * DTSBR116
|
|
00012 * DTSBR116
|
|
00013 * MODIFICATION HISTORY: DTSBR116
|
|
00014 * DTSBR116
|
|
00015 * 09-24-94 INITIAL DEVELOPMENT DTSBR116
|
|
00016 * REFERENCE RFP #RAP AUTHOR OF CHANGE - SFW DTSBR116
|
|
00017 * DTSBR116
|
|
00018 * 12-0D-97 PRINT TWO COPIES OF REPORT. TO FACILITATE DTSBR116
|
|
00019 * DISTRIBUTION OF REPORT (ONE COPY TO DLI AND ONE COPY DTSBR116
|
|
00020 * TO DOR), TWO FILE NAMES ARE USED. DTSBR116
|
|
00021 * REFERENCE RFP #NONE AUTHOR OF CHANGE - EHH DTSBR116
|
|
00022 * DTSBR116
|
|
00023 * 07-27-12 CHANGE TOTAL COUNTERS FROM 9(3) TO 9(5) DTSBR116
|
|
00024 * REFERENCE RFP #NONE AUTHOR OF CHANGE - ZL1 DTSBR116
|
|
00025 * DTSBR116
|
|
00026 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR116
|
|
00027 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR116
|
|
00028 * REFERENCE RFP #**** AUTHOR OF CHANGE - XXX DTSBR116
|
|
00029 * DTSBR116
|
|
00030 * DTSBR116
|
|
00031 * DESCRIPTION: DTSBR116
|
|
00032 * DTSBR116
|
|
00033 * THIS MODULE LISTS ALL EMPLOYERS FOR WHOM AN INITIAL SPAN DTSBR116
|
|
00034 * OF LIABILITY WAS ENTERED, AN ADDITIONAL SPAN OF DTSBR116
|
|
00035 * LIABILITY WAS ENTERED, AN INACTIVATION DATE WAS ENTERED, DTSBR116
|
|
00036 * OR AND INACTIVATION DATE WAS REMOVED. DTSBR116
|
|
00037 * DTSBR116
|
|
00038 * DTSBR116
|
|
00039 * RECORDS READ: DTSBR116
|
|
00040 * DTSBR116
|
|
00041 * NONE. DTSBR116
|
|
00042 * DTSBR116
|
|
00043 * DTSBR116
|
|
00044 * PRINTED OUTPUTS: DTSBR116
|
|
00045 * DTSBR116
|
|
00046 * 116R1 NEW, REACTIVATED, INACTIVATED EMPLOYERS LIST DTSBR116
|
|
00047 * DTSBR116
|
|
00048 * DTSBR116
|
|
00049 * RECORDS WRITTEN: DTSBR116
|
|
00050 * DTSBR116
|
|
00051 * NONE. DTSBR116
|
|
00052 * DTSBR116
|
|
00053 * DTSBR116
|
|
00054 * MODULES CALLED: DTSBR116
|
|
00055 * DTSBR116
|
|
00056 * DTSBU001 DATE EDIT/CONVERSION MODULE DTSBR116
|
|
00057 * DTSBR116
|
|
00058 * DTSBR116
|
|
00059 ***** DTSBR116
|
|
00060 EJECT DTSBR116
|
|
00061 ENVIRONMENT DIVISION. DTSBR116
|
|
00062 DTSBR116
|
|
00063 CONFIGURATION SECTION. DTSBR116
|
|
00064 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. DTSBR116
|
|
00065 DTSBR116
|
|
00066 INPUT-OUTPUT SECTION. DTSBR116
|
|
00067 DTSBR116
|
|
00068 FILE-CONTROL. DTSBR116
|
|
00069 SELECT PRT-FILE1 ASSIGN TO RPT116R1. DTSBR116
|
|
00070 *** SELECT PRT-FILE2 ASSIGN TO RPT116R2. DTSBR116
|
|
00071 DTSBR116
|
|
00072 DATA DIVISION. DTSBR116
|
|
00073 DTSBR116
|
|
00074 FILE SECTION. DTSBR116
|
|
00075 DTSBR116
|
|
00076 FD PRT-FILE1 DTSBR116
|
|
00077 RECORDING MODE IS F. DTSBR116
|
|
00078 01 PRT-RECORD PIC X(133). DTSBR116
|
|
00079 DTSBR116
|
|
00080 EJECT DTSBR116
|
|
00081 WORKING-STORAGE SECTION. DTSBR116
|
|
000815 77 PAN-VALET PICTURE X(24) VALUE '032DTSBR116 08/30/12'. DTSBR116
|
|
00082 DTSBR116
|
|
00083 01 WRK-AREA. DTSBR116
|
|
00084 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +116.DTSBR116
|
|
00085 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR116
|
|
00086 DTSBR116
|
|
00087 05 WS-FOOT-NUMBER-ONE PIC S9(05) COMP-3 VALUE +0. DTSBR116
|
|
00088 05 WS-SUM-NUMBER-ONE PIC S9(05) COMP-3 VALUE +0. DTSBR116
|
|
00089 05 WS-LINE-CNT PIC S9(02) COMP-3 VALUE 60. DTSBR116
|
|
00090 05 WS-LINE-CNT2 PIC S9(02) COMP-3 VALUE +0. DTSBR116
|
|
00091 05 WS-PAGE-CNT PIC S9(03) COMP-3 VALUE +0. DTSBR116
|
|
00092 DTSBR116
|
|
00093 05 WS-CATEGORY-HOLD PIC X(01). DTSBR116
|
|
00094 88 WS-HOLD-NEW-88 VALUE '1'. DTSBR116
|
|
00095 88 WS-HOLD-REACT-88 VALUE '2'. DTSBR116
|
|
00096 88 WS-HOLD-INACT-88 VALUE '3'. DTSBR116
|
|
00097 DTSBR116
|
|
00098 05 WS-COLUMN-HEADING3. DTSBR116
|
|
00099 10 FILLER PIC X(40) DTSBR116
|
|
00100 VALUE 'EMP NO PRIMARY NAME '. DTSBR116
|
|
00101 10 FILLER PIC X(40) DTSBR116
|
|
00102 VALUE ' LIABILITY DATE IN'. DTSBR116
|
|
00103 10 FILLER PIC X(40) DTSBR116
|
|
00104 VALUE 'ACTIVE DATE NUMBER OF CLA'. DTSBR116
|
|
00105 10 FILLER PIC X(05) DTSBR116
|
|
00106 VALUE 'SS '. DTSBR116
|
|
00107 05 WS-COLUMN-HEADING4. DTSBR116
|
|
00108 10 FILLER PIC X(97) VALUE SPACES. DTSBR116
|
|
00109 10 FILLER PIC X(09) DTSBR116
|
|
00110 VALUE 'DELQ RPTS'. DTSBR116
|
|
00111 10 FILLER PIC X(19) VALUE SPACES. DTSBR116
|
|
00112 EJECT DTSBR116
|
|
00113 01 L001-LINK-AREA. DTSBR116
|
|
00114 ++INCLUDE DTSIL001 DTSBR116
|
|
00115 EJECT DTSBR116
|
|
00116 01 HEADER-1. DTSBR116
|
|
00117 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00118 05 FILLER PIC X(05) DTSBR116
|
|
00119 VALUE '116R1'. DTSBR116
|
|
00120 05 FILLER PIC X(34) VALUE SPACES. DTSBR116
|
|
00121 05 WS-AGY-NAME-LINE1 PIC X(50) VALUE SPACES. DTSBR116
|
|
00122 05 FILLER PIC X(28) VALUE SPACES. DTSBR116
|
|
00123 05 FILLER PIC X(05) DTSBR116
|
|
00124 VALUE 'DATE:'. DTSBR116
|
|
00125 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00126 05 WS-SYS-DATE PIC X(08) VALUE SPACES. DTSBR116
|
|
00127 01 HEADER-2. DTSBR116
|
|
00128 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00129 05 FILLER PIC X(39) VALUE SPACES. DTSBR116
|
|
00130 05 WS-AGY-NAME-LINE2 PIC X(50) VALUE SPACES. DTSBR116
|
|
00131 05 FILLER PIC X(28) VALUE SPACES. DTSBR116
|
|
00132 05 FILLER PIC X(05) DTSBR116
|
|
00133 VALUE 'TIME:'. DTSBR116
|
|
00134 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00135 05 WS-SYS-TIME PIC X(08) VALUE SPACES. DTSBR116
|
|
00136 01 HEADER-3. DTSBR116
|
|
00137 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00138 05 FILLER PIC X(42) DTSBR116
|
|
00139 VALUE 'ROUTE TO: REGISTRATION AND RATES'. DTSBR116
|
|
00140 05 FILLER PIC X(02) VALUE SPACES. DTSBR116
|
|
00141 05 FILLER PIC X(39) DTSBR116
|
|
00142 VALUE 'NEW, REACTIVATED, INACTIVATED EMPLOYERS'. DTSBR116
|
|
00143 05 FILLER PIC X(05) DTSBR116
|
|
00144 VALUE ' LIST'. DTSBR116
|
|
00145 05 FILLER PIC X(29) VALUE SPACES. DTSBR116
|
|
00146 05 FILLER PIC X(05) DTSBR116
|
|
00147 VALUE 'PAGE:'. DTSBR116
|
|
00148 05 FILLER PIC X(03) VALUE SPACES. DTSBR116
|
|
00149 05 HDR3-PAGE-CNT PIC ZZ,ZZ9. DTSBR116
|
|
00150 01 HEADER-4. DTSBR116
|
|
00151 05 FILLER PIC X(10) VALUE SPACES. DTSBR116
|
|
00152 05 FILLER PIC X(20) DTSBR116
|
|
00153 VALUE ' EMPLOYER SERVICES '. DTSBR116
|
|
00154 01 HEADER-5. DTSBR116
|
|
00155 05 FILLER PIC X(10) VALUE SPACES. DTSBR116
|
|
00156 05 FILLER PIC X(20) DTSBR116
|
|
00157 VALUE ' LMI '. DTSBR116
|
|
00158 01 HEADER-6. DTSBR116
|
|
00159 05 FILLER PIC X(56) VALUE SPACES. DTSBR116
|
|
00160 05 WS-REPORT-TITLE PIC X(21) VALUE SPACES. DTSBR116
|
|
00161 01 HEADER-7 PIC X(133) VALUE SPACES. DTSBR116
|
|
00162 01 HEADER-8 PIC X(133) VALUE SPACES. DTSBR116
|
|
00163 01 HEADER-9. DTSBR116
|
|
00164 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00165 05 WS-COLUMN-HEADING1 PIC X(125) VALUE SPACES. DTSBR116
|
|
00166 01 HEADER-10. DTSBR116
|
|
00167 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00168 05 WS-COLUMN-HEADING2 PIC X(125) VALUE SPACES. DTSBR116
|
|
00169 DTSBR116
|
|
00170 01 DETAIL-LINE-2. DTSBR116
|
|
00171 05 FILLER PIC X(01) VALUE SPACE. DTSBR116
|
|
00172 05 WS-EMP-NO PIC 999B999. DTSBR116
|
|
00173 05 FILLER PIC X(03) VALUE SPACES. DTSBR116
|
|
00174 05 WS-PRIMARY-NAME PIC X(40) VALUE SPACES. DTSBR116
|
|
00175 05 FILLER PIC X(07) VALUE SPACES. DTSBR116
|
|
00176 05 WS-LIAB-DATE PIC X(10) VALUE SPACES. DTSBR116
|
|
00177 05 FILLER PIC X(13) VALUE SPACES. DTSBR116
|
|
00178 05 WS-INACT-DATE PIC X(10) VALUE SPACES. DTSBR116
|
|
00179 05 FILLER PIC X(11) VALUE SPACES. DTSBR116
|
|
00180 05 WS-NUM-DELQ-RPTS PIC ZZZ. DTSBR116
|
|
00181 05 FILLER PIC X(13) VALUE SPACES. DTSBR116
|
|
00182 05 WS-EMP-CLASS PIC X(12) VALUE SPACES. DTSBR116
|
|
00183 DTSBR116
|
|
00184 01 FOOTING-LINE-5. DTSBR116
|
|
00185 05 FILLER PIC X(50) VALUE SPACES. DTSBR116
|
|
00186 05 FOOT-NUMBER-ONE PIC ZZ,ZZ9. DTSBR116
|
|
00187 05 FILLER PIC X(01) VALUE SPACES. DTSBR116
|
|
00188 05 FILLER PIC X(09) DTSBR116
|
|
00189 VALUE 'ACCOUNTS '. DTSBR116
|
|
00190 05 WS-REPORT-FOOTING PIC X(11) VALUE SPACES. DTSBR116
|
|
00191 DTSBR116
|
|
00192 01 SUM-LINE-3. DTSBR116
|
|
00193 05 FILLER PIC X(50) VALUE SPACES. DTSBR116
|
|
00194 05 SUM-NUMBER-ONE PIC ZZ,ZZ9. DTSBR116
|
|
00195 05 FILLER PIC X(01) VALUE SPACES. DTSBR116
|
|
00196 05 FILLER PIC X(40) DTSBR116
|
|
00197 VALUE 'ACCOUNTS SET UP, REACTIVATED, OR INACTIV'. DTSBR116
|
|
00198 05 FILLER PIC X(04) DTSBR116
|
|
00199 VALUE 'ATED'. DTSBR116
|
|
00200 01 SUM-LINE-6. DTSBR116
|
|
00201 05 FILLER PIC X(25) VALUE SPACES. DTSBR116
|
|
00202 05 FILLER PIC X(17) DTSBR116
|
|
00203 VALUE '*** END OF REPORT'. DTSBR116
|
|
00204 EJECT DTSBR116
|
|
00205 LINKAGE SECTION. DTSBR116
|
|
00206 DTSBR116
|
|
00207 01 LRCM-LINK-AREA. DTSBR116
|
|
00208 ++INCLUDE DTSILRCM DTSBR116
|
|
00209 EJECT DTSBR116
|
|
00210 01 R116-REC. DTSBR116
|
|
00211 ++INCLUDE DTSIR116 DTSBR116
|
|
00212 EJECT DTSBR116
|
|
00213 EJECT DTSBR116
|
|
00214 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR116
|
|
00215 R116-REC. DTSBR116
|
|
00216 DTSBR116
|
|
00217 IF FIRST-TIME-IND = 'Y' DTSBR116
|
|
00218 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR116
|
|
00219 MOVE 'N' TO FIRST-TIME-IND. DTSBR116
|
|
00220 DTSBR116
|
|
00221 IF LRCM-EOR-88 DTSBR116
|
|
00222 PERFORM P1010-SET-FOOTING THRU P1010-EXIT DTSBR116
|
|
00223 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR116
|
|
00224 ELSE DTSBR116
|
|
00225 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR116
|
|
00226 DTSBR116
|
|
00227 GOBACK. DTSBR116
|
|
00228 EJECT DTSBR116
|
|
00229 I1000-INITIATE. DTSBR116
|
|
00230 PERFORM P1020-SET-HEADINGS THRU P1020-EXIT. DTSBR116
|
|
00231 MOVE R116-CATEGORY TO WS-CATEGORY-HOLD. DTSBR116
|
|
00232 OPEN OUTPUT PRT-FILE1. DTSBR116
|
|
00233 MOVE LRCM-SYS-DATE TO WS-SYS-DATE. DTSBR116
|
|
00234 MOVE LRCM-SYS-TIME TO WS-SYS-TIME. DTSBR116
|
|
00235 MOVE LRCM-AGY-NAME-LINE1 TO WS-AGY-NAME-LINE1. DTSBR116
|
|
00236 MOVE LRCM-AGY-NAME-LINE2 TO WS-AGY-NAME-LINE2. DTSBR116
|
|
00237 MOVE SPACES TO PRT-RECORD. DTSBR116
|
|
00238 DTSBR116
|
|
00239 I1000-EXIT. DTSBR116
|
|
00240 EXIT. DTSBR116
|
|
00241 EJECT DTSBR116
|
|
00242 P1000-PROCESS. DTSBR116
|
|
00243 DTSBR116
|
|
00244 IF R116-EMP-CLASS = 'C' DTSBR116
|
|
00245 GO TO P1000-EXIT. DTSBR116
|
|
00246 DTSBR116
|
|
00247 IF R116-CATEGORY = WS-CATEGORY-HOLD DTSBR116
|
|
00248 NEXT SENTENCE DTSBR116
|
|
00249 ELSE DTSBR116
|
|
00250 PERFORM P1010-SET-FOOTING THRU P1010-EXIT DTSBR116
|
|
00251 MOVE R116-CATEGORY TO WS-CATEGORY-HOLD DTSBR116
|
|
00252 PERFORM P3000-PRINT-FOOTER THRU P3000-EXIT DTSBR116
|
|
00253 MOVE +60 TO WS-LINE-CNT2 DTSBR116
|
|
00254 PERFORM P1020-SET-HEADINGS THRU P1020-EXIT. DTSBR116
|
|
00255 DTSBR116
|
|
00256 EVALUATE TRUE DTSBR116
|
|
00257 WHEN R116-NEW-88 DTSBR116
|
|
00258 MOVE R116-NEW-EMP-NO TO WS-EMP-NO DTSBR116
|
|
00259 MOVE R116-NEW-LIAB-DATE TO L001-FED-8-DATE-9 DTSBR116
|
|
00260 WHEN R116-REACT-88 DTSBR116
|
|
00261 MOVE R116-REACT-EMP-NO TO WS-EMP-NO DTSBR116
|
|
00262 MOVE R116-REACT-LIAB-DATE TO L001-FED-8-DATE-9 DTSBR116
|
|
00263 WHEN R116-INACT-88 DTSBR116
|
|
00264 MOVE R116-INACT-EMP-NO TO WS-EMP-NO DTSBR116
|
|
00265 MOVE R116-INACT-LIAB-DATE TO L001-FED-8-DATE-9 DTSBR116
|
|
00266 END-EVALUATE. DTSBR116
|
|
00267 SET L001-FROM-FED-8 TO TRUE. DTSBR116
|
|
00268 PERFORM S001-DATE THRU S001-EXIT. DTSBR116
|
|
00269 MOVE L001-SLASH-8-DATE TO WS-LIAB-DATE. DTSBR116
|
|
00270 DTSBR116
|
|
00271 IF R116-INACT-DATE = 999999999 DTSBR116
|
|
00272 MOVE SPACES TO WS-INACT-DATE DTSBR116
|
|
00273 ELSE DTSBR116
|
|
00274 MOVE R116-INACT-DATE TO L001-FED-8-DATE-9 DTSBR116
|
|
00275 SET L001-FROM-FED-8 TO TRUE DTSBR116
|
|
00276 PERFORM S001-DATE THRU S001-EXIT DTSBR116
|
|
00277 MOVE L001-SLASH-8-DATE TO WS-INACT-DATE. DTSBR116
|
|
00278 DTSBR116
|
|
00279 EVALUATE TRUE DTSBR116
|
|
00280 WHEN R116-CLASS-RATED-88 DTSBR116
|
|
00281 MOVE 'RATED ' TO WS-EMP-CLASS DTSBR116
|
|
00282 WHEN R116-CLASS-SELF-INS-88 DTSBR116
|
|
00283 MOVE 'SELF INSURED' TO WS-EMP-CLASS DTSBR116
|
|
00284 WHEN OTHER DTSBR116
|
|
00285 MOVE 'UNKNOWN' TO WS-EMP-CLASS DTSBR116
|
|
00286 END-EVALUATE. DTSBR116
|
|
00287 DTSBR116
|
|
00288 MOVE R116-PRIMARY-NAME TO WS-PRIMARY-NAME. DTSBR116
|
|
00289 MOVE R116-NUM-DELQ-RPTS TO WS-NUM-DELQ-RPTS. DTSBR116
|
|
00290 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR116
|
|
00291 WRITE PRT-RECORD FROM DETAIL-LINE-2 AFTER 2. DTSBR116
|
|
00292 ADD +2 TO WS-LINE-CNT2. DTSBR116
|
|
00293 ADD +1 TO WS-FOOT-NUMBER-ONE. DTSBR116
|
|
00294 ADD +1 TO WS-SUM-NUMBER-ONE. DTSBR116
|
|
00295 DTSBR116
|
|
00296 P1000-EXIT. DTSBR116
|
|
00297 EXIT. DTSBR116
|
|
00298 EJECT DTSBR116
|
|
00299 P1010-SET-FOOTING. DTSBR116
|
|
00300 DTSBR116
|
|
00301 EVALUATE TRUE DTSBR116
|
|
00302 WHEN WS-HOLD-NEW-88 DTSBR116
|
|
00303 MOVE 'SET UP ' TO WS-REPORT-FOOTING DTSBR116
|
|
00304 WHEN WS-HOLD-REACT-88 DTSBR116
|
|
00305 MOVE 'REACTIVATED' TO WS-REPORT-FOOTING DTSBR116
|
|
00306 WHEN WS-HOLD-INACT-88 DTSBR116
|
|
00307 MOVE 'INACTIVATED' TO WS-REPORT-FOOTING DTSBR116
|
|
00308 END-EVALUATE. DTSBR116
|
|
00309 DTSBR116
|
|
00310 P1010-EXIT. DTSBR116
|
|
00311 EXIT. DTSBR116
|
|
00312 DTSBR116
|
|
00313 P1020-SET-HEADINGS. DTSBR116
|
|
00314 DTSBR116
|
|
00315 MOVE WS-COLUMN-HEADING3 TO WS-COLUMN-HEADING1. DTSBR116
|
|
00316 MOVE WS-COLUMN-HEADING4 TO WS-COLUMN-HEADING2. DTSBR116
|
|
00317 EVALUATE TRUE DTSBR116
|
|
00318 WHEN R116-NEW-88 DTSBR116
|
|
00319 MOVE ' NEW ACCOUNTS ' TO WS-REPORT-TITLE DTSBR116
|
|
00320 WHEN R116-REACT-88 DTSBR116
|
|
00321 MOVE 'ACCOUNT REACTIVATIONS' TO WS-REPORT-TITLE DTSBR116
|
|
00322 WHEN R116-INACT-88 DTSBR116
|
|
00323 MOVE 'ACCOUNT INACTIVATIONS' TO WS-REPORT-TITLE DTSBR116
|
|
00324 END-EVALUATE. DTSBR116
|
|
00325 DTSBR116
|
|
00326 P1020-EXIT. DTSBR116
|
|
00327 EXIT. DTSBR116
|
|
00328 EJECT DTSBR116
|
|
00329 DTSBR116
|
|
00330 P2000-PRINT-HEADER. DTSBR116
|
|
00331 IF WS-LINE-CNT GREATER 58 OR DTSBR116
|
|
00332 WS-LINE-CNT2 GREATER 58 DTSBR116
|
|
00333 MOVE +0 TO WS-LINE-CNT DTSBR116
|
|
00334 MOVE +0 TO WS-LINE-CNT2 DTSBR116
|
|
00335 ADD +1 TO WS-PAGE-CNT DTSBR116
|
|
00336 MOVE WS-PAGE-CNT TO HDR3-PAGE-CNT DTSBR116
|
|
00337 WRITE PRT-RECORD FROM HEADER-1 AFTER TOP-OF-PAGE DTSBR116
|
|
00338 WRITE PRT-RECORD FROM HEADER-2 AFTER 1 DTSBR116
|
|
00339 WRITE PRT-RECORD FROM HEADER-3 AFTER 1 DTSBR116
|
|
00340 WRITE PRT-RECORD FROM HEADER-4 AFTER 1 DTSBR116
|
|
00341 WRITE PRT-RECORD FROM HEADER-5 AFTER 1 DTSBR116
|
|
00342 WRITE PRT-RECORD FROM HEADER-6 AFTER 1 DTSBR116
|
|
00343 WRITE PRT-RECORD FROM HEADER-7 AFTER 1 DTSBR116
|
|
00344 WRITE PRT-RECORD FROM HEADER-8 AFTER 1 DTSBR116
|
|
00345 WRITE PRT-RECORD FROM HEADER-9 AFTER 1 DTSBR116
|
|
00346 WRITE PRT-RECORD FROM HEADER-10 AFTER 1 DTSBR116
|
|
00347 ADD +10 TO WS-LINE-CNT2. DTSBR116
|
|
00348 P2000-EXIT. DTSBR116
|
|
00349 EXIT. DTSBR116
|
|
00350 DTSBR116
|
|
00351 P3000-PRINT-FOOTER. DTSBR116
|
|
00352 IF WS-LINE-CNT2 > 52 DTSBR116
|
|
00353 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR116
|
|
00354 END-IF. DTSBR116
|
|
00355 DTSBR116
|
|
00356 MOVE WS-FOOT-NUMBER-ONE TO FOOT-NUMBER-ONE. DTSBR116
|
|
00357 WRITE PRT-RECORD FROM FOOTING-LINE-5 AFTER 5. DTSBR116
|
|
00358 DTSBR116
|
|
00359 MOVE +0 TO WS-FOOT-NUMBER-ONE. DTSBR116
|
|
00360 DTSBR116
|
|
00361 P3000-EXIT. DTSBR116
|
|
00362 EXIT. DTSBR116
|
|
00363 DTSBR116
|
|
00364 T1000-TERMINATE. DTSBR116
|
|
00365 DTSBR116
|
|
00366 IF WS-LINE-CNT2 > 52 DTSBR116
|
|
00367 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR116
|
|
00368 END-IF. DTSBR116
|
|
00369 DTSBR116
|
|
00370 MOVE WS-FOOT-NUMBER-ONE TO FOOT-NUMBER-ONE. DTSBR116
|
|
00371 WRITE PRT-RECORD FROM FOOTING-LINE-5 AFTER 5. DTSBR116
|
|
00372 DTSBR116
|
|
00373 MOVE WS-SUM-NUMBER-ONE TO SUM-NUMBER-ONE. DTSBR116
|
|
00374 WRITE PRT-RECORD FROM SUM-LINE-3 AFTER 3. DTSBR116
|
|
00375 WRITE PRT-RECORD FROM SUM-LINE-6 AFTER 3. DTSBR116
|
|
00376 DTSBR116
|
|
00377 CLOSE PRT-FILE1. DTSBR116
|
|
00378 DTSBR116
|
|
00379 T1000-EXIT. DTSBR116
|
|
00380 EXIT. DTSBR116
|
|
00381 EJECT DTSBR116
|
|
00382 S001-DATE. DTSBR116
|
|
00383 DTSBR116
|
|
00384 CALL 'DTSBU001' USING L001-LINK-AREA. DTSBR116
|
|
00385 DTSBR116
|
|
00386 S001-EXIT. DTSBR116
|
|
00387 EXIT. DTSBR116
|
|
00388 DTSBR116
|
|
00389 S999-ABEND. DTSBR116
|
|
00390 DTSBR116
|
|
00391 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR116
|
|
00392 DTSBR116
|
|
00393 S999-EXIT. DTSBR116
|
|
00394 EXIT. DTSBR116
|
|
00395 DTSBR116
|