616 lines
49 KiB
COBOL
616 lines
49 KiB
COBOL
00001 IDENTIFICATION DIVISION. 05/22/01
|
|
00002 PROGRAM-ID. TDECVAL1. TDECVALX
|
|
00003 LV001
|
|
00004 ******************************************************************TDECVALX
|
|
00005 * *TDECVALX
|
|
00006 * FUNCTION: *TDECVALX
|
|
00007 * THE FUNCTION OF TDECVAL IS TO VALIDATE THE *TDECVALX
|
|
00008 * WAGE RECORD DATA THAT IS TRANSMITTED FROM THE TDEC COMPANY*TDECVALX
|
|
00009 * *TDECVALX
|
|
00010 ******************************************************************TDECVALX
|
|
00011 ******************************************************************TDECVALX
|
|
00012 * MODIFICATION HISTORY: *TDECVALX
|
|
00013 * *TDECVALX
|
|
00014 * 04-13-2001 MODIFIED TO INTERFACE WITH TAPE TRACKING SYSTEM *TDECVALX
|
|
00015 * THROUGH DESBD200. *TDECVALX
|
|
00016 * MODIFIED OUTPUT RECORD: FIRST DATA ELEMENT IS THE *TDECVALX
|
|
00017 * LOG NUMBER FOR THE TRAKING SYSTEM. *TDECVALX
|
|
00018 * *TDECVALX
|
|
00019 * REFERENCE RFP # AUTHOR OF CHANGE - GD *TDECVALX
|
|
00020 * *TDECVALX
|
|
00021 * 05-16-2001 MODIFIED TO OUTPUT A CLEAN TDEVOUT DISK FILE. I.E., *TDECVALX
|
|
00022 * WITHOUT THE EXCPTION RECORDS. *TDECVALX
|
|
00023 * REFERENCE RFP # AUTHOR OF CHANGE - RW *TDECVALX
|
|
00024 * *TDECVALX
|
|
00025 * MM-DD-YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *TDECVALX
|
|
00026 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *TDECVALX
|
|
00027 * REFERENCE RFP #**** AUTHOR OF CHANGE - *** *TDECVALX
|
|
00028 ******************************************************************TDECVALX
|
|
00029 TDECVALX
|
|
00030 ENVIRONMENT DIVISION. TDECVALX
|
|
00031 TDECVALX
|
|
00032 CONFIGURATION SECTION. TDECVALX
|
|
00033 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. TDECVALX
|
|
00034 TDECVALX
|
|
00035 INPUT-OUTPUT SECTION. TDECVALX
|
|
00036 FILE-CONTROL. TDECVALX
|
|
00037 SELECT TDECFILE ASSIGN TO TDECFILE. TDECVALX
|
|
00038 SELECT TDECOUT ASSIGN TO TDECOUT. TDECVALX
|
|
00039 SELECT LISTOUT ASSIGN TO UR-S-LISTOUT. TDECVALX
|
|
00040 TDECVALX
|
|
00041 DATA DIVISION. TDECVALX
|
|
00042 FILE SECTION. TDECVALX
|
|
00043 TDECVALX
|
|
00044 FD TDECFILE TDECVALX
|
|
00045 RECORDING MODE IS F TDECVALX
|
|
00046 BLOCK CONTAINS 0 CHARACTERS TDECVALX
|
|
00047 LABEL RECORDS ARE STANDARD TDECVALX
|
|
00048 DATA RECORD IS TDECREC. TDECVALX
|
|
00049 01 TRANSACTION-RECORD PIC X(80). TDECVALX
|
|
00050 TDECVALX
|
|
00051 FD TDECOUT TDECVALX
|
|
00052 RECORDING MODE IS F TDECVALX
|
|
00053 BLOCK CONTAINS 0 CHARACTERS TDECVALX
|
|
00054 LABEL RECORDS ARE STANDARD TDECVALX
|
|
00055 DATA RECORD IS TDECOUT-REC. TDECVALX
|
|
00056 01 TDECOUT-REC PIC X(90). TDECVALX
|
|
00057 TDECVALX
|
|
00058 FD LISTOUT TDECVALX
|
|
00059 RECORD CONTAINS 133 CHARACTERS TDECVALX
|
|
00060 LABEL RECORDS ARE OMITTED TDECVALX
|
|
00061 RECORDING MODE IS F TDECVALX
|
|
00062 DATA RECORD IS PRINT-REC. TDECVALX
|
|
00063 01 PRINT-REC PIC X(133). TDECVALX
|
|
00064 TDECVALX
|
|
00065 WORKING-STORAGE SECTION. TDECVALX
|
|
000655 77 PAN-VALET PICTURE X(24) VALUE '001TDECVALX 05/22/01'. TDECVALX
|
|
00066 TDECVALX
|
|
00067 01 WRK-AREA. TDECVALX
|
|
00068 05 ABEND-CD PIC X(05) VALUE 'TVAL1'. TDECVALX
|
|
00069 05 ABEND-MOD PIC X(08) VALUE 'DTSBU999'. TDECVALX
|
|
00070 05 ABEND-MSG PIC X(60). TDECVALX
|
|
00071 05 WRK-MOD-NAME PIC X(08) VALUE 'TDECVAL1'. TDECVALX
|
|
00072 05 WRK-LOG-NO PIC 9(10) VALUE 0. TDECVALX
|
|
00073 05 ERROR-SW PIC 9. TDECVALX
|
|
00074 TDECVALX
|
|
00075 01 WS-QUARTER-YR-QTR PIC 9(05). TDECVALX
|
|
00076 01 FILLER REDEFINES WS-QUARTER-YR-QTR. TDECVALX
|
|
00077 05 WS-QUARTER-YEAR PIC 9(4). TDECVALX
|
|
00078 05 WS-QUARTER-QTR PIC 9(1). TDECVALX
|
|
00079 TDECVALX
|
|
00080 01 L004-LINK-AREA. TDECVALX
|
|
00081 ++INCLUDE DTSIL004 TDECVALX
|
|
00082 EJECT TDECVALX
|
|
00083 TDECVALX
|
|
00084 01 WS-WAGE-ACCOUNT PIC 9(06). TDECVALX
|
|
00085 TDECVALX
|
|
00086 01 WS-CURR-EMP PIC 9(06) VALUE ZERO. TDECVALX
|
|
00087 01 WS-EMP-TOT-CNT PIC S9(07) COMP-3 VALUE +0. TDECVALX
|
|
00088 01 WS-EMP-SUCCESS-CNT PIC S9(07) COMP-3 VALUE +0. TDECVALX
|
|
00089 TDECVALX
|
|
00090 01 L200-LINK-AREA. TDECVALX
|
|
00091 ++INCLUDE DESIL200 TDECVALX
|
|
00092 TDECVALX
|
|
00093 01 C202-MSG-TABLE. TDECVALX
|
|
00094 ++INCLUDE DTSIC202 TDECVALX
|
|
00095 TDECVALX
|
|
00096 01 WS-ETA-EMP-NAME-FOUR PIC X(4). TDECVALX
|
|
00097 TDECVALX
|
|
00098 01 TDECOUT-WORK-AREA. TDECVALX
|
|
00099 ******************************************************************TDECVALX
|
|
00100 * TDEC-OUTPUT TRANSACTION RECORD AREA *TDECVALX
|
|
00101 ******************************************************************TDECVALX
|
|
00102 05 WRK-TRANSACTION-AREA. TDECVALX
|
|
00103 10 WRK-TRAN-LOG-NO PIC 9(10) VALUE 0. TDECVALX
|
|
00104 10 WRK-TRAN-AREA PIC X(80) VALUE SPACES. TDECVALX
|
|
00105 TDECVALX
|
|
00106 01 TRANSACTION-WORK-AREA. TDECVALX
|
|
00107 ******************************************************************TDECVALX
|
|
00108 * ESP TRANSACTION RECORD DESCRIPTIONS *TDECVALX
|
|
00109 ******************************************************************TDECVALX
|
|
00110 05 ESP-TRANSACTION-AREA. TDECVALX
|
|
00111 10 TRAN-SSN PIC 9(10). TDECVALX
|
|
00112 10 FILLER REDEFINES TRAN-SSN. TDECVALX
|
|
00113 15 TR-SSN PIC 9(9). TDECVALX
|
|
00114 15 TR-SSN-SEQ PIC 9(1). TDECVALX
|
|
00115 10 TRAN-ID PIC X(02). TDECVALX
|
|
00116 10 FILLER REDEFINES TRAN-ID. TDECVALX
|
|
00117 15 TRAN-ID-PFX PIC X(1). TDECVALX
|
|
00118 88 TRAN-ID-PFX-WAGE VALUE 'W'. TDECVALX
|
|
00119 15 FILLER PIC X(1). TDECVALX
|
|
00120 10 TRAN-OPER-ID PIC 9(8). TDECVALX
|
|
00121 10 FILLER REDEFINES TRAN-OPER-ID. TDECVALX
|
|
00122 15 BATCH-NUMBER PIC 9(03). TDECVALX
|
|
00123 15 FILLER REDEFINES BATCH-NUMBER. TDECVALX
|
|
00124 20 BATCH-NUMBER-NN PIC 9(02). TDECVALX
|
|
00125 20 FILLER PIC X(01). TDECVALX
|
|
00126 15 TRAN-LOCAL-OFFICE PIC 9(02). TDECVALX
|
|
00127 15 TRAN-OPERATOR-ID PIC 9(03). TDECVALX
|
|
00128 10 TRAN-DATE-ENTERED PIC 9(08). TDECVALX
|
|
00129 10 TRAN-TIME-ENTERED PIC 9(06). TDECVALX
|
|
00130 10 FILLER PIC 9(06). TDECVALX
|
|
00131 10 TRAN-NAME-CHECK PIC X(3). TDECVALX
|
|
00132 10 TRAN-QUARTER-YR-QTR PIC 9(5). TDECVALX
|
|
00133 10 TRAN-AFFI-CODE PIC 9(1). TDECVALX
|
|
00134 10 TRAN-QUARTER-EARNINGS PIC 9(7). TDECVALX
|
|
00135 10 TRAN-ACCOUNT PIC 9(6). TDECVALX
|
|
00136 10 TRAN-EMP-NAME PIC X(4). TDECVALX
|
|
00137 10 TRAN-FILLER PIC X(299). TDECVALX
|
|
00138 TDECVALX
|
|
00139 01 COUNTERS. TDECVALX
|
|
00140 03 EMP-QTR-TOT-EARNINGS PIC 9(7). TDECVALX
|
|
00141 03 RECS-IN PIC 9(5). TDECVALX
|
|
00142 03 RECS-OUT PIC 9(5). TDECVALX
|
|
00143 03 QTR-RECS-OUT PIC 9(5). TDECVALX
|
|
00144 03 PAGE-CTR PIC 9(5). TDECVALX
|
|
00145 03 ERROR-RECS PIC 9(5). TDECVALX
|
|
00146 03 WS-RUN-DATE. TDECVALX
|
|
00147 05 RUN-YR PIC 99. TDECVALX
|
|
00148 05 RUN-MO PIC 99. TDECVALX
|
|
00149 05 RUN-DA PIC 99. TDECVALX
|
|
00150 TDECVALX
|
|
00151 03 ZERO-WAGE-CNT PIC 9(5). TDECVALX
|
|
00152 03 EXCEPTION-CNT PIC 9(5). TDECVALX
|
|
00153 03 WS-ZERO-WAGE-NO PIC 9(5). TDECVALX
|
|
00154 TDECVALX
|
|
00155 TDECVALX
|
|
00156 01 LINE-CTR PIC 9(5) VALUE 56. TDECVALX
|
|
00157 01 EOF PIC X. TDECVALX
|
|
00158 TDECVALX
|
|
00159 01 SELECT-CARD. TDECVALX
|
|
00160 03 PGM-NAME PIC X(09) VALUE '**TDECVAL'. TDECVALX
|
|
00161 03 FIL PIC XX. TDECVALX
|
|
00162 03 SELECT-QUARTER PIC 9(5). TDECVALX
|
|
00163 03 FIL PIC X. TDECVALX
|
|
00164 03 SELECT-QUARTER1 PIC 9(5). TDECVALX
|
|
00165 03 FIL PIC X(73). TDECVALX
|
|
00166 TDECVALX
|
|
00167 01 HD1. TDECVALX
|
|
00168 03 FIL PIC X(5) VALUE SPACES. TDECVALX
|
|
00169 03 FIL PIC X(8) VALUE 'TDECVAL1'. TDECVALX
|
|
00170 03 FIL PIC X(31) VALUE SPACES. TDECVALX
|
|
00171 03 FIL PIC X(42) VALUE TDECVALX
|
|
00172 'DISTRICT DEPARTMENT OF EMPLOYMENT SERVICES'. TDECVALX
|
|
00173 03 FIL PIC X(35) VALUE SPACES. TDECVALX
|
|
00174 03 FIL PIC X(5) VALUE 'PAGE:'. TDECVALX
|
|
00175 03 PAGE-CTR-PRT PIC ZZ,ZZ9. TDECVALX
|
|
00176 TDECVALX
|
|
00177 01 HD2. TDECVALX
|
|
00178 03 FIL PIC X(49) VALUE SPACES. TDECVALX
|
|
00179 03 FIL PIC X(39) VALUE TDECVALX
|
|
00180 'DOES UI WAGE RECORD EDIT REPORT'. TDECVALX
|
|
00181 TDECVALX
|
|
00182 01 HD3. TDECVALX
|
|
00183 03 FIL PIC X(55) VALUE SPACES. TDECVALX
|
|
00184 03 FIL PIC X(10) VALUE 'RUN DATE: '. TDECVALX
|
|
00185 03 RUN-DATE. TDECVALX
|
|
00186 05 RUN-MO1 PIC 99. TDECVALX
|
|
00187 05 FIL PIC X VALUE '/'. TDECVALX
|
|
00188 05 RUN-DA1 PIC 99. TDECVALX
|
|
00189 05 FIL PIC X VALUE '/'. TDECVALX
|
|
00190 05 RUN-CEN PIC 99. TDECVALX
|
|
00191 05 RUN-YR1 PIC 99. TDECVALX
|
|
00192 TDECVALX
|
|
00193 01 HD4. TDECVALX
|
|
00194 03 FIL PIC X(5) VALUE SPACES. TDECVALX
|
|
00195 03 FIL PIC X(3) VALUE 'SSN'. TDECVALX
|
|
00196 03 FIL PIC X(7) VALUE SPACES. TDECVALX
|
|
00197 03 FIL PIC X(12) VALUE 'DATE ENTERED'. TDECVALX
|
|
00198 03 FIL PIC X(02) VALUE SPACES. TDECVALX
|
|
00199 03 FIL PIC X(13) VALUE 'EMPLOYEE NAME'. TDECVALX
|
|
00200 03 FIL PIC X(2) VALUE SPACES. TDECVALX
|
|
00201 03 FIL PIC X(7) VALUE 'QUARTER'. TDECVALX
|
|
00202 03 FIL PIC X(6) VALUE SPACES. TDECVALX
|
|
00203 03 FIL PIC X(8) VALUE 'EARNINGS'. TDECVALX
|
|
00204 03 FIL PIC X(6) VALUE SPACES. TDECVALX
|
|
00205 03 FIL PIC X(14) VALUE 'ACCOUNT NUMBER'. TDECVALX
|
|
00206 03 FIL PIC X(2) VALUE SPACES. TDECVALX
|
|
00207 03 FIL PIC X(11) VALUE ' TDEC NAME'. TDECVALX
|
|
00208 03 FIL PIC X(05) VALUE SPACES. TDECVALX
|
|
00209 03 FIL PIC X(18) VALUE 'ERRORS ENCOUNTERED'. TDECVALX
|
|
00210 TDECVALX
|
|
00211 01 DTL1. TDECVALX
|
|
00212 03 FIL PIC X(5) VALUE SPACES. TDECVALX
|
|
00213 03 SSN-PRT PIC X(9). TDECVALX
|
|
00214 03 FIL PIC X(04) VALUE SPACES. TDECVALX
|
|
00215 03 DATE-ENTERED-PRT PIC X(06). TDECVALX
|
|
00216 03 FIL PIC X(10) VALUE SPACES. TDECVALX
|
|
00217 03 EMPEE-NAME PIC X(3). TDECVALX
|
|
00218 03 FIL PIC X(08) VALUE SPACES. TDECVALX
|
|
00219 03 QTR-PRT PIC X(5). TDECVALX
|
|
00220 03 FIL PIC X(08) VALUE SPACES. TDECVALX
|
|
00221 03 EARNINGS-PRT PIC X(7). TDECVALX
|
|
00222 03 FIL PIC X(10) VALUE SPACES. TDECVALX
|
|
00223 03 ACCT-NUM-PRT PIC X(6). TDECVALX
|
|
00224 03 FIL PIC X(10) VALUE SPACES. TDECVALX
|
|
00225 03 EMPOR-PRT PIC X(6). TDECVALX
|
|
00226 03 FIL PIC X(06) VALUE SPACES. TDECVALX
|
|
00227 03 MESSAGE-AREA PIC X(30) VALUE SPACES. TDECVALX
|
|
00228 TDECVALX
|
|
00229 01 TOT1. TDECVALX
|
|
00230 03 FIL PIC X(2) VALUE SPACES. TDECVALX
|
|
00231 03 FIL PIC X(21) VALUE 'TOTAL WAGE RECS READ:'. TDECVALX
|
|
00232 03 WAGE-CNT-PRT PIC ZZZ,ZZ9. TDECVALX
|
|
00233 03 FIL PIC X(6) VALUE SPACES. TDECVALX
|
|
00234 03 FIL PIC X(24) VALUE 'TOTAL WAGE RECS WRITTEN:'.TDECVALX
|
|
00235 03 WAGE-OUT-PRT PIC ZZZ,ZZ9. TDECVALX
|
|
00236 03 FIL PIC X(6) VALUE SPACES. TDECVALX
|
|
00237 03 FIL PIC X(20) VALUE 'TOTAL ERROR RECORDS:'. TDECVALX
|
|
00238 03 ERRORS-PRT PIC ZZ,ZZ9. TDECVALX
|
|
00239 03 FIL PIC X(6) VALUE SPACES. TDECVALX
|
|
00240 03 FIL PIC X(20) VALUE 'TOTAL ZERO WAGR REC:'. TDECVALX
|
|
00241 03 ZERO-WAGE-PRT PIC ZZ,ZZ9. TDECVALX
|
|
00242 TDECVALX
|
|
00243 01 BLANK-LINE PIC X(133) VALUE SPACES. TDECVALX
|
|
00244 TDECVALX
|
|
00245 01 EMPLOYER-STATUS-RECORD-DATA. TDECVALX
|
|
00246 ++INCLUDE ESPTAXAD TDECVALX
|
|
00247 ++INCLUDE ESPSCSWA TDECVALX
|
|
00248 ++INCLUDE WSDATES TDECVALX
|
|
00249 TDECVALX
|
|
00250 LINKAGE SECTION. TDECVALX
|
|
00251 01 PARM-AREA. TDECVALX
|
|
00252 05 PARM-LENGTH PIC S9(04) COMP. TDECVALX
|
|
00253 05 PARM-LOG-NO PIC 9(06). TDECVALX
|
|
00254 05 FILLER PIC X(01). TDECVALX
|
|
00255 05 PARM-ZERO-WAGE-NO PIC 9(05). TDECVALX
|
|
00256 TDECVALX
|
|
00257 PROCEDURE DIVISION USING PARM-AREA. TDECVALX
|
|
00258 TDECVALX
|
|
00259 ** READY TRACE. TDECVALX
|
|
00260 ACCEPT SELECT-CARD. TDECVALX
|
|
00261 ++INCLUDE CODEDATE TDECVALX
|
|
00262 MOVE WS-SYSTEM-DATE TO WS-RUN-DATE. TDECVALX
|
|
00263 MOVE RUN-DA TO RUN-DA1 TDECVALX
|
|
00264 MOVE RUN-MO TO RUN-MO1 TDECVALX
|
|
00265 MOVE 20 TO RUN-CEN TDECVALX
|
|
00266 MOVE RUN-YR TO RUN-YR1 TDECVALX
|
|
00267 TDECVALX
|
|
00268 OPEN INPUT TDECFILE TDECVALX
|
|
00269 OUTPUT LISTOUT TDECOUT. TDECVALX
|
|
00270 TDECVALX
|
|
00271 MOVE ZEROS TO COUNTERS. TDECVALX
|
|
00272 TDECVALX
|
|
00273 PERFORM INIT0100-EDIT-PARMS THRU INIT0100-EXIT. TDECVALX
|
|
00274 TDECVALX
|
|
00275 MOVE 'Y' TO CSV-TAX-FILE-FLAG. TDECVALX
|
|
00276 PERFORM 100-READ-WAGE THRU 100-RW-EXIT TDECVALX
|
|
00277 UNTIL TDECVALX
|
|
00278 EOF = 1. TDECVALX
|
|
00279 TDECVALX
|
|
00280 INIT0100-EDIT-PARMS. TDECVALX
|
|
00281 TDECVALX
|
|
00282 IF PARM-LOG-NO NOT NUMERIC TDECVALX
|
|
00283 MOVE 'PARM-LOG-NO IS NOT NUMERIC ' TO ABEND-MSG TDECVALX
|
|
00284 PERFORM SERV9999-ABEND THRU SERV9999-EXIT. TDECVALX
|
|
00285 TDECVALX
|
|
00286 DISPLAY 'PARM-LOG-NO = ' PARM-LOG-NO. TDECVALX
|
|
00287 TDECVALX
|
|
00288 IF PARM-ZERO-WAGE-NO NOT NUMERIC TDECVALX
|
|
00289 MOVE 'PARM-ZERO-WAGE-NO IS NOT NUMERIC ' TO ABEND-MSG TDECVALX
|
|
00290 PERFORM SERV9999-ABEND THRU SERV9999-EXIT. TDECVALX
|
|
00291 TDECVALX
|
|
00292 MOVE PARM-ZERO-WAGE-NO TO WS-ZERO-WAGE-NO. TDECVALX
|
|
00293 DISPLAY 'PARM-ZERO-WAGE-NO = ' WS-ZERO-WAGE-NO. TDECVALX
|
|
00294 TDECVALX
|
|
00295 SET L200-CMD-INIT-88 TO TRUE. TDECVALX
|
|
00296 MOVE PARM-LOG-NO TO L200-LOG-NO-SFX. TDECVALX
|
|
00297 MOVE WRK-MOD-NAME TO L200-PROG-NAME. TDECVALX
|
|
00298 CALL 'DESBD200' USING L200-LINK-AREA C202-MSG-TABLE. TDECVALX
|
|
00299 MOVE L200-LOG-NO TO WRK-LOG-NO. TDECVALX
|
|
00300 TDECVALX
|
|
00301 DISPLAY 'WRK-LOG-NO = ' WRK-LOG-NO. TDECVALX
|
|
00302 TDECVALX
|
|
00303 INIT0100-EXIT. TDECVALX
|
|
00304 EXIT. TDECVALX
|
|
00305 TDECVALX
|
|
00306 100-READ-WAGE. TDECVALX
|
|
00307 READ TDECFILE INTO ESP-TRANSACTION-AREA TDECVALX
|
|
00308 AT END TDECVALX
|
|
00309 MOVE 1 TO EOF TDECVALX
|
|
00310 TDECVALX
|
|
00311 IF WS-EMP-TOT-CNT > ZERO TDECVALX
|
|
00312 MOVE WS-CURR-EMP TO L200-EMP-NO TDECVALX
|
|
00313 MOVE WS-QUARTER-YR-QTR TO L200-REPORTING-DATE TDECVALX
|
|
00314 MOVE WS-EMP-TOT-CNT TO L200-TOT-CNT TDECVALX
|
|
00315 MOVE WS-EMP-SUCCESS-CNT TO L200-SUCCESS-CNT TDECVALX
|
|
00316 ELSE TDECVALX
|
|
00317 MOVE ZERO TO L200-EMP-NO TDECVALX
|
|
00318 L200-TOT-CNT TDECVALX
|
|
00319 L200-SUCCESS-CNT TDECVALX
|
|
00320 END-IF TDECVALX
|
|
00321 TDECVALX
|
|
00322 SET L200-CMD-TERMINATE-88 TO TRUE TDECVALX
|
|
00323 PERFORM SERV0200-UPD-LOG THRU SERV0200-EXIT. TDECVALX
|
|
00324 TDECVALX
|
|
00325 IF EOF = 1 TDECVALX
|
|
00326 GO TO 999-CLOSE-FILES. TDECVALX
|
|
00327 TDECVALX
|
|
00328 **TO BYPASS WAGE REPORTS PRINTED FROM THE OLD TAX M/F TDECVALX
|
|
00329 TDECVALX
|
|
00330 IF TRAN-QUARTER-YR-QTR < 19994 TDECVALX
|
|
00331 ** ADD 1 TO RECS-IN TDECVALX
|
|
00332 GO TO 100-READ-WAGE. TDECVALX
|
|
00333 TDECVALX
|
|
00334 ADD 1 TO RECS-IN. TDECVALX
|
|
00335 TDECVALX
|
|
00336 INSPECT TRAN-QUARTER-EARNINGS REPLACING TDECVALX
|
|
00337 LEADING ' ' BY ZERO. TDECVALX
|
|
00338 TDECVALX
|
|
00339 IF TRAN-QUARTER-EARNINGS = ZEROS TDECVALX
|
|
00340 IF WS-ZERO-WAGE-NO = EXCEPTION-CNT TDECVALX
|
|
00341 ADD 1 TO ZERO-WAGE-CNT TDECVALX
|
|
00342 GO TO 100-READ-WAGE TDECVALX
|
|
00343 ELSE TDECVALX
|
|
00344 MOVE 'GROSS-WAGE EQUAL ZEROS' TO MESSAGE-AREA TDECVALX
|
|
00345 ADD 1 TO ZERO-WAGE-CNT TDECVALX
|
|
00346 ADD 1 TO EXCEPTION-CNT TDECVALX
|
|
00347 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00348 SET EMSG106-SELECTED-YES TO TRUE TDECVALX
|
|
00349 MOVE ZERO TO ERROR-SW TDECVALX
|
|
00350 GO TO 100-RW-EXIT. TDECVALX
|
|
00351 TDECVALX
|
|
00352 MOVE TRAN-ACCOUNT TO WS-WAGE-ACCOUNT. TDECVALX
|
|
00353 TDECVALX
|
|
00354 IF WS-WAGE-ACCOUNT NOT NUMERIC TDECVALX
|
|
00355 MOVE ZEROS TO WS-WAGE-ACCOUNT TDECVALX
|
|
00356 ELSE TDECVALX
|
|
00357 IF WS-CURR-EMP = ZERO TDECVALX
|
|
00358 MOVE WS-WAGE-ACCOUNT TO WS-CURR-EMP TDECVALX
|
|
00359 MOVE +1 TO WS-EMP-TOT-CNT TDECVALX
|
|
00360 MOVE ZERO TO WS-EMP-SUCCESS-CNT TDECVALX
|
|
00361 ELSE TDECVALX
|
|
00362 IF WS-WAGE-ACCOUNT NOT = WS-CURR-EMP TDECVALX
|
|
00363 SET L200-CMD-EMP-COMPLETE-88 TO TRUE TDECVALX
|
|
00364 MOVE WS-CURR-EMP TO L200-EMP-NO TDECVALX
|
|
00365 MOVE WS-QUARTER-YR-QTR TO L200-REPORTING-DATE TDECVALX
|
|
00366 MOVE WS-EMP-TOT-CNT TO L200-TOT-CNT TDECVALX
|
|
00367 MOVE WS-EMP-SUCCESS-CNT TO L200-SUCCESS-CNT TDECVALX
|
|
00368 PERFORM SERV0200-UPD-LOG THRU SERV0200-EXIT TDECVALX
|
|
00369 MOVE +1 TO WS-EMP-TOT-CNT TDECVALX
|
|
00370 MOVE ZERO TO WS-EMP-SUCCESS-CNT TDECVALX
|
|
00371 MOVE WS-WAGE-ACCOUNT TO WS-CURR-EMP TDECVALX
|
|
00372 ELSE TDECVALX
|
|
00373 ADD +1 TO WS-EMP-TOT-CNT TDECVALX
|
|
00374 END-IF TDECVALX
|
|
00375 END-IF TDECVALX
|
|
00376 END-IF. TDECVALX
|
|
00377 TDECVALX
|
|
00378 PERFORM 110-VALIDATE-WAGE THRU 121-VW-EXIT. TDECVALX
|
|
00379 TDECVALX
|
|
00380 IF ERROR-SW = 1 TDECVALX
|
|
00381 MOVE ZERO TO ERROR-SW TDECVALX
|
|
00382 GO TO 100-RW-EXIT TDECVALX
|
|
00383 ELSE TDECVALX
|
|
00384 MOVE ZERO TO ERROR-SW. TDECVALX
|
|
00385 TDECVALX
|
|
00386 PERFORM 220-CREATE-W4-TRAN THRU 220-CW-EXIT. TDECVALX
|
|
00387 TDECVALX
|
|
00388 100-RW-EXIT. TDECVALX
|
|
00389 EXIT. TDECVALX
|
|
00390 TDECVALX
|
|
00391 110-VALIDATE-WAGE. TDECVALX
|
|
00392 TDECVALX
|
|
00393 MOVE SPACES TO MESSAGE-AREA. TDECVALX
|
|
00394 TDECVALX
|
|
00395 111-VALIDATE-SSN. TDECVALX
|
|
00396 IF TR-SSN NOT NUMERIC TDECVALX
|
|
00397 OR (TR-SSN NOT GREATER THAN ZEROES) TDECVALX
|
|
00398 MOVE 'SSN NOT NUMERIC ' TO MESSAGE-AREA TDECVALX
|
|
00399 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00400 MOVE 1 TO ERROR-SW TDECVALX
|
|
00401 SET EMSG104-SELECTED-YES TO TRUE TDECVALX
|
|
00402 GO TO 121-VW-EXIT. TDECVALX
|
|
00403 TDECVALX
|
|
00404 112-VALIDATE-ID. TDECVALX
|
|
00405 IF TRAN-ID NOT = 'W4' TDECVALX
|
|
00406 MOVE 'TRAN-ID ERROR' TO MESSAGE-AREA TDECVALX
|
|
00407 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00408 MOVE 1 TO ERROR-SW TDECVALX
|
|
00409 SET EMSG112-SELECTED-YES TO TRUE. TDECVALX
|
|
00410 TDECVALX
|
|
00411 113-VALIDATE-DATE. TDECVALX
|
|
00412 IF TRAN-DATE-ENTERED NOT NUMERIC TDECVALX
|
|
00413 MOVE 'DATE ENTERED ERROR' TO MESSAGE-AREA TDECVALX
|
|
00414 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00415 MOVE 1 TO ERROR-SW TDECVALX
|
|
00416 SET EMSG113-SELECTED-YES TO TRUE. TDECVALX
|
|
00417 TDECVALX
|
|
00418 114-VALIDATE-TIME. TDECVALX
|
|
00419 IF TRAN-TIME-ENTERED NOT NUMERIC TDECVALX
|
|
00420 MOVE 'TIME-ENTERED ERROR' TO MESSAGE-AREA TDECVALX
|
|
00421 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00422 MOVE 1 TO ERROR-SW TDECVALX
|
|
00423 SET EMSG114-SELECTED-YES TO TRUE. TDECVALX
|
|
00424 TDECVALX
|
|
00425 115-VALIDATE-NAME. TDECVALX
|
|
00426 IF TRAN-NAME-CHECK EQUAL SPACES TDECVALX
|
|
00427 MOVE 'EMPLOYEE NAME IS SPACES' TO MESSAGE-AREA TDECVALX
|
|
00428 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00429 MOVE 1 TO ERROR-SW TDECVALX
|
|
00430 SET EMSG107-SELECTED-YES TO TRUE. TDECVALX
|
|
00431 TDECVALX
|
|
00432 116-VALIDATE-QUARTER1. TDECVALX
|
|
00433 IF TRAN-QUARTER-YR-QTR NOT NUMERIC TDECVALX
|
|
00434 MOVE 'QUARTER FIELD NOT VALID' TO MESSAGE-AREA TDECVALX
|
|
00435 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00436 MOVE 1 TO ERROR-SW TDECVALX
|
|
00437 SET EMSG101-SELECTED-YES TO TRUE TDECVALX
|
|
00438 GO TO 118-QUARTER-EARNINGS-CHECK. TDECVALX
|
|
00439 TDECVALX
|
|
00440 IF SELECT-QUARTER EQUAL 'ALL' TDECVALX
|
|
00441 GO TO 118-QUARTER-EARNINGS-CHECK. TDECVALX
|
|
00442 TDECVALX
|
|
00443 117-VALIDATE-QUARTER2. TDECVALX
|
|
00444 IF TRAN-QUARTER-YR-QTR EQUAL SELECT-QUARTER TDECVALX
|
|
00445 OR TDECVALX
|
|
00446 SELECT-QUARTER1 TDECVALX
|
|
00447 MOVE TRAN-QUARTER-YR-QTR TO WS-QUARTER-YR-QTR TDECVALX
|
|
00448 ELSE TDECVALX
|
|
00449 MOVE 'QUARTER FIELD NOT VALID' TO MESSAGE-AREA TDECVALX
|
|
00450 MOVE 1 TO ERROR-SW TDECVALX
|
|
00451 SET EMSG101-SELECTED-YES TO TRUE TDECVALX
|
|
00452 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT. TDECVALX
|
|
00453 TDECVALX
|
|
00454 118-QUARTER-EARNINGS-CHECK. TDECVALX
|
|
00455 IF TRAN-QUARTER-EARNINGS NOT NUMERIC TDECVALX
|
|
00456 MOVE 'QUARTER EARNINGS NOT NUMERIC' TO MESSAGE-AREA TDECVALX
|
|
00457 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00458 MOVE 1 TO ERROR-SW TDECVALX
|
|
00459 SET EMSG105-SELECTED-YES TO TRUE TDECVALX
|
|
00460 GO TO 121-VW-EXIT. TDECVALX
|
|
00461 TDECVALX
|
|
00462 119-TRAN-ACCOUNT1. TDECVALX
|
|
00463 IF TRAN-ACCOUNT NOT NUMERIC TDECVALX
|
|
00464 MOVE 'ACCOUNT NUMBER NOT NUMERIC' TO MESSAGE-AREA TDECVALX
|
|
00465 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00466 MOVE 1 TO ERROR-SW TDECVALX
|
|
00467 SET EMSG108-SELECTED-YES TO TRUE TDECVALX
|
|
00468 * GO TO 120-TRAN-EMP-NAME. TDECVALX
|
|
00469 GO TO 121-VW-EXIT. TDECVALX
|
|
00470 TDECVALX
|
|
00471 IF TRAN-ACCOUNT EQUAL ZEROS TDECVALX
|
|
00472 MOVE 'ACCOUNT NUMBER EQUAL ZEROS' TO MESSAGE-AREA TDECVALX
|
|
00473 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00474 MOVE 1 TO ERROR-SW TDECVALX
|
|
00475 SET EMSG109-SELECTED-YES TO TRUE TDECVALX
|
|
00476 * GO TO 120-TRAN-EMP-NAME. TDECVALX
|
|
00477 GO TO 121-VW-EXIT. TDECVALX
|
|
00478 TDECVALX
|
|
00479 119-TRAN-ACCOUNT2. TDECVALX
|
|
00480 MOVE TRAN-ACCOUNT TO ETA-EMP-ACCT-NO. TDECVALX
|
|
00481 PERFORM SERV3000-ACCESS-TAX THRU SERV3000-EXIT. TDECVALX
|
|
00482 * IF NOT ETA-NO-RECORD-FOUND TDECVALX
|
|
00483 IF ETA-IO-COMPLETE TDECVALX
|
|
00484 GO TO 120-TRAN-EMP-NAME TDECVALX
|
|
00485 ELSE TDECVALX
|
|
00486 *** DISPLAY 'ACCOUNT # INVALID KEY ' EMPL-ACCT-NO TDECVALX
|
|
00487 MOVE 'ACCOUNT NUMBER NOT ON M/F ' TO MESSAGE-AREA TDECVALX
|
|
00488 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00489 MOVE 1 TO ERROR-SW TDECVALX
|
|
00490 SET EMSG109-SELECTED-YES TO TRUE TDECVALX
|
|
00491 GO TO 121-VW-EXIT. TDECVALX
|
|
00492 TDECVALX
|
|
00493 120-TRAN-EMP-NAME. TDECVALX
|
|
00494 MOVE ETA-EMP-NAME TO WS-ETA-EMP-NAME-FOUR. TDECVALX
|
|
00495 IF TRAN-EMP-NAME EQUAL SPACES TDECVALX
|
|
00496 MOVE 'EMPLOYER NAME EQUAL SPACES' TO MESSAGE-AREA TDECVALX
|
|
00497 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00498 MOVE 1 TO ERROR-SW TDECVALX
|
|
00499 SET EMSG110-SELECTED-YES TO TRUE TDECVALX
|
|
00500 GO TO 121-VW-EXIT. TDECVALX
|
|
00501 TDECVALX
|
|
00502 *** DISPLAY '2511 ALPHA-NAME' WS-ETA-EMP-NAME-FOUR TRAN-EMP-NAME.TDECVALX
|
|
00503 IF WS-ETA-EMP-NAME-FOUR = TRAN-EMP-NAME TDECVALX
|
|
00504 NEXT SENTENCE TDECVALX
|
|
00505 ELSE TDECVALX
|
|
00506 MOVE ETA-EMP-NAME TDECVALX
|
|
00507 TO MESSAGE-AREA TDECVALX
|
|
00508 *** MOVE '****' TO ASTR TDECVALX
|
|
00509 MOVE TRAN-EMP-NAME TO EMPOR-PRT TDECVALX
|
|
00510 MOVE 1 TO ERROR-SW TDECVALX
|
|
00511 PERFORM 125-WAGE-REPORT THRU 125-WR-EXIT TDECVALX
|
|
00512 SET EMSG111-SELECTED-YES TO TRUE. TDECVALX
|
|
00513 TDECVALX
|
|
00514 121-VW-EXIT. TDECVALX
|
|
00515 EXIT. TDECVALX
|
|
00516 TDECVALX
|
|
00517 125-WAGE-REPORT. TDECVALX
|
|
00518 TDECVALX
|
|
00519 MOVE TR-SSN TO SSN-PRT. TDECVALX
|
|
00520 MOVE TRAN-DATE-ENTERED TO DATE-ENTERED-PRT. TDECVALX
|
|
00521 MOVE TRAN-NAME-CHECK TO EMPEE-NAME. TDECVALX
|
|
00522 MOVE TRAN-QUARTER-EARNINGS TO EARNINGS-PRT. TDECVALX
|
|
00523 MOVE TRAN-QUARTER-YR-QTR TO QTR-PRT. TDECVALX
|
|
00524 MOVE TRAN-ACCOUNT TO ACCT-NUM-PRT. TDECVALX
|
|
00525 *** MOVE WS-ETA-EMP-NAME-FOUR TO EMPOR-PRT. TDECVALX
|
|
00526 IF LINE-CTR > 55 TDECVALX
|
|
00527 PERFORM 130-WAGE-HEADER THRU 130-WH-EXIT. TDECVALX
|
|
00528 WRITE PRINT-REC FROM DTL1. TDECVALX
|
|
00529 IF TRAN-QUARTER-EARNINGS NOT = ZEROS TDECVALX
|
|
00530 ADD 1 TO ERROR-RECS. TDECVALX
|
|
00531 MOVE SPACES TO DTL1. TDECVALX
|
|
00532 ADD 1 TO LINE-CTR. TDECVALX
|
|
00533 TDECVALX
|
|
00534 125-WR-EXIT. TDECVALX
|
|
00535 EXIT. TDECVALX
|
|
00536 TDECVALX
|
|
00537 130-WAGE-HEADER. TDECVALX
|
|
00538 ADD 1 TO PAGE-CTR. TDECVALX
|
|
00539 MOVE PAGE-CTR TO PAGE-CTR-PRT. TDECVALX
|
|
00540 WRITE PRINT-REC FROM HD1 AFTER TOP-OF-PAGE. TDECVALX
|
|
00541 WRITE PRINT-REC FROM HD2. TDECVALX
|
|
00542 WRITE PRINT-REC FROM HD3. TDECVALX
|
|
00543 WRITE PRINT-REC FROM HD4. TDECVALX
|
|
00544 MOVE 4 TO LINE-CTR. TDECVALX
|
|
00545 TDECVALX
|
|
00546 130-WH-EXIT. TDECVALX
|
|
00547 EXIT. TDECVALX
|
|
00548 TDECVALX
|
|
00549 220-CREATE-W4-TRAN. TDECVALX
|
|
00550 TDECVALX
|
|
00551 ADD +1 TO WS-EMP-SUCCESS-CNT. TDECVALX
|
|
00552 TDECVALX
|
|
00553 MOVE WRK-LOG-NO TO WRK-TRAN-LOG-NO. TDECVALX
|
|
00554 MOVE ESP-TRANSACTION-AREA TO WRK-TRAN-AREA. TDECVALX
|
|
00555 TDECVALX
|
|
00556 WRITE TDECOUT-REC FROM WRK-TRANSACTION-AREA. TDECVALX
|
|
00557 ADD 1 TO QTR-RECS-OUT. TDECVALX
|
|
00558 ADD TRAN-QUARTER-EARNINGS TO EMP-QTR-TOT-EARNINGS. TDECVALX
|
|
00559 TDECVALX
|
|
00560 220-CW-EXIT. TDECVALX
|
|
00561 EXIT. TDECVALX
|
|
00562 TDECVALX
|
|
00563 ******************************************************************TDECVALX
|
|
00564 * OBTAIN YYYYQ YEAR-QUARTER INFORMATION. *TDECVALX
|
|
00565 ******************************************************************TDECVALX
|
|
00566 S004-FROM-3. TDECVALX
|
|
00567 SET L004-FROM-3 TO TRUE. TDECVALX
|
|
00568 GO TO S004-YRQ. TDECVALX
|
|
00569 TDECVALX
|
|
00570 S004-YRQ. TDECVALX
|
|
00571 CALL 'DTSBU004' USING L004-LINK-AREA. TDECVALX
|
|
00572 TDECVALX
|
|
00573 S004-EXIT. TDECVALX
|
|
00574 EXIT. TDECVALX
|
|
00575 EJECT TDECVALX
|
|
00576 TDECVALX
|
|
00577 ******************************************************************TDECVALX
|
|
00578 * CALL DESBD200 TO UPDATE MSTF LOG FILE. *TDECVALX
|
|
00579 ******************************************************************TDECVALX
|
|
00580 SERV0200-UPD-LOG. TDECVALX
|
|
00581 TDECVALX
|
|
00582 MOVE WRK-LOG-NO TO L200-LOG-NO. TDECVALX
|
|
00583 MOVE WRK-MOD-NAME TO L200-PROG-NAME. TDECVALX
|
|
00584 TDECVALX
|
|
00585 CALL 'DESBD200' USING L200-LINK-AREA C202-MSG-TABLE. TDECVALX
|
|
00586 TDECVALX
|
|
00587 SERV0200-EXIT. TDECVALX
|
|
00588 EXIT. TDECVALX
|
|
00589 TDECVALX
|
|
00590 SERV3000-ACCESS-TAX. TDECVALX
|
|
00591 MOVE CSV-TAX-FILE-FLAG TO ETA-TAX-FIRST-TIME-IND. TDECVALX
|
|
00592 CALL 'ESP925D' USING ETA-EMPLOYER-STATUS-DATA. TDECVALX
|
|
00593 MOVE ETA-TAX-FIRST-TIME-IND TO CSV-TAX-FILE-FLAG. TDECVALX
|
|
00594 SERV3000-EXIT. TDECVALX
|
|
00595 EXIT. TDECVALX
|
|
00596 TDECVALX
|
|
00597 SERV9999-ABEND. TDECVALX
|
|
00598 DISPLAY '**** TDECVAL1 ABENDING ' ABEND-MSG. TDECVALX
|
|
00599 CALL ABEND-MOD USING ABEND-CD. TDECVALX
|
|
00600 SERV9999-EXIT. TDECVALX
|
|
00601 EXIT. TDECVALX
|
|
00602 TDECVALX
|
|
00603 999-CLOSE-FILES. TDECVALX
|
|
00604 MOVE RECS-IN TO WAGE-CNT-PRT. TDECVALX
|
|
00605 MOVE QTR-RECS-OUT TO WAGE-OUT-PRT. TDECVALX
|
|
00606 MOVE ERROR-RECS TO ERRORS-PRT. TDECVALX
|
|
00607 MOVE ZERO-WAGE-CNT TO ZERO-WAGE-PRT. TDECVALX
|
|
00608 IF LINE-CTR > 52 TDECVALX
|
|
00609 PERFORM 130-WAGE-HEADER THRU 130-WH-EXIT. TDECVALX
|
|
00610 WRITE PRINT-REC FROM TOT1 AFTER 2. TDECVALX
|
|
00611 CLOSE TDECFILE LISTOUT. TDECVALX
|
|
00612 CLOSE TDECOUT. TDECVALX
|
|
00613 STOP RUN. TDECVALX
|
|
00614 TDECVALX
|