giteaadmin/DUTAS
4
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
aebe4cd149224d6205bca068416c8998025a6c5d
DUTAS/Batch/SAMPS041.cob
Neeraj Kumar ca3572c5df DUTAS re-platformed to Raincode - Initial Source Code
2025-07-21 11:20:11 -04:00

1015 lines
80 KiB
COBOL
Raw Blame History

00001 IDENTIFICATION DIVISION. 02/12/04
00002 PROGRAM-ID. SAMPS041. SAMPS041
00003 AUTHOR KENNETH FELLOWS. LV001
00004 DATE-WRITTEN NOVEMBER, 1992. SAMPS041
00005 SAMPS041
00006 *************************************************************** SAMPS041
00007 ** --------------------PROGRAM DESCRIPTION------------------ ** SAMPS041
00008 *************************************************************** SAMPS041
00009 ** CODING FOR VS COBOL VSAM ** SAMPS041
00010 *************************************************************** SAMPS041
00011 ** ** SAMPS041
00012 ** ** SAMPS041
00013 ** THIS PROGRAM READS THREE FILES AS INPUT TO THE PROGRAM, ** SAMPS041
00014 ** TRANS-FILE, CNTRL-DATA, AND SELECT-FILE. THE TRANS-FILE ** SAMPS041
00015 ** UTILIZES A VSAM FILE STRUCTURE WITH (SEQ-NMBR) AS THE ** SAMPS041
00016 ** RECORD KEY. THE CNTRL-DATA FILE CONTAINS SOME PROCESSING ** SAMPS041
00017 ** INFORMATION WHICH IS USED IN THE OUTPUT REPORTS ** SAMPS041
00018 ** HIT-FILE, HIT-LIST, AND CHECK-LIST. THE SELECT-FILE ** SAMPS041
00019 ** CONTAINS THE RECORD NUMBERS OF THE RECORDS TO BE SELECTED ** SAMPS041
00020 ** FOR THE SAMPLE. THESE NUMBERS ARE USED AS THE RECORD ** SAMPS041
00021 ** KEY (SEQ-NMBR) TO ACCESS THE TRANS-FILE. THE RECORDS ** SAMPS041
00022 ** THAT ARE READ FROM THE TRANS-FILE ARE OUTPUT TO THE THREE ** SAMPS041
00023 ** FILES, HIT-FILE, HIT-LIST, AND CHECK-LIST. EACH RECORD ** SAMPS041
00024 ** THAT IS READ IS ALSO UPDATED TO INDICATE THAT THE RECORD ** SAMPS041
00025 ** WAS SELECTED AS PART OF THE SAMPLE. THIS IS DONE BY ** SAMPS041
00026 ** CHANGING THE SELECTED-FLAG FIELD FROM A '1' TO A '2'. ** SAMPS041
00027 ** ** SAMPS041
00028 *************************************************************** SAMPS041
00029 SAMPS041
00030 ENVIRONMENT DIVISION. SAMPS041
00031 CONFIGURATION SECTION. SAMPS041
00032 INPUT-OUTPUT SECTION. SAMPS041
00033 FILE-CONTROL. SAMPS041
00034 SELECT TRANS-FILE SAMPS041
00035 ASSIGN TO SYS003-DISKUNIT SAMPS041
00036 ORGANIZATION IS INDEXED SAMPS041
00037 ACCESS MODE IS RANDOM SAMPS041
00038 RECORD KEY IS SEQ-NMBR SAMPS041
00039 FILE STATUS IS TRANS-FILE-ERROR-CODE. SAMPS041
00040 SELECT CNTRL-DATA SAMPS041
00041 ASSIGN TO UT-S-CNTRLDTA. SAMPS041
00042 SELECT SELECT-FILE SAMPS041
00043 ASSIGN TO UT-S-SLCTREC. SAMPS041
00044 SELECT HIT-FILE SAMPS041
00045 ASSIGN TO UT-S-HITFILE. SAMPS041
00046 SELECT HIT-LIST SAMPS041
00047 ASSIGN TO UT-S-PRINTER. SAMPS041
00048 SELECT CHECK-LIST SAMPS041
00049 ASSIGN TO UT-S-CHECK. SAMPS041
00050 SELECT JOB-STATUS SAMPS041
00051 ASSIGN TO UT-S-MSGOUT. SAMPS041
00052 SAMPS041
00053 DATA DIVISION. SAMPS041
00054 FILE SECTION. SAMPS041
00055 SAMPS041
00056 *************************************************************** SAMPS041
00057 ** TRANS-FILE IS THE VSAM FILE CREATED BY THE STATE ** SAMPS041
00058 ** EMPLOYMENT SECURITY AGENCIES (SESA) WITH THE RECORDS THAT ** SAMPS041
00059 ** MAKE UP THE SAMPLING UNIVERSE. THE KEY OF THE FILE IS ** SAMPS041
00060 ** (SEQ-NMBR). THIS FIELD CONTAINS THE SEQUENTIAL RECORD ** SAMPS041
00061 ** NUMBER. ** SAMPS041
00062 *************************************************************** SAMPS041
00063 FD TRANS-FILE SAMPS041
00064 LABEL RECORDS ARE STANDARD SAMPS041
00065 BLOCK CONTAINS 0 RECORDS. SAMPS041
00066 01 TRANS-REC. SAMPS041
00067 05 SEQ-NMBR PIC 9(8). SAMPS041
00068 05 REC-TYPE PIC X(5). SAMPS041
00069 05 TRANS-TYPE PIC X. SAMPS041
00070 05 SELECT-FLAG PIC 9. SAMPS041
00071 05 EMP-ID PIC X(12). SAMPS041
00072 05 DATE-COMPLETED PIC 9(8). SAMPS041
00073 05 STATE-OPTION PIC X(25). SAMPS041
00074 SAMPS041
00075 ******************************************************************SAMPS041
00076 ** CNTRL-DATA CONTAINS SOME OF THE PROCESSING INFORMATION **SAMPS041
00077 ** NEEDED FOR SAMPLING. IT CONTAINS THE RANDOM NUMBER **SAMPS041
00078 ** (CNTRL-RANDOM), THE NUMBER OF RECORDS TO BE SELECTED FOR **SAMPS041
00079 ** THE SAMPLE (SAMPLED-NMBR), AND THE RECORD COUNT OF THE **SAMPS041
00080 ** NUMBER OF RECORDS (TRANS-REC-CNTR) CONTAINED ON THE **SAMPS041
00081 ** TRANS-FILE. FOR THE PURPOSE OF THIS PROGRAM, ONLY **SAMPS041
00082 ** THE SESA-ID FIELD, SAMPLE-TYPE, AND SAMPLED-NMBR ARE NEEDED.** SAMPS041
00083 ******************************************************************SAMPS041
00084 SAMPS041
00085 FD CNTRL-DATA SAMPS041
00086 RECORDING MODE IS F SAMPS041
00087 LABEL RECORD IS OMITTED SAMPS041
00088 BLOCK CONTAINS 1 RECORDS. SAMPS041
00089 01 CNTRL-DATA-REC. SAMPS041
00090 05 CNTRL-TYPE PIC X(5). SAMPS041
00091 05 CNTRL-TRANS-TYPE PIC X. SAMPS041
00092 05 SESA-ID PIC XX. SAMPS041
00093 05 CNTRL-RANDOM PIC V999. SAMPS041
00094 05 CNTRL-RANDOM-ALF REDEFINES CNTRL-RANDOM PIC X(3). SAMPS041
00095 05 SAMPLED-NMBR PIC 9(4). SAMPS041
00096 05 SAMPLED-NMBR-ALF REDEFINES SAMPLED-NMBR PIC X(4). SAMPS041
00097 05 TRANS-REC-CNTR PIC 9(8). SAMPS041
00098 05 TRANS-REC-CNTR-ALF REDEFINES TRANS-REC-CNTR PIC X(8). SAMPS041
00099 05 SAMPLE-TYPE PIC X(02). SAMPS041
00100 05 CNTRL-YEAR-QTR PIC 9(05). SAMPS041
00101 05 DATE-FILLER PIC 9(3). SAMPS041
00102 SAMPS041
00103 *************************************************************** SAMPS041
00104 ** HIT-LIST CONTAINS THE PRINTED REPORT OF THE RECORDS ** SAMPS041
00105 ** SELECTED FOR SAMPLING. ** SAMPS041
00106 *************************************************************** SAMPS041
00107 SAMPS041
00108 FD HIT-LIST SAMPS041
00109 LABEL RECORD IS STANDARD. SAMPS041
00110 01 PRINT-HIT-REC PIC X(132). SAMPS041
00111 SAMPS041
00112 ************************************************************* SAMPS041
00113 *** *** SAMPS041
00114 ** THE CHECK-LIST CONTAINS THE INFORMATION NECCESSARY ** SAMPS041
00115 ** TO CARRY OUT THE REVENUE QUALITY CONTROL (RQC) ** SAMPS041
00116 ** CONTRIBUTION REPORT PROCESSING TAX FUNCTION. THIS ** SAMPS041
00117 ** CHECK LIST IS A DUPLICATE OF THE CONTRIBUTION REPORT ** SAMPS041
00118 ** SAMPLING CODING SHEET IN THE RQC HANDBOOK. ** SAMPS041
00119 *** *** SAMPS041
00120 ************************************************************* SAMPS041
00121 FD CHECK-LIST SAMPS041
00122 LABEL RECORD IS STANDARD. SAMPS041
00123 01 CHECK-LIST-REC PIC X(132). SAMPS041
00124 SAMPS041
00125 *************************************************************** SAMPS041
00126 ** HIT-FILE IS THE DATA FILE FOR STORING THE RECORDS THAT ** SAMPS041
00127 ** HAVE BEEN SELECTED FROM THE (TRANS-FILE) FOR THE SAMPLE. ** SAMPS041
00128 ** THESE RECORDS ARE WRITTEN TO A DISK FILE WITH DELIMITERS ** SAMPS041
00129 ** OF '|' BETWEEN EACH FIELD OF THE RECORD. THIS FILE ** SAMPS041
00130 ** (HIT-FILE), WILL BE PASSED TO THE INFORMIX SIDE OF THE ** SAMPS041
00131 ** RQC SYSTEM FOR FURTHER PROCESSING. ** SAMPS041
00132 *************************************************************** SAMPS041
00133 SAMPS041
00134 FD HIT-FILE SAMPS041
00135 LABEL RECORDS ARE STANDARD. SAMPS041
00136 01 TRANS-HIT-REC PIC X(42). SAMPS041
00137 SAMPS041
00138 ********************************************************* SAMPS041
00139 *** *** SAMPS041
00140 ** THE SELECT-FILE IS THE INPUT FILE THAT CONTAINS THE ** SAMPS041
00141 ** RECORD NUMBERS CREATED IN THE SAMPLE DETERMINATION ** SAMPS041
00142 ** PROGRAM (PICKNMBR). THESE NUMBERS ARE USED AS THE ** SAMPS041
00143 ** RECORD KEY TO SELECT THE RECORDS FROM THE VSAM ** SAMPS041
00144 ** FILE (TRANS-FILE) FOR SAMPLING. ** SAMPS041
00145 *** *** SAMPS041
00146 ********************************************************* SAMPS041
00147 FD SELECT-FILE SAMPS041
00148 LABEL RECORD IS OMITTED SAMPS041
00149 BLOCK CONTAINS 0 RECORDS. SAMPS041
00150 01 SL-REC-NUM PIC 9(08). SAMPS041
00151 SAMPS041
00152 ********************************************** SAMPS041
00153 *** *** SAMPS041
00154 ** THE JOB-STATUS FILE IS A SEPERATE FILE ** SAMPS041
00155 ** CREATED TO OUTPUT THE END OF JOB MESSAGES** SAMPS041
00156 ** SAMPS041 - NORMAL END OF JOB, AND ** SAMPS041
00157 ** SAMPS041 - JOB TERMINATED. ** SAMPS041
00158 *** *** SAMPS041
00159 ********************************************** SAMPS041
00160 FD JOB-STATUS SAMPS041
00161 LABEL RECORD IS STANDARD. SAMPS041
00162 01 MESSAGE-RECORD PIC X(132). SAMPS041
00163 SAMPS041
00164 WORKING-STORAGE SECTION. SAMPS041
001645 77 PAN-VALET PICTURE X(24) VALUE '001SAMPS041 02/12/04'. SAMPS041
00165 SAMPS041
00166 01 WS-WORK-AREA. SAMPS041
00167 05 MATCH-CNTR PIC 9(08) VALUE 0. SAMPS041
00168 05 WS-SELECT-EOF PIC X(01) VALUE 'N'. SAMPS041
00169 05 CNTRL-FLAG PIC X(01) VALUE 'N'. SAMPS041
00170 05 SELECTED-FLAG PIC 9(01) VALUE 2. SAMPS041
00171 05 LIST-COUNTER PIC 9(02) VALUE 0. SAMPS041
00172 05 LIST-PAGE PIC 9(06) VALUE 0. SAMPS041
00173 SAMPS041
00174 05 WS-DATE PIC 9(06) VALUE ZEROES. SAMPS041
00175 05 WS-DATE-R REDEFINES WS-DATE. SAMPS041
00176 10 WS-YY PIC 9(02). SAMPS041
00177 10 WS-MM PIC 9(02). SAMPS041
00178 10 WS-DD PIC 9(02). SAMPS041
00179 SAMPS041
00180 05 WRK-DATE-AREA. SAMPS041
00181 10 WRK-MM PIC X(02). SAMPS041
00182 10 FILLER PIC X(01) VALUE '/'. SAMPS041
00183 10 WRK-DD PIC X(02). SAMPS041
00184 10 FILLER PIC X(01) VALUE '/'. SAMPS041
00185 10 WRK-YY PIC X(02). SAMPS041
00186 SAMPS041
00187 *************************************************** SAMPS041
00188 *** *** SAMPS041
00189 ** TRANS-FILE-ERROR-CODE: ** SAMPS041
00190 ** FILE STATUS FIELD WHICH STORES THE VALUE ** SAMPS041
00191 ** OF AN ERROR CODE IF AN ERROR IS ENCOUNTERED ** SAMPS041
00192 ** DURING A READ OR WRITE TO THE VSAM (TRANS- ** SAMPS041
00193 ** FILE) FILE. ** SAMPS041
00194 *** *** SAMPS041
00195 *************************************************** SAMPS041
00196 SAMPS041
00197 01 TRANS-FILE-ERROR-CODE PIC X(02). SAMPS041
00198 SAMPS041
00199 01 WS-REPORT-CONTROLS. SAMPS041
00200 05 WS-CHECKLIST-CNTR PIC 9(02) VALUE 0. SAMPS041
00201 05 WS-PAGE-CNTR PIC 9(04) VALUE 0. SAMPS041
00202 SAMPS041
00203 01 WS-HEADER-SWITCH-AREA. SAMPS041
00204 05 WS-CHECKLIST-SWITCH PIC X(01) VALUE '0'. SAMPS041
00205 05 WS-HIT-LIST-SWITCH PIC X(01) VALUE '0'. SAMPS041
00206 SAMPS041
00207 01 WS-CHECKLIST-HOLD-AREA. SAMPS041
00208 SAMPS041
00209 05 WS-EMPL-HOLD-AREA PIC X(12). SAMPS041
00210 05 WS-CASE-HOLD-AREA PIC 9(08). SAMPS041
00211 05 WS-SESA-NAME-AREA PIC X(20). SAMPS041
00212 05 WS-SAMPLE-NAME-AREA PIC X(24). SAMPS041
00213 SAMPS041
00214 *************************************************************** SAMPS041
00215 ** WS-MATCH-RECORD: ** SAMPS041
00216 ** STORES THE VALUE OF THE SELECTED RECORDS FROM THE VSAM ** SAMPS041
00217 ** FILE (TRANS-FILE). ** SAMPS041
00218 *************************************************************** SAMPS041
00219 SAMPS041
00220 01 WS-MATCH-RECORD. SAMPS041
00221 05 MATCH-SEQ-NMBR PIC 9(8). SAMPS041
00222 05 MATCH-REC-TYPE PIC X(5). SAMPS041
00223 05 MATCH-TRANS-TYPE PIC X(01). SAMPS041
00224 05 MATCH-SELECT-FLAG PIC X(01). SAMPS041
00225 05 MATCH-EMP-ID PIC X(12). SAMPS041
00226 05 MATCH-DATE-COMPLETED PIC X(8). SAMPS041
00227 05 MATCH-STATE-OPTION PIC X(25). SAMPS041
00228 SAMPS041
00229 01 WS-SAMPLE-TABLE-CONTROLS. SAMPS041
00230 05 WS-ENTRY-FOUND-SWITCH PIC X(03). SAMPS041
00231 88 WS-SAMPLE-FOUND VALUE 'YES'. SAMPS041
00232 88 WS-END-OF-SAMPLE-TABLE VALUE 'END'. SAMPS041
00233 SAMPS041
00234 *************************************************** SAMPS041
00235 *** *** SAMPS041
00236 ** WS-SAMPLE-DATA: ** SAMPS041
00237 ** CONTAINS THE RQC - SAMPLE TYPE: A 2 CHARACTER ** SAMPS041
00238 ** CODE AND A 24 CHARACTER DEFINITION. ** SAMPS041
00239 *** *** SAMPS041
00240 *************************************************** SAMPS041
00241 SAMPS041
00242 01 WS-SAMPLE-DATA. SAMPS041
00243 05 FILLER PIC X(26) SAMPS041
00244 VALUE 'A11ST ACCEPTANCE SAMPLE '. SAMPS041
00245 05 FILLER PIC X(26) SAMPS041
00246 VALUE 'A22ND ACCEPTANCE SAMPLE '. SAMPS041
00247 05 FILLER PIC X(26) SAMPS041
00248 VALUE 'E1EXPANDED SAMPLE '. SAMPS041
00249 05 FILLER PIC X(26) SAMPS041
00250 VALUE 'O11ST SESA OPTIONAL SAMPLE'. SAMPS041
00251 05 FILLER PIC X(26) SAMPS041
00252 VALUE 'O22ND SESA OPTIONAL SAMPLE'. SAMPS041
00253 01 WS-SAMPLE-TABLE REDEFINES WS-SAMPLE-DATA. SAMPS041
00254 05 WS-SAMPLE-ENTRY OCCURS 5 TIMES SAMPS041
00255 INDEXED BY WS-INDEX. SAMPS041
00256 10 WS-SAMPLE-ID PIC X(02). SAMPS041
00257 10 WS-SAMPLE-DESCRIPTION PIC X(24). SAMPS041
00258 SAMPS041
00259 01 ST-TABLE-CONTROLS. SAMPS041
00260 05 ST-ENTRY-FOUND-SWITCH PIC X(03). SAMPS041
00261 88 ST-ENTRY-FOUND VALUE 'YES'. SAMPS041
00262 88 ST-END-OF-TABLE VALUE 'END'. SAMPS041
00263 SAMPS041
00264 ************************************************** SAMPS041
00265 *** *** SAMPS041
00266 ** ST-STATE-DATA: ** SAMPS041
00267 ** CONTAINS THE FIPS CODE AND STATE NAME. ** SAMPS041
00268 *** *** SAMPS041
00269 ************************************************** SAMPS041
00270 SAMPS041
00271 01 ST-STATE-DATA. SAMPS041
00272 05 FILLER PIC X(22) VALUE 'AKALASKA '. SAMPS041
00273 05 FILLER PIC X(22) VALUE 'ALALABAMA '. SAMPS041
00274 05 FILLER PIC X(22) VALUE 'ARARKANSAS '. SAMPS041
00275 05 FILLER PIC X(22) VALUE 'AZARIZONA '. SAMPS041
00276 05 FILLER PIC X(22) VALUE 'CACALIFORNIA '. SAMPS041
00277 05 FILLER PIC X(22) VALUE 'COCOLORADO '. SAMPS041
00278 05 FILLER PIC X(22) VALUE 'CTCONNECTICUT '. SAMPS041
00279 05 FILLER PIC X(22) VALUE 'DCDISTRICT OF COLUMBIA'. SAMPS041
00280 05 FILLER PIC X(22) VALUE 'DEDELAWARE '. SAMPS041
00281 05 FILLER PIC X(22) VALUE 'FLFLORIDA '. SAMPS041
00282 05 FILLER PIC X(22) VALUE 'GAGEORGIA '. SAMPS041
00283 05 FILLER PIC X(22) VALUE 'HIHAWAII '. SAMPS041
00284 05 FILLER PIC X(22) VALUE 'IAIOWA '. SAMPS041
00285 05 FILLER PIC X(22) VALUE 'IDIDAHO '. SAMPS041
00286 05 FILLER PIC X(22) VALUE 'ILILLINOIS '. SAMPS041
00287 05 FILLER PIC X(22) VALUE 'ININDIANA '. SAMPS041
00288 05 FILLER PIC X(22) VALUE 'KSKANSAS '. SAMPS041
00289 05 FILLER PIC X(22) VALUE 'KYKENTUCKY '. SAMPS041
00290 05 FILLER PIC X(22) VALUE 'LALOUISIANA '. SAMPS041
00291 05 FILLER PIC X(22) VALUE 'MAMASSACHUSETTS '. SAMPS041
00292 05 FILLER PIC X(22) VALUE 'MDMARYLAND '. SAMPS041
00293 05 FILLER PIC X(22) VALUE 'MEMAINE '. SAMPS041
00294 05 FILLER PIC X(22) VALUE 'MIMICHIGAN '. SAMPS041
00295 05 FILLER PIC X(22) VALUE 'MNMINNESOTA '. SAMPS041
00296 05 FILLER PIC X(22) VALUE 'MOMISSOURI '. SAMPS041
00297 05 FILLER PIC X(22) VALUE 'MSMISSISSIPPI '. SAMPS041
00298 05 FILLER PIC X(22) VALUE 'MTMONTANA '. SAMPS041
00299 05 FILLER PIC X(22) VALUE 'NENEBRASKA '. SAMPS041
00300 05 FILLER PIC X(22) VALUE 'NHNEW HAMSHIRE '. SAMPS041
00301 05 FILLER PIC X(22) VALUE 'NJNEW JERSEY '. SAMPS041
00302 05 FILLER PIC X(22) VALUE 'NMNEW MEXICO '. SAMPS041
00303 05 FILLER PIC X(22) VALUE 'NVNEVADA '. SAMPS041
00304 05 FILLER PIC X(22) VALUE 'NYNEW YORK '. SAMPS041
00305 05 FILLER PIC X(22) VALUE 'NCNORTH CAROLINA '. SAMPS041
00306 05 FILLER PIC X(22) VALUE 'NDNORTH DAKOTA '. SAMPS041
00307 05 FILLER PIC X(22) VALUE 'OHOHIO '. SAMPS041
00308 05 FILLER PIC X(22) VALUE 'OKOKLAHOMA '. SAMPS041
00309 05 FILLER PIC X(22) VALUE 'OROREGON '. SAMPS041
00310 05 FILLER PIC X(22) VALUE 'PAPENNSYLVANIA '. SAMPS041
00311 05 FILLER PIC X(22) VALUE 'PRPUERTO RICO '. SAMPS041
00312 05 FILLER PIC X(22) VALUE 'RIRHODE ISLAND '. SAMPS041
00313 05 FILLER PIC X(22) VALUE 'SCSOUTH CAROLINA '. SAMPS041
00314 05 FILLER PIC X(22) VALUE 'SDSOUTH DAKOTA '. SAMPS041
00315 05 FILLER PIC X(22) VALUE 'TNTENNESSEE '. SAMPS041
00316 05 FILLER PIC X(22) VALUE 'TXTEXAS '. SAMPS041
00317 05 FILLER PIC X(22) VALUE 'UTUTAH '. SAMPS041
00318 05 FILLER PIC X(22) VALUE 'VAVIRGINIA '. SAMPS041
00319 05 FILLER PIC X(22) VALUE 'VIVIRGIN ISLAND '. SAMPS041
00320 05 FILLER PIC X(22) VALUE 'VTVERMONT '. SAMPS041
00321 05 FILLER PIC X(22) VALUE 'WAWASHINGTON '. SAMPS041
00322 05 FILLER PIC X(22) VALUE 'WVWEST VIRGINIA '. SAMPS041
00323 05 FILLER PIC X(22) VALUE 'WIWISCONSIN '. SAMPS041
00324 05 FILLER PIC X(22) VALUE 'WYWYOMING '. SAMPS041
00325 01 ST-STATE-TABLE REDEFINES ST-STATE-DATA. SAMPS041
00326 05 ST-STATE-ENTRY OCCURS 53 TIMES SAMPS041
00327 INDEXED BY ST-INDEX. SAMPS041
00328 10 ST-STATE-ID PIC X(02). SAMPS041
00329 10 ST-STATE-NAME PIC X(20). SAMPS041
00330 SAMPS041
00331 SAMPS041
00332 ************************************************ SAMPS041
00333 *** *** SAMPS041
00334 ** WS-END-OF-JOB-MESSAGES: ** SAMPS041
00335 ** END OF JOB STATUS MESSAGES: MESSAGE-1 ** SAMPS041
00336 ** AND MESSAGE-2. ** SAMPS041
00337 *** *** SAMPS041
00338 ************************************************ SAMPS041
00339 SAMPS041
00340 01 WS-END-OF-JOB-MESSAGES. SAMPS041
00341 05 MESSAGE-1 PIC X(28) SAMPS041
00342 VALUE 'SAMPS041 - NORMAL END OF JOB'. SAMPS041
00343 05 MESSAGE-2 PIC X(28) SAMPS041
00344 VALUE 'SAMPS041 - JOB TERMINATED '. SAMPS041
00345 SAMPS041
00346 01 WS-EOJ-DETAIL-LINE. SAMPS041
00347 05 FILLER PIC X(02) VALUE SPACES. SAMPS041
00348 05 WS-MESSAGE-FILE PIC X(28). SAMPS041
00349 05 FILLER PIC X(102) VALUE SPACES. SAMPS041
00350 SAMPS041
00351 01 DTL-DATE-REFORMAT-AREA. SAMPS041
00352 05 DTL-DATE-COMPLETED PIC X(08). SAMPS041
00353 05 FILLER REDEFINES DTL-DATE-COMPLETED. SAMPS041
00354 10 DTL-COMPLETED-YR PIC X(04). SAMPS041
00355 10 DTL-COMPLETED-MO PIC X(02). SAMPS041
00356 10 DTL-COMPLETED-DA PIC X(02). SAMPS041
00357 SAMPS041
00358 01 WS-CHECKLIST-PERIOD-REFORMAT. SAMPS041
00359 05 WS-PERIOD-DATE PIC X(05). SAMPS041
00360 05 WS-PERIOD-X REDEFINES WS-PERIOD-DATE. SAMPS041
00361 10 WS-CHECKLIST-YEAR PIC X(04). SAMPS041
00362 10 WS-CHECKLIST-QTR PIC X(01). SAMPS041
00363 SAMPS041
00364 *************************************************************** SAMPS041
00365 *** *** SAMPS041
00366 ** (OUTPUT-HIT-REC) IS THE RECORD LAYOUT FOR THE RECORDS ** SAMPS041
00367 ** THAT ARE WRITTEN TO THE FILE (HIT-FILE). THIS FILE CAN ** SAMPS041
00368 ** BE DOWNLOADED TO SUN MICOCOMPUTER INTO THE CORE RQC ** SAMPS041
00369 ** SAMPLING SUBSYSTEM. ** SAMPS041
00370 *** *** SAMPS041
00371 *************************************************************** SAMPS041
00372 01 OUTPUT-HIT-REC. SAMPS041
00373 SAMPS041
00374 05 HIT-REC-TYPE PIC X(05) VALUE SPACES. SAMPS041
00375 05 FILLER PIC X(01) VALUE '|'. SAMPS041
00376 05 HIT-STATE PIC X(02) VALUE SPACES. SAMPS041
00377 05 FILLER PIC X(01) VALUE '|'. SAMPS041
00378 05 HIT-SAMPLE-YEAR PIC X(05) VALUE SPACES. SAMPS041
00379 05 FILLER PIC X(01) VALUE '|'. SAMPS041
00380 05 HIT-TRANS-TYPE PIC X(01) VALUE ZEROS. SAMPS041
00381 05 FILLER PIC X(01) VALUE '|'. SAMPS041
00382 05 HIT-SAMPLE-TYPE PIC X(02) VALUE ZEROS. SAMPS041
00383 05 FILLER PIC X(01) VALUE '|'. SAMPS041
00384 05 HIT-CASE-NUMBER PIC 9(08) VALUE ZEROS. SAMPS041
00385 05 FILLER PIC X(01) VALUE '|'. SAMPS041
00386 05 HIT-EMPLOYER-ID PIC X(12) VALUE SPACES. SAMPS041
00387 05 FILLER PIC X(01) VALUE '|'. SAMPS041
00388 SAMPS041
00389 *************************************************************** SAMPS041
00390 ** (OUTPUT-TITLES) DESCRIBES THE LINES FOR EACH LINE OF THE ** SAMPS041
00391 ** REPORT TITLE. ** SAMPS041
00392 *************************************************************** SAMPS041
00393 SAMPS041
00394 01 LIST-HEADING-1. SAMPS041
00395 10 FILLER PIC X(1) VALUE SPACES. SAMPS041
00396 10 FILLER PIC X(9) VALUE 'RUN DATE:'. SAMPS041
00397 10 FILLER PIC X(1) VALUE SPACES. SAMPS041
00398 10 O-RUN-DATE PIC X(8) VALUE SPACES. SAMPS041
00399 10 FILLER PIC X(17) VALUE SPACES. SAMPS041
00400 10 FILLER PIC X(19) VALUE SAMPS041
00401 'CONTRIBUTION REPORT'. SAMPS041
00402 10 FILLER PIC X(17) VALUE SPACES. SAMPS041
00403 10 FILLER PIC X(5) VALUE 'PAGE:'. SAMPS041
00404 10 FILLER PIC X(1) VALUE SPACES. SAMPS041
00405 10 O-LIST-PAGE PIC ZZZZZ9. SAMPS041
00406 10 FILLER PIC X(17) VALUE SPACES. SAMPS041
00407 SAMPS041
00408 01 LIST-HEADING-2. SAMPS041
00409 10 FILLER PIC X(36) VALUE SPACES. SAMPS041
00410 10 FILLER PIC X(25) SAMPS041
00411 VALUE 'SAMPLING HIT FILE LISTING'. SAMPS041
00412 10 FILLER PIC X(71) VALUE SPACES. SAMPS041
00413 SAMPS041
00414 01 LIST-HEADING-3. SAMPS041
00415 10 FILLER PIC X(36) VALUE SPACES. SAMPS041
00416 10 FILLER PIC X(9) VALUE 'STATE OF '. SAMPS041
00417 10 O-CNTRL-SESA-NAME PIC X(20) VALUE SPACES. SAMPS041
00418 10 FILLER PIC X(67) VALUE SPACES. SAMPS041
00419 SAMPS041
00420 01 LIST-HEADING-4. SAMPS041
00421 10 FILLER PIC X(22) VALUE SPACES. SAMPS041
00422 10 FILLER PIC X(4) VALUE 'CASE'. SAMPS041
00423 10 FILLER PIC X(8) VALUE SPACES. SAMPS041
00424 10 FILLER PIC X(8) VALUE 'EMPLOYER'. SAMPS041
00425 10 FILLER PIC X(09) VALUE SPACES. SAMPS041
00426 10 FILLER PIC X(4) VALUE 'DATE'. SAMPS041
00427 10 FILLER PIC X(7) VALUE SPACES. SAMPS041
00428 10 FILLER PIC X(8) VALUE 'SEQUENCE'. SAMPS041
00429 10 FILLER PIC X(67) VALUE SPACES. SAMPS041
00430 SAMPS041
00431 01 LIST-HEADING-5. SAMPS041
00432 10 FILLER PIC X(22) VALUE SPACES. SAMPS041
00433 10 FILLER PIC X(6) VALUE 'NUMBER'. SAMPS041
00434 10 FILLER PIC X(6) VALUE SPACES. SAMPS041
00435 10 FILLER PIC X(9) VALUE 'ID NUMBER'. SAMPS041
00436 10 FILLER PIC X(06) VALUE SPACES. SAMPS041
00437 10 FILLER PIC X(9) SAMPS041
00438 VALUE 'COMPLETED'. SAMPS041
00439 10 FILLER PIC X(5) VALUE SPACES. SAMPS041
00440 10 FILLER PIC X(7) VALUE 'NUMBER'. SAMPS041
00441 10 FILLER PIC X(63) VALUE SPACES. SAMPS041
00442 SAMPS041
00443 *************************************************************** SAMPS041
00444 ** (OUTPUT-DTL-LINE) DESCRIBES THE OUTPUT FOR THE DETAIL ** SAMPS041
00445 ** LINES OF THE REPORT. ** SAMPS041
00446 *************************************************************** SAMPS041
00447 SAMPS041
00448 01 HIT-LIST-REC. SAMPS041
00449 10 FILLER PIC X(19) VALUE SPACES. SAMPS041
00450 10 DTL-CASE-NO PIC ZZZZZZZ9 VALUE ZEROS. SAMPS041
00451 10 FILLER PIC X(06) VALUE SPACES. SAMPS041
00452 10 DTL-EMP-ID PIC X(12) VALUE SPACES. SAMPS041
00453 10 FILLER PIC X(04) VALUE SPACES. SAMPS041
00454 10 O-COMPLETED-MO PIC X(02) VALUE ZEROS. SAMPS041
00455 10 FILLER PIC X SAMPS041
00456 VALUE '/'. SAMPS041
00457 10 O-COMPLETED-DA PIC X(02) VALUE ZEROS. SAMPS041
00458 10 FILLER PIC X SAMPS041
00459 VALUE '/'. SAMPS041
00460 10 O-COMPLETED-YR PIC X(04) VALUE ZEROS. SAMPS041
00461 10 FILLER PIC X(02) VALUE SPACES. SAMPS041
00462 10 DTL-SEQ-NMBR PIC ZZZZZZZ9 VALUE ZEROS. SAMPS041
00463 10 FILLER PIC X(63) VALUE SPACES. SAMPS041
00464 SAMPS041
00465 ********************************************** SAMPS041
00466 *** *** SAMPS041
00467 ** ADDITIONAL COBOL CODE TO CREATE A CODING ** SAMPS041
00468 ** SHEET FOR THE REVENUE QUALITY CONTROL ** SAMPS041
00469 ** (RQC) REVIEWER. IT IS A DUPLICATE OF ** SAMPS041
00470 ** THE CODING SHEET IN THE RQC OPERATIONS ** SAMPS041
00471 ** HANDBOOK. ** SAMPS041
00472 *** *** SAMPS041
00473 ********************************************** SAMPS041
00474 01 FL-BANNER-LINE PIC X(132) VALUE ALL '-'. SAMPS041
00475 SAMPS041
00476 01 HD-NEW-EMP-CHECKLIST. SAMPS041
00477 SAMPS041
00478 05 FILLER PIC X(53) VALUE SPACES. SAMPS041
00479 05 FILLER PIC X(23) VALUE SAMPS041
00480 'REVENUE QUALITY CONTROL'. SAMPS041
00481 05 FILLER PIC X(32) VALUE SPACES. SAMPS041
00482 05 FILLER PIC X(06) VALUE SAMPS041
00483 'PAGE: '. SAMPS041
00484 05 HD-PAGE-NUMBER PIC ZZZZZ9. SAMPS041
00485 05 FILLER PIC X(10) VALUE SPACES. SAMPS041
00486 SAMPS041
00487 01 HT-TAX-FUNCTION-HEADER. SAMPS041
00488 SAMPS041
00489 05 FILLER PIC X(01) VALUE SPACES. SAMPS041
00490 05 FILLER PIC X(42) VALUE SAMPS041
00491 'ACCOUNT MAINTENANCE SAMPLING CODING SHEET'. SAMPS041
00492 05 FILLER PIC X(65) VALUE SPACES. SAMPS041
00493 05 FILLER PIC X(10) VALUE SAMPS041
00494 'RUN DATE: '. SAMPS041
00495 05 HD-RUN-DATE PIC X(08). SAMPS041
00496 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00497 SAMPS041
00498 01 HT-TAX-FUNCTION-2. SAMPS041
00499 05 FILLER PIC X(01) VALUE SPACES. SAMPS041
00500 05 FILLER PIC X(54) VALUE SAMPS041
00501 'QUARTERY CONTRIBUTION REPORT PROCESSING - CHECKLIST #1'. SAMPS041
00502 05 FILLER PIC X(81) VALUE SPACES. SAMPS041
00503 SAMPS041
00504 01 FL-FIRST-LINE-COLUMN-HEADER. SAMPS041
00505 SAMPS041
00506 05 FILLER PIC X(02) VALUE SPACES. SAMPS041
00507 05 FILLER PIC X(11) VALUE SAMPS041
00508 'SESA NAME: '. SAMPS041
00509 05 FL-SESA-NAME PIC X(20). SAMPS041
00510 05 FILLER PIC X(05) VALUE SPACES. SAMPS041
00511 05 FILLER PIC X(16) VALUE SAMPS041
00512 'PERIOD/QUARTER: '. SAMPS041
00513 05 FL-PERIOD. SAMPS041
00514 10 FL-YEAR PIC X(04). SAMPS041
00515 10 FILLER PIC X(01) VALUE '/'. SAMPS041
00516 10 FL-QUARTER PIC X(01). SAMPS041
00517 05 FILLER PIC X(05) VALUE SPACES. SAMPS041
00518 05 FILLER PIC X(13) VALUE SAMPS041
00519 'SAMPLE TYPE: '. SAMPS041
00520 05 FL-SAMPLE-TYPE PIC X(24). SAMPS041
00521 05 FILLER PIC X(03) VALUE SPACES. SAMPS041
00522 05 FILLER PIC X(25) VALUE SAMPS041
00523 'REVIEWER: _______________'. SAMPS041
00524 05 FILLER PIC X(12) VALUE SPACES. SAMPS041
00525 SAMPS041
00526 01 SL-SECOND-LINE-COL-HEADER. SAMPS041
00527 SAMPS041
00528 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00529 05 FILLER PIC X(04) VALUE SAMPS041
00530 'CASE'. SAMPS041
00531 05 FILLER PIC X(03) VALUE SPACES. SAMPS041
00532 05 FILLER PIC X(08) VALUE SAMPS041
00533 'EMPLOYER'. SAMPS041
00534 05 FILLER PIC X(11) VALUE SPACES. SAMPS041
00535 05 FILLER PIC X(01) VALUE '1'. SAMPS041
00536 05 FILLER PIC X(06) VALUE SPACES. SAMPS041
00537 05 FILLER PIC X(02) VALUE '2*'. SAMPS041
00538 05 FILLER PIC X(06) VALUE SPACES. SAMPS041
00539 05 FILLER PIC X(03) VALUE '3A*'. SAMPS041
00540 05 FILLER PIC X(06) VALUE SPACES. SAMPS041
00541 05 FILLER PIC X(03) VALUE '3B*'. SAMPS041
00542 05 FILLER PIC X(06) VALUE SPACES. SAMPS041
00543 05 FILLER PIC X(03) VALUE '3C*'. SAMPS041
00544 05 FILLER PIC X(06) VALUE SPACES. SAMPS041
00545 05 FILLER PIC X(03) VALUE '3D*'. SAMPS041
00546 05 FILLER PIC X(06) VALUE SPACES. SAMPS041
00547 05 FILLER PIC X(02) VALUE '4*'. SAMPS041
00548 05 FILLER PIC X(11) VALUE SPACES. SAMPS041
00549 05 FILLER PIC X(09) SAMPS041
00550 VALUE 'PASS/FAIL'. SAMPS041
00551 05 FILLER PIC X(14) VALUE SPACES. SAMPS041
00552 SAMPS041
00553 01 TL-THIRD-COLUMN-HEADER. SAMPS041
00554 SAMPS041
00555 05 FILLER PIC X(03) VALUE SPACES. SAMPS041
00556 05 FILLER PIC X(06) VALUE SAMPS041
00557 'NUMBER'. SAMPS041
00558 05 FILLER PIC X(02) VALUE SPACES. SAMPS041
00559 05 FILLER PIC X(09) VALUE SAMPS041
00560 'ID NUMBER'. SAMPS041
00561 05 FILLER PIC X(76) VALUE SPACES. SAMPS041
00562 05 FILLER PIC X(05) VALUE '(Y/N)'. SAMPS041
00563 05 FILLER PIC X(27) VALUE SPACES. SAMPS041
00564 SAMPS041
00565 01 CL-COLUMN-UNDERLINE. SAMPS041
00566 SAMPS041
00567 05 FILLER PIC X(03) VALUE SPACES. SAMPS041
00568 05 FILLER PIC X(06) VALUE SAMPS041
00569 '------'. SAMPS041
00570 05 FILLER PIC X(02) VALUE SPACES. SAMPS041
00571 05 FILLER PIC X(09) VALUE SAMPS041
00572 '---------'. SAMPS041
00573 05 FILLER PIC X(09) VALUE SPACES. SAMPS041
00574 05 FILLER PIC X(03) VALUE '---'. SAMPS041
00575 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00576 05 FILLER PIC X(04) VALUE '----'. SAMPS041
00577 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00578 05 FILLER PIC X(05) VALUE '-----'. SAMPS041
00579 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00580 05 FILLER PIC X(05) VALUE '-----'. SAMPS041
00581 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00582 05 FILLER PIC X(05) VALUE '-----'. SAMPS041
00583 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00584 05 FILLER PIC X(05) VALUE '-----'. SAMPS041
00585 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00586 05 FILLER PIC X(06) VALUE '----'. SAMPS041
00587 05 FILLER PIC X(08) VALUE SPACES. SAMPS041
00588 05 FILLER PIC X(09) VALUE '---------'. SAMPS041
00589 05 FILLER PIC X(26) VALUE SPACES. SAMPS041
00590 SAMPS041
00591 01 DL-BANNER-LINE PIC X(132) VALUE ALL '-'. SAMPS041
00592 SAMPS041
00593 01 DL-CHECKLIST-DETAIL. SAMPS041
00594 05 DL-CHECKLIST-CASE-NO PIC ZZZZZZZ9. SAMPS041
00595 05 FILLER PIC X(02) VALUE SPACES. SAMPS041
00596 05 DL-CHECKLIST-EMP-ID PIC X(17). SAMPS041
00597 05 FILLER PIC X(02) VALUE SPACES. SAMPS041
00598 05 FILLER PIC X(03) VALUE '( )'. SAMPS041
00599 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00600 05 FILLER PIC X(04) VALUE '( )'. SAMPS041
00601 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00602 05 FILLER PIC X(05) VALUE '( )'. SAMPS041
00603 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00604 05 FILLER PIC X(05) VALUE '( )'. SAMPS041
00605 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00606 05 FILLER PIC X(05) VALUE '( )'. SAMPS041
00607 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00608 05 FILLER PIC X(05) VALUE '( )'. SAMPS041
00609 05 FILLER PIC X(04) VALUE SPACES. SAMPS041
00610 05 FILLER PIC X(04) VALUE '( )'. SAMPS041
00611 05 FILLER PIC X(13) VALUE SPACES. SAMPS041
00612 05 FILLER PIC X(04) VALUE '( )'. SAMPS041
00613 05 FILLER PIC X(8) VALUE SPACES. SAMPS041
00614 SAMPS041
00615 01 Q-EVALUATIVE-DETAIL. SAMPS041
00616 05 FILLER PIC X(03) VALUE SPACES. SAMPS041
00617 05 FILLER PIC X(53) VALUE SAMPS041
00618 '"*" QUESTIONS 2,3A,3B,3C,3D, AND 4 ARE EVALUATIVE'. SAMPS041
00619 05 FILLER PIC X(76) VALUE SPACES. SAMPS041
00620 SAMPS041
00621 PROCEDURE DIVISION. SAMPS041
00622 ******************************************** SAMPS041
00623 *** *** SAMPS041
00624 ** THE DECLARATIVES SECTION THAT FOLLOWS ** SAMPS041
00625 ** IS PERFORMED IF AN INPUT/OUTPUT ERROR ** SAMPS041
00626 ** OCCURS TO THE VSAM FILE (TRANS-FILE) ** SAMPS041
00627 ** DURING PROCESSING. ** SAMPS041
00628 *** *** SAMPS041
00629 ******************************************** SAMPS041
00630 DECLARATIVES. SAMPS041
00631 A000-EXCEPTION-HANDLING SECTION. SAMPS041
00632 USE AFTER ERROR PROCEDURE SAMPS041
00633 ON TRANS-FILE. SAMPS041
00634 SAMPS041
00635 ***************************************************** SAMPS041
00636 *** *** SAMPS041
00637 ** THIS SECTION WILL DISPLAY THAT AN INPUT/OUTPUT ** SAMPS041
00638 ** ERROR HAS OCCURRED, DISPLAY A FILE STATUS ** SAMPS041
00639 ** ERROR CODE (TRANS-FILE-ERROR-CODE), CLOSE ALL ** SAMPS041
00640 ** INPUT/OUTPUT FILES AND STOP THE EXECUTION ** SAMPS041
00641 ** OF THE PROGRAM. ** SAMPS041
00642 *** *** SAMPS041
00643 ***************************************************** SAMPS041
00644 A100-CHECK-ERROR-ROUTINE. SAMPS041
00645 SAMPS041
00646 DISPLAY 'INPUT/OUTPUT ERROR HAS OCCURRED.' SAMPS041
00647 DISPLAY 'THE FILE STATUS CODE ERROR IS : ' SAMPS041
00648 DISPLAY TRANS-FILE-ERROR-CODE SAMPS041
00649 DISPLAY ' - SAMPS041 - JOB TERMINATED ' SAMPS041
00650 CLOSE SELECT-FILE SAMPS041
00651 CLOSE CNTRL-DATA SAMPS041
00652 CLOSE TRANS-FILE SAMPS041
00653 CLOSE JOB-STATUS SAMPS041
00654 CLOSE HIT-FILE SAMPS041
00655 CLOSE HIT-LIST SAMPS041
00656 CLOSE CHECK-LIST SAMPS041
00657 STOP RUN. SAMPS041
00658 SAMPS041
00659 END DECLARATIVES. SAMPS041
00660 *************************************************************** SAMPS041
00661 ** 0000-DRIVER-ROUTINE. ** SAMPS041
00662 ** THIS SECTION PERFORMS THE MAIN PROCESSING OF THE PROGRAM. ** SAMPS041
00663 *************************************************************** SAMPS041
00664 B000-REGULAR-PROCESSING SECTION. SAMPS041
00665 0000-DRIVER-ROUTINE. SAMPS041
00666 SAMPS041
00667 PERFORM 0100-OPEN-ROUTINE SAMPS041
00668 THRU 0100-OPEN-ROUTINE-EXIT. SAMPS041
00669 PERFORM 0200-VALIDATE-TRANSACTION-TYPE SAMPS041
00670 THRU 0200-VALIDATION-EXIT. SAMPS041
00671 PERFORM 0300-STATE-TABLE-ROUTINE SAMPS041
00672 THRU 0300-STATE-TABLE-EXIT. SAMPS041
00673 PERFORM 0305-SAMPLE-TABLE-ROUTINE SAMPS041
00674 THRU 0305-SAMPLE-TABLE-EXIT. SAMPS041
00675 PERFORM 0500-SELECT-RECORDS SAMPS041
00676 THRU 0500-SELECT-RECS-EXIT SAMPS041
00677 UNTIL WS-SELECT-EOF = 'Y'. SAMPS041
00678 SAMPS041
00679 ************************************************************ SAMPS041
00680 ** 0100-OPEN-ROUTINE: ** SAMPS041
00681 ** THIS SECTION OPENS INPUT FILES CNTRL-DATA, AND ** SAMPS041
00682 ** SELECT-FILE. THE FOLLOWING OUTPUT FILES ARE OPENED: ** SAMPS041
00683 ** HIT-FILE, HIT-LIST, CHECK-LIST, AND JOB-STATUS. ** SAMPS041
00684 ** THIS SECTION ALSO OPENS THE VSAM FILE TRANS-FILE AS ** SAMPS041
00685 ** INPUT/OUTPUT, MOVES THE CURRENT DATE TO THE OUTPUT ** SAMPS041
00686 ** FILE HIT-LIST AND CHECK-LIST FOR PRINTING, AND READS ** SAMPS041
00687 ** THE IN RECORD THE CNTRL-DATA FILE. ** SAMPS041
00688 ************************************************************ SAMPS041
00689 0100-OPEN-ROUTINE. SAMPS041
00690 SAMPS041
00691 OPEN INPUT CNTRL-DATA. SAMPS041
00692 OPEN INPUT SELECT-FILE. SAMPS041
00693 OPEN I-O TRANS-FILE. SAMPS041
00694 OPEN OUTPUT HIT-FILE. SAMPS041
00695 OPEN OUTPUT HIT-LIST. SAMPS041
00696 OPEN OUTPUT CHECK-LIST. SAMPS041
00697 OPEN OUTPUT JOB-STATUS. SAMPS041
00698 ACCEPT WS-DATE FROM DATE. SAMPS041
00699 MOVE WS-YY TO WRK-YY. SAMPS041
00700 MOVE WS-MM TO WRK-MM. SAMPS041
00701 MOVE WS-DD TO WRK-DD. SAMPS041
00702 MOVE WRK-DATE-AREA TO O-RUN-DATE HD-RUN-DATE. SAMPS041
00703 READ CNTRL-DATA AT END MOVE 'Y' TO CNTRL-FLAG. SAMPS041
00704 SAMPS041
00705 0100-OPEN-ROUTINE-EXIT. SAMPS041
00706 EXIT. SAMPS041
00707 SAMPS041
00708 ******************************************************* SAMPS041
00709 *** *** SAMPS041
00710 ** 0200-VALIDATE-TRANSACTION-TYPE: ** SAMPS041
00711 ** UTILIZING THE CNTRL-TRANS-TYPE FIELD FROM THE ** SAMPS041
00712 ** INPUT FILE CNTRL-DATA FILE, THIS PROCEDURE ** SAMPS041
00713 ** VALIDATES THE REPORT TRANSACTION TYPE FIELD. IF ** SAMPS041
00714 ** THE CNTRL-TRANS-TYPE IS NOT A 1, AN ERROR MESSAGE ** SAMPS041
00715 ** IS DISPLAYED AND THE PROGRAM RUN IS TERMINATED. ** SAMPS041
00716 *** *** SAMPS041
00717 ******************************************************* SAMPS041
00718 SAMPS041
00719 0200-VALIDATE-TRANSACTION-TYPE. SAMPS041
00720 SAMPS041
00721 IF CNTRL-TRANS-TYPE = '1' SAMPS041
00722 NEXT SENTENCE SAMPS041
00723 ELSE SAMPS041
00724 DISPLAY 'INVALID TRANSACTION TYPE' SAMPS041
00725 DISPLAY 'TRANSACTION TYPE IN ERROR IS: ' SAMPS041
00726 DISPLAY CNTRL-TRANS-TYPE SAMPS041
00727 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS041
00728 PERFORM 9999-CLOSE-FILES. SAMPS041
00729 SAMPS041
00730 0200-VALIDATION-EXIT. SAMPS041
00731 EXIT. SAMPS041
00732 SAMPS041
00733 ************************************************* SAMPS041
00734 *** *** SAMPS041
00735 ** 0300-STATE-TABLE-ROUTINE: ** SAMPS041
00736 ** THIS SECTION SEARCHES THE ST-STATE-DATA ** SAMPS041
00737 ** TABLE, FOUND IN THE WORKING STORAGE SECTION,** SAMPS041
00738 ** FOR A MATCHING CONDITION OF THE SESA-ID ** SAMPS041
00739 ** FIELD OF THE CNTRL-DATA FILE. IF A MATCH ** SAMPS041
00740 ** OCCURS, THE STATE ABREVIATION (SESA-ID) IS ** SAMPS041
00741 ** REPLACED WITH THE STATE NAME ** SAMPS041
00742 ** DESCRIPTION. IF A MATCH IS NOT FOUND, ** SAMPS041
00743 ** AN ERROR MESSAGE IS DISPLAYED AND THE ** SAMPS041
00744 ** PROGRAM RUN IS TERMINATED. ** SAMPS041
00745 *** *** SAMPS041
00746 ************************************************* SAMPS041
00747 0300-STATE-TABLE-ROUTINE. SAMPS041
00748 SAMPS041
00749 SET ST-INDEX TO 1. SAMPS041
00750 SEARCH ST-STATE-ENTRY SAMPS041
00751 AT END MOVE 'END' TO ST-ENTRY-FOUND-SWITCH SAMPS041
00752 WHEN SESA-ID SAMPS041
00753 IS EQUAL TO ST-STATE-ID (ST-INDEX) SAMPS041
00754 MOVE 'YES' TO ST-ENTRY-FOUND-SWITCH. SAMPS041
00755 IF ST-ENTRY-FOUND SAMPS041
00756 MOVE ST-STATE-NAME (ST-INDEX) SAMPS041
00757 TO WS-SESA-NAME-AREA SAMPS041
00758 ELSE SAMPS041
00759 DISPLAY SESA-ID, ' - NOT FOUND ON STATE TABLE' SAMPS041
00760 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS041
00761 PERFORM 9999-CLOSE-FILES. SAMPS041
00762 SAMPS041
00763 0300-STATE-TABLE-EXIT. SAMPS041
00764 EXIT. SAMPS041
00765 SAMPS041
00766 *************************************************** SAMPS041
00767 *** *** SAMPS041
00768 ** 0305-SAMPLE-TABLE-ROUTINE: ** SAMPS041
00769 ** THIS SECTION SEARCHES THE WS-SAMPLE-DATA ** SAMPS041
00770 ** TABLE, FOUND IN THE WORKING STORAGE SECTION, ** SAMPS041
00771 ** FOR A MATCHING CONDITION OF THE SAMPLE-TYPE ** SAMPS041
00772 ** FIELD OF THE CNTRL-DATA FILE. IF A MATCH ** SAMPS041
00773 ** OCCURS, THE SAMPLE-TYPE ABBREVIATION IS ** SAMPS041
00774 ** REPLACED WITH THE SAMPLE-TYPE DESCRIPTION. ** SAMPS041
00775 ** IF A MATCH IS NOT FOUND, AN ERROR MESSAGE ** SAMPS041
00776 ** IS DISPLAYED AND THE PROGRAM RUN TERMINATED. ** SAMPS041
00777 *** *** SAMPS041
00778 *************************************************** SAMPS041
00779 0305-SAMPLE-TABLE-ROUTINE. SAMPS041
00780 SAMPS041
00781 SET WS-INDEX TO 1. SAMPS041
00782 SEARCH WS-SAMPLE-ENTRY SAMPS041
00783 AT END MOVE 'END' TO WS-ENTRY-FOUND-SWITCH SAMPS041
00784 WHEN SAMPLE-TYPE SAMPS041
00785 IS EQUAL TO WS-SAMPLE-ID (WS-INDEX) SAMPS041
00786 MOVE 'YES' TO WS-ENTRY-FOUND-SWITCH. SAMPS041
00787 IF WS-SAMPLE-FOUND SAMPS041
00788 MOVE WS-SAMPLE-DESCRIPTION (WS-INDEX) SAMPS041
00789 TO WS-SAMPLE-NAME-AREA SAMPS041
00790 ELSE SAMPS041
00791 DISPLAY SAMPLE-TYPE, '- NOT ON SAMPLE TABLE' SAMPS041
00792 MOVE MESSAGE-2 TO WS-MESSAGE-FILE SAMPS041
00793 PERFORM 9999-CLOSE-FILES. SAMPS041
00794 SAMPS041
00795 0305-SAMPLE-TABLE-EXIT. SAMPS041
00796 EXIT. SAMPS041
00797 SAMPS041
00798 ********************************************************* SAMPS041
00799 *** *** SAMPS041
00800 ** 0400-HIT-LIST-HEADING: ** SAMPS041
00801 ** THIS SECTION GENERATES THE PAGE AND COLUMN HEADER ** SAMPS041
00802 ** FOR THE HIT-LIST OUTPUT REPORT. ** SAMPS041
00803 *** *** SAMPS041
00804 ********************************************************* SAMPS041
00805 SAMPS041
00806 0400-HIT-LIST-HEADING. SAMPS041
00807 SAMPS041
00808 ADD 1 TO LIST-PAGE. SAMPS041
00809 MOVE SPACES TO PRINT-HIT-REC. SAMPS041
00810 MOVE LIST-PAGE TO O-LIST-PAGE. SAMPS041
00811 MOVE WS-SESA-NAME-AREA TO O-CNTRL-SESA-NAME. SAMPS041
00812 WRITE PRINT-HIT-REC FROM LIST-HEADING-1 SAMPS041
00813 AFTER ADVANCING PAGE. SAMPS041
00814 WRITE PRINT-HIT-REC FROM LIST-HEADING-2 SAMPS041
00815 AFTER ADVANCING 1 LINE. SAMPS041
00816 WRITE PRINT-HIT-REC FROM LIST-HEADING-3 SAMPS041
00817 AFTER ADVANCING 1 LINE. SAMPS041
00818 WRITE PRINT-HIT-REC FROM LIST-HEADING-4 SAMPS041
00819 AFTER ADVANCING 3 LINES. SAMPS041
00820 WRITE PRINT-HIT-REC FROM LIST-HEADING-5 SAMPS041
00821 AFTER ADVANCING 1 LINE. SAMPS041
00822 MOVE SPACES TO PRINT-HIT-REC. SAMPS041
00823 WRITE PRINT-HIT-REC AFTER ADVANCING 1 LINE. SAMPS041
00824 SAMPS041
00825 0400-HIT-LIST-EXIT. SAMPS041
00826 EXIT. SAMPS041
00827 SAMPS041
00828 *********************************************** SAMPS041
00829 *** *** SAMPS041
00830 ** 0405-CHECKLIST-HEADER-RTN: ** SAMPS041
00831 ** THIS SECTION CREATES THE PAGE, AND COLUMN ** SAMPS041
00832 ** HEADERS FOR THE CHECK-LIST OUTPUT REPORT. ** SAMPS041
00833 *** *** SAMPS041
00834 *********************************************** SAMPS041
00835 0405-CHECKLIST-HEADER-RTN. SAMPS041
00836 SAMPS041
00837 ADD 1 TO WS-PAGE-CNTR. SAMPS041
00838 MOVE SPACES TO CHECK-LIST-REC. SAMPS041
00839 MOVE WS-PAGE-CNTR TO HD-PAGE-NUMBER. SAMPS041
00840 WRITE CHECK-LIST-REC FROM FL-BANNER-LINE SAMPS041
00841 AFTER ADVANCING PAGE. SAMPS041
00842 WRITE CHECK-LIST-REC FROM HD-NEW-EMP-CHECKLIST SAMPS041
00843 AFTER ADVANCING 1 LINE. SAMPS041
00844 WRITE CHECK-LIST-REC FROM HT-TAX-FUNCTION-HEADER SAMPS041
00845 AFTER ADVANCING 1 LINE. SAMPS041
00846 WRITE CHECK-LIST-REC FROM HT-TAX-FUNCTION-2 SAMPS041
00847 AFTER ADVANCING 1 LINE. SAMPS041
00848 WRITE CHECK-LIST-REC FROM FL-BANNER-LINE SAMPS041
00849 AFTER ADVANCING 1 LINE. SAMPS041
00850 MOVE WS-SESA-NAME-AREA TO FL-SESA-NAME. SAMPS041
00851 MOVE CNTRL-YEAR-QTR TO WS-PERIOD-DATE. SAMPS041
00852 MOVE WS-CHECKLIST-YEAR TO FL-YEAR. SAMPS041
00853 MOVE WS-CHECKLIST-QTR TO FL-QUARTER. SAMPS041
00854 MOVE WS-SAMPLE-NAME-AREA TO FL-SAMPLE-TYPE. SAMPS041
00855 WRITE CHECK-LIST-REC FROM FL-FIRST-LINE-COLUMN-HEADER SAMPS041
00856 AFTER ADVANCING 2 LINES. SAMPS041
00857 WRITE CHECK-LIST-REC FROM SL-SECOND-LINE-COL-HEADER SAMPS041
00858 AFTER ADVANCING 2 LINES. SAMPS041
00859 WRITE CHECK-LIST-REC FROM TL-THIRD-COLUMN-HEADER SAMPS041
00860 AFTER ADVANCING 1 LINE. SAMPS041
00861 WRITE CHECK-LIST-REC FROM CL-COLUMN-UNDERLINE SAMPS041
00862 AFTER ADVANCING 1 LINE. SAMPS041
00863 MOVE SPACES TO CHECK-LIST-REC. SAMPS041
00864 WRITE CHECK-LIST-REC AFTER ADVANCING 1 LINES. SAMPS041
00865 SAMPS041
00866 0405-CHECKLIST-HEADER-EXIT. SAMPS041
00867 EXIT. SAMPS041
00868 SAMPS041
00869 SAMPS041
00870 *************************************************************** SAMPS041
00871 ** 0500-SELECT-RECORDS: ** SAMPS041
00872 ** THE SECTION WILL READ THE SELECT-FILE WHICH CONTAINS ** SAMPS041
00873 ** THE SELECTED NUMBERS FOR THE SAMPLE. EACH SELECT ** SAMPS041
00874 ** RECORD WILL ALSO BE USED AS THE RECORD KEY TO READ THE ** SAMPS041
00875 ** SAMPLING TRANSACTION VSAM FILE (TRANS-FILE). THE ** SAMPS041
00876 ** TRANSACTION FILE IS INDEXED BY A FIELD (SEQ-NMBER) WHICH ** SAMPS041
00877 ** IS THE KEY USED DURING THE READ OF THE VSAM FILE. THE ** SAMPS041
00878 ** VALUE OF THE SELECT RECORD NUMBER (SL-REC-NUM) IS MOVED ** SAMPS041
00879 ** TO (SEQ-NMBR) AND THE RECORD ON THE TRANSACTION FILE ** SAMPS041
00880 ** FOR THAT RECORD NUMBER IS READ AND PROCESSED. FOR THE ** SAMPS041
00881 ** RECORDS THAT HAVE BEEN SELECTED FROM THE TRANSACTION ** SAMPS041
00882 ** FILE, THE SELECTED FLAG FIELD (SELECTED-FLAG) IS CHANGED ** SAMPS041
00883 ** TO A 2, AND THE RECORD IS WRITTEN TO THE DISK FILE ** SAMPS041
00884 ** (HIT-FILE). THIS SAME RECORD IS WRITTEN TO A (HIT-FILE) ** SAMPS041
00885 ** LISTING (HIT-LIST) AND A CODING SHEET OUTPUT REPORT ** SAMPS041
00886 ** (CHECK-LIST). THIS PROCESSING IS CONTINUED UNTIL EACH ** SAMPS041
00887 ** RECORD FROM THE SELECT-FILE HAS BEEN READ. ** SAMPS041
00888 *************************************************************** SAMPS041
00889 0500-SELECT-RECORDS. SAMPS041
00890 SAMPS041
00891 READ SELECT-FILE SAMPS041
00892 AT END MOVE 'Y' TO WS-SELECT-EOF. SAMPS041
00893 IF WS-SELECT-EOF = 'Y' SAMPS041
00894 AND MATCH-CNTR NOT EQUAL TO SAMPLED-NMBR SAMPS041
00895 DISPLAY 'RECORDS SELECTED NE TO RECORDS DESIRED' SAMPS041
00896 MOVE MESSAGE-1 TO WS-MESSAGE-FILE SAMPS041
00897 PERFORM 9999-CLOSE-FILES. SAMPS041
00898 IF WS-SELECT-EOF = 'Y' SAMPS041
00899 AND MATCH-CNTR EQUAL TO SAMPLED-NMBR SAMPS041
00900 MOVE MESSAGE-1 TO WS-MESSAGE-FILE SAMPS041
00901 PERFORM 9999-CLOSE-FILES. SAMPS041
00902 IF WS-SELECT-EOF NOT EQUAL 'Y' SAMPS041
00903 ADD 1 TO MATCH-CNTR SAMPS041
00904 MOVE SL-REC-NUM TO SEQ-NMBR SAMPS041
00905 READ TRANS-FILE RECORD INTO WS-MATCH-RECORD. SAMPS041
00906 IF WS-HIT-LIST-SWITCH = '0' SAMPS041
00907 PERFORM 0400-HIT-LIST-HEADING SAMPS041
00908 THRU 0400-HIT-LIST-EXIT. SAMPS041
00909 IF WS-CHECKLIST-SWITCH = '0' SAMPS041
00910 PERFORM 0405-CHECKLIST-HEADER-RTN SAMPS041
00911 THRU 0405-CHECKLIST-HEADER-EXIT. SAMPS041
00912 PERFORM 0600-PRINT-HIT-RECS SAMPS041
00913 THRU 0600-PRINT-EXIT. SAMPS041
00914 MOVE SELECTED-FLAG TO SELECT-FLAG. SAMPS041
00915 MOVE SELECTED-FLAG TO MATCH-SELECT-FLAG. SAMPS041
00916 REWRITE TRANS-REC. SAMPS041
00917 SAMPS041
00918 0500-SELECT-RECS-EXIT. SAMPS041
00919 EXIT. SAMPS041
00920 SAMPS041
00921 *************************************************************** SAMPS041
00922 ** 0600-PRINT-HIT-RECS: ** SAMPS041
00923 ** THIS ROUTINE MOVES THE INFORMATION REQUIRED TO EACH OF ** SAMPS041
00924 ** THE FOLLOWING OUTPUT FILES: HIT-FILE, HIT-LIST AND CHECK- ** SAMPS041
00925 ** LIST. THE ROUTINE ALSO CONTROLS LINE COUNT AND HEADER ** SAMPS041
00926 ** GENERATION FOR THE HIT-LIST AND CHECK-LIST. ** SAMPS041
00927 *************************************************************** SAMPS041
00928 SAMPS041
00929 0600-PRINT-HIT-RECS. SAMPS041
00930 SAMPS041
00931 MOVE '1' TO WS-CHECKLIST-SWITCH. SAMPS041
00932 MOVE '1' TO WS-HIT-LIST-SWITCH. SAMPS041
00933 MOVE MATCH-CNTR TO DTL-CASE-NO. SAMPS041
00934 MOVE MATCH-SEQ-NMBR TO DTL-SEQ-NMBR. SAMPS041
00935 MOVE MATCH-EMP-ID TO DTL-EMP-ID. SAMPS041
00936 MOVE MATCH-DATE-COMPLETED TO DTL-DATE-COMPLETED. SAMPS041
00937 MOVE DTL-COMPLETED-MO TO O-COMPLETED-MO. SAMPS041
00938 MOVE DTL-COMPLETED-YR TO O-COMPLETED-YR. SAMPS041
00939 MOVE DTL-COMPLETED-DA TO O-COMPLETED-DA. SAMPS041
00940 MOVE CNTRL-YEAR-QTR TO WS-PERIOD-DATE. SAMPS041
00941 MOVE WS-CHECKLIST-YEAR TO FL-YEAR. SAMPS041
00942 MOVE WS-CHECKLIST-QTR TO FL-QUARTER. SAMPS041
00943 MOVE SESA-ID TO HIT-STATE. SAMPS041
00944 MOVE MATCH-CNTR TO HIT-CASE-NUMBER. SAMPS041
00945 MOVE MATCH-REC-TYPE TO HIT-REC-TYPE. SAMPS041
00946 MOVE MATCH-TRANS-TYPE TO HIT-TRANS-TYPE. SAMPS041
00947 MOVE MATCH-EMP-ID TO HIT-EMPLOYER-ID. SAMPS041
00948 MOVE CNTRL-YEAR-QTR TO HIT-SAMPLE-YEAR. SAMPS041
00949 MOVE SAMPLE-TYPE TO HIT-SAMPLE-TYPE. SAMPS041
00950 MOVE MATCH-CNTR TO WS-CASE-HOLD-AREA. SAMPS041
00951 MOVE WS-CASE-HOLD-AREA TO DL-CHECKLIST-CASE-NO. SAMPS041
00952 MOVE MATCH-EMP-ID TO WS-EMPL-HOLD-AREA. SAMPS041
00953 MOVE WS-EMPL-HOLD-AREA TO DL-CHECKLIST-EMP-ID. SAMPS041
00954 ADD 1 TO LIST-COUNTER. SAMPS041
00955 IF LIST-COUNTER > 50 SAMPS041
00956 MOVE 1 TO LIST-COUNTER SAMPS041
00957 PERFORM 0400-HIT-LIST-HEADING SAMPS041
00958 THRU 0400-HIT-LIST-EXIT. SAMPS041
00959 WRITE PRINT-HIT-REC FROM HIT-LIST-REC. SAMPS041
00960 PERFORM 0700-CHECKLIST-ROUTINE SAMPS041
00961 THRU 0700-CHECKLIST-EXIT. SAMPS041
00962 WRITE TRANS-HIT-REC FROM OUTPUT-HIT-REC. SAMPS041
00963 SAMPS041
00964 0600-PRINT-EXIT. SAMPS041
00965 EXIT. SAMPS041
00966 SAMPS041
00967 ******************************************************* SAMPS041
00968 *** *** SAMPS041
00969 ** 0700-CHECKLIST-ROUTINE: ** SAMPS041
00970 ** THIS SECTION CONTROLS THE PROCESSING OF THE ** SAMPS041
00971 ** CHECK-LIST REPORT. ** SAMPS041
00972 *** *** SAMPS041
00973 ******************************************************* SAMPS041
00974 0700-CHECKLIST-ROUTINE. SAMPS041
00975 SAMPS041
00976 ADD 1 TO WS-CHECKLIST-CNTR. SAMPS041
00977 IF WS-CHECKLIST-CNTR > 20 SAMPS041
00978 MOVE 1 TO WS-CHECKLIST-CNTR SAMPS041
00979 WRITE CHECK-LIST-REC FROM Q-EVALUATIVE-DETAIL SAMPS041
00980 AFTER ADVANCING 1 LINE SAMPS041
00981 PERFORM 0405-CHECKLIST-HEADER-RTN SAMPS041
00982 THRU 0405-CHECKLIST-HEADER-EXIT SAMPS041
00983 ELSE SAMPS041
00984 NEXT SENTENCE. SAMPS041
00985 WRITE CHECK-LIST-REC FROM DL-CHECKLIST-DETAIL SAMPS041
00986 AFTER ADVANCING 1 LINE. SAMPS041
00987 WRITE CHECK-LIST-REC FROM DL-BANNER-LINE SAMPS041
00988 AFTER ADVANCING 1 LINE. SAMPS041
00989 SAMPS041
00990 0700-CHECKLIST-EXIT. SAMPS041
00991 EXIT. SAMPS041
00992 SAMPS041
00993 SAMPS041
00994 *************************************************************** SAMPS041
00995 ** 9999-CLOSE-FILES. ** SAMPS041
00996 ** THIS SECTION WRITES AN END OF JOB MESSAGE, AND CLOSES THE ** SAMPS041
00997 ** INPUT FILES: SELECT-FILE, CNTRL-DATA, AND INPUT/OUTPUT ** SAMPS041
00998 ** FILE TRANS-FILE. THE FOLLOWING OUTPUT FILES ARE ALSO ** SAMPS041
00999 ** CLOSED: JOB-STATUS, HIT-FILE, HIT-LIST, CHECK-LIST.. ** SAMPS041
01000 *************************************************************** SAMPS041
01001 9999-CLOSE-FILES. SAMPS041
01002 SAMPS041
01003 WRITE CHECK-LIST-REC FROM Q-EVALUATIVE-DETAIL SAMPS041
01004 AFTER ADVANCING 1 LINE. SAMPS041
01005 WRITE MESSAGE-RECORD FROM WS-EOJ-DETAIL-LINE. SAMPS041
01006 CLOSE SELECT-FILE SAMPS041
01007 CLOSE CNTRL-DATA SAMPS041
01008 CLOSE TRANS-FILE SAMPS041
01009 CLOSE JOB-STATUS SAMPS041
01010 CLOSE HIT-FILE SAMPS041
01011 CLOSE HIT-LIST SAMPS041
01012 CLOSE CHECK-LIST SAMPS041
01013 STOP RUN. SAMPS041
Reference in New Issue View Git Blame Copy Permalink