giteaadmin/DUTAS
4
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
2a54f65e13ffdac7ccbe8ea99bd8eb7cbb392cec
DUTAS/Batch/SAMPS042.cob
Neeraj Kumar ca3572c5df DUTAS re-platformed to Raincode - Initial Source Code
2025-07-21 11:20:11 -04:00

1072 lines
85 KiB
COBOL
Raw Blame History

00001 IDENTIFICATION DIVISION. 02/12/04
00002 PROGRAM-ID. SAMPS042. SAMPS042
00003 AUTHOR. JOHN VIENNAS. LV001
00004 DATE-WRITTEN. FEBRUARY 12, 1993. SAMPS042
00005 SAMPS042
00006 *************************************************************** SAMPS042
00007 ** --------------------PROGRAM DESCRIPTION------------------ ** SAMPS042
00008 *************************************************************** SAMPS042
00009 ** CODING FOR VS COBOL VSAM ** SAMPS042
00010 *************************************************************** SAMPS042
00011 ** ** SAMPS042
00012 ** ** SAMPS042
00013 ** THIS PROGRAM READS THREE FILES AS INPUT TO THE PROGRAM, ** SAMPS042
00014 ** TRANS-FILE, CNTRL-DATA, AND SELECT-FILE. THE TRANS-FILE ** SAMPS042
00015 ** UTILIZES A VSAM FILE STRUCTURE WITH (SEQ-NMBR) AS THE ** SAMPS042
00016 ** RECORD KEY. THE CNTRL-DATA FILE CONTAINS SOME PROCESSING ** SAMPS042
00017 ** INFORMATION WHICH IS USED IN THE OUTPUT REPORTS ** SAMPS042
00018 ** HIT-FILE, HIT-LIST, AND CHECK-LIST. THE SELECT-FILE ** SAMPS042
00019 ** CONTAINS THE RECORD NUMBERS OF THE RECORDS TO BE SELECTED ** SAMPS042
00020 ** FOR THE SAMPLE. THESE NUMBERS ARE USED AS THE RECORD ** SAMPS042
00021 ** KEY (SEQ-NMBR) TO ACCESS THE TRANS-FILE. THE RECORDS ** SAMPS042
00022 ** THAT ARE READ FROM THE TRANS-FILE ARE OUTPUT TO THE THREE ** SAMPS042
00023 ** FILES, HIT-FILE, HIT-LIST, AND CHECK-LIST. EACH RECORD ** SAMPS042
00024 ** THAT IS READ IS ALSO UPDATED TO INDICATE THAT THE RECORD ** SAMPS042
00025 ** WAS SELECTED AS PART OF THE SAMPLE. THIS IS DONE BY ** SAMPS042
00026 ** CHANGING THE SELECTED-FLAG FIELD FROM A '1' TO A '2'. ** SAMPS042
00027 ** ** SAMPS042
00028 *************************************************************** SAMPS042
00029 SAMPS042
00030 ENVIRONMENT DIVISION. SAMPS042
00031 CONFIGURATION SECTION. SAMPS042
00032 INPUT-OUTPUT SECTION. SAMPS042
00033 FILE-CONTROL. SAMPS042
00034 SELECT TRANS-FILE SAMPS042
00035 ASSIGN TO SYS003-DISKUNIT SAMPS042
00036 ORGANIZATION IS INDEXED SAMPS042
00037 ACCESS MODE IS RANDOM SAMPS042
00038 RECORD KEY IS SEQ-NMBR-A SAMPS042
00039 FILE STATUS IS TRANS-FILE-ERROR-CODE. SAMPS042
00040 SELECT CNTRL-DATA SAMPS042
00041 ASSIGN TO UT-S-CNTRLDTA. SAMPS042
00042 SELECT SELECT-FILE SAMPS042
00043 ASSIGN TO UT-S-SLCTREC. SAMPS042
00044 SELECT HIT-FILE SAMPS042
00045 ASSIGN TO UT-S-HITFILE. SAMPS042
00046 SELECT HIT-LIST SAMPS042
00047 ASSIGN TO UT-S-PRINTER. SAMPS042
00048 SELECT CHECK-LIST SAMPS042
00049 ASSIGN TO UT-S-CHECK. SAMPS042
00050 SELECT JOB-STATUS SAMPS042
00051 ASSIGN TO UT-S-MSGOUT. SAMPS042
00052 SAMPS042
00053 DATA DIVISION. SAMPS042
00054 FILE SECTION. SAMPS042
00055 SAMPS042
00056 *************************************************************** SAMPS042
00057 ** TRANS-FILE IS THE VSAM FILE CREATED BY THE STATE ** SAMPS042
00058 ** EMPLOYMENT SECURITY AGENCIES (SESA) WITH THE RECORDS THAT ** SAMPS042
00059 ** MAKE UP THE SAMPLING UNIVERSE. THE KEY OF THE FILE IS ** SAMPS042
00060 ** (SEQ-NMBR). THIS FIELD CONTAINS THE SEQUENTIAL RECORD ** SAMPS042
00061 ** NUMBER. ** SAMPS042
00062 *************************************************************** SAMPS042
00063 FD TRANS-FILE SAMPS042
00064 LABEL RECORDS ARE STANDARD SAMPS042
00065 BLOCK CONTAINS 0 RECORDS. SAMPS042
00066 01 TRANS-REC. SAMPS042
00067 05 SEQ-NMBR-A PIC X(8). SAMPS042
00068 05 SEQ-NMBR REDEFINES SEQ-NMBR-A PIC 9(8). SAMPS042
00069 05 REC-TYPE PIC X(5). SAMPS042
00070 05 TRANS-TYPE PIC X. SAMPS042
00071 05 SELECT-FLAG PIC X. SAMPS042
00072 05 EMP-ID PIC X(12). SAMPS042
00073 05 DATE-FILE-CREATED PIC X(8). SAMPS042
00074 05 TAX-DUE PIC 9(11). SAMPS042
00075 05 TAX-PAID PIC 9(11). SAMPS042
00076 05 STATE-OPTION PIC X(25). SAMPS042
00077 SAMPS042
00078 *************************************************************** SAMPS042
00079 ** CNTRL-DATA CONTAINS SOME OF THE PROCESSING INFORMATION ** SAMPS042
00080 ** NEEDED FOR SAMPLING. IT CONTAINS THE RANDOM NUMBER ** SAMPS042
00081 ** (CNTRL-RANDOM), THE NUMBER OF RECORDS TO BE SELECTED FOR ** SAMPS042
00082 ** THE SAMPLE (SAMPLED-NMBR), AND THE RECORD COUNT OF THE ** SAMPS042
00083 ** NUMBER OF RECORDS (TRANS-REC-CNTR) CONTAINED ON THE ** SAMPS042
00084 ** TRANS-FILE. FOR THE PURPOSE OF THIS PROGRAM, ONLY ** SAMPS042
00085 ** THE SESA-ID, SAMPLE-TYPE AND SAMPLED-NMBR FIELDS ARE ** SAMPS042
00086 ** NEEDED. ** SAMPS042
00087 *************************************************************** SAMPS042
00088 FD CNTRL-DATA SAMPS042
00089 RECORDING MODE IS F SAMPS042
00090 LABEL RECORD IS OMITTED SAMPS042
00091 BLOCK CONTAINS 1 RECORDS. SAMPS042
00092 01 CNTRL-DATA-REC. SAMPS042
00093 05 CNTRL-TYPE PIC X(5). SAMPS042
00094 05 CNTRL-TRANS-TYPE PIC X. SAMPS042
00095 05 SESA-ID PIC XX. SAMPS042
00096 05 CNTRL-RANDOM PIC V999. SAMPS042
00097 05 CNTRL-RANDOM-ALF REDEFINES CNTRL-RANDOM PIC X(3). SAMPS042
00098 05 SAMPLED-NMBR PIC 9(4). SAMPS042
00099 05 SAMPLED-NMBR-ALF REDEFINES SAMPLED-NMBR PIC X(4). SAMPS042
00100 05 TRANS-REC-CNTR PIC 9(8). SAMPS042
00101 05 TRANS-REC-CNTR-ALF REDEFINES TRANS-REC-CNTR PIC X(8). SAMPS042
00102 05 SAMPLE-TYPE PIC X(02). SAMPS042
00103 05 CNTRL-YEAR-QTR PIC X(05). SAMPS042
00104 05 DATE-FILLER PIC 9(03). SAMPS042
00105 SAMPS042
00106 *************************************************************** SAMPS042
00107 ** HIT-LIST CONTAINS THE PRINTED REPORT OF THE RECORDS ** SAMPS042
00108 ** SELECTED FOR SAMPLING. ** SAMPS042
00109 *************************************************************** SAMPS042
00110 SAMPS042
00111 FD HIT-LIST SAMPS042
00112 RECORDING MODE IS F SAMPS042
00113 LABEL RECORD IS STANDARD. SAMPS042
00114 01 PRINT-HIT-REC PIC X(132). SAMPS042
00115 SAMPS042
00116 ************************************************************* SAMPS042
00117 *** *** SAMPS042
00118 ** THE CHECK-LIST CONTAINS THE INFORMATION NECCESSARY ** SAMPS042
00119 ** TO CARRY OUT THE REVENUE QUALITY CONTROL (RQC) EMPLOYER ** SAMPS042
00120 ** DEBITS/BILLINGS TAX FUNCTION. THIS CHECK LIST IS A ** SAMPS042
00121 ** DUPLICATE OF THE EMPLOYER DEBITS/BILLINGS SAMPLING ** SAMPS042
00122 ** CODING SHEET IN THE RQC OPERATIONS HANDBOOK. ** SAMPS042
00123 *** *** SAMPS042
00124 ************************************************************* SAMPS042
00125 FD CHECK-LIST SAMPS042
00126 RECORDING MODE IS F SAMPS042
00127 LABEL RECORD IS STANDARD. SAMPS042
00128 01 CHECK-LIST-REC PIC X(132). SAMPS042
00129 SAMPS042
00130 *************************************************************** SAMPS042
00131 ** HIT-FILE IS THE DATA FILE FOR STORING THE RECORDS THAT ** SAMPS042
00132 ** HAVE BEEN SELECTED FROM THE (TRANS-FILE) FOR THE SAMPLE. ** SAMPS042
00133 ** THESE RECORDS ARE WRITTEN TO A DISK FILE WITH DELIMITERS ** SAMPS042
00134 ** OF '|' BETWEEN EACH FIELD OF THE RECORD. THIS FILE ** SAMPS042
00135 ** (HIT-FILE), WILL BE PASSED TO THE INFORMIX SIDE OF THE ** SAMPS042
00136 ** RQC SYSTEM FOR FURTHER PROCESSING. ** SAMPS042
00137 *************************************************************** SAMPS042
00138 SAMPS042
00139 FD HIT-FILE SAMPS042
00140 RECORDING MODE IS F SAMPS042
00141 LABEL RECORDS ARE STANDARD. SAMPS042
00142 01 TRANS-HIT-REC PIC X(42). SAMPS042
00143 SAMPS042
00144 ********************************************************* SAMPS042
00145 *** *** SAMPS042
00146 ** THE SELECT-FILE IS THE INPUT FILE THAT CONTAINS THE ** SAMPS042
00147 ** RECORD NUMBERS CREATED IN THE SAMPLE DETERMINATION ** SAMPS042
00148 ** PROGRAM (PICKNMBR). THESE NUMBERS ARE USED AS THE ** SAMPS042
00149 ** RECORD KEY TO SELECT THE RECORDS FROM THE VSAM ** SAMPS042
00150 ** FILE (TRANS-FILE) FOR SAMPLING. ** SAMPS042
00151 *** *** SAMPS042
00152 ********************************************************* SAMPS042
00153 FD SELECT-FILE SAMPS042
00154 RECORDING MODE IS F SAMPS042
00155 LABEL RECORD IS OMITTED SAMPS042
00156 BLOCK CONTAINS 0 RECORDS. SAMPS042
00157 01 SL-REC-NUM PIC 9(08). SAMPS042
00158 SAMPS042
00159 ********************************************** SAMPS042
00160 *** *** SAMPS042
00161 ** THE JOB-STATUS FILE IS A SEPERATE FILE ** SAMPS042
00162 ** CREATED TO OUTPUT THE END OF JOB MESSAGES** SAMPS042
00163 ** SAMPS042 - NORMAL END OF JOB, AND ** SAMPS042
00164 ** SAMPS042 - JOB TERMINATED. ** SAMPS042
00165 *** *** SAMPS042
00166 ********************************************** SAMPS042
00167 FD JOB-STATUS SAMPS042
00168 RECORDING MODE IS F SAMPS042
00169 LABEL RECORD IS STANDARD. SAMPS042
00170 01 MESSAGE-RECORD PIC X(132). SAMPS042
00171 SAMPS042
00172 WORKING-STORAGE SECTION. SAMPS042
001725 77 PAN-VALET PICTURE X(24) VALUE '001SAMPS042 02/12/04'. SAMPS042
00173 SAMPS042
00174 01 WS-WORK-AREA. SAMPS042
00175 05 MATCH-CNTR PIC 9(08) VALUE 0. SAMPS042
00176 05 WS-SELECT-EOF PIC X(01) VALUE 'N'. SAMPS042
00177 05 CNTRL-FLAG PIC X(01) VALUE 'N'. SAMPS042
00178 05 SELECTED-FLAG PIC 9(01) VALUE 2. SAMPS042
00179 05 LIST-COUNTER PIC 9(02) VALUE 0. SAMPS042
00180 05 LIST-PAGE PIC 9(06) VALUE 0. SAMPS042
00181 SAMPS042
00182 05 WS-DATE PIC 9(06) VALUE ZEROES. SAMPS042
00183 05 WS-DATE-R REDEFINES WS-DATE. SAMPS042
00184 10 WS-YY PIC 9(02). SAMPS042
00185 10 WS-MM PIC 9(02). SAMPS042
00186 10 WS-DD PIC 9(02). SAMPS042
00187 SAMPS042
00188 05 WRK-DATE-AREA. SAMPS042
00189 10 WRK-MM PIC X(02). SAMPS042
00190 10 FILLER PIC X(01) VALUE '/'. SAMPS042
00191 10 WRK-DD PIC X(02). SAMPS042
00192 10 FILLER PIC X(01) VALUE '/'. SAMPS042
00193 10 WRK-YY PIC X(02). SAMPS042
00194 *************************************************** SAMPS042
00195 *** *** SAMPS042
00196 ** TRANS-FILE-ERROR-CODE: ** SAMPS042
00197 ** FILE STATUS FIELD WHICH STORES THE VALUE OF ** SAMPS042
00198 ** AN ERROR CODE IF AN ERROR IS ENCOUNTERED ** SAMPS042
00199 ** DURING A READ OR WRITE TO THE VSAM ** SAMPS042
00200 ** (TRANS-FILE) FILE. ** SAMPS042
00201 *** *** SAMPS042
00202 *************************************************** SAMPS042
00203 01 TRANS-FILE-ERROR-CODE PIC X(02). SAMPS042
00204 SAMPS042
00205 01 WS-REPORT-CONTROLS. SAMPS042
00206 05 WS-CHECKLIST-CNTR PIC 9(02) VALUE 0. SAMPS042
00207 05 WS-PAGE-CNTR PIC 9(04) VALUE 0. SAMPS042
00208 SAMPS042
00209 01 WS-HEADER-SWITCH-AREA. SAMPS042
00210 05 WS-CHECKLIST-SWITCH PIC X(01) VALUE '0'. SAMPS042
00211 05 WS-HIT-LIST-SWITCH PIC X(01) VALUE '0'. SAMPS042
00212 SAMPS042
00213 01 WS-CHECKLIST-HOLD-AREA. SAMPS042
00214 SAMPS042
00215 05 WS-EMPL-HOLD-AREA PIC X(12). SAMPS042
00216 05 WS-CASE-HOLD-AREA PIC 9(08). SAMPS042
00217 05 WS-SESA-NAME-AREA PIC X(20). SAMPS042
00218 05 WS-SAMPLE-NAME-AREA PIC X(24). SAMPS042
00219 SAMPS042
00220 *************************************************************** SAMPS042
00221 ** (WS-MATCH-RECORD) STORES THE VALUE OF THE SELECTED RECORDS** SAMPS042
00222 ** FROM THE VSAM FILE (TRANS-FILE). ** SAMPS042
00223 *************************************************************** SAMPS042
00224 SAMPS042
00225 01 WS-MATCH-RECORD. SAMPS042
00226 05 MATCH-SEQ-NMBR PIC 9(8). SAMPS042
00227 05 MATCH-REC-TYPE PIC X(5). SAMPS042
00228 05 MATCH-TRANS-TYPE PIC X(01). SAMPS042
00229 05 MATCH-SELECT-FLAG PIC X(01). SAMPS042
00230 05 MATCH-EMP-ID PIC X(12). SAMPS042
00231 05 MATCH-DATE-CREATED PIC X(8). SAMPS042
00232 05 MATCH-TAX-DUE PIC 9(11). SAMPS042
00233 05 MATCH-TAX-PAID PIC 9(11). SAMPS042
00234 05 MATCH-STATE-OPTION PIC X(25). SAMPS042
00235 SAMPS042
00236 SAMPS042
00237 01 WS-SAMPLE-TABLE-CONTROLS. SAMPS042
00238 05 WS-ENTRY-FOUND-SWITCH PIC X(03). SAMPS042
00239 88 WS-SAMPLE-FOUND VALUE 'YES'. SAMPS042
00240 88 WS-END-OF-SAMPLE-TABLE VALUE 'END'. SAMPS042
00241 SAMPS042
00242 SAMPS042
00243 ********************************************* SAMPS042
00244 *** *** SAMPS042
00245 ** WS-SAMPLE-DATA. ** SAMPS042
00246 ** CONTAINS THE RQC - SAMPLE TYPES; ** SAMPS042
00247 ** A 2 CHARACTER CODE AND A 24 CHARACTER ** SAMPS042
00248 ** DEFINITION. ** SAMPS042
00249 *** *** SAMPS042
00250 ********************************************* SAMPS042
00251 01 WS-SAMPLE-DATA. SAMPS042
00252 05 FILLER PIC X(26) SAMPS042
00253 VALUE 'A11ST ACCEPTANCE SAMPLE '. SAMPS042
00254 05 FILLER PIC X(26) SAMPS042
00255 VALUE 'A22ND ACCEPTANCE SAMPLE '. SAMPS042
00256 05 FILLER PIC X(26) SAMPS042
00257 VALUE 'E1EXPANDED SAMPLE '. SAMPS042
00258 05 FILLER PIC X(26) SAMPS042
00259 VALUE 'O11ST SESA OPTIONAL SAMPLE'. SAMPS042
00260 05 FILLER PIC X(26) SAMPS042
00261 VALUE 'O22ND SESA OPTIONAL SAMPLE'. SAMPS042
00262 01 WS-SAMPLE-TABLE REDEFINES WS-SAMPLE-DATA. SAMPS042
00263 05 WS-SAMPLE-ENTRY OCCURS 5 TIMES SAMPS042
00264 INDEXED BY WS-INDEX. SAMPS042
00265 10 WS-SAMPLE-ID PIC X(02). SAMPS042
00266 10 WS-SAMPLE-DESCRIPTION PIC X(24). SAMPS042
00267 SAMPS042
00268 SAMPS042
00269 01 ST-TABLE-CONTROLS. SAMPS042
00270 05 ST-ENTRY-FOUND-SWITCH PIC X(03). SAMPS042
00271 88 ST-ENTRY-FOUND VALUE 'YES'. SAMPS042
00272 88 ST-END-OF-TABLE VALUE 'END'. SAMPS042
00273 SAMPS042
00274 SAMPS042
00275 ************************************************** SAMPS042
00276 *** *** SAMPS042
00277 ** ST-STATE-DATA: ** SAMPS042
00278 ** CONTAINS THE FIPS CODE AND STATE NAME. ** SAMPS042
00279 *** *** SAMPS042
00280 ************************************************** SAMPS042
00281 01 ST-STATE-DATA. SAMPS042
00282 05 FILLER PIC X(22) VALUE 'AKALASKA '. SAMPS042
00283 05 FILLER PIC X(22) VALUE 'ALALABAMA '. SAMPS042
00284 05 FILLER PIC X(22) VALUE 'ARARKANSAS '. SAMPS042
00285 05 FILLER PIC X(22) VALUE 'AZARIZONA '. SAMPS042
00286 05 FILLER PIC X(22) VALUE 'CACALIFORNIA '. SAMPS042
00287 05 FILLER PIC X(22) VALUE 'COCOLORADO '. SAMPS042
00288 05 FILLER PIC X(22) VALUE 'CTCONNECTICUT '. SAMPS042
00289 05 FILLER PIC X(22) VALUE 'DCDISTRICT OF COLUMBIA'. SAMPS042
00290 05 FILLER PIC X(22) VALUE 'DEDELAWARE '. SAMPS042
00291 05 FILLER PIC X(22) VALUE 'FLFLORIDA '. SAMPS042
00292 05 FILLER PIC X(22) VALUE 'GAGEORGIA '. SAMPS042
00293 05 FILLER PIC X(22) VALUE 'HIHAWAII '. SAMPS042
00294 05 FILLER PIC X(22) VALUE 'IAIOWA '. SAMPS042
00295 05 FILLER PIC X(22) VALUE 'IDIDAHO '. SAMPS042
00296 05 FILLER PIC X(22) VALUE 'ILILLINOIS '. SAMPS042
00297 05 FILLER PIC X(22) VALUE 'ININDIANA '. SAMPS042
00298 05 FILLER PIC X(22) VALUE 'KSKANSAS '. SAMPS042
00299 05 FILLER PIC X(22) VALUE 'KYKENTUCKY '. SAMPS042
00300 05 FILLER PIC X(22) VALUE 'LALOUISIANA '. SAMPS042
00301 05 FILLER PIC X(22) VALUE 'MAMASSACHUSETTS '. SAMPS042
00302 05 FILLER PIC X(22) VALUE 'MDMARYLAND '. SAMPS042
00303 05 FILLER PIC X(22) VALUE 'MEMAINE '. SAMPS042
00304 05 FILLER PIC X(22) VALUE 'MIMICHIGAN '. SAMPS042
00305 05 FILLER PIC X(22) VALUE 'MNMINNESOTA '. SAMPS042
00306 05 FILLER PIC X(22) VALUE 'MOMISSOURI '. SAMPS042
00307 05 FILLER PIC X(22) VALUE 'MSMISSISSIPPI '. SAMPS042
00308 05 FILLER PIC X(22) VALUE 'MTMONTANA '. SAMPS042
00309 05 FILLER PIC X(22) VALUE 'NENEBRASKA '. SAMPS042
00310 05 FILLER PIC X(22) VALUE 'NHNEW HAMSHIRE '. SAMPS042
00311 05 FILLER PIC X(22) VALUE 'NJNEW JERSEY '. SAMPS042
00312 05 FILLER PIC X(22) VALUE 'NMNEW MEXICO '. SAMPS042
00313 05 FILLER PIC X(22) VALUE 'NVNEVADA '. SAMPS042
00314 05 FILLER PIC X(22) VALUE 'NYNEW YORK '. SAMPS042
00315 05 FILLER PIC X(22) VALUE 'NCNORTH CAROLINA '. SAMPS042
00316 05 FILLER PIC X(22) VALUE 'NDNORTH DAKOTA '. SAMPS042
00317 05 FILLER PIC X(22) VALUE 'OHOHIO '. SAMPS042
00318 05 FILLER PIC X(22) VALUE 'OKOKLAHOMA '. SAMPS042
00319 05 FILLER PIC X(22) VALUE 'OROREGON '. SAMPS042
00320 05 FILLER PIC X(22) VALUE 'PAPENNSYLVANIA '. SAMPS042
00321 05 FILLER PIC X(22) VALUE 'PRPUERTO RICO '. SAMPS042
00322 05 FILLER PIC X(22) VALUE 'RIRHODE ISLAND '. SAMPS042
00323 05 FILLER PIC X(22) VALUE 'SCSOUTH CAROLINA '. SAMPS042
00324 05 FILLER PIC X(22) VALUE 'SDSOUTH DAKOTA '. SAMPS042
00325 05 FILLER PIC X(22) VALUE 'TNTENNESSEE '. SAMPS042
00326 05 FILLER PIC X(22) VALUE 'TXTEXAS '. SAMPS042
00327 05 FILLER PIC X(22) VALUE 'UTUTAH '. SAMPS042
00328 05 FILLER PIC X(22) VALUE 'VAVIRGINIA '. SAMPS042
00329 05 FILLER PIC X(22) VALUE 'VIVIRGIN ISLAND '. SAMPS042
00330 05 FILLER PIC X(22) VALUE 'VTVERMONT '. SAMPS042
00331 05 FILLER PIC X(22) VALUE 'WAWASHINGTON '. SAMPS042
00332 05 FILLER PIC X(22) VALUE 'WVWEST VIRGINIA '. SAMPS042
00333 05 FILLER PIC X(22) VALUE 'WIWISCONSIN '. SAMPS042
00334 05 FILLER PIC X(22) VALUE 'WYWYOMING '. SAMPS042
00335 01 ST-STATE-TABLE REDEFINES ST-STATE-DATA. SAMPS042
00336 05 ST-STATE-ENTRY OCCURS 53 TIMES SAMPS042
00337 INDEXED BY ST-INDEX. SAMPS042
00338 10 ST-STATE-ID PIC X(02). SAMPS042
00339 10 ST-STATE-NAME PIC X(20). SAMPS042
00340 SAMPS042
00341 SAMPS042
00342 01 WS-TRANS-TYPE-DESCRIPTION. SAMPS042
00343 05 WS-TYPE-DESCR PIC X(12) SAMPS042
00344 VALUE 'CONTRIBUTORY'. SAMPS042
00345 05 WS-TYPE-REIMB PIC X(12) SAMPS042
00346 VALUE 'REIMBURSING '. SAMPS042
00347 SAMPS042
00348 ************************************************ SAMPS042
00349 *** *** SAMPS042
00350 ** WS-END-OF-JOB-MESSAGES: ** SAMPS042
00351 ** END OF JOB STATUS MESSAGES: MESSAGE-1 ** SAMPS042
00352 ** AND MESSAGE-2. ** SAMPS042
00353 *** *** SAMPS042
00354 ************************************************ SAMPS042
00355 SAMPS042
00356 01 WS-END-OF-JOB-MESSAGES. SAMPS042
00357 05 MESSAGE-1 PIC X(28) SAMPS042
00358 VALUE 'SAMPS042 - NORMAL END OF JOB'. SAMPS042
00359 05 MESSAGE-2 PIC X(28) SAMPS042
00360 VALUE 'SAMPS042 - JOB TERMINATED '. SAMPS042
00361 SAMPS042
00362 01 WS-EOJ-DETAIL-LINE. SAMPS042
00363 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00364 05 WS-MESSAGE-FILE PIC X(28). SAMPS042
00365 05 FILLER PIC X(102) VALUE SPACES. SAMPS042
00366 SAMPS042
00367 01 DTL-DATE-REFORMAT-AREA. SAMPS042
00368 05 DTL-DATE-CREATED PIC X(08). SAMPS042
00369 05 FILLER REDEFINES DTL-DATE-CREATED. SAMPS042
00370 10 DTL-CREATED-YR PIC X(04). SAMPS042
00371 10 DTL-CREATED-MO PIC X(02). SAMPS042
00372 10 DTL-CREATED-DA PIC X(02). SAMPS042
00373 SAMPS042
00374 01 WS-CHECKLIST-PERIOD-REFORMAT. SAMPS042
00375 05 WS-PERIOD-DATE PIC X(05). SAMPS042
00376 05 WS-PERIOD-X REDEFINES WS-PERIOD-DATE. SAMPS042
00377 10 WS-CHECKLIST-YEAR PIC X(04). SAMPS042
00378 10 WS-CHECKLIST-QUARTER PIC X(01). SAMPS042
00379 SAMPS042
00380 *************************************************************** SAMPS042
00381 ** (OUTPUT-HIT-REC) IS THE RECORD LAYOUT FOR THE RECORDS ** SAMPS042
00382 ** THAT ARE WRITTEN TO THE FILE (HIT-FILE). THIS FILE CAN ** SAMPS042
00383 ** BE DOWNLOADED TO THE SUN MICROCOMPUTER INTO THE CORE ** SAMPS042
00384 ** RQC SAMPLING SUBSYSTEM. ** SAMPS042
00385 *************************************************************** SAMPS042
00386 01 OUTPUT-HIT-REC. SAMPS042
00387 SAMPS042
00388 05 HIT-RECORD-TYPE PIC X(05) VALUE SPACES. SAMPS042
00389 05 FILLER PIC X(01) VALUE '|'. SAMPS042
00390 05 HIT-STATE PIC X(02) VALUE SPACES. SAMPS042
00391 05 FILLER PIC X(01) VALUE '|'. SAMPS042
00392 05 HIT-SAMPLE-YEAR PIC X(05) VALUE SPACES. SAMPS042
00393 05 FILLER PIC X(01) VALUE '|'. SAMPS042
00394 05 HIT-TRANS-TYPE PIC X(01) VALUE ZEROS. SAMPS042
00395 05 FILLER PIC X(01) VALUE '|'. SAMPS042
00396 05 HIT-SAMPLE-TYPE PIC X(02) VALUE ZEROS. SAMPS042
00397 05 FILLER PIC X(01) VALUE '|'. SAMPS042
00398 05 HIT-CASE-NUMBER PIC 9(08) VALUE ZEROS. SAMPS042
00399 05 FILLER PIC X(01) VALUE '|'. SAMPS042
00400 05 HIT-EMPLOYER-ID PIC X(12) VALUE SPACES. SAMPS042
00401 05 FILLER PIC X(01) VALUE '|'. SAMPS042
00402 SAMPS042
00403 *************************************************************** SAMPS042
00404 ** (OUTPUT-TITLES) DESCRIBES THE LINES FOR EACH LINE OF THE ** SAMPS042
00405 ** REPORT TITLE. ** SAMPS042
00406 *************************************************************** SAMPS042
00407 SAMPS042
00408 01 LIST-HEADING-1. SAMPS042
00409 10 FILLER PIC X(1) VALUE SPACES. SAMPS042
00410 10 FILLER PIC X(9) VALUE 'RUN DATE:'. SAMPS042
00411 10 FILLER PIC X(1) VALUE SPACES. SAMPS042
00412 10 O-RUN-DATE PIC X(8) VALUE SPACES. SAMPS042
00413 10 FILLER PIC X(32) VALUE SPACES. SAMPS042
00414 10 FILLER PIC X(27) SAMPS042
00415 VALUE 'EMPLOYER DEBITS/BILLINGS - '. SAMPS042
00416 10 FILLER PIC X(1) VALUE SPACES. SAMPS042
00417 10 DTL-OUTPUT-TRANS-TYPE PIC X(12). SAMPS042
00418 10 FILLER PIC X(20) VALUE SPACES. SAMPS042
00419 10 FILLER PIC X(5) VALUE 'PAGE:'. SAMPS042
00420 10 FILLER PIC X(1) VALUE SPACES. SAMPS042
00421 10 O-LIST-PAGE PIC ZZZZZ9. SAMPS042
00422 10 FILLER PIC X(04) VALUE SPACES. SAMPS042
00423 SAMPS042
00424 01 LIST-HEADING-2. SAMPS042
00425 10 FILLER PIC X(51) VALUE SPACES. SAMPS042
00426 10 FILLER PIC X(25) SAMPS042
00427 VALUE 'SAMPLING HIT FILE LISTING'. SAMPS042
00428 10 FILLER PIC X(56) VALUE SPACES. SAMPS042
00429 SAMPS042
00430 01 LIST-HEADING-3. SAMPS042
00431 10 FILLER PIC X(51) VALUE SPACES. SAMPS042
00432 10 FILLER PIC X(9) VALUE 'STATE OF '. SAMPS042
00433 10 O-CNTRL-SESA-NAME PIC X(20) VALUE SPACES. SAMPS042
00434 10 FILLER PIC X(52) VALUE SPACES. SAMPS042
00435 SAMPS042
00436 01 LIST-HEADING-4. SAMPS042
00437 10 FILLER PIC X(22) VALUE SPACES. SAMPS042
00438 10 FILLER PIC X(4) VALUE 'CASE'. SAMPS042
00439 10 FILLER PIC X(8) VALUE SPACES. SAMPS042
00440 10 FILLER PIC X(8) VALUE 'EMPLOYER'. SAMPS042
00441 10 FILLER PIC X(13) VALUE SPACES. SAMPS042
00442 10 FILLER PIC X(03) VALUE 'TAX'. SAMPS042
00443 10 FILLER PIC X(15) VALUE SPACES. SAMPS042
00444 10 FILLER PIC X(03) VALUE 'TAX'. SAMPS042
00445 10 FILLER PIC X(11) VALUE SPACES. SAMPS042
00446 10 FILLER PIC X(4) VALUE 'DATE'. SAMPS042
00447 10 FILLER PIC X(07) VALUE SPACES. SAMPS042
00448 10 FILLER PIC X(8) VALUE 'SEQUENCE'. SAMPS042
00449 10 FILLER PIC X(41) VALUE SPACES. SAMPS042
00450 SAMPS042
00451 01 LIST-HEADING-5. SAMPS042
00452 10 FILLER PIC X(22) VALUE SPACES. SAMPS042
00453 10 FILLER PIC X(6) VALUE 'NUMBER'. SAMPS042
00454 10 FILLER PIC X(06) VALUE SPACES. SAMPS042
00455 10 FILLER PIC X(9) VALUE 'ID NUMBER'. SAMPS042
00456 10 FILLER PIC X(12) VALUE SPACES. SAMPS042
00457 10 FILLER PIC X(03) VALUE 'DUE'. SAMPS042
00458 10 FILLER PIC X(15) VALUE SPACES. SAMPS042
00459 10 FILLER PIC X(04) VALUE 'PAID'. SAMPS042
00460 10 FILLER PIC X(09) VALUE SPACES. SAMPS042
00461 10 FILLER PIC X(9) SAMPS042
00462 VALUE 'CREATED'. SAMPS042
00463 10 FILLER PIC X(04) VALUE SPACES. SAMPS042
00464 10 FILLER PIC X(06) VALUE 'NUMBER'. SAMPS042
00465 10 FILLER PIC X(21) VALUE SPACES. SAMPS042
00466 SAMPS042
00467 *************************************************************** SAMPS042
00468 ** (OUTPUT-DTL-LINE) DESCRIBES THE OUTPUT FOR THE DETAIL ** SAMPS042
00469 ** LINES OF THE REPORT. ** SAMPS042
00470 *************************************************************** SAMPS042
00471 SAMPS042
00472 01 HIT-LIST-REC. SAMPS042
00473 10 FILLER PIC X(19) VALUE SPACES. SAMPS042
00474 10 DTL-CASE-NO PIC ZZZZZZZ9 VALUE ZEROS. SAMPS042
00475 10 FILLER PIC X(6) VALUE SPACES. SAMPS042
00476 10 DTL-EMP-ID PIC X(12) VALUE SPACES. SAMPS042
00477 10 FILLER PIC X(03) VALUE SPACES. SAMPS042
00478 10 DTL-TAX-DUE PIC $$$,$$$,$$$,$$$. SAMPS042
00479 10 FILLER PIC X(03) VALUE SPACES. SAMPS042
00480 10 DTL-TAX-PAID PIC $$$,$$$,$$$,$$$. SAMPS042
00481 10 FILLER PIC X(04) VALUE SPACES. SAMPS042
00482 10 O-CREATED-MO PIC X(02) VALUE ZEROS. SAMPS042
00483 10 FILLER PIC X SAMPS042
00484 VALUE '/'. SAMPS042
00485 10 O-CREATED-DA PIC X(02) VALUE ZEROS. SAMPS042
00486 10 FILLER PIC X SAMPS042
00487 VALUE '/'. SAMPS042
00488 10 O-CREATED-YR PIC X(04) VALUE ZEROS. SAMPS042
00489 10 FILLER PIC X(03) VALUE SPACES. SAMPS042
00490 10 DTL-SEQ-NMBR PIC ZZZZZZZ9 VALUE ZEROS. SAMPS042
00491 10 FILLER PIC X(32) VALUE SPACES. SAMPS042
00492 SAMPS042
00493 ********************************************** SAMPS042
00494 *** *** SAMPS042
00495 ** ADDITIONAL COBOL CODE TO CREATE A CODING ** SAMPS042
00496 ** SHEET FOR THE REVENUE QUALITY CONTROL ** SAMPS042
00497 ** (RQC) REVIEWER. IT IS A DUPLICATE OF ** SAMPS042
00498 ** THE CODING SHEET IN THE RQC OPERATIONS ** SAMPS042
00499 ** HANDBOOK. ** SAMPS042
00500 *** *** SAMPS042
00501 ********************************************** SAMPS042
00502 01 FL-BANNER-LINE PIC X(132) VALUE ALL '-'. SAMPS042
00503 SAMPS042
00504 01 HD-NEW-EMP-CHECKLIST. SAMPS042
00505 SAMPS042
00506 05 FILLER PIC X(53) VALUE SPACES. SAMPS042
00507 05 FILLER PIC X(23) VALUE SAMPS042
00508 'REVENUE QUALITY CONTROL'. SAMPS042
00509 05 FILLER PIC X(34) VALUE SPACES. SAMPS042
00510 05 FILLER PIC X(06) VALUE SAMPS042
00511 'PAGE: '. SAMPS042
00512 05 HD-PAGE-NUMBER PIC ZZZZZ9. SAMPS042
00513 05 FILLER PIC X(10) VALUE SPACES. SAMPS042
00514 SAMPS042
00515 01 HT-TAX-FUNCTION-HEADER. SAMPS042
00516 SAMPS042
00517 05 FILLER PIC X(01) VALUE SPACES. SAMPS042
00518 05 FILLER PIC X(39) VALUE SAMPS042
00519 'ACCOUNT MAINTENANCE SAMPLE CODING SHEET'. SAMPS042
00520 05 FILLER PIC X(70) VALUE SPACES. SAMPS042
00521 05 FILLER PIC X(10) VALUE SAMPS042
00522 'RUN DATE: '. SAMPS042
00523 05 HD-RUN-DATE PIC X(08). SAMPS042
00524 05 FILLER PIC X(04) VALUE SPACES. SAMPS042
00525 SAMPS042
00526 01 H2-TAX-FUNCTION-HEADER-2. SAMPS042
00527 SAMPS042
00528 05 FILLER PIC X(01) VALUE SPACES. SAMPS042
00529 05 FILLER PIC X(39) VALUE SAMPS042
00530 'EMPLOYER DEBITS/BILLINGS - CHECKLIST #2'. SAMPS042
00531 05 FILLER PIC X(92) VALUE SPACES. SAMPS042
00532 SAMPS042
00533 01 FL-FIRST-LINE-COLUMN-HEADER. SAMPS042
00534 SAMPS042
00535 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00536 05 FILLER PIC X(11) VALUE SAMPS042
00537 'SESA NAME: '. SAMPS042
00538 05 FL-SESA-NAME PIC X(20). SAMPS042
00539 05 FILLER PIC X(05) VALUE SPACES. SAMPS042
00540 05 FILLER PIC X(15) SAMPS042
00541 VALUE 'PERIOD/QUARTER:'. SAMPS042
00542 05 FILLER PIC X(01) VALUE SPACES. SAMPS042
00543 05 FL-PERIOD. SAMPS042
00544 10 FL-YEAR PIC X(04). SAMPS042
00545 10 FILLER PIC X(01) VALUE '/'. SAMPS042
00546 10 FL-QUARTER PIC X(01). SAMPS042
00547 05 FILLER PIC X(25) VALUE SPACES. SAMPS042
00548 05 FILLER PIC X(25) VALUE SAMPS042
00549 'REVIEWER: _______________'. SAMPS042
00550 05 FILLER PIC X(22) VALUE SPACES. SAMPS042
00551 SAMPS042
00552 01 WS-TRANSACTION-TYPE-FIELD. SAMPS042
00553 SAMPS042
00554 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00555 05 FILLER PIC X(18) SAMPS042
00556 VALUE 'TRANSACTION TYPE: '. SAMPS042
00557 05 WS-TRANS-TYPE PIC X(12). SAMPS042
00558 05 FILLER PIC X(15) VALUE SPACES. SAMPS042
00559 05 FILLER PIC X(13) VALUE SAMPS042
00560 'SAMPLE TYPE: '. SAMPS042
00561 05 WS-SAMPLE-TYPE PIC X(24). SAMPS042
00562 05 FILLER PIC X(48) VALUE SPACES. SAMPS042
00563 SAMPS042
00564 01 SL-SECOND-LINE-COL-HEADER. SAMPS042
00565 SAMPS042
00566 05 FILLER PIC X(04) VALUE SPACES. SAMPS042
00567 05 FILLER PIC X(04) VALUE SAMPS042
00568 'CASE'. SAMPS042
00569 05 FILLER PIC X(03) VALUE SPACES. SAMPS042
00570 05 FILLER PIC X(08) VALUE SAMPS042
00571 'EMPLOYER'. SAMPS042
00572 05 FILLER PIC X(08) VALUE SPACES. SAMPS042
00573 05 FILLER PIC X(02) VALUE '1A'. SAMPS042
00574 05 FILLER PIC X(04) VALUE SPACES. SAMPS042
00575 05 FILLER PIC X(02) VALUE '1B'. SAMPS042
00576 05 FILLER PIC X(06) VALUE SPACES. SAMPS042
00577 05 FILLER PIC X(01) VALUE '2'. SAMPS042
00578 05 FILLER PIC X(05) VALUE SPACES. SAMPS042
00579 05 FILLER PIC X(02) VALUE '3A'. SAMPS042
00580 05 FILLER PIC X(05) VALUE SPACES. SAMPS042
00581 05 FILLER PIC X(02) VALUE '3B'. SAMPS042
00582 05 FILLER PIC X(06) VALUE SPACES. SAMPS042
00583 05 FILLER PIC X(01) VALUE '4'. SAMPS042
00584 05 FILLER PIC X(05) VALUE SPACES. SAMPS042
00585 05 FILLER PIC X(09) SAMPS042
00586 VALUE 'PASS/FAIL'. SAMPS042
00587 05 FILLER PIC X(61) VALUE SPACES. SAMPS042
00588 SAMPS042
00589 01 TL-THIRD-COLUMN-HEADER. SAMPS042
00590 SAMPS042
00591 05 FILLER PIC X(03) VALUE SPACES. SAMPS042
00592 05 FILLER PIC X(06) VALUE SAMPS042
00593 'NUMBER'. SAMPS042
00594 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00595 05 FILLER PIC X(09) VALUE SAMPS042
00596 'ID NUMBER'. SAMPS042
00597 05 FILLER PIC X(50) VALUE SPACES. SAMPS042
00598 05 FILLER PIC X(05) SAMPS042
00599 VALUE '(Y/N)'. SAMPS042
00600 05 FILLER PIC X(57) VALUE SPACES. SAMPS042
00601 SAMPS042
00602 01 CL-COLUMN-UNDERLINE. SAMPS042
00603 SAMPS042
00604 05 FILLER PIC X(03) VALUE SPACES. SAMPS042
00605 05 FILLER PIC X(06) VALUE SAMPS042
00606 '------'. SAMPS042
00607 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00608 05 FILLER PIC X(09) VALUE SAMPS042
00609 '---------'. SAMPS042
00610 05 FILLER PIC X(06) VALUE SPACES. SAMPS042
00611 05 FILLER PIC X(05) VALUE '-----'. SAMPS042
00612 05 FILLER PIC X(01) VALUE SPACES. SAMPS042
00613 05 FILLER PIC X(05) VALUE '-----'. SAMPS042
00614 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00615 05 FILLER PIC X(05) VALUE '-----'. SAMPS042
00616 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00617 05 FILLER PIC X(05) VALUE '-----'. SAMPS042
00618 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00619 05 FILLER PIC X(05) VALUE '-----'. SAMPS042
00620 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00621 05 FILLER PIC X(05) VALUE '-----'. SAMPS042
00622 05 FILLER PIC X(03) VALUE SPACES. SAMPS042
00623 05 FILLER PIC X(09) VALUE '---------'. SAMPS042
00624 05 FILLER PIC X(58) VALUE SPACES. SAMPS042
00625 SAMPS042
00626 01 DL-BANNER-LINE PIC X(77) VALUE ALL '-'. SAMPS042
00627 SAMPS042
00628 01 DL-CHECKLIST-DETAIL. SAMPS042
00629 05 DL-CHECKLIST-CASE-NO PIC ZZZZZZZ9. SAMPS042
00630 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00631 05 DL-CHECKLIST-EMP-ID PIC X(12). SAMPS042
00632 05 FILLER PIC X(04) VALUE SPACES. SAMPS042
00633 05 FILLER PIC X(05) VALUE '( )'. SAMPS042
00634 05 FILLER PIC X(01) VALUE SPACES. SAMPS042
00635 05 FILLER PIC X(05) VALUE '( )'. SAMPS042
00636 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00637 05 FILLER PIC X(05) VALUE '( )'. SAMPS042
00638 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00639 05 FILLER PIC X(05) VALUE '( )'. SAMPS042
00640 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00641 05 FILLER PIC X(05) VALUE '( )'. SAMPS042
00642 05 FILLER PIC X(02) VALUE SPACES. SAMPS042
00643 05 FILLER PIC X(05) VALUE '( )'. SAMPS042
00644 05 FILLER PIC X(05) VALUE SPACES. SAMPS042
00645 05 FILLER PIC X(05) VALUE '( )'. SAMPS042
00646 05 FILLER PIC X(67) VALUE SPACES. SAMPS042
00647 SAMPS042
00648 01 WS-FOOTNOTE-AREA. SAMPS042
00649 05 FILLER PIC X(01) VALUE SPACES. SAMPS042
00650 05 FILLER PIC X(46) SAMPS042
00651 VALUE 'QUESTIONS 1A, 1B, 3A, 3B, AND 4 ARE EVALUATIVE'. SAMPS042
00652 05 FILLER PIC X(85) VALUE SPACES. SAMPS042
00653 SAMPS042
00654 SAMPS042
00655 PROCEDURE DIVISION. SAMPS042
00656 ******************************************** SAMPS042
00657 *** *** SAMPS042
00658 ** THE DECLARATIVES SECTION THAT FOLLOWS ** SAMPS042
00659 ** IS PERFORMED IF AN INPUT/OUTPUT ERROR ** SAMPS042
00660 ** OCCURS TO THE VSAM FILE (TRANS-FILE) ** SAMPS042
00661 ** DURING PROCESSING. ** SAMPS042
00662 *** *** SAMPS042
00663 ******************************************** SAMPS042
00664 DECLARATIVES. SAMPS042
00665 A000-EXCEPTION-HANDLING SECTION. SAMPS042
00666 USE AFTER ERROR PROCEDURE SAMPS042
00667 ON TRANS-FILE. SAMPS042
00668 SAMPS042
00669 ******************************************* SAMPS042
00670 *** *** SAMPS042
00671 ** A100-CHECK-ERROR-ROUTINE. ** SAMPS042
00672 ** THIS SECTION WILL DISPLAY THAT AN ** SAMPS042
00673 ** INPUT/OUTPUT ERROR HAS OCCURRED, ** SAMPS042
00674 ** DISPLAY A FILE STATUS ERROR CODE ** SAMPS042
00675 ** (TRANS-FILE-ERROR-CODE), CLOSES ALL ** SAMPS042
00676 ** INPUT/OUTPUT FILES AND STOPS THE ** SAMPS042
00677 ** EXECUTION OF THE PROGRAM. ** SAMPS042
00678 *** *** SAMPS042
00679 ******************************************* SAMPS042
00680 A100-CHECK-ERROR-ROUTINE. SAMPS042
00681 SAMPS042
00682 DISPLAY 'INPUT/OUTPUT ERROR HAS OCCURRED.' SAMPS042
00683 DISPLAY 'THE FILE STATUS CODE ERROR IS : ' SAMPS042
00684 DISPLAY TRANS-FILE-ERROR-CODE SAMPS042
00685 DISPLAY 'THE FILE SEQ-NMBR-KEY IS : ' SAMPS042
00686 DISPLAY SEQ-NMBR-A SAMPS042
00687 DISPLAY ' - SAMPS042 - JOB TERMINATED ' SAMPS042
00688 CLOSE SELECT-FILE SAMPS042
00689 CLOSE CNTRL-DATA SAMPS042
00690 CLOSE TRANS-FILE SAMPS042
00691 CLOSE JOB-STATUS SAMPS042
00692 CLOSE HIT-FILE SAMPS042
00693 CLOSE HIT-LIST SAMPS042
00694 CLOSE CHECK-LIST SAMPS042
00695 STOP RUN. SAMPS042
00696 SAMPS042
00697 END DECLARATIVES. SAMPS042
00698 *************************************************************** SAMPS042
00699 ** 0000-DRIVER-ROUTINE. ** SAMPS042
00700 ** THIS SECTION PERFORMS THE MAIN PROCESSING OF THE PROGRAM. ** SAMPS042
00701 *************************************************************** SAMPS042
00702 B000-REGULAR-PROCESSING SECTION. SAMPS042
00703 0000-DRIVER-ROUTINE. SAMPS042
00704 SAMPS042
00705 PERFORM 0100-OPEN-ROUTINE SAMPS042
00706 THRU 0100-OPEN-ROUTINE-EXIT. SAMPS042
00707 PERFORM 0200-VALIDATE-TRANSACTION-TYPE SAMPS042
00708 THRU 0200-VALIDATION-EXIT. SAMPS042
00709 PERFORM 0300-STATE-TABLE-ROUTINE SAMPS042
00710 THRU 0300-STATE-TABLE-EXIT. SAMPS042
00711 PERFORM 0305-SAMPLE-TABLE-ROUTINE SAMPS042
00712 THRU 0305-SAMPLE-TABLE-EXIT. SAMPS042
00713 PERFORM 0500-SELECT-RECORDS SAMPS042
00714 THRU 0500-SELECT-RECS-EXIT SAMPS042
00715 UNTIL WS-SELECT-EOF = 'Y'. SAMPS042
00716 SAMPS042
00717 ************************************************************ SAMPS042
00718 ** 0100-OPEN-ROUTINE. ** SAMPS042
00719 ** THIS SECTION OPENS INPUT FILES CNTRL-DATA, AND ** SAMPS042
00720 ** SELECT-FILE. THE FOLLOWING OUTPUT FILES ARE OPENED: ** SAMPS042
00721 ** HIT-FILE, HIT-LIST, CHECK-LIST, AND JOB-STATUS. ** SAMPS042
00722 ** THIS SECTION ALSO OPENS THE VSAM FILE TRANS-FILE AS ** SAMPS042
00723 ** INPUT/OUTPUT, MOVES THE CURRENT DATE TO THE OUTPUT ** SAMPS042
00724 ** FILE HIT-LIST AND CHECK-LIST FOR PRINTING, AND READS ** SAMPS042
00725 ** THE RECORD IN THE CNTRL-DATA FILE. ** SAMPS042
00726 ************************************************************ SAMPS042
00727 0100-OPEN-ROUTINE. SAMPS042
00728 SAMPS042
00729 OPEN INPUT CNTRL-DATA. SAMPS042
00730 OPEN INPUT SELECT-FILE. SAMPS042
00731 OPEN I-O TRANS-FILE. SAMPS042
00732 OPEN OUTPUT HIT-FILE. SAMPS042
00733 OPEN OUTPUT HIT-LIST. SAMPS042
00734 OPEN OUTPUT CHECK-LIST. SAMPS042
00735 OPEN OUTPUT JOB-STATUS. SAMPS042
00736 ACCEPT WS-DATE FROM DATE. SAMPS042
00737 MOVE WS-YY TO WRK-YY. SAMPS042
00738 MOVE WS-MM TO WRK-MM. SAMPS042
00739 MOVE WS-DD TO WRK-DD. SAMPS042
00740 MOVE WRK-DATE-AREA TO O-RUN-DATE HD-RUN-DATE. SAMPS042
00741 READ CNTRL-DATA AT END MOVE 'Y' TO CNTRL-FLAG. SAMPS042
00742 SAMPS042
00743 0100-OPEN-ROUTINE-EXIT. SAMPS042
00744 EXIT. SAMPS042
00745 SAMPS042
00746 ******************************************************* SAMPS042
00747 *** *** SAMPS042
00748 ** 0200-VALIDATE-TRANSACTION-TYPE: ** SAMPS042
00749 ** UTILIZING THE CNTRL-TRANS-TYPE FIELD FROM THE ** SAMPS042
00750 ** INPUT FILE CNTRL-DATA, THIS PROCEDURE VALIDATES ** SAMPS042
00751 ** WHETHER THE REPORT TYPE IS CONTRIBUTORY OR ** SAMPS042
00752 ** REIMBURSING. IF THE CNTRL-TRANS-TYPE IS NOT ANY ** SAMPS042
00753 ** OF THE TWO CONTROL TYPES (1 OR 2), AN ERROR ** SAMPS042
00754 ** MESSAGE IS DISPLAYED AND THE PROGRAM IS ** SAMPS042
00755 ** TERMINATED. ** SAMPS042
00756 *** *** SAMPS042
00757 ******************************************************* SAMPS042
00758 SAMPS042
00759 0200-VALIDATE-TRANSACTION-TYPE. SAMPS042
00760 SAMPS042
00761 IF CNTRL-TRANS-TYPE = '1' SAMPS042
00762 MOVE WS-TYPE-DESCR TO DTL-OUTPUT-TRANS-TYPE SAMPS042
00763 MOVE WS-TYPE-DESCR TO WS-TRANS-TYPE SAMPS042
00764 ELSE SAMPS042
00765 IF CNTRL-TRANS-TYPE = '2' SAMPS042
00766 MOVE WS-TYPE-REIMB TO DTL-OUTPUT-TRANS-TYPE SAMPS042
00767 MOVE WS-TYPE-REIMB TO WS-TRANS-TYPE SAMPS042
00768 ELSE SAMPS042
00769 DISPLAY 'INVALID TRANSACTION TYPE' SAMPS042
00770 DISPLAY 'TRANSACTION TYPE IN ERROR IS: ' SAMPS042
00771 DISPLAY CNTRL-TRANS-TYPE SAMPS042
00772 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS042
00773 PERFORM 9999-CLOSE-FILES SAMPS042
00774 STOP RUN. SAMPS042
00775 SAMPS042
00776 0200-VALIDATION-EXIT. SAMPS042
00777 EXIT. SAMPS042
00778 ************************************************* SAMPS042
00779 *** *** SAMPS042
00780 ** 0300-STATE-TABLE-ROUTINE. ** SAMPS042
00781 ** THIS ROUTINE SEARCHES THE ST-STATE-DATA ** SAMPS042
00782 ** TABLE, FOUND IN THE WORKING STORAGE SECTION,** SAMPS042
00783 ** FOR A MATCHING CONDITION OF THE SESA-ID ** SAMPS042
00784 ** FIELD OF THE CNTRL-DATA FILE. IF A MATCH ** SAMPS042
00785 ** OCCURS, THE STATE ABBREVIATION (SESA-ID) IS ** SAMPS042
00786 ** REPLACED WITH THE STATE NAME DESCRIPTION. ** SAMPS042
00787 ** IF A MATCH IS NOT FOUND, AN ERROR MESSAGE IS** SAMPS042
00788 ** DISPLAYED AND THE PROGRAM RUN IS TERMINATED.** SAMPS042
00789 *** *** SAMPS042
00790 ************************************************* SAMPS042
00791 SAMPS042
00792 0300-STATE-TABLE-ROUTINE. SAMPS042
00793 SAMPS042
00794 SET ST-INDEX TO 1. SAMPS042
00795 SEARCH ST-STATE-ENTRY SAMPS042
00796 AT END MOVE 'END' TO ST-ENTRY-FOUND-SWITCH SAMPS042
00797 WHEN SESA-ID SAMPS042
00798 IS EQUAL TO ST-STATE-ID (ST-INDEX) SAMPS042
00799 MOVE 'YES' TO ST-ENTRY-FOUND-SWITCH. SAMPS042
00800 IF ST-ENTRY-FOUND SAMPS042
00801 MOVE ST-STATE-NAME (ST-INDEX) SAMPS042
00802 TO WS-SESA-NAME-AREA SAMPS042
00803 ELSE SAMPS042
00804 DISPLAY SESA-ID, ' - NOT FOUND ON STATE TABLE' SAMPS042
00805 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS042
00806 PERFORM 9999-CLOSE-FILES SAMPS042
00807 STOP RUN. SAMPS042
00808 SAMPS042
00809 0300-STATE-TABLE-EXIT. SAMPS042
00810 EXIT. SAMPS042
00811 SAMPS042
00812 ************************************************* SAMPS042
00813 *** *** SAMPS042
00814 ** 0305-SAMPLE-TABLE-ROUTINE: ** SAMPS042
00815 ** THIS ROUTINE SEARCHES THE WS-SAMPLE-DATA ** SAMPS042
00816 ** TABLE,FOUND IN THE WORKING STORAGE SECTION, ** SAMPS042
00817 ** FOR A MATCHING CONDITION OF THE SAMPLE-TYPE ** SAMPS042
00818 ** FIELD OF THE CNTRL-DATA FILE. IF A MATCH ** SAMPS042
00819 ** OCCURS, THE SAMPLE-TYPE ABBREVIATION IS ** SAMPS042
00820 ** REPLACED WITH THE SAMPLE-TYPE DESCRIPTION. ** SAMPS042
00821 ** IF A MATCH IS NOT FOUND, AN ERROR MESSAGE ** SAMPS042
00822 ** IS DISPLAYED AND THE PROGRAM RUN IS ** SAMPS042
00823 ** TERMINATED. ** SAMPS042
00824 *** *** SAMPS042
00825 ************************************************* SAMPS042
00826 0305-SAMPLE-TABLE-ROUTINE. SAMPS042
00827 SAMPS042
00828 SET WS-INDEX TO 1. SAMPS042
00829 SEARCH WS-SAMPLE-ENTRY SAMPS042
00830 AT END MOVE 'END' TO WS-ENTRY-FOUND-SWITCH SAMPS042
00831 WHEN SAMPLE-TYPE SAMPS042
00832 IS EQUAL TO WS-SAMPLE-ID (WS-INDEX) SAMPS042
00833 MOVE 'YES' TO WS-ENTRY-FOUND-SWITCH. SAMPS042
00834 IF WS-SAMPLE-FOUND SAMPS042
00835 MOVE WS-SAMPLE-DESCRIPTION (WS-INDEX) SAMPS042
00836 TO WS-SAMPLE-NAME-AREA SAMPS042
00837 ELSE SAMPS042
00838 DISPLAY SAMPLE-TYPE, '- NOT ON SAMPLE TABLE' SAMPS042
00839 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS042
00840 PERFORM 9999-CLOSE-FILES SAMPS042
00841 STOP RUN. SAMPS042
00842 SAMPS042
00843 0305-SAMPLE-TABLE-EXIT. SAMPS042
00844 EXIT. SAMPS042
00845 SAMPS042
00846 ********************************************************* SAMPS042
00847 *** *** SAMPS042
00848 ** 0400-HIT-LIST-HEADING. ** SAMPS042
00849 ** THIS SECTION GENERATES THE PAGE AND COLUMN ** SAMPS042
00850 ** HEADERS FOR THE HIT-LIST OUTPUT REPORT. ** SAMPS042
00851 *** *** SAMPS042
00852 ********************************************************* SAMPS042
00853 0400-HIT-LIST-HEADING. SAMPS042
00854 SAMPS042
00855 ADD 1 TO LIST-PAGE. SAMPS042
00856 MOVE SPACES TO PRINT-HIT-REC. SAMPS042
00857 MOVE LIST-PAGE TO O-LIST-PAGE. SAMPS042
00858 MOVE WS-SESA-NAME-AREA TO O-CNTRL-SESA-NAME. SAMPS042
00859 WRITE PRINT-HIT-REC FROM LIST-HEADING-1 SAMPS042
00860 AFTER ADVANCING PAGE. SAMPS042
00861 WRITE PRINT-HIT-REC FROM LIST-HEADING-2 SAMPS042
00862 AFTER ADVANCING 1 LINE. SAMPS042
00863 WRITE PRINT-HIT-REC FROM LIST-HEADING-3 SAMPS042
00864 AFTER ADVANCING 1 LINE. SAMPS042
00865 WRITE PRINT-HIT-REC FROM LIST-HEADING-4 SAMPS042
00866 AFTER ADVANCING 3 LINES. SAMPS042
00867 WRITE PRINT-HIT-REC FROM LIST-HEADING-5 SAMPS042
00868 AFTER ADVANCING 1 LINE. SAMPS042
00869 MOVE SPACES TO PRINT-HIT-REC. SAMPS042
00870 WRITE PRINT-HIT-REC AFTER ADVANCING 1 LINE. SAMPS042
00871 SAMPS042
00872 0400-HIT-LIST-EXIT. SAMPS042
00873 EXIT. SAMPS042
00874 SAMPS042
00875 ********************************************* SAMPS042
00876 *** *** SAMPS042
00877 ** 0405-CHECKLIST-HEADER-RTN. ** SAMPS042
00878 ** THIS SECTION CREATES THE PAGE AND ** SAMPS042
00879 ** COLUMN HEADERS FOR THE CHECK-LIST ** SAMPS042
00880 ** OUTPUT REPORT. ** SAMPS042
00881 *** *** SAMPS042
00882 ********************************************* SAMPS042
00883 0405-CHECKLIST-HEADER-RTN. SAMPS042
00884 SAMPS042
00885 ADD 1 TO WS-PAGE-CNTR. SAMPS042
00886 MOVE SPACES TO CHECK-LIST-REC. SAMPS042
00887 MOVE WS-PAGE-CNTR TO HD-PAGE-NUMBER. SAMPS042
00888 WRITE CHECK-LIST-REC FROM FL-BANNER-LINE SAMPS042
00889 AFTER ADVANCING PAGE. SAMPS042
00890 WRITE CHECK-LIST-REC FROM HD-NEW-EMP-CHECKLIST SAMPS042
00891 AFTER ADVANCING 1 LINE. SAMPS042
00892 WRITE CHECK-LIST-REC FROM HT-TAX-FUNCTION-HEADER SAMPS042
00893 AFTER ADVANCING 1 LINE. SAMPS042
00894 WRITE CHECK-LIST-REC FROM H2-TAX-FUNCTION-HEADER-2 SAMPS042
00895 AFTER ADVANCING 1 LINE. SAMPS042
00896 WRITE CHECK-LIST-REC FROM FL-BANNER-LINE SAMPS042
00897 AFTER ADVANCING 1 LINE. SAMPS042
00898 MOVE WS-SESA-NAME-AREA TO FL-SESA-NAME. SAMPS042
00899 MOVE CNTRL-YEAR-QTR TO WS-PERIOD-DATE. SAMPS042
00900 MOVE WS-CHECKLIST-YEAR TO FL-YEAR. SAMPS042
00901 MOVE WS-CHECKLIST-QUARTER TO FL-QUARTER. SAMPS042
00902 MOVE WS-SAMPLE-NAME-AREA TO WS-SAMPLE-TYPE. SAMPS042
00903 WRITE CHECK-LIST-REC FROM FL-FIRST-LINE-COLUMN-HEADER SAMPS042
00904 AFTER ADVANCING 2 LINES. SAMPS042
00905 WRITE CHECK-LIST-REC FROM WS-TRANSACTION-TYPE-FIELD SAMPS042
00906 AFTER ADVANCING 1 LINE. SAMPS042
00907 WRITE CHECK-LIST-REC FROM SL-SECOND-LINE-COL-HEADER SAMPS042
00908 AFTER ADVANCING 2 LINES. SAMPS042
00909 WRITE CHECK-LIST-REC FROM TL-THIRD-COLUMN-HEADER SAMPS042
00910 AFTER ADVANCING 1 LINE. SAMPS042
00911 WRITE CHECK-LIST-REC FROM CL-COLUMN-UNDERLINE SAMPS042
00912 AFTER ADVANCING 1 LINE. SAMPS042
00913 MOVE SPACES TO CHECK-LIST-REC. SAMPS042
00914 WRITE CHECK-LIST-REC AFTER ADVANCING 1 LINES. SAMPS042
00915 SAMPS042
00916 0405-CHECKLIST-HEADER-EXIT. SAMPS042
00917 EXIT. SAMPS042
00918 SAMPS042
00919 *************************************************************** SAMPS042
00920 ** 0500-SELECT-RECORDS. ** SAMPS042
00921 ** THIS SECTION WILL READ THE SELECT-FILE WHICH CONTAINS ** SAMPS042
00922 ** THE SELECTED NUMBERS FOR THE SAMPLE. EACH SELECT RECORD ** SAMPS042
00923 ** WILL ALSO BE USED AS THE RECORD KEY TO READ THE SAMPLING ** SAMPS042
00924 ** TRANSACTION VSAM FILE (TRANS-FILE). THE TRANSACTION ** SAMPS042
00925 ** FILE IS INDEXED BY A FIELD (SEQ-NMBR) WHICH IS THE KEY ** SAMPS042
00926 ** USED DURING THE READ OF THE VSAM FILE. THE VALUE OF THE ** SAMPS042
00927 ** SELECT RECORD NUMBER (SL-REC-NUM) IS MOVED TO (SEQ-NMBR) ** SAMPS042
00928 ** AND THE RECORD ON THE TRANSACTION FILE FOR THAT RECORD ** SAMPS042
00929 ** NUMBER IS READ AND PROCESSED. FOR THE RECORDS THAT HAVE ** SAMPS042
00930 ** BEEN SELECTED FROM THE TRANSACTION FILE, THE SELECTED-FLAG** SAMPS042
00931 ** FIELD IS CHANGED TO A 2, AND THE RECORD IS WRITTEN TO THE ** SAMPS042
00932 ** DISK FILE (HIT-FILE). THIS SAME RECORD IS WRITTEN TO A ** SAMPS042
00933 ** HIT FILE LISTING (HIT-LIST) AND A CODING SHEET OUTPUT ** SAMPS042
00934 ** REPORT, (CHECK-LIST). THIS PROCESSING IS CONTINUED UNTIL ** SAMPS042
00935 ** EACH RECORD FROM THE (SELECT-FILE) HAS BEEN READ. ** SAMPS042
00936 *************************************************************** SAMPS042
00937 0500-SELECT-RECORDS. SAMPS042
00938 SAMPS042
00939 READ SELECT-FILE SAMPS042
00940 AT END MOVE 'Y' TO WS-SELECT-EOF. SAMPS042
00941 IF WS-SELECT-EOF = 'Y' SAMPS042
00942 AND MATCH-CNTR NOT EQUAL TO SAMPLED-NMBR SAMPS042
00943 DISPLAY 'RECORDS SELECTED NE TO RECORDS DESIRED' SAMPS042
00944 MOVE MESSAGE-1 TO WS-MESSAGE-FILE SAMPS042
00945 PERFORM 9999-CLOSE-FILES SAMPS042
00946 STOP RUN. SAMPS042
00947 SAMPS042
00948 IF WS-SELECT-EOF = 'Y' SAMPS042
00949 AND MATCH-CNTR EQUAL TO SAMPLED-NMBR SAMPS042
00950 WRITE CHECK-LIST-REC FROM WS-FOOTNOTE-AREA SAMPS042
00951 AFTER ADVANCING 1 LINE SAMPS042
00952 MOVE MESSAGE-1 TO WS-MESSAGE-FILE SAMPS042
00953 PERFORM 9999-CLOSE-FILES SAMPS042
00954 STOP RUN. SAMPS042
00955 SAMPS042
00956 IF WS-SELECT-EOF NOT EQUAL 'Y' SAMPS042
00957 ADD 1 TO MATCH-CNTR SAMPS042
00958 MOVE SL-REC-NUM TO SEQ-NMBR SAMPS042
00959 READ TRANS-FILE RECORD INTO WS-MATCH-RECORD. SAMPS042
00960 IF WS-HIT-LIST-SWITCH = '0' SAMPS042
00961 PERFORM 0400-HIT-LIST-HEADING SAMPS042
00962 THRU 0400-HIT-LIST-EXIT. SAMPS042
00963 IF WS-CHECKLIST-SWITCH = '0' SAMPS042
00964 PERFORM 0405-CHECKLIST-HEADER-RTN SAMPS042
00965 THRU 0405-CHECKLIST-HEADER-EXIT. SAMPS042
00966 PERFORM 0600-PRINT-HIT-RECS SAMPS042
00967 THRU 0600-PRINT-EXIT. SAMPS042
00968 MOVE SELECTED-FLAG TO SELECT-FLAG. SAMPS042
00969 MOVE SELECTED-FLAG TO MATCH-SELECT-FLAG. SAMPS042
00970 REWRITE TRANS-REC. SAMPS042
00971 SAMPS042
00972 0500-SELECT-RECS-EXIT. SAMPS042
00973 EXIT. SAMPS042
00974 SAMPS042
00975 *************************************************************** SAMPS042
00976 ** 0600-PRINT-HIT-RECS. ** SAMPS042
00977 ** THIS ROUTINE MOVES THE INFORMATION REQUIRED TO EACH OF ** SAMPS042
00978 ** OUTPUT FILES; HIT-FILE, HIT-LIST, AND CHECK-LIST. THE ** SAMPS042
00979 ** ROUTINE ALSO CONTROLS LINE COUNT, AND HEADER GENERATION ** SAMPS042
00980 ** FOR THE HIT-LIST, AND CHECK-LIST REPORT. ** SAMPS042
00981 *************************************************************** SAMPS042
00982 0600-PRINT-HIT-RECS. SAMPS042
00983 SAMPS042
00984 MOVE '1' TO WS-CHECKLIST-SWITCH. SAMPS042
00985 MOVE '1' TO WS-HIT-LIST-SWITCH. SAMPS042
00986 MOVE MATCH-CNTR TO DTL-CASE-NO. SAMPS042
00987 MOVE MATCH-SEQ-NMBR TO DTL-SEQ-NMBR. SAMPS042
00988 MOVE MATCH-EMP-ID TO DTL-EMP-ID. SAMPS042
00989 MOVE MATCH-DATE-CREATED TO DTL-DATE-CREATED. SAMPS042
00990 MOVE CNTRL-YEAR-QTR TO WS-PERIOD-DATE. SAMPS042
00991 MOVE WS-CHECKLIST-YEAR TO FL-YEAR. SAMPS042
00992 MOVE WS-CHECKLIST-QUARTER TO FL-QUARTER. SAMPS042
00993 MOVE MATCH-TAX-DUE TO DTL-TAX-DUE. SAMPS042
00994 MOVE MATCH-TAX-PAID TO DTL-TAX-PAID. SAMPS042
00995 MOVE DTL-CREATED-YR TO O-CREATED-YR. SAMPS042
00996 MOVE DTL-CREATED-MO TO O-CREATED-MO. SAMPS042
00997 MOVE DTL-CREATED-DA TO O-CREATED-DA. SAMPS042
00998 MOVE CNTRL-TYPE TO HIT-RECORD-TYPE. SAMPS042
00999 MOVE SESA-ID TO HIT-STATE. SAMPS042
01000 MOVE MATCH-CNTR TO HIT-CASE-NUMBER. SAMPS042
01001 MOVE MATCH-TRANS-TYPE TO HIT-TRANS-TYPE. SAMPS042
01002 MOVE MATCH-EMP-ID TO HIT-EMPLOYER-ID. SAMPS042
01003 MOVE CNTRL-YEAR-QTR TO HIT-SAMPLE-YEAR. SAMPS042
01004 MOVE SAMPLE-TYPE TO HIT-SAMPLE-TYPE. SAMPS042
01005 MOVE MATCH-CNTR TO WS-CASE-HOLD-AREA. SAMPS042
01006 MOVE WS-CASE-HOLD-AREA TO DL-CHECKLIST-CASE-NO. SAMPS042
01007 MOVE MATCH-EMP-ID TO WS-EMPL-HOLD-AREA. SAMPS042
01008 MOVE WS-EMPL-HOLD-AREA TO DL-CHECKLIST-EMP-ID. SAMPS042
01009 ADD 1 TO LIST-COUNTER. SAMPS042
01010 IF LIST-COUNTER > 50 SAMPS042
01011 MOVE 1 TO LIST-COUNTER SAMPS042
01012 PERFORM 0400-HIT-LIST-HEADING SAMPS042
01013 THRU 0400-HIT-LIST-EXIT. SAMPS042
01014 WRITE PRINT-HIT-REC FROM HIT-LIST-REC. SAMPS042
01015 PERFORM 0700-CHECKLIST-ROUTINE SAMPS042
01016 THRU 0700-CHECKLIST-EXIT. SAMPS042
01017 WRITE TRANS-HIT-REC FROM OUTPUT-HIT-REC. SAMPS042
01018 SAMPS042
01019 0600-PRINT-EXIT. SAMPS042
01020 EXIT. SAMPS042
01021 SAMPS042
01022 ******************************************************* SAMPS042
01023 *** *** SAMPS042
01024 ** 0700-CHECKLIST-ROUTINE. ** SAMPS042
01025 ** THIS SECTION CONTROLS THE PROCESSING OF THE ** SAMPS042
01026 ** CHECK-LIST REPORT. ** SAMPS042
01027 *** *** SAMPS042
01028 ******************************************************* SAMPS042
01029 0700-CHECKLIST-ROUTINE. SAMPS042
01030 SAMPS042
01031 ADD 1 TO WS-CHECKLIST-CNTR. SAMPS042
01032 IF WS-CHECKLIST-CNTR > 20 SAMPS042
01033 WRITE CHECK-LIST-REC FROM WS-FOOTNOTE-AREA SAMPS042
01034 AFTER ADVANCING 1 LINE SAMPS042
01035 MOVE 1 TO WS-CHECKLIST-CNTR SAMPS042
01036 PERFORM 0405-CHECKLIST-HEADER-RTN SAMPS042
01037 THRU 0405-CHECKLIST-HEADER-EXIT SAMPS042
01038 ELSE SAMPS042
01039 NEXT SENTENCE. SAMPS042
01040 WRITE CHECK-LIST-REC FROM DL-CHECKLIST-DETAIL SAMPS042
01041 AFTER ADVANCING 1 LINE. SAMPS042
01042 WRITE CHECK-LIST-REC FROM DL-BANNER-LINE SAMPS042
01043 AFTER ADVANCING 1 LINE. SAMPS042
01044 SAMPS042
01045 0700-CHECKLIST-EXIT. SAMPS042
01046 EXIT. SAMPS042
01047 SAMPS042
01048 SAMPS042
01049 *************************************************************** SAMPS042
01050 *** *** SAMPS042
01051 ** 9999-CLOSE-FILES. ** SAMPS042
01052 ** THIS SECTION WRITES AN END OF JOB MESSAGE, AND CLOSES THE ** SAMPS042
01053 ** INPUT FILES: SELECT-FILE, CNTRL-DATA, AND INPUT/OUTPUT ** SAMPS042
01054 ** FILE TRANS-FILE. THE FOLLOWING OUTPUT FILES ARE ALSO ** SAMPS042
01055 ** CLOSED; JOB-STATUS, HIT-FILE, HIT-LIST, CHECK-LIST. ** SAMPS042
01056 *** *** SAMPS042
01057 *************************************************************** SAMPS042
01058 9999-CLOSE-FILES. SAMPS042
01059 SAMPS042
01060 WRITE MESSAGE-RECORD FROM WS-EOJ-DETAIL-LINE. SAMPS042
01061 CLOSE SELECT-FILE SAMPS042
01062 CLOSE CNTRL-DATA SAMPS042
01063 CLOSE TRANS-FILE SAMPS042
01064 CLOSE JOB-STATUS SAMPS042
01065 CLOSE HIT-FILE SAMPS042
01066 CLOSE HIT-LIST SAMPS042
01067 CLOSE CHECK-LIST. SAMPS042
01068 SAMPS042
01069 9999-CLOSE-EXIT. SAMPS042
01070 EXIT. SAMPS042
Reference in New Issue View Git Blame Copy Permalink