giteaadmin/DUTAS
4
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
42a3da46ab1a7bd4c48cb25d4d4073a83ce34294
DUTAS/Batch/SAMPS031.cob
Neeraj Kumar ca3572c5df DUTAS re-platformed to Raincode - Initial Source Code
2025-07-21 11:20:11 -04:00

1063 lines
84 KiB
COBOL
Raw Blame History

00001 IDENTIFICATION DIVISION. 02/12/04
00002 PROGRAM-ID. SAMPS031. SAMPS031
00003 AUTHOR. JOHN VIENNAS. LV001
00004 DATE-WRITTEN. NOVEMBER, 1992. SAMPS031
00005 SAMPS031
00006 *************************************************************** SAMPS031
00007 ** --------------------PROGRAM DESCRIPTION------------------ ** SAMPS031
00008 *************************************************************** SAMPS031
00009 ** CODING FOR VS COBOL VSAM ** SAMPS031
00010 *************************************************************** SAMPS031
00011 ** ** SAMPS031
00012 ** ** SAMPS031
00013 ** THIS PROGRAM READS THREE FILES AS INPUT TO THE PROGRAM, ** SAMPS031
00014 ** TRANS-FILE, CNTRL-DATA, AND SELECT-FILE. THE TRANS-FILE ** SAMPS031
00015 ** UTILIZES A VSAM FILE STRUCTURE WITH (SEQ-NMBR) AS THE ** SAMPS031
00016 ** RECORD KEY. THE CNTRL-DATA FILE CONTAINS SOME PROCESSING ** SAMPS031
00017 ** INFORMATION WHICH IS USED IN THE OUTPUT REPORTS ** SAMPS031
00018 ** HIT-FILE, HIT-LIST, AND CHECK-LIST. THE SELECT-FILE ** SAMPS031
00019 ** CONTAINS THE RECORD NUMBERS OF THE RECORDS TO BE SELECTED ** SAMPS031
00020 ** FOR THE SAMPLE. THESE NUMBERS ARE USED AS THE RECORD ** SAMPS031
00021 ** KEY (SEQ-NMBR) TO ACCESS THE TRANS-FILE. THE RECORDS ** SAMPS031
00022 ** THAT ARE READ FROM THE TRANS-FILE ARE OUTPUT TO THE THREE ** SAMPS031
00023 ** FILES, HIT-FILE, HIT-LIST, AND CHECK-LIST. EACH RECORD ** SAMPS031
00024 ** THAT IS READ IS ALSO UPDATED TO INDICATE THAT THE RECORD ** SAMPS031
00025 ** WAS SELECTED AS PART OF THE SAMPLE. THIS IS DONE BY ** SAMPS031
00026 ** CHANGING THE SELECTED-FLAG FIELD FROM A '1' TO A '2'. ** SAMPS031
00027 ** ** SAMPS031
00028 *************************************************************** SAMPS031
00029 SAMPS031
00030 ENVIRONMENT DIVISION. SAMPS031
00031 CONFIGURATION SECTION. SAMPS031
00032 INPUT-OUTPUT SECTION. SAMPS031
00033 FILE-CONTROL. SAMPS031
00034 SELECT TRANS-FILE SAMPS031
00035 ASSIGN TO SYS003-DISKUNIT SAMPS031
00036 ORGANIZATION IS INDEXED SAMPS031
00037 ACCESS MODE IS RANDOM SAMPS031
00038 RECORD KEY IS SEQ-NMBR SAMPS031
00039 FILE STATUS IS TRANS-FILE-ERROR-CODE. SAMPS031
00040 SELECT CNTRL-DATA SAMPS031
00041 ASSIGN TO UT-S-CNTRLDTA. SAMPS031
00042 SELECT SELECT-FILE SAMPS031
00043 ASSIGN TO UT-S-SLCTREC. SAMPS031
00044 SELECT HIT-FILE SAMPS031
00045 ASSIGN TO UT-S-HITFILE. SAMPS031
00046 SELECT HIT-LIST SAMPS031
00047 ASSIGN TO UT-S-PRINTER. SAMPS031
00048 SELECT CHECK-LIST SAMPS031
00049 ASSIGN TO UT-S-CHECK. SAMPS031
00050 SELECT JOB-STATUS SAMPS031
00051 ASSIGN TO UT-S-MSGOUT. SAMPS031
00052 SAMPS031
00053 DATA DIVISION. SAMPS031
00054 FILE SECTION. SAMPS031
00055 SAMPS031
00056 *************************************************************** SAMPS031
00057 ** TRANS-FILE IS THE VSAM FILE CREATED BY THE STATE ** SAMPS031
00058 ** EMPLOYMENT SECURITY AGENCIES (SESA) WITH THE RECORDS THAT ** SAMPS031
00059 ** MAKE UP THE SAMPLING UNIVERSE. THE KEY OF THE FILE IS ** SAMPS031
00060 ** (SEQ-NMBR). THIS FIELD CONTAINS THE SEQUENTIAL RECORD ** SAMPS031
00061 ** NUMBER. ** SAMPS031
00062 *************************************************************** SAMPS031
00063 FD TRANS-FILE SAMPS031
00064 LABEL RECORDS ARE STANDARD SAMPS031
00065 BLOCK CONTAINS 0 RECORDS. SAMPS031
00066 01 TRANS-REC. SAMPS031
00067 05 SEQ-NMBR PIC 9(8). SAMPS031
00068 05 REC-TYPE PIC X(5). SAMPS031
00069 05 TRANS-TYPE PIC X. SAMPS031
00070 05 SELECT-FLAG PIC X. SAMPS031
00071 05 EMP-ID PIC X(12). SAMPS031
00072 05 DATE-COMPLETED PIC X(8). SAMPS031
00073 05 STATE-OPTION PIC X(25). SAMPS031
00074 SAMPS031
00075 *************************************************************** SAMPS031
00076 ** CNTRL-DATA CONTAINS SOME OF THE PROCESSING INFORMATION ** SAMPS031
00077 ** NEEDED FOR SAMPLING. IT CONTAINS THE RANDOM NUMBER ** SAMPS031
00078 ** (CNTRL-RANDOM), THE NUMBER OF RECORDS TO BE SELECTED FOR ** SAMPS031
00079 ** THE SAMPLE (SAMPLED-NMBR), AND THE RECORD COUNT OF THE ** SAMPS031
00080 ** NUMBER OF RECORDS (TRANS-REC-CNTR) CONTAINED ON THE ** SAMPS031
00081 ** TRANS-FILE. FOR THE PURPOSE OF THIS PROGRAM, ONLY ** SAMPS031
00082 ** THE SESA-ID, SAMPLE-TYPE, AND SAMPLED-NMBR FIELDS ARE ** SAMPS031
00083 ** NEEDED. ** SAMPS031
00084 *************************************************************** SAMPS031
00085 SAMPS031
00086 FD CNTRL-DATA SAMPS031
00087 RECORDING MODE IS F SAMPS031
00088 LABEL RECORD IS OMITTED SAMPS031
00089 BLOCK CONTAINS 1 RECORDS. SAMPS031
00090 01 CNTRL-DATA-REC. SAMPS031
00091 05 CNTRL-TYPE PIC X(5). SAMPS031
00092 05 CNTRL-TRANS-TYPE PIC X. SAMPS031
00093 05 SESA-ID PIC XX. SAMPS031
00094 05 CNTRL-RANDOM PIC V999. SAMPS031
00095 05 CNTRL-RANDOM-ALF REDEFINES CNTRL-RANDOM PIC X(3). SAMPS031
00096 05 SAMPLED-NMBR PIC 9(4). SAMPS031
00097 05 SAMPLED-NMBR-ALF REDEFINES SAMPLED-NMBR PIC X(4). SAMPS031
00098 05 TRANS-REC-CNTR PIC 9(8). SAMPS031
00099 05 TRANS-REC-CNTR-ALF REDEFINES TRANS-REC-CNTR PIC X(8). SAMPS031
00100 05 SAMPLE-TYPE PIC X(02). SAMPS031
00101 05 CNTRL-YEAR-SELECTED PIC X(04). SAMPS031
00102 05 DATE-FILLER PIC 9(04). SAMPS031
00103 SAMPS031
00104 *************************************************************** SAMPS031
00105 ** HIT-LIST CONTAINS THE PRINTED REPORT OF THE RECORDS ** SAMPS031
00106 ** SELECTED FOR SAMPLING. ** SAMPS031
00107 *************************************************************** SAMPS031
00108 SAMPS031
00109 FD HIT-LIST SAMPS031
00110 LABEL RECORD IS STANDARD. SAMPS031
00111 01 PRINT-HIT-REC PIC X(132). SAMPS031
00112 SAMPS031
00113 ************************************************************* SAMPS031
00114 *** *** SAMPS031
00115 ** THE CHECK-LIST CONTAINS THE INFORMATION NECCESSARY ** SAMPS031
00116 ** TO CARRY OUT THE REVENUE QUALITY CONTROL (RQC) FIELD ** SAMPS031
00117 ** AUDIT SAMPLING TASK. THIS CHECK LIST IS A DUPLICATE ** SAMPS031
00118 ** OF THE FIELD AUDIT CODING SHEET IN THE RQC HANDBOOK. ** SAMPS031
00119 *** *** SAMPS031
00120 ************************************************************* SAMPS031
00121 FD CHECK-LIST SAMPS031
00122 LABEL RECORD IS STANDARD. SAMPS031
00123 01 CHECK-LIST-REC PIC X(132). SAMPS031
00124 SAMPS031
00125 *************************************************************** SAMPS031
00126 ** (HIT-FILE) IS THE DATA FILE FOR STORING THE RECORDS THAT ** SAMPS031
00127 ** HAVE BEEN SELECTED FROM THE (TRANS-FILE) FOR THE SAMPLE. ** SAMPS031
00128 ** THESE RECORDS ARE WRITTEN TO A DISK FILE WITH DELIMITERS ** SAMPS031
00129 ** OF '|' BETWEEN EACH FIELD OF THE RECORD. THIS FILE ** SAMPS031
00130 ** (HIT-FILE), WILL BE PASSED TO THE INFORMIX SIDE OF THE ** SAMPS031
00131 ** RQC SYSTEM FOR FURTHER PROCESSING. ** SAMPS031
00132 *************************************************************** SAMPS031
00133 SAMPS031
00134 FD HIT-FILE SAMPS031
00135 LABEL RECORDS ARE STANDARD. SAMPS031
00136 01 TRANS-HIT-REC PIC X(41). SAMPS031
00137 SAMPS031
00138 ********************************************************* SAMPS031
00139 *** *** SAMPS031
00140 ** THE SELECT-FILE IS THE INPUT FILE THAT CONTAINS THE ** SAMPS031
00141 ** RECORD NUMBERS CREATED IN THE SAMPLE DETERMINATION ** SAMPS031
00142 ** PROGRAM (PICKNMBR). THESE NUMBERS ARE USED AS THE ** SAMPS031
00143 ** RECORD KEY TO SELECT THE RECORDS FROM THE VSAM ** SAMPS031
00144 ** FILE (TRANS-FILE) FOR SAMPLING. ** SAMPS031
00145 *** *** SAMPS031
00146 ********************************************************* SAMPS031
00147 FD SELECT-FILE SAMPS031
00148 LABEL RECORD IS OMITTED SAMPS031
00149 BLOCK CONTAINS 0 RECORDS. SAMPS031
00150 01 SL-REC-NUM PIC 9(08). SAMPS031
00151 SAMPS031
00152 ********************************************** SAMPS031
00153 *** *** SAMPS031
00154 ** THE JOB-STATUS FILE IS A SEPERATE FILE ** SAMPS031
00155 ** CREATED TO OUTPUT THE END OF JOB MESSAGES** SAMPS031
00156 ** SAMPS031 - NORMAL END OF JOB, AND ** SAMPS031
00157 ** SAMPS031 - JOB TERMINATED. ** SAMPS031
00158 *** *** SAMPS031
00159 ********************************************** SAMPS031
00160 FD JOB-STATUS SAMPS031
00161 LABEL RECORD IS STANDARD. SAMPS031
00162 01 MESSAGE-RECORD PIC X(132). SAMPS031
00163 SAMPS031
00164 WORKING-STORAGE SECTION. SAMPS031
001645 77 PAN-VALET PICTURE X(24) VALUE '001SAMPS031 02/12/04'. SAMPS031
00165 SAMPS031
00166 01 WS-WORK-AREA. SAMPS031
00167 05 MATCH-CNTR PIC 9(08) VALUE 0. SAMPS031
00168 05 WS-SELECT-EOF PIC X(01) VALUE 'N'. SAMPS031
00169 05 CNTRL-FLAG PIC X(01) VALUE 'N'. SAMPS031
00170 05 SELECTED-FLAG PIC 9(01) VALUE 2. SAMPS031
00171 05 LIST-COUNTER PIC 9(02) VALUE 0. SAMPS031
00172 05 LIST-PAGE PIC 9(06) VALUE 0. SAMPS031
00173 SAMPS031
00174 05 WS-DATE PIC 9(06) VALUE ZEROES. SAMPS031
00175 05 WS-DATE-R REDEFINES WS-DATE. SAMPS031
00176 10 WS-YY PIC 9(02). SAMPS031
00177 10 WS-MM PIC 9(02). SAMPS031
00178 10 WS-DD PIC 9(02). SAMPS031
00179 SAMPS031
00180 05 WRK-DATE-AREA. SAMPS031
00181 10 WRK-MM PIC X(02). SAMPS031
00182 10 FILLER PIC X(01) VALUE '/'. SAMPS031
00183 10 WRK-DD PIC X(02). SAMPS031
00184 10 FILLER PIC X(01) VALUE '/'. SAMPS031
00185 10 WRK-YY PIC X(02). SAMPS031
00186 *************************************************** SAMPS031
00187 *** *** SAMPS031
00188 ** TRANS-FILE-ERROR-CODE: ** SAMPS031
00189 ** FILE STATUS FIELD WHICH STORES THE VALUE OF ** SAMPS031
00190 ** AN ERROR CODE IF AN ERROR IS ENCOUNTERED ** SAMPS031
00191 ** DURING A READ OR WRITE TO THE VSAM ** SAMPS031
00192 ** (TRANS-FILE) FILE. ** SAMPS031
00193 *** *** SAMPS031
00194 *************************************************** SAMPS031
00195 01 TRANS-FILE-ERROR-CODE PIC X(02). SAMPS031
00196 SAMPS031
00197 01 WS-REPORT-CONTROLS. SAMPS031
00198 05 WS-CHECKLIST-CNTR PIC 9(02) VALUE 0. SAMPS031
00199 05 WS-PAGE-CNTR PIC 9(04) VALUE 0. SAMPS031
00200 SAMPS031
00201 01 WS-HEADER-SWITCH-AREA. SAMPS031
00202 05 WS-CHECKLIST-SWITCH PIC X(01) VALUE '0'. SAMPS031
00203 05 WS-HIT-LIST-SWITCH PIC X(01) VALUE '0'. SAMPS031
00204 SAMPS031
00205 01 WS-CHECKLIST-HOLD-AREA. SAMPS031
00206 SAMPS031
00207 05 WS-EMPL-HOLD-AREA PIC X(12). SAMPS031
00208 05 WS-CASE-HOLD-AREA PIC 9(08). SAMPS031
00209 05 WS-PERIOD-AREA PIC X(04). SAMPS031
00210 05 WS-SESA-NAME-AREA PIC X(20). SAMPS031
00211 05 WS-SAMPLE-NAME-AREA PIC X(24). SAMPS031
00212 SAMPS031
00213 *************************************************************** SAMPS031
00214 ** (WS-MATCH-RECORD) STORES THE VALUE OF THE SELECTED RECORDS** SAMPS031
00215 ** FROM THE VSAM FILE (TRANS-FILE). ** SAMPS031
00216 *************************************************************** SAMPS031
00217 SAMPS031
00218 01 WS-MATCH-RECORD. SAMPS031
00219 05 MATCH-SEQ-NMBR PIC 9(8). SAMPS031
00220 05 MATCH-REC-TYPE PIC X(5). SAMPS031
00221 05 MATCH-TRANS-TYPE PIC X(01). SAMPS031
00222 05 MATCH-SELECT-FLAG PIC X(01). SAMPS031
00223 05 MATCH-EMP-ID PIC X(12). SAMPS031
00224 05 MATCH-DATE-COMPLETED PIC X(8). SAMPS031
00225 05 MATCH-STATE-OPTION PIC X(25). SAMPS031
00226 SAMPS031
00227 01 WS-SAMPLE-TABLE-CONTROLS. SAMPS031
00228 05 WS-ENTRY-FOUND-SWITCH PIC X(03). SAMPS031
00229 88 WS-SAMPLE-FOUND VALUE 'YES'. SAMPS031
00230 88 WS-END-OF-SAMPLE-TABLE VALUE 'END'. SAMPS031
00231 SAMPS031
00232 ********************************************* SAMPS031
00233 *** *** SAMPS031
00234 ** WS-SAMPLE-DATA. ** SAMPS031
00235 ** CONTAINS THE RQC - SAMPLE TYPES; ** SAMPS031
00236 ** A 2 CHARACTER CODE AND A 24 CHARACTER ** SAMPS031
00237 ** DEFINITION. ** SAMPS031
00238 *** *** SAMPS031
00239 ********************************************* SAMPS031
00240 SAMPS031
00241 01 WS-SAMPLE-DATA. SAMPS031
00242 05 FILLER PIC X(26) SAMPS031
00243 VALUE 'A11ST ACCEPTANCE SAMPLE '. SAMPS031
00244 05 FILLER PIC X(26) SAMPS031
00245 VALUE 'A22ND ACCEPTANCE SAMPLE '. SAMPS031
00246 05 FILLER PIC X(26) SAMPS031
00247 VALUE 'E1EXPANDED SAMPLE '. SAMPS031
00248 05 FILLER PIC X(26) SAMPS031
00249 VALUE 'O11ST SESA OPTIONAL SAMPLE'. SAMPS031
00250 05 FILLER PIC X(26) SAMPS031
00251 VALUE 'O22ND SESA OPTIONAL SAMPLE'. SAMPS031
00252 01 WS-SAMPLE-TABLE REDEFINES WS-SAMPLE-DATA. SAMPS031
00253 05 WS-SAMPLE-ENTRY OCCURS 5 TIMES SAMPS031
00254 INDEXED BY WS-INDEX. SAMPS031
00255 10 WS-SAMPLE-ID PIC X(02). SAMPS031
00256 10 WS-SAMPLE-DESCRIPTION PIC X(24). SAMPS031
00257 SAMPS031
00258 01 ST-TABLE-CONTROLS. SAMPS031
00259 05 ST-ENTRY-FOUND-SWITCH PIC X(03). SAMPS031
00260 88 ST-ENTRY-FOUND VALUE 'YES'. SAMPS031
00261 88 ST-END-OF-TABLE VALUE 'END'. SAMPS031
00262 SAMPS031
00263 ************************************************** SAMPS031
00264 *** *** SAMPS031
00265 ** ST-STATE-DATA: ** SAMPS031
00266 ** CONTAINS THE FIPS CODE AND STATE NAME. ** SAMPS031
00267 *** *** SAMPS031
00268 ************************************************** SAMPS031
00269 01 ST-STATE-DATA. SAMPS031
00270 05 FILLER PIC X(22) VALUE 'AKALASKA '. SAMPS031
00271 05 FILLER PIC X(22) VALUE 'ALALABAMA '. SAMPS031
00272 05 FILLER PIC X(22) VALUE 'ARARKANSAS '. SAMPS031
00273 05 FILLER PIC X(22) VALUE 'AZARIZONA '. SAMPS031
00274 05 FILLER PIC X(22) VALUE 'CACALIFORNIA '. SAMPS031
00275 05 FILLER PIC X(22) VALUE 'COCOLORADO '. SAMPS031
00276 05 FILLER PIC X(22) VALUE 'CTCONNECTICUT '. SAMPS031
00277 05 FILLER PIC X(22) VALUE 'DCDISTRICT OF COLUMBIA'. SAMPS031
00278 05 FILLER PIC X(22) VALUE 'DEDELAWARE '. SAMPS031
00279 05 FILLER PIC X(22) VALUE 'FLFLORIDA '. SAMPS031
00280 05 FILLER PIC X(22) VALUE 'GAGEORGIA '. SAMPS031
00281 05 FILLER PIC X(22) VALUE 'HIHAWAII '. SAMPS031
00282 05 FILLER PIC X(22) VALUE 'IAIOWA '. SAMPS031
00283 05 FILLER PIC X(22) VALUE 'IDIDAHO '. SAMPS031
00284 05 FILLER PIC X(22) VALUE 'ILILLINOIS '. SAMPS031
00285 05 FILLER PIC X(22) VALUE 'ININDIANA '. SAMPS031
00286 05 FILLER PIC X(22) VALUE 'KSKANSAS '. SAMPS031
00287 05 FILLER PIC X(22) VALUE 'KYKENTUCKY '. SAMPS031
00288 05 FILLER PIC X(22) VALUE 'LALOUISIANA '. SAMPS031
00289 05 FILLER PIC X(22) VALUE 'MAMASSACHUSETTS '. SAMPS031
00290 05 FILLER PIC X(22) VALUE 'MDMARYLAND '. SAMPS031
00291 05 FILLER PIC X(22) VALUE 'MEMAINE '. SAMPS031
00292 05 FILLER PIC X(22) VALUE 'MIMICHIGAN '. SAMPS031
00293 05 FILLER PIC X(22) VALUE 'MNMINNESOTA '. SAMPS031
00294 05 FILLER PIC X(22) VALUE 'MOMISSOURI '. SAMPS031
00295 05 FILLER PIC X(22) VALUE 'MSMISSISSIPPI '. SAMPS031
00296 05 FILLER PIC X(22) VALUE 'MTMONTANA '. SAMPS031
00297 05 FILLER PIC X(22) VALUE 'NENEBRASKA '. SAMPS031
00298 05 FILLER PIC X(22) VALUE 'NHNEW HAMSHIRE '. SAMPS031
00299 05 FILLER PIC X(22) VALUE 'NJNEW JERSEY '. SAMPS031
00300 05 FILLER PIC X(22) VALUE 'NMNEW MEXICO '. SAMPS031
00301 05 FILLER PIC X(22) VALUE 'NVNEVADA '. SAMPS031
00302 05 FILLER PIC X(22) VALUE 'NYNEW YORK '. SAMPS031
00303 05 FILLER PIC X(22) VALUE 'NCNORTH CAROLINA '. SAMPS031
00304 05 FILLER PIC X(22) VALUE 'NDNORTH DAKOTA '. SAMPS031
00305 05 FILLER PIC X(22) VALUE 'OHOHIO '. SAMPS031
00306 05 FILLER PIC X(22) VALUE 'OKOKLAHOMA '. SAMPS031
00307 05 FILLER PIC X(22) VALUE 'OROREGON '. SAMPS031
00308 05 FILLER PIC X(22) VALUE 'PAPENNSYLVANIA '. SAMPS031
00309 05 FILLER PIC X(22) VALUE 'PRPUERTO RICO '. SAMPS031
00310 05 FILLER PIC X(22) VALUE 'RIRHODE ISLAND '. SAMPS031
00311 05 FILLER PIC X(22) VALUE 'SCSOUTH CAROLINA '. SAMPS031
00312 05 FILLER PIC X(22) VALUE 'SDSOUTH DAKOTA '. SAMPS031
00313 05 FILLER PIC X(22) VALUE 'TNTENNESSEE '. SAMPS031
00314 05 FILLER PIC X(22) VALUE 'TXTEXAS '. SAMPS031
00315 05 FILLER PIC X(22) VALUE 'UTUTAH '. SAMPS031
00316 05 FILLER PIC X(22) VALUE 'VAVIRGINIA '. SAMPS031
00317 05 FILLER PIC X(22) VALUE 'VIVIRGIN ISLAND '. SAMPS031
00318 05 FILLER PIC X(22) VALUE 'VTVERMONT '. SAMPS031
00319 05 FILLER PIC X(22) VALUE 'WAWASHINGTON '. SAMPS031
00320 05 FILLER PIC X(22) VALUE 'WVWEST VIRGINIA '. SAMPS031
00321 05 FILLER PIC X(22) VALUE 'WIWISCONSIN '. SAMPS031
00322 05 FILLER PIC X(22) VALUE 'WYWYOMING '. SAMPS031
00323 01 ST-STATE-TABLE REDEFINES ST-STATE-DATA. SAMPS031
00324 05 ST-STATE-ENTRY OCCURS 53 TIMES SAMPS031
00325 INDEXED BY ST-INDEX. SAMPS031
00326 10 ST-STATE-ID PIC X(02). SAMPS031
00327 10 ST-STATE-NAME PIC X(20). SAMPS031
00328 SAMPS031
00329 01 TRANS-TYPE-DESCR. SAMPS031
00330 05 OTHER-1 PIC X(6) VALUE 'OTHER '. SAMPS031
00331 05 RANDOMM PIC X(6) VALUE 'RANDOM'. SAMPS031
00332 SAMPS031
00333 ************************************************ SAMPS031
00334 *** *** SAMPS031
00335 ** WS-END-OF-JOB-MESSAGES: ** SAMPS031
00336 ** END OF JOB STATUS MESSAGES: MESSAGE-1 ** SAMPS031
00337 ** AND MESSAGE-2. ** SAMPS031
00338 *** *** SAMPS031
00339 ************************************************ SAMPS031
00340 SAMPS031
00341 01 WS-END-OF-JOB-MESSAGES. SAMPS031
00342 05 MESSAGE-1 PIC X(28) SAMPS031
00343 VALUE 'SAMPS031 - NORMAL END OF JOB'. SAMPS031
00344 05 MESSAGE-2 PIC X(28) SAMPS031
00345 VALUE 'SAMPS031 - JOB TERMINATED '. SAMPS031
00346 SAMPS031
00347 01 WS-EOJ-DETAIL-LINE. SAMPS031
00348 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00349 05 WS-MESSAGE-FILE PIC X(28). SAMPS031
00350 05 FILLER PIC X(102) VALUE SPACES. SAMPS031
00351 SAMPS031
00352 01 DTL-DATE-REFORMAT-AREA. SAMPS031
00353 05 DTL-DATE-COMPLETED PIC X(08). SAMPS031
00354 05 FILLER REDEFINES DTL-DATE-COMPLETED. SAMPS031
00355 10 DTL-COMPLETED-YR PIC X(04). SAMPS031
00356 10 DTL-COMPLETED-MO PIC X(02). SAMPS031
00357 10 DTL-COMPLETED-DA PIC X(02). SAMPS031
00358 SAMPS031
00359 *************************************************************** SAMPS031
00360 ** (OUTPUT-HIT-REC) IS THE RECORD LAYOUT FOR THE RECORDS ** SAMPS031
00361 ** THAT ARE WRITTEN TO THE FILE (HIT-FILE). THIS FILE CAN ** SAMPS031
00362 ** BE DOWNLOADED TO THE SUN MICROCOMPUTER INTO THE CORE ** SAMPS031
00363 ** RQC SAMPLING SUBSYSTEM. ** SAMPS031
00364 *************************************************************** SAMPS031
00365 01 OUTPUT-HIT-REC. SAMPS031
00366 SAMPS031
00367 05 HIT-RECORD-TYPE PIC X(05) VALUE SPACES. SAMPS031
00368 05 FILLER PIC X(01) VALUE '|'. SAMPS031
00369 05 HIT-STATE PIC X(02) VALUE SPACES. SAMPS031
00370 05 FILLER PIC X(01) VALUE '|'. SAMPS031
00371 05 HIT-SAMPLE-YEAR PIC X(04) VALUE SPACES. SAMPS031
00372 05 FILLER PIC X(01) VALUE '|'. SAMPS031
00373 05 HIT-TRANS-TYPE PIC X(01) VALUE ZEROS. SAMPS031
00374 05 FILLER PIC X(01) VALUE '|'. SAMPS031
00375 05 HIT-SAMPLE-TYPE PIC X(02) VALUE ZEROS. SAMPS031
00376 05 FILLER PIC X(01) VALUE '|'. SAMPS031
00377 05 HIT-CASE-NUMBER PIC 9(08) VALUE ZEROS. SAMPS031
00378 05 FILLER PIC X(01) VALUE '|'. SAMPS031
00379 05 HIT-EMPLOYER-ID PIC X(12) VALUE SPACES. SAMPS031
00380 05 FILLER PIC X(01) VALUE '|'. SAMPS031
00381 SAMPS031
00382 *************************************************************** SAMPS031
00383 ** (OUTPUT-TITLES) DESCRIBES THE LINES FOR EACH LINE OF THE ** SAMPS031
00384 ** REPORT TITLE. ** SAMPS031
00385 *************************************************************** SAMPS031
00386 SAMPS031
00387 01 LIST-HEADING-1. SAMPS031
00388 10 FILLER PIC X(1) VALUE SPACES. SAMPS031
00389 10 FILLER PIC X(9) VALUE 'RUN DATE:'. SAMPS031
00390 10 FILLER PIC X(1) VALUE SPACES. SAMPS031
00391 10 O-RUN-DATE PIC X(08) VALUE SPACES. SAMPS031
00392 10 FILLER PIC X(17) VALUE SPACES. SAMPS031
00393 10 FILLER PIC X(14) SAMPS031
00394 VALUE 'FIELD AUDIT - '. SAMPS031
00395 10 FILLER PIC X(1) VALUE SPACES. SAMPS031
00396 10 DTL-OUTPUT-TRANS-TYPE PIC X(6). SAMPS031
00397 10 FILLER PIC X(41) VALUE SPACES. SAMPS031
00398 10 FILLER PIC X(5) VALUE 'PAGE:'. SAMPS031
00399 10 FILLER PIC X(1) VALUE SPACES. SAMPS031
00400 10 O-LIST-PAGE PIC ZZZZZ9. SAMPS031
00401 10 FILLER PIC X(17) VALUE SPACES. SAMPS031
00402 SAMPS031
00403 01 LIST-HEADING-2. SAMPS031
00404 10 FILLER PIC X(36) VALUE SPACES. SAMPS031
00405 10 FILLER PIC X(25) SAMPS031
00406 VALUE 'SAMPLING HIT FILE LISTING'. SAMPS031
00407 10 FILLER PIC X(71) VALUE SPACES. SAMPS031
00408 SAMPS031
00409 01 LIST-HEADING-3. SAMPS031
00410 10 FILLER PIC X(36) VALUE SPACES. SAMPS031
00411 10 FILLER PIC X(9) VALUE 'STATE OF '. SAMPS031
00412 10 O-CNTRL-SESA-NAME PIC X(20) VALUE SPACES. SAMPS031
00413 10 FILLER PIC X(67) VALUE SPACES. SAMPS031
00414 SAMPS031
00415 01 LIST-HEADING-4. SAMPS031
00416 10 FILLER PIC X(22) VALUE SPACES. SAMPS031
00417 10 FILLER PIC X(4) VALUE 'CASE'. SAMPS031
00418 10 FILLER PIC X(8) VALUE SPACES. SAMPS031
00419 10 FILLER PIC X(8) VALUE 'EMPLOYER'. SAMPS031
00420 10 FILLER PIC X(09) VALUE SPACES. SAMPS031
00421 10 FILLER PIC X(4) VALUE 'DATE'. SAMPS031
00422 10 FILLER PIC X(7) VALUE SPACES. SAMPS031
00423 10 FILLER PIC X(8) VALUE 'SEQUENCE'. SAMPS031
00424 10 FILLER PIC X(67) VALUE SPACES. SAMPS031
00425 SAMPS031
00426 01 LIST-HEADING-5. SAMPS031
00427 10 FILLER PIC X(22) VALUE SPACES. SAMPS031
00428 10 FILLER PIC X(6) VALUE 'NUMBER'. SAMPS031
00429 10 FILLER PIC X(6) VALUE SPACES. SAMPS031
00430 10 FILLER PIC X(9) VALUE 'ID NUMBER'. SAMPS031
00431 10 FILLER PIC X(06) VALUE SPACES. SAMPS031
00432 10 FILLER PIC X(9) SAMPS031
00433 VALUE 'COMPLETED'. SAMPS031
00434 10 FILLER PIC X(5) VALUE SPACES. SAMPS031
00435 10 FILLER PIC X(7) VALUE 'NUMBER'. SAMPS031
00436 10 FILLER PIC X(63) VALUE SPACES. SAMPS031
00437 SAMPS031
00438 *************************************************************** SAMPS031
00439 ** (OUTPUT-DTL-LINE) DESCRIBES THE OUTPUT FOR THE DETAIL ** SAMPS031
00440 ** LINES OF THE REPORT. ** SAMPS031
00441 *************************************************************** SAMPS031
00442 SAMPS031
00443 01 HIT-LIST-REC. SAMPS031
00444 10 FILLER PIC X(19) VALUE SPACES. SAMPS031
00445 10 DTL-CASE-NO PIC ZZZZZZZ9 VALUE ZEROS. SAMPS031
00446 10 FILLER PIC X(6) VALUE SPACES. SAMPS031
00447 10 DTL-EMP-ID PIC X(12) VALUE SPACES. SAMPS031
00448 10 FILLER PIC X(03) VALUE SPACES. SAMPS031
00449 10 O-COMPLETED-MO PIC XX VALUE ZEROS. SAMPS031
00450 10 FILLER PIC X SAMPS031
00451 VALUE '/'. SAMPS031
00452 10 O-COMPLETED-DA PIC XX VALUE ZEROS. SAMPS031
00453 10 FILLER PIC X SAMPS031
00454 VALUE '/'. SAMPS031
00455 10 O-COMPLETED-YR PIC X(04) VALUE ZEROS. SAMPS031
00456 10 FILLER PIC X(3) VALUE SPACES. SAMPS031
00457 10 DTL-SEQ-NMBR PIC ZZZZZZZ9 VALUE ZEROS. SAMPS031
00458 10 FILLER PIC X(64) VALUE SPACES. SAMPS031
00459 SAMPS031
00460 ********************************************** SAMPS031
00461 *** *** SAMPS031
00462 ** ADDITIONAL COBOL CODE TO CREATE A CODING ** SAMPS031
00463 ** SHEET FOR THE REVENUE QUALITY CONTROL ** SAMPS031
00464 ** (RQC) REVIEWER. IT IS A DUPLICATE OF ** SAMPS031
00465 ** THE CODING SHEET IN THE RQC OPERATIONS ** SAMPS031
00466 ** HANDBOOK. ** SAMPS031
00467 *** *** SAMPS031
00468 ********************************************** SAMPS031
00469 01 FL-BANNER-LINE PIC X(132) VALUE ALL '-'. SAMPS031
00470 SAMPS031
00471 01 HD-NEW-EMP-CHECKLIST. SAMPS031
00472 SAMPS031
00473 05 FILLER PIC X(53) VALUE SPACES. SAMPS031
00474 05 FILLER PIC X(23) VALUE SAMPS031
00475 'REVENUE QUALITY CONTROL'. SAMPS031
00476 05 FILLER PIC X(34) VALUE SPACES. SAMPS031
00477 05 FILLER PIC X(06) VALUE SAMPS031
00478 'PAGE: '. SAMPS031
00479 05 HD-PAGE-NUMBER PIC ZZZZZ9. SAMPS031
00480 05 FILLER PIC X(10) VALUE SPACES. SAMPS031
00481 SAMPS031
00482 01 HT-TAX-FUNCTION-HEADER. SAMPS031
00483 SAMPS031
00484 05 FILLER PIC X(01) VALUE SPACES. SAMPS031
00485 05 FILLER PIC X(31) VALUE SAMPS031
00486 'FIELD AUDIT SAMPLE CODING SHEET'. SAMPS031
00487 05 FILLER PIC X(78) VALUE SPACES. SAMPS031
00488 05 FILLER PIC X(10) VALUE SAMPS031
00489 'RUN DATE: '. SAMPS031
00490 05 HD-RUN-DATE PIC X(08). SAMPS031
00491 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00492 SAMPS031
00493 01 FL-FIRST-LINE-COLUMN-HEADER. SAMPS031
00494 SAMPS031
00495 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00496 05 FILLER PIC X(11) VALUE SAMPS031
00497 'SESA NAME: '. SAMPS031
00498 05 FL-SESA-NAME PIC X(20). SAMPS031
00499 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00500 05 FILLER PIC X(08) VALUE SAMPS031
00501 'PERIOD: '. SAMPS031
00502 05 FL-PERIOD PIC X(04). SAMPS031
00503 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00504 05 FILLER PIC X(13) VALUE SAMPS031
00505 'SAMPLE TYPE: '. SAMPS031
00506 05 FL-SAMPLE-TYPE PIC X(24). SAMPS031
00507 05 FILLER PIC X(03) VALUE SPACES. SAMPS031
00508 05 FILLER PIC X(25) VALUE SAMPS031
00509 'REVIEWER: _______________'. SAMPS031
00510 05 FILLER PIC X(12) VALUE SPACES. SAMPS031
00511 SAMPS031
00512 01 TT-TRANSACTION-TYPE-FIELD. SAMPS031
00513 SAMPS031
00514 05 FILLER PIC X(38) VALUE SPACES. SAMPS031
00515 05 FILLER PIC X(18) SAMPS031
00516 VALUE 'TRANSACTION TYPE: '. SAMPS031
00517 05 TT-TRANS-TYPE PIC X(06). SAMPS031
00518 05 FILLER PIC X(56) VALUE SPACES. SAMPS031
00519 SAMPS031
00520 01 SL-SECOND-LINE-COL-HEADER. SAMPS031
00521 SAMPS031
00522 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00523 05 FILLER PIC X(04) VALUE SAMPS031
00524 'CASE'. SAMPS031
00525 05 FILLER PIC X(03) VALUE SPACES. SAMPS031
00526 05 FILLER PIC X(08) VALUE SAMPS031
00527 'EMPLOYER'. SAMPS031
00528 05 FILLER PIC X(06) VALUE SPACES. SAMPS031
00529 05 FILLER PIC X(01) VALUE '1'. SAMPS031
00530 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00531 05 FILLER PIC X(01) VALUE '2'. SAMPS031
00532 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00533 05 FILLER PIC X(01) VALUE '3'. SAMPS031
00534 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00535 05 FILLER PIC X(01) VALUE '4'. SAMPS031
00536 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00537 05 FILLER PIC X(01) VALUE '5'. SAMPS031
00538 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00539 05 FILLER PIC X(01) VALUE '6'. SAMPS031
00540 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00541 05 FILLER PIC X(01) VALUE '7'. SAMPS031
00542 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00543 05 FILLER PIC X(01) VALUE '8'. SAMPS031
00544 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00545 05 FILLER PIC X(01) VALUE '9'. SAMPS031
00546 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00547 05 FILLER PIC X(06) SAMPS031
00548 VALUE 'TOTAL'. SAMPS031
00549 05 FILLER PIC X(03) VALUE SPACES. SAMPS031
00550 05 FILLER PIC X(09) SAMPS031
00551 VALUE 'PASS/FAIL'. SAMPS031
00552 05 FILLER PIC X(33) VALUE SPACES. SAMPS031
00553 SAMPS031
00554 01 TL-THIRD-COLUMN-HEADER. SAMPS031
00555 SAMPS031
00556 05 FILLER PIC X(03) VALUE SPACES. SAMPS031
00557 05 FILLER PIC X(06) VALUE SAMPS031
00558 'NUMBER'. SAMPS031
00559 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00560 05 FILLER PIC X(09) VALUE SAMPS031
00561 'ID NUMBER'. SAMPS031
00562 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00563 05 FILLER PIC X(04) VALUE '(10)'. SAMPS031
00564 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00565 05 FILLER PIC X(03) VALUE '(5)'. SAMPS031
00566 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00567 05 FILLER PIC X(03) VALUE '(5)'. SAMPS031
00568 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00569 05 FILLER PIC X(04) VALUE '(25)'. SAMPS031
00570 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00571 05 FILLER PIC X(04) VALUE '(25)'. SAMPS031
00572 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00573 05 FILLER PIC X(03) VALUE '(5)'. SAMPS031
00574 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00575 05 FILLER PIC X(04) VALUE '(10)'. SAMPS031
00576 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00577 05 FILLER PIC X(03) VALUE '(5)'. SAMPS031
00578 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00579 05 FILLER PIC X(04) VALUE '(10)'. SAMPS031
00580 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00581 05 FILLER PIC X(06) VALUE 'POINTS'. SAMPS031
00582 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00583 05 FILLER PIC X(05) VALUE '(Y/N)'. SAMPS031
00584 05 FILLER PIC X(45) VALUE SPACES. SAMPS031
00585 SAMPS031
00586 01 CL-COLUMN-UNDERLINE. SAMPS031
00587 SAMPS031
00588 05 FILLER PIC X(03) VALUE SPACES. SAMPS031
00589 05 FILLER PIC X(06) VALUE SAMPS031
00590 '------'. SAMPS031
00591 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00592 05 FILLER PIC X(09) VALUE SAMPS031
00593 '---------'. SAMPS031
00594 05 FILLER PIC X(04) VALUE SPACES. SAMPS031
00595 05 FILLER PIC X(04) VALUE '----'. SAMPS031
00596 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00597 05 FILLER PIC X(03) VALUE '---'. SAMPS031
00598 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00599 05 FILLER PIC X(03) VALUE '---'. SAMPS031
00600 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00601 05 FILLER PIC X(04) VALUE '----'. SAMPS031
00602 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00603 05 FILLER PIC X(04) VALUE '----'. SAMPS031
00604 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00605 05 FILLER PIC X(03) VALUE '---'. SAMPS031
00606 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00607 05 FILLER PIC X(04) VALUE '----'. SAMPS031
00608 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00609 05 FILLER PIC X(03) VALUE '---'. SAMPS031
00610 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00611 05 FILLER PIC X(04) VALUE '----'. SAMPS031
00612 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00613 05 FILLER PIC X(06) VALUE '------'. SAMPS031
00614 05 FILLER PIC X(03) VALUE SPACES. SAMPS031
00615 05 FILLER PIC X(09) VALUE '---------'. SAMPS031
00616 05 FILLER PIC X(42) VALUE SPACES. SAMPS031
00617 SAMPS031
00618 01 DL-BANNER-LINE PIC X(92) VALUE ALL '-'. SAMPS031
00619 SAMPS031
00620 01 DL-CHECKLIST-DETAIL. SAMPS031
00621 05 DL-CHECKLIST-CASE-NO PIC ZZZZZZZ9. SAMPS031
00622 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00623 05 DL-CHECKLIST-EMP-ID PIC X(12). SAMPS031
00624 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00625 05 FILLER PIC X(04) VALUE '( )'. SAMPS031
00626 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00627 05 FILLER PIC X(03) VALUE '( )'. SAMPS031
00628 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00629 05 FILLER PIC X(03) VALUE '( )'. SAMPS031
00630 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00631 05 FILLER PIC X(04) VALUE '( )'. SAMPS031
00632 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00633 05 FILLER PIC X(04) VALUE '( )'. SAMPS031
00634 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00635 05 FILLER PIC X(03) VALUE '( )'. SAMPS031
00636 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00637 05 FILLER PIC X(04) VALUE '( )'. SAMPS031
00638 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00639 05 FILLER PIC X(03) VALUE '( )'. SAMPS031
00640 05 FILLER PIC X(02) VALUE SPACES. SAMPS031
00641 05 FILLER PIC X(04) VALUE '( )'. SAMPS031
00642 05 FILLER PIC X(03) VALUE SPACES. SAMPS031
00643 05 FILLER PIC X(05) VALUE '( )'. SAMPS031
00644 05 FILLER PIC X(05) VALUE SPACES. SAMPS031
00645 05 FILLER PIC X(05) VALUE '( )'. SAMPS031
00646 05 FILLER PIC X(42) VALUE SPACES. SAMPS031
00647 SAMPS031
00648 01 WS-FOOTNOTE1-AREA. SAMPS031
00649 05 FILLER PIC X(01) VALUE SPACES. SAMPS031
00650 05 FILLER PIC X(16) SAMPS031
00651 VALUE 'SCORING ANALYSIS'. SAMPS031
00652 05 FILLER PIC X(116) VALUE SPACES. SAMPS031
00653 SAMPS031
00654 01 WS-FOOTNOTE2-AREA. SAMPS031
00655 05 FILLER PIC X(01) VALUE SPACES. SAMPS031
00656 05 FILLER PIC X(49) SAMPS031
00657 VALUE '* AUDITS SCORING 80 OR MORE POINTS ARE ACCEPTABLE'.SAMPS031
00658 05 FILLER PIC X(82) VALUE SPACES. SAMPS031
00659 SAMPS031
00660 PROCEDURE DIVISION. SAMPS031
00661 ******************************************** SAMPS031
00662 *** *** SAMPS031
00663 ** THE DECLARATIVES SECTION THAT FOLLOWS ** SAMPS031
00664 ** IS PERFORMED IF AN INPUT/OUTPUT ERROR ** SAMPS031
00665 ** OCCURS TO THE VSAM FILE TRANS-FILE ** SAMPS031
00666 ** DURING PROCESSING. ** SAMPS031
00667 *** *** SAMPS031
00668 ******************************************** SAMPS031
00669 DECLARATIVES. SAMPS031
00670 A000-EXCEPTION-HANDLING SECTION. SAMPS031
00671 USE AFTER ERROR PROCEDURE SAMPS031
00672 ON TRANS-FILE. SAMPS031
00673 SAMPS031
00674 ******************************************* SAMPS031
00675 *** *** SAMPS031
00676 ** A100-CHECK-ERROR-ROUTINE. ** SAMPS031
00677 ** THIS SECTION WILL DISPLAY THAT AN ** SAMPS031
00678 ** INPUT/OUTPUT ERROR HAS OCCURRED, ** SAMPS031
00679 ** DISPLAY A FILE STATUS ERROR CODE ** SAMPS031
00680 ** (TRANS-FILE-ERROR-CODE), CLOSES ALL ** SAMPS031
00681 ** INPUT/OUTPUT FILES AND STOPS THE ** SAMPS031
00682 ** EXECUTION OF THE PROGRAM. ** SAMPS031
00683 *** *** SAMPS031
00684 ******************************************* SAMPS031
00685 A100-CHECK-ERROR-ROUTINE. SAMPS031
00686 SAMPS031
00687 DISPLAY 'INPUT/OUTPUT ERROR HAS OCCURRED.' SAMPS031
00688 DISPLAY 'THE FILE STATUS CODE ERROR IS : ' SAMPS031
00689 DISPLAY TRANS-FILE-ERROR-CODE SAMPS031
00690 DISPLAY ' - SAMPS031 - JOB TERMINATED ' SAMPS031
00691 CLOSE SELECT-FILE SAMPS031
00692 CLOSE CNTRL-DATA SAMPS031
00693 CLOSE TRANS-FILE SAMPS031
00694 CLOSE JOB-STATUS SAMPS031
00695 CLOSE HIT-FILE SAMPS031
00696 CLOSE HIT-LIST SAMPS031
00697 CLOSE CHECK-LIST SAMPS031
00698 STOP RUN. SAMPS031
00699 SAMPS031
00700 END DECLARATIVES. SAMPS031
00701 *************************************************************** SAMPS031
00702 ** 0000-DRIVER-ROUTINE. ** SAMPS031
00703 ** THIS SECTION PERFORMS THE MAIN PROCESSING OF THE PROGRAM. ** SAMPS031
00704 *************************************************************** SAMPS031
00705 B000-REGULAR-PROCESSING SECTION. SAMPS031
00706 0000-DRIVER-ROUTINE. SAMPS031
00707 SAMPS031
00708 PERFORM 0100-OPEN-ROUTINE SAMPS031
00709 THRU 0100-OPEN-ROUTINE-EXIT. SAMPS031
00710 PERFORM 0200-VALIDATE-TRANSACTION-TYPE SAMPS031
00711 THRU 0200-VALIDATION-EXIT. SAMPS031
00712 PERFORM 0300-STATE-TABLE-ROUTINE SAMPS031
00713 THRU 0300-STATE-TABLE-EXIT. SAMPS031
00714 PERFORM 0305-SAMPLE-TABLE-ROUTINE SAMPS031
00715 THRU 0305-SAMPLE-TABLE-EXIT. SAMPS031
00716 PERFORM 0500-SELECT-RECORDS SAMPS031
00717 THRU 0500-SELECT-RECS-EXIT SAMPS031
00718 UNTIL WS-SELECT-EOF = 'Y'. SAMPS031
00719 SAMPS031
00720 ************************************************************ SAMPS031
00721 ** 0100-OPEN-ROUTINE. ** SAMPS031
00722 ** THIS SECTION OPENS INPUT FILES CNTRL-DATA, AND ** SAMPS031
00723 ** SELECT-FILE. THE FOLLOWING OUTPUT FILES ARE OPENED: ** SAMPS031
00724 ** HIT-FILE, HIT-LIST, CHECK-LIST, AND JOB-STATUS. ** SAMPS031
00725 ** THIS SECTION ALSO OPENS THE VSAM FILE TRANS-FILE AS ** SAMPS031
00726 ** INPUT/OUTPUT, MOVES THE CURRENT DATE TO THE OUTPUT ** SAMPS031
00727 ** FILE HIT-LIST AND CHECK-LIST FOR PRINTING, AND READS ** SAMPS031
00728 ** THE RECORD IN THE CNTRL-DATA FILE. ** SAMPS031
00729 ************************************************************ SAMPS031
00730 0100-OPEN-ROUTINE. SAMPS031
00731 SAMPS031
00732 OPEN INPUT CNTRL-DATA. SAMPS031
00733 OPEN INPUT SELECT-FILE. SAMPS031
00734 OPEN I-O TRANS-FILE. SAMPS031
00735 OPEN OUTPUT HIT-FILE. SAMPS031
00736 OPEN OUTPUT HIT-LIST. SAMPS031
00737 OPEN OUTPUT CHECK-LIST. SAMPS031
00738 OPEN OUTPUT JOB-STATUS. SAMPS031
00739 ACCEPT WS-DATE FROM DATE. SAMPS031
00740 MOVE WS-YY TO WRK-YY. SAMPS031
00741 MOVE WS-MM TO WRK-MM. SAMPS031
00742 MOVE WS-DD TO WRK-DD. SAMPS031
00743 MOVE WRK-DATE-AREA TO O-RUN-DATE HD-RUN-DATE. SAMPS031
00744 READ CNTRL-DATA AT END MOVE 'Y' TO CNTRL-FLAG. SAMPS031
00745 SAMPS031
00746 0100-OPEN-ROUTINE-EXIT. SAMPS031
00747 EXIT. SAMPS031
00748 SAMPS031
00749 ******************************************************* SAMPS031
00750 *** *** SAMPS031
00751 ** 0200-VALIDATE-TRANSACTION-TYPE. ** SAMPS031
00752 ** UTILIZING THE CNTRL-TRANS-TYPE FIELD FROM THE ** SAMPS031
00753 ** INPUT FILE CNTRL-DATA, THIS PROCEDURE VALIDATES ** SAMPS031
00754 ** WHETHER THE REPORT IS A RANDOM-AUDIT OR AN OTHER- ** SAMPS031
00755 ** AUDIT REPORT. IF THE CNTRL-TRANS-TYPE IS ** SAMPS031
00756 ** NOT ANY OF THE TWO CONTROL TYPES (1 OR 2), AN ** SAMPS031
00757 ** ERROR MESSAGE IS DISPLAYED AND THE PROGRAM RUN IS ** SAMPS031
00758 ** TERMINATED. ** SAMPS031
00759 *** *** SAMPS031
00760 ******************************************************* SAMPS031
00761 SAMPS031
00762 0200-VALIDATE-TRANSACTION-TYPE. SAMPS031
00763 SAMPS031
00764 IF CNTRL-TRANS-TYPE = '1' SAMPS031
00765 MOVE RANDOMM TO DTL-OUTPUT-TRANS-TYPE SAMPS031
00766 MOVE RANDOMM TO TT-TRANS-TYPE SAMPS031
00767 ELSE SAMPS031
00768 IF CNTRL-TRANS-TYPE = '2' SAMPS031
00769 MOVE OTHER-1 TO DTL-OUTPUT-TRANS-TYPE SAMPS031
00770 MOVE OTHER-1 TO TT-TRANS-TYPE SAMPS031
00771 ELSE SAMPS031
00772 DISPLAY 'INVALID TRANSACTION TYPE' SAMPS031
00773 DISPLAY 'TRANSACTION TYPE IN ERROR IS: ' SAMPS031
00774 DISPLAY CNTRL-TRANS-TYPE SAMPS031
00775 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS031
00776 PERFORM 9999-CLOSE-FILES. SAMPS031
00777 SAMPS031
00778 0200-VALIDATION-EXIT. SAMPS031
00779 EXIT. SAMPS031
00780 SAMPS031
00781 ************************************************* SAMPS031
00782 *** *** SAMPS031
00783 ** 0300-STATE-TABLE-ROUTINE. ** SAMPS031
00784 ** THIS ROUTINE SEARCHES THE ST-STATE-DATA ** SAMPS031
00785 ** TABLE, FOUND IN THE WORKING STORAGE SECTION,** SAMPS031
00786 ** FOR A MATCHING CONDITION OF THE SESA-ID ** SAMPS031
00787 ** FIELD OF THE CNTRL-DATA FILE. IF A MATCH ** SAMPS031
00788 ** OCCURS, THE STATE ABBREVIATION (SESA-ID) IS ** SAMPS031
00789 ** REPLACED WITH THE STATE NAME DESCRIPTION. ** SAMPS031
00790 ** IF A MATCH IS NOT FOUND, AN ERROR MESSAGE IS** SAMPS031
00791 ** DISPLAYED AND THE PROGRAM RUN IS TERMINATED.** SAMPS031
00792 *** *** SAMPS031
00793 ************************************************* SAMPS031
00794 0300-STATE-TABLE-ROUTINE. SAMPS031
00795 SAMPS031
00796 SET ST-INDEX TO 1. SAMPS031
00797 SEARCH ST-STATE-ENTRY SAMPS031
00798 AT END MOVE 'END' TO ST-ENTRY-FOUND-SWITCH SAMPS031
00799 WHEN SESA-ID SAMPS031
00800 IS EQUAL TO ST-STATE-ID (ST-INDEX) SAMPS031
00801 MOVE 'YES' TO ST-ENTRY-FOUND-SWITCH. SAMPS031
00802 IF ST-ENTRY-FOUND SAMPS031
00803 MOVE ST-STATE-NAME (ST-INDEX) SAMPS031
00804 TO WS-SESA-NAME-AREA SAMPS031
00805 ELSE SAMPS031
00806 DISPLAY SESA-ID, ' - NOT FOUND ON STATE TABLE' SAMPS031
00807 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS031
00808 PERFORM 9999-CLOSE-FILES. SAMPS031
00809 SAMPS031
00810 0300-STATE-TABLE-EXIT. SAMPS031
00811 EXIT. SAMPS031
00812 SAMPS031
00813 ************************************************* SAMPS031
00814 *** *** SAMPS031
00815 ** 0305-SAMPLE-TABLE-ROUTINE. ** SAMPS031
00816 ** THIS SECTION SEARCHES THE WS-SAMPLE-DATA ** SAMPS031
00817 ** TABLE FOUND IN THE WORKING-STORAGE SECTION ** SAMPS031
00818 ** FOR A MATCHING CONDITION OF THE SAMPLE-TYPE ** SAMPS031
00819 ** FIELD OF THE CNTRL-DATA FILE. IF A MATCH ** SAMPS031
00820 ** OCCURS, THE SAMPLE TYPE ABBREVIATION IS ** SAMPS031
00821 ** REPLACED WITH THE SAMPLE-TYPE DESCRIPTION. ** SAMPS031
00822 ** IF A MATCH IS NOT FOUND, AN ERROR MESSAGE IS** SAMPS031
00823 ** DISPLAYED AND THE PROGRAM RUN IS TERMINATED.** SAMPS031
00824 *** *** SAMPS031
00825 ************************************************* SAMPS031
00826 0305-SAMPLE-TABLE-ROUTINE. SAMPS031
00827 SAMPS031
00828 SET WS-INDEX TO 1. SAMPS031
00829 SEARCH WS-SAMPLE-ENTRY SAMPS031
00830 AT END MOVE 'END' TO WS-ENTRY-FOUND-SWITCH SAMPS031
00831 WHEN SAMPLE-TYPE SAMPS031
00832 IS EQUAL TO WS-SAMPLE-ID (WS-INDEX) SAMPS031
00833 MOVE 'YES' TO WS-ENTRY-FOUND-SWITCH. SAMPS031
00834 IF WS-SAMPLE-FOUND SAMPS031
00835 MOVE WS-SAMPLE-DESCRIPTION (WS-INDEX) SAMPS031
00836 TO WS-SAMPLE-NAME-AREA SAMPS031
00837 ELSE SAMPS031
00838 DISPLAY SAMPLE-TYPE, '- NOT ON SAMPLE TABLE' SAMPS031
00839 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS031
00840 PERFORM 9999-CLOSE-FILES. SAMPS031
00841 SAMPS031
00842 0305-SAMPLE-TABLE-EXIT. SAMPS031
00843 EXIT. SAMPS031
00844 SAMPS031
00845 ********************************************************* SAMPS031
00846 *** *** SAMPS031
00847 ** 0400-HIT-LIST-HEADING. ** SAMPS031
00848 ** THIS SECTION GENERATES THE PAGE AND COLUMN ** SAMPS031
00849 ** HEADERS FOR THE HIT-LIST OUTPUT REPORT. ** SAMPS031
00850 *** *** SAMPS031
00851 ********************************************************* SAMPS031
00852 SAMPS031
00853 0400-HIT-LIST-HEADING. SAMPS031
00854 SAMPS031
00855 ADD 1 TO LIST-PAGE. SAMPS031
00856 MOVE SPACES TO PRINT-HIT-REC. SAMPS031
00857 MOVE LIST-PAGE TO O-LIST-PAGE. SAMPS031
00858 MOVE WS-SESA-NAME-AREA TO O-CNTRL-SESA-NAME. SAMPS031
00859 WRITE PRINT-HIT-REC FROM LIST-HEADING-1 SAMPS031
00860 AFTER ADVANCING PAGE. SAMPS031
00861 WRITE PRINT-HIT-REC FROM LIST-HEADING-2 SAMPS031
00862 AFTER ADVANCING 1 LINE. SAMPS031
00863 WRITE PRINT-HIT-REC FROM LIST-HEADING-3 SAMPS031
00864 AFTER ADVANCING 1 LINE. SAMPS031
00865 WRITE PRINT-HIT-REC FROM LIST-HEADING-4 SAMPS031
00866 AFTER ADVANCING 3 LINES. SAMPS031
00867 WRITE PRINT-HIT-REC FROM LIST-HEADING-5 SAMPS031
00868 AFTER ADVANCING 1 LINE. SAMPS031
00869 MOVE SPACES TO PRINT-HIT-REC. SAMPS031
00870 WRITE PRINT-HIT-REC AFTER ADVANCING 1 LINE. SAMPS031
00871 SAMPS031
00872 0400-HIT-LIST-EXIT. SAMPS031
00873 EXIT. SAMPS031
00874 SAMPS031
00875 ********************************************* SAMPS031
00876 *** *** SAMPS031
00877 ** 0405-CHECKLIST-HEADER-RTN. ** SAMPS031
00878 ** THIS SECTION CREATES THE PAGE, AND ** SAMPS031
00879 ** COLUMN HEADERS FOR THE CHECK-LIST ** SAMPS031
00880 ** OUTPUT REPORT. ** SAMPS031
00881 *** *** SAMPS031
00882 ********************************************* SAMPS031
00883 0405-CHECKLIST-HEADER-RTN. SAMPS031
00884 SAMPS031
00885 ADD 1 TO WS-PAGE-CNTR. SAMPS031
00886 MOVE SPACES TO CHECK-LIST-REC. SAMPS031
00887 MOVE WS-PAGE-CNTR TO HD-PAGE-NUMBER. SAMPS031
00888 WRITE CHECK-LIST-REC FROM FL-BANNER-LINE SAMPS031
00889 AFTER ADVANCING PAGE. SAMPS031
00890 WRITE CHECK-LIST-REC FROM HD-NEW-EMP-CHECKLIST SAMPS031
00891 AFTER ADVANCING 1 LINE. SAMPS031
00892 WRITE CHECK-LIST-REC FROM HT-TAX-FUNCTION-HEADER SAMPS031
00893 AFTER ADVANCING 1 LINE. SAMPS031
00894 WRITE CHECK-LIST-REC FROM FL-BANNER-LINE SAMPS031
00895 AFTER ADVANCING 1 LINE. SAMPS031
00896 MOVE WS-SESA-NAME-AREA TO FL-SESA-NAME. SAMPS031
00897 MOVE CNTRL-YEAR-SELECTED TO FL-PERIOD. SAMPS031
00898 MOVE WS-SAMPLE-NAME-AREA TO FL-SAMPLE-TYPE. SAMPS031
00899 WRITE CHECK-LIST-REC FROM FL-FIRST-LINE-COLUMN-HEADER SAMPS031
00900 AFTER ADVANCING 2 LINES. SAMPS031
00901 WRITE CHECK-LIST-REC FROM TT-TRANSACTION-TYPE-FIELD SAMPS031
00902 AFTER ADVANCING 1 LINE. SAMPS031
00903 WRITE CHECK-LIST-REC FROM SL-SECOND-LINE-COL-HEADER SAMPS031
00904 AFTER ADVANCING 2 LINES. SAMPS031
00905 WRITE CHECK-LIST-REC FROM TL-THIRD-COLUMN-HEADER SAMPS031
00906 AFTER ADVANCING 1 LINE. SAMPS031
00907 WRITE CHECK-LIST-REC FROM CL-COLUMN-UNDERLINE SAMPS031
00908 AFTER ADVANCING 1 LINE. SAMPS031
00909 MOVE SPACES TO CHECK-LIST-REC. SAMPS031
00910 WRITE CHECK-LIST-REC AFTER ADVANCING 1 LINES. SAMPS031
00911 SAMPS031
00912 0405-CHECKLIST-HEADER-EXIT. SAMPS031
00913 EXIT. SAMPS031
00914 SAMPS031
00915 SAMPS031
00916 *************************************************************** SAMPS031
00917 ** 0500-SELECT-RECORDS. ** SAMPS031
00918 ** THIS SECTION WILL READ THE SELECT-FILE WHICH CONTAINS ** SAMPS031
00919 ** THE SELECTED NUMBERS FOR THE SAMPLE. EACH SELECT RECORD ** SAMPS031
00920 ** WILL ALSO BE USED AS THE RECORD KEY TO READ THE SAMPLING ** SAMPS031
00921 ** TRANSACTION VSAM FILE, (TRANS-FILE). THE TRANSACTION ** SAMPS031
00922 ** FILE IS INDEXED BY A FIELD (SEQ-NMBR) WHICH IS THE KEY ** SAMPS031
00923 ** USED DURING THE READ OF THE VSAM FILE. THE VALUE OF THE ** SAMPS031
00924 ** SELECT RECORD NUMBER (SL-REC-NUM) IS MOVED TO (SEQ-NMBR) ** SAMPS031
00925 ** AND THE RECORD ON THE TRANSACTION FILE FOR THAT RECORD ** SAMPS031
00926 ** NUMBER IS READ AND PROCESSED. FOR THE RECORDS THAT HAVE ** SAMPS031
00927 ** BEEN SELECTED FROM THE TRANSACTION FILE, A SELECTED-FLAG ** SAMPS031
00928 ** FIELD IS CHANGED TO A 2, AND A RECORD IS WRITTEN TO A DISK** SAMPS031
00929 ** FILE (HIT-FILE). THIS SAME RECORD IS WRITTEN TO A HIT ** SAMPS031
00930 ** FILE LISTING (HIT-LIST), AND A CODING SHEET OUTPUT REPORT ** SAMPS031
00931 ** (CHECK-LIST). THIS PROCESSING IS CONTINUED UNTIL EACH ** SAMPS031
00932 ** RECORD FROM THE SELECT-FILE HAS BEEN READ. ** SAMPS031
00933 *************************************************************** SAMPS031
00934 0500-SELECT-RECORDS. SAMPS031
00935 SAMPS031
00936 READ SELECT-FILE SAMPS031
00937 AT END MOVE 'Y' TO WS-SELECT-EOF. SAMPS031
00938 IF WS-SELECT-EOF = 'Y' SAMPS031
00939 AND MATCH-CNTR NOT EQUAL TO SAMPLED-NMBR SAMPS031
00940 DISPLAY 'RECORDS SELECTED NE TO RECORDS DESIRED' SAMPS031
00941 MOVE MESSAGE-1 TO WS-MESSAGE-FILE SAMPS031
00942 PERFORM 9999-CLOSE-FILES. SAMPS031
00943 IF WS-SELECT-EOF = 'Y' SAMPS031
00944 AND MATCH-CNTR EQUAL TO SAMPLED-NMBR SAMPS031
00945 WRITE CHECK-LIST-REC FROM WS-FOOTNOTE1-AREA SAMPS031
00946 AFTER ADVANCING 1 LINE SAMPS031
00947 WRITE CHECK-LIST-REC FROM WS-FOOTNOTE2-AREA SAMPS031
00948 AFTER ADVANCING 1 LINE SAMPS031
00949 MOVE MESSAGE-1 TO WS-MESSAGE-FILE SAMPS031
00950 PERFORM 9999-CLOSE-FILES. SAMPS031
00951 IF WS-SELECT-EOF NOT EQUAL 'Y' SAMPS031
00952 ADD 1 TO MATCH-CNTR SAMPS031
00953 MOVE SL-REC-NUM TO SEQ-NMBR SAMPS031
00954 READ TRANS-FILE RECORD INTO WS-MATCH-RECORD. SAMPS031
00955 IF WS-HIT-LIST-SWITCH = '0' SAMPS031
00956 PERFORM 0400-HIT-LIST-HEADING SAMPS031
00957 THRU 0400-HIT-LIST-EXIT. SAMPS031
00958 IF WS-CHECKLIST-SWITCH = '0' SAMPS031
00959 PERFORM 0405-CHECKLIST-HEADER-RTN SAMPS031
00960 THRU 0405-CHECKLIST-HEADER-EXIT. SAMPS031
00961 PERFORM 0600-PRINT-HIT-RECS SAMPS031
00962 THRU 0600-PRINT-EXIT. SAMPS031
00963 MOVE SELECTED-FLAG TO SELECT-FLAG. SAMPS031
00964 MOVE SELECTED-FLAG TO MATCH-SELECT-FLAG. SAMPS031
00965 REWRITE TRANS-REC. SAMPS031
00966 SAMPS031
00967 0500-SELECT-RECS-EXIT. SAMPS031
00968 EXIT. SAMPS031
00969 SAMPS031
00970 SAMPS031
00971 *************************************************************** SAMPS031
00972 ** 0600-PRINT-HIT-RECS. ** SAMPS031
00973 ** THIS ROUTINE MOVES THE INFORMATION REQUIRED TO EACH OF ** SAMPS031
00974 ** OUTPUT FILES; HIT-FILE, HIT-LIST, AND CHECK-LIST. THE ** SAMPS031
00975 ** ROUTINE ALSO CONTROLS LINE COUNT, AND HEADER GENERATION ** SAMPS031
00976 ** FOR THE HIT-LIST, AND CHECK-LIST REPORT. ** SAMPS031
00977 *************************************************************** SAMPS031
00978 0600-PRINT-HIT-RECS. SAMPS031
00979 SAMPS031
00980 MOVE '1' TO WS-CHECKLIST-SWITCH. SAMPS031
00981 MOVE '1' TO WS-HIT-LIST-SWITCH. SAMPS031
00982 MOVE MATCH-CNTR TO DTL-CASE-NO. SAMPS031
00983 MOVE MATCH-SEQ-NMBR TO DTL-SEQ-NMBR. SAMPS031
00984 MOVE MATCH-EMP-ID TO DTL-EMP-ID. SAMPS031
00985 MOVE MATCH-DATE-COMPLETED TO DTL-DATE-COMPLETED. SAMPS031
00986 MOVE DTL-COMPLETED-YR TO O-COMPLETED-YR. SAMPS031
00987 MOVE DTL-COMPLETED-MO TO O-COMPLETED-MO. SAMPS031
00988 MOVE DTL-COMPLETED-DA TO O-COMPLETED-DA. SAMPS031
00989 MOVE CNTRL-TYPE TO HIT-RECORD-TYPE. SAMPS031
00990 MOVE SESA-ID TO HIT-STATE. SAMPS031
00991 MOVE MATCH-CNTR TO HIT-CASE-NUMBER. SAMPS031
00992 MOVE MATCH-TRANS-TYPE TO HIT-TRANS-TYPE. SAMPS031
00993 MOVE MATCH-EMP-ID TO HIT-EMPLOYER-ID. SAMPS031
00994 MOVE CNTRL-YEAR-SELECTED TO HIT-SAMPLE-YEAR. SAMPS031
00995 MOVE SAMPLE-TYPE TO HIT-SAMPLE-TYPE. SAMPS031
00996 MOVE MATCH-CNTR TO WS-CASE-HOLD-AREA. SAMPS031
00997 MOVE WS-CASE-HOLD-AREA TO DL-CHECKLIST-CASE-NO. SAMPS031
00998 MOVE MATCH-EMP-ID TO WS-EMPL-HOLD-AREA. SAMPS031
00999 MOVE WS-EMPL-HOLD-AREA TO DL-CHECKLIST-EMP-ID. SAMPS031
01000 ADD 1 TO LIST-COUNTER. SAMPS031
01001 IF LIST-COUNTER > 50 SAMPS031
01002 MOVE 1 TO LIST-COUNTER SAMPS031
01003 PERFORM 0400-HIT-LIST-HEADING SAMPS031
01004 THRU 0400-HIT-LIST-EXIT. SAMPS031
01005 WRITE PRINT-HIT-REC FROM HIT-LIST-REC. SAMPS031
01006 PERFORM 0700-CHECKLIST-ROUTINE SAMPS031
01007 THRU 0700-CHECKLIST-EXIT. SAMPS031
01008 WRITE TRANS-HIT-REC FROM OUTPUT-HIT-REC. SAMPS031
01009 SAMPS031
01010 0600-PRINT-EXIT. SAMPS031
01011 EXIT. SAMPS031
01012 SAMPS031
01013 ******************************************************* SAMPS031
01014 *** *** SAMPS031
01015 ** 0700-CHECKLIST-ROUTINE. ** SAMPS031
01016 ** THIS SECTION CONTROLS THE PROCESSING OF THE ** SAMPS031
01017 ** CHECK-LIST REPORT. ** SAMPS031
01018 *** *** SAMPS031
01019 ******************************************************* SAMPS031
01020 0700-CHECKLIST-ROUTINE. SAMPS031
01021 SAMPS031
01022 ADD 1 TO WS-CHECKLIST-CNTR. SAMPS031
01023 IF WS-CHECKLIST-CNTR > 20 SAMPS031
01024 WRITE CHECK-LIST-REC FROM WS-FOOTNOTE1-AREA SAMPS031
01025 AFTER ADVANCING 1 LINE SAMPS031
01026 WRITE CHECK-LIST-REC FROM WS-FOOTNOTE2-AREA SAMPS031
01027 AFTER ADVANCING 1 LINE SAMPS031
01028 MOVE 1 TO WS-CHECKLIST-CNTR SAMPS031
01029 PERFORM 0405-CHECKLIST-HEADER-RTN SAMPS031
01030 THRU 0405-CHECKLIST-HEADER-EXIT SAMPS031
01031 ELSE SAMPS031
01032 NEXT SENTENCE. SAMPS031
01033 WRITE CHECK-LIST-REC FROM DL-CHECKLIST-DETAIL SAMPS031
01034 AFTER ADVANCING 1 LINE. SAMPS031
01035 WRITE CHECK-LIST-REC FROM DL-BANNER-LINE SAMPS031
01036 AFTER ADVANCING 1 LINE. SAMPS031
01037 SAMPS031
01038 0700-CHECKLIST-EXIT. SAMPS031
01039 EXIT. SAMPS031
01040 SAMPS031
01041 SAMPS031
01042 *************************************************************** SAMPS031
01043 *** *** SAMPS031
01044 ** 9999-CLOSE-FILES. ** SAMPS031
01045 ** THIS SECTION WRITES AN END OF JOB MESSAGE, AND CLOSES THE ** SAMPS031
01046 ** INPUT FILES: SELECT-FILE, CNTRL-DATA, AND INPUT/OUTPUT ** SAMPS031
01047 ** FILE TRANS-FILE. THE FOLLOWING OUTPUT FILES ARE ALSO ** SAMPS031
01048 ** CLOSED: JOB-STATUS, HIT-FILE, HIT-LIST, CHECK-LIST. ** SAMPS031
01049 *** *** SAMPS031
01050 *************************************************************** SAMPS031
01051 9999-CLOSE-FILES. SAMPS031
01052 SAMPS031
01053 WRITE MESSAGE-RECORD FROM WS-EOJ-DETAIL-LINE. SAMPS031
01054 CLOSE SELECT-FILE SAMPS031
01055 CLOSE CNTRL-DATA SAMPS031
01056 CLOSE TRANS-FILE SAMPS031
01057 CLOSE JOB-STATUS SAMPS031
01058 CLOSE HIT-FILE SAMPS031
01059 CLOSE HIT-LIST SAMPS031
01060 CLOSE CHECK-LIST SAMPS031
01061 STOP RUN. SAMPS031
Reference in New Issue View Git Blame Copy Permalink