748 lines
59 KiB
COBOL
748 lines
59 KiB
COBOL
00001 IDENTIFICATION DIVISION. 04/26/16
|
|
00002 PROGRAM-ID. DTSBD321. DTSBD321
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV002
|
|
00004 DATE-WRITTEN. SEPTEMBER 1994. DTSBD321
|
|
00005 DATE-COMPILED. DTSBD321
|
|
00006 SKIP3 DTSBD321
|
|
00007 ***** DTSBD321
|
|
00008 * DTSBD321
|
|
00009 * FUNCTION: LIEN PACKAGE. DTSBD321
|
|
00010 * DTSBD321
|
|
00011 * DTSBD321
|
|
00012 * MODIFICATION LOG: DTSBD321
|
|
00013 * DTSBD321
|
|
00014 * 09/29/94 INITIAL DEVELOPMENT. DTSBD321
|
|
00015 * WORK ORDER: PROGRAMMER: RHC DTSBD321
|
|
00016 * DTSBD321
|
|
00017 * 05/05/94 WRITE EVENT LOG RECORD WHEN A LIEN PACKAGE IS DTSBD321
|
|
00018 * PRINTED. DTSBD321
|
|
00019 * WORK ORDER: TPR021 PROGRAMMER: RHC DTSBD321
|
|
00020 * DTSBD321
|
|
00021 * 01/29/1999 REVIEWED AND MODIFIED FOR DC. DTSBD321
|
|
00022 * REFERENCE: DC DEVELOPMENT PROGRAMMER: EHH DTSBD321
|
|
00023 * DTSBD321
|
|
00024 * 10/25/2000 MODIFIED TO INCLUDE RESPONSIBLE OPID IN R403 DTSBD321
|
|
00025 RECORD. DTSBD321
|
|
00026 * REFERENCE: DC DEVELOPMENT PROGRAMMER: ZL1 DTSBD321
|
|
00027 * DTSBD321
|
|
00028 * 08/01/2006 PENALTY AND INTEREST CALCULATIONS MODIFIED DTSBD321
|
|
00029 * TO EXCLUDE SUR-TAX: P3100. DTSBD321
|
|
00030 * REFERENCE: ADMIN ASSESS PROGRAMMER: GD DTSBD321
|
|
00031 * DTSBD321
|
|
00032 * 08/14/2006 MODIFIED P3100: ADD SUR-TAX BALANCE TO TAX DTSBD321
|
|
00033 * BALANCE FOR DISPLAY ON LIEN FORM. DTSBD321
|
|
00034 * REFERENCE: ADMIN ASSESS PROGRAMMER: GD DTSBD321
|
|
00035 * DTSBD321
|
|
00036 * 01/31/2008 MODIFIED ADMINISTRATIVE ASSESSMENT PROCESS DTSBD321
|
|
00037 * TO INCLUDE PENALTY AND INTEREST CALCULATION DTSBD321
|
|
00038 * STARTING WITH 2008/1. DTSBD321
|
|
00039 * REFERENCE: ADMIN ASSESS PROGRAMMER: RW1 DTSBD321
|
|
00040 * DTSBD321
|
|
00041 * 03/26/2008 ADDED SUR TAX FIELD TO DTSIR403 RECORD FORMAT DTSBD321
|
|
00042 * TO PRINT THE SUR TAX ON THE LIEN FORMS. DTSBD321
|
|
00043 * REFERENCE: ADMIN ASSESS PROGRAMMER: ZL1 DTSBD321
|
|
00044 * DTSBD321
|
|
00045 * MM/DD/YYYY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBD321
|
|
00046 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBD321
|
|
00047 * REFERENCE: XXXXXXXXXXXXXXX PROGRAMMER: XXX DTSBD321
|
|
00048 * DTSBD321
|
|
00049 * DTSBD321
|
|
00050 * DESCRIPTION: DTSBD321
|
|
00051 * DTSBD321
|
|
00052 * READ THE MLIN RECORD INDICATED BY T011-ESTB-ABSTIME. DTSBD321
|
|
00053 * IF MLIN RECORD INDICATED BY T011-ESTB-ABSTIME DOES NOT DTSBD321
|
|
00054 * EXIST, THEN THE TRANSACTION IS IN ERROR. DTSBD321
|
|
00055 * DTSBD321
|
|
00056 * IF NOT MLIN-STATUS-OPEN-88, THEN THE TRANSACTION IS DTSBD321
|
|
00057 * IN ERROR. DTSBD321
|
|
00058 * DTSBD321
|
|
00059 * SCAN THE MQTR RECORDS INDICATED BY MLIN-COVERED-YRQ. DTSBD321
|
|
00060 * IF NO AMOUNTS ARE DUE IN MLIN-COVERED-YRQ(S), DTSBD321
|
|
00061 * THEN CHANGE MLIN STATUS TO MLIN-STATUS-WITHDRAWN-88 DTSBD321
|
|
00062 * AND THE TRANSACTION IS IN ERROR. DTSBD321
|
|
00063 * DTSBD321
|
|
00064 * THE FOLLOWING SPECIFICATIONS ASSUME AMOUNTS ARE DUE DTSBD321
|
|
00065 * IN ONE OR MORE OF MLIN-COVERED-YRQ(S). DTSBD321
|
|
00066 * DTSBD321
|
|
00067 * CONSTRUCT AND WRITE A R403 RECORD. DTSBD321
|
|
00068 * DTSBD321
|
|
00069 * CONSTRUCT AND WRITE A R404 RECORD. DTSBD321
|
|
00070 * DTSBD321
|
|
00071 * WRITE AN EVENT LOG RECORD. DTSBD321
|
|
00072 * DTSBD321
|
|
00073 * UPDATE THE MLIN RECORD. DTSBD321
|
|
00074 * DTSBD321
|
|
00075 * REWRITE THE MLIN RECORD. DTSBD321
|
|
00076 * DTSBD321
|
|
00077 * THERE ARE TWO TRICKY BITS. DTSBD321
|
|
00078 * DTSBD321
|
|
00079 * THE FIRST TRICKY BIT IS R403-LETTER-TOTAL-AMT. R403-LETTERDTSBD321
|
|
00080 * TOTAL-AMT REFLECTS THE TOTAL BALANCE DUE (WITH INTEREST DTSBD321
|
|
00081 * PROJECTED THRU R403-FORM-COMP-DATE) FOR ALL QTRS COVERED DTSBD321
|
|
00082 * BY OPEN LIENS (NOT LIMITED TO THE QUARTERS COVERED BY DTSBD321
|
|
00083 * THE SUJECT LIEN). DON'T FEEL TOO SORRY FOR YOURSELF. DTSBD321
|
|
00084 * COMPARED TO VERMONT (WHERE LIEN FEES ARE ASSESSED BASED DTSBD321
|
|
00085 * ON THE NUMBER OF PAGES IN THE LIEN DOCUMENT), THIS IS DTSBD321
|
|
00086 * A PIECE OF CAKE. DTSBD321
|
|
00087 * DTSBD321
|
|
00088 * THE SECOND TRICKY BIT IS THE HANDLING OF TOLERANCE DTSBD321
|
|
00089 * DURING THE UPDATE. TOLERANCE IS NOT RESOLVED UNTIL DTSBD321
|
|
00090 * ALL TRANSACTIONS FOR THE EMPLOYER HAVE BEEN PROCESSED. DTSBD321
|
|
00091 * THUS, THIS MODULE SHOULD DO SOME "PSEUDO" TOLERANCE DTSBD321
|
|
00092 * PROCESSING. WHILE PROCESSING MQTR RECORDS, JUST ADD DTSBD321
|
|
00093 * UP THE BALANCES DUE (WITHOUT PROJECTING INTEREST). DTSBD321
|
|
00094 * IF THE RESULT IS LESS THAN OR EQUAL TO LBCM-QTR-TOL-MAX, DTSBD321
|
|
00095 * THEN JUST PRETEND THERE IS NO BALANCE DUE FOR THIS DTSBD321
|
|
00096 * QUARTER. DTSBD321
|
|
00097 * DTSBD321
|
|
00098 * DTSBD321
|
|
00099 * SEE DTSCS44 FOR AN EXAMPLE OF DETERMINING THE BALANCE DTSBD321
|
|
00100 * DUE IN A PARTICULAR QUARTER AND PROJECTING INTEREST DTSBD321
|
|
00101 * THRU A SPECIFIED "COMPUTATION" DATE. DTSBD321
|
|
00102 * DTSBD321
|
|
00103 * DTSBD321
|
|
00104 * MASTER FILE RECORDS READ: DTSBD321
|
|
00105 * DTSBD321
|
|
00106 * MLIN DTSBD321
|
|
00107 * MQTR DTSBD321
|
|
00108 * DTSBD321
|
|
00109 * DTSBD321
|
|
00110 * MASTER FILE RECORDS UPDATED: DTSBD321
|
|
00111 * DTSBD321
|
|
00112 * MLIN (REWRITE) DTSBD321
|
|
00113 * MEVL (WRITE) DTSBD321
|
|
00114 * DTSBD321
|
|
00115 * DTSBD321
|
|
00116 * REPORT RECORDS WRITTEN: DTSBD321
|
|
00117 * DTSBD321
|
|
00118 * R403 LIEN DOCUMENTS. DTSBD321
|
|
00119 * R404 LIEN PACKAGES PRINTED CONTROL REPORT. DTSBD321
|
|
00120 * R907 EXCEPTION REPORT. DTSBD321
|
|
00121 * DTSBD321
|
|
00122 * DTSBD321
|
|
00123 * MODULES CALLED: DTSBD321
|
|
00124 * DTSBD321
|
|
00125 * DTSBU001 DATE EDIT/CONVERSION. DTSBD321
|
|
00126 * DTSBU004 QUARTER EDIT/CONVERSION. DTSBD321
|
|
00127 * DTSBU005 TIME EDIT/CONVERSION. DTSBD321
|
|
00128 * DTSBU101 INTEREST CHARGE/ABATEMENT COMPUTATION. DTSBD321
|
|
00129 * DTSBU910 MASTER FILE I/O DRIVER. DTSBD321
|
|
00130 * DTSBU946 VARIABLE LENGTH RECORD SEQUENTAIL OUTPUT 1. DTSBD321
|
|
00131 * DTSBD321
|
|
00132 * DTSBD321
|
|
00133 ***** DTSBD321
|
|
00134 SKIP3 DTSBD321
|
|
00135 ENVIRONMENT DIVISION. DTSBD321
|
|
00136 EJECT DTSBD321
|
|
00137 DATA DIVISION. DTSBD321
|
|
00138 SKIP3 DTSBD321
|
|
00139 WORKING-STORAGE SECTION. DTSBD321
|
|
001395 77 PAN-VALET PICTURE X(24) VALUE '002DTSBD321 04/26/16'. DTSBD321
|
|
00140 77 PAN-VALET PICTURE X(24) VALUE '020DTSBD321 04/30/08'. DTSBD321
|
|
00141 SKIP3 DTSBD321
|
|
00142 01 WRK-AREA. DTSBD321
|
|
00143 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +321.DTSBD321
|
|
00144 DTSBD321
|
|
00145 05 WRK-MOD-NAME PIC X(08) VALUE 'DTSBD321'.DTSBD321
|
|
00146 DTSBD321
|
|
00147 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBD321
|
|
00148 DTSBD321
|
|
00149 DTSBD321
|
|
00150 05 WRK-CNT PIC S9(04) COMP. DTSBD321
|
|
00151 DTSBD321
|
|
00152 05 WRK-TOT-BALANCE-AMT PIC S9(09)V9(02) COMP-3. DTSBD321
|
|
00153 DTSBD321
|
|
00154 05 WRK-TAX-BALANCE-AMT PIC S9(09)V9(02) COMP-3. DTSBD321
|
|
00155 DTSBD321
|
|
00156 05 WRK-SUR-TAX-BALANCE-AMT PIC S9(09)V9(02) COMP-3. DTSBD321
|
|
00157 DTSBD321
|
|
00158 05 WRK-INT-BALANCE-AMT PIC S9(09)V9(02) COMP-3. DTSBD321
|
|
00159 DTSBD321
|
|
00160 05 WRK-LP-NP-MP-BALANCE-AMT PIC S9(09)V9(02) COMP-3. DTSBD321
|
|
00161 DTSBD321
|
|
00162 05 WRK-FIRST-PEN-INT-YRQ PIC S9(05) COMP-3. DTSBD321
|
|
00163 DTSBD321
|
|
00164 DTSBD321
|
|
00165 05 WRK-COV-QTRS-TBL. DTSBD321
|
|
00166 10 FILLER OCCURS 400. DTSBD321
|
|
00167 15 WRK-COV-QTR PIC S9(05) COMP-3. DTSBD321
|
|
00168 88 WRK-NOT-COVERED-88 VALUE +0. DTSBD321
|
|
00169 15 WRK-COV-SUBJECT-IND PIC X(01). DTSBD321
|
|
00170 88 WRK-COV-SUBJECT-YES-88 VALUE 'X'. DTSBD321
|
|
00171 88 WRK-COV-SUBJECT-NO-88 VALUE SPACE. DTSBD321
|
|
00172 DTSBD321
|
|
00173 DTSBD321
|
|
00174 05 WRK-SMALL-ABS-QTR PIC S9(04) COMP. DTSBD321
|
|
00175 DTSBD321
|
|
00176 05 WRK-LARGE-ABS-QTR PIC S9(04) COMP. DTSBD321
|
|
00177 DTSBD321
|
|
00178 DTSBD321
|
|
00179 05 WRK-EVENT-TXT. DTSBD321
|
|
00180 10 FILLER PIC X(36) DTSBD321
|
|
00181 VALUE 'LIEN PACKAGE PRINTED. CERTIFICATE: '. DTSBD321
|
|
00182 10 WRK-MEVL-CERTIFICATE-NO PIC 99B9999. DTSBD321
|
|
00183 EJECT DTSBD321
|
|
00184 01 MSG-TABLE. DTSBD321
|
|
00185 05 MSG1-MLIN-NOT-FOUND. DTSBD321
|
|
00186 10 MSG1-ID PIC X(11) VALUE 'DTSBD321401'. DTSBD321
|
|
00187 10 MSG1-SHORT-TEXT PIC X(20) VALUE 'DELETED MLIN '. DTSBD321
|
|
00188 10 MSG1-LONG-TEXT. DTSBD321
|
|
00189 15 FILLER PIC X(30) DTSBD321
|
|
00190 VALUE 'TRANSACTION FAILED - RECORD NO'. DTSBD321
|
|
00191 15 FILLER PIC X(30) DTSBD321
|
|
00192 VALUE 'T FOUND - NO LIEN PKG PRINTED '. DTSBD321
|
|
00193 DTSBD321
|
|
00194 05 MSG2-MLIN-NOT-OPEN. DTSBD321
|
|
00195 10 MSG2-ID PIC X(11) VALUE 'DTSBD321402'. DTSBD321
|
|
00196 10 MSG2-SHORT-TEXT PIC X(20) VALUE 'NOT OPEN MLIN '. DTSBD321
|
|
00197 10 MSG2-LONG-TEXT. DTSBD321
|
|
00198 15 FILLER PIC X(30) DTSBD321
|
|
00199 VALUE 'TRANSACTION FAILED - LIEN NOT '. DTSBD321
|
|
00200 15 FILLER PIC X(30) DTSBD321
|
|
00201 VALUE 'OPEN - NO LIEN PACKAGE PRINTED'. DTSBD321
|
|
00202 DTSBD321
|
|
00203 05 MSG3-NO-DUE. DTSBD321
|
|
00204 10 MSG3-ID. DTSBD321
|
|
00205 15 MSG3-ID-1 PIC X(08) VALUE 'DTSBD321'. DTSBD321
|
|
00206 15 MSG3-ID-2 PIC X(03) VALUE '403'. DTSBD321
|
|
00207 10 MSG3-SHORT-TEXT PIC X(20) VALUE 'NOTHING DUE '. DTSBD321
|
|
00208 10 MSG3-LONG-TEXT. DTSBD321
|
|
00209 15 FILLER PIC X(30) DTSBD321
|
|
00210 VALUE 'NO AMOUNTS DUE - NO LIEN PACKA'. DTSBD321
|
|
00211 15 FILLER PIC X(30) DTSBD321
|
|
00212 VALUE 'GE PRINTED '. DTSBD321
|
|
00213 EJECT DTSBD321
|
|
00214 01 L001-LINK-AREA. DTSBD321
|
|
00215 ++INCLUDE DTSIL001 DTSBD321
|
|
00216 SKIP3 DTSBD321
|
|
00217 01 L004-LINK-AREA. DTSBD321
|
|
00218 ++INCLUDE DTSIL004 DTSBD321
|
|
00219 SKIP3 DTSBD321
|
|
00220 01 L005-LINK-AREA. DTSBD321
|
|
00221 ++INCLUDE DTSIL005 DTSBD321
|
|
00222 SKIP3 DTSBD321
|
|
00223 01 L101-LINK-AREA. DTSBD321
|
|
00224 ++INCLUDE DTSIL101 DTSBD321
|
|
00225 SKIP3 DTSBD321
|
|
00226 01 L109-LINK-AREA. DTSBD321
|
|
00227 ++INCLUDE DTSIL109 DTSBD321
|
|
00228 SKIP3 DTSBD321
|
|
00229 01 L910-LINK-AREA. DTSBD321
|
|
00230 ++INCLUDE DTSIL910 DTSBD321
|
|
00231 SKIP3 DTSBD321
|
|
00232 01 MSKL-REC. DTSBD321
|
|
00233 ++INCLUDE DTSIMSKL DTSBD321
|
|
00234 SKIP3 DTSBD321
|
|
00235 01 MLIN-REC. DTSBD321
|
|
00236 ++INCLUDE DTSIMLIN DTSBD321
|
|
00237 SKIP3 DTSBD321
|
|
00238 01 MQTR-REC. DTSBD321
|
|
00239 ++INCLUDE DTSIMQTR DTSBD321
|
|
00240 SKIP3 DTSBD321
|
|
00241 01 MEVL-REC. DTSBD321
|
|
00242 ++INCLUDE DTSIMEVL DTSBD321
|
|
00243 EJECT DTSBD321
|
|
00244 01 MMAX-LITERALS. DTSBD321
|
|
00245 ++INCLUDE DTSIMMAX DTSBD321
|
|
00246 EJECT DTSBD321
|
|
00247 01 R403-REC. DTSBD321
|
|
00248 ++INCLUDE DTSIR403 DTSBD321
|
|
00249 SKIP3 DTSBD321
|
|
00250 01 R404-REC. DTSBD321
|
|
00251 ++INCLUDE DTSIR404 DTSBD321
|
|
00252 SKIP3 DTSBD321
|
|
00253 01 R907-REC. DTSBD321
|
|
00254 ++INCLUDE DTSIR907 DTSBD321
|
|
00255 EJECT DTSBD321
|
|
00256 LINKAGE SECTION. DTSBD321
|
|
00257 SKIP3 DTSBD321
|
|
00258 01 LBCM-LINK-AREA. DTSBD321
|
|
00259 ++INCLUDE DTSILBCM DTSBD321
|
|
00260 EJECT DTSBD321
|
|
00261 01 MPRF-REC. DTSBD321
|
|
00262 ++INCLUDE DTSIMPRF DTSBD321
|
|
00263 EJECT DTSBD321
|
|
00264 01 T011-REC. DTSBD321
|
|
00265 ++INCLUDE DTSIT011 DTSBD321
|
|
00266 EJECT DTSBD321
|
|
00267 PROCEDURE DIVISION USING LBCM-LINK-AREA DTSBD321
|
|
00268 MPRF-REC DTSBD321
|
|
00269 T011-REC. DTSBD321
|
|
00270 DTSBD321
|
|
00271 DTSBD321
|
|
00272 IF FIRST-TIME-IND = 'Y' DTSBD321
|
|
00273 PERFORM I0000-FIRST-TIME THRU I0000-EXIT DTSBD321
|
|
00274 MOVE 'N' TO FIRST-TIME-IND. DTSBD321
|
|
00275 DTSBD321
|
|
00276 DTSBD321
|
|
00277 IF T011-LIN-PKG DTSBD321
|
|
00278 PERFORM P0000-PROCESS THRU P0000-EXIT DTSBD321
|
|
00279 ELSE DTSBD321
|
|
00280 PERFORM S999-ABEND THRU S999-EXIT. DTSBD321
|
|
00281 DTSBD321
|
|
00282 DTSBD321
|
|
00283 GOBACK. DTSBD321
|
|
00284 EJECT DTSBD321
|
|
00285 I0000-FIRST-TIME. DTSBD321
|
|
00286 MOVE LBCM-TRACE-IND TO L910-TRACE-IND. DTSBD321
|
|
00287 DTSBD321
|
|
00288 MOVE WRK-MOD-NAME TO L910-MOD-NAME DTSBD321
|
|
00289 R907-MODULE-NAME. DTSBD321
|
|
00290 DTSBD321
|
|
00291 MOVE LENGTH OF R403-REC TO R403-LENGTH. DTSBD321
|
|
00292 DTSBD321
|
|
00293 MOVE LENGTH OF R404-REC TO R404-LENGTH. DTSBD321
|
|
00294 DTSBD321
|
|
00295 MOVE LENGTH OF R907-REC TO R907-LENGTH. DTSBD321
|
|
00296 *RW1 DTSBD321
|
|
00297 PERFORM S109-FIRST-PEN-INT-YRQ THRU S109-EXIT. DTSBD321
|
|
00298 MOVE L109-FIRST-PEN-INT-YRQ TO WRK-FIRST-PEN-INT-YRQ. DTSBD321
|
|
00299 *RW2 DTSBD321
|
|
00300 I0000-EXIT. DTSBD321
|
|
00301 EXIT. DTSBD321
|
|
00302 EJECT DTSBD321
|
|
00303 P0000-PROCESS. DTSBD321
|
|
00304 PERFORM S1000-READ-SUBJECT-MLIN THRU S1000-EXIT. DTSBD321
|
|
00305 DTSBD321
|
|
00306 IF L910-NO-REC-88 DTSBD321
|
|
00307 SET LBCM-TRN-NOT-OK-88 TO TRUE DTSBD321
|
|
00308 MOVE MSG1-MLIN-NOT-FOUND TO LBCM-TRN-MSG-AREA DTSBD321
|
|
00309 GO TO P0000-EXIT. DTSBD321
|
|
00310 DTSBD321
|
|
00311 IF NOT MLIN-STATUS-OPEN-88 DTSBD321
|
|
00312 SET LBCM-TRN-NOT-OK-88 TO TRUE DTSBD321
|
|
00313 MOVE MSG2-MLIN-NOT-OPEN TO LBCM-TRN-MSG-AREA DTSBD321
|
|
00314 GO TO P0000-EXIT. DTSBD321
|
|
00315 DTSBD321
|
|
00316 PERFORM P1000-START-R403 THRU P1000-EXIT. DTSBD321
|
|
00317 DTSBD321
|
|
00318 PERFORM P2000-LOAD-COV-TABLE THRU P2000-EXIT. DTSBD321
|
|
00319 DTSBD321
|
|
00320 MOVE R403-FORM-COMP-DATE TO L101-RECEIVED-DATE. DTSBD321
|
|
00321 DTSBD321
|
|
00322 SET L101-WAIVE-INT-NO-88 TO TRUE. DTSBD321
|
|
00323 DTSBD321
|
|
00324 MOVE LOW-VALUE TO MQTR-KEY-AREA. DTSBD321
|
|
00325 DTSBD321
|
|
00326 MOVE MPRF-EMP-NO TO MQTR-EMP-NO. DTSBD321
|
|
00327 DTSBD321
|
|
00328 SET MQTR-QTR-88 TO TRUE. DTSBD321
|
|
00329 DTSBD321
|
|
00330 PERFORM P3000-PROCESS-MQTR THRU P3000-EXIT DTSBD321
|
|
00331 VARYING WRK-CNT FROM WRK-SMALL-ABS-QTR BY 1 DTSBD321
|
|
00332 UNTIL WRK-CNT > WRK-LARGE-ABS-QTR. DTSBD321
|
|
00333 DTSBD321
|
|
00334 DTSBD321
|
|
00335 PERFORM P4000-WRITE-MLIN-AND-REPORT THRU P4000-EXIT. DTSBD321
|
|
00336 P0000-EXIT. DTSBD321
|
|
00337 EXIT. DTSBD321
|
|
00338 EJECT DTSBD321
|
|
00339 P1000-START-R403. DTSBD321
|
|
00340 MOVE T011-RESP-OP-ID TO R403-OP-ID. DTSBD321
|
|
00341 DTSBD321
|
|
00342 MOVE MPRF-EMP-NO TO R403-EMP-NO. DTSBD321
|
|
00343 DTSBD321
|
|
00344 DTSBD321
|
|
00345 INITIALIZE R403-COMMON-DATA-AREA. DTSBD321
|
|
00346 DTSBD321
|
|
00347 MOVE MLIN-CERTIFICATE-NO TO R403-CERTIFICATE-NO. DTSBD321
|
|
00348 DTSBD321
|
|
00349 MOVE MLIN-CERTIFICATE-DATE TO R403-CERTIFICATE-DATE. DTSBD321
|
|
00350 DTSBD321
|
|
00351 MOVE MPRF-EMP-STATUS TO R403-EMP-STATUS. DTSBD321
|
|
00352 DTSBD321
|
|
00353 MOVE MLIN-STMT-DATE TO R403-STMT-DATE. DTSBD321
|
|
00354 DTSBD321
|
|
00355 MOVE MPRF-PRIMARY-NAME TO R403-PRIMARY-NAME. DTSBD321
|
|
00356 DTSBD321
|
|
00357 MOVE MLIN-ADDRESS TO R403-FMT-ADDR. DTSBD321
|
|
00358 DTSBD321
|
|
00359 DTSBD321
|
|
00360 INITIALIZE R403-LIEN-FORM-DATA-AREA. DTSBD321
|
|
00361 DTSBD321
|
|
00362 MOVE MLIN-COMP-DATE TO R403-FORM-COMP-DATE. DTSBD321
|
|
00363 DTSBD321
|
|
00364 DTSBD321
|
|
00365 INITIALIZE R403-LIEN-LETTERS-DATA-AREA. DTSBD321
|
|
00366 DTSBD321
|
|
00367 MOVE MLIN-LICENSE-IND TO R403-LETTER-LICENSE-IND. DTSBD321
|
|
00368 P1000-EXIT. DTSBD321
|
|
00369 EXIT. DTSBD321
|
|
00370 EJECT DTSBD321
|
|
00371 P2000-LOAD-COV-TABLE. DTSBD321
|
|
00372 INITIALIZE WRK-COV-QTRS-TBL. DTSBD321
|
|
00373 DTSBD321
|
|
00374 MOVE +400 TO WRK-SMALL-ABS-QTR. DTSBD321
|
|
00375 DTSBD321
|
|
00376 MOVE +1 TO WRK-LARGE-ABS-QTR. DTSBD321
|
|
00377 DTSBD321
|
|
00378 DTSBD321
|
|
00379 MOVE LOW-VALUE TO MSKL-KEY-AREA. DTSBD321
|
|
00380 DTSBD321
|
|
00381 MOVE MPRF-EMP-NO TO MSKL-EMP-NO. DTSBD321
|
|
00382 DTSBD321
|
|
00383 SET MSKL-LIN-88 TO TRUE. DTSBD321
|
|
00384 DTSBD321
|
|
00385 PERFORM S910-START-BROWSE THRU S910-EXIT. DTSBD321
|
|
00386 DTSBD321
|
|
00387 PERFORM DTSBD321
|
|
00388 UNTIL L910-NO-REC-88 DTSBD321
|
|
00389 MOVE MSKL-REC TO MLIN-REC DTSBD321
|
|
00390 IF MLIN-STATUS-ACTIVE-88 DTSBD321
|
|
00391 PERFORM P2100-COVERED-SCAN THRU P2100-EXIT DTSBD321
|
|
00392 VARYING MLIN-COV-IDX FROM 1 BY 1 DTSBD321
|
|
00393 UNTIL MLIN-COV-IDX > MLIN-COV-CNT DTSBD321
|
|
00394 END-IF DTSBD321
|
|
00395 PERFORM S910-READ-NEXT THRU S910-EXIT DTSBD321
|
|
00396 END-PERFORM. DTSBD321
|
|
00397 DTSBD321
|
|
00398 DTSBD321
|
|
00399 PERFORM S1000-READ-SUBJECT-MLIN THRU S1000-EXIT. DTSBD321
|
|
00400 DTSBD321
|
|
00401 IF L910-NO-REC-88 DTSBD321
|
|
00402 PERFORM S999-ABEND THRU S999-EXIT. DTSBD321
|
|
00403 P2000-EXIT. DTSBD321
|
|
00404 EXIT. DTSBD321
|
|
00405 SKIP3 DTSBD321
|
|
00406 P2100-COVERED-SCAN. DTSBD321
|
|
00407 MOVE MLIN-COVERED-YRQ (MLIN-COV-IDX) TO L004-QTR-5-9. DTSBD321
|
|
00408 DTSBD321
|
|
00409 PERFORM S004-FROM-5 THRU S004-EXIT. DTSBD321
|
|
00410 DTSBD321
|
|
00411 IF L004-INVALID-QTR DTSBD321
|
|
00412 GO TO P2100-EXIT. DTSBD321
|
|
00413 DTSBD321
|
|
00414 DTSBD321
|
|
00415 MOVE L004-QTR-5-9 TO WRK-COV-QTR (L004-ABS-QTR). DTSBD321
|
|
00416 DTSBD321
|
|
00417 IF MLIN-ESTB-ABSTIME = T011-ESTB-ABSTIME DTSBD321
|
|
00418 SET WRK-COV-SUBJECT-YES-88 (L004-ABS-QTR) TO TRUE. DTSBD321
|
|
00419 DTSBD321
|
|
00420 DTSBD321
|
|
00421 IF L004-ABS-QTR < WRK-SMALL-ABS-QTR DTSBD321
|
|
00422 MOVE L004-ABS-QTR TO WRK-SMALL-ABS-QTR. DTSBD321
|
|
00423 DTSBD321
|
|
00424 IF L004-ABS-QTR > WRK-LARGE-ABS-QTR DTSBD321
|
|
00425 MOVE L004-ABS-QTR TO WRK-LARGE-ABS-QTR. DTSBD321
|
|
00426 P2100-EXIT. DTSBD321
|
|
00427 EXIT. DTSBD321
|
|
00428 EJECT DTSBD321
|
|
00429 P3000-PROCESS-MQTR. DTSBD321
|
|
00430 IF WRK-NOT-COVERED-88 (WRK-CNT) DTSBD321
|
|
00431 GO TO P3000-EXIT. DTSBD321
|
|
00432 DTSBD321
|
|
00433 DTSBD321
|
|
00434 MOVE WRK-COV-QTR (WRK-CNT) TO MQTR-YRQ. DTSBD321
|
|
00435 DTSBD321
|
|
00436 MOVE MQTR-KEY-AREA TO MSKL-KEY-AREA. DTSBD321
|
|
00437 DTSBD321
|
|
00438 PERFORM S910-READ THRU S910-EXIT. DTSBD321
|
|
00439 DTSBD321
|
|
00440 IF L910-OK-88 DTSBD321
|
|
00441 MOVE MSKL-REC TO MQTR-REC DTSBD321
|
|
00442 ELSE DTSBD321
|
|
00443 GO TO P3000-EXIT. DTSBD321
|
|
00444 DTSBD321
|
|
00445 DTSBD321
|
|
00446 MOVE +0 TO WRK-TOT-BALANCE-AMT DTSBD321
|
|
00447 WRK-TAX-BALANCE-AMT DTSBD321
|
|
00448 WRK-SUR-TAX-BALANCE-AMT DTSBD321
|
|
00449 WRK-INT-BALANCE-AMT DTSBD321
|
|
00450 WRK-LP-NP-MP-BALANCE-AMT DTSBD321
|
|
00451 L101-PAID-CHNG. DTSBD321
|
|
00452 DTSBD321
|
|
00453 DTSBD321
|
|
00454 PERFORM P3100-PROCESS-ACCT-AREA THRU P3100-EXIT DTSBD321
|
|
00455 VARYING MQTR-ACCT-IDX FROM 1 BY 1 DTSBD321
|
|
00456 UNTIL MQTR-ACCT-IDX > MQTR-ACCT-CNT. DTSBD321
|
|
00457 DTSBD321
|
|
00458 IF WRK-TOT-BALANCE-AMT NOT > LBCM-QTR-TOL-MAX DTSBD321
|
|
00459 GO TO P3000-EXIT. DTSBD321
|
|
00460 DTSBD321
|
|
00461 DTSBD321
|
|
00462 MOVE MQTR-TAX-DUE-DATE TO L101-TAX-DUE-DATE. DTSBD321
|
|
00463 DTSBD321
|
|
00464 MOVE MQTR-INT-AREA TO L101-INT-AREA. DTSBD321
|
|
00465 DTSBD321
|
|
00466 PERFORM S101-PER-MONTH-NO THRU S101-EXIT. DTSBD321
|
|
00467 DTSBD321
|
|
00468 ADD L101-INT-CHARGE-CHNG TO WRK-TOT-BALANCE-AMT DTSBD321
|
|
00469 WRK-INT-BALANCE-AMT. DTSBD321
|
|
00470 DTSBD321
|
|
00471 SUBTRACT L101-INT-WAIVE-CHNG FROM WRK-TOT-BALANCE-AMT DTSBD321
|
|
00472 WRK-INT-BALANCE-AMT. DTSBD321
|
|
00473 DTSBD321
|
|
00474 DTSBD321
|
|
00475 ADD WRK-TOT-BALANCE-AMT TO R403-LETTER-TOTAL-AMT. DTSBD321
|
|
00476 DTSBD321
|
|
00477 IF WRK-COV-SUBJECT-YES-88 (WRK-CNT) DTSBD321
|
|
00478 AND R403-FORM-QTR-CNT < MMAX-LIN-COV-MAX DTSBD321
|
|
00479 ADD +1 TO R403-FORM-QTR-CNT DTSBD321
|
|
00480 MOVE MQTR-YRQ TO R403-FORM-QTR (R403-FORM-QTR-CNT) DTSBD321
|
|
00481 MOVE WRK-TAX-BALANCE-AMT DTSBD321
|
|
00482 TO R403-FORM-TAX-BALANCE-AMT (R403-FORM-QTR-CNT) DTSBD321
|
|
00483 MOVE WRK-SUR-TAX-BALANCE-AMT DTSBD321
|
|
00484 TO R403-FORM-SUR-TAX-BALANCE-AMT (R403-FORM-QTR-CNT) DTSBD321
|
|
00485 MOVE WRK-INT-BALANCE-AMT DTSBD321
|
|
00486 TO R403-FORM-INT-BALANCE-AMT (R403-FORM-QTR-CNT) DTSBD321
|
|
00487 MOVE WRK-LP-NP-MP-BALANCE-AMT DTSBD321
|
|
00488 TO R403-FORM-LP-NP-MP-BALANCE-AMT (R403-FORM-QTR-CNT) DTSBD321
|
|
00489 IF MQTR-CURR-ESTIM-88 DTSBD321
|
|
00490 SET R403-FORM-ESTIMATED-YES-88 (R403-FORM-QTR-CNT) DTSBD321
|
|
00491 TO TRUE DTSBD321
|
|
00492 END-IF. DTSBD321
|
|
00493 P3000-EXIT. DTSBD321
|
|
00494 EXIT. DTSBD321
|
|
00495 EJECT DTSBD321
|
|
00496 P3100-PROCESS-ACCT-AREA. DTSBD321
|
|
00497 ADD MQTR-BALANCE-AMT (MQTR-ACCT-IDX) TO WRK-TOT-BALANCE-AMT. DTSBD321
|
|
00498 DTSBD321
|
|
00499 ******************************************************** DTSBD321
|
|
00500 * INCLUDE ONLY UI TAX BALANCE FOR INTEREST CALCULATION & DTSBD321
|
|
00501 * ADMINISTRATIVE ASSESSMENT INCLUDED IN INTEREST CALCULA- DTSBD321
|
|
00502 * TION STARTING WITH 2008/1. DTSBD321
|
|
00503 ******************************************************** DTSBD321
|
|
00504 EVALUATE TRUE DTSBD321
|
|
00505 WHEN MQTR-ACCT-UI-88 (MQTR-ACCT-IDX) DTSBD321
|
|
00506 ADD MQTR-BALANCE-AMT (MQTR-ACCT-IDX) DTSBD321
|
|
00507 TO WRK-TAX-BALANCE-AMT DTSBD321
|
|
00508 L101-PAID-CHNG DTSBD321
|
|
00509 DTSBD321
|
|
00510 WHEN MQTR-ACCT-SUR-88 (MQTR-ACCT-IDX) DTSBD321
|
|
00511 ADD MQTR-BALANCE-AMT (MQTR-ACCT-IDX) DTSBD321
|
|
00512 TO WRK-SUR-TAX-BALANCE-AMT DTSBD321
|
|
00513 *RW1 DTSBD321
|
|
00514 IF MQTR-YRQ >= WRK-FIRST-PEN-INT-YRQ DTSBD321
|
|
00515 ADD MQTR-BALANCE-AMT (MQTR-ACCT-IDX) DTSBD321
|
|
00516 TO L101-PAID-CHNG DTSBD321
|
|
00517 DISPLAY 'BD321 P3100 SUR BAL ' DTSBD321
|
|
00518 MQTR-BALANCE-AMT (MQTR-ACCT-IDX) DTSBD321
|
|
00519 END-IF DTSBD321
|
|
00520 *RW2 DTSBD321
|
|
00521 WHEN MQTR-ACCT-INT-88 (MQTR-ACCT-IDX) DTSBD321
|
|
00522 ADD MQTR-BALANCE-AMT (MQTR-ACCT-IDX) DTSBD321
|
|
00523 TO WRK-INT-BALANCE-AMT DTSBD321
|
|
00524 DTSBD321
|
|
00525 WHEN (MQTR-ACCT-LATE-PEN-88 (MQTR-ACCT-IDX)) DTSBD321
|
|
00526 OR (MQTR-ACCT-NSF-PEN-88 (MQTR-ACCT-IDX)) DTSBD321
|
|
00527 OR (MQTR-ACCT-MISC-PEN-88 (MQTR-ACCT-IDX)) DTSBD321
|
|
00528 ADD MQTR-BALANCE-AMT (MQTR-ACCT-IDX) DTSBD321
|
|
00529 TO WRK-LP-NP-MP-BALANCE-AMT DTSBD321
|
|
00530 DTSBD321
|
|
00531 WHEN OTHER DTSBD321
|
|
00532 PERFORM S999-ABEND THRU S999-EXIT DTSBD321
|
|
00533 END-EVALUATE. DTSBD321
|
|
00534 P3100-EXIT. DTSBD321
|
|
00535 EXIT. DTSBD321
|
|
00536 EJECT DTSBD321
|
|
00537 P4000-WRITE-MLIN-AND-REPORT. DTSBD321
|
|
00538 MOVE +0 TO MLIN-STMT-DUE-AMT. DTSBD321
|
|
00539 DTSBD321
|
|
00540 PERFORM VARYING R403-FORM-QTR-IDX FROM 1 BY 1 DTSBD321
|
|
00541 UNTIL R403-FORM-QTR-IDX > R403-FORM-QTR-CNT DTSBD321
|
|
00542 ADD R403-FORM-TAX-BALANCE-AMT (R403-FORM-QTR-IDX) DTSBD321
|
|
00543 TO MLIN-STMT-DUE-AMT DTSBD321
|
|
00544 ADD R403-FORM-SUR-TAX-BALANCE-AMT (R403-FORM-QTR-IDX) DTSBD321
|
|
00545 TO MLIN-STMT-DUE-AMT DTSBD321
|
|
00546 ADD R403-FORM-INT-BALANCE-AMT (R403-FORM-QTR-IDX) DTSBD321
|
|
00547 TO MLIN-STMT-DUE-AMT DTSBD321
|
|
00548 ADD R403-FORM-LP-NP-MP-BALANCE-AMT (R403-FORM-QTR-IDX) DTSBD321
|
|
00549 TO MLIN-STMT-DUE-AMT DTSBD321
|
|
00550 END-PERFORM. DTSBD321
|
|
00551 DTSBD321
|
|
00552 IF MLIN-STMT-DUE-AMT > +0 DTSBD321
|
|
00553 PERFORM S946-WRITE-R403 THRU S946-EXIT DTSBD321
|
|
00554 MOVE MLIN-CERTIFICATE-NO TO WRK-MEVL-CERTIFICATE-NO DTSBD321
|
|
00555 PERFORM P4100-WRITE-MEVL THRU P4100-EXIT DTSBD321
|
|
00556 PERFORM P4200-CONSTRUCT-R404 THRU P4200-EXIT DTSBD321
|
|
00557 PERFORM S946-WRITE-R404 THRU S946-EXIT DTSBD321
|
|
00558 ELSE DTSBD321
|
|
00559 MOVE MSG3-ID-2 TO R907-MSG-ID DTSBD321
|
|
00560 MOVE MPRF-EMP-NO TO R907-EMP-NO DTSBD321
|
|
00561 MOVE MSG3-LONG-TEXT TO R907-MSG-TEXT DTSBD321
|
|
00562 PERFORM S946-WRITE-R907 THRU S946-EXIT DTSBD321
|
|
00563 SET MLIN-STATUS-WITHDRAWN-88 TO TRUE DTSBD321
|
|
00564 MOVE LBCM-CURR-RUN-DATE TO MLIN-STATUS-DATE DTSBD321
|
|
00565 MOVE 'SYSTEM' TO MLIN-STATUS-OP-ID. DTSBD321
|
|
00566 DTSBD321
|
|
00567 DTSBD321
|
|
00568 MOVE LBCM-CURR-RUN-DATE TO MLIN-CHNG-DATE. DTSBD321
|
|
00569 DTSBD321
|
|
00570 MOVE MLIN-REC TO MSKL-REC. DTSBD321
|
|
00571 DTSBD321
|
|
00572 PERFORM S910-REWRITE THRU S910-EXIT. DTSBD321
|
|
00573 P4000-EXIT. DTSBD321
|
|
00574 EXIT. DTSBD321
|
|
00575 EJECT DTSBD321
|
|
00576 P4100-WRITE-MEVL. DTSBD321
|
|
00577 MOVE LOW-VALUE TO MEVL-REC. DTSBD321
|
|
00578 DTSBD321
|
|
00579 MOVE MPRF-EMP-NO TO MEVL-EMP-NO. DTSBD321
|
|
00580 DTSBD321
|
|
00581 SET MEVL-EVL-88 TO TRUE. DTSBD321
|
|
00582 DTSBD321
|
|
00583 ADD +1000 TO LBCM-EMP-ABSTIME. DTSBD321
|
|
00584 DTSBD321
|
|
00585 MOVE LBCM-EMP-ABSTIME TO L005-ABSTIME. DTSBD321
|
|
00586 DTSBD321
|
|
00587 PERFORM S005-FROM-ABSTIME THRU S005-EXIT. DTSBD321
|
|
00588 DTSBD321
|
|
00589 MOVE L005-DATE TO MEVL-DATE. DTSBD321
|
|
00590 DTSBD321
|
|
00591 MOVE L005-TIME TO MEVL-TIME. DTSBD321
|
|
00592 DTSBD321
|
|
00593 MOVE +0 TO MEVL-PURGE-DATE. DTSBD321
|
|
00594 DTSBD321
|
|
00595 MOVE WRK-EVENT-TXT TO MEVL-TEXT. DTSBD321
|
|
00596 DTSBD321
|
|
00597 SET MEVL-SOURCE-SYSTEM-88 TO TRUE. DTSBD321
|
|
00598 DTSBD321
|
|
00599 SET MEVL-NOT-CONVERTED-88 TO TRUE. DTSBD321
|
|
00600 DTSBD321
|
|
00601 MOVE LBCM-CURR-RUN-DATE TO MEVL-ESTB-DATE DTSBD321
|
|
00602 MEVL-CHNG-DATE. DTSBD321
|
|
00603 DTSBD321
|
|
00604 MOVE MEVL-REC TO MSKL-REC. DTSBD321
|
|
00605 DTSBD321
|
|
00606 PERFORM S910-WRITE THRU S910-EXIT. DTSBD321
|
|
00607 P4100-EXIT. DTSBD321
|
|
00608 EXIT. DTSBD321
|
|
00609 EJECT DTSBD321
|
|
00610 P4200-CONSTRUCT-R404. DTSBD321
|
|
00611 MOVE MPRF-EMP-NO TO R404-EMP-NO. DTSBD321
|
|
00612 DTSBD321
|
|
00613 MOVE LOW-VALUES TO R404-DATA-AREA. DTSBD321
|
|
00614 DTSBD321
|
|
00615 MOVE MLIN-CERTIFICATE-NO TO R404-CERTIFICATE-NO. DTSBD321
|
|
00616 DTSBD321
|
|
00617 MOVE MPRF-PRIMARY-NAME TO R404-PRIMARY-NAME. DTSBD321
|
|
00618 DTSBD321
|
|
00619 MOVE R403-FORM-QTR-CNT TO R404-COV-CNT. DTSBD321
|
|
00620 DTSBD321
|
|
00621 PERFORM DTSBD321
|
|
00622 VARYING R403-FORM-QTR-IDX FROM 1 BY 1 DTSBD321
|
|
00623 UNTIL R403-FORM-QTR-IDX > R403-FORM-QTR-CNT DTSBD321
|
|
00624 SET R404-COVERED-IDX TO R403-FORM-QTR-IDX DTSBD321
|
|
00625 MOVE R403-FORM-QTR (R403-FORM-QTR-IDX) DTSBD321
|
|
00626 TO R404-COVERED-YRQ (R404-COVERED-IDX) DTSBD321
|
|
00627 END-PERFORM. DTSBD321
|
|
00628 DTSBD321
|
|
00629 MOVE MLIN-LICENSE-IND TO R404-LICENSE-IND. DTSBD321
|
|
00630 DTSBD321
|
|
00631 MOVE MLIN-STMT-DUE-AMT TO R404-STMT-DUE-AMT. DTSBD321
|
|
00632 DTSBD321
|
|
00633 MOVE MLIN-ADDRESS TO R404-FMT-ADDR. DTSBD321
|
|
00634 P4200-EXIT. DTSBD321
|
|
00635 EXIT. DTSBD321
|
|
00636 EJECT DTSBD321
|
|
00637 S1000-READ-SUBJECT-MLIN. DTSBD321
|
|
00638 MOVE LOW-VALUE TO MLIN-KEY-AREA. DTSBD321
|
|
00639 DTSBD321
|
|
00640 MOVE MPRF-EMP-NO TO MLIN-EMP-NO. DTSBD321
|
|
00641 DTSBD321
|
|
00642 SET MLIN-LIN-88 TO TRUE. DTSBD321
|
|
00643 DTSBD321
|
|
00644 MOVE T011-ESTB-ABSTIME TO MLIN-ESTB-ABSTIME. DTSBD321
|
|
00645 DTSBD321
|
|
00646 MOVE MLIN-KEY-AREA TO MSKL-KEY-AREA. DTSBD321
|
|
00647 DTSBD321
|
|
00648 PERFORM S910-READ THRU S910-EXIT. DTSBD321
|
|
00649 DTSBD321
|
|
00650 IF L910-OK-88 DTSBD321
|
|
00651 MOVE MSKL-REC TO MLIN-REC. DTSBD321
|
|
00652 S1000-EXIT. DTSBD321
|
|
00653 EXIT. DTSBD321
|
|
00654 EJECT DTSBD321
|
|
00655 S004-FROM-5. DTSBD321
|
|
00656 SET L004-FROM-5 TO TRUE. DTSBD321
|
|
00657 GO TO S004-YRQ. DTSBD321
|
|
00658 DTSBD321
|
|
00659 S004-YRQ. DTSBD321
|
|
00660 CALL 'DTSBU004' USING L004-LINK-AREA. DTSBD321
|
|
00661 S004-EXIT. DTSBD321
|
|
00662 EXIT. DTSBD321
|
|
00663 SKIP3 DTSBD321
|
|
00664 S005-FROM-ABSTIME. DTSBD321
|
|
00665 SET L005-FROM-ABSTIME TO TRUE. DTSBD321
|
|
00666 GO TO S005-TIME. DTSBD321
|
|
00667 DTSBD321
|
|
00668 S005-TIME. DTSBD321
|
|
00669 CALL 'DTSBU005' USING L005-LINK-AREA. DTSBD321
|
|
00670 S005-EXIT. DTSBD321
|
|
00671 EXIT. DTSBD321
|
|
00672 SKIP3 DTSBD321
|
|
00673 S101-PER-MONTH-NO. DTSBD321
|
|
00674 SET L101-PER-MONTH-NO-88 TO TRUE. DTSBD321
|
|
00675 GO TO S101-INTEREST. DTSBD321
|
|
00676 DTSBD321
|
|
00677 S101-INTEREST. DTSBD321
|
|
00678 CALL 'DTSBU101' USING L101-LINK-AREA. DTSBD321
|
|
00679 S101-EXIT. DTSBD321
|
|
00680 EXIT. DTSBD321
|
|
00681 SKIP3 DTSBD321
|
|
00682 S109-FIRST-PEN-INT-YRQ. DTSBD321
|
|
00683 SET L109-CMND-PEN-INT-QTR-88 TO TRUE. DTSBD321
|
|
00684 GO TO S109-SUR-RATE. DTSBD321
|
|
00685 DTSBD321
|
|
00686 S109-SUR-RATE. DTSBD321
|
|
00687 CALL 'DTSBU109' USING L109-LINK-AREA. DTSBD321
|
|
00688 S109-EXIT. DTSBD321
|
|
00689 EXIT. DTSBD321
|
|
00690 SKIP3 DTSBD321
|
|
00691 S910-READ. DTSBD321
|
|
00692 SET L910-READ-88 TO TRUE. DTSBD321
|
|
00693 GO TO S910-MSTR-IO. DTSBD321
|
|
00694 DTSBD321
|
|
00695 S910-START-BROWSE. DTSBD321
|
|
00696 SET L910-START-BROWSE-88 TO TRUE. DTSBD321
|
|
00697 GO TO S910-MSTR-IO. DTSBD321
|
|
00698 DTSBD321
|
|
00699 S910-READ-NEXT. DTSBD321
|
|
00700 SET L910-READ-NEXT-88 TO TRUE. DTSBD321
|
|
00701 GO TO S910-MSTR-IO. DTSBD321
|
|
00702 DTSBD321
|
|
00703 *S910-COUNT. DTSBD321
|
|
00704 *****SET L910-COUNT-88 TO TRUE. DTSBD321
|
|
00705 *****GO TO S910-MSTR-IO. DTSBD321
|
|
00706 DTSBD321
|
|
00707 S910-WRITE. DTSBD321
|
|
00708 SET LBCM-EMP-UPDATE-YES-88 TO TRUE. DTSBD321
|
|
00709 SET L910-WRITE-88 TO TRUE. DTSBD321
|
|
00710 GO TO S910-MSTR-IO. DTSBD321
|
|
00711 DTSBD321
|
|
00712 S910-REWRITE. DTSBD321
|
|
00713 SET LBCM-EMP-UPDATE-YES-88 TO TRUE. DTSBD321
|
|
00714 SET L910-REWRITE-88 TO TRUE. DTSBD321
|
|
00715 GO TO S910-MSTR-IO. DTSBD321
|
|
00716 DTSBD321
|
|
00717 *S910-DELETE. DTSBD321
|
|
00718 *****SET LBCM-EMP-UPDATE-YES-88 TO TRUE. DTSBD321
|
|
00719 *****SET L910-DELETE-88 TO TRUE. DTSBD321
|
|
00720 *****GO TO S910-MSTR-IO. DTSBD321
|
|
00721 DTSBD321
|
|
00722 S910-MSTR-IO. DTSBD321
|
|
00723 CALL 'DTSBU910' USING L910-LINK-AREA DTSBD321
|
|
00724 MSKL-REC. DTSBD321
|
|
00725 S910-EXIT. DTSBD321
|
|
00726 EXIT. DTSBD321
|
|
00727 SKIP3 DTSBD321
|
|
00728 S946-WRITE-R403. DTSBD321
|
|
00729 CALL 'DTSBU946' USING R403-REC. DTSBD321
|
|
00730 GO TO S946-EXIT. DTSBD321
|
|
00731 DTSBD321
|
|
00732 S946-WRITE-R404. DTSBD321
|
|
00733 CALL 'DTSBU946' USING R404-REC. DTSBD321
|
|
00734 GO TO S946-EXIT. DTSBD321
|
|
00735 DTSBD321
|
|
00736 S946-WRITE-R907. DTSBD321
|
|
00737 CALL 'DTSBU946' USING R907-REC. CL**2
|
|
00738 GO TO S946-EXIT. DTSBD321
|
|
00739 DTSBD321
|
|
00740 S946-EXIT. DTSBD321
|
|
00741 EXIT. DTSBD321
|
|
00742 SKIP3 DTSBD321
|
|
00743 S999-ABEND. DTSBD321
|
|
00744 CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBD321
|
|
00745 S999-EXIT. DTSBD321
|
|
00746 EXIT. DTSBD321
|