548 lines
43 KiB
COBOL
548 lines
43 KiB
COBOL
00001 IDENTIFICATION DIVISION. 05/07/20
|
|
00002 PROGRAM-ID. CHGBD220. CHGBD220
|
|
00003 *AUTHOR. TRW. LV004
|
|
00004 *DATE-WRITTEN. JUNE 2001. CHGBD220
|
|
00005 DATE-COMPILED. CHGBD220
|
|
00006 SKIP3 CHGBD220
|
|
00007 ***** CHGBD220
|
|
00008 * CHGBD220
|
|
00009 * FUNCTION: CHGBD220
|
|
00010 * CHGBD220
|
|
00011 * 1. VERIFY THAT THERE IS A TAX MASTER FILE RECORD FOR CHGBD220
|
|
00012 * EVERY EMPLOYER CHARGED FOR BENEFITS. CHGBD220
|
|
00013 * CHGBD220
|
|
00014 * 2. VERIFY THAT THE EMPLOYER STATUS IS VALID CHGBD220
|
|
00015 * (I.E., LIABLE OR CHARGE-ONLY). CHGBD220
|
|
00016 * CHGBD220
|
|
00017 * 3. FIND EMPLOYER MAILING ADDRESS CHGBD220
|
|
00018 * CHGBD220
|
|
00019 * 4. WRITE A MAILING LABEL FOR EACH SELF-INSURED, CHGBD220
|
|
00020 * CWC AND FEDERAL EMPLOYER. CHGBD220
|
|
00021 * CHGBD220
|
|
00022 * WRITE AN OUTPUT RECORD (TO BE INPUT TO THE PRINT PROCESS)CHGBD220
|
|
00023 * FOR EACH EACH VALID INPUT RECORD. CHGBD220
|
|
00024 * CHGBD220
|
|
00025 * INPUT: CHGBD220
|
|
00026 * CHGBD220
|
|
00027 * BD200CHG - CHARGE REPORT RECORDS GENERATED BY CHGBD220
|
|
00028 * CHGBD200. CHGBD220
|
|
00029 * CHGPARM - PARAMETER DATA INPUT FROM CHGBD305 CHGBD220
|
|
00030 * CHGBD220
|
|
00031 * OUTPUT: CHGBD220
|
|
00032 * BD210CHG - CHARGE REPORT RECORDS GENERATED BY CHGBD220
|
|
00033 * CHGBD220. CHGBD220
|
|
00034 * CHGBD220
|
|
00035 ***** CHGBD220
|
|
00036 CHGBD220
|
|
00037 ******************************************************************CHGBD220
|
|
00038 * MODIFICATION HISTORY: *CHGBD220
|
|
00039 * *CHGBD220
|
|
00040 * 02-02-1999 INITIAL DEVELOPMENT *CHGBD220
|
|
00041 * REFERENCE RFP # AUTHOR OF CHANGE - GD *CHGBD220
|
|
00042 * *CHGBD220
|
|
00043 * 04-23-2002 MODIFIED TO OUTPUT TEUC RPC150R1 REPORT *CHGBD220
|
|
00044 * REFERENCE RFP # AUTHOR OF CHANGE - RW1 *CHGBD220
|
|
00045 * *CHGBD220
|
|
00046 * 04-02-2007 MODIFIED TO OUTPUT LABELS WHEN REQUESTING CWC AND *CHGBD220
|
|
00047 * FED REPORTS *CHGBD220
|
|
00048 * REFERENCE RFP # AUTHOR OF CHANGE - RW1 *CHGBD220
|
|
00049 * *CHGBD220
|
|
00050 * 01-03-2008 RECOMPILED FOR NEW VERSION OF CHGIM004. *CHGBD220
|
|
00051 * REFERENCE RFP # AUTHOR OF CHANGE - GD *CHGBD220
|
|
00052 * *CHGBD220
|
|
00053 * 03-03-2009 RECOMPILED FOR NEW VERSION OF CHGIM004 (PROGRAM *CHGBD220
|
|
00054 * CODE UPDATES) *CHGBD220
|
|
00055 * REFERENCE RFP # AUTHOR OF CHANGE - GD *CHGBD220
|
|
00056 * *CHGBD220
|
|
00057 * 05-14-2010 RECOMPILED FOR NEW VERSION OF CHGIM004 (PROGRAM *CHGBD220
|
|
00058 * CODE UPDATES) *CHGBD220
|
|
00059 * REFERENCE RFP # AUTHOR OF CHANGE - ZL1 *CHGBD220
|
|
00060 * * CL**2
|
|
00061 * 10-04-2014 RECOMPILED FOR NEW VERSION OF CHGIM004 (PROGRAM * CL**2
|
|
00062 * CODE UPDATES) * CL**2
|
|
00063 * REFERENCE RFP # UCPIA AUTHOR OF CHANGE - ZL1 * CL**2
|
|
00064 * * CL**4
|
|
00065 * 05-04-2020 RECOMPILED FOR NEW VERSION OF CHGIM004 (PROGRAM * CL**4
|
|
00066 * CODE UPDATES) PEUC, PUA, FRUR, FPUC * CL**4
|
|
00067 * REFERENCE RFP # AUTHOR OF CHANGE - ZL1 * CL**4
|
|
00068 * *CHGBD220
|
|
00069 * MM-DD-YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *CHGBD220
|
|
00070 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX *CHGBD220
|
|
00071 * REFERENCE RFP #**** AUTHOR OF CHANGE - *** *CHGBD220
|
|
00072 ******************************************************************CHGBD220
|
|
00073 CHGBD220
|
|
00074 SKIP3 CHGBD220
|
|
00075 ENVIRONMENT DIVISION. CHGBD220
|
|
00076 SKIP3 CHGBD220
|
|
00077 INPUT-OUTPUT SECTION. CHGBD220
|
|
00078 SKIP3 CHGBD220
|
|
00079 FILE-CONTROL. CHGBD220
|
|
00080 SELECT CHG-FILE-IN ASSIGN TO BD210CHG CHGBD220
|
|
00081 FILE STATUS IS CHG-IN-STATUS. CHGBD220
|
|
00082 CHGBD220
|
|
00083 SELECT CHG-FILE-OUT ASSIGN TO BD220CHG CHGBD220
|
|
00084 FILE STATUS IS CHG-OUT-STATUS. CHGBD220
|
|
00085 CHGBD220
|
|
00086 SELECT CHG-PARM-FILE ASSIGN TO CHGPARM CHGBD220
|
|
00087 FILE STATUS IS CHG-PARM-STATUS. CHGBD220
|
|
00088 EJECT CHGBD220
|
|
00089 DATA DIVISION. CHGBD220
|
|
00090 FILE SECTION. CHGBD220
|
|
00091 FD CHG-FILE-IN CHGBD220
|
|
00092 RECORDING MODE IS F CHGBD220
|
|
00093 LABEL RECORDS ARE STANDARD CHGBD220
|
|
00094 BLOCK CONTAINS 0 CHARACTERS. CHGBD220
|
|
00095 SKIP1 CHGBD220
|
|
00096 01 CHG-REC-IN. CHGBD220
|
|
00097 ++INCLUDE CHGIM004 CHGBD220
|
|
00098 CHGBD220
|
|
00099 FD CHG-FILE-OUT CHGBD220
|
|
00100 RECORDING MODE IS F CHGBD220
|
|
00101 LABEL RECORDS ARE STANDARD CHGBD220
|
|
00102 BLOCK CONTAINS 0 CHARACTERS. CHGBD220
|
|
00103 SKIP1 CHGBD220
|
|
00104 01 CHG-REC-OUT PIC X(388). CHGBD220
|
|
00105 CHGBD220
|
|
00106 FD CHG-PARM-FILE CHGBD220
|
|
00107 RECORDING MODE IS F CHGBD220
|
|
00108 BLOCK CONTAINS 0 CHARACTERS. CHGBD220
|
|
00109 SKIP1 CHGBD220
|
|
00110 01 CHG-PARM-REC. CHGBD220
|
|
00111 ++INCLUDE CHGIM003 CHGBD220
|
|
00112 CHGBD220
|
|
00113 EJECT CHGBD220
|
|
00114 WORKING-STORAGE SECTION. CHGBD220
|
|
001145 77 PAN-VALET PICTURE X(24) VALUE '004CHGBD220 05/07/20'. CHGBD220
|
|
00115 77 PAN-VALET PICTURE X(24) VALUE '021CHGBD220 05/25/10'. CHGBD220
|
|
00116 CHGBD220
|
|
00117 01 WRK-AREA. CHGBD220
|
|
00118 *& CHGBD220
|
|
00119 05 WRK-ZERO-CHG-CNT PIC 9(07) COMP-3 VALUE 0. CHGBD220
|
|
00120 05 WRK-TOT-CHG PIC S9(09)V99 COMP-3 VALUE +0. CHGBD220
|
|
00121 05 WRK-TOT-CHG-DISP PIC Z(08)9.99-. CHGBD220
|
|
00122 05 WRK-EMP-CHG PIC S9(09)V99 COMP-3 VALUE +0. CHGBD220
|
|
00123 05 WRK-DISP-AREA. CHGBD220
|
|
00124 10 WRK-EMP-DISP PIC 9(06). CHGBD220
|
|
00125 10 FILLER PIC X(02) VALUE SPACES. CHGBD220
|
|
00126 10 WRK-SSN-DISP PIC 9(09). CHGBD220
|
|
00127 10 FILLER PIC X(02) VALUE SPACES. CHGBD220
|
|
00128 10 WRK-CHG-DISP PIC Z9(08)9.99-. CHGBD220
|
|
00129 *& CHGBD220
|
|
00130 05 WRK-CHG-IN-CNT PIC 9(08) COMP-3 VALUE 0. CHGBD220
|
|
00131 05 WRK-CHG-OUT-CNT PIC 9(08) COMP-3 VALUE 0. CHGBD220
|
|
00132 05 WRK-CHG-SUM-CNT PIC 9(08) COMP-3 VALUE 0. CHGBD220
|
|
00133 05 WRK-LABEL-CNT PIC 9(08) COMP-3 VALUE 0. CHGBD220
|
|
00134 05 ABEND-CODE PIC S9(04) COMP CHGBD220
|
|
00135 VALUE +220. CHGBD220
|
|
00136 05 ABEND-MOD PIC X(08) CHGBD220
|
|
00137 VALUE 'DTSBU999'. CHGBD220
|
|
00138 05 ABEND-MSG PIC X(60). CHGBD220
|
|
00139 CHGBD220
|
|
00140 05 CHG-IN-STATUS PIC X(02) VALUE SPACES. CHGBD220
|
|
00141 88 CHG-IN-OK-88 VALUE ZERO. CHGBD220
|
|
00142 88 CHG-IN-EOF-88 VALUE '10'. CHGBD220
|
|
00143 CHGBD220
|
|
00144 05 CHG-OUT-STATUS PIC X(02) VALUE SPACES. CHGBD220
|
|
00145 88 CHG-OUT-OK-88 VALUE ZERO. CHGBD220
|
|
00146 CHGBD220
|
|
00147 05 CHG-PARM-STATUS PIC X(02) VALUE SPACES. CHGBD220
|
|
00148 88 CHG-PARM-FILE-OK-88 VALUE ZERO. CHGBD220
|
|
00149 88 CHG-PARM-FILE-EOF-88 VALUE '10'. CHGBD220
|
|
00150 CHGBD220
|
|
00151 05 WRK-ERROR-IND PIC X(01). CHGBD220
|
|
00152 88 WRK-ERROR-YES-88 VALUE 'Y'. CHGBD220
|
|
00153 88 WRK-ERROR-NO-88 VALUE 'N'. CHGBD220
|
|
00154 CHGBD220
|
|
00155 05 WRK-LAST-LABEL-EMP PIC S9(07) COMP-3 CHGBD220
|
|
00156 VALUE ZERO. CHGBD220
|
|
00157 CHGBD220
|
|
00158 05 WRK-L030-SSN PIC 9(10). CHGBD220
|
|
00159 05 FILLER REDEFINES WRK-L030-SSN. CHGBD220
|
|
00160 10 WRK-L030-SSN-9 PIC 9(09). CHGBD220
|
|
00161 10 WRK-L030-SSN-SEQ PIC 9(01). CHGBD220
|
|
00162 CHGBD220
|
|
00163 05 WRK-CURR-RPT-TYPE PIC X(01) VALUE SPACE. CHGBD220
|
|
00164 88 WRK-CURR-RPT-RATED-88 VALUE '1'. CHGBD220
|
|
00165 88 WRK-CURR-RPT-SELF-INS-88 VALUE '2'. CHGBD220
|
|
00166 88 WRK-CURR-RPT-CWC-88 VALUE '3'. CHGBD220
|
|
00167 88 WRK-CURR-RPT-FED-88 VALUE '4'. CHGBD220
|
|
00168 CHGBD220
|
|
00169 05 WRK-LABEL-ROUTE-AREA. CHGBD220
|
|
00170 10 WRK-LABEL-ROUTE-STARS PIC X(40) VALUE CHGBD220
|
|
00171 ALL '*'. CHGBD220
|
|
00172 10 WRK-LABEL-ROUTE-SELF-INS PIC X(40) VALUE CHGBD220
|
|
00173 ' SELF-INSURED '. CHGBD220
|
|
00174 10 WRK-LABEL-ROUTE-CWC PIC X(40) VALUE CHGBD220
|
|
00175 ' CWC '. CHGBD220
|
|
00176 10 WRK-LABEL-ROUTE-FED PIC X(40) VALUE CHGBD220
|
|
00177 ' FEDERAL '. CHGBD220
|
|
00178 01 DISPLAY-PARM-REC. CHGBD220
|
|
00179 05 DISPLAY-RUN-TYPE PIC X(03). CHGBD220
|
|
00180 05 FILLER PIC X(01). CHGBD220
|
|
00181 05 DISPLAY-BEGIN-DATE PIC 9(06). CHGBD220
|
|
00182 05 FILLER PIC X(01). CHGBD220
|
|
00183 05 DISPLAY-END-DATE PIC 9(06). CHGBD220
|
|
00184 05 FILLER PIC X(01). CHGBD220
|
|
00185 05 DISPLAY-REPORT-TYPES. CHGBD220
|
|
00186 10 DISPLAY-RPT-TYPE-RATED PIC X(01). CHGBD220
|
|
00187 10 DISPLAY-RPT-TYPE-SELF-IND PIC X(01). CHGBD220
|
|
00188 10 DISPLAY-RPT-TYPE-CWC PIC X(01). CHGBD220
|
|
00189 10 DISPLAY-RPT-TYPE-FED PIC X(01). CHGBD220
|
|
00190 10 DISPLAY-RPT-TYPE-TEUC PIC X(01). CHGBD220
|
|
00191 10 DISPLAY-RPT-TYPE-FPUC PIC X(01). CL**3
|
|
00192 05 FILLER PIC X(01). CHGBD220
|
|
00193 05 DISPLAY-EMP-NO PIC 9(06). CHGBD220
|
|
00194 05 FILLER PIC X(49). CL**3
|
|
00195 CHGBD220
|
|
00196 01 WRK-CHG-REC. CHGBD220
|
|
00197 ++INCLUDE CHGIM004 CHGBD220
|
|
00198 CHGBD220
|
|
00199 ** REPORT I-O SKELETAL RECORD CHGBD220
|
|
00200 01 RSKL-REC. CHGBD220
|
|
00201 ++INCLUDE DTSIRSK1 CHGBD220
|
|
00202 ** MAILING LABEL RECORD CHGBD220
|
|
00203 01 R901-REC. CHGBD220
|
|
00204 ++INCLUDE DTSIR901 CHGBD220
|
|
00205 CHGBD220
|
|
00206 01 CG-L030-LINK-AREA. CHGBD220
|
|
00207 ++INCLUDE CHGIL030 CHGBD220
|
|
00208 CHGBD220
|
|
00209 PROCEDURE DIVISION. CHGBD220
|
|
00210 SKIP2 CHGBD220
|
|
00211 CHGBD220-MAIN. CHGBD220
|
|
00212 PERFORM I0000-INITIATE THRU I0000-EXIT. CHGBD220
|
|
00213 IF WRK-ERROR-YES-88 CHGBD220
|
|
00214 GO TO CHGBD220-EXIT. CHGBD220
|
|
00215 CHGBD220
|
|
00216 PERFORM P0000-PROCESS THRU P0000-EXIT. CHGBD220
|
|
00217 PERFORM T0000-TERMINATE THRU T0000-EXIT. CHGBD220
|
|
00218 CHGBD220
|
|
00219 CHGBD220-EXIT. CHGBD220
|
|
00220 STOP RUN. CHGBD220
|
|
00221 EJECT CHGBD220
|
|
00222 I0000-INITIATE. CHGBD220
|
|
00223 CHGBD220
|
|
00224 MOVE ZERO TO WRK-CHG-IN-CNT CHGBD220
|
|
00225 WRK-CHG-OUT-CNT CHGBD220
|
|
00226 WRK-LABEL-CNT CHGBD220
|
|
00227 WRK-CHG-SUM-CNT. CHGBD220
|
|
00228 CHGBD220
|
|
00229 SET WRK-ERROR-NO-88 TO TRUE. CHGBD220
|
|
00230 CHGBD220
|
|
00231 MOVE LENGTH OF R901-REC TO R901-LENGTH. CHGBD220
|
|
00232 CHGBD220
|
|
00233 PERFORM I2000-OPEN-FILES THRU I2000-EXIT. CHGBD220
|
|
00234 CHGBD220
|
|
00235 I0000-EXIT. CHGBD220
|
|
00236 EXIT. CHGBD220
|
|
00237 CHGBD220
|
|
00238 I2000-OPEN-FILES. CHGBD220
|
|
00239 OPEN INPUT CHG-FILE-IN. CHGBD220
|
|
00240 IF NOT CHG-IN-OK-88 CHGBD220
|
|
00241 DISPLAY 'INPUT FILE OPEN ERROR: ' CHG-IN-STATUS CHGBD220
|
|
00242 PERFORM S999-ABEND THRU S999-EXIT. CHGBD220
|
|
00243 CHGBD220
|
|
00244 OPEN OUTPUT CHG-FILE-OUT. CHGBD220
|
|
00245 IF NOT CHG-OUT-OK-88 CHGBD220
|
|
00246 DISPLAY 'OUTPUT FILE OPEN ERROR: ' CHG-OUT-STATUS CHGBD220
|
|
00247 PERFORM S999-ABEND THRU S999-EXIT. CHGBD220
|
|
00248 CHGBD220
|
|
00249 OPEN INPUT CHG-PARM-FILE. CHGBD220
|
|
00250 IF NOT CHG-PARM-FILE-OK-88 CHGBD220
|
|
00251 DISPLAY 'CHARGE PARM FILE OPEN ERROR: ' CHGBD220
|
|
00252 CHG-PARM-STATUS CHGBD220
|
|
00253 PERFORM S999-ABEND THRU S999-EXIT. CHGBD220
|
|
00254 CHGBD220
|
|
00255 READ CHG-PARM-FILE. CHGBD220
|
|
00256 IF NOT CHG-PARM-FILE-OK-88 CHGBD220
|
|
00257 DISPLAY 'CHARGE PARM FILE READ ERROR: ' CHGBD220
|
|
00258 CHG-PARM-STATUS CHGBD220
|
|
00259 PERFORM S999-ABEND THRU S999-EXIT. CHGBD220
|
|
00260 CHGBD220
|
|
00261 DISPLAY '***** CHGBD220 PARM RECORD *****'. CHGBD220
|
|
00262 MOVE CHG3-RUN-TYPE TO DISPLAY-RUN-TYPE. CHGBD220
|
|
00263 MOVE CHG3-BEGIN-DATE TO DISPLAY-BEGIN-DATE. CHGBD220
|
|
00264 MOVE CHG3-END-DATE TO DISPLAY-END-DATE. CHGBD220
|
|
00265 MOVE CHG3-RPT-TYPES TO DISPLAY-REPORT-TYPES. CHGBD220
|
|
00266 MOVE CHG3-EMP-NO TO DISPLAY-EMP-NO. CHGBD220
|
|
00267 DISPLAY DISPLAY-PARM-REC. CHGBD220
|
|
00268 DISPLAY SPACE. CHGBD220
|
|
00269 CHGBD220
|
|
00270 SET CG-L030-CMND-INIT-88 TO TRUE. CHGBD220
|
|
00271 PERFORM S030-TOT-CHARGE THRU S030-EXIT. CHGBD220
|
|
00272 CHGBD220
|
|
00273 I2000-EXIT. CHGBD220
|
|
00274 EXIT. CHGBD220
|
|
00275 CHGBD220
|
|
00276 P0000-PROCESS. CHGBD220
|
|
00277 PERFORM S1000-READ-BD210 THRU S1000-EXIT. CHGBD220
|
|
00278 IF NOT CHG-IN-OK-88 CHGBD220
|
|
00279 DISPLAY 'BD210 FILE EMPTY: ' CHG-IN-STATUS CHGBD220
|
|
00280 SET WRK-ERROR-YES-88 TO TRUE CHGBD220
|
|
00281 GO TO P0000-EXIT. CHGBD220
|
|
00282 CHGBD220
|
|
00283 ADD 1 TO WRK-CHG-IN-CNT. CHGBD220
|
|
00284 MOVE CHG-REC-IN TO WRK-CHG-REC. CHGBD220
|
|
00285 CHGBD220
|
|
00286 PERFORM P1000-PROCESS-CHARGES THRU P1000-EXIT CHGBD220
|
|
00287 UNTIL CHG-IN-EOF-88 CHGBD220
|
|
00288 OR WRK-ERROR-YES-88. CHGBD220
|
|
00289 CHGBD220
|
|
00290 P0000-EXIT. CHGBD220
|
|
00291 EXIT. CHGBD220
|
|
00292 CHGBD220
|
|
00293 P1000-PROCESS-CHARGES. CHGBD220
|
|
00294 PERFORM S1000-READ-BD210 THRU S1000-EXIT. CHGBD220
|
|
00295 IF CHG-IN-EOF-88 CHGBD220
|
|
00296 PERFORM P1200-WRITE-CHARGES THRU P1200-EXIT CHGBD220
|
|
00297 GO TO P1000-EXIT CHGBD220
|
|
00298 ELSE CHGBD220
|
|
00299 IF NOT CHG-IN-OK-88 CHGBD220
|
|
00300 DISPLAY 'BD210 FILE READ ERROR: ' CHG-IN-STATUS CHGBD220
|
|
00301 SET WRK-ERROR-YES-88 TO TRUE CHGBD220
|
|
00302 SET CHG-IN-EOF-88 TO TRUE CHGBD220
|
|
00303 GO TO P1000-EXIT CHGBD220
|
|
00304 END-IF CHGBD220
|
|
00305 END-IF. CHGBD220
|
|
00306 CHGBD220
|
|
00307 ADD 1 TO WRK-CHG-IN-CNT. CHGBD220
|
|
00308 CHGBD220
|
|
00309 IF CHG4-SORT-KEY-AREA OF CHG-REC-IN = CHGBD220
|
|
00310 CHG4-SORT-KEY-AREA OF WRK-CHG-REC CHGBD220
|
|
00311 PERFORM P1100-SUM-CHARGES THRU P1100-EXIT CHGBD220
|
|
00312 ELSE CHGBD220
|
|
00313 PERFORM P1200-WRITE-CHARGES THRU P1200-EXIT CHGBD220
|
|
00314 MOVE CHG-REC-IN TO WRK-CHG-REC CHGBD220
|
|
00315 END-IF. CHGBD220
|
|
00316 CHGBD220
|
|
00317 P1000-EXIT. CHGBD220
|
|
00318 EXIT. CHGBD220
|
|
00319 CHGBD220
|
|
00320 P1100-SUM-CHARGES. CHGBD220
|
|
00321 ADD 1 TO WRK-CHG-SUM-CNT. CHGBD220
|
|
00322 CHGBD220
|
|
00323 ADD CHG4-CURR-BEN-AMT OF CHG-REC-IN CHGBD220
|
|
00324 TO CHG4-CURR-BEN-AMT OF WRK-CHG-REC. CHGBD220
|
|
00325 CHGBD220
|
|
00326 ADD CHG4-CURR-ADJ-AMT OF CHG-REC-IN CHGBD220
|
|
00327 TO CHG4-CURR-ADJ-AMT OF WRK-CHG-REC. CHGBD220
|
|
00328 CHGBD220
|
|
00329 ADD CHG4-TOT-BEN-AMT OF CHG-REC-IN CHGBD220
|
|
00330 TO CHG4-TOT-BEN-AMT OF WRK-CHG-REC. CHGBD220
|
|
00331 CHGBD220
|
|
00332 ADD CHG4-TOT-ADJ-AMT OF CHG-REC-IN CHGBD220
|
|
00333 TO CHG4-TOT-ADJ-AMT OF WRK-CHG-REC. CHGBD220
|
|
00334 CHGBD220
|
|
00335 ADD CHG4-OP-RECOVER-AMT OF CHG-REC-IN CHGBD220
|
|
00336 TO CHG4-OP-RECOVER-AMT OF WRK-CHG-REC. CHGBD220
|
|
00337 CHGBD220
|
|
00338 P1100-EXIT. CHGBD220
|
|
00339 EXIT. CHGBD220
|
|
00340 CHGBD220
|
|
00341 P1200-WRITE-CHARGES. CHGBD220
|
|
00342 COMPUTE WRK-EMP-CHG = CHGBD220
|
|
00343 + CHG4-CURR-BEN-AMT OF WRK-CHG-REC CHGBD220
|
|
00344 + CHG4-CURR-ADJ-AMT OF WRK-CHG-REC. CHGBD220
|
|
00345 CHGBD220
|
|
00346 IF WRK-EMP-CHG = ZERO CHGBD220
|
|
00347 ADD +1 TO WRK-ZERO-CHG-CNT CHGBD220
|
|
00348 IF CHG4-RPT-TYPE-NULL-88 OF WRK-CHG-REC CHGBD220
|
|
00349 PERFORM S1100-WRITE-BD220 THRU S1100-EXIT CHGBD220
|
|
00350 END-IF CHGBD220
|
|
00351 ELSE CHGBD220
|
|
00352 PERFORM P1210-TOT-CHG THRU P1210-EXIT CHGBD220
|
|
00353 PERFORM S1100-WRITE-BD220 THRU S1100-EXIT CHGBD220
|
|
00354 IF CHG4-EMP-NO OF WRK-CHG-REC NOT = CHGBD220
|
|
00355 WRK-LAST-LABEL-EMP CHGBD220
|
|
00356 PERFORM P3000-MAILING-LABEL THRU P3000-EXIT CHGBD220
|
|
00357 END-IF CHGBD220
|
|
00358 END-IF. CHGBD220
|
|
00359 CHGBD220
|
|
00360 P1200-EXIT. CHGBD220
|
|
00361 EXIT. CHGBD220
|
|
00362 CHGBD220
|
|
00363 P1210-TOT-CHG. CHGBD220
|
|
00364 MOVE CHG4-SSN OF WRK-CHG-REC TO CG-L030-SSN. CHGBD220
|
|
00365 MOVE CHG3-BEGIN-DATE TO CG-L030-START-DATE. CHGBD220
|
|
00366 MOVE CHG3-END-DATE TO CG-L030-END-DATE. CHGBD220
|
|
00367 MOVE CHG4-BYE OF WRK-CHG-REC TO CG-L030-BYE. CHGBD220
|
|
00368 MOVE CHG4-PROGRAM OF WRK-CHG-REC TO CG-L030-PROGRAM. CHGBD220
|
|
00369 *& CHGBD220
|
|
00370 * DISPLAY 'INP ' CG-L030-SSN CHGBD220
|
|
00371 * ' ' CG-L030-START-DATE CHGBD220
|
|
00372 * ' ' CG-L030-END-DATE CHGBD220
|
|
00373 * ' ' CG-L030-BYE CHGBD220
|
|
00374 * ' ' CG-L030-PROGRAM. CHGBD220
|
|
00375 *& CHGBD220
|
|
00376 CHGBD220
|
|
00377 SET CG-L030-CMND-PROCESS-88 TO TRUE. CHGBD220
|
|
00378 PERFORM S030-TOT-CHARGE THRU S030-EXIT. CHGBD220
|
|
00379 CHGBD220
|
|
00380 MOVE CG-L030-TOT-CHG TO CHG4-TOT-BEN-AMT CHGBD220
|
|
00381 OF WRK-CHG-REC. CHGBD220
|
|
00382 MOVE ZERO TO CHG4-TOT-ADJ-AMT CHGBD220
|
|
00383 OF WRK-CHG-REC. CHGBD220
|
|
00384 *& CHGBD220
|
|
00385 * MOVE CHG4-TOT-BEN-AMT OF WRK-CHG-REC CHGBD220
|
|
00386 * TO WRK-TOT-CHG-DISP. CHGBD220
|
|
00387 * DISPLAY 'TOT CHG ' WRK-TOT-CHG-DISP CHGBD220
|
|
00388 * ' ' CHG4-EMP-NO OF WRK-CHG-REC CHGBD220
|
|
00389 * ' ' CHG4-SSN OF WRK-CHG-REC. CHGBD220
|
|
00390 *& CHGBD220
|
|
00391 CHGBD220
|
|
00392 P1210-EXIT. CHGBD220
|
|
00393 EXIT. CHGBD220
|
|
00394 CHGBD220
|
|
00395 P3000-MAILING-LABEL. CHGBD220
|
|
00396 IF CHG3-RUN-TYPE-QTRLY-88 OR CHGBD220
|
|
00397 CHG3-RUN-TYPE-RPTS-88 CHGBD220
|
|
00398 NEXT SENTENCE CHGBD220
|
|
00399 ELSE CHGBD220
|
|
00400 GO TO P3000-EXIT. CHGBD220
|
|
00401 CHGBD220
|
|
00402 IF CHG4-RPT-TYPE-SELF-INS-88 OF WRK-CHG-REC CHGBD220
|
|
00403 OR CHG4-RPT-TYPE-CWC-88 OF WRK-CHG-REC CHGBD220
|
|
00404 OR CHG4-RPT-TYPE-FED-88 OF WRK-CHG-REC CHGBD220
|
|
00405 NEXT SENTENCE CHGBD220
|
|
00406 ELSE CHGBD220
|
|
00407 GO TO P3000-EXIT. CHGBD220
|
|
00408 CHGBD220
|
|
00409 IF CHG4-REPORT-TYPE OF WRK-CHG-REC NOT = WRK-CURR-RPT-TYPE CHGBD220
|
|
00410 MOVE CHG4-REPORT-TYPE OF WRK-CHG-REC TO CHGBD220
|
|
00411 WRK-CURR-RPT-TYPE CHGBD220
|
|
00412 PERFORM P3100-SEPARATOR-LABEL THRU P3100-EXIT. CHGBD220
|
|
00413 CHGBD220
|
|
00414 PERFORM P3200-PRINT-LABEL THRU P3200-EXIT. CHGBD220
|
|
00415 CHGBD220
|
|
00416 P3000-EXIT. CHGBD220
|
|
00417 EXIT. CHGBD220
|
|
00418 CHGBD220
|
|
00419 P3100-SEPARATOR-LABEL. CHGBD220
|
|
00420 SET R901-ON-REQUEST-88 TO TRUE. CHGBD220
|
|
00421 MOVE LOW-VALUE TO R901-SORT-VAR-AREA. CHGBD220
|
|
00422 MOVE SPACES TO R901-FMT-ADDR CHGBD220
|
|
00423 R901-ZIP CHGBD220
|
|
00424 R901-ADVANCED-BARCODE. CHGBD220
|
|
00425 CHGBD220
|
|
00426 IF WRK-CURR-RPT-SELF-INS-88 CHGBD220
|
|
00427 MOVE WRK-LABEL-ROUTE-SELF-INS TO R901-FMT-LINE (2) CHGBD220
|
|
00428 ELSE CHGBD220
|
|
00429 IF WRK-CURR-RPT-CWC-88 CHGBD220
|
|
00430 MOVE WRK-LABEL-ROUTE-CWC TO R901-FMT-LINE (2) CHGBD220
|
|
00431 ELSE CHGBD220
|
|
00432 IF WRK-CURR-RPT-FED-88 CHGBD220
|
|
00433 MOVE WRK-LABEL-ROUTE-FED TO R901-FMT-LINE (2) CHGBD220
|
|
00434 ELSE CHGBD220
|
|
00435 GO TO P3100-EXIT. CHGBD220
|
|
00436 CHGBD220
|
|
00437 MOVE WRK-CURR-RPT-TYPE TO R901-GRP1-OP-ID. CHGBD220
|
|
00438 MOVE 000000 TO R901-EMP-NO. CHGBD220
|
|
00439 MOVE +1 TO R901-LABEL-CNT. CHGBD220
|
|
00440 MOVE WRK-LABEL-ROUTE-STARS TO R901-FMT-LINE (1) CHGBD220
|
|
00441 R901-FMT-LINE (3). CHGBD220
|
|
00442 CHGBD220
|
|
00443 MOVE R901-REC TO RSKL-REC. CHGBD220
|
|
00444 PERFORM S946-RPT-REC-O THRU S946-EXIT. CHGBD220
|
|
00445 CHGBD220
|
|
00446 P3100-EXIT. CHGBD220
|
|
00447 EXIT. CHGBD220
|
|
00448 CHGBD220
|
|
00449 P3200-PRINT-LABEL. CHGBD220
|
|
00450 SET R901-ON-REQUEST-88 TO TRUE. CHGBD220
|
|
00451 MOVE LOW-VALUE TO R901-SORT-VAR-AREA. CHGBD220
|
|
00452 CHGBD220
|
|
00453 MOVE CHG4-REPORT-TYPE OF WRK-CHG-REC CHGBD220
|
|
00454 TO R901-GRP1-OP-ID. CHGBD220
|
|
00455 MOVE CHG4-EMP-NO OF WRK-CHG-REC CHGBD220
|
|
00456 TO R901-EMP-NO CHGBD220
|
|
00457 WRK-LAST-LABEL-EMP. CHGBD220
|
|
00458 MOVE +1 TO R901-LABEL-CNT. CHGBD220
|
|
00459 CHGBD220
|
|
00460 MOVE CHG4-FMT-ADDR OF WRK-CHG-REC TO R901-FMT-ADDR. CHGBD220
|
|
00461 MOVE CHG4-ZIP OF WRK-CHG-REC TO R901-ZIP. CHGBD220
|
|
00462 MOVE CHG4-ADVANCED-BARCODE OF WRK-CHG-REC TO CHGBD220
|
|
00463 R901-ADVANCED-BARCODE. CHGBD220
|
|
00464 CHGBD220
|
|
00465 MOVE R901-REC TO RSKL-REC. CHGBD220
|
|
00466 PERFORM S946-RPT-REC-O THRU S946-EXIT. CHGBD220
|
|
00467 CHGBD220
|
|
00468 ADD +1 TO WRK-LABEL-CNT. CHGBD220
|
|
00469 CHGBD220
|
|
00470 P3200-EXIT. CHGBD220
|
|
00471 EXIT. CHGBD220
|
|
00472 CHGBD220
|
|
00473 S1000-READ-BD210. CHGBD220
|
|
00474 READ CHG-FILE-IN. CHGBD220
|
|
00475 CHGBD220
|
|
00476 S1000-EXIT. CHGBD220
|
|
00477 EXIT. CHGBD220
|
|
00478 CHGBD220
|
|
00479 S1100-WRITE-BD220. CHGBD220
|
|
00480 COMPUTE WRK-TOT-CHG = WRK-TOT-CHG CHGBD220
|
|
00481 + CHG4-CURR-BEN-AMT OF WRK-CHG-REC CHGBD220
|
|
00482 + CHG4-CURR-ADJ-AMT OF WRK-CHG-REC. CHGBD220
|
|
00483 CHGBD220
|
|
00484 WRITE CHG-REC-OUT FROM WRK-CHG-REC. CHGBD220
|
|
00485 IF CHG-OUT-OK-88 CHGBD220
|
|
00486 ADD 1 TO WRK-CHG-OUT-CNT. CHGBD220
|
|
00487 CHGBD220
|
|
00488 S1100-EXIT. CHGBD220
|
|
00489 EXIT. CHGBD220
|
|
00490 CHGBD220
|
|
00491 S030-TOT-CHARGE. CHGBD220
|
|
00492 CALL 'CHGBD235' USING CG-L030-LINK-AREA. CHGBD220
|
|
00493 S030-EXIT. EXIT. CHGBD220
|
|
00494 CHGBD220
|
|
00495 ** REPORT RECORD I-O CHGBD220
|
|
00496 S946-RPT-REC-O. CHGBD220
|
|
00497 CALL 'DTSBU946' USING RSKL-REC. CHGBD220
|
|
00498 CHGBD220
|
|
00499 S946-EXIT. CHGBD220
|
|
00500 EXIT. CHGBD220
|
|
00501 CHGBD220
|
|
00502 T0000-TERMINATE. CHGBD220
|
|
00503 CLOSE CHG-FILE-IN CHGBD220
|
|
00504 CHG-FILE-OUT CHGBD220
|
|
00505 CHG-PARM-FILE. CHGBD220
|
|
00506 CHGBD220
|
|
00507 SET CG-L030-CMND-TERM-88 TO TRUE. CHGBD220
|
|
00508 PERFORM S030-TOT-CHARGE THRU S030-EXIT. CHGBD220
|
|
00509 CHGBD220
|
|
00510 DISPLAY '***********************************************'. CHGBD220
|
|
00511 DISPLAY '*** CHGBD220 COUNTS *** '. CHGBD220
|
|
00512 DISPLAY '***'. CHGBD220
|
|
00513 CHGBD220
|
|
00514 DISPLAY ' INPUT CHARGE RECORDS READ : ' CHGBD220
|
|
00515 WRK-CHG-IN-CNT. CHGBD220
|
|
00516 CHGBD220
|
|
00517 DISPLAY ' OUTPUT CHARGE RECORDS WRITTEN: ' CHGBD220
|
|
00518 WRK-CHG-OUT-CNT. CHGBD220
|
|
00519 CHGBD220
|
|
00520 DISPLAY ' CHARGE RECORDS COMBINED : ' CHGBD220
|
|
00521 WRK-CHG-SUM-CNT. CHGBD220
|
|
00522 CHGBD220
|
|
00523 DISPLAY ' TOTAL CHARGE = ZERO BYPASSED : ' CHGBD220
|
|
00524 WRK-ZERO-CHG-CNT. CHGBD220
|
|
00525 CHGBD220
|
|
00526 DISPLAY ' MAILING LABELS WRITTEN : ' CHGBD220
|
|
00527 WRK-LABEL-CNT. CHGBD220
|
|
00528 CHGBD220
|
|
00529 MOVE WRK-TOT-CHG TO WRK-TOT-CHG-DISP. CHGBD220
|
|
00530 DISPLAY ' TOTAL CHARGES : ' CHGBD220
|
|
00531 WRK-TOT-CHG-DISP. CHGBD220
|
|
00532 CHGBD220
|
|
00533 DISPLAY '***********************************************'. CHGBD220
|
|
00534 CHGBD220
|
|
00535 T0000-EXIT. CHGBD220
|
|
00536 EXIT. CHGBD220
|
|
00537 EJECT CHGBD220
|
|
00538 CHGBD220
|
|
00539 S999-ABEND. CHGBD220
|
|
00540 DISPLAY '**** CHGBD220 ABENDING ' CHGBD220
|
|
00541 ABEND-MSG. CHGBD220
|
|
00542 CALL ABEND-MOD USING ABEND-CODE. CHGBD220
|
|
00543 CHGBD220
|
|
00544 S999-EXIT. CHGBD220
|
|
00545 EXIT. CHGBD220
|
|
00546 CHGBD220
|