564 lines
44 KiB
COBOL
564 lines
44 KiB
COBOL
00001 IDENTIFICATION DIVISION. 09/13/16
|
|
00002 PROGRAM-ID. DTSBR303. DTSBR303
|
|
00003 AUTHOR. TRW S&ITG LV076
|
|
00004 DATE-WRITTEN. DECEMBER 1998 DTSBR303
|
|
00005 DATE-COMPILED. DTSBR303
|
|
00006 DTSBR303
|
|
00007 ***** DTSBR303
|
|
00008 * DTSBR303
|
|
00009 * CALLING SEQUENCE: DTSBD300 CALLS DTSBD370 DTSBR303
|
|
00010 * WHICH CALLS DTSBD372 DTSBR303
|
|
00011 * WHICH CREATES DTSIR303 RECORDS. DTSBR303
|
|
00012 * DTSBD800 CALLS DTSBR303 DTSBR303
|
|
00013 * WHICH PRODUCES THE VOUCHER REPORTDTSBR303
|
|
00014 * DTSBR303
|
|
00015 * FUNCTION: REVENUE REFUND VOUCHER. DTSBR303
|
|
00016 * DTSBR303
|
|
00017 * DTSBR303
|
|
00018 * MODIFICATION HISTORY: DTSBR303
|
|
00019 * DTSBR303
|
|
00020 * DTSBR303
|
|
00021 * 01-28-2008 MODIFIED TO PRODUCE AN OUTPUT FILE OF REFUNDS TO BE DTSBR303
|
|
00022 * TRANSMITTED THROUGH FTP TO THE CFO. DTSBR303
|
|
00023 * REFERENCE RFP #**** AUTHOR OF CHANGE - GD DTSBR303
|
|
00024 * DTSBR303
|
|
00025 * 07-22-2008 RECOMPILED WITH NEW VERSION OF DTSIX304 - ADDRESS DTSBR303
|
|
00026 * LINES REDUCED TO 30 BYTES. DTSBR303
|
|
00027 * REFERENCE RFP #**** AUTHOR OF CHANGE - GD DTSBR303
|
|
00028 * DTSBR303
|
|
00029 * 10-16-2008 CORRECTED X304-EFFECTIVE-DATE. IT WAS BASED ON THE DTSBR303
|
|
00030 * FISCAL YEAR, BUT SHOULD BE THE SAME AS X303-BATCH-DATDTSBR303
|
|
00031 * REFERENCE RFP #**** AUTHOR OF CHANGE - GD DTSBR303
|
|
00032 * DTSBR303
|
|
00033 * 06-03-2009 ADDED P1200 TO ADD ANY PART OF THE SECOND ADDRESS DTSBR303
|
|
00034 * LINE THAT MIGHT BE TRUNCATED TO THE FIRST LINE. DTSBR303
|
|
00035 * REFERENCE RFP ENH139 AUTHOR OF CHANGE - GD DTSBR303
|
|
00036 * DTSBR303
|
|
00037 * 06-19-2009 CORRECTED PROBLEM WITH ADDRESS: THE DAFRIN FORMAT DTSBR303
|
|
00038 * REQUIRES THAT THE FIRST STREET ADDRESS LINE BE USED DTSBR303
|
|
00039 * FIRST, WITH OVERFLOW GOING INTO THE SECOND LINE. DTSBR303
|
|
00040 * REFERENCE RFP AUTHOR OF CHANGE - GD DTSBR303
|
|
00041 * DTSBR303
|
|
00042 * 09-16-2009 MODIFIED TO SET DOC DATE EQUAL TO BATCH DATE. DTSBR303
|
|
00043 * THE DOC DATE FIELD IS NOW REQUIRED. DTSBR303
|
|
00044 * REFERENCE RFP AUTHOR OF CHANGE - GD DTSBR303
|
|
00045 * DTSBR303
|
|
00046 * 02-02-2010 RECOMPILED FOR CHANGE IN BANK ID FROM 121 TO 150. DTSBR303
|
|
00047 * THE ID IS HARD-CODED IN DTSIX304. DTSBR303
|
|
00048 * REFERENCE; EMAIL FROM LASHAWN AUTHOR OF CHANGE - GD DTSBR303
|
|
00049 * 07-20-2016 CORRECTED ISSUE WITH ADDRESS USING MOVE INSTEAD OF DTSBR303
|
|
00050 * PERFORM. DTSBR303
|
|
00051 * REFERENCE; MEETING WITH SIA AUTHOR OF CHANGE - NH DTSBR303
|
|
00052 * DTSBR303
|
|
00053 * MM-DD-YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXDTSBR303
|
|
00054 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXDTSBR303
|
|
00055 * REFERENCE RFP #**** AUTHOR OF CHANGE - XXXDTSBR303
|
|
00056 * DTSBR303
|
|
00057 * DTSBR303
|
|
00058 * DESCRIPTION: DTSBR303
|
|
00059 * DTSBR303
|
|
00060 * THIS MODULE PRODUCES PRINTOUTS OF REFUND VOUCHERS. DTSBR303
|
|
00061 * DTSBR303
|
|
00062 * DTSBR303
|
|
00063 * RECORDS READ: DTSBR303
|
|
00064 * DTSBR303
|
|
00065 * DTSIR303. DTSBR303
|
|
00066 * DTSBR303
|
|
00067 * DTSBR303
|
|
00068 * PRINTED OUTPUTS: DTSBR303
|
|
00069 * DTSBR303
|
|
00070 * DTSBR303 REFUND VOUCHER. DTSBR303
|
|
00071 * DTSBR303
|
|
00072 * DTSBR303
|
|
00073 * RECORDS WRITTEN: DTSBR303
|
|
00074 * DTSBR303
|
|
00075 * NONE. DTSBR303
|
|
00076 * DTSBR303
|
|
00077 * DTSBR303
|
|
00078 * MODULES CALLED: DTSBR303
|
|
00079 * DTSBR303
|
|
00080 * DTSBU001 DATE EDIT/CONVERSION MODULE DTSBR303
|
|
00081 * DTSBR303
|
|
00082 ***** DTSBR303
|
|
00083 EJECT DTSBR303
|
|
00084 ENVIRONMENT DIVISION. DTSBR303
|
|
00085 DTSBR303
|
|
00086 CONFIGURATION SECTION. DTSBR303
|
|
00087 SPECIAL-NAMES. DTSBR303
|
|
00088 C01 IS TOP-OF-PAGE. DTSBR303
|
|
00089 INPUT-OUTPUT SECTION. DTSBR303
|
|
00090 DTSBR303
|
|
00091 FILE-CONTROL. DTSBR303
|
|
00092 SELECT CFO-FILE ASSIGN TO RPT303R3. DTSBR303
|
|
00093 SELECT MEMO-FILE ASSIGN TO RPT303R2. DTSBR303
|
|
00094 DTSBR303
|
|
00095 DATA DIVISION. DTSBR303
|
|
00096 DTSBR303
|
|
00097 FILE SECTION. DTSBR303
|
|
00098 FD CFO-FILE DTSBR303
|
|
00099 RECORDING MODE IS F DTSBR303
|
|
00100 LABEL RECORDS ARE OMITTED DTSBR303
|
|
00101 RECORD CONTAINS 750 CHARACTERS DTSBR303
|
|
00102 DATA RECORD IS PRINT-RCD. DTSBR303
|
|
00103 01 CFO-RCD PIC X(750). DTSBR303
|
|
00104 DTSBR303
|
|
00105 FD MEMO-FILE DTSBR303
|
|
00106 RECORDING MODE IS F DTSBR303
|
|
00107 LABEL RECORDS ARE OMITTED DTSBR303
|
|
00108 RECORD CONTAINS 133 CHARACTERS DTSBR303
|
|
00109 DATA RECORD IS MEMO-RCD. DTSBR303
|
|
00110 01 MEMO-RCD PIC X(133). DTSBR303
|
|
00111 EJECT DTSBR303
|
|
00112 WORKING-STORAGE SECTION. DTSBR303
|
|
001125 77 PAN-VALET PICTURE X(24) VALUE '076DTSBR303 09/13/16'. DTSBR303
|
|
00113 77 PAN-VALET PICTURE X(24) VALUE '001DTSBR303 09/13/16'. DTSBR303
|
|
00114 77 PAN-VALET PICTURE X(24) VALUE '074DTSBR303 09/13/16'. DTSBR303
|
|
00115 77 PAN-VALET PICTURE X(24) VALUE '004DTSBR303 09/13/16'. DTSBR303
|
|
00116 77 PAN-VALET PICTURE X(24) VALUE '072DTSBR303 02/02/10'. DTSBR303
|
|
00117 DTSBR303
|
|
00118 01 WRK-AREA. DTSBR303
|
|
00119 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +303. DTSBR303
|
|
00120 05 PROG-FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR303
|
|
00121 88 PROG-FIRST-TIME-YES-88 VALUE 'Y'. DTSBR303
|
|
00122 88 PROG-FIRST-TIME-NO-88 VALUE 'N'. DTSBR303
|
|
00123 05 FIRST-R303-IND PIC X(01) VALUE 'Y'. DTSBR303
|
|
00124 88 FIRST-R303-YES-88 VALUE 'Y'. DTSBR303
|
|
00125 88 FIRST-R303-NO-88 VALUE 'N'. DTSBR303
|
|
00126 05 WRK-FEIN PIC S9(09) VALUE ZEROS. DTSBR303
|
|
00127 05 SUB1 PIC S9(04) COMP. DTSBR303
|
|
00128 05 SUB2 PIC S9(04) COMP. DTSBR303
|
|
00129 05 SUB3 PIC S9(04) COMP. DTSBR303
|
|
00130 05 SUB4 PIC S9(04) COMP. DTSBR303
|
|
00131 05 SUB5 PIC S9(04) COMP. DTSBR303
|
|
00132 05 SUB6 PIC S9(04) COMP. DTSBR303
|
|
00133 05 WRK-SUITE-FOUND-IND PIC X(01). DTSBR303
|
|
00134 88 WRK-SUITE-FOUND-YES-88 VALUE 'Y'. DTSBR303
|
|
00135 88 WRK-SUITE-FOUND-NO-88 VALUE 'N'. DTSBR303
|
|
00136 DTSBR303
|
|
00137 01 WRK-KEY-CFO-DATA. DTSBR303
|
|
00138 05 WRK-BATCH-DATE PIC 9(08) VALUE 0. DTSBR303
|
|
00139 05 WRK-JUL-DATE PIC 9(07). DTSBR303
|
|
00140 05 FILLER REDEFINES WRK-JUL-DATE. DTSBR303
|
|
00141 10 FILLER PIC X(02). DTSBR303
|
|
00142 10 WRK-SYSTEM-DATE PIC 9(05). DTSBR303
|
|
00143 05 WRK-EFF-DATE PIC 9(08) VALUE 0. DTSBR303
|
|
00144 05 WRK-CFO-BATCH PIC 9(03) VALUE 0. DTSBR303
|
|
00145 05 WRK-MAX-SEQ PIC 9(05) VALUE 0. DTSBR303
|
|
00146 05 WRK-TOT-REFUND PIC 9(11)V99 VALUE 0. DTSBR303
|
|
00147 05 WRK-EMP-NO PIC 9(06). DTSBR303
|
|
00148 DTSBR303
|
|
00149 01 WRK-R309-AREA. DTSBR303
|
|
00150 05 WS-CTR PIC S9(07) COMP-3 VALUE ZEROS. DTSBR303
|
|
00151 05 WRK-R309-STMT-DATE PIC X(10) VALUE SPACES. DTSBR303
|
|
00152 05 WRK-R309-ADDR5 PIC X(40) VALUE SPACES. DTSBR303
|
|
00153 05 WRK-R309-ADDR4 PIC X(40) VALUE SPACES. DTSBR303
|
|
00154 05 WRK-R309-ADDR3 PIC X(40) VALUE SPACES. DTSBR303
|
|
00155 05 WRK-R309-ADDR2 PIC X(40) VALUE SPACES. DTSBR303
|
|
00156 05 WRK-R309-ADDR1 PIC X(40) VALUE SPACES. DTSBR303
|
|
00157 05 WS-AMT PIC X(14). DTSBR303
|
|
00158 05 WS-AMT-EDIT REDEFINES WS-AMT DTSBR303
|
|
00159 PIC ZZZ,ZZZ,ZZ9.99. DTSBR303
|
|
00160 DTSBR303
|
|
00161 01 WRK-HEADING-LINE. DTSBR303
|
|
00162 05 FILLER PIC X(01) VALUE SPACE. DTSBR303
|
|
00163 01 WRK-PRINT-LINE-1. DTSBR303
|
|
00164 05 FILLER1 PIC X(75). DTSBR303
|
|
00165 05 WRK-ACCT-NUM PIC 999B999. DTSBR303
|
|
00166 05 FILLER2 PIC X(35). DTSBR303
|
|
00167 05 WRK-VOUCHER-NUM PIC ZZZZZZZZ. DTSBR303
|
|
00168 05 FILLER3 PIC X(09). DTSBR303
|
|
00169 01 WRK-PRINT-LINE-2. DTSBR303
|
|
00170 05 FILLER4 PIC X(72). DTSBR303
|
|
00171 05 WRK-EMPLOYER-NAME PIC X(40). DTSBR303
|
|
00172 05 FILLER5 PIC X(17). DTSBR303
|
|
00173 01 WRK-PRINT-LINE-3. DTSBR303
|
|
00174 05 FILLER6 PIC X(41). DTSBR303
|
|
00175 05 WRK-TODAY-MONTH PIC X(02). DTSBR303
|
|
00176 05 FILLER7 PIC X(02). DTSBR303
|
|
00177 05 WRK-TODAY-DAY PIC X(02). DTSBR303
|
|
00178 05 FILLER8 PIC X(02). DTSBR303
|
|
00179 05 WRK-TODAY-YEAR PIC X(04). DTSBR303
|
|
00180 01 WRK-PRINT-LINE-3A. DTSBR303
|
|
00181 05 FILLER9 PIC X(72). DTSBR303
|
|
00182 05 WRK-ADDRESS-1 PIC X(40). DTSBR303
|
|
00183 05 FILLER10 PIC X(27). DTSBR303
|
|
00184 01 WRK-PRINT-LINE-4. DTSBR303
|
|
00185 05 FILLER11 PIC X(73). DTSBR303
|
|
00186 05 WRK-ADDRESS-2 PIC X(40). DTSBR303
|
|
00187 05 FILLER12 PIC X(24). DTSBR303
|
|
00188 01 WRK-PRINT-LINE-5. DTSBR303
|
|
00189 05 FILLER13 PIC X(80). DTSBR303
|
|
00190 05 WRK-CITY PIC X(25). DTSBR303
|
|
00191 05 FILLER14 PIC X(02). DTSBR303
|
|
00192 05 WRK-STATE PIC X(02). DTSBR303
|
|
00193 05 FILLER15 PIC X(10). DTSBR303
|
|
00194 05 WRK-ZIP PIC X(10). DTSBR303
|
|
00195 05 FILLER16 PIC X(11). DTSBR303
|
|
00196 01 WRK-PRINT-LINE-6. DTSBR303
|
|
00197 05 FILLER17 PIC X(119). DTSBR303
|
|
00198 05 WRK-REFUND-AMT PIC --,---,--9.99. DTSBR303
|
|
00199 05 FILLER18 PIC X(02). DTSBR303
|
|
00200 01 WRK-PRINT-LINE-7. DTSBR303
|
|
00201 05 FILLER19 PIC X(119). DTSBR303
|
|
00202 05 WRK-TOTAL-AMT PIC --,---,--9.99. DTSBR303
|
|
00203 05 FILLER20 PIC X(02). DTSBR303
|
|
00204 DTSBR303
|
|
00205 01 C072-LINK-AREA. DTSBR303
|
|
00206 ++INCLUDE DTSIC072 DTSBR303
|
|
00207 DTSBR303
|
|
00208 ++INCLUDE DTSXL303 DTSBR303
|
|
00209 EJECT DTSBR303
|
|
00210 ++INCLUDE DTSXD303 DTSBR303
|
|
00211 EJECT DTSBR303
|
|
00212 ++INCLUDE DTSXL30A DTSBR303
|
|
00213 EJECT DTSBR303
|
|
00214 01 L001-LINK-AREA. DTSBR303
|
|
00215 ++INCLUDE DTSIL001 DTSBR303
|
|
00216 EJECT DTSBR303
|
|
00217 01 L090-LINK-AREA. DTSBR303
|
|
00218 ++INCLUDE DTSIL090 DTSBR303
|
|
00219 EJECT DTSBR303
|
|
00220 01 X303-REC. DTSBR303
|
|
00221 ++INCLUDE DTSIX303 DTSBR303
|
|
00222 EJECT DTSBR303
|
|
00223 01 X304-REC. DTSBR303
|
|
00224 ++INCLUDE DTSIX304 DTSBR303
|
|
00225 EJECT DTSBR303
|
|
00226 EJECT DTSBR303
|
|
00227 LINKAGE SECTION. DTSBR303
|
|
00228 DTSBR303
|
|
00229 01 LRCM-LINK-AREA. DTSBR303
|
|
00230 ++INCLUDE DTSILRCM DTSBR303
|
|
00231 EJECT DTSBR303
|
|
00232 01 R303-REC. DTSBR303
|
|
00233 ++INCLUDE DTSIR303 DTSBR303
|
|
00234 EJECT DTSBR303
|
|
00235 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR303
|
|
00236 R303-REC. DTSBR303
|
|
00237 DTSBR303
|
|
00238 IF PROG-FIRST-TIME-YES-88 DTSBR303
|
|
00239 PERFORM I1000-INITIATE DTSBR303
|
|
00240 THRU I1000-EXIT DTSBR303
|
|
00241 SET PROG-FIRST-TIME-NO-88 TO TRUE DTSBR303
|
|
00242 END-IF. DTSBR303
|
|
00243 DTSBR303
|
|
00244 IF LRCM-EOR-88 DTSBR303
|
|
00245 PERFORM T1000-TERMINATE DTSBR303
|
|
00246 THRU T1000-EXIT DTSBR303
|
|
00247 ELSE DTSBR303
|
|
00248 PERFORM P1000-PROCESS DTSBR303
|
|
00249 THRU P1000-EXIT. DTSBR303
|
|
00250 DTSBR303
|
|
00251 GOBACK. DTSBR303
|
|
00252 EJECT DTSBR303
|
|
00253 I1000-INITIATE. DTSBR303
|
|
00254 DTSBR303
|
|
00255 OPEN OUTPUT CFO-FILE DTSBR303
|
|
00256 MEMO-FILE. DTSBR303
|
|
00257 DTSBR303
|
|
00258 WRITE MEMO-RCD FROM LINE-13 AFTER 12. DTSBR303
|
|
00259 WRITE MEMO-RCD FROM LINE-14. DTSBR303
|
|
00260 WRITE MEMO-RCD FROM LINE-15. DTSBR303
|
|
00261 WRITE MEMO-RCD FROM LINE-16. DTSBR303
|
|
00262 WRITE MEMO-RCD FROM LINE-17. DTSBR303
|
|
00263 WRITE MEMO-RCD FROM XEROX-XD303-LINE1. DTSBR303
|
|
00264 WRITE MEMO-RCD FROM XEROX-XD303-LINE2. DTSBR303
|
|
00265 I1000-EXIT. DTSBR303
|
|
00266 EXIT. DTSBR303
|
|
00267 EJECT DTSBR303
|
|
00268 P1000-PROCESS. DTSBR303
|
|
00269 MOVE R303-CFO-AGENCY TO X304-BATCH-AGY. DTSBR303
|
|
00270 MOVE R303-CFO-TYPE TO X304-BATCH-TYPE. DTSBR303
|
|
00271 MOVE R303-CFO-REQUEST-DATE TO L001-FED-8-DATE-9. DTSBR303
|
|
00272 SET L001-FROM-FED-8 TO TRUE. DTSBR303
|
|
00273 PERFORM S001-DATE THRU S001-EXIT. DTSBR303
|
|
00274 MOVE L001-FED-8-DATE-X TO X304-BATCH-DATE DTSBR303
|
|
00275 X304-INVOICE-DATE DTSBR303
|
|
00276 X304-DUE-DATE DTSBR303
|
|
00277 X304-SERVICE-DATE DTSBR303
|
|
00278 X304-EFFECTIVE-DATE DTSBR303
|
|
00279 X304-DOC-DATE. DTSBR303
|
|
00280 DISPLAY 'DOC DATE ' X304-DOC-DATE. DTSBR303
|
|
00281 DTSBR303
|
|
00282 IF L001-FED-8-MO = 10 OR 11 OR 12 DTSBR303
|
|
00283 ADD 1 TO L001-FED-8-YR DTSBR303
|
|
00284 MOVE L001-FED-8-YR (3:2) TO X304-APPN-YEAR DTSBR303
|
|
00285 ELSE DTSBR303
|
|
00286 MOVE L001-FED-8-YR (3:2) TO X304-APPN-YEAR DTSBR303
|
|
00287 END-IF. DTSBR303
|
|
00288 MOVE X304-APPN-YEAR TO X304-DOC-YEAR. DTSBR303
|
|
00289 MOVE R303-CFO-BATCH-NO TO X304-BATCH-NUMBER. DTSBR303
|
|
00290 MOVE R303-CFO-SEQ-NO TO X304-BATCH-SEQUENCE DTSBR303
|
|
00291 WRK-MAX-SEQ. DTSBR303
|
|
00292 MOVE R303-EMP-NO TO WRK-EMP-NO. DTSBR303
|
|
00293 STRING DTSBR303
|
|
00294 'EMP NBR ', DTSBR303
|
|
00295 WRK-EMP-NO DTSBR303
|
|
00296 DELIMITED BY SIZE DTSBR303
|
|
00297 INTO X304-INVOICE-NO. DTSBR303
|
|
00298 MOVE R303-FEIN TO X304-FEIN. DTSBR303
|
|
00299 MOVE R303-CURR-DOC-NO TO X304-CURR-DOC-NO. DTSBR303
|
|
00300 ** MOVE R303-CURR-DOC-NO-SFX TO X304-CURR-DOC-NO-SFX. DTSBR303
|
|
00301 MOVE R303-REFUND-AMT TO X304-TRANS-AMT. DTSBR303
|
|
00302 ADD R303-REFUND-AMT TO WRK-TOT-REFUND. DTSBR303
|
|
00303 MOVE R303-PRIMARY-NAME (1:30) TO X304-VENDOR-NAME. DTSBR303
|
|
00304 ***COMMENTING OUT THE P1200 ADDRESS AND USING THE MOVES INSTEAD DTSBR303
|
|
00305 ** PERFORM P1200-ADDRESS THRU P1200-EXIT. DTSBR303
|
|
00306 IF R303-DELIV-LINE-1 > SPACES DTSBR303
|
|
00307 MOVE R303-DELIV-LINE-1 (1:30) TO X304-VENDOR-ADDR-1 DTSBR303
|
|
00308 MOVE R303-DELIV-LINE-2 (1:30) TO X304-VENDOR-ADDR-2 DTSBR303
|
|
00309 ELSE DTSBR303
|
|
00310 IF R303-DELIV-LINE-1 = SPACES DTSBR303
|
|
00311 MOVE R303-DELIV-LINE-2 (1:30) TO X304-VENDOR-ADDR-1 DTSBR303
|
|
00312 MOVE R303-DELIV-LINE-1 (1:30) TO X304-VENDOR-ADDR-2 DTSBR303
|
|
00313 END-IF DTSBR303
|
|
00314 END-IF. DTSBR303
|
|
00315 ***COMMENTING OUT THE P1200 ADDRESS AND USING THE MOVES INSTEAD DTSBR303
|
|
00316 MOVE SPACES TO X304-VENDOR-ADDR-3 DTSBR303
|
|
00317 X304-VENDOR-ADDR-4. DTSBR303
|
|
00318 MOVE R303-CITY TO X304-VENDOR-CITY. DTSBR303
|
|
00319 MOVE R303-ST TO X304-VENDOR-STATE. DTSBR303
|
|
00320 MOVE R303-ZIP (1:5) TO X304-VENDOR-ZIP-1-5. DTSBR303
|
|
00321 MOVE R303-ZIP (7:4) TO X304-VENDOR-ZIP-6-9. DTSBR303
|
|
00322 MOVE R303-ST TO C072-ST. DTSBR303
|
|
00323 IF C072-US-88 DTSBR303
|
|
00324 MOVE 'US' TO X304-COUNTRY-CODE DTSBR303
|
|
00325 ELSE DTSBR303
|
|
00326 IF C072-CANADA-88 DTSBR303
|
|
00327 MOVE 'CN' TO X304-COUNTRY-CODE DTSBR303
|
|
00328 ELSE DTSBR303
|
|
00329 MOVE SPACES TO X304-COUNTRY-CODE DTSBR303
|
|
00330 END-IF DTSBR303
|
|
00331 END-IF. DTSBR303
|
|
00332 DTSBR303
|
|
00333 WRITE CFO-RCD FROM X304-REC. DTSBR303
|
|
00334 DTSBR303
|
|
00335 IF FIRST-R303-YES-88 DTSBR303
|
|
00336 PERFORM P1100-SAVE-KEY-DATA THRU P1100-EXIT DTSBR303
|
|
00337 SET FIRST-R303-NO-88 TO TRUE DTSBR303
|
|
00338 END-IF. DTSBR303
|
|
00339 DTSBR303
|
|
00340 MOVE R303-FMT-LINE(1) TO WRK-R309-ADDR1. DTSBR303
|
|
00341 MOVE R303-FMT-LINE(2) TO WRK-R309-ADDR2. DTSBR303
|
|
00342 MOVE R303-FMT-LINE(3) TO WRK-R309-ADDR3. DTSBR303
|
|
00343 MOVE R303-FMT-LINE(4) TO WRK-R309-ADDR4. DTSBR303
|
|
00344 MOVE R303-FMT-LINE(5) TO WRK-R309-ADDR5. DTSBR303
|
|
00345 MOVE R303-EMP-NO TO WRK-ACCT-NUM. DTSBR303
|
|
00346 MOVE R303-FEIN TO WRK-FEIN. DTSBR303
|
|
00347 SET L001-FROM-FED-8 TO TRUE. DTSBR303
|
|
00348 MOVE R303-CURR-MAIL-DATE TO L001-FED-8-DATE-9. DTSBR303
|
|
00349 PERFORM S001-DATE THRU S001-EXIT. DTSBR303
|
|
00350 MOVE L001-FED-6-YR TO WRK-TODAY-YEAR. DTSBR303
|
|
00351 MOVE L001-FED-6-DA TO WRK-TODAY-DAY. DTSBR303
|
|
00352 MOVE L001-FED-6-MO TO WRK-TODAY-MONTH. DTSBR303
|
|
00353 MOVE L001-SLASH-8-DATE TO WRK-R309-STMT-DATE. DTSBR303
|
|
00354 MOVE R303-REFUND-AMT TO WS-AMT-EDIT. DTSBR303
|
|
00355 PERFORM S2000-WRITE-CREDIT-MEMO THRU S2000-EXIT. DTSBR303
|
|
00356 DTSBR303
|
|
00357 DISPLAY SPACE. DTSBR303
|
|
00358 DISPLAY 'X304 DETAIL'. DTSBR303
|
|
00359 DISPLAY ' BATCH NO ' X304-BATCH-NUMBER. DTSBR303
|
|
00360 DISPLAY ' DOC DATE ' X304-DOC-DATE. DTSBR303
|
|
00361 DISPLAY ' DOC NO ' X304-CURR-DOC-NO. DTSBR303
|
|
00362 DISPLAY ' SEQUENCE ' X304-BATCH-SEQUENCE. DTSBR303
|
|
00363 DISPLAY ' REFUND ' X304-TRANS-AMT. DTSBR303
|
|
00364 DTSBR303
|
|
00365 P1000-EXIT. DTSBR303
|
|
00366 EXIT. DTSBR303
|
|
00367 DTSBR303
|
|
00368 P1100-SAVE-KEY-DATA. DTSBR303
|
|
00369 MOVE X304-BATCH-DATE TO WRK-BATCH-DATE. DTSBR303
|
|
00370 MOVE X304-EFFECTIVE-DATE TO WRK-EFF-DATE. DTSBR303
|
|
00371 MOVE X304-BATCH-DATE TO L001-FED-8-DATE-9. DTSBR303
|
|
00372 SET L001-FROM-FED-8 TO TRUE. DTSBR303
|
|
00373 PERFORM S001-DATE THRU S001-EXIT. DTSBR303
|
|
00374 MOVE L001-JUL-DATE TO WRK-JUL-DATE. DTSBR303
|
|
00375 MOVE X304-BATCH-NUMBER TO WRK-CFO-BATCH. DTSBR303
|
|
00376 DTSBR303
|
|
00377 P1100-EXIT. DTSBR303
|
|
00378 EXIT. DTSBR303
|
|
00379 DTSBR303
|
|
00380 P1200-ADDRESS. DTSBR303
|
|
00381 SET WRK-SUITE-FOUND-NO-88 TO TRUE. DTSBR303
|
|
00382 MOVE +0 TO SUB2 DTSBR303
|
|
00383 SUB3 DTSBR303
|
|
00384 SUB4 DTSBR303
|
|
00385 SUB5 DTSBR303
|
|
00386 SUB6. DTSBR303
|
|
00387 DTSBR303
|
|
00388 PERFORM DTSBR303
|
|
00389 VARYING SUB1 FROM +1 BY +1 DTSBR303
|
|
00390 UNTIL SUB1 > +40 DTSBR303
|
|
00391 IF WRK-SUITE-FOUND-NO-88 DTSBR303
|
|
00392 IF R303-DELIV-LINE-2 (SUB1:4) = 'STE ' DTSBR303
|
|
00393 SET WRK-SUITE-FOUND-YES-88 TO TRUE DTSBR303
|
|
00394 MOVE SUB1 TO SUB6 DTSBR303
|
|
00395 END-IF DTSBR303
|
|
00396 END-IF DTSBR303
|
|
00397 IF R303-DELIV-LINE-2 (SUB1:1) = SPACE DTSBR303
|
|
00398 IF SUB1 <= 30 DTSBR303
|
|
00399 MOVE SUB1 TO SUB2 DTSBR303
|
|
00400 END-IF DTSBR303
|
|
00401 ELSE DTSBR303
|
|
00402 IF R303-DELIV-LINE-2 (SUB1:1) > SPACE DTSBR303
|
|
00403 MOVE SUB1 TO SUB3 DTSBR303
|
|
00404 END-IF DTSBR303
|
|
00405 END-IF DTSBR303
|
|
00406 END-PERFORM. DTSBR303
|
|
00407 DTSBR303
|
|
00408 IF SUB3 > +30 DTSBR303
|
|
00409 IF SUB6 > 1 DTSBR303
|
|
00410 SUBTRACT +1 FROM SUB6 DTSBR303
|
|
00411 IF SUB6 < SUB2 DTSBR303
|
|
00412 MOVE SUB6 TO SUB2 DTSBR303
|
|
00413 END-IF DTSBR303
|
|
00414 END-IF DTSBR303
|
|
00415 MOVE R303-DELIV-LINE-2 (1:SUB2) TO X304-VENDOR-ADDR-1 DTSBR303
|
|
00416 COMPUTE SUB1 = SUB3 - SUB2 + 1 DTSBR303
|
|
00417 PERFORM DTSBR303
|
|
00418 VARYING SUB4 FROM +1 BY +1 DTSBR303
|
|
00419 UNTIL SUB4 > +40 DTSBR303
|
|
00420 IF R303-DELIV-LINE-1 (SUB4:1) NOT = SPACE DTSBR303
|
|
00421 MOVE SUB4 TO SUB5 DTSBR303
|
|
00422 END-IF DTSBR303
|
|
00423 END-PERFORM DTSBR303
|
|
00424 STRING DTSBR303
|
|
00425 R303-DELIV-LINE-2 (SUB2:SUB1) DTSBR303
|
|
00426 ' ' DTSBR303
|
|
00427 R303-DELIV-LINE-1 (1:SUB5) DTSBR303
|
|
00428 DELIMITED BY SIZE DTSBR303
|
|
00429 INTO X304-VENDOR-ADDR-2 DTSBR303
|
|
00430 END-STRING DTSBR303
|
|
00431 ELSE DTSBR303
|
|
00432 MOVE R303-DELIV-LINE-1 (1:30) TO X304-VENDOR-ADDR-2 DTSBR303
|
|
00433 MOVE R303-DELIV-LINE-2 (1:30) TO X304-VENDOR-ADDR-1 DTSBR303
|
|
00434 END-IF. DTSBR303
|
|
00435 DTSBR303
|
|
00436 P1200-EXIT. DTSBR303
|
|
00437 EXIT. DTSBR303
|
|
00438 DTSBR303
|
|
00439 T1000-TERMINATE. DTSBR303
|
|
00440 MOVE WRK-BATCH-DATE TO X303-BATCH-DATE DTSBR303
|
|
00441 MOVE WRK-CFO-BATCH TO X303-BATCH-NO. DTSBR303
|
|
00442 MOVE ZERO TO X303-BATCH-SEQ-NO. DTSBR303
|
|
00443 MOVE WRK-EFF-DATE TO X303-BATCH-EFF-DATE. DTSBR303
|
|
00444 MOVE WRK-MAX-SEQ TO X303-BATCH-LAST-SEQ-NO DTSBR303
|
|
00445 X303-ENTERED-BATCH-CNT-N. DTSBR303
|
|
00446 MOVE WRK-SYSTEM-DATE TO X303-BATCH-SYSTEM-DATE. DTSBR303
|
|
00447 MOVE WRK-TOT-REFUND TO X303-ENTERED-BATCH-AMT-N. DTSBR303
|
|
00448 DTSBR303
|
|
00449 WRITE CFO-RCD FROM X303-REC. DTSBR303
|
|
00450 DISPLAY SPACE. DTSBR303
|
|
00451 DISPLAY 'X303 HEADER'. DTSBR303
|
|
00452 DISPLAY ' BATCH NO ' X303-BATCH-NO. DTSBR303
|
|
00453 DISPLAY ' SYSTEM DATE ' X303-BATCH-SYSTEM-DATE. DTSBR303
|
|
00454 DISPLAY ' LAST SEQ ' X303-BATCH-LAST-SEQ-NO. DTSBR303
|
|
00455 DISPLAY ' TOT REFUND ' X303-ENTERED-BATCH-AMT-N. DTSBR303
|
|
00456 DTSBR303
|
|
00457 CLOSE CFO-FILE DTSBR303
|
|
00458 MEMO-FILE. DTSBR303
|
|
00459 DTSBR303
|
|
00460 T1000-EXIT. DTSBR303
|
|
00461 EXIT. DTSBR303
|
|
00462 EJECT DTSBR303
|
|
00463 DTSBR303
|
|
00464 S2000-WRITE-CREDIT-MEMO. DTSBR303
|
|
00465 DTSBR303
|
|
00466 MOVE WRK-R309-ADDR1 TO MSH-FMT-LINE-1. DTSBR303
|
|
00467 MOVE WRK-R309-ADDR2 TO MSH-FMT-LINE-2. DTSBR303
|
|
00468 MOVE WRK-R309-ADDR3 TO MSH-FMT-LINE-3. DTSBR303
|
|
00469 MOVE WRK-R309-ADDR4 TO MSH-FMT-LINE-4. DTSBR303
|
|
00470 MOVE WRK-R309-ADDR5 TO MSH-FMT-LINE-5. DTSBR303
|
|
00471 MOVE WRK-ACCT-NUM TO MSH-EMP-NO. DTSBR303
|
|
00472 MOVE WRK-FEIN TO MSH-EMP-FEIN. DTSBR303
|
|
00473 MOVE WRK-R309-STMT-DATE TO MSH-STMT-DATE. DTSBR303
|
|
00474 WRITE MEMO-RCD FROM BLANK-LINE AFTER DTSBR303
|
|
00475 ADVANCING TOP-OF-PAGE. DTSBR303
|
|
00476 WRITE MEMO-RCD FROM BLANK-LINE AFTER ADVANCING 10 LINE. DTSBR303
|
|
00477 WRITE MEMO-RCD FROM MSH-LINE-12 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00478 WRITE MEMO-RCD FROM MSH-LINE-13 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00479 WRITE MEMO-RCD FROM MSH-LINE-14 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00480 WRITE MEMO-RCD FROM MSH-LINE-15 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00481 WRITE MEMO-RCD FROM MSH-LINE-16 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00482 WRITE MEMO-RCD FROM MSH-LINE-17 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00483 WRITE MEMO-RCD FROM MSH-LINE-18 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00484 DTSBR303
|
|
00485 MOVE 'YOUR ACCOUNT HAS A CREDIT BALANCE OF $' DTSBR303
|
|
00486 TO L090-PHRASE-TABLE (1). DTSBR303
|
|
00487 DTSBR303
|
|
00488 MOVE +0 TO WS-CTR. DTSBR303
|
|
00489 INSPECT WS-AMT TALLYING WS-CTR FOR LEADING SPACES. DTSBR303
|
|
00490 MOVE WS-AMT (WS-CTR + 1:) TO L090-PHRASE-TABLE (2). DTSBR303
|
|
00491 DTSBR303
|
|
00492 MOVE '. YOU EITHER NEED TO DEDUCT THIS AMOUNT' DTSBR303
|
|
00493 TO L090-PHRASE-TABLE (3). DTSBR303
|
|
00494 MOVE 'FROM YOUR NEXT UNEMPLOYMENT INSURANCE' DTSBR303
|
|
00495 TO L090-PHRASE-TABLE (4). DTSBR303
|
|
00496 MOVE 'EMPLOYER''S QUARTERLY WAGE REPORT' DTSBR303
|
|
00497 TO L090-PHRASE-TABLE (5). DTSBR303
|
|
00498 MOVE 'OR REQUEST A REFUND. TO REQUEST A REFUND,' DTSBR303
|
|
00499 TO L090-PHRASE-TABLE (6). DTSBR303
|
|
00500 MOVE 'SIGN BELOW AND RETURN THIS FORM TO THE' DTSBR303
|
|
00501 TO L090-PHRASE-TABLE (7). DTSBR303
|
|
00502 MOVE 'DISTRICT''S UNEMPLOYMENT INSURANCE DIVISION.' DTSBR303
|
|
00503 TO L090-PHRASE-TABLE (8). DTSBR303
|
|
00504 MOVE +8 TO L090-PHRASE-CNT. DTSBR303
|
|
00505 MOVE +77 TO L090-DESIRED-LINE-LIMIT. DTSBR303
|
|
00506 PERFORM S090-PARAGRAPH-FORMAT THRU S090-EXIT. DTSBR303
|
|
00507 DTSBR303
|
|
00508 MOVE L090-PARAGRAPH-LINE (1) TO MSF-PARA-LINE-1. DTSBR303
|
|
00509 MOVE L090-PARAGRAPH-LINE (2) TO MSF-PARA-LINE-2. DTSBR303
|
|
00510 MOVE L090-PARAGRAPH-LINE (3) TO MSF-PARA-LINE-3. DTSBR303
|
|
00511 MOVE L090-PARAGRAPH-LINE (4) TO MSF-PARA-LINE-4. DTSBR303
|
|
00512 WRITE MEMO-RCD FROM BLANK-LINE AFTER ADVANCING 7 LINE. DTSBR303
|
|
00513 WRITE MEMO-RCD FROM MSF-LINE-26 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00514 WRITE MEMO-RCD FROM MSF-LINE-27 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00515 WRITE MEMO-RCD FROM MSF-LINE-28 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00516 WRITE MEMO-RCD FROM MSF-LINE-29 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00517 WRITE MEMO-RCD FROM MSF-LINE-30 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00518 WRITE MEMO-RCD FROM MSF-LINE-31 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00519 WRITE MEMO-RCD FROM MSF-LINE-32 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00520 WRITE MEMO-RCD FROM MSF-LINE-33 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00521 WRITE MEMO-RCD FROM MSF-LINE-34 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00522 WRITE MEMO-RCD FROM MSF-LINE-37 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00523 WRITE MEMO-RCD FROM MSF-LINE-38 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00524 WRITE MEMO-RCD FROM MSF-LINE-39 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00525 WRITE MEMO-RCD FROM MSF-LINE-40 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00526 WRITE MEMO-RCD FROM MSF-LINE-41 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00527 WRITE MEMO-RCD FROM MSF-LINE-42 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00528 WRITE MEMO-RCD FROM MSF-LINE-43 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00529 WRITE MEMO-RCD FROM MSF-LINE-44 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00530 WRITE MEMO-RCD FROM MSF-LINE-45 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00531 WRITE MEMO-RCD FROM MSF-LINE-46 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00532 WRITE MEMO-RCD FROM MSF-LINE-47 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00533 WRITE MEMO-RCD FROM MSF-LINE-48 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00534 WRITE MEMO-RCD FROM MSF-LINE-49 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00535 WRITE MEMO-RCD FROM MSF-LINE-50 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00536 WRITE MEMO-RCD FROM MSF-LINE-51 AFTER ADVANCING 1 LINE. DTSBR303
|
|
00537 DTSBR303
|
|
00538 DTSBR303
|
|
00539 S2000-EXIT. DTSBR303
|
|
00540 EXIT. DTSBR303
|
|
00541 EJECT DTSBR303
|
|
00542 S001-DATE. DTSBR303
|
|
00543 DTSBR303
|
|
00544 CALL 'DTSBU001' USING L001-LINK-AREA. DTSBR303
|
|
00545 DTSBR303
|
|
00546 S001-EXIT. DTSBR303
|
|
00547 EXIT. DTSBR303
|
|
00548 DTSBR303
|
|
00549 S090-PARAGRAPH-FORMAT. DTSBR303
|
|
00550 SKIP1 DTSBR303
|
|
00551 MOVE +0 TO L090-INDENT. DTSBR303
|
|
00552 SET L090-SPECIAL-CHAR-STD-88 TO TRUE. DTSBR303
|
|
00553 DTSBR303
|
|
00554 CALL 'DTSBU090' USING L090-LINK-AREA. DTSBR303
|
|
00555 SKIP2 DTSBR303
|
|
00556 S090-EXIT. DTSBR303
|
|
00557 *S999-ABEND. DTSBR303
|
|
00558 * DTSBR303
|
|
00559 * CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR303
|
|
00560 * DTSBR303
|
|
00561 *S999-EXIT. DTSBR303
|
|
00562 * EXIT. DTSBR303
|