350 lines
28 KiB
COBOL
350 lines
28 KiB
COBOL
00001 IDENTIFICATION DIVISION. 11/29/01
|
|
00002 PROGRAM-ID. DTSBR705. DTSBR705
|
|
00003 AUTHOR. MT DEPT OF LABOR/UI PROGRAMMING SECTION LV013
|
|
00004 DATE-WRITTEN. DECEMBER 1994. DTSBR705
|
|
00005 DATE-COMPILED. DTSBR705
|
|
00006 DTSBR705
|
|
00007 ***** DTSBR705
|
|
00008 * DTSBR705
|
|
00009 * FUNCTION: FAILED FUTA CERTIFICATIONS. DTSBR705
|
|
00010 * DTSBR705
|
|
00011 * DTSBR705
|
|
00012 * CALLING SEQUENCE: DTSBD300 CALLS DTSBD610 DTSBR705
|
|
00013 * WHICH CREATES DTSIR705 RECORDS. DTSBR705
|
|
00014 * DTSBD800 CALLS DTSBR705 DTSBR705
|
|
00015 * WHICH PRODUCES THE FUTA FAILED DTSBR705
|
|
00016 * CERTIFICATION LISTING. DTSBR705
|
|
00017 * MODIFICATION HISTORY: DTSBR705
|
|
00018 * DTSBR705
|
|
00019 * 12-09-94 INITIAL DEVELOPMENT DTSBR705
|
|
00020 * REFERENCE RFP #RAP AUTHOR OF CHANGE - SFW DTSBR705
|
|
00021 * DTSBR705
|
|
00022 * 11-13-97 TAX YEAR 1996 MODIFICATIONS. FOUR DIGIT YEAR. DTSBR705
|
|
00023 * REFERENCE RFP #TCL 222 AUTHOR OF CHANGE - EHH DTSBR705
|
|
00024 * DTSBR705
|
|
00025 * 02-22-99 MODIFIED TO MEET DUTAS PROGRAMMING SPAECIFICATIONS. DTSBR705
|
|
00026 * REFERENCE RFP #**** AUTHOR OF CHANGE - DVS DTSBR705
|
|
00027 * DTSBR705
|
|
00028 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR705
|
|
00029 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR705
|
|
00030 * REFERENCE RFP #**** AUTHOR OF CHANGE - XXX DTSBR705
|
|
00031 * DTSBR705
|
|
00032 * DTSBR705
|
|
00033 * DESCRIPTION: DTSBR705
|
|
00034 * DTSBR705
|
|
00035 * THIS MODULE GENERATES A DETAIL LINE FOR EVERY IRS FORM DTSBR705
|
|
00036 * 940 IDENTIFICATION TAPE RECORD FOR WHICH THERE WAS NO DTSBR705
|
|
00037 * MATCH ON THE MONTANA TAX SYSTEM MASTER FILE DURING DTSBR705
|
|
00038 * YEARLY FUTA PROCESSING. DTSBR705
|
|
00039 * DTSBR705
|
|
00040 * DTSBR705
|
|
00041 * RECORDS READ: DTSBR705
|
|
00042 * DTSBR705
|
|
00043 * NONE. DTSBR705
|
|
00044 * DTSBR705
|
|
00045 * DTSBR705
|
|
00046 * PRINTED OUTPUTS: DTSBR705
|
|
00047 * DTSBR705
|
|
00048 * 705R1 FAILED FUTA CERTIFICATIONS DTSBR705
|
|
00049 * DTSBR705
|
|
00050 * DTSBR705
|
|
00051 * RECORDS WRITTEN: DTSBR705
|
|
00052 * DTSBR705
|
|
00053 * NONE. DTSBR705
|
|
00054 * DTSBR705
|
|
00055 * DTSBR705
|
|
00056 * MODULES CALLED: DTSBR705
|
|
00057 * DTSBR705
|
|
00058 * NONE. DTSBR705
|
|
00059 * DTSBR705
|
|
00060 * DTSBR705
|
|
00061 ***** DTSBR705
|
|
00062 EJECT DTSBR705
|
|
00063 ENVIRONMENT DIVISION. DTSBR705
|
|
00064 DTSBR705
|
|
00065 CONFIGURATION SECTION. DTSBR705
|
|
00066 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. DTSBR705
|
|
00067 DTSBR705
|
|
00068 INPUT-OUTPUT SECTION. DTSBR705
|
|
00069 DTSBR705
|
|
00070 FILE-CONTROL. DTSBR705
|
|
00071 SELECT PRT-FILE ASSIGN TO RPT705R1. DTSBR705
|
|
00072 DTSBR705
|
|
00073 DATA DIVISION. DTSBR705
|
|
00074 DTSBR705
|
|
00075 FILE SECTION. DTSBR705
|
|
00076 DTSBR705
|
|
00077 FD PRT-FILE DTSBR705
|
|
00078 RECORDING MODE IS F. DTSBR705
|
|
00079 01 REPORT-LISTING1 PIC X(133). DTSBR705
|
|
00080 DTSBR705
|
|
00081 EJECT DTSBR705
|
|
00082 WORKING-STORAGE SECTION. DTSBR705
|
|
000825 77 PAN-VALET PICTURE X(24) VALUE '013DTSBR705 11/29/01'. DTSBR705
|
|
00083 DTSBR705
|
|
00084 01 WRK-AREA. DTSBR705
|
|
00085 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +705.DTSBR705
|
|
00086 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR705
|
|
00087 05 WS-NUMBER-ONE PIC S9(05) COMP-3 DTSBR705
|
|
00088 VALUE +0. DTSBR705
|
|
00089 DTSBR705
|
|
00090 05 WS-LINE-CNT PIC S9(02) COMP-3 VALUE 60. DTSBR705
|
|
00091 05 WS-LINE-CNT2 PIC S9(02) COMP-3 VALUE +0. DTSBR705
|
|
00092 05 WS-PAGE-CNT PIC S9(03) COMP-3 VALUE +0. DTSBR705
|
|
00093 05 BLANK-LINE PIC X(133) VALUE SPACES. DTSBR705
|
|
00094 DTSBR705
|
|
00095 05 WS-EMP-NO PIC X(07). DTSBR705
|
|
00096 05 WS-EMP-NO-EDIT REDEFINES WS-EMP-NO DTSBR705
|
|
00097 PIC 999B999. DTSBR705
|
|
00098 05 WS-SUB PIC S9(04) COMP. DTSBR705
|
|
00099 05 WS-NAME-ADD-CNT PIC S9(04) COMP. DTSBR705
|
|
00100 05 WS-NAME-ADD OCCURS 6 TIMES PIC X(35). DTSBR705
|
|
00101 EJECT DTSBR705
|
|
00102 DTSBR705
|
|
00103 01 PAGE-HEADING. DTSBR705
|
|
00104 05 HDR-LINE-1. DTSBR705
|
|
00105 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00106 10 FILLER PIC X(05) DTSBR705
|
|
00107 VALUE '705R1'. DTSBR705
|
|
00108 10 FILLER PIC X(35) VALUE SPACES. DTSBR705
|
|
00109 10 HDR-AGY-NAME-LINE1 PIC X(50). DTSBR705
|
|
00110 10 FILLER PIC X(28) VALUE SPACES. DTSBR705
|
|
00111 10 FILLER PIC X(05) DTSBR705
|
|
00112 VALUE 'DATE:'. DTSBR705
|
|
00113 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00114 10 HDR-SYS-DATE PIC X(08). DTSBR705
|
|
00115 DTSBR705
|
|
00116 05 HDR-LINE-2. DTSBR705
|
|
00117 10 FILLER PIC X(41) VALUE SPACES. DTSBR705
|
|
00118 10 HDR-AGY-NAME-LINE2 PIC X(50). DTSBR705
|
|
00119 10 FILLER PIC X(28) VALUE SPACES. DTSBR705
|
|
00120 10 FILLER PIC X(05) DTSBR705
|
|
00121 VALUE 'TIME:'. DTSBR705
|
|
00122 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00123 10 HDR-SYS-TIME PIC X(08). DTSBR705
|
|
00124 DTSBR705
|
|
00125 05 HDR-LINE-3. DTSBR705
|
|
00126 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00127 10 FILLER PIC X(30) DTSBR705
|
|
00128 VALUE 'ROUTE TO: CHIEF, TAX DIVISION'. DTSBR705
|
|
00129 10 FILLER PIC X(88) VALUE SPACES. DTSBR705
|
|
00130 10 FILLER PIC X(05) DTSBR705
|
|
00131 VALUE 'PAGE:'. DTSBR705
|
|
00132 10 FILLER PIC X(03) VALUE SPACES. DTSBR705
|
|
00133 10 HDR-PAGE-CNT PIC ZZ,ZZ9. DTSBR705
|
|
00134 DTSBR705
|
|
00135 05 HDR-LINE-4. DTSBR705
|
|
00136 10 FILLER PIC X(12) VALUE SPACES. DTSBR705
|
|
00137 10 FILLER PIC X(20) DTSBR705
|
|
00138 VALUE ' '. DTSBR705
|
|
00139 10 FILLER PIC X(21) VALUE SPACES. DTSBR705
|
|
00140 10 FILLER PIC X(26) DTSBR705
|
|
00141 VALUE 'FAILED FUTA CERTIFICATIONS'. DTSBR705
|
|
00142 DTSBR705
|
|
00143 05 HDR-LINE-5 PIC X(133) VALUE SPACES. DTSBR705
|
|
00144 05 HDR-LINE-6 PIC X(133) VALUE SPACES. DTSBR705
|
|
00145 05 HDR-LINE-7. DTSBR705
|
|
00146 10 FILLER PIC X(11) VALUE SPACES. DTSBR705
|
|
00147 10 FILLER PIC X(03) DTSBR705
|
|
00148 VALUE 'TAX'. DTSBR705
|
|
00149 10 FILLER PIC X(15) VALUE SPACES. DTSBR705
|
|
00150 10 FILLER PIC X(14) DTSBR705
|
|
00151 VALUE ALL '*'. DTSBR705
|
|
00152 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00153 10 FILLER PIC X(24) DTSBR705
|
|
00154 VALUE 'CERT REQUEST RECORD INFO'. DTSBR705
|
|
00155 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00156 10 FILLER PIC X(13) DTSBR705
|
|
00157 VALUE ALL '*'. DTSBR705
|
|
00158 DTSBR705
|
|
00159 05 HDR-LINE-8. DTSBR705
|
|
00160 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00161 10 FILLER PIC X(40) DTSBR705
|
|
00162 VALUE 'EMP NO PER FEIN NAME/ADDRE'. DTSBR705
|
|
00163 10 FILLER PIC X(02) DTSBR705
|
|
00164 VALUE 'SS'. DTSBR705
|
|
00165 10 FILLER PIC X(23) VALUE SPACES. DTSBR705
|
|
00166 10 FILLER PIC X(34) DTSBR705
|
|
00167 VALUE 'XREF FEIN NCRL ERROR MESSAGE'. DTSBR705
|
|
00168 05 HDR-LINE-9 PIC X(133) VALUE SPACES. DTSBR705
|
|
00169 DTSBR705
|
|
00170 01 DETAIL-LINE1. DTSBR705
|
|
00171 05 DTL1-LINE-1. DTSBR705
|
|
00172 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00173 10 DTL1-EMP-NO PIC 999B999. DTSBR705
|
|
00174 10 FILLER PIC X(02) VALUE SPACES. DTSBR705
|
|
00175 10 DTL1-TAX-YEAR PIC 9(04). DTSBR705
|
|
00176 10 FILLER PIC X(03) VALUE SPACES. DTSBR705
|
|
00177 10 DTL1-FEIN PIC 99B9(07). DTSBR705
|
|
00178 10 FILLER PIC X(02) VALUE SPACES. DTSBR705
|
|
00179 10 DTL1-NAME-ADD-1 PIC X(35). DTSBR705
|
|
00180 10 FILLER PIC X(02) VALUE SPACES. DTSBR705
|
|
00181 10 DTL1-XREF-FEIN PIC 99B9(07). DTSBR705
|
|
00182 10 FILLER PIC X(02) VALUE SPACES. DTSBR705
|
|
00183 10 DTL1-NAME-CONTROL PIC X(04). DTSBR705
|
|
00184 10 FILLER PIC X(04) VALUE SPACES. DTSBR705
|
|
00185 10 DTL1-MSG-TEXT-1 PIC X(40). DTSBR705
|
|
00186 DTSBR705
|
|
00187 01 DETAIL-LINE2. DTSBR705
|
|
00188 05 DTL2-LINE-1. DTSBR705
|
|
00189 10 FILLER PIC X(29) VALUE SPACES. DTSBR705
|
|
00190 10 DTL2-NAME-ADD-2 PIC X(35). DTSBR705
|
|
00191 10 FILLER PIC X(02) VALUE SPACES. DTSBR705
|
|
00192 10 DTL2-MSG-TEXT-2 PIC X(40). DTSBR705
|
|
00193 DTSBR705
|
|
00194 01 DETAIL-LINE3. DTSBR705
|
|
00195 05 DTL3-LINE-1. DTSBR705
|
|
00196 10 FILLER PIC X(29) VALUE SPACES. DTSBR705
|
|
00197 10 DTL3-NAME-ADD-3 PIC X(35). DTSBR705
|
|
00198 DTSBR705
|
|
00199 01 CONTROL-FOOTING-FINAL. DTSBR705
|
|
00200 05 CFF-LINE-4. DTSBR705
|
|
00201 10 FILLER PIC X(11) VALUE SPACES. DTSBR705
|
|
00202 10 CFF-NUMBER-ONE PIC ZZZZ,ZZ9. DTSBR705
|
|
00203 10 FILLER PIC X(01) VALUE SPACE. DTSBR705
|
|
00204 10 FILLER PIC X(26) DTSBR705
|
|
00205 VALUE 'FAILED FUTA CERTIFICATIONS'. DTSBR705
|
|
00206 EJECT DTSBR705
|
|
00207 LINKAGE SECTION. DTSBR705
|
|
00208 DTSBR705
|
|
00209 01 LRCM-LINK-AREA. DTSBR705
|
|
00210 ++INCLUDE DTSILRCM DTSBR705
|
|
00211 EJECT DTSBR705
|
|
00212 01 R705-REC. DTSBR705
|
|
00213 ++INCLUDE DTSIR705 DTSBR705
|
|
00214 EJECT DTSBR705
|
|
00215 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR705
|
|
00216 R705-REC. DTSBR705
|
|
00217 IF FIRST-TIME-IND = 'Y' DTSBR705
|
|
00218 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR705
|
|
00219 MOVE 'N' TO FIRST-TIME-IND. DTSBR705
|
|
00220 DTSBR705
|
|
00221 IF LRCM-EOR-88 DTSBR705
|
|
00222 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR705
|
|
00223 ELSE DTSBR705
|
|
00224 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR705
|
|
00225 DTSBR705
|
|
00226 GOBACK. DTSBR705
|
|
00227 EJECT DTSBR705
|
|
00228 I1000-INITIATE. DTSBR705
|
|
00229 DTSBR705
|
|
00230 OPEN OUTPUT PRT-FILE. DTSBR705
|
|
00231 MOVE LRCM-SYS-DATE TO HDR-SYS-DATE. DTSBR705
|
|
00232 MOVE LRCM-SYS-TIME TO HDR-SYS-TIME. DTSBR705
|
|
00233 MOVE LRCM-AGY-NAME-LINE1 TO HDR-AGY-NAME-LINE1. DTSBR705
|
|
00234 MOVE LRCM-AGY-NAME-LINE2 TO HDR-AGY-NAME-LINE2. DTSBR705
|
|
00235 MOVE SPACES TO REPORT-LISTING1. DTSBR705
|
|
00236 DTSBR705
|
|
00237 I1000-EXIT. DTSBR705
|
|
00238 EXIT. DTSBR705
|
|
00239 EJECT DTSBR705
|
|
00240 P1000-PROCESS. DTSBR705
|
|
00241 DTSBR705
|
|
00242 IF R705-EMP-NO = ZEROES DTSBR705
|
|
00243 MOVE SPACES TO WS-EMP-NO DTSBR705
|
|
00244 ELSE DTSBR705
|
|
00245 MOVE R705-EMP-NO TO WS-EMP-NO-EDIT. DTSBR705
|
|
00246 DTSBR705
|
|
00247 MOVE +0 TO WS-NAME-ADD-CNT. DTSBR705
|
|
00248 IF R705-NAME1 NOT = SPACES DTSBR705
|
|
00249 ADD +1 TO WS-NAME-ADD-CNT DTSBR705
|
|
00250 MOVE R705-NAME1 TO WS-NAME-ADD (WS-NAME-ADD-CNT). DTSBR705
|
|
00251 IF R705-NAME2 NOT = SPACES DTSBR705
|
|
00252 ADD +1 TO WS-NAME-ADD-CNT DTSBR705
|
|
00253 MOVE R705-NAME2 TO WS-NAME-ADD (WS-NAME-ADD-CNT). DTSBR705
|
|
00254 IF R705-NAME3 NOT = SPACES DTSBR705
|
|
00255 ADD +1 TO WS-NAME-ADD-CNT DTSBR705
|
|
00256 MOVE R705-NAME3 TO WS-NAME-ADD (WS-NAME-ADD-CNT). DTSBR705
|
|
00257 IF R705-NAME4 NOT = SPACES DTSBR705
|
|
00258 ADD +1 TO WS-NAME-ADD-CNT DTSBR705
|
|
00259 MOVE R705-NAME4 TO WS-NAME-ADD (WS-NAME-ADD-CNT). DTSBR705
|
|
00260 DTSBR705
|
|
00261 ADD +1 TO WS-NAME-ADD-CNT. DTSBR705
|
|
00262 MOVE R705-STREET-ADDR TO WS-NAME-ADD (WS-NAME-ADD-CNT). DTSBR705
|
|
00263 ADD +1 TO WS-NAME-ADD-CNT. DTSBR705
|
|
00264 MOVE SPACES TO WS-NAME-ADD (WS-NAME-ADD-CNT). DTSBR705
|
|
00265 STRING R705-CITY DELIMITED BY SIZE DTSBR705
|
|
00266 R705-STATE DELIMITED BY SIZE DTSBR705
|
|
00267 ' ' DELIMITED BY SIZE DTSBR705
|
|
00268 R705-ZIP-CODE DELIMITED BY SIZE DTSBR705
|
|
00269 INTO DTSBR705
|
|
00270 WS-NAME-ADD (WS-NAME-ADD-CNT). DTSBR705
|
|
00271 DTSBR705
|
|
00272 MOVE WS-EMP-NO TO DTL1-EMP-NO. DTSBR705
|
|
00273 MOVE R705-TAX-YEAR TO DTL1-TAX-YEAR. DTSBR705
|
|
00274 MOVE R705-FEIN TO DTL1-FEIN. DTSBR705
|
|
00275 MOVE WS-NAME-ADD (1) TO DTL1-NAME-ADD-1. DTSBR705
|
|
00276 MOVE R705-XREF-FEIN TO DTL1-XREF-FEIN. DTSBR705
|
|
00277 MOVE R705-NAME-CONTROL TO DTL1-NAME-CONTROL. DTSBR705
|
|
00278 MOVE R705-MSG-TEXT-1 TO DTL1-MSG-TEXT-1. DTSBR705
|
|
00279 DTSBR705
|
|
00280 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR705
|
|
00281 WRITE REPORT-LISTING1 FROM DTL1-LINE-1 AFTER 1. DTSBR705
|
|
00282 ADD +1 TO WS-NUMBER-ONE. DTSBR705
|
|
00283 ADD +1 TO WS-LINE-CNT2. DTSBR705
|
|
00284 DTSBR705
|
|
00285 MOVE WS-NAME-ADD (2) TO DTL2-NAME-ADD-2. DTSBR705
|
|
00286 MOVE R705-MSG-TEXT-2 TO DTL2-MSG-TEXT-2. DTSBR705
|
|
00287 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR705
|
|
00288 WRITE REPORT-LISTING1 FROM DTL2-LINE-1 AFTER 1. DTSBR705
|
|
00289 ADD +1 TO WS-LINE-CNT2. DTSBR705
|
|
00290 DTSBR705
|
|
00291 PERFORM DTSBR705
|
|
00292 VARYING WS-SUB FROM +3 BY +1 DTSBR705
|
|
00293 UNTIL WS-SUB > WS-NAME-ADD-CNT DTSBR705
|
|
00294 MOVE WS-NAME-ADD (WS-SUB) TO DTL3-NAME-ADD-3 DTSBR705
|
|
00295 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR705
|
|
00296 WRITE REPORT-LISTING1 FROM DTL3-LINE-1 AFTER 1 DTSBR705
|
|
00297 ADD +1 TO WS-LINE-CNT2 DTSBR705
|
|
00298 DTSBR705
|
|
00299 END-PERFORM. DTSBR705
|
|
00300 WRITE REPORT-LISTING1 FROM BLANK-LINE AFTER 1. DTSBR705
|
|
00301 ADD +1 TO WS-LINE-CNT2. DTSBR705
|
|
00302 DTSBR705
|
|
00303 P1000-EXIT. DTSBR705
|
|
00304 EXIT. DTSBR705
|
|
00305 DTSBR705
|
|
00306 P2000-PRINT-HEADER. DTSBR705
|
|
00307 DTSBR705
|
|
00308 IF WS-LINE-CNT GREATER 58 OR DTSBR705
|
|
00309 WS-LINE-CNT2 GREATER 58 DTSBR705
|
|
00310 MOVE +0 TO WS-LINE-CNT DTSBR705
|
|
00311 MOVE +0 TO WS-LINE-CNT2 DTSBR705
|
|
00312 ADD +1 TO WS-PAGE-CNT DTSBR705
|
|
00313 MOVE WS-PAGE-CNT TO HDR-PAGE-CNT DTSBR705
|
|
00314 WRITE REPORT-LISTING1 FROM HDR-LINE-1 DTSBR705
|
|
00315 AFTER TOP-OF-PAGE DTSBR705
|
|
00316 WRITE REPORT-LISTING1 FROM HDR-LINE-2 AFTER 1 DTSBR705
|
|
00317 WRITE REPORT-LISTING1 FROM HDR-LINE-3 AFTER 1 DTSBR705
|
|
00318 WRITE REPORT-LISTING1 FROM HDR-LINE-4 AFTER 1 DTSBR705
|
|
00319 WRITE REPORT-LISTING1 FROM HDR-LINE-5 AFTER 1 DTSBR705
|
|
00320 WRITE REPORT-LISTING1 FROM HDR-LINE-6 AFTER 1 DTSBR705
|
|
00321 WRITE REPORT-LISTING1 FROM HDR-LINE-7 AFTER 1 DTSBR705
|
|
00322 WRITE REPORT-LISTING1 FROM HDR-LINE-8 AFTER 1 DTSBR705
|
|
00323 WRITE REPORT-LISTING1 FROM HDR-LINE-9 AFTER 1 DTSBR705
|
|
00324 ADD +9 TO WS-LINE-CNT2. DTSBR705
|
|
00325 DTSBR705
|
|
00326 P2000-EXIT. DTSBR705
|
|
00327 EXIT. DTSBR705
|
|
00328 DTSBR705
|
|
00329 T1000-TERMINATE. DTSBR705
|
|
00330 DTSBR705
|
|
00331 IF WS-LINE-CNT2 > 52 DTSBR705
|
|
00332 MOVE +60 TO WS-LINE-CNT2 DTSBR705
|
|
00333 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR705
|
|
00334 DTSBR705
|
|
00335 MOVE WS-NUMBER-ONE TO CFF-NUMBER-ONE. DTSBR705
|
|
00336 WRITE REPORT-LISTING1 FROM CFF-LINE-4 AFTER 4. DTSBR705
|
|
00337 CLOSE PRT-FILE. DTSBR705
|
|
00338 DTSBR705
|
|
00339 T1000-EXIT. DTSBR705
|
|
00340 EXIT. DTSBR705
|
|
00341 DTSBR705
|
|
00342 *S999-ABEND. DTSBR705
|
|
00343 * DTSBR705
|
|
00344 * CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR705
|
|
00345 * DTSBR705
|
|
00346 *S999-EXIT. DTSBR705
|
|
00347 * EXIT. DTSBR705
|
|
00348 DTSBR705
|