340 lines
26 KiB
COBOL
340 lines
26 KiB
COBOL
00001 IDENTIFICATION DIVISION. 08/13/98
|
|
00002 PROGRAM-ID. DTSCS90. DTSCS90
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV002
|
|
00004 DATE-WRITTEN. NOVEMBER 1991. DTSCS90
|
|
00005 DATE-COMPILED. DTSCS90
|
|
00006 SKIP3 DTSCS90
|
|
00007 ***** DTSCS90
|
|
00008 * DTSCS90
|
|
00009 * FUNCTION: SYSTEM ADMINISTRATION MENU SCREEN PROCESSOR. DTSCS90
|
|
00010 * DTSCS90
|
|
00011 * DTSCS90
|
|
00012 * MODIFICATION LOG: DTSCS90
|
|
00013 * DTSCS90
|
|
00014 * 11/06/91 INITIAL DEVELOPMENT. DTSCS90
|
|
00015 * WORK ORDER: PROGRAMMER: TCL DTSCS90
|
|
00016 * DTSCS90
|
|
00017 * 04/11/94 MODIFIED FOR MONTANA. DTSCS90
|
|
00018 * WORK ORDER: PROGRAMMER: RHC DTSCS90
|
|
00019 * DTSCS90
|
|
00020 * 08/13/1998 REVIEWED AND MODIFIED FOR DC. DTSCS90
|
|
00021 * REFERENCE: DC DEVELOPMENT PROGRAMMER: EHH DTSCS90
|
|
00022 * DTSCS90
|
|
00023 * MM/DD/YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSCS90
|
|
00024 * REFERENCE: XXXXXXXXXXXXXXX PROGRAMMER: XXX DTSCS90
|
|
00025 * DTSCS90
|
|
00026 * DTSCS90
|
|
00027 * DESCRIPTION: DTSCS90
|
|
00028 * DTSCS90
|
|
00029 * IF SCREEN '90' NOT CURRENTLY DISPLAYED DTSCS90
|
|
00030 * SEND SCREEN 90 (WITH PMSG-KEY-OPTION MESSAGE) DTSCS90
|
|
00031 * RETURN TO DRIVER. DTSCS90
|
|
00032 * DTSCS90
|
|
00033 * RECEIVE SCREEN '90'. DTSCS90
|
|
00034 * DTSCS90
|
|
00035 * IF CLEAR KEY PRESSED DTSCS90
|
|
00036 * SEND SCREEN 90 (WITH PMSG-KEY-OPTION MESSAGE) DTSCS90
|
|
00037 * SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00038 * RETURN TO DRIVER. DTSCS90
|
|
00039 * DTSCS90
|
|
00040 * IF PA2 KEY PRESSED DTSCS90
|
|
00041 * SEND SCREEN 90 (DATA ONLY) DTSCS90
|
|
00042 * SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00043 * RETURN TO DRIVER. DTSCS90
|
|
00044 * DTSCS90
|
|
00045 * IF F3 KEY PRESSED DTSCS90
|
|
00046 * MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID DTSCS90
|
|
00047 * SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS90
|
|
00048 * RETURN TO DRIVER. DTSCS90
|
|
00049 * DTSCS90
|
|
00050 * IF F4 KEY PRESSED DTSCS90
|
|
00051 * MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID DTSCS90
|
|
00052 * SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS90
|
|
00053 * RETURN TO DRIVER. DTSCS90
|
|
00054 * DTSCS90
|
|
00055 * IF NOT ENTER KEY PRESSED DTSCS90
|
|
00056 * BUILD INVALID KEY MESSAGE (VIA LINK TO DTSCU804) DTSCS90
|
|
00057 * SEND SCREEN 90 (WITH THE INVALID KEY PRESSED MESSAGE) DTSCS90
|
|
00058 * SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00059 * RETURN TO DRIVER. DTSCS90
|
|
00060 * DTSCS90
|
|
00061 * DTSCS90
|
|
00062 * IF MAP-OPT = SPACES OR LOW-VALUES OR '90' DTSCS90
|
|
00063 * SEND SCREEN 00 (WITH THE PMSG-KEY-OPTION MESSAGE) DTSCS90
|
|
00064 * SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00065 * RETURN TO DRIVER. DTSCS90
|
|
00066 * DTSCS90
|
|
00067 * CONVERT MAP-OPT INTO A SCREEN IDENTIFIER, PLACING THE DTSCS90
|
|
00068 * RESULT IN LCCM-REQ-SCR-ID. DTSCS90
|
|
00069 * DTSCS90
|
|
00070 * EDIT LCCM-REQ-SCR-ID FOR VALIDITY (VIA A CALL TO DTSIU803). DTSCS90
|
|
00071 * DTSCS90
|
|
00072 * IF LCCM-REQ-SCR-ID VALID (LCCM-NO-MSG) DTSCS90
|
|
00073 * SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS90
|
|
00074 * RETURN TO DRIVER DTSCS90
|
|
00075 * ELSE DTSCS90
|
|
00076 * SEND SCREEN 90 (WITH ERROR MESSAGE) DTSCS90
|
|
00077 * SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00078 * RETURN TO DRIVER. DTSCS90
|
|
00079 * DTSCS90
|
|
00080 * DTSCS90
|
|
00081 ***** DTSCS90
|
|
00082 SKIP3 DTSCS90
|
|
00083 ENVIRONMENT DIVISION. DTSCS90
|
|
00084 SKIP3 DTSCS90
|
|
00085 DATA DIVISION. DTSCS90
|
|
00086 SKIP3 DTSCS90
|
|
00087 WORKING-STORAGE SECTION. DTSCS90
|
|
000875 77 PAN-VALET PICTURE X(24) VALUE '002DTSCS90 08/13/98'. DTSCS90
|
|
00088 SKIP3 DTSCS90
|
|
00089 01 WRK-AREA. DTSCS90
|
|
00090 05 WRK-ABEND-CD PIC X(04) VALUE 'S90 '. DTSCS90
|
|
00091 05 WRK-RESP-CD PIC S9(08) COMP. DTSCS90
|
|
00092 DTSCS90
|
|
00093 05 WRK-SCR-ID PIC X(02) VALUE '90'. DTSCS90
|
|
00094 05 WRK-F03-SCR-ID PIC X(02) VALUE '00'. DTSCS90
|
|
00095 DTSCS90
|
|
00096 05 RESP-IND PIC X(01). DTSCS90
|
|
00097 88 RESP-CURSOR-TO-OPT-88 VALUE 'C'. DTSCS90
|
|
00098 88 RESP-MSGONLY-88 VALUE 'M'. DTSCS90
|
|
00099 88 RESP-SCREEN-88 VALUE 'S'. DTSCS90
|
|
00100 88 RESP-JUMP-88 VALUE 'J'. DTSCS90
|
|
00101 DTSCS90
|
|
00102 05 CURSOR-IND PIC X(01). DTSCS90
|
|
00103 88 CURSOR-SET-88 VALUE 'Y'. DTSCS90
|
|
00104 DTSCS90
|
|
00105 05 WRK-DATE-AREA. DTSCS90
|
|
00106 10 WRK-DATE PIC X(08). DTSCS90
|
|
00107 10 FILLER PIC X(01) VALUE '.'. DTSCS90
|
|
00108 EJECT DTSCS90
|
|
00109 01 L851-COMM-AREA. DTSCS90
|
|
00110 ++INCLUDE DTSIL851 DTSCS90
|
|
00111 SKIP3 DTSCS90
|
|
00112 05 MAP-AREA REDEFINES L851-MAP-AREA. DTSCS90
|
|
00113 ++INCLUDE DTSISSM DTSCS90
|
|
00114 EJECT DTSCS90
|
|
00115 01 L805-COMM-AREA. DTSCS90
|
|
00116 ++INCLUDE DTSIL805 DTSCS90
|
|
00117 EJECT DTSCS90
|
|
00118 01 CATB-LITERALS. DTSCS90
|
|
00119 ++INCLUDE DTSICATB DTSCS90
|
|
00120 SKIP3 DTSCS90
|
|
00121 01 EMSG-LITERALS. DTSCS90
|
|
00122 ++INCLUDE DTSICECD DTSCS90
|
|
00123 SKIP3 DTSCS90
|
|
00124 01 PMSG-LITERALS. DTSCS90
|
|
00125 ++INCLUDE DTSICPCD DTSCS90
|
|
00126 EJECT DTSCS90
|
|
00127 LINKAGE SECTION. DTSCS90
|
|
00128 SKIP3 DTSCS90
|
|
00129 01 DFHCOMMAREA. DTSCS90
|
|
00130 ++INCLUDE DTSILCCM DTSCS90
|
|
00131 EJECT DTSCS90
|
|
00132 PROCEDURE DIVISION. DTSCS90
|
|
00133 SKIP2 DTSCS90
|
|
00134 MOVE LOW-VALUES TO MAP-AREA. DTSCS90
|
|
00135 DTSCS90
|
|
00136 MOVE 'N' TO CURSOR-IND. DTSCS90
|
|
00137 SKIP2 DTSCS90
|
|
00138 MOVE SPACE TO RESP-IND. DTSCS90
|
|
00139 PERFORM P1000-ANALYZE-REQUEST THRU P1000-EXIT. DTSCS90
|
|
00140 SKIP2 DTSCS90
|
|
00141 IF RESP-MSGONLY-88 DTSCS90
|
|
00142 MOVE LOW-VALUES TO MAP-AREA DTSCS90
|
|
00143 PERFORM S805-MSG-AREA THRU S805-EXIT DTSCS90
|
|
00144 PERFORM S2200-SEND-DATAONLY THRU S2200-EXIT DTSCS90
|
|
00145 SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00146 ELSE DTSCS90
|
|
00147 IF RESP-SCREEN-88 DTSCS90
|
|
00148 PERFORM P2000-CONSTRUCT-S-AREA THRU P2000-EXIT DTSCS90
|
|
00149 PERFORM S2100-SEND THRU S2100-EXIT DTSCS90
|
|
00150 SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00151 ELSE DTSCS90
|
|
00152 IF RESP-JUMP-88 DTSCS90
|
|
00153 SET LCCM-LINK-SCREEN-88 TO TRUE DTSCS90
|
|
00154 ELSE DTSCS90
|
|
00155 IF RESP-CURSOR-TO-OPT-88 DTSCS90
|
|
00156 MOVE LOW-VALUES TO MAP-AREA DTSCS90
|
|
00157 MOVE CATB-CURSOR TO MAP-OPT-L DTSCS90
|
|
00158 SET CURSOR-SET-88 TO TRUE DTSCS90
|
|
00159 PERFORM S2200-SEND-DATAONLY THRU S2200-EXIT DTSCS90
|
|
00160 SET LCCM-END-TASK-88 TO TRUE DTSCS90
|
|
00161 ELSE DTSCS90
|
|
00162 PERFORM S899-ABEND THRU S899-EXIT. DTSCS90
|
|
00163 SKIP2 DTSCS90
|
|
00164 EXEC CICS DTSCS90
|
|
00165 RETURN DTSCS90
|
|
00166 END-EXEC. DTSCS90
|
|
00167 SKIP2 DTSCS90
|
|
00168 GOBACK. DTSCS90
|
|
00169 EJECT DTSCS90
|
|
00170 P1000-ANALYZE-REQUEST. DTSCS90
|
|
00171 IF LCCM-SCR-ID NOT = WRK-SCR-ID DTSCS90
|
|
00172 MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA DTSCS90
|
|
00173 SET RESP-SCREEN-88 TO TRUE DTSCS90
|
|
00174 GO TO P1000-EXIT. DTSCS90
|
|
00175 DTSCS90
|
|
00176 PERFORM S1100-RECEIVE THRU S1100-EXIT. DTSCS90
|
|
00177 DTSCS90
|
|
00178 IF LCCM-CLEAR-88 OR LCCM-F12-88 DTSCS90
|
|
00179 MOVE LOW-VALUES TO MAP-AREA CL**2
|
|
00180 MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA DTSCS90
|
|
00181 SET RESP-SCREEN-88 TO TRUE DTSCS90
|
|
00182 GO TO P1000-EXIT. DTSCS90
|
|
00183 DTSCS90
|
|
00184 IF LCCM-PA2-88 DTSCS90
|
|
00185 SET RESP-CURSOR-TO-OPT-88 TO TRUE DTSCS90
|
|
00186 GO TO P1000-EXIT. DTSCS90
|
|
00187 DTSCS90
|
|
00188 IF LCCM-ENTER-88 OR LCCM-F03-88 OR LCCM-F04-88 OR LCCM-F14-88DTSCS90
|
|
00189 NEXT SENTENCE DTSCS90
|
|
00190 ELSE DTSCS90
|
|
00191 PERFORM S804-INVALID-KEY THRU S804-EXIT DTSCS90
|
|
00192 SET RESP-MSGONLY-88 TO TRUE DTSCS90
|
|
00193 GO TO P1000-EXIT. DTSCS90
|
|
00194 DTSCS90
|
|
00195 IF LCCM-F03-88 DTSCS90
|
|
00196 MOVE WRK-F03-SCR-ID TO LCCM-REQ-SCR-ID DTSCS90
|
|
00197 SET RESP-JUMP-88 TO TRUE DTSCS90
|
|
00198 GO TO P1000-EXIT. DTSCS90
|
|
00199 DTSCS90
|
|
00200 IF LCCM-F04-88 DTSCS90
|
|
00201 MOVE LCCM-PRIOR-SCR-ID TO LCCM-REQ-SCR-ID DTSCS90
|
|
00202 SET RESP-JUMP-88 TO TRUE DTSCS90
|
|
00203 GO TO P1000-EXIT. DTSCS90
|
|
00204 DTSCS90
|
|
00205 IF LCCM-F14-88 DTSCS90
|
|
00206 MOVE LCCM-CORR-SCR-ID TO LCCM-REQ-SCR-ID DTSCS90
|
|
00207 PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT DTSCS90
|
|
00208 IF LCCM-MSG DTSCS90
|
|
00209 SET RESP-SCREEN-88 TO TRUE DTSCS90
|
|
00210 GO TO P1000-EXIT DTSCS90
|
|
00211 ELSE DTSCS90
|
|
00212 SET RESP-JUMP-88 TO TRUE DTSCS90
|
|
00213 GO TO P1000-EXIT. DTSCS90
|
|
00214 DTSCS90
|
|
00215 IF MAP-OPT = SPACES OR LOW-VALUES OR WRK-SCR-ID DTSCS90
|
|
00216 MOVE PMSG-KEY-OPTION TO LCCM-MSG-AREA DTSCS90
|
|
00217 SET RESP-SCREEN-88 TO TRUE DTSCS90
|
|
00218 GO TO P1000-EXIT. DTSCS90
|
|
00219 DTSCS90
|
|
00220 IF MAP-OPT = '1 ' OR ' 1' DTSCS90
|
|
00221 MOVE '91' TO LCCM-REQ-SCR-ID DTSCS90
|
|
00222 ELSE DTSCS90
|
|
00223 IF MAP-OPT = '2 ' OR ' 2' DTSCS90
|
|
00224 MOVE '92' TO LCCM-REQ-SCR-ID DTSCS90
|
|
00225 ELSE DTSCS90
|
|
00226 IF MAP-OPT = '8 ' OR ' 8' DTSCS90
|
|
00227 MOVE '98' TO LCCM-REQ-SCR-ID DTSCS90
|
|
00228 ELSE DTSCS90
|
|
00229 IF MAP-OPT = '9 ' OR ' 9' DTSCS90
|
|
00230 MOVE '99' TO LCCM-REQ-SCR-ID DTSCS90
|
|
00231 ELSE DTSCS90
|
|
00232 MOVE MAP-OPT TO LCCM-REQ-SCR-ID. DTSCS90
|
|
00233 DTSCS90
|
|
00234 PERFORM S803-REQ-SCR-ID-EDIT THRU S803-EXIT. DTSCS90
|
|
00235 IF LCCM-MSG DTSCS90
|
|
00236 SET RESP-SCREEN-88 TO TRUE DTSCS90
|
|
00237 ELSE DTSCS90
|
|
00238 SET RESP-JUMP-88 TO TRUE. DTSCS90
|
|
00239 P1000-EXIT. DTSCS90
|
|
00240 EXIT. DTSCS90
|
|
00241 EJECT DTSCS90
|
|
00242 P2000-CONSTRUCT-S-AREA. DTSCS90
|
|
00243 MOVE LCCM-TASK-START-DISP-DATE TO MAP-SYS-DATE. DTSCS90
|
|
00244 MOVE LCCM-TASK-START-DISP-TIME TO MAP-SYS-TIME. DTSCS90
|
|
00245 MOVE LCCM-CICS-REGION-NAME TO MAP-CICS-REGION-NAME. DTSCS90
|
|
00246 DTSCS90
|
|
00247 PERFORM S805-MSG-AREA THRU S805-EXIT. DTSCS90
|
|
00248 P2000-EXIT. DTSCS90
|
|
00249 EXIT. DTSCS90
|
|
00250 EJECT DTSCS90
|
|
00251 S803-REQ-SCR-ID-EDIT. DTSCS90
|
|
00252 DTSCS90
|
|
00253 EXEC CICS DTSCS90
|
|
00254 LINK DTSCS90
|
|
00255 PROGRAM ('DTSCU803') DTSCS90
|
|
00256 COMMAREA (DFHCOMMAREA) DTSCS90
|
|
00257 END-EXEC. DTSCS90
|
|
00258 DTSCS90
|
|
00259 S803-EXIT. DTSCS90
|
|
00260 EXIT. DTSCS90
|
|
00261 SKIP3 DTSCS90
|
|
00262 S804-INVALID-KEY. DTSCS90
|
|
00263 DTSCS90
|
|
00264 EXEC CICS DTSCS90
|
|
00265 LINK DTSCS90
|
|
00266 PROGRAM ('DTSCU804') DTSCS90
|
|
00267 COMMAREA (DFHCOMMAREA) DTSCS90
|
|
00268 END-EXEC. DTSCS90
|
|
00269 DTSCS90
|
|
00270 S804-EXIT. DTSCS90
|
|
00271 EXIT. DTSCS90
|
|
00272 SKIP3 DTSCS90
|
|
00273 S805-MSG-AREA. DTSCS90
|
|
00274 MOVE LCCM-MSG-AREA TO L805-MSG-AREA. DTSCS90
|
|
00275 DTSCS90
|
|
00276 EXEC CICS DTSCS90
|
|
00277 LINK DTSCS90
|
|
00278 PROGRAM ('DTSCU805') DTSCS90
|
|
00279 COMMAREA (L805-COMM-AREA) DTSCS90
|
|
00280 END-EXEC. DTSCS90
|
|
00281 DTSCS90
|
|
00282 MOVE L805-S-MSG-AREA TO MAP-MSG-AREA. DTSCS90
|
|
00283 S805-EXIT. DTSCS90
|
|
00284 EXIT. DTSCS90
|
|
00285 SKIP3 DTSCS90
|
|
00286 S851-SCREEN-PROCESSING. DTSCS90
|
|
00287 EXEC CICS DTSCS90
|
|
00288 LINK DTSCS90
|
|
00289 PROGRAM ('DTSCU851') DTSCS90
|
|
00290 COMMAREA (L851-COMM-AREA) DTSCS90
|
|
00291 END-EXEC. DTSCS90
|
|
00292 S851-EXIT. DTSCS90
|
|
00293 EXIT. DTSCS90
|
|
00294 SKIP3 DTSCS90
|
|
00295 S899-ABEND. DTSCS90
|
|
00296 DTSCS90
|
|
00297 EXEC CICS DTSCS90
|
|
00298 ABEND DTSCS90
|
|
00299 ABCODE (WRK-ABEND-CD) DTSCS90
|
|
00300 END-EXEC. DTSCS90
|
|
00301 DTSCS90
|
|
00302 S899-EXIT. DTSCS90
|
|
00303 EXIT. DTSCS90
|
|
00304 EJECT DTSCS90
|
|
00305 S1100-RECEIVE. DTSCS90
|
|
00306 SET L851-RECEIVE-88 TO TRUE. DTSCS90
|
|
00307 MOVE WRK-SCR-ID TO L851-SCR-ID. DTSCS90
|
|
00308 PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT. DTSCS90
|
|
00309 MOVE L851-AID TO LCCM-AID. DTSCS90
|
|
00310 MOVE L851-CURSOR TO LCCM-CURSOR. DTSCS90
|
|
00311 S1100-EXIT. DTSCS90
|
|
00312 EXIT. DTSCS90
|
|
00313 SKIP3 DTSCS90
|
|
00314 S2100-SEND. DTSCS90
|
|
00315 SET L851-SEND-88 TO TRUE. DTSCS90
|
|
00316 PERFORM S2900-PREPARE-SEND THRU S2900-EXIT. DTSCS90
|
|
00317 PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT. DTSCS90
|
|
00318 S2100-EXIT. DTSCS90
|
|
00319 EXIT. DTSCS90
|
|
00320 SKIP3 DTSCS90
|
|
00321 S2200-SEND-DATAONLY. DTSCS90
|
|
00322 SET L851-SEND-DATAONLY-88 TO TRUE. DTSCS90
|
|
00323 PERFORM S2900-PREPARE-SEND THRU S2900-EXIT. DTSCS90
|
|
00324 PERFORM S851-SCREEN-PROCESSING THRU S851-EXIT. DTSCS90
|
|
00325 S2200-EXIT. DTSCS90
|
|
00326 EXIT. DTSCS90
|
|
00327 SKIP3 DTSCS90
|
|
00328 S2900-PREPARE-SEND. DTSCS90
|
|
00329 MOVE WRK-SCR-ID TO L851-SCR-ID DTSCS90
|
|
00330 LCCM-SCR-ID. DTSCS90
|
|
00331 MOVE LCCM-OP-ALARM-IND TO L851-ALARM-IND. DTSCS90
|
|
00332 MOVE LCCM-MSG-TYPE TO L851-MSG-TYPE. DTSCS90
|
|
00333 IF CURSOR-SET-88 DTSCS90
|
|
00334 NEXT SENTENCE DTSCS90
|
|
00335 ELSE DTSCS90
|
|
00336 MOVE CATB-CURSOR TO MAP-OPT-L. DTSCS90
|
|
00337 S2900-EXIT. DTSCS90
|
|
00338 EXIT. DTSCS90
|