393 lines
31 KiB
COBOL
393 lines
31 KiB
COBOL
00001 IDENTIFICATION DIVISION. 03/02/99
|
|
00002 PROGRAM-ID. DTSBE729. DTSBE729
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD. LV007
|
|
00004 DATE-WRITTEN. SEPTEMBER 1994. DTSBE729
|
|
00005 DATE-COMPILED. DTSBE729
|
|
00006 SKIP3 DTSBE729
|
|
00007 ***** DTSBE729
|
|
00008 * DTSBE729
|
|
00009 * CALLING SEQUENCE: DTSBD400 CALLS CL**6
|
|
00010 * DTSBE729 WHICH UPDATES DTSIR729 CL**6
|
|
00011 * DTSBR729 READS DTSIR729 RECORDS. CL**6
|
|
00012 * CL**6
|
|
00013 * FUNCTION: ACCOUNTS AVAILABLE FOR PURGE LIST EXTRACT. DTSBE729
|
|
00014 * DTSBE729
|
|
00015 * DTSBE729
|
|
00016 * MODIFICATION LOG: DTSBE729
|
|
00017 * DTSBE729
|
|
00018 * 03/02/99 MODIFIED TO MEET DUTAS PROGRAMMING SPECIFICIATIONS. CL**2
|
|
00019 * WORK ORDER: PROGRAMMER: DVS CL**2
|
|
00020 * DTSBE729
|
|
00021 * XX/XX/XX XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX CL**2
|
|
00022 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX CL**2
|
|
00023 * WORK ORDER: PROGRAMMER: XXX CL**2
|
|
00024 * CL**2
|
|
00025 * DTSBE729
|
|
00026 * DESCRIPTION: DTSBE729
|
|
00027 * DTSBE729
|
|
00028 * DTSBE729
|
|
00029 * INITIATION: DTSBE729
|
|
00030 * DTSBE729
|
|
00031 * SET LECM-MST-OPEN-READ-88 TO TRUE. DTSBE729
|
|
00032 * SET LECM-REF-OPEN-READ-88 TO TRUE. DTSBE729
|
|
00033 * DTSBE729
|
|
00034 * EDIT AND DEFAULT PARAMETERS. DTSBE729
|
|
00035 * DTSBE729
|
|
00036 * DTSBE729
|
|
00037 * PROCESSING: DTSBE729
|
|
00038 * DTSBE729
|
|
00039 * SEE PRINTED OUTPUTS DESCRIPTION AND LAYOUTS (729R1). DTSBE729
|
|
00040 * DTSBE729
|
|
00041 * DTSBE729
|
|
00042 * TERMINATION: DTSBE729
|
|
00043 * DTSBE729
|
|
00044 * NONE. DTSBE729
|
|
00045 * DTSBE729
|
|
00046 * DTSBE729
|
|
00047 * RECORDS READ: DTSBE729
|
|
00048 * DTSBE729
|
|
00049 * MASTER: DTSBE729
|
|
00050 * DTSBE729
|
|
00051 * MHDR DTSBE729
|
|
00052 * MSOL DTSBE729
|
|
00053 * DTSBE729
|
|
00054 * DTSBE729
|
|
00055 * ALTERNATE INDEX: DTSBE729
|
|
00056 * DTSBE729
|
|
00057 * NONE. DTSBE729
|
|
00058 * DTSBE729
|
|
00059 * DTSBE729
|
|
00060 * REFERENCE: DTSBE729
|
|
00061 * DTSBE729
|
|
00062 * NONE. DTSBE729
|
|
00063 * DTSBE729
|
|
00064 * DTSBE729
|
|
00065 * RECORDS UPDATED: DTSBE729
|
|
00066 * DTSBE729
|
|
00067 * NONE. DTSBE729
|
|
00068 * DTSBE729
|
|
00069 * DTSBE729
|
|
00070 * REPORT RECORDS WRITTEN: DTSBE729
|
|
00071 * DTSBE729
|
|
00072 * R729 ACCOUNTS AVAILABLE FOR PURGE LIST. DTSBE729
|
|
00073 * DTSBE729
|
|
00074 * DTSBE729
|
|
00075 * BATCH TRANSACTION COLLECTION RECORDS WRITTEN: DTSBE729
|
|
00076 * DTSBE729
|
|
00077 * NONE. DTSBE729
|
|
00078 * DTSBE729
|
|
00079 * DTSBE729
|
|
00080 * MODULES CALLED: DTSBE729
|
|
00081 * DTSBE729
|
|
00082 * DTSBU001 DATE EDIT/CONVERSION. CL**2
|
|
00083 * DTSBU910 MASTER FILE I/O. CL**2
|
|
00084 * DTSBU946 VARIABLE LENGTH RECORDS SEQUENTIAL OUTPUT 1. CL**2
|
|
00085 * DTSBE729
|
|
00086 * DTSBE729
|
|
00087 * VERMONT REFERENCE: DTSBE729
|
|
00088 * DTSBE729
|
|
00089 * NONE. DTSBE729
|
|
00090 * DTSBE729
|
|
00091 ***** DTSBE729
|
|
00092 SKIP3 DTSBE729
|
|
00093 ENVIRONMENT DIVISION. DTSBE729
|
|
00094 EJECT DTSBE729
|
|
00095 DATA DIVISION. DTSBE729
|
|
00096 SKIP3 DTSBE729
|
|
00097 WORKING-STORAGE SECTION. DTSBE729
|
|
000975 77 PAN-VALET PICTURE X(24) VALUE '007DTSBE729 03/02/99'. DTSBE729
|
|
00098 SKIP3 DTSBE729
|
|
00099 01 WRK-AREA. DTSBE729
|
|
00100 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +729.DTSBE729
|
|
00101 SKIP1 DTSBE729
|
|
00102 05 WRK-MOD-NAME PIC X(08) VALUE 'DTSBE729'. CL**2
|
|
00103 SKIP3 DTSBE729
|
|
00104 05 ABEND-MSG PIC X(60). DTSBE729
|
|
00105 SKIP3 DTSBE729
|
|
00106 05 WRK-PARM-CUTOFF-DATE PIC S9(09) COMP-3. DTSBE729
|
|
00107 SKIP3 DTSBE729
|
|
00108 05 WRK-CUTOFF-DATE-MINUS-5-YEARS DTSBE729
|
|
00109 PIC S9(09) COMP-3. DTSBE729
|
|
00110 EJECT DTSBE729
|
|
00111 01 L001-LINK-AREA. DTSBE729
|
|
00112 ++INCLUDE DTSIL001 CL**2
|
|
00113 EJECT DTSBE729
|
|
00114 01 L910-LINK-AREA. DTSBE729
|
|
00115 ++INCLUDE DTSIL910 CL**2
|
|
00116 SKIP3 DTSBE729
|
|
00117 01 MSKL-REC. DTSBE729
|
|
00118 ++INCLUDE DTSIMSKL CL**2
|
|
00119 SKIP3 DTSBE729
|
|
00120 01 MHDR-REC. DTSBE729
|
|
00121 ++INCLUDE DTSIMHDR CL**2
|
|
00122 SKIP3 DTSBE729
|
|
00123 01 MSOL-REC. DTSBE729
|
|
00124 ++INCLUDE DTSIMSOL CL**2
|
|
00125 EJECT DTSBE729
|
|
00126 01 R729-REC. DTSBE729
|
|
00127 ++INCLUDE DTSIR729 CL**2
|
|
00128 EJECT DTSBE729
|
|
00129 LINKAGE SECTION. DTSBE729
|
|
00130 SKIP3 DTSBE729
|
|
00131 01 LECM-LINK-AREA. DTSBE729
|
|
00132 ++INCLUDE DTSILECM CL**2
|
|
00133 SKIP3 DTSBE729
|
|
00134 10 FILLER REDEFINES LECM-EXTRACT-PARMS. DTSBE729
|
|
00135 15 LECM-PARM-CUTOFF-DATE PIC X(06). DTSBE729
|
|
00136 15 FILLER PIC X(62). DTSBE729
|
|
00137 EJECT DTSBE729
|
|
00138 01 MPRF-LINK-REC. DTSBE729
|
|
00139 ++INCLUDE DTSIMPRF CL**2
|
|
00140 EJECT DTSBE729
|
|
00141 ************************************************************** DTSBE729
|
|
00142 * PROCEDURE DIVISION FOR DTSBE729 - ACCOUNTS AVAILABLE FOR CL**2
|
|
00143 * PURGE LIST. DTSBE729
|
|
00144 ************************************************************** DTSBE729
|
|
00145 DTSBE729
|
|
00146 PROCEDURE DIVISION USING LECM-LINK-AREA DTSBE729
|
|
00147 MPRF-LINK-REC. DTSBE729
|
|
00148 SKIP2 DTSBE729
|
|
00149 MOVE LENGTH OF R729-REC TO R729-LENGTH. CL**5
|
|
00150 MOVE '729' TO R729-REC-TYPE. CL**5
|
|
00151 SKIP2 CL**5
|
|
00152 IF LECM-PROCESS-88 DTSBE729
|
|
00153 PERFORM P0000-PROCESS THRU P0000-EXIT DTSBE729
|
|
00154 ELSE DTSBE729
|
|
00155 IF LECM-INITIALIZE-88 DTSBE729
|
|
00156 PERFORM I0000-INITIALIZE THRU I0000-EXIT DTSBE729
|
|
00157 ELSE DTSBE729
|
|
00158 IF LECM-TERMINATE-88 DTSBE729
|
|
00159 PERFORM T0000-TERMINATE THRU T0000-EXIT DTSBE729
|
|
00160 ELSE DTSBE729
|
|
00161 MOVE 'INVALID LECM-CALL-TYPE-IND ENCOUNTERED' DTSBE729
|
|
00162 TO ABEND-MSG DTSBE729
|
|
00163 PERFORM S999-ABEND THRU S999-EXIT. DTSBE729
|
|
00164 SKIP2 DTSBE729
|
|
00165 GOBACK. DTSBE729
|
|
00166 EJECT DTSBE729
|
|
00167 ************************************************************** DTSBE729
|
|
00168 * THIS IS THE INITIALIZATION PARAGRAPH FOR DTSBE729. CL**2
|
|
00169 ************************************************************** DTSBE729
|
|
00170 DTSBE729
|
|
00171 I0000-INITIALIZE. DTSBE729
|
|
00172 SKIP2 DTSBE729
|
|
00173 MOVE LECM-TRACE-IND TO L910-TRACE-IND. DTSBE729
|
|
00174 MOVE WRK-MOD-NAME TO L910-MOD-NAME. DTSBE729
|
|
00175 DTSBE729
|
|
00176 PERFORM I1000-EDIT-AND-DEFAULT-PARMS THRU I1000-EXIT. DTSBE729
|
|
00177 DTSBE729
|
|
00178 MOVE WRK-PARM-CUTOFF-DATE TO L001-FED-8-DATE-9. DTSBE729
|
|
00179 SUBTRACT 5 FROM L001-FED-8-YR. DTSBE729
|
|
00180 MOVE L001-FED-8-DATE-9 TO WRK-CUTOFF-DATE-MINUS-5-YEARS. DTSBE729
|
|
00181 DTSBE729
|
|
00182 SET LECM-MST-OPEN-READ-88 TO TRUE. DTSBE729
|
|
00183 SET LECM-REF-OPEN-READ-88 TO TRUE. DTSBE729
|
|
00184 SKIP2 DTSBE729
|
|
00185 I0000-EXIT. DTSBE729
|
|
00186 EXIT. DTSBE729
|
|
00187 SKIP3 DTSBE729
|
|
00188 I1000-EDIT-AND-DEFAULT-PARMS. DTSBE729
|
|
00189 MOVE LOW-VALUES TO MHDR-KEY-AREA. DTSBE729
|
|
00190 MOVE +0 TO MHDR-EMP-NO. DTSBE729
|
|
00191 SET MHDR-HDR-88 TO TRUE. DTSBE729
|
|
00192 MOVE MHDR-KEY-AREA TO MSKL-KEY-AREA. DTSBE729
|
|
00193 PERFORM S910-READ THRU S910-EXIT. DTSBE729
|
|
00194 IF L910-NO-REC-88 DTSBE729
|
|
00195 MOVE 'MHDR RECORD NOT FOUND' TO ABEND-MSG DTSBE729
|
|
00196 PERFORM S999-ABEND THRU S999-EXIT. DTSBE729
|
|
00197 DTSBE729
|
|
00198 MOVE MSKL-REC TO MHDR-REC. DTSBE729
|
|
00199 DTSBE729
|
|
00200 PERFORM I1100-CUTOFF-DATE THRU I1100-EXIT. DTSBE729
|
|
00201 I1000-EXIT. DTSBE729
|
|
00202 EXIT. DTSBE729
|
|
00203 EJECT DTSBE729
|
|
00204 I1100-CUTOFF-DATE. DTSBE729
|
|
00205 IF LECM-PARM-CUTOFF-DATE = SPACES DTSBE729
|
|
00206 MOVE MHDR-CMPL-YEAR-END-DATE DTSBE729
|
|
00207 TO WRK-PARM-CUTOFF-DATE DTSBE729
|
|
00208 MOVE LECM-PRIOR-RUN-DATE TO L001-FED-8-DATE-9 DTSBE729
|
|
00209 IF L001-FED-8-MO = 12 DTSBE729
|
|
00210 MOVE MHDR-CMPL-YEAR-END-DATE TO L001-FED-8-DATE-9 DTSBE729
|
|
00211 ADD +1 TO L001-FED-8-YR DTSBE729
|
|
00212 MOVE L001-FED-8-DATE-9 TO WRK-PARM-CUTOFF-DATE DTSBE729
|
|
00213 ELSE DTSBE729
|
|
00214 NEXT SENTENCE DTSBE729
|
|
00215 ELSE DTSBE729
|
|
00216 MOVE LECM-PARM-CUTOFF-DATE TO L001-CAL-6-DATE-X DTSBE729
|
|
00217 PERFORM S001-FROM-CAL-6 THRU S001-EXIT DTSBE729
|
|
00218 IF L001-VALID-DATE DTSBE729
|
|
00219 MOVE L001-FED-8-DATE-9 TO WRK-PARM-CUTOFF-DATE DTSBE729
|
|
00220 ELSE DTSBE729
|
|
00221 MOVE 'LECM-PARM-CUTOFF-DATE NOT VALID' DTSBE729
|
|
00222 TO ABEND-MSG DTSBE729
|
|
00223 PERFORM S999-ABEND THRU S999-EXIT. DTSBE729
|
|
00224 I1100-EXIT. DTSBE729
|
|
00225 EXIT. DTSBE729
|
|
00226 EJECT DTSBE729
|
|
00227 ************************************************************** DTSBE729
|
|
00228 * THIS IS THE PROCESS PARAGRAPH FOR DTSBE729. CL**2
|
|
00229 ************************************************************** DTSBE729
|
|
00230 DTSBE729
|
|
00231 P0000-PROCESS. DTSBE729
|
|
00232 DTSBE729
|
|
00233 IF MPRF-CLASS-CHG-ONLY-88 DTSBE729
|
|
00234 GO TO P0000-EXIT. DTSBE729
|
|
00235 DTSBE729
|
|
00236 IF MPRF-STATUS-NEVERSUB-88 DTSBE729
|
|
00237 IF MPRF-ESTB-DATE GREATER THAN DTSBE729
|
|
00238 WRK-CUTOFF-DATE-MINUS-5-YEARS DTSBE729
|
|
00239 GO TO P0000-EXIT DTSBE729
|
|
00240 ELSE DTSBE729
|
|
00241 PERFORM P1000-SETUP-R729-NOTSUB THRU P1000-EXIT DTSBE729
|
|
00242 PERFORM S946-WRITE-R729 THRU S946-EXIT DTSBE729
|
|
00243 GO TO P0000-EXIT. DTSBE729
|
|
00244 DTSBE729
|
|
00245 IF MPRF-CLASS-SUB-88 DTSBE729
|
|
00246 PERFORM P2000-FIND-LAST-MSOL THRU P2000-EXIT DTSBE729
|
|
00247 IF MSOL-INACT-DATE GREATER THAN DTSBE729
|
|
00248 WRK-CUTOFF-DATE-MINUS-5-YEARS DTSBE729
|
|
00249 GO TO P0000-EXIT DTSBE729
|
|
00250 ELSE DTSBE729
|
|
00251 PERFORM P3000-SETUP-R729 THRU P3000-EXIT DTSBE729
|
|
00252 PERFORM S946-WRITE-R729 THRU S946-EXIT. DTSBE729
|
|
00253 DTSBE729
|
|
00254 P0000-EXIT. DTSBE729
|
|
00255 EXIT. DTSBE729
|
|
00256 EJECT DTSBE729
|
|
00257 ************************************************************** DTSBE729
|
|
00258 * THIS PARAGRAPH SETS UP THE R729 EXTRACT RECORD FOR DTSBE729
|
|
00259 * EMPLOYERS THAT WERE NEVER SUBJECT, AND THE ESTABLISHED DTSBE729
|
|
00260 * DATE IS OVER FIVE YEARS OLD. DTSBE729
|
|
00261 ************************************************************** DTSBE729
|
|
00262 DTSBE729
|
|
00263 P1000-SETUP-R729-NOTSUB. DTSBE729
|
|
00264 DTSBE729
|
|
00265 MOVE MPRF-EMP-NO TO R729-EMP-NO. DTSBE729
|
|
00266 SET R729-CLASS-NEVER-SUB-88 TO TRUE. DTSBE729
|
|
00267 MOVE MPRF-PRIMARY-NAME TO R729-PRIMARY-NAME. CL**3
|
|
00268 MOVE ZEROS TO R729-LIAB-DATE DTSBE729
|
|
00269 R729-INACT-DATE. DTSBE729
|
|
00270 MOVE MPRF-TOT-BALANCE-AMT TO R729-TOT-BALANCE-AMT. DTSBE729
|
|
00271 MOVE MPRF-TOT-CREDIT-AMT TO R729-TOT-CREDIT-AMT. DTSBE729
|
|
00272 MOVE MPRF-WRITE-OFF-DATE TO R729-WRITE-OFF-DATE. CL**4
|
|
00273 SET R729-NO-PURSUED-RPT-88 TO TRUE. DTSBE729
|
|
00274 DTSBE729
|
|
00275 P1000-EXIT. DTSBE729
|
|
00276 EXIT. DTSBE729
|
|
00277 EJECT DTSBE729
|
|
00278 ************************************************************** DTSBE729
|
|
00279 * THIS PARAGRAPH FINDS THE LAST MSOL RECORD. DTSBE729
|
|
00280 ************************************************************** DTSBE729
|
|
00281 DTSBE729
|
|
00282 P2000-FIND-LAST-MSOL. DTSBE729
|
|
00283 DTSBE729
|
|
00284 MOVE LOW-VALUES TO MSOL-KEY-AREA. DTSBE729
|
|
00285 MOVE MPRF-EMP-NO TO MSOL-EMP-NO. DTSBE729
|
|
00286 SET MSOL-SOL-88 TO TRUE. DTSBE729
|
|
00287 MOVE MSOL-KEY-AREA TO MSKL-KEY-AREA. DTSBE729
|
|
00288 DTSBE729
|
|
00289 PERFORM S910-COUNT THRU S910-EXIT. DTSBE729
|
|
00290 DTSBE729
|
|
00291 MOVE ZEROS TO MSOL-LIAB-DATE DTSBE729
|
|
00292 MSOL-INACT-DATE. DTSBE729
|
|
00293 DTSBE729
|
|
00294 IF L910-RECORD-CNT GREATER THAN ZERO DTSBE729
|
|
00295 PERFORM S910-READ THRU S910-EXIT DTSBE729
|
|
00296 IF L910-OK-88 DTSBE729
|
|
00297 MOVE MSKL-REC TO MSOL-REC. DTSBE729
|
|
00298 DTSBE729
|
|
00299 P2000-EXIT. DTSBE729
|
|
00300 EXIT. DTSBE729
|
|
00301 EJECT DTSBE729
|
|
00302 ************************************************************** DTSBE729
|
|
00303 * THIS PARAGRAPH SETS UP THE R729 EXTRACT RECORD FOR DTSBE729
|
|
00304 * EMPLOYERS WHO WERE LIABLE BUT HAVE BEEN INACTIVE FOR DTSBE729
|
|
00305 * OVER 5 YEARS. DTSBE729
|
|
00306 ************************************************************** DTSBE729
|
|
00307 DTSBE729
|
|
00308 P3000-SETUP-R729. DTSBE729
|
|
00309 DTSBE729
|
|
00310 MOVE MPRF-EMP-NO TO R729-EMP-NO. DTSBE729
|
|
00311 DTSBE729
|
|
00312 IF MPRF-CLASS-RATED-88 CL**7
|
|
00313 SET R729-CLASS-RATED-88 TO TRUE CL**7
|
|
00314 ELSE CL**7
|
|
00315 SET R729-CLASS-SELF-INS-88 TO TRUE. CL**7
|
|
00316 DTSBE729
|
|
00317 MOVE MPRF-PRIMARY-NAME TO R729-PRIMARY-NAME. CL**3
|
|
00318 MOVE MSOL-LIAB-DATE TO R729-LIAB-DATE. DTSBE729
|
|
00319 MOVE MSOL-INACT-DATE TO R729-INACT-DATE. DTSBE729
|
|
00320 MOVE MPRF-TOT-BALANCE-AMT TO R729-TOT-BALANCE-AMT. DTSBE729
|
|
00321 MOVE MPRF-TOT-CREDIT-AMT TO R729-TOT-CREDIT-AMT. DTSBE729
|
|
00322 MOVE MPRF-WRITE-OFF-DATE TO R729-WRITE-OFF-DATE. CL**4
|
|
00323 DTSBE729
|
|
00324 IF MPRF-PURSUED-RPT-CNT GREATER THAN ZERO DTSBE729
|
|
00325 SET R729-PURSUED-RPT-EXISTS-88 DTSBE729
|
|
00326 TO TRUE DTSBE729
|
|
00327 ELSE DTSBE729
|
|
00328 SET R729-NO-PURSUED-RPT-88 TO TRUE. DTSBE729
|
|
00329 DTSBE729
|
|
00330 P3000-EXIT. DTSBE729
|
|
00331 EXIT. DTSBE729
|
|
00332 EJECT DTSBE729
|
|
00333 T0000-TERMINATE. DTSBE729
|
|
00334 SKIP2 DTSBE729
|
|
00335 SKIP2 DTSBE729
|
|
00336 T0000-EXIT. DTSBE729
|
|
00337 EXIT. DTSBE729
|
|
00338 EJECT DTSBE729
|
|
00339 S001-FROM-FED-8. DTSBE729
|
|
00340 SET L001-FROM-FED-8 TO TRUE. DTSBE729
|
|
00341 GO TO S001-DATE. DTSBE729
|
|
00342 SKIP1 DTSBE729
|
|
00343 S001-FROM-ABS-DAY. DTSBE729
|
|
00344 SET L001-FROM-ABS-DAY TO TRUE. DTSBE729
|
|
00345 GO TO S001-DATE. DTSBE729
|
|
00346 SKIP1 DTSBE729
|
|
00347 S001-FROM-CAL-6. DTSBE729
|
|
00348 SET L001-FROM-CAL-6 TO TRUE. DTSBE729
|
|
00349 GO TO S001-DATE. DTSBE729
|
|
00350 SKIP1 DTSBE729
|
|
00351 S001-DATE. DTSBE729
|
|
00352 CALL 'DTSBU001' USING L001-LINK-AREA. CL**2
|
|
00353 S001-EXIT. DTSBE729
|
|
00354 EXIT. DTSBE729
|
|
00355 SKIP3 DTSBE729
|
|
00356 S910-READ. DTSBE729
|
|
00357 SET L910-READ-88 TO TRUE. DTSBE729
|
|
00358 GO TO S910-MSTR-IO. DTSBE729
|
|
00359 SKIP1 DTSBE729
|
|
00360 S910-START-BROWSE. DTSBE729
|
|
00361 SET L910-START-BROWSE-88 TO TRUE. DTSBE729
|
|
00362 GO TO S910-MSTR-IO. DTSBE729
|
|
00363 SKIP1 DTSBE729
|
|
00364 S910-READ-NEXT. DTSBE729
|
|
00365 SET L910-READ-NEXT-88 TO TRUE. DTSBE729
|
|
00366 GO TO S910-MSTR-IO. DTSBE729
|
|
00367 SKIP1 DTSBE729
|
|
00368 S910-COUNT. DTSBE729
|
|
00369 SET L910-COUNT-88 TO TRUE. DTSBE729
|
|
00370 GO TO S910-MSTR-IO. DTSBE729
|
|
00371 SKIP1 DTSBE729
|
|
00372 S910-MSTR-IO. DTSBE729
|
|
00373 CALL 'DTSBU910' USING L910-LINK-AREA CL**2
|
|
00374 MSKL-REC. DTSBE729
|
|
00375 S910-EXIT. DTSBE729
|
|
00376 EXIT. DTSBE729
|
|
00377 SKIP3 DTSBE729
|
|
00378 S946-WRITE-R729. DTSBE729
|
|
00379 CALL 'DTSBU946' USING R729-REC. CL**2
|
|
00380 GO TO S946-EXIT. DTSBE729
|
|
00381 SKIP1 DTSBE729
|
|
00382 S946-EXIT. DTSBE729
|
|
00383 EXIT. DTSBE729
|
|
00384 SKIP3 DTSBE729
|
|
00385 S999-ABEND. DTSBE729
|
|
00386 DISPLAY '*** DTSBE729 ABENDING. ' CL**2
|
|
00387 ABEND-MSG. DTSBE729
|
|
00388 SKIP1 DTSBE729
|
|
00389 CALL 'DTSBU999' USING WRK-ABEND-CD. CL**2
|
|
00390 S999-EXIT. DTSBE729
|
|
00391 EXIT. DTSBE729
|