770 lines
61 KiB
COBOL
770 lines
61 KiB
COBOL
00001 IDENTIFICATION DIVISION. 04/06/17
|
|
00002 PROGRAM-ID. DTSBR415. DTSBR415
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV011
|
|
00004 DATE-WRITTEN. NOV 2002. DTSBR415
|
|
00005 DATE-COMPILED. DTSBR415
|
|
00006 SKIP3 DTSBR415
|
|
00007 ***** DTSBR415
|
|
00008 * DTSBR415
|
|
00009 * CALLING SEQUENCE: DTSBD300 CALLS DTSBR415
|
|
00010 * DTSBd327 WHICH CREATES DTSIR415 RECORDS DTSBR415
|
|
00011 * DTSBD800 CALLS DTSBR415
|
|
00012 * DTSBR415 WHICH READS DTSIR415 RECORDS DTSBR415
|
|
00013 * DTSBR415
|
|
00014 * FUNCTION: DEBIT MEMO PRINT (overnight) DTSBR415
|
|
00015 * DTSBR415
|
|
00016 * MODIFICATION HISTORY: DTSBR415
|
|
00017 * DTSBR415
|
|
00018 * 11-12-02 MODIFIED TO REFORMAT BILL USING NEW FORM. DTSBR415
|
|
00019 * DTSBR415
|
|
00020 * REFERENCE RFP # PROGRAMMER: ZL1 DTSBR415
|
|
00021 * DTSBR415
|
|
00022 * 03-32-06 MODIFIED TO include administrative assessment as a DTSBR415
|
|
00023 * seperate line item on bill. DTSBR415
|
|
00024 * REFERENCE RFP # PROGRAMMER: ZL1 DTSBR415
|
|
00025 * DTSBR415
|
|
00026 * 04-06-17 modified program to accomodate verbiage changes for DTSBR415
|
|
00027 * overnight bills and allows staff to create zero statements. DTSBR415
|
|
00028 * REFERENCE RFP # PROGRAMMER: nh1 DTSBR415
|
|
00029 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR415
|
|
00030 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR415
|
|
00031 * REFERENCE RFP #**** PROGRAMMER: XXX DTSBR415
|
|
00032 * DTSBR415
|
|
00033 * DTSBR415
|
|
00034 * DESCRIPTION: DTSBR415
|
|
00035 * DTSBR415
|
|
00036 * THIS MODULE PRINTS DEBIT MEMOS. DTSBR415
|
|
00037 * DTSBR415
|
|
00038 * IF DTSBR415 IS MODIFIED, THERE IS A STRONG PROBABILITY DTSBR415
|
|
00039 * THAT CORRESPONDING MODIFICATIONS MUST BE MADE TO DTSBR415
|
|
00040 * DTSCS46 (ON-LINE STATEMENT OF ACCOUNT PRINT). DTSBR415
|
|
00041 * DTSBR415
|
|
00042 * DTSBR415
|
|
00043 * PROCESSING: DTSBR415
|
|
00044 * DTSBR415
|
|
00045 * DETAIL: DTSBR415
|
|
00046 * DTSBR415
|
|
00047 * DTSBR415
|
|
00048 * RECORDS READ: DTSBR415
|
|
00049 * DTSBR415
|
|
00050 * FOPR. DTSBR415
|
|
00051 * DTSBR415
|
|
00052 * DTSBR415
|
|
00053 * PRINTED OUTPUTS: DTSBR415
|
|
00054 * DTSBR415
|
|
00055 * 415R1 STATEMENT OF ACCOUNT (DEBIT OVERNIGHT) DTSBR415
|
|
00056 * DTSBR415
|
|
00057 * DTSBR415
|
|
00058 * RECORDS WRITTEN: DTSBR415
|
|
00059 * DTSBR415
|
|
00060 * NONE. DTSBR415
|
|
00061 * DTSBR415
|
|
00062 * DTSBR415
|
|
00063 * MODULES CALLED: DTSBR415
|
|
00064 * DTSBR415
|
|
00065 * DTSBU001 DATE EDIT/CONVERSION. DTSBR415
|
|
00066 * DTSBR415
|
|
00067 ***** DTSBR415
|
|
00068 EJECT DTSBR415
|
|
00069 ENVIRONMENT DIVISION. DTSBR415
|
|
00070 SKIP2 DTSBR415
|
|
00071 INPUT-OUTPUT SECTION. DTSBR415
|
|
00072 DTSBR415
|
|
00073 FILE-CONTROL. DTSBR415
|
|
00074 SELECT PRT-FILE1 ASSIGN TO RPT415R1. DTSBR415
|
|
00075 SKIP3 DTSBR415
|
|
00076 DATA DIVISION. DTSBR415
|
|
00077 SKIP3 DTSBR415
|
|
00078 FILE SECTION. DTSBR415
|
|
00079 SKIP3 DTSBR415
|
|
00080 FD PRT-FILE1 DTSBR415
|
|
00081 LABEL RECORDS ARE STANDARD. DTSBR415
|
|
00082 01 PRT-REC1. DTSBR415
|
|
00083 05 FILLER PIC X(132). DTSBR415
|
|
00084 SKIP3 DTSBR415
|
|
00085 WORKING-STORAGE SECTION. DTSBR415
|
|
000855 77 PAN-VALET PICTURE X(24) VALUE '011DTSBR415 04/06/17'. DTSBR415
|
|
00086 77 PAN-VALET PICTURE X(24) VALUE '018DTSBR415 04/06/17'. DTSBR415
|
|
00087 77 PAN-VALET PICTURE X(24) VALUE '009DTSBR415 03/02/11'. DTSBR415
|
|
00088 SKIP3 DTSBR415
|
|
00089 01 WRK-AREA-CONSTANTS. DTSBR415
|
|
00090 05 WRK-ABEND-CD PIC S9(04) COMP DTSBR415
|
|
00091 VALUE +415. DTSBR415
|
|
00092 DTSBR415
|
|
00093 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR415
|
|
00094 DTSBR415
|
|
00095 05 TOT-LINE-CNT PIC S9(04) COMP VALUE +29. DTSBR415
|
|
00096 05 MAX-QTR-PRINT PIC S9(04) COMP VALUE +10. DTSBR415
|
|
00097 05 LINE-CNT PIC S9(04) COMP VALUE +0. DTSBR415
|
|
00098 DTSBR415
|
|
00099 05 ABEND-MSG PIC X(60) VALUE SPACE. DTSBR415
|
|
00100 DTSBR415
|
|
00101 05 PRT-FILE1-PAGE-CNT PIC S9(07) COMP-3 VALUE +0. DTSBR415
|
|
00102 DTSBR415
|
|
00103 05 DISPLAY-CNT PIC X(09) VALUE ZEROS. DTSBR415
|
|
00104 05 DISPLAY-CNT-Z REDEFINES DISPLAY-CNT DTSBR415
|
|
00105 PIC Z,ZZZ,ZZ9. DTSBR415
|
|
00106 05 WS-WRK-QTR PIC 9(05) VALUE ZEROS. DTSBR415
|
|
00107 05 WS-WRK-QTR-X REDEFINES WS-WRK-QTR. DTSBR415
|
|
00108 10 WRK-QTR-YR PIC 9(04). DTSBR415
|
|
00109 10 WRK-QTR-Q PIC 9(01). DTSBR415
|
|
00110 DTSBR415
|
|
00111 05 WS-PRT-QTR. DTSBR415
|
|
00112 10 WRK-PRT-YR PIC X(04) VALUE SPACES. DTSBR415
|
|
00113 10 WRK-PRT-SLASH PIC X(01) VALUE SPACES. DTSBR415
|
|
00114 10 WRK-PRT-Q PIC X(01) VALUE SPACES. DTSBR415
|
|
00115 DTSBR415
|
|
00116 05 WS-EMP-NAME. DTSBR415
|
|
00117 10 WRK-FIRST-4 PIC X(04) VALUE SPACES. DTSBR415
|
|
00118 10 WRK-LAST-36 PIC X(36) VALUE SPACES. DTSBR415
|
|
00119 DTSBR415
|
|
00120 SKIP3 DTSBR415
|
|
00121 05 WS-REC PIC X(132) VALUE SPACES. DTSBR415
|
|
00122 05 WS-XREC PIC X(132) VALUE SPACES. DTSBR415
|
|
00123 DTSBR415
|
|
00124 05 AMT-DISPLAYED-IND PIC X(01). DTSBR415
|
|
00125 88 AMT-DISPLAYED-NO-88 VALUE 'N'. DTSBR415
|
|
00126 88 AMT-DISPLAYED-YES-88 VALUE 'Y'. DTSBR415
|
|
00127 DTSBR415
|
|
00128 05 PRINT-PRIOR-QTRS-IND PIC X(01). DTSBR415
|
|
00129 88 PRINT-PRIOR-QTRS-NO-88 VALUE 'N'. DTSBR415
|
|
00130 88 PRINT-PRIOR-QTRS-YES-88 VALUE 'Y'. DTSBR415
|
|
00131 DTSBR415
|
|
00132 05 PRINT-FNOTE1-IND PIC X(01). DTSBR415
|
|
00133 88 PRINT-FNOTE1-NO-88 VALUE 'N'. DTSBR415
|
|
00134 88 PRINT-FNOTE1-YES-88 VALUE 'Y'. DTSBR415
|
|
00135 DTSBR415
|
|
00136 05 PRINT-FNOTE2-IND PIC X(01). DTSBR415
|
|
00137 88 PRINT-FNOTE2-NO-88 VALUE 'N'. DTSBR415
|
|
00138 88 PRINT-FNOTE2-YES-88 VALUE 'Y'. DTSBR415
|
|
00139 DTSBR415
|
|
00140 05 PRINT-FNOTE3-IND PIC X(01). DTSBR415
|
|
00141 88 PRINT-FNOTE3-NO-88 VALUE 'N'. DTSBR415
|
|
00142 88 PRINT-FNOTE3-YES-88 VALUE 'Y'. DTSBR415
|
|
00143 DTSBR415
|
|
00144 05 PRINT-FNOTE4-IND PIC X(01). DTSBR415
|
|
00145 88 PRINT-FNOTE4-NO-88 VALUE 'N'. DTSBR415
|
|
00146 88 PRINT-FNOTE4-YES-88 VALUE 'Y'. DTSBR415
|
|
00147 DTSBR415
|
|
00148 05 SUM-PRIOR-QTRS-IND PIC X(01). DTSBR415
|
|
00149 88 SUM-PRIOR-QTRS-NO-88 VALUE 'N'. DTSBR415
|
|
00150 88 SUM-PRIOR-QTRS-YES-88 VALUE 'Y'. DTSBR415
|
|
00151 DTSBR415
|
|
00152 SKIP3 DTSBR415
|
|
00153 05 WS-TOTAL-CONTRIB-AMT PIC S9(09)V9(02) COMP-3 DTSBR415
|
|
00154 VALUE +0. DTSBR415
|
|
00155 05 WS-TOTAL-INTEREST-AMT PIC S9(09)V9(02) COMP-3 DTSBR415
|
|
00156 VALUE +0. DTSBR415
|
|
00157 05 WS-TOTAL-PENALTY-AMT PIC S9(09)V9(02) COMP-3 DTSBR415
|
|
00158 VALUE +0. DTSBR415
|
|
00159 05 WS-TOTAL-BALANCE-AMT PIC S9(09)V9(02) COMP-3 DTSBR415
|
|
00160 VALUE +0. DTSBR415
|
|
00161 05 WS-TOTAL-SURCHRG-AMT PIC S9(09)V9(02) COMP-3 DTSBR415
|
|
00162 VALUE +0. DTSBR415
|
|
00163 05 WS-STUB-BALANCE-AMT PIC S9(09)V9(02) COMP-3 DTSBR415
|
|
00164 VALUE +0. DTSBR415
|
|
00165 05 WS-QTR-PLUS20 PIC 9(3) VALUE ZERO. DTSBR415
|
|
00166 05 WS-QTR-CNT PIC 9(3) VALUE ZERO. DTSBR415
|
|
00167 05 WS-QTR-IDX PIC 9(3) VALUE ZERO. DTSBR415
|
|
00168 05 WRK-CNT PIC 9(3) DTSBR415
|
|
00169 VALUE ZERO. DTSBR415
|
|
00170 05 WRK-CTR PIC S9(04) COMP DTSBR415
|
|
00171 VALUE +0. DTSBR415
|
|
00172 05 WS-QTR-FNOTE PIC X(7) VALUE SPACES. DTSBR415
|
|
00173 05 WS-QTR-FNOTEX REDEFINES WS-QTR-FNOTE. DTSBR415
|
|
00174 10 WFNOTE1 PIC X(03). DTSBR415
|
|
00175 10 WFNOTE2 PIC X(03). DTSBR415
|
|
00176 10 FILLER PIC X. DTSBR415
|
|
00177 EJECT DTSBR415
|
|
00178 DTSBR415
|
|
00179 ++INCLUDE DTSXL415 DTSBR415
|
|
00180 SKIP3 DTSBR415
|
|
00181 05 STUB-LINE. DTSBR415
|
|
00182 10 FILLER PIC X(04) VALUE SPACES. DTSBR415
|
|
00183 10 STUB-EMP-NO PIC 999B999. DTSBR415
|
|
00184 10 FILLER PIC X(03) VALUE SPACES. DTSBR415
|
|
00185 10 STUB-EMP-FEIN PIC 99B9999999. DTSBR415
|
|
00186 10 FILLER PIC X(04) VALUE SPACES. DTSBR415
|
|
00187 10 STUB-STMT-DATE PIC X(10). DTSBR415
|
|
00188 10 FILLER PIC X(06) VALUE SPACES. DTSBR415
|
|
00189 10 STUB-COMP-DATE PIC X(10). DTSBR415
|
|
00190 10 FILLER PIC X(07) VALUE SPACES. DTSBR415
|
|
00191 10 STUB-AMT PIC $,$$$,$$$.$$. DTSBR415
|
|
00192 DTSBR415
|
|
00193 05 ADDR01. DTSBR415
|
|
00194 10 FILLER PIC X(01) VALUE SPACE. DTSBR415
|
|
00195 10 FILLER PIC X(27) VALUE SPACES. DTSBR415
|
|
00196 10 STUB-ADDR-LINE1 PIC X(40). DTSBR415
|
|
00197 10 FILLER PIC X(23) value spaces. DTSBR415
|
|
00198 DTSBR415
|
|
00199 05 ADDR02. DTSBR415
|
|
00200 10 FILLER PIC X(01) VALUE SPACE. DTSBR415
|
|
00201 10 FILLER PIC X(27) VALUE SPACES. DTSBR415
|
|
00202 10 STUB-ADDR-LINE2 PIC X(40). DTSBR415
|
|
00203 10 FILLER PIC X(23) value spaces. DTSBR415
|
|
00204 DTSBR415
|
|
00205 05 ADDR03. DTSBR415
|
|
00206 10 FILLER PIC X(01) VALUE SPACE. DTSBR415
|
|
00207 10 FILLER PIC X(27) VALUE SPACES. DTSBR415
|
|
00208 10 STUB-ADDR-LINE3 PIC X(40). DTSBR415
|
|
00209 10 FILLER PIC X(23) value spaces. DTSBR415
|
|
00210 DTSBR415
|
|
00211 05 ADDR04. DTSBR415
|
|
00212 10 FILLER PIC X(01) VALUE SPACE. DTSBR415
|
|
00213 10 FILLER PIC X(27) VALUE SPACES. DTSBR415
|
|
00214 10 STUB-ADDR-LINE4 PIC X(40). DTSBR415
|
|
00215 10 FILLER PIC X(32) VALUE SPACES. DTSBR415
|
|
00216 DTSBR415
|
|
00217 05 ADDR05. DTSBR415
|
|
00218 10 FILLER PIC X(01) VALUE SPACE. DTSBR415
|
|
00219 10 FILLER PIC X(27) VALUE SPACES. DTSBR415
|
|
00220 10 STUB-ADDR-LINE5 PIC X(40). DTSBR415
|
|
00221 10 FILLER PIC X(32) VALUE SPACES. DTSBR415
|
|
00222 DTSBR415
|
|
00223 05 STMT-LINE2. DTSBR415
|
|
00224 10 FILLER PIC X(63) VALUE SPACE. DTSBR415
|
|
00225 10 STMT-LAST-ACCT-UPDATE-DATE DTSBR415
|
|
00226 PIC X(10). DTSBR415
|
|
00227 10 FILLER PIC X(02) VALUE '. '. DTSBR415
|
|
00228 DTSBR415
|
|
00229 05 STMT-LINE1. DTSBR415
|
|
00230 10 FILLER PIC X(03) VALUE SPACES. DTSBR415
|
|
00231 10 STMT-EMP-NO PIC 999B999. DTSBR415
|
|
00232 10 FILLER PIC X(03) VALUE SPACES. DTSBR415
|
|
00233 10 STMT-NAME-CHEK PIC X(04). DTSBR415
|
|
00234 10 FILLER PIC X(04) VALUE SPACES. DTSBR415
|
|
00235 10 STMT-EMP-FEIN PIC 99B9999999. DTSBR415
|
|
00236 10 FILLER PIC X(03) VALUE SPACES. DTSBR415
|
|
00237 10 STMT-STMT-DATE PIC X(10). DTSBR415
|
|
00238 10 FILLER PIC X(04) VALUE SPACES. DTSBR415
|
|
00239 10 STMT-COMP-DATE PIC X(10). DTSBR415
|
|
00240 10 FILLER PIC X(06) VALUE SPACES. DTSBR415
|
|
00241 DTSBR415
|
|
00242 05 STMT-QTR-DETAIL. DTSBR415
|
|
00243 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00244 10 QTR-DET-YR. DTSBR415
|
|
00245 15 QTR-DET-YR1 PIC X(06). DTSBR415
|
|
00246 15 QTR-DET-YR2 PIC X(03). DTSBR415
|
|
00247 10 QTR-DET-FNOTE. DTSBR415
|
|
00248 15 QTR-DET-FNOTE1 PIC X(06). DTSBR415
|
|
00249 15 QTR-DET-FNOTE2 PIC X(01). DTSBR415
|
|
00250 10 FILLER PIC X(02). DTSBR415
|
|
00251 10 QTR-DET-CONTRIB-AMT PIC ZZZ,ZZZ,ZZZ.ZZ. DTSBR415
|
|
00252 * 10 FILLER PIC X(04). DTSBR415
|
|
00253 10 QTR-DET-INTEREST-AMT PIC ZZZ,ZZZ,ZZZ.ZZ. DTSBR415
|
|
00254 * 10 FILLER PIC X(03). DTSBR415
|
|
00255 10 QTR-DET-PENALTY-AMT PIC Z,ZZZ,ZZZ.ZZ. DTSBR415
|
|
00256 * 10 FILLER PIC X(03). DTSBR415
|
|
00257 10 QTR-DET-SURCHRG-AMT PIC Z,ZZZ,ZZZ.ZZ. DTSBR415
|
|
00258 * 10 FILLER PIC X(02). DTSBR415
|
|
00259 10 QTR-DET-BALANCE-AMT PIC ZZZ,ZZZ,ZZZ.ZZ. DTSBR415
|
|
00260 10 FILLER PIC X(02). DTSBR415
|
|
00261 DTSBR415
|
|
00262 05 STMT-TOTAL-LINE. DTSBR415
|
|
00263 10 FILLER PIC X(21) VALUE SPACE. DTSBR415
|
|
00264 10 TOTAL-CONTRIB-AMT PIC $$$,$$$,$$$.$$. DTSBR415
|
|
00265 * 10 FILLER PIC X(03) VALUE SPACES. DTSBR415
|
|
00266 10 TOTAL-INTEREST-AMT PIC $$$,$$$,$$$.$$. DTSBR415
|
|
00267 * 10 FILLER PIC X(03) VALUE SPACES. DTSBR415
|
|
00268 10 TOTAL-PENALTY-AMT PIC $,$$$,$$$.$$. DTSBR415
|
|
00269 * 10 FILLER PIC X(04) VALUE SPACES. DTSBR415
|
|
00270 10 TOTAL-SURCHRG-AMT PIC $,$$$,$$$.$$. DTSBR415
|
|
00271 10 FILLER PIC X(01) VALUE SPACES. DTSBR415
|
|
00272 10 TOTAL-BALANCE-AMT PIC $$$,$$$,$$9.99. DTSBR415
|
|
00273 10 FILLER PIC X(02) VALUE SPACES. DTSBR415
|
|
00274 DTSBR415
|
|
00275 05 STMT-EXAMINER-CALLBACK. DTSBR415
|
|
00276 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00277 10 FILLER PIC X(49) VALUE DTSBR415
|
|
00278 'If you have any questions, please contact the Tax'. DTSBR415
|
|
00279 10 FILLER PIC X(38) VALUE DTSBR415
|
|
00280 ' Division at the number listed below.'. DTSBR415
|
|
00281 DTSBR415
|
|
00282 05 STMT-EXAMINER-LINE1. DTSBR415
|
|
00283 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00284 10 RPT-EXAMIN-UNIT PIC X(20) VALUE SPACE. DTSBR415
|
|
00285 10 FILLER PIC X(105) VALUE SPACE. DTSBR415
|
|
00286 DTSBR415
|
|
00287 05 STMT-EXAMINER-LINE2. DTSBR415
|
|
00288 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00289 10 RPT-EXAMIN-NAME PIC X(20) VALUE SPACE. DTSBR415
|
|
00290 10 FILLER PIC X(105) VALUE SPACE. DTSBR415
|
|
00291 DTSBR415
|
|
00292 05 STMT-EXAMINER-LINE3. DTSBR415
|
|
00293 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00294 10 FILLER PIC X(01) VALUE '('. DTSBR415
|
|
00295 10 RPT-EXAMIN-AREA-CD PIC X(03) VALUE SPACES. DTSBR415
|
|
00296 10 FILLER PIC X(02) VALUE ') '. DTSBR415
|
|
00297 10 RPT-EXAMIN-PREFIX PIC X(03) VALUE SPACES. DTSBR415
|
|
00298 10 FILLER PIC X(01) VALUE '-'. DTSBR415
|
|
00299 10 RPT-EXAMIN-SUFFIX PIC X(04) VALUE SPACES. DTSBR415
|
|
00300 10 FILLER PIC X(105) VALUE SPACE. DTSBR415
|
|
00301 DTSBR415
|
|
00302 05 FNOTE1. DTSBR415
|
|
00303 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00304 10 FILLER PIC X(31) VALUE DTSBR415
|
|
00305 '(a) = estimated report on file'. DTSBR415
|
|
00306 DTSBR415
|
|
00307 05 FNOTE2. DTSBR415
|
|
00308 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00309 10 FILLER PIC X(31) VALUE DTSBR415
|
|
00310 '(b) = report missing '. DTSBR415
|
|
00311 DTSBR415
|
|
00312 05 FNOTE3. DTSBR415
|
|
00313 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00314 10 FILLER PIC X(31) VALUE DTSBR415
|
|
00315 '(c) = annual report '. DTSBR415
|
|
00316 DTSBR415
|
|
00317 05 FNOTE4. DTSBR415
|
|
00318 10 FILLER PIC X(03) VALUE SPACE. DTSBR415
|
|
00319 10 FILLER PIC X(31) VALUE DTSBR415
|
|
00320 '(d) = appeal pending '. DTSBR415
|
|
00321 DTSBR415
|
|
00322 05 FNOTE-MISSING-RPT. DTSBR415
|
|
00323 10 FILLER PIC X(33) VALUE SPACE. DTSBR415
|
|
00324 10 FILLER PIC X(57) VALUE DTSBR415
|
|
00325 'Balance Due does not include charges for missing reports'. DTSBR415
|
|
00326 DTSBR415
|
|
00327 EJECT DTSBR415
|
|
00328 01 L001-LINK-AREA. DTSBR415
|
|
00329 ++INCLUDE DTSIL001 DTSBR415
|
|
00330 EJECT DTSBR415
|
|
00331 01 L082-LINK-AREA. DTSBR415
|
|
00332 ++INCLUDE DTSIL082 DTSBR415
|
|
00333 EJECT DTSBR415
|
|
00334 01 L071-LINK-AREA. DTSBR415
|
|
00335 ++INCLUDE DTSIL071 DTSBR415
|
|
00336 EJECT DTSBR415
|
|
00337 LINKAGE SECTION. DTSBR415
|
|
00338 SKIP3 DTSBR415
|
|
00339 01 LRCM-LINK-AREA. DTSBR415
|
|
00340 ++INCLUDE DTSILRCM DTSBR415
|
|
00341 EJECT DTSBR415
|
|
00342 01 R415-REC. DTSBR415
|
|
00343 ++INCLUDE DTSIR415 DTSBR415
|
|
00344 EJECT DTSBR415
|
|
00345 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR415
|
|
00346 R415-REC. DTSBR415
|
|
00347 SKIP2 DTSBR415
|
|
00348 IF FIRST-TIME-IND = 'Y' DTSBR415
|
|
00349 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR415
|
|
00350 MOVE 'N' TO FIRST-TIME-IND. DTSBR415
|
|
00351 DTSBR415
|
|
00352 IF LRCM-EOR-88 DTSBR415
|
|
00353 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR415
|
|
00354 ELSE DTSBR415
|
|
00355 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR415
|
|
00356 SKIP2 DTSBR415
|
|
00357 GOBACK. DTSBR415
|
|
00358 EJECT DTSBR415
|
|
00359 I1000-INITIATE. DTSBR415
|
|
00360 OPEN OUTPUT PRT-FILE1. DTSBR415
|
|
00361 DTSBR415
|
|
00362 MOVE +0 TO PRT-FILE1-PAGE-CNT. DTSBR415
|
|
00363 DTSBR415
|
|
00364 MOVE 0 TO STMT-EMP-NO DTSBR415
|
|
00365 STUB-EMP-NO DTSBR415
|
|
00366 STUB-EMP-FEIN DTSBR415
|
|
00367 STMT-EMP-FEIN. DTSBR415
|
|
00368 MOVE SPACES TO STMT-STMT-DATE DTSBR415
|
|
00369 STMT-COMP-DATE. DTSBR415
|
|
00370 DTSBR415
|
|
00371 MOVE XEROX-8X11-LINE TO WS-REC. DTSBR415
|
|
00372 WRITE PRT-REC1 FROM WS-REC DTSBR415
|
|
00373 AFTER ADVANCING PAGE. DTSBR415
|
|
00374 DTSBR415
|
|
00375 MOVE XEROX-CNTL-LINE2 TO WS-REC. DTSBR415
|
|
00376 WRITE PRT-REC1 FROM WS-REC DTSBR415
|
|
00377 AFTER ADVANCING 1. DTSBR415
|
|
00378 DTSBR415
|
|
00379 I1000-EXIT. DTSBR415
|
|
00380 EXIT. DTSBR415
|
|
00381 SKIP3 DTSBR415
|
|
00382 P1000-PROCESS. DTSBR415
|
|
00383 DTSBR415
|
|
00384 SET PRINT-FNOTE1-NO-88 TO TRUE. DTSBR415
|
|
00385 SET PRINT-FNOTE2-NO-88 TO TRUE. DTSBR415
|
|
00386 SET PRINT-FNOTE3-NO-88 TO TRUE. DTSBR415
|
|
00387 SET PRINT-FNOTE4-NO-88 TO TRUE. DTSBR415
|
|
00388 MOVE SPACES TO WS-REC. DTSBR415
|
|
00389 DTSBR415
|
|
00390 MOVE +0 TO WS-TOTAL-CONTRIB-AMT DTSBR415
|
|
00391 WS-TOTAL-PENALTY-AMT DTSBR415
|
|
00392 WS-TOTAL-INTEREST-AMT DTSBR415
|
|
00393 WS-TOTAL-SURCHRG-AMT DTSBR415
|
|
00394 WS-STUB-BALANCE-AMT DTSBR415
|
|
00395 WS-TOTAL-BALANCE-AMT. DTSBR415
|
|
00396 DTSBR415
|
|
00397 PERFORM P1100-STUB-STMT-TOTALS THRU P1100-EXIT DTSBR415
|
|
00398 VARYING R415-QTR-IDX FROM 1 BY 1 DTSBR415
|
|
00399 UNTIL R415-QTR-IDX > R415-QTR-CNT. DTSBR415
|
|
00400 DTSBR415
|
|
00401 MOVE R415-EMP-NO TO STUB-EMP-NO DTSBR415
|
|
00402 STMT-EMP-NO. DTSBR415
|
|
00403 MOVE R415-EMP-FEIN TO STUB-EMP-FEIN DTSBR415
|
|
00404 STMT-EMP-FEIN. DTSBR415
|
|
00405 MOVE WS-STUB-BALANCE-AMT TO STUB-AMT. DTSBR415
|
|
00406 DTSBR415
|
|
00407 MOVE R415-STMT-DATE TO L001-FED-8-DATE-9. DTSBR415
|
|
00408 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBR415
|
|
00409 MOVE L001-SLASH-8-DATE TO STUB-STMT-DATE DTSBR415
|
|
00410 STMT-STMT-DATE. DTSBR415
|
|
00411 DTSBR415
|
|
00412 MOVE R415-COMP-DATE TO L001-FED-8-DATE-9. DTSBR415
|
|
00413 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBR415
|
|
00414 IF L001-INVALID-DATE DTSBR415
|
|
00415 MOVE SPACES TO STUB-COMP-DATE DTSBR415
|
|
00416 STMT-COMP-DATE DTSBR415
|
|
00417 ELSE DTSBR415
|
|
00418 MOVE L001-SLASH-8-DATE TO STUB-COMP-DATE DTSBR415
|
|
00419 STMT-COMP-DATE. DTSBR415
|
|
00420 DTSBR415
|
|
00421 MOVE R415-FMT-LINE (1) TO STUB-ADDR-LINE1 DTSBR415
|
|
00422 MAIL-ADDR-LINE1 DTSBR415
|
|
00423 WS-EMP-NAME. DTSBR415
|
|
00424 DTSBR415
|
|
00425 MOVE R415-FMT-LINE (2) TO STUB-ADDR-LINE2 DTSBR415
|
|
00426 MAIL-ADDR-LINE2. DTSBR415
|
|
00427 DTSBR415
|
|
00428 MOVE R415-FMT-LINE (3) TO STUB-ADDR-LINE3 DTSBR415
|
|
00429 MAIL-ADDR-LINE3. DTSBR415
|
|
00430 DTSBR415
|
|
00431 MOVE R415-FMT-LINE (4) TO STUB-ADDR-LINE4 DTSBR415
|
|
00432 MAIL-ADDR-LINE4. DTSBR415
|
|
00433 DTSBR415
|
|
00434 MOVE R415-FMT-LINE (5) TO STUB-ADDR-LINE5 DTSBR415
|
|
00435 MAIL-ADDR-LINE5. DTSBR415
|
|
00436 DTSBR415
|
|
00437 MOVE WRK-FIRST-4 TO STMT-NAME-CHEK. DTSBR415
|
|
00438 DTSBR415
|
|
00439 MOVE R415-LAST-ACCT-UPDATE-DATE TO L001-FED-8-DATE-9. DTSBR415
|
|
00440 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBR415
|
|
00441 MOVE L001-SLASH-8-DATE TO STMT-LAST-ACCT-UPDATE-DATE. DTSBR415
|
|
00442 DTSBR415
|
|
00443 PERFORM P1200-PRINT-STUB-MAILR THRU P1200-EXIT. DTSBR415
|
|
00444 DTSBR415
|
|
00445 MOVE 14 TO LINE-CNT. DTSBR415
|
|
00446 DTSBR415
|
|
00447 SET AMT-DISPLAYED-NO-88 TO TRUE. DTSBR415
|
|
00448 SET SUM-PRIOR-QTRS-NO-88 TO TRUE. DTSBR415
|
|
00449 SET PRINT-PRIOR-QTRS-NO-88 TO TRUE. DTSBR415
|
|
00450 DTSBR415
|
|
00451 MOVE 0 TO WS-QTR-PLUS20 DTSBR415
|
|
00452 WS-QTR-CNT. DTSBR415
|
|
00453 DTSBR415
|
|
00454 PERFORM P1300-DISPLAY-QTR THRU P1300-EXIT DTSBR415
|
|
00455 VARYING R415-QTR-IDX FROM 1 BY 1 DTSBR415
|
|
00456 UNTIL R415-QTR-IDX > R415-QTR-CNT. DTSBR415
|
|
00457 DTSBR415
|
|
00458 MOVE SPACES TO WS-REC DTSBR415
|
|
00459 DTSBR415
|
|
00460 IF AMT-DISPLAYED-YES-88 DTSBR415
|
|
00461 MOVE WS-TOTAL-CONTRIB-AMT TO TOTAL-CONTRIB-AMT DTSBR415
|
|
00462 MOVE WS-TOTAL-INTEREST-AMT TO TOTAL-INTEREST-AMT DTSBR415
|
|
00463 MOVE WS-TOTAL-PENALTY-AMT TO TOTAL-PENALTY-AMT DTSBR415
|
|
00464 MOVE WS-TOTAL-SURCHRG-AMT TO TOTAL-SURCHRG-AMT DTSBR415
|
|
00465 MOVE WS-TOTAL-BALANCE-AMT TO TOTAL-BALANCE-AMT. DTSBR415
|
|
00466 DTSBR415
|
|
00467 **nh COMPUTE WRK-CTR = TOT-LINE-CNT - LINE-CNT. DTSBR415
|
|
00468 COMPUTE WRK-CTR = TOT-LINE-CNT - LINE-CNT - 2. DTSBR415
|
|
00469 **nh DTSBR415
|
|
00470 if ws-total-balance-amt = +0 DTSBR415
|
|
00471 move 0.00 to TOTAL-BALANCE-AMT DTSBR415
|
|
00472 end-if. DTSBR415
|
|
00473 **nh DTSBR415
|
|
00474 DTSBR415
|
|
00475 IF AMT-DISPLAYED-YES-88 DTSBR415
|
|
00476 MOVE STMT-TOTAL-LINE TO WS-REC DTSBR415
|
|
00477 ELSE DTSBR415
|
|
00478 MOVE SPACES TO WS-REC. DTSBR415
|
|
00479 DTSBR415
|
|
00480 WRITE PRT-REC1 FROM WS-REC DTSBR415
|
|
00481 AFTER ADVANCING WRK-CTR LINES. DTSBR415
|
|
00482 DTSBR415
|
|
00483 MOVE SPACES TO WS-REC DTSBR415
|
|
00484 DTSBR415
|
|
00485 MOVE R415-OP-ID TO L082-OP-ID DTSBR415
|
|
00486 PERFORM S082-OP-ID-INFO THRU S082-EXIT. DTSBR415
|
|
00487 DTSBR415
|
|
00488 MOVE L082-NAME TO L071-NAM DTSBR415
|
|
00489 MOVE 2 TO L071-NAME-FORMAT DTSBR415
|
|
00490 PERFORM S071-DESLASH-NAME THRU S071-EXIT. DTSBR415
|
|
00491 DTSBR415
|
|
00492 MOVE L071-NAM TO RPT-EXAMIN-NAME DTSBR415
|
|
00493 MOVE L082-UNIT-NAME TO RPT-EXAMIN-UNIT DTSBR415
|
|
00494 DTSBR415
|
|
00495 MOVE L082-VOICE-1-AREA-CD TO RPT-EXAMIN-AREA-CD DTSBR415
|
|
00496 MOVE L082-VOICE-1-PREFIX TO RPT-EXAMIN-PREFIX DTSBR415
|
|
00497 MOVE L082-VOICE-1-SUFFIX TO RPT-EXAMIN-SUFFIX DTSBR415
|
|
00498 DTSBR415
|
|
00499 IF PRINT-FNOTE2-YES-88 DTSBR415
|
|
00500 WRITE PRT-REC1 FROM FNOTE-MISSING-RPT DTSBR415
|
|
00501 AFTER ADVANCING 2 LINES DTSBR415
|
|
00502 ELSE DTSBR415
|
|
00503 WRITE PRT-REC1 FROM WS-REC DTSBR415
|
|
00504 AFTER ADVANCING 2 LINES. DTSBR415
|
|
00505 DTSBR415
|
|
00506 * WRITE PRT-REC1 FROM STMT-EXAMINER-CALLBACK DTSBR415
|
|
00507 * AFTER ADVANCING 3 LINES. DTSBR415
|
|
00508 WRITE PRT-REC1 FROM STMT-EXAMINER-LINE1 DTSBR415
|
|
00509 AFTER ADVANCING 5 LINES. DTSBR415
|
|
00510 WRITE PRT-REC1 FROM STMT-EXAMINER-LINE2 DTSBR415
|
|
00511 AFTER ADVANCING 1 LINES. DTSBR415
|
|
00512 WRITE PRT-REC1 FROM STMT-EXAMINER-LINE3 DTSBR415
|
|
00513 AFTER ADVANCING 1 LINES. DTSBR415
|
|
00514 DTSBR415
|
|
00515 DTSBR415
|
|
00516 WRITE PRT-REC1 FROM WS-REC DTSBR415
|
|
00517 AFTER ADVANCING 3 LINES. DTSBR415
|
|
00518 DTSBR415
|
|
00519 IF PRINT-FNOTE1-YES-88 DTSBR415
|
|
00520 WRITE PRT-REC1 FROM FNOTE1 DTSBR415
|
|
00521 AFTER ADVANCING 1 LINES. DTSBR415
|
|
00522 DTSBR415
|
|
00523 IF PRINT-FNOTE2-YES-88 DTSBR415
|
|
00524 WRITE PRT-REC1 FROM FNOTE2 DTSBR415
|
|
00525 AFTER ADVANCING 1 LINES. DTSBR415
|
|
00526 DTSBR415
|
|
00527 IF PRINT-FNOTE3-YES-88 DTSBR415
|
|
00528 WRITE PRT-REC1 FROM FNOTE3 DTSBR415
|
|
00529 AFTER ADVANCING 1 LINES. DTSBR415
|
|
00530 DTSBR415
|
|
00531 IF PRINT-FNOTE4-YES-88 DTSBR415
|
|
00532 WRITE PRT-REC1 FROM FNOTE4 DTSBR415
|
|
00533 AFTER ADVANCING 1 LINES. DTSBR415
|
|
00534 DTSBR415
|
|
00535 DTSBR415
|
|
00536 MOVE SPACES TO WS-XREC DTSBR415
|
|
00537 DTSBR415
|
|
00538 PERFORM P1500-PRINT-MAILR-ADDR THRU P1500-EXIT. DTSBR415
|
|
00539 DTSBR415
|
|
00540 P1000-EXIT. DTSBR415
|
|
00541 EXIT. DTSBR415
|
|
00542 SKIP3 DTSBR415
|
|
00543 DTSBR415
|
|
00544 P1100-STUB-STMT-TOTALS. DTSBR415
|
|
00545 DTSBR415
|
|
00546 IF R415-BALANCE-AMT (R415-QTR-IDX) > ZEROS DTSBR415
|
|
00547 ADD R415-BALANCE-AMT (R415-QTR-IDX) DTSBR415
|
|
00548 TO WS-STUB-BALANCE-AMT. DTSBR415
|
|
00549 **nh zero balance statements DTSBR415
|
|
00550 IF R415-BALANCE-AMT (R415-QTR-IDX) = ZEROS DTSBR415
|
|
00551 ADD R415-BALANCE-AMT (R415-QTR-IDX) DTSBR415
|
|
00552 TO WS-STUB-BALANCE-AMT. DTSBR415
|
|
00553 **nh zero balance statements DTSBR415
|
|
00554 P1100-EXIT. DTSBR415
|
|
00555 EXIT. DTSBR415
|
|
00556 SKIP3 DTSBR415
|
|
00557 DTSBR415
|
|
00558 P1200-PRINT-STUB-MAILR. DTSBR415
|
|
00559 DTSBR415
|
|
00560 ADD +1 TO PRT-FILE1-PAGE-CNT DTSBR415
|
|
00561 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING PAGE DTSBR415
|
|
00562 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 6 LINES DTSBR415
|
|
00563 MOVE STUB-LINE TO WS-REC DTSBR415
|
|
00564 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 1 LINES DTSBR415
|
|
00565 MOVE ADDR01 TO WS-REC DTSBR415
|
|
00566 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 1 LINES DTSBR415
|
|
00567 MOVE ADDR02 TO WS-REC DTSBR415
|
|
00568 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 1 LINES DTSBR415
|
|
00569 MOVE ADDR03 TO WS-REC DTSBR415
|
|
00570 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 1 LINES DTSBR415
|
|
00571 MOVE ADDR04 TO WS-REC DTSBR415
|
|
00572 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 1 LINES DTSBR415
|
|
00573 MOVE ADDR05 TO WS-REC DTSBR415
|
|
00574 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 1 LINES DTSBR415
|
|
00575 MOVE STMT-LINE1 TO WS-REC DTSBR415
|
|
00576 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 4 LINES DTSBR415
|
|
00577 MOVE STMT-LINE2 TO WS-REC DTSBR415
|
|
00578 **nh WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 5 LINES. DTSBR415
|
|
00579 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 7 LINES. DTSBR415
|
|
00580 MOVE SPACES TO WS-REC. DTSBR415
|
|
00581 WRITE PRT-REC1 FROM WS-REC AFTER ADVANCING 3 LINES. DTSBR415
|
|
00582 P1200-EXIT. DTSBR415
|
|
00583 EXIT. DTSBR415
|
|
00584 SKIP3 DTSBR415
|
|
00585 P1300-DISPLAY-QTR. DTSBR415
|
|
00586 DTSBR415
|
|
00587 MOVE SPACES TO STMT-QTR-DETAIL DTSBR415
|
|
00588 WS-QTR-FNOTE. DTSBR415
|
|
00589 IF LRCM-PICKUP-YRQ = R415-QTR (R415-QTR-IDX) DTSBR415
|
|
00590 MOVE 'PRIOR TO ' TO QTR-DET-YR DTSBR415
|
|
00591 MOVE '1995/4' TO QTR-DET-FNOTE DTSBR415
|
|
00592 ELSE DTSBR415
|
|
00593 MOVE R415-QTR (R415-QTR-IDX) TO WS-WRK-QTR DTSBR415
|
|
00594 IF R415-ANN-FILER-YES-88 (R415-QTR-IDX) DTSBR415
|
|
00595 MOVE SPACES TO WRK-PRT-Q DTSBR415
|
|
00596 MOVE WRK-QTR-YR TO WRK-PRT-YR DTSBR415
|
|
00597 MOVE SPACES TO WRK-PRT-SLASH DTSBR415
|
|
00598 MOVE WS-PRT-QTR TO QTR-DET-YR1 DTSBR415
|
|
00599 MOVE SPACES TO QTR-DET-YR2 DTSBR415
|
|
00600 ELSE DTSBR415
|
|
00601 MOVE WRK-QTR-Q TO WRK-PRT-Q DTSBR415
|
|
00602 MOVE WRK-QTR-YR TO WRK-PRT-YR DTSBR415
|
|
00603 MOVE '/' TO WRK-PRT-SLASH DTSBR415
|
|
00604 MOVE WS-PRT-QTR TO QTR-DET-YR1 DTSBR415
|
|
00605 MOVE SPACES TO QTR-DET-YR2. DTSBR415
|
|
00606 DTSBR415
|
|
00607 ** IF R415-BALANCE-AMT (R415-QTR-IDX) > +0 DTSBR415
|
|
00608 IF R415-BALANCE-AMT (R415-QTR-IDX) >= +0 DTSBR415
|
|
00609 SET AMT-DISPLAYED-YES-88 TO TRUE DTSBR415
|
|
00610 MOVE R415-CONTRIB-AMT (R415-QTR-IDX) DTSBR415
|
|
00611 TO QTR-DET-CONTRIB-AMT DTSBR415
|
|
00612 ADD R415-CONTRIB-AMT (R415-QTR-IDX) DTSBR415
|
|
00613 TO WS-TOTAL-CONTRIB-AMT DTSBR415
|
|
00614 ADD R415-INTEREST-AMT (R415-QTR-IDX) DTSBR415
|
|
00615 TO WS-TOTAL-INTEREST-AMT DTSBR415
|
|
00616 MOVE R415-INTEREST-AMT (R415-QTR-IDX) DTSBR415
|
|
00617 TO QTR-DET-INTEREST-AMT DTSBR415
|
|
00618 ADD R415-PENALTY-AMT (R415-QTR-IDX) DTSBR415
|
|
00619 TO WS-TOTAL-PENALTY-AMT DTSBR415
|
|
00620 MOVE R415-PENALTY-AMT (R415-QTR-IDX) DTSBR415
|
|
00621 TO QTR-DET-PENALTY-AMT DTSBR415
|
|
00622 ADD R415-SURCHRG-AMT (R415-QTR-IDX) DTSBR415
|
|
00623 TO WS-TOTAL-SURCHRG-AMT DTSBR415
|
|
00624 MOVE R415-SURCHRG-AMT (R415-QTR-IDX) DTSBR415
|
|
00625 TO QTR-DET-SURCHRG-AMT DTSBR415
|
|
00626 ADD R415-BALANCE-AMT (R415-QTR-IDX) DTSBR415
|
|
00627 TO WS-TOTAL-BALANCE-AMT. DTSBR415
|
|
00628 MOVE R415-BALANCE-AMT (R415-QTR-IDX) DTSBR415
|
|
00629 TO QTR-DET-BALANCE-AMT. DTSBR415
|
|
00630 DTSBR415
|
|
00631 IF LRCM-PICKUP-YRQ = R415-QTR (R415-QTR-IDX) DTSBR415
|
|
00632 SET R415-ANN-FILER-NO-88 (R415-QTR-IDX) TO TRUE DTSBR415
|
|
00633 SET R415-RPT-MISSING-NO-88 (R415-QTR-IDX) TO TRUE DTSBR415
|
|
00634 SET R415-QTR-EST-RPT-NO-88 (R415-QTR-IDX) TO TRUE DTSBR415
|
|
00635 SET R415-QTR-APPEAL-NO-88 (R415-QTR-IDX) TO TRUE. DTSBR415
|
|
00636 DTSBR415
|
|
00637 IF R415-QTR-APPEAL-YES-88 (R415-QTR-IDX) DTSBR415
|
|
00638 SET PRINT-FNOTE4-YES-88 TO TRUE DTSBR415
|
|
00639 MOVE '(d)' TO WFNOTE1 DTSBR415
|
|
00640 ELSE DTSBR415
|
|
00641 IF R415-QTR-EST-RPT-YES-88 (R415-QTR-IDX) DTSBR415
|
|
00642 SET PRINT-FNOTE1-YES-88 TO TRUE DTSBR415
|
|
00643 MOVE '(a)' TO WFNOTE1 DTSBR415
|
|
00644 ELSE DTSBR415
|
|
00645 IF R415-RPT-MISSING-YES-88 (R415-QTR-IDX) DTSBR415
|
|
00646 SET PRINT-FNOTE2-YES-88 TO TRUE DTSBR415
|
|
00647 MOVE '(b)' TO WFNOTE1. DTSBR415
|
|
00648 DTSBR415
|
|
00649 IF R415-ANN-FILER-YES-88 (R415-QTR-IDX) DTSBR415
|
|
00650 SET PRINT-FNOTE3-YES-88 TO TRUE DTSBR415
|
|
00651 IF WFNOTE1 = SPACES DTSBR415
|
|
00652 MOVE '(c)' TO WFNOTE1 DTSBR415
|
|
00653 ELSE DTSBR415
|
|
00654 MOVE '(c)' TO WFNOTE2. DTSBR415
|
|
00655 DTSBR415
|
|
00656 DTSBR415
|
|
00657 IF WS-QTR-FNOTE > SPACES DTSBR415
|
|
00658 MOVE WS-QTR-FNOTE TO QTR-DET-FNOTE. DTSBR415
|
|
00659 DTSBR415
|
|
00660 IF R415-QTR-CNT > 10 AND DTSBR415
|
|
00661 PRINT-PRIOR-QTRS-NO-88 DTSBR415
|
|
00662 PERFORM P1400-SUM-PRIOR-QTRS THRU P1400-EXIT DTSBR415
|
|
00663 IF PRINT-PRIOR-QTRS-NO-88 DTSBR415
|
|
00664 GO TO P1300-EXIT. DTSBR415
|
|
00665 DTSBR415
|
|
00666 ADD 1 TO LINE-CNT. DTSBR415
|
|
00667 MOVE STMT-QTR-DETAIL TO WS-REC. DTSBR415
|
|
00668 WRITE PRT-REC1 FROM WS-REC AFTER 1. DTSBR415
|
|
00669 DTSBR415
|
|
00670 P1300-EXIT. DTSBR415
|
|
00671 EXIT. DTSBR415
|
|
00672 DTSBR415
|
|
00673 P1400-SUM-PRIOR-QTRS. DTSBR415
|
|
00674 IF SUM-PRIOR-QTRS-NO-88 DTSBR415
|
|
00675 MOVE 1 TO WS-QTR-PLUS20 DTSBR415
|
|
00676 COMPUTE WS-QTR-CNT = DTSBR415
|
|
00677 R415-QTR-CNT - MAX-QTR-PRINT DTSBR415
|
|
00678 SET SUM-PRIOR-QTRS-YES-88 TO TRUE. DTSBR415
|
|
00679 DTSBR415
|
|
00680 IF WS-QTR-CNT = WS-QTR-PLUS20 DTSBR415
|
|
00681 NEXT SENTENCE DTSBR415
|
|
00682 ELSE DTSBR415
|
|
00683 ADD 1 TO WS-QTR-PLUS20 DTSBR415
|
|
00684 GO TO P1400-EXIT. DTSBR415
|
|
00685 DTSBR415
|
|
00686 MOVE WS-TOTAL-BALANCE-AMT TO QTR-DET-BALANCE-AMT DTSBR415
|
|
00687 MOVE WS-TOTAL-PENALTY-AMT TO QTR-DET-PENALTY-AMT DTSBR415
|
|
00688 MOVE WS-TOTAL-CONTRIB-AMT TO QTR-DET-CONTRIB-AMT DTSBR415
|
|
00689 MOVE WS-TOTAL-INTEREST-AMT TO QTR-DET-INTEREST-AMT DTSBR415
|
|
00690 MOVE WS-TOTAL-SURCHRG-AMT TO QTR-DET-SURCHRG-AMT DTSBR415
|
|
00691 SET AMT-DISPLAYED-YES-88 TO TRUE DTSBR415
|
|
00692 SET WS-QTR-IDX TO R415-QTR-IDX DTSBR415
|
|
00693 ADD 1 TO WS-QTR-IDX DTSBR415
|
|
00694 MOVE R415-QTR (WS-QTR-IDX) TO WS-WRK-QTR DTSBR415
|
|
00695 MOVE WRK-QTR-Q TO WRK-PRT-Q DTSBR415
|
|
00696 MOVE WRK-QTR-YR TO WRK-PRT-YR DTSBR415
|
|
00697 MOVE '/' TO WRK-PRT-SLASH DTSBR415
|
|
00698 MOVE WS-PRT-QTR TO QTR-DET-FNOTE1 DTSBR415
|
|
00699 MOVE SPACES TO QTR-DET-FNOTE2 DTSBR415
|
|
00700 MOVE 'PRIOR TO ' TO QTR-DET-YR DTSBR415
|
|
00701 SET PRINT-PRIOR-QTRS-YES-88 TO TRUE. DTSBR415
|
|
00702 DTSBR415
|
|
00703 P1400-EXIT. DTSBR415
|
|
00704 EXIT. DTSBR415
|
|
00705 SKIP3 DTSBR415
|
|
00706 P1500-PRINT-MAILR-ADDR. DTSBR415
|
|
00707 DTSBR415
|
|
00708 WRITE PRT-REC1 FROM WS-XREC AFTER ADVANCING PAGE DTSBR415
|
|
00709 MOVE LINE-ADDR-17 TO WS-XREC DTSBR415
|
|
00710 WRITE PRT-REC1 FROM WS-XREC DTSBR415
|
|
00711 AFTER ADVANCING 17 LINES DTSBR415
|
|
00712 MOVE LINE-ADDR-18 TO WS-XREC DTSBR415
|
|
00713 WRITE PRT-REC1 FROM WS-XREC AFTER 1 DTSBR415
|
|
00714 MOVE LINE-ADDR-19 TO WS-XREC DTSBR415
|
|
00715 WRITE PRT-REC1 FROM WS-XREC AFTER 1 DTSBR415
|
|
00716 MOVE LINE-ADDR-20 TO WS-XREC DTSBR415
|
|
00717 WRITE PRT-REC1 FROM WS-XREC AFTER 1 DTSBR415
|
|
00718 MOVE LINE-ADDR-21 TO WS-XREC DTSBR415
|
|
00719 WRITE PRT-REC1 FROM WS-XREC AFTER 1. DTSBR415
|
|
00720 P1500-EXIT. DTSBR415
|
|
00721 EXIT. DTSBR415
|
|
00722 SKIP3 DTSBR415
|
|
00723 T1000-TERMINATE. DTSBR415
|
|
00724 CLOSE PRT-FILE1. DTSBR415
|
|
00725 DTSBR415
|
|
00726 DISPLAY '***'. DTSBR415
|
|
00727 DTSBR415
|
|
00728 DISPLAY '*** DTSBR415 (STATEMENT OF ACCOUNTS ) ' DTSBR415
|
|
00729 'TERMINATION STATISTICS'. DTSBR415
|
|
00730 DTSBR415
|
|
00731 DISPLAY '***'. DTSBR415
|
|
00732 DTSBR415
|
|
00733 MOVE PRT-FILE1-PAGE-CNT TO DISPLAY-CNT-Z. DTSBR415
|
|
00734 DISPLAY '*** ' DTSBR415
|
|
00735 DISPLAY-CNT DTSBR415
|
|
00736 ' -8X11 PAGE STATEMENTS PRINTED'. DTSBR415
|
|
00737 DTSBR415
|
|
00738 DISPLAY '***'. DTSBR415
|
|
00739 DTSBR415
|
|
00740 DTSBR415
|
|
00741 DISPLAY '***END JOB****'. DTSBR415
|
|
00742 T1000-EXIT. DTSBR415
|
|
00743 EXIT. DTSBR415
|
|
00744 EJECT DTSBR415
|
|
00745 S001-FROM-FED-8. DTSBR415
|
|
00746 SET L001-FROM-FED-8 TO TRUE. DTSBR415
|
|
00747 GO TO S001-DATE. DTSBR415
|
|
00748 DTSBR415
|
|
00749 S001-DATE. DTSBR415
|
|
00750 CALL 'DTSBU001' USING L001-LINK-AREA. DTSBR415
|
|
00751 S001-EXIT. DTSBR415
|
|
00752 EXIT. DTSBR415
|
|
00753 SKIP3 DTSBR415
|
|
00754 S071-DESLASH-NAME. DTSBR415
|
|
00755 CALL 'DTSBU071' USING L071-LINK-AREA. DTSBR415
|
|
00756 S071-EXIT. DTSBR415
|
|
00757 EXIT. DTSBR415
|
|
00758 S082-OP-ID-INFO. DTSBR415
|
|
00759 CALL 'DTSBU082' USING L082-LINK-AREA. DTSBR415
|
|
00760 S082-EXIT. DTSBR415
|
|
00761 EXIT. DTSBR415
|
|
00762 SKIP3 DTSBR415
|
|
00763 S999-ABEND. DTSBR415
|
|
00764 DISPLAY ABEND-MSG. DTSBR415
|
|
00765 DTSBR415
|
|
00766 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR415
|
|
00767 S999-EXIT. DTSBR415
|
|
00768 EXIT. DTSBR415
|