539 lines
43 KiB
COBOL
539 lines
43 KiB
COBOL
00001 IDENTIFICATION DIVISION. 01/29/01
|
|
00002 PROGRAM-ID. DTSBR906. DTSBR906
|
|
00003 AUTHOR. MT DEPT OF LABOR/UI PROGRAMMING SECTION LV009
|
|
00004 DATE-WRITTEN. OCTOBER 1994. DTSBR906
|
|
00005 DATE-COMPILED. DTSBR906
|
|
00006 DTSBR906
|
|
00007 ***** DTSBR906
|
|
00008 * DTSBR906
|
|
00009 * CALLING SEQUENCE: DTSCU221 READS DTSIR906 DTSBR906
|
|
00010 * DTSBR906
|
|
00011 * FUNCTION: ONLINE UPDATE LOG DTSBR906
|
|
00012 * DTSBR906
|
|
00013 * DTSBR906
|
|
00014 * MODIFICATION HISTORY: DTSBR906
|
|
00015 * DTSBR906
|
|
00016 * 10-31-94 INITIAL DEVELOPMENT DTSBR906
|
|
00017 * REFERENCE RFP #RAP AUTHOR OF CHANGE - SFW DTSBR906
|
|
00018 * DTSBR906
|
|
00019 * 08-30-95 CHANGED ROUTING INFORMATION TO INCLUDE TAX ACCOUNTING. DTSBR906
|
|
00020 * LYNNETTE HAS DECIDED IT NEEDS TO BE PRINTED EVERY DAY. DTSBR906
|
|
00021 * REFERENCE RFP #NONE PROGRAMMER: MJA DTSBR906
|
|
00022 * DTSBR906
|
|
00023 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR906
|
|
00024 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR906
|
|
00025 * REFERENCE RFP #**** PROGRAMMER: XXX DTSBR906
|
|
00026 * DTSBR906
|
|
00027 * DTSBR906
|
|
00028 * DESCRIPTION: DTSBR906
|
|
00029 * DTSBR906
|
|
00030 * THIS MODULE LISTS ONLINE UPDATES THAT HAVE OCCURRED DTSBR906
|
|
00031 * DTSBR906
|
|
00032 * DTSBR906
|
|
00033 * RECORDS READ: DTSBR906
|
|
00034 * DTSBR906
|
|
00035 * A SINGLE INPUT PARAMETER RECORD SPECIFYING SELECTION DTSBR906
|
|
00036 * CRITERIA ON REPORT RECORDS (OPTIONAL) DTSBR906
|
|
00037 * - IF THE PARM RECORD IS OMITTED ALL RECORDS ARE DTSBR906
|
|
00038 * SELECTED DTSBR906
|
|
00039 * - IF THE PARM START DATE OR START TIME ARE ZEROES DTSBR906
|
|
00040 * OR SPACES INPUT RECORDS ARE COMPARED TO ZEROES DTSBR906
|
|
00041 * - IF THE PARM END DATE OR END TIME ARE 9'S OR SPACES DTSBR906
|
|
00042 * INPUT RECORDS ARE COMPARED TO ALL 9'S DTSBR906
|
|
00043 * DTSBR906
|
|
00044 * DTSBR906
|
|
00045 * PRINTED OUTPUTS: DTSBR906
|
|
00046 * DTSBR906
|
|
00047 * 906R1 ONLINE UPDATE LOG DTSBR906
|
|
00048 * DTSBR906
|
|
00049 * DTSBR906
|
|
00050 * RECORDS WRITTEN: DTSBR906
|
|
00051 * DTSBR906
|
|
00052 * NONE. DTSBR906
|
|
00053 * DTSBR906
|
|
00054 * DTSBR906
|
|
00055 * MODULES CALLED: DTSBR906
|
|
00056 * DTSBR906
|
|
00057 * DTSBU001 DATE EDIT/CONVERSION MODULE DTSBR906
|
|
00058 * DTSBU010 TIME VALIDATE/FORMAT MODULE DTSBR906
|
|
00059 * DTSBR906
|
|
00060 * DTSBR906
|
|
00061 ***** DTSBR906
|
|
00062 EJECT DTSBR906
|
|
00063 ENVIRONMENT DIVISION. DTSBR906
|
|
00064 DTSBR906
|
|
00065 CONFIGURATION SECTION. DTSBR906
|
|
00066 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. DTSBR906
|
|
00067 DTSBR906
|
|
00068 INPUT-OUTPUT SECTION. DTSBR906
|
|
00069 DTSBR906
|
|
00070 FILE-CONTROL. DTSBR906
|
|
00071 SELECT PARM-FILE ASSIGN TO PARM906. DTSBR906
|
|
00072 SELECT PRT-FILE ASSIGN TO RPT906R1. DTSBR906
|
|
00073 DTSBR906
|
|
00074 DATA DIVISION. DTSBR906
|
|
00075 DTSBR906
|
|
00076 FILE SECTION. DTSBR906
|
|
00077 DTSBR906
|
|
00078 FD PARM-FILE DTSBR906
|
|
00079 RECORDING MODE IS F DTSBR906
|
|
00080 BLOCK CONTAINS 0 RECORDS. DTSBR906
|
|
00081 01 PARM-REC. DTSBR906
|
|
00082 05 PARM-MOD-NAME PIC X(08). DTSBR906
|
|
00083 05 FILLER PIC X(01). DTSBR906
|
|
00084 05 PARM-START-MMDDYY PIC X(06). DTSBR906
|
|
00085 05 PARM-START-MMDDYY-9 REDEFINES PARM-START-MMDDYY DTSBR906
|
|
00086 PIC 9(06). DTSBR906
|
|
00087 05 FILLER PIC X(01). DTSBR906
|
|
00088 05 PARM-START-HHMMSS PIC X(06). DTSBR906
|
|
00089 05 PARM-START-HHMMSS-9 REDEFINES PARM-START-HHMMSS DTSBR906
|
|
00090 PIC 9(06). DTSBR906
|
|
00091 05 FILLER PIC X(01). DTSBR906
|
|
00092 05 PARM-END-MMDDYY PIC X(06). DTSBR906
|
|
00093 05 PARM-END-MMDDYY-9 REDEFINES PARM-END-MMDDYY DTSBR906
|
|
00094 PIC 9(06). DTSBR906
|
|
00095 05 FILLER PIC X(01). DTSBR906
|
|
00096 05 PARM-END-HHMMSS PIC X(06). DTSBR906
|
|
00097 05 PARM-END-HHMMSS-9 REDEFINES PARM-END-HHMMSS DTSBR906
|
|
00098 PIC 9(06). DTSBR906
|
|
00099 05 FILLER PIC X(44). DTSBR906
|
|
00100 DTSBR906
|
|
00101 FD PRT-FILE DTSBR906
|
|
00102 RECORDING MODE IS F. DTSBR906
|
|
00103 01 REPORT-LISTING1 PIC X(133). DTSBR906
|
|
00104 DTSBR906
|
|
00105 WORKING-STORAGE SECTION. DTSBR906
|
|
001055 77 PAN-VALET PICTURE X(24) VALUE '009DTSBR906 01/29/01'. DTSBR906
|
|
00106 DTSBR906
|
|
00107 01 WRK-AREA. DTSBR906
|
|
00108 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +906.DTSBR906
|
|
00109 05 WRK-ABEND-MSG PIC X(50) VALUE SPACES. DTSBR906
|
|
00110 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR906
|
|
00111 DTSBR906
|
|
00112 05 WS-LINE-CNT PIC S9(02) COMP-3 VALUE 60. DTSBR906
|
|
00113 05 WS-LINE-CNT2 PIC S9(02) COMP-3 VALUE +0. DTSBR906
|
|
00114 05 WS-PAGE-CNT PIC S9(03) COMP-3 VALUE +0. DTSBR906
|
|
00115 DTSBR906
|
|
00116 05 WS-NUMBER-ONE PIC S9(03) COMP-3 VALUE +0. DTSBR906
|
|
00117 05 WRK-OP-ID PIC X(08) VALUE SPACE. DTSBR906
|
|
00118 DTSBR906
|
|
00119 05 WS-ZEROES-DATE PIC S9(09) COMP-3 DTSBR906
|
|
00120 VALUE +000000000.DTSBR906
|
|
00121 05 WS-NINES-DATE PIC S9(09) COMP-3 DTSBR906
|
|
00122 VALUE +999999999.DTSBR906
|
|
00123 05 WS-ZEROES-TIME PIC S9(07) COMP-3 DTSBR906
|
|
00124 VALUE +0000000. DTSBR906
|
|
00125 05 WS-NINES-TIME PIC S9(07) COMP-3 DTSBR906
|
|
00126 VALUE +9999999. DTSBR906
|
|
00127 05 WS-START-DATE PIC S9(09) COMP-3 VALUE +0. DTSBR906
|
|
00128 05 WS-START-TIME PIC S9(07) COMP-3 VALUE +0. DTSBR906
|
|
00129 05 WS-END-DATE PIC S9(09) COMP-3 VALUE +0. DTSBR906
|
|
00130 05 WS-END-TIME PIC S9(07) COMP-3 VALUE +0. DTSBR906
|
|
00131 DTSBR906
|
|
00132 05 WS-START-DATE-DISPLAY-I. DTSBR906
|
|
00133 10 FILLER PIC X(12) DTSBR906
|
|
00134 VALUE 'START DATE: '. DTSBR906
|
|
00135 10 WS-START-DATE-SLASH PIC X(08). DTSBR906
|
|
00136 05 WS-START-DATE-DISPLAY DTSBR906
|
|
00137 REDEFINES WS-START-DATE-DISPLAY-I DTSBR906
|
|
00138 PIC X(20). DTSBR906
|
|
00139 05 WS-END-DATE-DISPLAY-I. DTSBR906
|
|
00140 10 FILLER PIC X(14) DTSBR906
|
|
00141 VALUE ' END DATE: '. DTSBR906
|
|
00142 10 WS-END-DATE-SLASH PIC X(08). DTSBR906
|
|
00143 05 WS-END-DATE-DISPLAY DTSBR906
|
|
00144 REDEFINES WS-END-DATE-DISPLAY-I DTSBR906
|
|
00145 PIC X(22). DTSBR906
|
|
00146 DTSBR906
|
|
00147 05 WS-START-TIME-DISPLAY-I. DTSBR906
|
|
00148 10 FILLER PIC X(12) DTSBR906
|
|
00149 VALUE 'START TIME: '. DTSBR906
|
|
00150 10 WS-START-TIME-DOTS PIC X(08). DTSBR906
|
|
00151 05 WS-START-TIME-DISPLAY DTSBR906
|
|
00152 REDEFINES WS-START-TIME-DISPLAY-I DTSBR906
|
|
00153 PIC X(20). DTSBR906
|
|
00154 05 WS-END-TIME-DISPLAY-I. DTSBR906
|
|
00155 10 FILLER PIC X(14) DTSBR906
|
|
00156 VALUE ' END TIME: '. DTSBR906
|
|
00157 10 WS-END-TIME-DOTS PIC X(08). DTSBR906
|
|
00158 05 WS-END-TIME-DISPLAY DTSBR906
|
|
00159 REDEFINES WS-END-TIME-DISPLAY-I DTSBR906
|
|
00160 PIC X(22). DTSBR906
|
|
00161 DTSBR906
|
|
00162 01 L001-LINK-AREA. DTSBR906
|
|
00163 ++INCLUDE DTSIL001 DTSBR906
|
|
00164 EJECT DTSBR906
|
|
00165 01 L010-LINK-AREA. DTSBR906
|
|
00166 ++INCLUDE DTSIL010 DTSBR906
|
|
00167 EJECT DTSBR906
|
|
00168 DTSBR906
|
|
00169 01 PAGE-HEADING. DTSBR906
|
|
00170 05 HDR1-LINE-1. DTSBR906
|
|
00171 10 FILLER PIC X(01) VALUE SPACE. DTSBR906
|
|
00172 10 FILLER PIC X(05) DTSBR906
|
|
00173 VALUE '906R1'. DTSBR906
|
|
00174 10 FILLER PIC X(34) VALUE SPACES. DTSBR906
|
|
00175 10 HDR1-AGY-NAME-LINE1 PIC X(50). DTSBR906
|
|
00176 10 FILLER PIC X(28) VALUE SPACES. DTSBR906
|
|
00177 10 FILLER PIC X(05) DTSBR906
|
|
00178 VALUE 'DATE:'. DTSBR906
|
|
00179 10 FILLER PIC X(01) VALUE SPACE. DTSBR906
|
|
00180 10 HDR1-SYS-DATE PIC X(08). DTSBR906
|
|
00181 05 HDR1-LINE-2. DTSBR906
|
|
00182 10 FILLER PIC X(40) VALUE SPACES. DTSBR906
|
|
00183 10 HDR1-AGY-NAME-LINE2 PIC X(50). DTSBR906
|
|
00184 10 FILLER PIC X(28) VALUE SPACES. DTSBR906
|
|
00185 10 FILLER PIC X(05) DTSBR906
|
|
00186 VALUE 'TIME:'. DTSBR906
|
|
00187 10 FILLER PIC X(01) VALUE SPACE. DTSBR906
|
|
00188 10 HDR1-SYS-TIME PIC X(08). DTSBR906
|
|
00189 05 HDR1-LINE-3. DTSBR906
|
|
00190 10 FILLER PIC X(01) VALUE SPACE. DTSBR906
|
|
00191 10 FILLER PIC X(39) DTSBR906
|
|
00192 VALUE 'ROUTE TO: CHIEF, TAX DIVISION '. DTSBR906
|
|
00193 10 FILLER PIC X(78) VALUE SPACES. DTSBR906
|
|
00194 10 FILLER PIC X(05) DTSBR906
|
|
00195 VALUE 'PAGE:'. DTSBR906
|
|
00196 10 FILLER PIC X(03) VALUE SPACES. DTSBR906
|
|
00197 10 HDR1-PAGE-CNT PIC ZZ,ZZ9. DTSBR906
|
|
00198 05 HDR1-LINE-4. DTSBR906
|
|
00199 10 FILLER PIC X(11) VALUE SPACES. DTSBR906
|
|
00200 10 FILLER PIC X(20) DTSBR906
|
|
00201 VALUE 'ACCOUNTING PERSONNEL'. DTSBR906
|
|
00202 05 HDR1-LINE-5. DTSBR906
|
|
00203 10 FILLER PIC X(01) VALUE SPACE. DTSBR906
|
|
00204 10 HDR1-START-DATE-DISPLAY PIC X(20). DTSBR906
|
|
00205 10 HDR1-END-DATE-DISPLAY PIC X(22). DTSBR906
|
|
00206 10 FILLER PIC X(14) VALUE SPACE. DTSBR906
|
|
00207 10 FILLER PIC X(17) DTSBR906
|
|
00208 VALUE 'ONLINE UPDATE LOG'. DTSBR906
|
|
00209 05 HDR1-LINE-6. DTSBR906
|
|
00210 10 FILLER PIC X(01) VALUE SPACE. DTSBR906
|
|
00211 10 HDR1-START-TIME-DISPLAY PIC X(20). DTSBR906
|
|
00212 10 HDR1-END-TIME-DISPLAY PIC X(22). DTSBR906
|
|
00213 05 HDR1-LINE-7 PIC X(133) VALUE SPACES. DTSBR906
|
|
00214 05 HDR1-LINE-8. DTSBR906
|
|
00215 10 FILLER PIC X(06) VALUE SPACES. DTSBR906
|
|
00216 10 FILLER PIC X(06) DTSBR906
|
|
00217 VALUE 'OPID: '. DTSBR906
|
|
00218 10 FILLER PIC X(06) VALUE SPACES. DTSBR906
|
|
00219 10 HDR1-OP-ID PIC X(08). DTSBR906
|
|
00220 05 HDR1-LINE-9 PIC X(133) VALUE SPACES. DTSBR906
|
|
00221 05 HDR1-LINE-10 PIC X(133) VALUE SPACES. DTSBR906
|
|
00222 05 HDR1-LINE-11. DTSBR906
|
|
00223 10 FILLER PIC X(06) VALUE SPACES. DTSBR906
|
|
00224 10 FILLER PIC X(40) DTSBR906
|
|
00225 VALUE 'EMP NO DATE TIME '. DTSBR906
|
|
00226 10 FILLER PIC X(40) DTSBR906
|
|
00227 VALUE ' TASK ID TERM ID SCR ID FUNC'. DTSBR906
|
|
00228 10 FILLER PIC X(04) DTSBR906
|
|
00229 VALUE 'TION'. DTSBR906
|
|
00230 DTSBR906
|
|
00231 01 DETAIL-LINE. DTSBR906
|
|
00232 05 DTL1-LINE-2. DTSBR906
|
|
00233 10 FILLER PIC X(06) VALUE SPACES. DTSBR906
|
|
00234 10 DTL1-EMP-NO PIC 999B999. DTSBR906
|
|
00235 10 FILLER PIC X(06) VALUE SPACES. DTSBR906
|
|
00236 10 WS-TASK-START-DATE-SLASH PIC X(10). DTSBR906
|
|
00237 10 FILLER PIC X(05) VALUE SPACES. DTSBR906
|
|
00238 10 WS-TASK-START-TIME-DOTS PIC X(08). DTSBR906
|
|
00239 10 FILLER PIC X(04) VALUE SPACES. DTSBR906
|
|
00240 10 DTL1-TASK-ID PIC Z(07)9. DTSBR906
|
|
00241 10 FILLER PIC X(07) VALUE SPACES. DTSBR906
|
|
00242 10 DTL1-TERM-ID PIC X(04). DTSBR906
|
|
00243 10 FILLER PIC X(08) VALUE SPACES. DTSBR906
|
|
00244 10 DTL1-SCR-ID PIC X(02). DTSBR906
|
|
00245 10 FILLER PIC X(10) VALUE SPACES. DTSBR906
|
|
00246 10 DTL1-FUNCTION PIC X(01). DTSBR906
|
|
00247 DTSBR906
|
|
00248 01 CONTROL-FOOTING. DTSBR906
|
|
00249 05 CTF-LINE-3. DTSBR906
|
|
00250 10 FILLER PIC X(25) VALUE SPACES. DTSBR906
|
|
00251 10 FILLER PIC X(19) DTSBR906
|
|
00252 VALUE '*** END OF OPERATOR'. DTSBR906
|
|
00253 DTSBR906
|
|
00254 01 CONTROL-FOOTING-FINAL. DTSBR906
|
|
00255 05 CFF-LINE-3. DTSBR906
|
|
00256 10 FILLER PIC X(25) VALUE SPACES. DTSBR906
|
|
00257 10 FILLER PIC X(17) DTSBR906
|
|
00258 VALUE '*** END OF REPORT'. DTSBR906
|
|
00259 EJECT DTSBR906
|
|
00260 LINKAGE SECTION. DTSBR906
|
|
00261 DTSBR906
|
|
00262 01 LRCM-LINK-AREA. DTSBR906
|
|
00263 ++INCLUDE DTSILRCM DTSBR906
|
|
00264 EJECT DTSBR906
|
|
00265 01 R906-REC. DTSBR906
|
|
00266 ++INCLUDE DTSIR906 DTSBR906
|
|
00267 EJECT DTSBR906
|
|
00268 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR906
|
|
00269 R906-REC. DTSBR906
|
|
00270 DTSBR906
|
|
00271 IF FIRST-TIME-IND = 'Y' DTSBR906
|
|
00272 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR906
|
|
00273 MOVE 'N' TO FIRST-TIME-IND. DTSBR906
|
|
00274 DTSBR906
|
|
00275 IF LRCM-EOR-88 DTSBR906
|
|
00276 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR906
|
|
00277 ELSE DTSBR906
|
|
00278 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR906
|
|
00279 DTSBR906
|
|
00280 GOBACK. DTSBR906
|
|
00281 EJECT DTSBR906
|
|
00282 I1000-INITIATE. DTSBR906
|
|
00283 DTSBR906
|
|
00284 OPEN INPUT PARM-FILE DTSBR906
|
|
00285 OUTPUT PRT-FILE. DTSBR906
|
|
00286 DTSBR906
|
|
00287 MOVE LRCM-SYS-DATE TO HDR1-SYS-DATE. DTSBR906
|
|
00288 MOVE LRCM-SYS-TIME TO HDR1-SYS-TIME. DTSBR906
|
|
00289 MOVE LRCM-AGY-NAME-LINE1 TO HDR1-AGY-NAME-LINE1. DTSBR906
|
|
00290 MOVE LRCM-AGY-NAME-LINE2 TO HDR1-AGY-NAME-LINE2. DTSBR906
|
|
00291 MOVE SPACES TO REPORT-LISTING1. DTSBR906
|
|
00292 DTSBR906
|
|
00293 READ PARM-FILE DTSBR906
|
|
00294 AT END DTSBR906
|
|
00295 MOVE WS-ZEROES-DATE TO WS-START-DATE DTSBR906
|
|
00296 MOVE WS-NINES-DATE TO WS-END-DATE DTSBR906
|
|
00297 MOVE WS-ZEROES-TIME TO WS-START-TIME DTSBR906
|
|
00298 MOVE WS-NINES-TIME TO WS-END-TIME DTSBR906
|
|
00299 MOVE SPACES TO WS-START-DATE-DISPLAY DTSBR906
|
|
00300 HDR1-START-DATE-DISPLAY DTSBR906
|
|
00301 WS-START-TIME-DISPLAY DTSBR906
|
|
00302 HDR1-START-TIME-DISPLAY DTSBR906
|
|
00303 WS-END-DATE-DISPLAY DTSBR906
|
|
00304 HDR1-END-DATE-DISPLAY DTSBR906
|
|
00305 WS-END-TIME-DISPLAY DTSBR906
|
|
00306 HDR1-END-TIME-DISPLAY DTSBR906
|
|
00307 GO TO I1000-EXIT. DTSBR906
|
|
00308 DTSBR906
|
|
00309 PERFORM I2000-EDIT-PARM THRU I2000-EXIT. DTSBR906
|
|
00310 DTSBR906
|
|
00311 I1000-EXIT. DTSBR906
|
|
00312 EXIT. DTSBR906
|
|
00313 EJECT DTSBR906
|
|
00314 I2000-EDIT-PARM. DTSBR906
|
|
00315 DTSBR906
|
|
00316 IF PARM-MOD-NAME NOT = 'DTSBR906' DTSBR906
|
|
00317 MOVE 'INVALID PARM MODULE NAME' DTSBR906
|
|
00318 TO WRK-ABEND-MSG DTSBR906
|
|
00319 PERFORM S999-ABEND THRU S999-EXIT. DTSBR906
|
|
00320 IF PARM-START-MMDDYY = SPACES DTSBR906
|
|
00321 MOVE WS-ZEROES-DATE TO WS-START-DATE DTSBR906
|
|
00322 MOVE SPACES TO WS-START-DATE-DISPLAY DTSBR906
|
|
00323 HDR1-START-DATE-DISPLAY DTSBR906
|
|
00324 ELSE DTSBR906
|
|
00325 IF PARM-START-MMDDYY NUMERIC DTSBR906
|
|
00326 IF PARM-START-MMDDYY = '000000' DTSBR906
|
|
00327 MOVE WS-ZEROES-DATE TO WS-START-DATE DTSBR906
|
|
00328 MOVE SPACES TO WS-START-DATE-DISPLAY DTSBR906
|
|
00329 HDR1-START-DATE-DISPLAY DTSBR906
|
|
00330 ELSE DTSBR906
|
|
00331 MOVE PARM-START-MMDDYY-9 TO L001-CAL-6-DATE-9 DTSBR906
|
|
00332 SET L001-FROM-CAL-6 TO TRUE DTSBR906
|
|
00333 PERFORM S001-DATE THRU S001-EXIT DTSBR906
|
|
00334 IF L001-INVALID-DATE DTSBR906
|
|
00335 MOVE 'INVALID PARM DATE(S)' DTSBR906
|
|
00336 TO WRK-ABEND-MSG DTSBR906
|
|
00337 PERFORM S999-ABEND THRU S999-EXIT DTSBR906
|
|
00338 END-IF DTSBR906
|
|
00339 MOVE L001-SLASH-DATE TO WS-START-DATE-SLASH DTSBR906
|
|
00340 MOVE WS-START-DATE-DISPLAY-I TO HDR1-START-DATE-DISPLAY DTSBR906
|
|
00341 MOVE L001-FED-8-DATE-9 TO WS-START-DATE DTSBR906
|
|
00342 ELSE DTSBR906
|
|
00343 MOVE 'INVALID PARM DATE(S)' DTSBR906
|
|
00344 TO WRK-ABEND-MSG DTSBR906
|
|
00345 PERFORM S999-ABEND THRU S999-EXIT. DTSBR906
|
|
00346 IF PARM-END-MMDDYY = SPACES DTSBR906
|
|
00347 MOVE WS-NINES-DATE TO WS-END-DATE DTSBR906
|
|
00348 MOVE SPACES TO WS-END-DATE-DISPLAY HDR1-END-DATE-DISPLAY DTSBR906
|
|
00349 ELSE DTSBR906
|
|
00350 IF PARM-END-MMDDYY NUMERIC DTSBR906
|
|
00351 IF PARM-END-MMDDYY = '999999' DTSBR906
|
|
00352 MOVE WS-NINES-DATE TO WS-END-DATE DTSBR906
|
|
00353 MOVE SPACES TO WS-END-DATE-DISPLAY HDR1-END-DATE-DISPLAY DTSBR906
|
|
00354 ELSE DTSBR906
|
|
00355 MOVE PARM-END-MMDDYY-9 TO L001-CAL-6-DATE-9 DTSBR906
|
|
00356 SET L001-FROM-CAL-6 TO TRUE DTSBR906
|
|
00357 PERFORM S001-DATE THRU S001-EXIT DTSBR906
|
|
00358 IF L001-INVALID-DATE DTSBR906
|
|
00359 MOVE 'INVALID PARM DATE(S)' DTSBR906
|
|
00360 TO WRK-ABEND-MSG DTSBR906
|
|
00361 PERFORM S999-ABEND THRU S999-EXIT DTSBR906
|
|
00362 END-IF DTSBR906
|
|
00363 MOVE L001-SLASH-DATE TO WS-END-DATE-SLASH DTSBR906
|
|
00364 MOVE WS-END-DATE-DISPLAY-I TO HDR1-END-DATE-DISPLAY DTSBR906
|
|
00365 MOVE L001-FED-8-DATE-9 TO WS-END-DATE DTSBR906
|
|
00366 ELSE DTSBR906
|
|
00367 MOVE 'INVALID PARM DATE(S)' DTSBR906
|
|
00368 TO WRK-ABEND-MSG DTSBR906
|
|
00369 PERFORM S999-ABEND THRU S999-EXIT. DTSBR906
|
|
00370 IF PARM-START-HHMMSS = SPACES DTSBR906
|
|
00371 MOVE WS-ZEROES-TIME TO WS-START-TIME DTSBR906
|
|
00372 MOVE SPACES TO WS-START-TIME-DISPLAY DTSBR906
|
|
00373 HDR1-START-TIME-DISPLAY DTSBR906
|
|
00374 ELSE DTSBR906
|
|
00375 IF PARM-START-HHMMSS NUMERIC DTSBR906
|
|
00376 IF PARM-START-HHMMSS = '000000' DTSBR906
|
|
00377 MOVE WS-ZEROES-TIME TO WS-START-TIME DTSBR906
|
|
00378 MOVE SPACES TO WS-START-TIME-DISPLAY DTSBR906
|
|
00379 HDR1-START-TIME-DISPLAY DTSBR906
|
|
00380 ELSE DTSBR906
|
|
00381 MOVE PARM-START-HHMMSS TO L010-TIME DTSBR906
|
|
00382 PERFORM S010-TIME THRU S010-EXIT DTSBR906
|
|
00383 IF L010-INVALID-TIME DTSBR906
|
|
00384 MOVE 'INVALID PARM TIME(S)' DTSBR906
|
|
00385 TO WRK-ABEND-MSG DTSBR906
|
|
00386 PERFORM S999-ABEND THRU S999-EXIT DTSBR906
|
|
00387 END-IF DTSBR906
|
|
00388 MOVE L010-DOTS-TIME TO WS-START-TIME-DOTS DTSBR906
|
|
00389 MOVE WS-START-TIME-DISPLAY-I TO HDR1-START-TIME-DISPLAY DTSBR906
|
|
00390 MOVE L010-TIME TO WS-START-TIME DTSBR906
|
|
00391 ELSE DTSBR906
|
|
00392 MOVE 'INVALID PARM TIME(S)' DTSBR906
|
|
00393 TO WRK-ABEND-MSG DTSBR906
|
|
00394 PERFORM S999-ABEND THRU S999-EXIT. DTSBR906
|
|
00395 IF PARM-END-HHMMSS = SPACES DTSBR906
|
|
00396 MOVE WS-NINES-TIME TO WS-END-TIME DTSBR906
|
|
00397 MOVE SPACES TO WS-END-TIME-DISPLAY DTSBR906
|
|
00398 HDR1-END-TIME-DISPLAY DTSBR906
|
|
00399 ELSE DTSBR906
|
|
00400 IF PARM-END-HHMMSS NUMERIC DTSBR906
|
|
00401 IF PARM-END-HHMMSS = '000000' DTSBR906
|
|
00402 MOVE WS-NINES-TIME TO WS-END-TIME DTSBR906
|
|
00403 MOVE SPACES TO WS-END-TIME-DISPLAY DTSBR906
|
|
00404 HDR1-END-TIME-DISPLAY DTSBR906
|
|
00405 ELSE DTSBR906
|
|
00406 MOVE PARM-END-HHMMSS TO L010-TIME DTSBR906
|
|
00407 PERFORM S010-TIME THRU S010-EXIT DTSBR906
|
|
00408 IF L010-INVALID-TIME DTSBR906
|
|
00409 MOVE 'INVALID PARM TIME(S)' DTSBR906
|
|
00410 TO WRK-ABEND-MSG DTSBR906
|
|
00411 PERFORM S999-ABEND THRU S999-EXIT DTSBR906
|
|
00412 END-IF DTSBR906
|
|
00413 MOVE L010-DOTS-TIME TO WS-END-TIME-DOTS DTSBR906
|
|
00414 MOVE WS-END-TIME-DISPLAY-I TO HDR1-END-TIME-DISPLAY DTSBR906
|
|
00415 MOVE L010-TIME TO WS-END-TIME DTSBR906
|
|
00416 ELSE DTSBR906
|
|
00417 MOVE 'INVALID PARM TIME(S)' DTSBR906
|
|
00418 TO WRK-ABEND-MSG DTSBR906
|
|
00419 PERFORM S999-ABEND THRU S999-EXIT. DTSBR906
|
|
00420 DTSBR906
|
|
00421 I2000-EXIT. DTSBR906
|
|
00422 EXIT. DTSBR906
|
|
00423 EJECT DTSBR906
|
|
00424 P1000-PROCESS. DTSBR906
|
|
00425 DTSBR906
|
|
00426 IF (R906-TASK-START-DATE < WS-START-DATE) DTSBR906
|
|
00427 OR DTSBR906
|
|
00428 ((R906-TASK-START-DATE = WS-START-DATE) DTSBR906
|
|
00429 AND DTSBR906
|
|
00430 (R906-TASK-START-TIME < WS-START-TIME)) DTSBR906
|
|
00431 OR DTSBR906
|
|
00432 (R906-TASK-START-DATE > WS-END-DATE) DTSBR906
|
|
00433 OR DTSBR906
|
|
00434 ((R906-TASK-START-DATE = WS-END-DATE) DTSBR906
|
|
00435 AND DTSBR906
|
|
00436 (R906-TASK-START-TIME > WS-END-TIME)) DTSBR906
|
|
00437 GO TO P1000-EXIT. DTSBR906
|
|
00438 DTSBR906
|
|
00439 MOVE R906-TASK-START-DATE TO L001-FED-8-DATE-9. DTSBR906
|
|
00440 SET L001-FROM-FED-8 TO TRUE. DTSBR906
|
|
00441 PERFORM S001-DATE THRU S001-EXIT. DTSBR906
|
|
00442 MOVE L001-SLASH-8-DATE TO WS-TASK-START-DATE-SLASH. DTSBR906
|
|
00443 DTSBR906
|
|
00444 MOVE R906-TASK-START-TIME TO L010-TIME. DTSBR906
|
|
00445 PERFORM S010-TIME THRU S010-EXIT. DTSBR906
|
|
00446 MOVE L010-DOTS-TIME TO WS-TASK-START-TIME-DOTS. DTSBR906
|
|
00447 DTSBR906
|
|
00448 IF R906-OP-ID NOT = WRK-OP-ID DTSBR906
|
|
00449 MOVE R906-OP-ID TO WRK-OP-ID DTSBR906
|
|
00450 HDR1-OP-ID DTSBR906
|
|
00451 IF WS-NUMBER-ONE = +0 DTSBR906
|
|
00452 MOVE +99 TO WS-NUMBER-ONE DTSBR906
|
|
00453 ELSE DTSBR906
|
|
00454 PERFORM P3000-PRINT-FOOTER THRU P3000-EXIT DTSBR906
|
|
00455 MOVE +60 TO WS-LINE-CNT2 DTSBR906
|
|
00456 END-IF DTSBR906
|
|
00457 END-IF. DTSBR906
|
|
00458 DTSBR906
|
|
00459 MOVE R906-EMP-NO TO DTL1-EMP-NO. DTSBR906
|
|
00460 MOVE R906-TASK-ID TO DTL1-TASK-ID. DTSBR906
|
|
00461 MOVE R906-TERM-ID TO DTL1-TERM-ID. DTSBR906
|
|
00462 MOVE R906-SCR-ID TO DTL1-SCR-ID. DTSBR906
|
|
00463 MOVE R906-FUNCTION TO DTL1-FUNCTION. DTSBR906
|
|
00464 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR906
|
|
00465 WRITE REPORT-LISTING1 FROM DTL1-LINE-2 AFTER 2. DTSBR906
|
|
00466 ADD +2 TO WS-LINE-CNT2. DTSBR906
|
|
00467 DTSBR906
|
|
00468 DTSBR906
|
|
00469 P1000-EXIT. DTSBR906
|
|
00470 EXIT. DTSBR906
|
|
00471 DTSBR906
|
|
00472 P2000-PRINT-HEADER. DTSBR906
|
|
00473 DTSBR906
|
|
00474 IF WS-LINE-CNT GREATER 58 OR DTSBR906
|
|
00475 WS-LINE-CNT2 GREATER 58 DTSBR906
|
|
00476 MOVE +0 TO WS-LINE-CNT DTSBR906
|
|
00477 MOVE +0 TO WS-LINE-CNT2 DTSBR906
|
|
00478 ADD +1 TO WS-PAGE-CNT DTSBR906
|
|
00479 MOVE WS-PAGE-CNT TO HDR1-PAGE-CNT DTSBR906
|
|
00480 WRITE REPORT-LISTING1 FROM HDR1-LINE-1 DTSBR906
|
|
00481 AFTER TOP-OF-PAGE DTSBR906
|
|
00482 WRITE REPORT-LISTING1 FROM HDR1-LINE-2 AFTER 1 DTSBR906
|
|
00483 WRITE REPORT-LISTING1 FROM HDR1-LINE-3 AFTER 1 DTSBR906
|
|
00484 WRITE REPORT-LISTING1 FROM HDR1-LINE-4 AFTER 1 DTSBR906
|
|
00485 WRITE REPORT-LISTING1 FROM HDR1-LINE-5 AFTER 1 DTSBR906
|
|
00486 WRITE REPORT-LISTING1 FROM HDR1-LINE-6 AFTER 1 DTSBR906
|
|
00487 WRITE REPORT-LISTING1 FROM HDR1-LINE-7 AFTER 1 DTSBR906
|
|
00488 WRITE REPORT-LISTING1 FROM HDR1-LINE-8 AFTER 1 DTSBR906
|
|
00489 WRITE REPORT-LISTING1 FROM HDR1-LINE-9 AFTER 1 DTSBR906
|
|
00490 WRITE REPORT-LISTING1 FROM HDR1-LINE-10 AFTER 1 DTSBR906
|
|
00491 WRITE REPORT-LISTING1 FROM HDR1-LINE-11 AFTER 1 DTSBR906
|
|
00492 ADD +11 TO WS-LINE-CNT2. DTSBR906
|
|
00493 DTSBR906
|
|
00494 P2000-EXIT. DTSBR906
|
|
00495 EXIT. DTSBR906
|
|
00496 DTSBR906
|
|
00497 P3000-PRINT-FOOTER. DTSBR906
|
|
00498 IF WS-LINE-CNT2 > 52 DTSBR906
|
|
00499 ADD +8 TO WS-LINE-CNT2 DTSBR906
|
|
00500 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR906
|
|
00501 END-IF. DTSBR906
|
|
00502 DTSBR906
|
|
00503 WRITE REPORT-LISTING1 FROM CTF-LINE-3 AFTER 3. DTSBR906
|
|
00504 DTSBR906
|
|
00505 P3000-EXIT. DTSBR906
|
|
00506 EXIT. DTSBR906
|
|
00507 DTSBR906
|
|
00508 T1000-TERMINATE. DTSBR906
|
|
00509 DTSBR906
|
|
00510 PERFORM P3000-PRINT-FOOTER THRU P3000-EXIT. DTSBR906
|
|
00511 WRITE REPORT-LISTING1 FROM CFF-LINE-3 AFTER 3. DTSBR906
|
|
00512 CLOSE PARM-FILE PRT-FILE. DTSBR906
|
|
00513 DTSBR906
|
|
00514 T1000-EXIT. DTSBR906
|
|
00515 EXIT. DTSBR906
|
|
00516 EJECT DTSBR906
|
|
00517 S001-DATE. DTSBR906
|
|
00518 DTSBR906
|
|
00519 CALL 'DTSBU001' USING L001-LINK-AREA. DTSBR906
|
|
00520 DTSBR906
|
|
00521 S001-EXIT. DTSBR906
|
|
00522 EXIT. DTSBR906
|
|
00523 DTSBR906
|
|
00524 S010-TIME. DTSBR906
|
|
00525 DTSBR906
|
|
00526 CALL 'DTSBU010' USING L010-LINK-AREA. DTSBR906
|
|
00527 DTSBR906
|
|
00528 S010-EXIT. DTSBR906
|
|
00529 EXIT. DTSBR906
|
|
00530 DTSBR906
|
|
00531 S999-ABEND. DTSBR906
|
|
00532 SKIP1 DTSBR906
|
|
00533 DISPLAY '*** DTSBR906 ABENDING - ' WRK-ABEND-MSG. DTSBR906
|
|
00534 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR906
|
|
00535 SKIP2 DTSBR906
|
|
00536 S999-EXIT. DTSBR906
|
|
00537 EXIT. DTSBR906
|