373 lines
29 KiB
COBOL
373 lines
29 KiB
COBOL
00001 IDENTIFICATION DIVISION. 08/13/98
|
|
00002 PROGRAM-ID. DTSCS10. DTSCS10
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV001
|
|
00004 DATE-WRITTEN. NOVEMBER 1991. DTSCS10
|
|
00005 DATE-COMPILED. DTSCS10
|
|
00006 SKIP3 DTSCS10
|
|
00007 ***** DTSCS10
|
|
00008 * DTSCS10
|
|
00009 * FUNCTION: REGISTRATION MENU SCREEN PROCESSOR. DTSCS10
|
|
00010 * DTSCS10
|
|
00011 * DTSCS10
|
|
00012 * MODIFICATION LOG: DTSCS10
|
|
00013 * DTSCS10
|
|
00014 * 11/06/91 INITIAL DEVELOPMENT. DTSCS10
|
|
00015 * WORK ORDER: PROGRAMMER: TCL DTSCS10
|
|
00016 * DTSCS10
|
|
00017 * 04/06/94 MODIFIED FOR MONTANA. DTSCS10
|
|
00018 * WORK ORDER: PROGRAMMER: EHH DTSCS10
|
|
00019 * DTSCS10
|
|
00020 * 09/21/95 ADD OPTION 'E'. DTSCS10
|
|
00021 * WORK ORDER: JR PROGRAMMER: EHH DTSCS10
|
|
00022 * DTSCS10
|
|
00023 * 08/13/1998 REVIEWED AND MODIFIED FOR DC. DTSCS10
|
|
00024 * REFERENCE: DC DEVELOPMENT PROGRAMMER: EHH DTSCS10
|
|
00025 * DTSCS10
|
|
00026 * MM/DD/YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSCS10
|
|
00027 * REFERENCE: XXXXXXXXXXXXXXX PROGRAMMER: XXX DTSCS10
|
|
00028 * DTSCS10
|
|
00029 * DTSCS10
|
|
00030 * DESCRIPTION: DTSCS10
|
|
00031 * DTSCS10
|
|
00032 * IF SCREEN '10' NOT CURRENTLY DISPLAYED DTSCS10
|
|
00033 * SEND SCREEN 10 (WITH PMSG-KEY-OPTION MESSAGE) DTSCS10
|
|
00034 * RETURN TO DRIVER. DTSCS10
|
|
00035 * DTSCS10
|
|
00036 * RECEIVE SCREEN '10'. DTSCS10
|
|
00037 * DTSCS10
|
|
00038 * IF CLEAR KEY PRESSED DTSCS10
|
|
00039 * SEND SCREEN 10 (WITH PMSG-KEY-OPTION MESSAGE) DTSCS10
|
|
00040 * SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00041 * RETURN TO DRIVER. DTSCS10
|
|
00042 * DTSCS10
|
|
00043 * IF PA2 KEY PRESSED DTSCS10
|
|
00044 * SEND SCREEN 10 (DATA ONLY) DTSCS10
|
|
00045 * SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00046 * RETURN TO DRIVER. DTSCS10
|
|
00047 * DTSCS10
|
|
00048 * IF F3 KEY PRESSED DTSCS10
|
|
00049 * MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID DTSCS10
|
|
00050 * SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS10
|
|
00051 * RETURN TO DRIVER. DTSCS10
|
|
00052 * DTSCS10
|
|
00053 * IF F4 KEY PRESSED DTSCS10
|
|
00054 * MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID DTSCS10
|
|
00055 * SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS10
|
|
00056 * RETURN TO DRIVER. DTSCS10
|
|
00057 * DTSCS10
|
|
00058 * IF NOT ENTER KEY PRESSED DTSCS10
|
|
00059 * BUILD INVALID KEY MESSAGE (VIA LINK TO DTSCU804) DTSCS10
|
|
00060 * SEND SCREEN 10 (WITH THE INVALID KEY PRESSED MESSAGE) DTSCS10
|
|
00061 * SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00062 * RETURN TO DRIVER. DTSCS10
|
|
00063 * DTSCS10
|
|
00064 * DTSCS10
|
|
00065 * IF MAP-OPT = SPACES OR LOW-VALUES OR '10' DTSCS10
|
|
00066 * SEND SCREEN 00 (WITH THE PMSG-KEY-OPTION MESSAGE) DTSCS10
|
|
00067 * SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00068 * RETURN TO DRIVER. DTSCS10
|
|
00069 * DTSCS10
|
|
00070 * CONVERT MAP-OPT INTO A SCREEN IDENTIFIER, PLACING THE DTSCS10
|
|
00071 * RESULT IN LCCM-REQ-SCR-ID. DTSCS10
|
|
00072 * DTSCS10
|
|
00073 * EDIT LCCM-REQ-SCR-ID FOR VALIDITY (VIA A CALL TO DTSIU803). DTSCS10
|
|
00074 * DTSCS10
|
|
00075 * IF LCCM-REQ-SCR-ID VALID (LCCM-NO-MSG) DTSCS10
|
|
00076 * SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS10
|
|
00077 * RETURN TO DRIVER DTSCS10
|
|
00078 * ELSE DTSCS10
|
|
00079 * SEND SCREEN 10 (WITH ERROR MESSAGE) DTSCS10
|
|
00080 * SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00081 * RETURN TO DRIVER. DTSCS10
|
|
00082 * DTSCS10
|
|
00083 * DTSCS10
|
|
00084 ***** DTSCS10
|
|
00085 SKIP3 DTSCS10
|
|
00086 ENVIRONMENT DIVISION. DTSCS10
|
|
00087 SKIP3 DTSCS10
|
|
00088 DATA DIVISION. DTSCS10
|
|
00089 SKIP3 DTSCS10
|
|
00090 WORKING-STORAGE SECTION. DTSCS10
|
|
000905 77 PAN-VALET PICTURE X(24) VALUE '001DTSCS10 08/13/98'. DTSCS10
|
|
00091 SKIP3 DTSCS10
|
|
00092 01 WRK-AREA. DTSCS10
|
|
00093 05 WRK-ABEND-CD PIC X(04) VALUE 'S10 '. DTSCS10
|
|
00094 05 WRK-RESP-CD PIC S9(08) COMP. DTSCS10
|
|
00095 DTSCS10
|
|
00096 05 WRK-SCR-ID PIC X(02) VALUE '10'. DTSCS10
|
|
00097 05 WRK-F03-SCR-ID PIC X(02) VALUE '00'. DTSCS10
|
|
00098 DTSCS10
|
|
00099 05 RESP-IND PIC X(01). DTSCS10
|
|
00100 88 RESP-CURSOR-TO-OPT-88 VALUE 'C'. DTSCS10
|
|
00101 88 RESP-MSGONLY-88 VALUE 'M'. DTSCS10
|
|
00102 88 RESP-SCREEN-88 VALUE 'S'. DTSCS10
|
|
00103 88 RESP-JUMP-88 VALUE 'J'. DTSCS10
|
|
00104 DTSCS10
|
|
00105 05 CURSOR-IND PIC X(01). DTSCS10
|
|
00106 88 CURSOR-SET-88 VALUE 'Y'. DTSCS10
|
|
00107 DTSCS10
|
|
00108 05 WRK-DATE-AREA. DTSCS10
|
|
00109 10 WRK-DATE PIC X(08). DTSCS10
|
|
00110 10 FILLER PIC X(01) VALUE '.'. DTSCS10
|
|
00111 EJECT DTSCS10
|
|
00112 01 L851-COMM-AREA. DTSCS10
|
|
00113 ++INCLUDE DTSIL851 DTSCS10
|
|
00114 SKIP3 DTSCS10
|
|
00115 05 MAP-AREA REDEFINES L851-MAP-AREA. DTSCS10
|
|
00116 ++INCLUDE DTSISSM DTSCS10
|
|
00117 EJECT DTSCS10
|
|
00118 01 L805-COMM-AREA. DTSCS10
|
|
00119 ++INCLUDE DTSIL805 DTSCS10
|
|
00120 EJECT DTSCS10
|
|
00121 01 CATB-LITERALS. DTSCS10
|
|
00122 ++INCLUDE DTSICATB DTSCS10
|
|
00123 SKIP3 DTSCS10
|
|
00124 01 EMSG-LITERALS. DTSCS10
|
|
00125 ++INCLUDE DTSICECD DTSCS10
|
|
00126 SKIP3 DTSCS10
|
|
00127 01 PMSG-LITERALS. DTSCS10
|
|
00128 ++INCLUDE DTSICPCD DTSCS10
|
|
00129 EJECT DTSCS10
|
|
00130 LINKAGE SECTION. DTSCS10
|
|
00131 SKIP3 DTSCS10
|
|
00132 01 DFHCOMMAREA. DTSCS10
|
|
00133 ++INCLUDE DTSILCCM DTSCS10
|
|
00134 EJECT DTSCS10
|
|
00135 PROCEDURE DIVISION. DTSCS10
|
|
00136 SKIP2 DTSCS10
|
|
00137 MOVE LOW-VALUES TO MAP-AREA. DTSCS10
|
|
00138 DTSCS10
|
|
00139 MOVE 'N' TO CURSOR-IND. DTSCS10
|
|
00140 SKIP2 DTSCS10
|
|
00141 MOVE SPACE TO RESP-IND. DTSCS10
|
|
00142 PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT. DTSCS10
|
|
00143 SKIP2 DTSCS10
|
|
00144 IF RESP-MSGONLY-88 DTSCS10
|
|
00145 MOVE LOW-VALUES TO MAP-AREA DTSCS10
|
|
00146 PERFORM S805-MSG-AREA THRU S805-EXIT DTSCS10
|
|
00147 PERFORM S2200-SEND-DATAONLY THRU S2200-EXIT DTSCS10
|
|
00148 SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00149 ELSE DTSCS10
|
|
00150 IF RESP-SCREEN-88 DTSCS10
|
|
00151 PERFORM P2000-CONSTRUCT-S-AREA THRU P2000-EXIT DTSCS10
|
|
00152 PERFORM S2100-SEND THRU S2100-EXIT DTSCS10
|
|
00153 SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00154 ELSE DTSCS10
|
|
00155 IF RESP-JUMP-88 DTSCS10
|
|
00156 SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS10
|
|
00157 ELSE DTSCS10
|
|
00158 IF RESP-CURSOR-TO-OPT-88 DTSCS10
|
|
00159 MOVE LOW-VALUES TO MAP-AREA DTSCS10
|
|
00160 MOVE CATB-CURSOR TO MAP-OPT-L DTSCS10
|
|
00161 SET CURSOR-SET-88 TO TRUE DTSCS10
|
|
00162 PERFORM S2200-SEND-DATAONLY THRU S2200-EXIT DTSCS10
|
|
00163 SET LCCM-END-TASK-88 TO TRUE DTSCS10
|
|
00164 ELSE DTSCS10
|
|
00165 PERFORM S899-ABEND THRU S899-EXIT. DTSCS10
|
|
00166 SKIP2 DTSCS10
|
|
00167 EXEC CICS DTSCS10
|
|
00168 RETURN DTSCS10
|
|
00169 END-EXEC. DTSCS10
|
|
00170 SKIP2 DTSCS10
|
|
00171 GOBACK. DTSCS10
|
|
00172 EJECT DTSCS10
|
|
00173 P1000-ANALYZE-REQUEST. DTSCS10
|
|
00174 IF LCCM-SCR-ID NOT = WRK-SCR-ID DTSCS10
|
|
00175 MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA DTSCS10
|
|
00176 SET RESP-SCREEN-88 TO TRUE DTSCS10
|
|
00177 GO TO P1000-EXIT. DTSCS10
|
|
00178 DTSCS10
|
|
00179 PERFORM S1100-RECEIVE THRU S1100-EXIT. DTSCS10
|
|
00180 DTSCS10
|
|
00181 IF LCCM-CLEAR-88 OR LCCM-F12-88 DTSCS10
|
|
00182 MOVE LOW-VALUES TO MAP-AREA DTSCS10
|
|
00183 MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA DTSCS10
|
|
00184 SET RESP-SCREEN-88 TO TRUE DTSCS10
|
|
00185 GO TO P1000-EXIT. DTSCS10
|
|
00186 DTSCS10
|
|
00187 IF LCCM-PA2-88 DTSCS10
|
|
00188 SET RESP-CURSOR-TO-OPT-88 TO TRUE DTSCS10
|
|
00189 GO TO P1000-EXIT. DTSCS10
|
|
00190 DTSCS10
|
|
00191 IF LCCM-ENTER-88 OR LCCM-F03-88 OR LCCM-F04-88 OR LCCM-F14-88DTSCS10
|
|
00192 NEXT SENTENCE DTSCS10
|
|
00193 ELSE DTSCS10
|
|
00194 PERFORM S804-INVALID-KEY THRU S804-EXIT DTSCS10
|
|
00195 SET RESP-MSGONLY-88 TO TRUE DTSCS10
|
|
00196 GO TO P1000-EXIT. DTSCS10
|
|
00197 DTSCS10
|
|
00198 IF LCCM-F03-88 DTSCS10
|
|
00199 MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID DTSCS10
|
|
00200 SET RESP-JUMP-88 TO TRUE DTSCS10
|
|
00201 GO TO P1000-EXIT. DTSCS10
|
|
00202 DTSCS10
|
|
00203 IF LCCM-F04-88 DTSCS10
|
|
00204 MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID DTSCS10
|
|
00205 SET RESP-JUMP-88 TO TRUE DTSCS10
|
|
00206 GO TO P1000-EXIT. DTSCS10
|
|
00207 DTSCS10
|
|
00208 IF LCCM-F14-88 DTSCS10
|
|
00209 MOVE LCCM-CORR-SCR-ID TO LCCM-REQ-SCR-ID DTSCS10
|
|
00210 PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT DTSCS10
|
|
00211 IF LCCM-MSG DTSCS10
|
|
00212 SET RESP-SCREEN-88 TO TRUE DTSCS10
|
|
00213 GO TO P1000-EXIT DTSCS10
|
|
00214 ELSE DTSCS10
|
|
00215 SET RESP-JUMP-88 TO TRUE DTSCS10
|
|
00216 GO TO P1000-EXIT. DTSCS10
|
|
00217 DTSCS10
|
|
00218 IF MAP-OPT = SPACES OR LOW-VALUES OR WRK-SCR-ID DTSCS10
|
|
00219 MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA DTSCS10
|
|
00220 SET RESP-SCREEN-88 TO TRUE DTSCS10
|
|
00221 GO TO P1000-EXIT. DTSCS10
|
|
00222 DTSCS10
|
|
00223 IF MAP-OPT = '1 ' OR ' 1' DTSCS10
|
|
00224 MOVE '11' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00225 ELSE DTSCS10
|
|
00226 IF MAP-OPT = '2 ' OR ' 2' DTSCS10
|
|
00227 MOVE '12' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00228 ELSE DTSCS10
|
|
00229 IF MAP-OPT = '3 ' OR ' 3' DTSCS10
|
|
00230 MOVE '13' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00231 ELSE DTSCS10
|
|
00232 IF MAP-OPT = '4 ' OR ' 4' DTSCS10
|
|
00233 MOVE '14' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00234 ELSE DTSCS10
|
|
00235 IF MAP-OPT = '5 ' OR ' 5' DTSCS10
|
|
00236 MOVE '15' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00237 ELSE DTSCS10
|
|
00238 IF MAP-OPT = '6 ' OR ' 6' DTSCS10
|
|
00239 MOVE '16' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00240 ELSE DTSCS10
|
|
00241 IF MAP-OPT = '7 ' OR ' 7' DTSCS10
|
|
00242 MOVE '17' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00243 ELSE DTSCS10
|
|
00244 IF MAP-OPT = '8 ' OR ' 8' DTSCS10
|
|
00245 MOVE '18' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00246 ELSE DTSCS10
|
|
00247 IF MAP-OPT = '9 ' OR ' 9' DTSCS10
|
|
00248 MOVE '19' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00249 ELSE DTSCS10
|
|
00250 IF MAP-OPT = 'A ' OR ' A' DTSCS10
|
|
00251 MOVE '1A' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00252 *****ELSE DTSCS10
|
|
00253 *****IF MAP-OPT = 'B ' OR ' B' DTSCS10
|
|
00254 *********MOVE '1B' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00255 ELSE DTSCS10
|
|
00256 IF MAP-OPT = 'C ' OR ' C' DTSCS10
|
|
00257 MOVE '1C' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00258 ELSE DTSCS10
|
|
00259 IF MAP-OPT = 'D ' OR ' D' DTSCS10
|
|
00260 MOVE '1D' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00261 *****ELSE DTSCS10
|
|
00262 *****IF MAP-OPT = 'E ' OR ' E' DTSCS10
|
|
00263 *********MOVE '1E' TO LCCM-REQ-SCR-ID DTSCS10
|
|
00264 ELSE DTSCS10
|
|
00265 MOVE MAP-OPT TO LCCM-REQ-SCR-ID. DTSCS10
|
|
00266 DTSCS10
|
|
00267 PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT. DTSCS10
|
|
00268 IF LCCM-MSG DTSCS10
|
|
00269 SET RESP-SCREEN-88 TO TRUE DTSCS10
|
|
00270 ELSE DTSCS10
|
|
00271 SET RESP-JUMP-88 TO TRUE. DTSCS10
|
|
00272 P1000-EXIT. DTSCS10
|
|
00273 EXIT. DTSCS10
|
|
00274 EJECT DTSCS10
|
|
00275 P2000-CONSTRUCT-S-AREA. DTSCS10
|
|
00276 MOVE LCCM-TASK-START-DISP-DATE TO MAP-SYS-DATE. DTSCS10
|
|
00277 MOVE LCCM-TASK-START-DISP-TIME TO MAP-SYS-TIME. DTSCS10
|
|
00278 MOVE LCCM-CICS-REGION-NAME TO MAP-CICS-REGION-NAME. DTSCS10
|
|
00279 DTSCS10
|
|
00280 PERFORM S805-MSG-AREA THRU S805-EXIT. DTSCS10
|
|
00281 P2000-EXIT. DTSCS10
|
|
00282 EXIT. DTSCS10
|
|
00283 EJECT DTSCS10
|
|
00284 S803-REQ-SCR-ID-EDIT. DTSCS10
|
|
00285 DTSCS10
|
|
00286 EXEC CICS DTSCS10
|
|
00287 LINK DTSCS10
|
|
00288 PROGRAM ('DTSCU803') DTSCS10
|
|
00289 COMMAREA (DFHCOMMAREA) DTSCS10
|
|
00290 END-EXEC. DTSCS10
|
|
00291 DTSCS10
|
|
00292 S803-EXIT. DTSCS10
|
|
00293 EXIT. DTSCS10
|
|
00294 SKIP3 DTSCS10
|
|
00295 S804-INVALID-KEY. DTSCS10
|
|
00296 DTSCS10
|
|
00297 EXEC CICS DTSCS10
|
|
00298 LINK DTSCS10
|
|
00299 PROGRAM ('DTSCU804') DTSCS10
|
|
00300 COMMAREA (DFHCOMMAREA) DTSCS10
|
|
00301 END-EXEC. DTSCS10
|
|
00302 DTSCS10
|
|
00303 S804-EXIT. DTSCS10
|
|
00304 EXIT. DTSCS10
|
|
00305 SKIP3 DTSCS10
|
|
00306 S805-MSG-AREA. DTSCS10
|
|
00307 MOVE LCCM-MSG-AREA TO L805-MSG-AREA. DTSCS10
|
|
00308 DTSCS10
|
|
00309 EXEC CICS DTSCS10
|
|
00310 LINK DTSCS10
|
|
00311 PROGRAM ('DTSCU805') DTSCS10
|
|
00312 COMMAREA (L805-COMM-AREA) DTSCS10
|
|
00313 END-EXEC. DTSCS10
|
|
00314 DTSCS10
|
|
00315 MOVE L805-S-MSG-AREA TO MAP-MSG-AREA. DTSCS10
|
|
00316 S805-EXIT. DTSCS10
|
|
00317 EXIT. DTSCS10
|
|
00318 SKIP3 DTSCS10
|
|
00319 S851-SCREEN-PROCESSING. DTSCS10
|
|
00320 EXEC CICS DTSCS10
|
|
00321 LINK DTSCS10
|
|
00322 PROGRAM ('DTSCU851') DTSCS10
|
|
00323 COMMAREA (L851-COMM-AREA) DTSCS10
|
|
00324 END-EXEC. DTSCS10
|
|
00325 S851-EXIT. DTSCS10
|
|
00326 EXIT. DTSCS10
|
|
00327 SKIP3 DTSCS10
|
|
00328 S899-ABEND. DTSCS10
|
|
00329 DTSCS10
|
|
00330 EXEC CICS DTSCS10
|
|
00331 ABEND DTSCS10
|
|
00332 ABCODE (WRK-ABEND-CD) DTSCS10
|
|
00333 END-EXEC. DTSCS10
|
|
00334 DTSCS10
|
|
00335 S899-EXIT. DTSCS10
|
|
00336 EXIT. DTSCS10
|
|
00337 EJECT DTSCS10
|
|
00338 S1100-RECEIVE. DTSCS10
|
|
00339 SET L851-RECEIVE-88 TO TRUE. DTSCS10
|
|
00340 MOVE WRK-SCR-ID TO L851-SCR-ID. DTSCS10
|
|
00341 PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT. DTSCS10
|
|
00342 MOVE L851-AID TO LCCM-AID. DTSCS10
|
|
00343 MOVE L851-CURSOR TO LCCM-CURSOR. DTSCS10
|
|
00344 S1100-EXIT. DTSCS10
|
|
00345 EXIT. DTSCS10
|
|
00346 SKIP3 DTSCS10
|
|
00347 S2100-SEND. DTSCS10
|
|
00348 SET L851-SEND-88 TO TRUE. DTSCS10
|
|
00349 PERFORM S2900-PREPARE-SEND THRU S2900-EXIT. DTSCS10
|
|
00350 PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT. DTSCS10
|
|
00351 S2100-EXIT. DTSCS10
|
|
00352 EXIT. DTSCS10
|
|
00353 SKIP3 DTSCS10
|
|
00354 S2200-SEND-DATAONLY. DTSCS10
|
|
00355 SET L851-SEND-DATAONLY-88 TO TRUE. DTSCS10
|
|
00356 PERFORM S2900-PREPARE-SEND THRU S2900-EXIT. DTSCS10
|
|
00357 PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT. DTSCS10
|
|
00358 S2200-EXIT. DTSCS10
|
|
00359 EXIT. DTSCS10
|
|
00360 SKIP3 DTSCS10
|
|
00361 S2900-PREPARE-SEND. DTSCS10
|
|
00362 MOVE WRK-SCR-ID TO L851-SCR-ID DTSCS10
|
|
00363 LCCM-SCR-ID. DTSCS10
|
|
00364 MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND. DTSCS10
|
|
00365 MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE. DTSCS10
|
|
00366 IF CURSOR-SET-88 DTSCS10
|
|
00367 NEXT SENTENCE DTSCS10
|
|
00368 ELSE DTSCS10
|
|
00369 MOVE CATB-CURSOR TO MAP-OPT-L. DTSCS10
|
|
00370 S2900-EXIT. DTSCS10
|
|
00371 EXIT. DTSCS10
|