374 lines
30 KiB
COBOL
374 lines
30 KiB
COBOL
00001 IDENTIFICATION DIVISION. 02/16/12
|
|
00002 PROGRAM-ID. DTSCU423. DTSCU423
|
|
00003 AUTHOR. TRW. LV003
|
|
00004 DATE-WRITTEN. FEBRUARY 2002. DTSCU423
|
|
00005 DATE-COMPILED. DTSCU423
|
|
00006 SKIP3 DTSCU423
|
|
00007 ***** DTSCU423
|
|
00008 * *** ANNUAL REPORT VERSION *** DTSCU423
|
|
00009 * DTSCU423
|
|
00010 * FUNCTION: RETURN TOTAL AND TAXABLE WAGES FOR A GIVEN SSN. DTSCU423
|
|
00011 * CALCULATE WAGE AMOUNTS FROM WWGH WAGE HISTORY DTSCU423
|
|
00012 * AND WAGES FROM A CURRENT REPORT PROVIDED IN DTSCU423
|
|
00013 * THE L423 LINKAGE AREA. DTSCU423
|
|
00014 * DTSCU423
|
|
00015 * THIS PROGRAM IS USED IN USED TO EDIT WAGE AMOUNTS DTSCU423
|
|
00016 * IN SUPPLEMENTAL CONTRIBUTION AND WAGE REPORTS. DTSCU423
|
|
00017 * DTSCU423
|
|
00018 * MODIFICATION LOG: DTSCU423
|
|
00019 * DTSCU423
|
|
00020 * 02/18/2002 INITIAL DEVELOPMENT. DTSCU423
|
|
00021 * WORK ORDER: PROGRAMMER: GD DTSCU423
|
|
00022 * DTSCU423
|
|
00023 * 08/24/2011 ALLOW TAXABLE WAGE ADJUSTMENT FOR WAGES PAID DTSCU423
|
|
00024 * TO ANOTHER STATE. THE ADJUSTMENT TAKES PLACE DTSCU423
|
|
00025 * THROUGH THE TAXABLE WAGE BASE. REDUCING THE DTSCU423
|
|
00026 * EFFECTIVE TAXABLE WAGE BASE RESULTS IN A DTSCU423
|
|
00027 * RECALCULATION OF TAXABLE WAGES. DTSCU423
|
|
00028 * WORK ORDER: PROGRAMMER: GD DTSCU423
|
|
00029 * DTSCU423
|
|
00030 * MM/DD/YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSCU423
|
|
00031 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSCU423
|
|
00032 * REFERENCE: XXXXXXXXXXXXXXX PROGRAMMER: XXX DTSCU423
|
|
00033 * DTSCU423
|
|
00034 * DTSCU423
|
|
00035 * DESCRIPTION: DTSCU423
|
|
00036 * DTSCU423
|
|
00037 * DTSCU423 CALCULATES AND RETURNS TAXABLE AND TOTAL DTSCU423
|
|
00038 * WAGES FOR A GIVEN SSN FOR ALL QUARTERS IN THE DTSCU423
|
|
00039 * CALENDAR YEAR. DTSCU423
|
|
00040 * DTSCU423
|
|
00041 * DTSCU423
|
|
00042 * GENERAL SPECIFICATIONS: DTSCU423
|
|
00043 * DTSCU423
|
|
00044 * DTSCU423
|
|
00045 * DTSCU423
|
|
00046 * DTSCU423
|
|
00047 * COMMAND SPECIFIC SPECIFICATIONS: DTSCU423
|
|
00048 * DTSCU423
|
|
00049 * DTSCU423
|
|
00050 * DTSCU423
|
|
00051 ***** DTSCU423
|
|
00052 SKIP3 DTSCU423
|
|
00053 DATA DIVISION. DTSCU423
|
|
00054 WORKING-STORAGE SECTION. DTSCU423
|
|
000545 77 PAN-VALET PICTURE X(24) VALUE '003DTSCU423 02/16/12'. DTSCU423
|
|
00055 SKIP3 DTSCU423
|
|
00056 01 WRK-AREA. DTSCU423
|
|
00057 05 WRK-ABEND-CD PIC X(04) VALUE 'U423'. DTSCU423
|
|
00058 DTSCU423
|
|
00059 05 WRK-MOD-NAME PIC X(08) VALUE 'DTSCU423'. DTSCU423
|
|
00060 DTSCU423
|
|
00061 05 WRK-TAX-WAGE-BASE PIC S9(07)V99 COMP-3 VALUE +0. DTSCU423
|
|
00062 05 WRK-WAGE-BASE-REMAIN PIC S9(07)V99 COMP-3 VALUE +0. DTSCU423
|
|
00063 05 WRK-HDR-WAGE-BASE PIC S9(07)V99 COMP-3 VALUE +0. DTSCU423
|
|
00064 05 WRK-ADJ-WAGE-BASE PIC S9(07)V99 COMP-3 VALUE +0. DTSCU423
|
|
00065 DTSCU423
|
|
00066 ** THE FOLLOWING DATA ELEMENTS CONTAIN THE WAGES TO BE PASSED DTSCU423
|
|
00067 ** TO P1900 THAT CALCULATES THE TAXABLE WAGE AMOUNT. DTSCU423
|
|
00068 05 WRK-WAGES. DTSCU423
|
|
00069 10 WRK-QTR1-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00070 10 WRK-QTR2-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00071 10 WRK-QTR3-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00072 10 WRK-QTR4-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00073 DTSCU423
|
|
00074 ** THE FOLLOWING DATA ELEMENTS CONTAIN THE TAXABLE WAGES DTSCU423
|
|
00075 ** THAT P1900 RETURNS. DTSCU423
|
|
00076 05 WRK-WAGES. DTSCU423
|
|
00077 10 WRK-QTR1-TAX-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00078 10 WRK-QTR2-TAX-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00079 10 WRK-QTR3-TAX-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00080 10 WRK-QTR4-TAX-WAGES PIC S9(09)V99 COMP-3 VALUE +0. DTSCU423
|
|
00081 DTSCU423
|
|
00082 ** THE FOLLOWING DATA ELEMENTS CONTAIN THE TAXABLE WAGE AMOUNT DTSCU423
|
|
00083 ** CALCULATED FROM WAGES ALREADY ON FILE. DTSCU423
|
|
00084 05 WRK-OLD-TAX-WAGES. DTSCU423
|
|
00085 10 WRK-QTR1-OLD-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00086 VALUE +0. DTSCU423
|
|
00087 10 WRK-QTR2-OLD-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00088 VALUE +0. DTSCU423
|
|
00089 10 WRK-QTR3-OLD-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00090 VALUE +0. DTSCU423
|
|
00091 10 WRK-QTR4-OLD-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00092 VALUE +0. DTSCU423
|
|
00093 DTSCU423
|
|
00094 ** THE FOLLOWING DATA ELEMENTS CONTAIN THE TAXABLE WAGE AMOUNT DTSCU423
|
|
00095 ** CALCULATED FROM THE SUM OF WAGES ALREADY ON FILE AND THE DTSCU423
|
|
00096 ** NEW WAGES. DTSCU423
|
|
00097 05 WRK-NEW-TAX-WAGES. DTSCU423
|
|
00098 10 WRK-QTR1-NEW-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00099 VALUE +0. DTSCU423
|
|
00100 10 WRK-QTR2-NEW-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00101 VALUE +0. DTSCU423
|
|
00102 10 WRK-QTR3-NEW-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00103 VALUE +0. DTSCU423
|
|
00104 10 WRK-QTR4-NEW-TAX-WAGES PIC S9(09)V99 COMP-3 DTSCU423
|
|
00105 VALUE +0. DTSCU423
|
|
00106 DTSCU423
|
|
00107 05 WRK-TAX-BASE-YEAR PIC S9(05) COMP-3 VALUE +0. DTSCU423
|
|
00108 05 AMT-DISP1 PIC Z(06)9. DTSCU423
|
|
00109 05 AMT-DISP2 PIC Z(06)9. DTSCU423
|
|
00110 DTSCU423
|
|
00111 05 WRK-FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSCU423
|
|
00112 88 WRK-FIRST-TIME-YES-88 VALUE 'Y'. DTSCU423
|
|
00113 88 WRK-FIRST-TIME-NO-88 VALUE 'N'. DTSCU423
|
|
00114 DTSCU423
|
|
00115 05 WRK-ERROR-IND PIC X(01). DTSCU423
|
|
00116 88 WRK-ERROR-YES-88 VALUE 'Y'. DTSCU423
|
|
00117 88 WRK-ERROR-NO-88 VALUE 'N'. DTSCU423
|
|
00118 DTSCU423
|
|
00119 EJECT DTSCU423
|
|
00120 01 L004-COMM-AREA. DTSCU423
|
|
00121 ++INCLUDE DTSIL004 DTSCU423
|
|
00122 DTSCU423
|
|
00123 01 L831-COMM-AREA. DTSCU423
|
|
00124 05 L831-CONTROL-BLOCK. DTSCU423
|
|
00125 ++INCLUDE DTSIL831 DTSCU423
|
|
00126 SKIP3 DTSCU423
|
|
00127 05 FCOMM-REC. DTSCU423
|
|
00128 ++INCLUDE DTSIFSKL DTSCU423
|
|
00129 SKIP3 DTSCU423
|
|
00130 01 FCYR-REC. DTSCU423
|
|
00131 ++INCLUDE DTSIFCYR DTSCU423
|
|
00132 SKIP3 DTSCU423
|
|
00133 LINKAGE SECTION. DTSCU423
|
|
00134 SKIP3 DTSCU423
|
|
00135 01 DFHCOMMAREA. DTSCU423
|
|
00136 ++INCLUDE DTSIL423 DTSCU423
|
|
00137 EJECT DTSCU423
|
|
00138 PROCEDURE DIVISION. DTSCU423
|
|
00139 DTSCU423
|
|
00140 PERFORM I0000-INIT THRU I0000-EXIT. DTSCU423
|
|
00141 DTSCU423
|
|
00142 PERFORM P0000-PROCESS THRU P0000-EXIT. DTSCU423
|
|
00143 DTSCU423
|
|
00144 GOBACK. DTSCU423
|
|
00145 EJECT DTSCU423
|
|
00146 I0000-INIT. DTSCU423
|
|
00147 IF WRK-FIRST-TIME-YES-88 DTSCU423
|
|
00148 SET WRK-FIRST-TIME-NO-88 TO TRUE DTSCU423
|
|
00149 PERFORM I1000-TAX-WAGE-BASE THRU I1000-EXIT DTSCU423
|
|
00150 END-IF. DTSCU423
|
|
00151 DTSCU423
|
|
00152 PERFORM I1100-TAX-WG-BASE-ADJ THRU I1100-EXIT. DTSCU423
|
|
00153 DTSCU423
|
|
00154 I0000-EXIT. DTSCU423
|
|
00155 EXIT. DTSCU423
|
|
00156 SKIP3 DTSCU423
|
|
00157 I1000-TAX-WAGE-BASE. DTSCU423
|
|
00158 MOVE LOW-VALUES TO FCYR-KEY-AREA. DTSCU423
|
|
00159 DTSCU423
|
|
00160 MOVE L423-QTR1 TO L004-QTR-5-9. DTSCU423
|
|
00161 MOVE L004-QTR-5-YR TO FCYR-YR. DTSCU423
|
|
00162 SET FCYR-CYR-88 TO TRUE. DTSCU423
|
|
00163 MOVE FCYR-KEY-AREA TO FSKL-KEY-AREA. DTSCU423
|
|
00164 PERFORM S831A-READ THRU S831A-EXIT. DTSCU423
|
|
00165 IF L831-NO-REC-88 DTSCU423
|
|
00166 PERFORM S899-ABEND THRU S899-EXIT DTSCU423
|
|
00167 ELSE DTSCU423
|
|
00168 MOVE FCOMM-REC TO FCYR-REC DTSCU423
|
|
00169 MOVE FCYR-TAXABLE-WAGE-BASE TO WRK-HDR-WAGE-BASE. DTSCU423
|
|
00170 ** MOVE FCYR-TAXABLE-WAGE-BASE TO WRK-TAX-WAGE-BASE. DTSCU423
|
|
00171 DTSCU423
|
|
00172 DTSCU423
|
|
00173 I1000-EXIT. DTSCU423
|
|
00174 EXIT. DTSCU423
|
|
00175 DTSCU423
|
|
00176 I1100-TAX-WG-BASE-ADJ. DTSCU423
|
|
00177 IF L423-TAX-WG-BASE-ADJ NOT NUMERIC DTSCU423
|
|
00178 SET L423-TAX-WG-BASE-NULL-88 TO TRUE DTSCU423
|
|
00179 ELSE DTSCU423
|
|
00180 IF NOT L423-TAX-WG-BASE-NULL-88 DTSCU423
|
|
00181 IF L423-TAX-WG-BASE-ADJ < ZERO DTSCU423
|
|
00182 SET L423-TAX-WG-BASE-NULL-88 TO TRUE DTSCU423
|
|
00183 END-IF DTSCU423
|
|
00184 END-IF DTSCU423
|
|
00185 END-IF. DTSCU423
|
|
00186 DTSCU423
|
|
00187 I1100-EXIT. DTSCU423
|
|
00188 EXIT. DTSCU423
|
|
00189 DTSCU423
|
|
00190 P0000-PROCESS. DTSCU423
|
|
00191 MOVE ZERO TO L423-QTR1-TAX-WAGES DTSCU423
|
|
00192 L423-QTR2-TAX-WAGES DTSCU423
|
|
00193 L423-QTR3-TAX-WAGES DTSCU423
|
|
00194 L423-QTR4-TAX-WAGES. DTSCU423
|
|
00195 DTSCU423
|
|
00196 SET L423-QTR1-VALID-88 TO TRUE. DTSCU423
|
|
00197 SET L423-QTR2-VALID-88 TO TRUE. DTSCU423
|
|
00198 SET L423-QTR3-VALID-88 TO TRUE. DTSCU423
|
|
00199 SET L423-QTR4-VALID-88 TO TRUE. DTSCU423
|
|
00200 DTSCU423
|
|
00201 PERFORM P1000-CALC-TAXABLE-WAGES THRU P1000-EXIT. DTSCU423
|
|
00202 DTSCU423
|
|
00203 P0000-EXIT. DTSCU423
|
|
00204 EXIT. DTSCU423
|
|
00205 DTSCU423
|
|
00206 P1000-CALC-TAXABLE-WAGES. DTSCU423
|
|
00207 SET WRK-ERROR-NO-88 TO TRUE. DTSCU423
|
|
00208 DTSCU423
|
|
00209 PERFORM P1100-EDIT-WAGES THRU P1100-EXIT. DTSCU423
|
|
00210 IF WRK-ERROR-YES-88 DTSCU423
|
|
00211 GO TO P1000-EXIT. DTSCU423
|
|
00212 DTSCU423
|
|
00213 PERFORM P1200-OLD-TAX-WAGE THRU P1200-EXIT. DTSCU423
|
|
00214 DTSCU423
|
|
00215 PERFORM P1300-NEW-TAX-WAGE THRU P1300-EXIT. DTSCU423
|
|
00216 DTSCU423
|
|
00217 PERFORM P1400-NET-TAX-WAGE THRU P1400-EXIT. DTSCU423
|
|
00218 DTSCU423
|
|
00219 P1000-EXIT. DTSCU423
|
|
00220 EXIT. DTSCU423
|
|
00221 DTSCU423
|
|
00222 P1100-EDIT-WAGES. DTSCU423
|
|
00223 IF (L423-QTR1-CURR-WAGE + DTSCU423
|
|
00224 L423-QTR1-WAGE-CHNG) < ZERO DTSCU423
|
|
00225 SET L423-QTR1-INVLD-NEG-88 TO TRUE DTSCU423
|
|
00226 SET WRK-ERROR-YES-88 TO TRUE. DTSCU423
|
|
00227 DTSCU423
|
|
00228 IF (L423-QTR2-CURR-WAGE + DTSCU423
|
|
00229 L423-QTR2-WAGE-CHNG) < ZERO DTSCU423
|
|
00230 SET L423-QTR2-INVLD-NEG-88 TO TRUE DTSCU423
|
|
00231 SET WRK-ERROR-YES-88 TO TRUE. DTSCU423
|
|
00232 DTSCU423
|
|
00233 IF (L423-QTR3-CURR-WAGE + DTSCU423
|
|
00234 L423-QTR3-WAGE-CHNG) < ZERO DTSCU423
|
|
00235 SET L423-QTR3-INVLD-NEG-88 TO TRUE DTSCU423
|
|
00236 SET WRK-ERROR-YES-88 TO TRUE. DTSCU423
|
|
00237 DTSCU423
|
|
00238 IF (L423-QTR4-CURR-WAGE + DTSCU423
|
|
00239 L423-QTR4-WAGE-CHNG) < ZERO DTSCU423
|
|
00240 SET L423-QTR4-INVLD-NEG-88 TO TRUE DTSCU423
|
|
00241 SET WRK-ERROR-YES-88 TO TRUE. DTSCU423
|
|
00242 DTSCU423
|
|
00243 P1100-EXIT. DTSCU423
|
|
00244 EXIT. DTSCU423
|
|
00245 DTSCU423
|
|
00246 P1200-OLD-TAX-WAGE. DTSCU423
|
|
00247 MOVE L423-QTR1-CURR-WAGE TO WRK-QTR1-WAGES. DTSCU423
|
|
00248 MOVE L423-QTR2-CURR-WAGE TO WRK-QTR2-WAGES. DTSCU423
|
|
00249 MOVE L423-QTR3-CURR-WAGE TO WRK-QTR3-WAGES. DTSCU423
|
|
00250 MOVE L423-QTR4-CURR-WAGE TO WRK-QTR4-WAGES. DTSCU423
|
|
00251 DTSCU423
|
|
00252 MOVE WRK-HDR-WAGE-BASE TO WRK-TAX-WAGE-BASE. DTSCU423
|
|
00253 PERFORM P1900-CALC-TAX-WAGE THRU P1900-EXIT. DTSCU423
|
|
00254 DTSCU423
|
|
00255 MOVE WRK-QTR1-TAX-WAGES TO WRK-QTR1-OLD-TAX-WAGES. DTSCU423
|
|
00256 MOVE WRK-QTR2-TAX-WAGES TO WRK-QTR2-OLD-TAX-WAGES. DTSCU423
|
|
00257 MOVE WRK-QTR3-TAX-WAGES TO WRK-QTR3-OLD-TAX-WAGES. DTSCU423
|
|
00258 MOVE WRK-QTR4-TAX-WAGES TO WRK-QTR4-OLD-TAX-WAGES. DTSCU423
|
|
00259 DTSCU423
|
|
00260 P1200-EXIT. DTSCU423
|
|
00261 EXIT. DTSCU423
|
|
00262 DTSCU423
|
|
00263 P1300-NEW-TAX-WAGE. DTSCU423
|
|
00264 COMPUTE WRK-QTR1-WAGES = DTSCU423
|
|
00265 (L423-QTR1-WAGE-CHNG + L423-QTR1-CURR-WAGE) DTSCU423
|
|
00266 COMPUTE WRK-QTR2-WAGES = DTSCU423
|
|
00267 (L423-QTR2-WAGE-CHNG + L423-QTR2-CURR-WAGE) DTSCU423
|
|
00268 COMPUTE WRK-QTR3-WAGES = DTSCU423
|
|
00269 (L423-QTR3-WAGE-CHNG + L423-QTR3-CURR-WAGE) DTSCU423
|
|
00270 COMPUTE WRK-QTR4-WAGES = DTSCU423
|
|
00271 (L423-QTR4-WAGE-CHNG + L423-QTR4-CURR-WAGE). DTSCU423
|
|
00272 DTSCU423
|
|
00273 IF L423-TAX-WG-BASE-NULL-88 DTSCU423
|
|
00274 MOVE WRK-HDR-WAGE-BASE TO WRK-TAX-WAGE-BASE DTSCU423
|
|
00275 ELSE DTSCU423
|
|
00276 MOVE L423-TAX-WG-BASE-ADJ TO WRK-TAX-WAGE-BASE DTSCU423
|
|
00277 END-IF. DTSCU423
|
|
00278 PERFORM P1900-CALC-TAX-WAGE THRU P1900-EXIT. DTSCU423
|
|
00279 DTSCU423
|
|
00280 MOVE WRK-QTR1-TAX-WAGES TO WRK-QTR1-NEW-TAX-WAGES. DTSCU423
|
|
00281 MOVE WRK-QTR2-TAX-WAGES TO WRK-QTR2-NEW-TAX-WAGES. DTSCU423
|
|
00282 MOVE WRK-QTR3-TAX-WAGES TO WRK-QTR3-NEW-TAX-WAGES. DTSCU423
|
|
00283 MOVE WRK-QTR4-TAX-WAGES TO WRK-QTR4-NEW-TAX-WAGES. DTSCU423
|
|
00284 DTSCU423
|
|
00285 P1300-EXIT. DTSCU423
|
|
00286 EXIT. DTSCU423
|
|
00287 DTSCU423
|
|
00288 P1400-NET-TAX-WAGE. DTSCU423
|
|
00289 COMPUTE L423-QTR1-TAX-WAGES = DTSCU423
|
|
00290 (WRK-QTR1-NEW-TAX-WAGES - WRK-QTR1-OLD-TAX-WAGES). DTSCU423
|
|
00291 DTSCU423
|
|
00292 COMPUTE L423-QTR2-TAX-WAGES = DTSCU423
|
|
00293 (WRK-QTR2-NEW-TAX-WAGES - WRK-QTR2-OLD-TAX-WAGES). DTSCU423
|
|
00294 DTSCU423
|
|
00295 COMPUTE L423-QTR3-TAX-WAGES = DTSCU423
|
|
00296 (WRK-QTR3-NEW-TAX-WAGES - WRK-QTR3-OLD-TAX-WAGES). DTSCU423
|
|
00297 DTSCU423
|
|
00298 COMPUTE L423-QTR4-TAX-WAGES = DTSCU423
|
|
00299 (WRK-QTR4-NEW-TAX-WAGES - WRK-QTR4-OLD-TAX-WAGES). DTSCU423
|
|
00300 DTSCU423
|
|
00301 P1400-EXIT. DTSCU423
|
|
00302 EXIT. DTSCU423
|
|
00303 DTSCU423
|
|
00304 P1900-CALC-TAX-WAGE. DTSCU423
|
|
00305 MOVE WRK-TAX-WAGE-BASE TO WRK-WAGE-BASE-REMAIN. DTSCU423
|
|
00306 DTSCU423
|
|
00307 IF WRK-QTR1-WAGES > WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00308 MOVE WRK-WAGE-BASE-REMAIN TO WRK-QTR1-TAX-WAGES DTSCU423
|
|
00309 MOVE ZERO TO WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00310 ELSE DTSCU423
|
|
00311 MOVE WRK-QTR1-WAGES TO WRK-QTR1-TAX-WAGES DTSCU423
|
|
00312 SUBTRACT WRK-QTR1-WAGES FROM WRK-WAGE-BASE-REMAIN. DTSCU423
|
|
00313 DTSCU423
|
|
00314 IF WRK-QTR2-WAGES > WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00315 MOVE WRK-WAGE-BASE-REMAIN TO WRK-QTR2-TAX-WAGES DTSCU423
|
|
00316 MOVE ZERO TO WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00317 ELSE DTSCU423
|
|
00318 MOVE WRK-QTR2-WAGES TO WRK-QTR2-TAX-WAGES DTSCU423
|
|
00319 SUBTRACT WRK-QTR2-WAGES FROM WRK-WAGE-BASE-REMAIN. DTSCU423
|
|
00320 DTSCU423
|
|
00321 IF WRK-QTR3-WAGES > WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00322 MOVE WRK-WAGE-BASE-REMAIN TO WRK-QTR3-TAX-WAGES DTSCU423
|
|
00323 MOVE ZERO TO WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00324 ELSE DTSCU423
|
|
00325 MOVE WRK-QTR3-WAGES TO WRK-QTR3-TAX-WAGES DTSCU423
|
|
00326 SUBTRACT WRK-QTR3-WAGES FROM WRK-WAGE-BASE-REMAIN. DTSCU423
|
|
00327 DTSCU423
|
|
00328 IF WRK-QTR4-WAGES > WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00329 MOVE WRK-WAGE-BASE-REMAIN TO WRK-QTR4-TAX-WAGES DTSCU423
|
|
00330 MOVE ZERO TO WRK-WAGE-BASE-REMAIN DTSCU423
|
|
00331 ELSE DTSCU423
|
|
00332 MOVE WRK-QTR4-WAGES TO WRK-QTR4-TAX-WAGES DTSCU423
|
|
00333 SUBTRACT WRK-QTR4-WAGES FROM WRK-WAGE-BASE-REMAIN. DTSCU423
|
|
00334 DTSCU423
|
|
00335 P1900-EXIT. DTSCU423
|
|
00336 EXIT. DTSCU423
|
|
00337 DTSCU423
|
|
00338 S004-FROM-5. DTSCU423
|
|
00339 SET L004-FROM-5 TO TRUE. DTSCU423
|
|
00340 EXEC CICS DTSCU423
|
|
00341 LINK DTSCU423
|
|
00342 PROGRAM('DTSCU004') DTSCU423
|
|
00343 COMMAREA(L004-COMM-AREA) DTSCU423
|
|
00344 END-EXEC. DTSCU423
|
|
00345 DTSCU423
|
|
00346 S004-EXIT. DTSCU423
|
|
00347 EXIT. DTSCU423
|
|
00348 DTSCU423
|
|
00349 S831A-READ. DTSCU423
|
|
00350 SET L831-READ-88 TO TRUE. DTSCU423
|
|
00351 PERFORM S831Z-REF-IO THRU S831Z-EXIT. DTSCU423
|
|
00352 DTSCU423
|
|
00353 S831A-EXIT. DTSCU423
|
|
00354 EXIT. DTSCU423
|
|
00355 DTSCU423
|
|
00356 S831Z-REF-IO. DTSCU423
|
|
00357 EXEC CICS DTSCU423
|
|
00358 LINK DTSCU423
|
|
00359 PROGRAM('DTSCU831') DTSCU423
|
|
00360 COMMAREA(L831-COMM-AREA) DTSCU423
|
|
00361 END-EXEC. DTSCU423
|
|
00362 DTSCU423
|
|
00363 S831Z-EXIT. DTSCU423
|
|
00364 EXIT. DTSCU423
|
|
00365 DTSCU423
|
|
00366 S899-ABEND. DTSCU423
|
|
00367 EXEC CICS DTSCU423
|
|
00368 ABEND DTSCU423
|
|
00369 ABCODE(WRK-ABEND-CD) DTSCU423
|
|
00370 END-EXEC. DTSCU423
|
|
00371 S899-EXIT. DTSCU423
|
|
00372 EXIT. DTSCU423
|