516 lines
41 KiB
COBOL
516 lines
41 KiB
COBOL
00001 IDENTIFICATION DIVISION. 01/29/01
|
|
00002 PROGRAM-ID. DTSBR305. DTSBR305
|
|
00003 AUTHOR. TRW S&ITG. LV036
|
|
00004 DATE-WRITTEN. DECEMBER 1998. DTSBR305
|
|
00005 DATE-COMPILED. DTSBR305
|
|
00006 SKIP3 DTSBR305
|
|
00007 ***** DTSBR305
|
|
00008 * DTSBR305
|
|
00009 * CALLING SEQUENCE: DTSBE305 CREATES DTSIR305 RECORDS. DTSBR305
|
|
00010 * DTSBD800 CALLS DTSBR305 DTSBR305
|
|
00011 * WHICH PRODUCES THE TRIAL BALANCE.DTSBR305
|
|
00012 * DTSBR305
|
|
00013 * DTSBR305
|
|
00014 * FUNCTION: TRIAL BALANCE REPORT. DTSBR305
|
|
00015 * DTSBR305
|
|
00016 * DTSBR305
|
|
00017 * MODIFICATION HISTORY: DTSBR305
|
|
00018 * DTSBR305
|
|
00019 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR305
|
|
00020 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR305
|
|
00021 * REFERENCE RFP #**** AUTHOR OF CHANGE - XXX DTSBR305
|
|
00022 * DTSBR305
|
|
00023 * DTSBR305
|
|
00024 * DESCRIPTION: DTSBR305
|
|
00025 * DTSBR305
|
|
00026 * THIS MODULE DETAILS THE DISPOSITION OF ALL ACCOUNTS DTSBR305
|
|
00027 * (UI TAX, SUR TAX, LATE PENALTY, NSF PENALTY, MISC DTSBR305
|
|
00028 * PENALTY INTEREST AND CREDIT) WITHIN THE TAX SYSTEM. DTSBR305
|
|
00029 * DTSBR305
|
|
00030 * DTSBR305
|
|
00031 * RECORDS READ: DTSBR305
|
|
00032 * DTSBR305
|
|
00033 * NONE. DTSBR305
|
|
00034 * DTSBR305
|
|
00035 * DTSBR305
|
|
00036 * PRINTED OUTPUTS: DTSBR305
|
|
00037 * DTSBR305
|
|
00038 * 305R1 TRIAL BALANCE DTSBR305
|
|
00039 * DTSBR305
|
|
00040 * DTSBR305
|
|
00041 * RECORDS WRITTEN: DTSBR305
|
|
00042 * DTSBR305
|
|
00043 * NONE. DTSBR305
|
|
00044 * DTSBR305
|
|
00045 * DTSBR305
|
|
00046 * MODULES CALLED: DTSBR305
|
|
00047 * DTSBR305
|
|
00048 * DTSBU032 ACCOUNTING CODES EDIT/DESCRIPTION MODULE DTSBR305
|
|
00049 * DTSBR305
|
|
00050 * DTSBR305
|
|
00051 ***** DTSBR305
|
|
00052 EJECT DTSBR305
|
|
00053 ENVIRONMENT DIVISION. DTSBR305
|
|
00054 DTSBR305
|
|
00055 CONFIGURATION SECTION. DTSBR305
|
|
00056 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. DTSBR305
|
|
00057 DTSBR305
|
|
00058 INPUT-OUTPUT SECTION. DTSBR305
|
|
00059 DTSBR305
|
|
00060 FILE-CONTROL. DTSBR305
|
|
00061 SELECT PRT-FILE ASSIGN TO RPT305R1. DTSBR305
|
|
00062 DTSBR305
|
|
00063 DATA DIVISION. DTSBR305
|
|
00064 DTSBR305
|
|
00065 FILE SECTION. DTSBR305
|
|
00066 DTSBR305
|
|
00067 FD PRT-FILE DTSBR305
|
|
00068 RECORDING MODE IS F. DTSBR305
|
|
00069 01 PRT-RECORD PIC X(133). DTSBR305
|
|
00070 DTSBR305
|
|
00071 WORKING-STORAGE SECTION. DTSBR305
|
|
000715 77 PAN-VALET PICTURE X(24) VALUE '036DTSBR305 01/29/01'. DTSBR305
|
|
00072 SKIP3 DTSBR305
|
|
00073 01 WRK-AREA. DTSBR305
|
|
00074 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +305.DTSBR305
|
|
00075 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR305
|
|
00076 05 WS-EMP-CLASS-HOLD PIC X(01) VALUE SPACE. DTSBR305
|
|
00077 DTSBR305
|
|
00078 05 WS-BLANK-LINE PIC X(133) VALUE SPACES. DTSBR305
|
|
00079 05 WS-FOOT-NUMBER-ONE PIC S9(03) COMP-3 VALUE +0. DTSBR305
|
|
00080 05 WS-SUM-NUMBER-ONE PIC S9(03) COMP-3 VALUE +0. DTSBR305
|
|
00081 05 WS-LINE-CNT PIC S9(02) COMP-3 VALUE 60. DTSBR305
|
|
00082 05 WS-LINE-CNT2 PIC S9(02) COMP-3 VALUE +0. DTSBR305
|
|
00083 05 WS-PAGE-CNT PIC S9(03) COMP-3 VALUE +0. DTSBR305
|
|
00084 DTSBR305
|
|
00085 SKIP1 DTSBR305
|
|
00086 05 WS-DETAIL-AMTS. DTSBR305
|
|
00087 10 WS-CHARGED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00088 10 WS-PAID-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00089 10 WS-WAIVED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00090 10 WS-WRITTEN-OFF-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00091 10 WS-TOLER-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00092 10 WS-BALANCE-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00093 SKIP1 DTSBR305
|
|
00094 05 WS-SUB PIC S9(04) COMP VALUE +0. DTSBR305
|
|
00095 05 WS-TABLE-SIZE PIC S9(04) COMP DTSBR305
|
|
00096 VALUE +7. DTSBR305
|
|
00097 05 WS-ACCT-DSCR-TABLE OCCURS 7 TIMES. DTSBR305
|
|
00098 10 WS-ACCT-IND PIC X(02) VALUE SPACE. DTSBR305
|
|
00099 10 WS-ACCT-SHORT-DSCR PIC X(10) VALUE SPACE. DTSBR305
|
|
00100 05 WS-ALL-TABLE OCCURS 7 TIMES. DTSBR305
|
|
00101 10 WS-ALL-CHARGED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00102 10 WS-ALL-PAID-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00103 10 WS-ALL-WAIVED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00104 10 WS-ALL-WRITTEN-OFF-AMT PIC S9(11)V99 COMP-3 DTSBR305
|
|
00105 VALUE +0. DTSBR305
|
|
00106 10 WS-ALL-TOLER-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00107 10 WS-ALL-BALANCE-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00108 05 WS-FOOT-TABLE. DTSBR305
|
|
00109 10 WS-FOOT-CHARGED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00110 10 WS-FOOT-PAID-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00111 10 WS-FOOT-WAIVED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00112 10 WS-FOOT-WRITTEN-OFF-AMT PIC S9(11)V99 COMP-3 DTSBR305
|
|
00113 VALUE +0. DTSBR305
|
|
00114 10 WS-FOOT-TOLER-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00115 10 WS-FOOT-BALANCE-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00116 05 WS-SUM-TABLE. DTSBR305
|
|
00117 10 WS-SUM-CHARGED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00118 10 WS-SUM-PAID-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00119 10 WS-SUM-WAIVED-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00120 10 WS-SUM-WRITTEN-OFF-AMT PIC S9(11)V99 COMP-3 DTSBR305
|
|
00121 VALUE +0. DTSBR305
|
|
00122 10 WS-SUM-TOLER-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00123 10 WS-SUM-BALANCE-AMT PIC S9(11)V99 COMP-3 VALUE +0.DTSBR305
|
|
00124 EJECT DTSBR305
|
|
00125 01 L032-LINK-AREA. DTSBR305
|
|
00126 ++INCLUDE DTSIL032 DTSBR305
|
|
00127 EJECT DTSBR305
|
|
00128 01 PAGE-HEADING. DTSBR305
|
|
00129 05 HEADER-1. DTSBR305
|
|
00130 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00131 10 FILLER PIC X(05) DTSBR305
|
|
00132 VALUE '305R1'. DTSBR305
|
|
00133 10 FILLER PIC X(34) VALUE SPACES. DTSBR305
|
|
00134 10 WS-AGY-NAME-LINE1 PIC X(50). DTSBR305
|
|
00135 10 FILLER PIC X(28) VALUE SPACES. DTSBR305
|
|
00136 10 FILLER PIC X(05) DTSBR305
|
|
00137 VALUE 'DATE:'. DTSBR305
|
|
00138 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00139 10 WS-SYS-DATE PIC X(08). DTSBR305
|
|
00140 05 HEADER-2. DTSBR305
|
|
00141 10 FILLER PIC X(40) VALUE SPACES. DTSBR305
|
|
00142 10 WS-AGY-NAME-LINE2 PIC X(50). DTSBR305
|
|
00143 10 FILLER PIC X(28) VALUE SPACES. DTSBR305
|
|
00144 10 FILLER PIC X(05) DTSBR305
|
|
00145 VALUE 'TIME:'. DTSBR305
|
|
00146 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00147 10 WS-SYS-TIME PIC X(08). DTSBR305
|
|
00148 05 HEADER-3. DTSBR305
|
|
00149 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00150 10 FILLER PIC X(25) DTSBR305
|
|
00151 VALUE 'ROUTE TO: ACCOUNTING'. DTSBR305
|
|
00152 10 FILLER PIC X(32) VALUE SPACES. DTSBR305
|
|
00153 10 FILLER PIC X(13) DTSBR305
|
|
00154 VALUE 'TRIAL BALANCE'. DTSBR305
|
|
00155 10 FILLER PIC X(47) VALUE SPACES. DTSBR305
|
|
00156 10 FILLER PIC X(05) DTSBR305
|
|
00157 VALUE 'PAGE:'. DTSBR305
|
|
00158 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00159 10 HDR3-PAGE-CNT PIC ZZ,ZZ9. DTSBR305
|
|
00160 05 HEADER-4 PIC X(133) VALUE SPACES. DTSBR305
|
|
00161 05 HEADER-5. DTSBR305
|
|
00162 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00163 10 FILLER PIC X(15) DTSBR305
|
|
00164 VALUE 'EMPLOYER TYPE: '. DTSBR305
|
|
00165 10 WS-EMPLOYER-TYPE-DSCR PIC X(12). DTSBR305
|
|
00166 10 FILLER PIC X(105) VALUE SPACES. DTSBR305
|
|
00167 05 HEADER-6 PIC X(133) VALUE SPACES. DTSBR305
|
|
00168 05 HEADER-7. DTSBR305
|
|
00169 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00170 10 FILLER PIC X(07) DTSBR305
|
|
00171 VALUE 'ACCOUNT'. DTSBR305
|
|
00172 10 FILLER PIC X(125) VALUE SPACES. DTSBR305
|
|
00173 05 HEADER-8. DTSBR305
|
|
00174 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00175 10 FILLER PIC X(07) DTSBR305
|
|
00176 VALUE 'SUMMARY'. DTSBR305
|
|
00177 10 FILLER PIC X(07) VALUE SPACES. DTSBR305
|
|
00178 10 FILLER PIC X(01) DTSBR305
|
|
00179 VALUE 'D'. DTSBR305
|
|
00180 10 FILLER PIC X(12) VALUE SPACES. DTSBR305
|
|
00181 10 FILLER PIC X(07) DTSBR305
|
|
00182 VALUE 'CHARGED'. DTSBR305
|
|
00183 10 FILLER PIC X(15) VALUE SPACES. DTSBR305
|
|
00184 10 FILLER PIC X(04) DTSBR305
|
|
00185 VALUE 'PAID'. DTSBR305
|
|
00186 10 FILLER PIC X(13) VALUE SPACES. DTSBR305
|
|
00187 10 FILLER PIC X(06) DTSBR305
|
|
00188 VALUE 'WAIVED'. DTSBR305
|
|
00189 10 FILLER PIC X(08) VALUE SPACES. DTSBR305
|
|
00190 10 FILLER PIC X(11) DTSBR305
|
|
00191 VALUE 'WRITTEN OFF'. DTSBR305
|
|
00192 10 FILLER PIC X(10) VALUE SPACES. DTSBR305
|
|
00193 10 FILLER PIC X(09) DTSBR305
|
|
00194 VALUE 'TOLERANCE'. DTSBR305
|
|
00195 10 FILLER PIC X(12) VALUE SPACES. DTSBR305
|
|
00196 10 FILLER PIC X(07) DTSBR305
|
|
00197 VALUE 'BALANCE'. DTSBR305
|
|
00198 05 HEADER-9. DTSBR305
|
|
00199 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00200 10 FILLER PIC X(10) DTSBR305
|
|
00201 VALUE ALL '-'. DTSBR305
|
|
00202 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00203 10 FILLER PIC X(02) DTSBR305
|
|
00204 VALUE ALL '-'. DTSBR305
|
|
00205 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00206 10 FILLER PIC X(14) DTSBR305
|
|
00207 VALUE ALL '-'. DTSBR305
|
|
00208 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00209 10 FILLER PIC X(14) DTSBR305
|
|
00210 VALUE ALL '-'. DTSBR305
|
|
00211 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00212 10 FILLER PIC X(14) DTSBR305
|
|
00213 VALUE ALL '-'. DTSBR305
|
|
00214 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00215 10 FILLER PIC X(14) DTSBR305
|
|
00216 VALUE ALL '-'. DTSBR305
|
|
00217 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00218 10 FILLER PIC X(14) DTSBR305
|
|
00219 VALUE ALL '-'. DTSBR305
|
|
00220 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00221 10 FILLER PIC X(14) DTSBR305
|
|
00222 VALUE ALL '-'. DTSBR305
|
|
00223 SKIP2 DTSBR305
|
|
00224 01 DETAIL-LINE. DTSBR305
|
|
00225 05 DTL-LINE-1. DTSBR305
|
|
00226 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00227 10 WS-DTL-ACCT-SHORT-DSCR PIC X(10). DTSBR305
|
|
00228 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00229 10 WS-DTL-ACCT-IND PIC X(02). DTSBR305
|
|
00230 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00231 10 WS-DTL-CHARGED-AMT PIC -----,---,--9.99. DTSBR305
|
|
00232 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00233 10 WS-DTL-PAID-AMT PIC -----,---,--9.99. DTSBR305
|
|
00234 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00235 10 WS-DTL-WAIVED-AMT PIC -----,---,--9.99. DTSBR305
|
|
00236 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00237 10 WS-DTL-WRITTEN-OFF-AMT PIC -----,---,--9.99. DTSBR305
|
|
00238 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00239 10 WS-DTL-TOLER-AMT PIC -----,---,--9.99. DTSBR305
|
|
00240 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00241 10 WS-DTL-BALANCE-AMT PIC -----,---,--9.99. DTSBR305
|
|
00242 SKIP2 DTSBR305
|
|
00243 01 CONTROL-FOOTING. DTSBR305
|
|
00244 05 CTF-LINE-1. DTSBR305
|
|
00245 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00246 10 FILLER PIC X(10) DTSBR305
|
|
00247 VALUE ALL '-'. DTSBR305
|
|
00248 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00249 10 FILLER PIC X(02) DTSBR305
|
|
00250 VALUE ALL '-'. DTSBR305
|
|
00251 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00252 10 FILLER PIC X(14) DTSBR305
|
|
00253 VALUE ALL '-'. DTSBR305
|
|
00254 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00255 10 FILLER PIC X(14) DTSBR305
|
|
00256 VALUE ALL '-'. DTSBR305
|
|
00257 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00258 10 FILLER PIC X(14) DTSBR305
|
|
00259 VALUE ALL '-'. DTSBR305
|
|
00260 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00261 10 FILLER PIC X(14) DTSBR305
|
|
00262 VALUE ALL '-'. DTSBR305
|
|
00263 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00264 10 FILLER PIC X(14) DTSBR305
|
|
00265 VALUE ALL '-'. DTSBR305
|
|
00266 10 FILLER PIC X(05) VALUE SPACES. DTSBR305
|
|
00267 10 FILLER PIC X(14) DTSBR305
|
|
00268 VALUE ALL '-'. DTSBR305
|
|
00269 DTSBR305
|
|
00270 05 CTF-LINE-3. DTSBR305
|
|
00271 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00272 10 FILLER PIC X(05) DTSBR305
|
|
00273 VALUE 'TOTAL'. DTSBR305
|
|
00274 10 FILLER PIC X(13) VALUE SPACES. DTSBR305
|
|
00275 10 WS-CTF-CHARGED-AMT PIC -----,---,--9.99. DTSBR305
|
|
00276 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00277 10 WS-CTF-PAID-AMT PIC -----,---,--9.99. DTSBR305
|
|
00278 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00279 10 WS-CTF-WAIVED-AMT PIC -----,---,--9.99. DTSBR305
|
|
00280 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00281 10 WS-CTF-WRITTEN-OFF-AMT PIC -----,---,--9.99. DTSBR305
|
|
00282 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00283 10 WS-CTF-TOLER-AMT PIC -----,---,--9.99. DTSBR305
|
|
00284 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00285 10 WS-CTF-BALANCE-AMT PIC -----,---,--9.99. DTSBR305
|
|
00286 DTSBR305
|
|
00287 05 SUM-LINE-2. DTSBR305
|
|
00288 10 FILLER PIC X(01) VALUE SPACE. DTSBR305
|
|
00289 10 FILLER PIC X(05) DTSBR305
|
|
00290 VALUE 'TOTAL'. DTSBR305
|
|
00291 10 FILLER PIC X(13) VALUE SPACES. DTSBR305
|
|
00292 10 WS-CFF-CHARGED-AMT PIC -----,---,--9.99. DTSBR305
|
|
00293 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00294 10 WS-CFF-PAID-AMT PIC -----,---,--9.99. DTSBR305
|
|
00295 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00296 10 WS-CFF-WAIVED-AMT PIC -----,---,--9.99. DTSBR305
|
|
00297 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00298 10 WS-CFF-WRITTEN-OFF-AMT PIC -----,---,--9.99. DTSBR305
|
|
00299 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00300 10 WS-CFF-TOLER-AMT PIC -----,---,--9.99. DTSBR305
|
|
00301 10 FILLER PIC X(03) VALUE SPACES. DTSBR305
|
|
00302 10 WS-CFF-BALANCE-AMT PIC -----,---,--9.99. DTSBR305
|
|
00303 EJECT DTSBR305
|
|
00304 LINKAGE SECTION. DTSBR305
|
|
00305 SKIP3 DTSBR305
|
|
00306 01 LRCM-LINK-AREA. DTSBR305
|
|
00307 ++INCLUDE DTSILRCM DTSBR305
|
|
00308 EJECT DTSBR305
|
|
00309 01 R305-REC. DTSBR305
|
|
00310 ++INCLUDE DTSIR305 DTSBR305
|
|
00311 EJECT DTSBR305
|
|
00312 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR305
|
|
00313 R305-REC. DTSBR305
|
|
00314 SKIP2 DTSBR305
|
|
00315 IF FIRST-TIME-IND = 'Y' DTSBR305
|
|
00316 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR305
|
|
00317 MOVE 'N' TO FIRST-TIME-IND. DTSBR305
|
|
00318 SKIP1 DTSBR305
|
|
00319 IF LRCM-EOR-88 DTSBR305
|
|
00320 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR305
|
|
00321 ELSE DTSBR305
|
|
00322 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR305
|
|
00323 SKIP2 DTSBR305
|
|
00324 GOBACK. DTSBR305
|
|
00325 EJECT DTSBR305
|
|
00326 I1000-INITIATE. DTSBR305
|
|
00327 SKIP1 DTSBR305
|
|
00328 OPEN OUTPUT PRT-FILE. DTSBR305
|
|
00329 MOVE LRCM-SYS-DATE TO WS-SYS-DATE. DTSBR305
|
|
00330 MOVE LRCM-SYS-TIME TO WS-SYS-TIME. DTSBR305
|
|
00331 MOVE LRCM-AGY-NAME-LINE1 TO WS-AGY-NAME-LINE1. DTSBR305
|
|
00332 MOVE LRCM-AGY-NAME-LINE2 TO WS-AGY-NAME-LINE2. DTSBR305
|
|
00333 MOVE SPACES TO PRT-RECORD. DTSBR305
|
|
00334 DTSBR305
|
|
00335 MOVE SPACES TO WS-EMP-CLASS-HOLD. DTSBR305
|
|
00336 PERFORM DTSBR305
|
|
00337 VARYING WS-SUB FROM 1 BY 1 DTSBR305
|
|
00338 UNTIL WS-SUB > WS-TABLE-SIZE DTSBR305
|
|
00339 MOVE SPACES TO WS-ACCT-IND (WS-SUB) DTSBR305
|
|
00340 WS-ACCT-SHORT-DSCR (WS-SUB) DTSBR305
|
|
00341 MOVE ZEROES TO WS-ALL-CHARGED-AMT (WS-SUB) DTSBR305
|
|
00342 WS-ALL-PAID-AMT (WS-SUB) DTSBR305
|
|
00343 WS-ALL-WAIVED-AMT (WS-SUB) DTSBR305
|
|
00344 WS-ALL-WRITTEN-OFF-AMT (WS-SUB) DTSBR305
|
|
00345 WS-ALL-TOLER-AMT (WS-SUB) DTSBR305
|
|
00346 WS-ALL-BALANCE-AMT (WS-SUB) DTSBR305
|
|
00347 END-PERFORM. DTSBR305
|
|
00348 SKIP2 DTSBR305
|
|
00349 I1000-EXIT. DTSBR305
|
|
00350 EXIT. DTSBR305
|
|
00351 EJECT DTSBR305
|
|
00352 P1000-PROCESS. DTSBR305
|
|
00353 SKIP1 DTSBR305
|
|
00354 IF R305-EMP-CLASS NOT = WS-EMP-CLASS-HOLD DTSBR305
|
|
00355 MOVE R305-EMP-CLASS TO WS-EMP-CLASS-HOLD DTSBR305
|
|
00356 EVALUATE TRUE DTSBR305
|
|
00357 WHEN R305-CLASS-UNK-88 DTSBR305
|
|
00358 MOVE 'UNKNOWN ' TO WS-EMPLOYER-TYPE-DSCR DTSBR305
|
|
00359 WHEN R305-CLASS-RATED-88 DTSBR305
|
|
00360 MOVE 'RATED ' TO WS-EMPLOYER-TYPE-DSCR DTSBR305
|
|
00361 WHEN R305-CLASS-SELF-INS-88 DTSBR305
|
|
00362 MOVE 'SELF INSURED' TO WS-EMPLOYER-TYPE-DSCR DTSBR305
|
|
00363 END-EVALUATE. DTSBR305
|
|
00364 SKIP1 DTSBR305
|
|
00365 IF R305-ACCT-SUB > WS-TABLE-SIZE DTSBR305
|
|
00366 PERFORM S999-ABEND THRU S999-EXIT. DTSBR305
|
|
00367 MOVE R305-ACCT-SUB TO WS-SUB. DTSBR305
|
|
00368 SKIP1 DTSBR305
|
|
00369 IF WS-ACCT-IND (WS-SUB) = SPACES DTSBR305
|
|
00370 MOVE R305-ACCT-IND TO WS-ACCT-IND (WS-SUB) DTSBR305
|
|
00371 L032-CD-2 DTSBR305
|
|
00372 SET L032-MJRN-ACCT-ROW TO TRUE DTSBR305
|
|
00373 PERFORM S032-ACCT-DESCRIPTION THRU S032-EXIT DTSBR305
|
|
00374 MOVE L032-SHORT-DSCR TO WS-ACCT-SHORT-DSCR (WS-SUB) DTSBR305
|
|
00375 WS-DTL-ACCT-SHORT-DSCR. DTSBR305
|
|
00376 SKIP1 DTSBR305
|
|
00377 ADD R305-CHARGED-AMT TO WS-ALL-CHARGED-AMT (WS-SUB) DTSBR305
|
|
00378 WS-FOOT-CHARGED-AMT. DTSBR305
|
|
00379 ADD R305-PAID-AMT TO WS-ALL-PAID-AMT (WS-SUB) DTSBR305
|
|
00380 WS-FOOT-PAID-AMT. DTSBR305
|
|
00381 ADD R305-WAIVED-AMT TO WS-ALL-WAIVED-AMT (WS-SUB) DTSBR305
|
|
00382 WS-FOOT-WAIVED-AMT. DTSBR305
|
|
00383 ADD R305-WRITTEN-OFF-AMT TO WS-ALL-WRITTEN-OFF-AMT (WS-SUB) DTSBR305
|
|
00384 WS-FOOT-WRITTEN-OFF-AMT. DTSBR305
|
|
00385 ADD R305-TOLER-AMT TO WS-ALL-TOLER-AMT (WS-SUB) DTSBR305
|
|
00386 WS-FOOT-TOLER-AMT. DTSBR305
|
|
00387 ADD R305-BALANCE-AMT TO WS-ALL-BALANCE-AMT (WS-SUB) DTSBR305
|
|
00388 WS-FOOT-BALANCE-AMT. DTSBR305
|
|
00389 DTSBR305
|
|
00390 MOVE WS-ACCT-SHORT-DSCR (WS-SUB) TO WS-DTL-ACCT-SHORT-DSCR. DTSBR305
|
|
00391 MOVE WS-ACCT-IND (WS-SUB) TO WS-DTL-ACCT-IND. DTSBR305
|
|
00392 DTSBR305
|
|
00393 MOVE R305-CHARGED-AMT TO WS-DTL-CHARGED-AMT. DTSBR305
|
|
00394 MOVE R305-PAID-AMT TO WS-DTL-PAID-AMT. DTSBR305
|
|
00395 MOVE R305-WAIVED-AMT TO WS-DTL-WAIVED-AMT. DTSBR305
|
|
00396 MOVE R305-WRITTEN-OFF-AMT TO WS-DTL-WRITTEN-OFF-AMT. DTSBR305
|
|
00397 MOVE R305-TOLER-AMT TO WS-DTL-TOLER-AMT. DTSBR305
|
|
00398 MOVE R305-BALANCE-AMT TO WS-DTL-BALANCE-AMT. DTSBR305
|
|
00399 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR305
|
|
00400 WRITE PRT-RECORD FROM DTL-LINE-1 AFTER 1. DTSBR305
|
|
00401 ADD +1 TO WS-LINE-CNT2. DTSBR305
|
|
00402 DTSBR305
|
|
00403 IF R305-ACCT-SUB = +7 DTSBR305
|
|
00404 PERFORM P3000-PRINT-FOOTER THRU P3000-EXIT DTSBR305
|
|
00405 END-IF. DTSBR305
|
|
00406 DTSBR305
|
|
00407 SKIP2 DTSBR305
|
|
00408 P1000-EXIT. DTSBR305
|
|
00409 EXIT. DTSBR305
|
|
00410 EJECT DTSBR305
|
|
00411 DTSBR305
|
|
00412 P2000-PRINT-HEADER. DTSBR305
|
|
00413 IF WS-LINE-CNT GREATER 58 OR DTSBR305
|
|
00414 WS-LINE-CNT2 GREATER 58 DTSBR305
|
|
00415 MOVE +0 TO WS-LINE-CNT DTSBR305
|
|
00416 MOVE +0 TO WS-LINE-CNT2 DTSBR305
|
|
00417 ADD +1 TO WS-PAGE-CNT DTSBR305
|
|
00418 MOVE WS-PAGE-CNT TO HDR3-PAGE-CNT DTSBR305
|
|
00419 WRITE PRT-RECORD FROM HEADER-1 AFTER TOP-OF-PAGE DTSBR305
|
|
00420 WRITE PRT-RECORD FROM HEADER-2 AFTER 1 DTSBR305
|
|
00421 WRITE PRT-RECORD FROM HEADER-3 AFTER 1 DTSBR305
|
|
00422 WRITE PRT-RECORD FROM HEADER-4 AFTER 1 DTSBR305
|
|
00423 WRITE PRT-RECORD FROM HEADER-5 AFTER 1 DTSBR305
|
|
00424 WRITE PRT-RECORD FROM HEADER-6 AFTER 1 DTSBR305
|
|
00425 WRITE PRT-RECORD FROM HEADER-7 AFTER 1 DTSBR305
|
|
00426 WRITE PRT-RECORD FROM HEADER-8 AFTER 1 DTSBR305
|
|
00427 WRITE PRT-RECORD FROM HEADER-9 AFTER 1 DTSBR305
|
|
00428 WRITE PRT-RECORD FROM WS-BLANK-LINE AFTER 1 DTSBR305
|
|
00429 ADD +10 TO WS-LINE-CNT2. DTSBR305
|
|
00430 P2000-EXIT. DTSBR305
|
|
00431 EXIT. DTSBR305
|
|
00432 DTSBR305
|
|
00433 P3000-PRINT-FOOTER. DTSBR305
|
|
00434 IF WS-LINE-CNT2 > 52 DTSBR305
|
|
00435 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR305
|
|
00436 END-IF. DTSBR305
|
|
00437 DTSBR305
|
|
00438 MOVE WS-FOOT-CHARGED-AMT TO WS-CTF-CHARGED-AMT. DTSBR305
|
|
00439 MOVE WS-FOOT-PAID-AMT TO WS-CTF-PAID-AMT. DTSBR305
|
|
00440 MOVE WS-FOOT-WAIVED-AMT TO WS-CTF-WAIVED-AMT. DTSBR305
|
|
00441 MOVE WS-FOOT-WRITTEN-OFF-AMT TO WS-CTF-WRITTEN-OFF-AMT. DTSBR305
|
|
00442 MOVE WS-FOOT-TOLER-AMT TO WS-CTF-TOLER-AMT. DTSBR305
|
|
00443 MOVE WS-FOOT-BALANCE-AMT TO WS-CTF-BALANCE-AMT. DTSBR305
|
|
00444 DTSBR305
|
|
00445 ADD WS-FOOT-CHARGED-AMT TO WS-SUM-CHARGED-AMT. DTSBR305
|
|
00446 ADD WS-FOOT-PAID-AMT TO WS-SUM-PAID-AMT. DTSBR305
|
|
00447 ADD WS-FOOT-WAIVED-AMT TO WS-SUM-WAIVED-AMT. DTSBR305
|
|
00448 ADD WS-FOOT-WRITTEN-OFF-AMT TO WS-SUM-WRITTEN-OFF-AMT. DTSBR305
|
|
00449 ADD WS-FOOT-TOLER-AMT TO WS-SUM-TOLER-AMT. DTSBR305
|
|
00450 ADD WS-FOOT-BALANCE-AMT TO WS-SUM-BALANCE-AMT. DTSBR305
|
|
00451 DTSBR305
|
|
00452 WRITE PRT-RECORD FROM CTF-LINE-1 AFTER 1. DTSBR305
|
|
00453 WRITE PRT-RECORD FROM CTF-LINE-3 AFTER 2. DTSBR305
|
|
00454 DTSBR305
|
|
00455 ADD +60 TO WS-LINE-CNT2. DTSBR305
|
|
00456 MOVE +0 TO WS-FOOT-CHARGED-AMT. DTSBR305
|
|
00457 MOVE +0 TO WS-FOOT-PAID-AMT. DTSBR305
|
|
00458 MOVE +0 TO WS-FOOT-WAIVED-AMT. DTSBR305
|
|
00459 MOVE +0 TO WS-FOOT-WRITTEN-OFF-AMT. DTSBR305
|
|
00460 MOVE +0 TO WS-FOOT-TOLER-AMT. DTSBR305
|
|
00461 MOVE +0 TO WS-FOOT-BALANCE-AMT. DTSBR305
|
|
00462 DTSBR305
|
|
00463 P3000-EXIT. DTSBR305
|
|
00464 EXIT. DTSBR305
|
|
00465 DTSBR305
|
|
00466 T1000-TERMINATE. DTSBR305
|
|
00467 SKIP1 DTSBR305
|
|
00468 MOVE 'ALL' TO WS-EMPLOYER-TYPE-DSCR. DTSBR305
|
|
00469 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR305
|
|
00470 PERFORM DTSBR305
|
|
00471 VARYING WS-SUB FROM 1 BY 1 DTSBR305
|
|
00472 UNTIL WS-SUB > WS-TABLE-SIZE DTSBR305
|
|
00473 DTSBR305
|
|
00474 MOVE WS-ACCT-SHORT-DSCR (WS-SUB) TO WS-DTL-ACCT-SHORT-DSCRDTSBR305
|
|
00475 MOVE WS-ACCT-IND (WS-SUB) TO WS-DTL-ACCT-IND DTSBR305
|
|
00476 DTSBR305
|
|
00477 MOVE WS-ALL-CHARGED-AMT (WS-SUB) TO WS-DTL-CHARGED-AMT DTSBR305
|
|
00478 MOVE WS-ALL-PAID-AMT (WS-SUB) TO WS-DTL-PAID-AMT DTSBR305
|
|
00479 MOVE WS-ALL-WAIVED-AMT (WS-SUB) TO WS-DTL-WAIVED-AMT DTSBR305
|
|
00480 MOVE WS-ALL-WRITTEN-OFF-AMT (WS-SUB) TO DTSBR305
|
|
00481 WS-DTL-WRITTEN-OFF-AMT DTSBR305
|
|
00482 MOVE WS-ALL-TOLER-AMT (WS-SUB) TO WS-DTL-TOLER-AMT DTSBR305
|
|
00483 MOVE WS-ALL-BALANCE-AMT (WS-SUB) TO WS-DTL-BALANCE-AMT DTSBR305
|
|
00484 WRITE PRT-RECORD FROM DTL-LINE-1 AFTER 1 DTSBR305
|
|
00485 END-PERFORM. DTSBR305
|
|
00486 MOVE WS-SUM-CHARGED-AMT TO WS-CFF-CHARGED-AMT. DTSBR305
|
|
00487 MOVE WS-SUM-PAID-AMT TO WS-CFF-PAID-AMT. DTSBR305
|
|
00488 MOVE WS-SUM-WAIVED-AMT TO WS-CFF-WAIVED-AMT. DTSBR305
|
|
00489 MOVE WS-SUM-WRITTEN-OFF-AMT TO WS-CFF-WRITTEN-OFF-AMT. DTSBR305
|
|
00490 MOVE WS-SUM-TOLER-AMT TO WS-CFF-TOLER-AMT. DTSBR305
|
|
00491 MOVE WS-SUM-BALANCE-AMT TO WS-CFF-BALANCE-AMT. DTSBR305
|
|
00492 DTSBR305
|
|
00493 WRITE PRT-RECORD FROM CTF-LINE-1 AFTER 1. DTSBR305
|
|
00494 WRITE PRT-RECORD FROM SUM-LINE-2 AFTER 2. DTSBR305
|
|
00495 DTSBR305
|
|
00496 CLOSE PRT-FILE. DTSBR305
|
|
00497 SKIP2 DTSBR305
|
|
00498 T1000-EXIT. DTSBR305
|
|
00499 EXIT. DTSBR305
|
|
00500 EJECT DTSBR305
|
|
00501 S032-ACCT-DESCRIPTION. DTSBR305
|
|
00502 SKIP1 DTSBR305
|
|
00503 CALL 'DTSBU032' USING L032-LINK-AREA. DTSBR305
|
|
00504 SKIP2 DTSBR305
|
|
00505 S032-EXIT. DTSBR305
|
|
00506 EXIT. DTSBR305
|
|
00507 SKIP3 DTSBR305
|
|
00508 S999-ABEND. DTSBR305
|
|
00509 SKIP1 DTSBR305
|
|
00510 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR305
|
|
00511 SKIP2 DTSBR305
|
|
00512 S999-EXIT. DTSBR305
|
|
00513 EXIT. DTSBR305
|
|
00514 DTSBR305
|