388 lines
31 KiB
COBOL
388 lines
31 KiB
COBOL
00001 IDENTIFICATION DIVISION. 11/21/01
|
|
00002 PROGRAM-ID. DTSBR411. DTSBR411
|
|
00003 AUTHOR. TRICOASTAL CONSULTING LTD LV006
|
|
00004 MODIFIED BY TRW S&ITG. DTSBR411
|
|
00005 DATE-WRITTEN. DECEMBER 1994. DTSBR411
|
|
00006 DATE-COMPILED. DTSBR411
|
|
00007 DTSBR411
|
|
00008 ***** DTSBR411
|
|
00009 * DTSBR411
|
|
00010 * CALLING SEQUENCE: DTSBE411 CREATES DTSIR411 RECORDS. DTSBR411
|
|
00011 * DTSBD800 CALLS DTSBR411 DTSBR411
|
|
00012 * WHICH PRODUCES THE REPORT. DTSBR411
|
|
00013 * DTSBR411
|
|
00014 * FUNCTION: OPEN BANKRUPTCIES LIST. DTSBR411
|
|
00015 * DTSBR411
|
|
00016 * DTSBR411
|
|
00017 * MODIFICATION HISTORY: DTSBR411
|
|
00018 * DTSBR411
|
|
00019 * 12-20-94 INITIAL DEVELOPMENT DTSBR411
|
|
00020 * REFERENCE RFP #RAP AUTHOR OF CHANGE - RHC DTSBR411
|
|
00021 * DTSBR411
|
|
00022 * 03-29-95 MODIFY FOR DUPLEX. DTSBR411
|
|
00023 * REFERENCE RFP #CR056 AUTHOR OF CHANGE - RHC DTSBR411
|
|
00024 * DTSBR411
|
|
00025 * MM-DD-YY XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR411
|
|
00026 * XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX DTSBR411
|
|
00027 * REFERENCE RFP #**** AUTHOR OF CHANGE - XXX DTSBR411
|
|
00028 * DTSBR411
|
|
00029 * DTSBR411
|
|
00030 * DESCRIPTION: DTSBR411
|
|
00031 * DTSBR411
|
|
00032 * THIS MODULE PRODUCES THE OPEN BANKRUPTCIES LIST. DTSBR411
|
|
00033 * DTSBR411
|
|
00034 * DTSBR411
|
|
00035 * RECORDS READ: DTSBR411
|
|
00036 * DTSBR411
|
|
00037 * NONE. DTSBR411
|
|
00038 * DTSBR411
|
|
00039 * DTSBR411
|
|
00040 * PRINTED OUTPUTS: DTSBR411
|
|
00041 * DTSBR411
|
|
00042 * 411R1 OPEN BANKRUPTCIES LIST. DTSBR411
|
|
00043 * DTSBR411
|
|
00044 * DTSBR411
|
|
00045 * RECORDS WRITTEN: DTSBR411
|
|
00046 * DTSBR411
|
|
00047 * NONE. DTSBR411
|
|
00048 * DTSBR411
|
|
00049 * DTSBR411
|
|
00050 * MODULES CALLED: DTSBR411
|
|
00051 * DTSBR411
|
|
00052 * DTSBU001 DATE CONVERT. DTSBR411
|
|
00053 * DTSBR411
|
|
00054 * DTSBR411
|
|
00055 ***** DTSBR411
|
|
00056 EJECT DTSBR411
|
|
00057 ENVIRONMENT DIVISION. DTSBR411
|
|
00058 DTSBR411
|
|
00059 CONFIGURATION SECTION. DTSBR411
|
|
00060 SPECIAL-NAMES. C01 IS TOP-OF-PAGE. DTSBR411
|
|
00061 DTSBR411
|
|
00062 INPUT-OUTPUT SECTION. DTSBR411
|
|
00063 FILE-CONTROL. DTSBR411
|
|
00064 SELECT PRT-FILE ASSIGN TO RPT411R1. DTSBR411
|
|
00065 DTSBR411
|
|
00066 DATA DIVISION. DTSBR411
|
|
00067 FILE SECTION. DTSBR411
|
|
00068 DTSBR411
|
|
00069 FD PRT-FILE DTSBR411
|
|
00070 RECORDING MODE IS F. DTSBR411
|
|
00071 01 PRT-RECORD PIC X(133). DTSBR411
|
|
00072 DTSBR411
|
|
00073 EJECT DTSBR411
|
|
00074 WORKING-STORAGE SECTION. DTSBR411
|
|
000745 77 PAN-VALET PICTURE X(24) VALUE '006DTSBR411 11/21/01'. DTSBR411
|
|
00075 SKIP3 DTSBR411
|
|
00076 01 WRK-AREA. DTSBR411
|
|
00077 05 WRK-ABEND-CD PIC S9(04) COMP VALUE +411.DTSBR411
|
|
00078 05 FIRST-TIME-IND PIC X(01) VALUE 'Y'. DTSBR411
|
|
00079 05 FIRST-PAGE-IND PIC X(01) VALUE 'Y'. DTSBR411
|
|
00080 DTSBR411
|
|
00081 05 WS-FIELD-REP-ID PIC X(02) VALUE SPACES. DTSBR411
|
|
00082 05 WS-BLANK-LINE PIC X(133) VALUE SPACES. DTSBR411
|
|
00083 05 WRK-PAGE-TRUNCATE PIC 9(01). DTSBR411
|
|
00084 88 WRK-ODD-PAGE-88 VALUE 1 3 5 7 9. DTSBR411
|
|
00085 DTSBR411
|
|
00086 05 WS-NUMBER-ONE PIC S9(03) COMP-3 VALUE +0. DTSBR411
|
|
00087 05 WS-FOOT-NUMBER-ONE PIC S9(05) COMP-3 VALUE +0. DTSBR411
|
|
00088 05 WS-FOOT-NUMBER-TWO PIC S9(05) COMP-3 VALUE +0. DTSBR411
|
|
00089 05 WS-LINE-CNT PIC S9(02) COMP-3 VALUE 60. DTSBR411
|
|
00090 05 WS-LINE-CNT2 PIC S9(02) COMP-3 VALUE +0. DTSBR411
|
|
00091 05 WS-PAGE-CNT PIC S9(05) COMP-3 VALUE +0. DTSBR411
|
|
00092 DTSBR411
|
|
00093 01 L001-LINK-AREA. DTSBR411
|
|
00094 ++INCLUDE DTSIL001 DTSBR411
|
|
00095 EJECT DTSBR411
|
|
00096 DTSBR411
|
|
00097 01 PAGE-HEADING. DTSBR411
|
|
00098 05 HDR-LINE-1. DTSBR411
|
|
00099 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00100 10 FILLER PIC X(05) DTSBR411
|
|
00101 VALUE '411R1'. DTSBR411
|
|
00102 10 FILLER PIC X(35) VALUE SPACES.DTSBR411
|
|
00103 10 HDR-AGY-NAME-LINE1 PIC X(50). DTSBR411
|
|
00104 10 FILLER PIC X(27) VALUE SPACES.DTSBR411
|
|
00105 10 FILLER PIC X(05) DTSBR411
|
|
00106 VALUE 'DATE:'. DTSBR411
|
|
00107 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00108 10 HDR-SYS-DATE PIC X(08). DTSBR411
|
|
00109 05 HDR-LINE-2. DTSBR411
|
|
00110 10 FILLER PIC X(41) VALUE SPACES.DTSBR411
|
|
00111 10 HDR-AGY-NAME-LINE2 PIC X(50). DTSBR411
|
|
00112 10 FILLER PIC X(27) VALUE SPACES.DTSBR411
|
|
00113 10 FILLER PIC X(05) DTSBR411
|
|
00114 VALUE 'TIME:'. DTSBR411
|
|
00115 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00116 10 HDR-SYS-TIME PIC X(08). DTSBR411
|
|
00117 05 HDR-LINE-3. DTSBR411
|
|
00118 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00119 10 FILLER PIC X(35) DTSBR411
|
|
00120 VALUE 'ROUTE TO: ENFORCEMENT UNIT'. DTSBR411
|
|
00121 10 FILLER PIC X(19) VALUE SPACES.DTSBR411
|
|
00122 10 FILLER PIC X(22) DTSBR411
|
|
00123 VALUE 'OPEN BANKRUPTCIES LIST'. DTSBR411
|
|
00124 10 FILLER PIC X(41) VALUE SPACES.DTSBR411
|
|
00125 10 FILLER PIC X(05) DTSBR411
|
|
00126 VALUE 'PAGE:'. DTSBR411
|
|
00127 10 FILLER PIC X(03) VALUE SPACES.DTSBR411
|
|
00128 10 HDR-PAGE-CNT PIC ZZ,ZZ9. DTSBR411
|
|
00129 05 HDR-LINE-4 PIC X(133) VALUE SPACES.DTSBR411
|
|
00130 05 HDR-LINE-5 PIC X(133) VALUE SPACES.DTSBR411
|
|
00131 05 HDR-LINE-6. DTSBR411
|
|
00132 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00133 10 FILLER PIC X(15) DTSBR411
|
|
00134 VALUE 'FIELD REP CODE:'. DTSBR411
|
|
00135 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00136 10 HDR-FIELD-REP-ID PIC X(02). DTSBR411
|
|
00137 10 FILLER PIC X(101) VALUE SPACES.DTSBR411
|
|
00138 05 HDR-LINE-7 PIC X(133) VALUE SPACES.DTSBR411
|
|
00139 05 HDR-LINE-8. DTSBR411
|
|
00140 10 FILLER PIC X(84) VALUE SPACES.DTSBR411
|
|
00141 10 FILLER PIC X(08) DTSBR411
|
|
00142 VALUE 'PETITION'. DTSBR411
|
|
00143 10 FILLER PIC X(04) VALUE SPACES.DTSBR411
|
|
00144 10 FILLER PIC X(08) DTSBR411
|
|
00145 VALUE 'PROOF OF'. DTSBR411
|
|
00146 10 FILLER PIC X(07) VALUE SPACES.DTSBR411
|
|
00147 10 FILLER PIC X(03) DTSBR411
|
|
00148 VALUE 'PCC'. DTSBR411
|
|
00149 10 FILLER PIC X(04) DTSBR411
|
|
00150 VALUE 'LAST'. DTSBR411
|
|
00151 05 HDR-LINE-9. DTSBR411
|
|
00152 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00153 10 FILLER PIC X(06) DTSBR411
|
|
00154 VALUE 'EMP NO'. DTSBR411
|
|
00155 10 FILLER PIC X(07) VALUE SPACES.DTSBR411
|
|
00156 10 FILLER PIC X(13) DTSBR411
|
|
00157 VALUE 'PRIMARY NAME'. DTSBR411
|
|
00158 10 FILLER PIC X(27) VALUE SPACES.DTSBR411
|
|
00159 10 FILLER PIC X(07) DTSBR411
|
|
00160 VALUE 'CHAPTER'. DTSBR411
|
|
00161 10 FILLER PIC X(07) VALUE SPACES.DTSBR411
|
|
00162 10 FILLER PIC X(07) DTSBR411
|
|
00163 VALUE 'CASE NO'. DTSBR411
|
|
00164 10 FILLER PIC X(11) VALUE SPACES.DTSBR411
|
|
00165 10 FILLER PIC X(04) DTSBR411
|
|
00166 VALUE 'DATE'. DTSBR411
|
|
00167 10 FILLER PIC X(05) VALUE SPACES.DTSBR411
|
|
00168 10 FILLER PIC X(10) DTSBR411
|
|
00169 VALUE 'CLAIM DATE'. DTSBR411
|
|
00170 10 FILLER PIC X(04) VALUE SPACES.DTSBR411
|
|
00171 10 FILLER PIC X(08) DTSBR411
|
|
00172 VALUE 'REQUIRED'. DTSBR411
|
|
00173 10 FILLER PIC X(02) VALUE SPACES.DTSBR411
|
|
00174 10 FILLER PIC X(13) DTSBR411
|
|
00175 VALUE 'COMMUNICATION'. DTSBR411
|
|
00176 DTSBR411
|
|
00177 01 DETAIL-LINE. DTSBR411
|
|
00178 05 DTL-LINE-2. DTSBR411
|
|
00179 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00180 10 DTL-EMP-NO PIC 999B999. DTSBR411
|
|
00181 10 FILLER PIC X(06) VALUE SPACES.DTSBR411
|
|
00182 10 DTL-PRIMARY-NAME PIC X(40). DTSBR411
|
|
00183 10 FILLER PIC X(03) VALUE SPACES.DTSBR411
|
|
00184 10 DTL-BNK-CHAPTER PIC X(02). DTSBR411
|
|
00185 10 FILLER PIC X(05) VALUE SPACES.DTSBR411
|
|
00186 10 DTL-BNK-COURT-CASE-NO PIC X(15). DTSBR411
|
|
00187 10 FILLER PIC X(05) VALUE SPACES.DTSBR411
|
|
00188 10 WRK-PETITION-DATE PIC X(08). DTSBR411
|
|
00189 10 FILLER PIC X(04) VALUE SPACES.DTSBR411
|
|
00190 10 WRK-POC-FILED-DATE PIC X(08). DTSBR411
|
|
00191 10 FILLER PIC X(05) VALUE SPACES.DTSBR411
|
|
00192 10 WRK-POC-REQUIRED-DATE PIC X(08). DTSBR411
|
|
00193 10 FILLER PIC X(05) VALUE SPACES.DTSBR411
|
|
00194 10 WRK-LAST-COMM PIC X(08). DTSBR411
|
|
00195 DTSBR411
|
|
00196 01 CONTROL-FOOTING. DTSBR411
|
|
00197 05 CTF-LINE-3. DTSBR411
|
|
00198 10 FILLER PIC X(19) VALUE SPACES.DTSBR411
|
|
00199 10 CTF-FOOT-CNT PIC ZZ,ZZ9. DTSBR411
|
|
00200 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00201 10 FILLER PIC X(29) DTSBR411
|
|
00202 VALUE 'OPEN BANKRUPTCIES LISTED FOR '. DTSBR411
|
|
00203 10 FILLER PIC X(15) DTSBR411
|
|
00204 VALUE 'THIS FIELD REP '. DTSBR411
|
|
00205 DTSBR411
|
|
00206 01 CONTROL-FOOTING-FINAL. DTSBR411
|
|
00207 05 CFF-LINE-2. DTSBR411
|
|
00208 10 FILLER PIC X(19) VALUE SPACES.DTSBR411
|
|
00209 10 CFF-SUM-CNT PIC ZZ,ZZ9. DTSBR411
|
|
00210 10 FILLER PIC X(01) VALUE SPACE. DTSBR411
|
|
00211 10 FILLER PIC X(34) DTSBR411
|
|
00212 VALUE 'OPEN BANKRUPTCIES LISTED ON REPORT'. DTSBR411
|
|
00213 EJECT DTSBR411
|
|
00214 LINKAGE SECTION. DTSBR411
|
|
00215 SKIP3 DTSBR411
|
|
00216 01 LRCM-LINK-AREA. DTSBR411
|
|
00217 ++INCLUDE DTSILRCM DTSBR411
|
|
00218 EJECT DTSBR411
|
|
00219 01 R411-REC. DTSBR411
|
|
00220 ++INCLUDE DTSIR411 DTSBR411
|
|
00221 EJECT DTSBR411
|
|
00222 PROCEDURE DIVISION USING LRCM-LINK-AREA DTSBR411
|
|
00223 R411-REC. DTSBR411
|
|
00224 IF FIRST-TIME-IND = 'Y' DTSBR411
|
|
00225 PERFORM I1000-INITIATE THRU I1000-EXIT DTSBR411
|
|
00226 MOVE 'N' TO FIRST-TIME-IND. DTSBR411
|
|
00227 DTSBR411
|
|
00228 IF LRCM-EOR-88 DTSBR411
|
|
00229 PERFORM T1000-TERMINATE THRU T1000-EXIT DTSBR411
|
|
00230 ELSE DTSBR411
|
|
00231 PERFORM P1000-PROCESS THRU P1000-EXIT. DTSBR411
|
|
00232 DTSBR411
|
|
00233 GOBACK. DTSBR411
|
|
00234 EJECT DTSBR411
|
|
00235 I1000-INITIATE. DTSBR411
|
|
00236 DTSBR411
|
|
00237 OPEN OUTPUT PRT-FILE. DTSBR411
|
|
00238 MOVE LRCM-SYS-DATE TO HDR-SYS-DATE. DTSBR411
|
|
00239 MOVE LRCM-SYS-TIME TO HDR-SYS-TIME. DTSBR411
|
|
00240 MOVE LRCM-AGY-NAME-LINE1 TO HDR-AGY-NAME-LINE1. DTSBR411
|
|
00241 MOVE LRCM-AGY-NAME-LINE2 TO HDR-AGY-NAME-LINE2. DTSBR411
|
|
00242 MOVE SPACES TO PRT-RECORD. DTSBR411
|
|
00243 DTSBR411
|
|
00244 I1000-EXIT. DTSBR411
|
|
00245 EXIT. DTSBR411
|
|
00246 DTSBR411
|
|
00247 P1000-PROCESS. DTSBR411
|
|
00248 DTSBR411
|
|
00249 IF R411-FIELD-REP-ID NOT = WS-FIELD-REP-ID DTSBR411
|
|
00250 IF WS-NUMBER-ONE = +0 DTSBR411
|
|
00251 MOVE +99 TO WS-NUMBER-ONE DTSBR411
|
|
00252 ELSE DTSBR411
|
|
00253 PERFORM P3000-PRINT-FOOTER THRU P3000-EXIT DTSBR411
|
|
00254 MOVE +60 TO WS-LINE-CNT2 DTSBR411
|
|
00255 MOVE +0 TO WS-PAGE-CNT DTSBR411
|
|
00256 END-IF DTSBR411
|
|
00257 END-IF. DTSBR411
|
|
00258 DTSBR411
|
|
00259 MOVE R411-FIELD-REP-ID TO WS-FIELD-REP-ID. DTSBR411
|
|
00260 MOVE R411-FIELD-REP-ID TO HDR-FIELD-REP-ID. DTSBR411
|
|
00261 DTSBR411
|
|
00262 MOVE R411-BNK-PETITION-DATE TO L001-FED-8-DATE-9. DTSBR411
|
|
00263 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBR411
|
|
00264 IF L001-VALID-DATE DTSBR411
|
|
00265 MOVE L001-SLASH-DATE TO WRK-PETITION-DATE. DTSBR411
|
|
00266 DTSBR411
|
|
00267 MOVE R411-BNK-POC-FILED-DATE TO L001-FED-8-DATE-9. DTSBR411
|
|
00268 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBR411
|
|
00269 IF L001-VALID-DATE DTSBR411
|
|
00270 MOVE L001-SLASH-DATE TO WRK-POC-FILED-DATE. DTSBR411
|
|
00271 DTSBR411
|
|
00272 MOVE R411-BNK-POC-REQUIRED-DATE TO L001-FED-8-DATE-9. DTSBR411
|
|
00273 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBR411
|
|
00274 IF L001-VALID-DATE DTSBR411
|
|
00275 MOVE L001-SLASH-DATE TO WRK-POC-REQUIRED-DATE. DTSBR411
|
|
00276 DTSBR411
|
|
00277 MOVE R411-BNK-LAST-COMM TO L001-FED-8-DATE-9. DTSBR411
|
|
00278 PERFORM S001-FROM-FED-8 THRU S001-EXIT. DTSBR411
|
|
00279 IF L001-VALID-DATE DTSBR411
|
|
00280 MOVE L001-SLASH-DATE TO WRK-LAST-COMM. DTSBR411
|
|
00281 DTSBR411
|
|
00282 MOVE R411-EMP-NO TO DTL-EMP-NO. DTSBR411
|
|
00283 MOVE R411-PRIMARY-NAME TO DTL-PRIMARY-NAME. DTSBR411
|
|
00284 MOVE R411-BNK-CHAPTER TO DTL-BNK-CHAPTER. DTSBR411
|
|
00285 MOVE R411-BNK-COURT-CASE-NO TO DTL-BNK-COURT-CASE-NO. DTSBR411
|
|
00286 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT. DTSBR411
|
|
00287 WRITE PRT-RECORD FROM DTL-LINE-2 AFTER 2. DTSBR411
|
|
00288 ADD +2 TO WS-LINE-CNT2. DTSBR411
|
|
00289 ADD +1 TO WS-FOOT-NUMBER-ONE. DTSBR411
|
|
00290 ADD +1 TO WS-FOOT-NUMBER-TWO. DTSBR411
|
|
00291 DTSBR411
|
|
00292 P1000-EXIT. DTSBR411
|
|
00293 EXIT. DTSBR411
|
|
00294 DTSBR411
|
|
00295 P2000-PRINT-HEADER. DTSBR411
|
|
00296 DTSBR411
|
|
00297 IF WS-LINE-CNT GREATER 58 OR DTSBR411
|
|
00298 WS-LINE-CNT2 GREATER 58 DTSBR411
|
|
00299 MOVE +0 TO WS-LINE-CNT DTSBR411
|
|
00300 MOVE +0 TO WS-LINE-CNT2 DTSBR411
|
|
00301 ADD +1 TO WS-PAGE-CNT DTSBR411
|
|
00302 MOVE WS-PAGE-CNT TO HDR-PAGE-CNT DTSBR411
|
|
00303 WRITE PRT-RECORD FROM HDR-LINE-1 AFTER TOP-OF-PAGE DTSBR411
|
|
00304 WRITE PRT-RECORD FROM HDR-LINE-2 AFTER 1 DTSBR411
|
|
00305 WRITE PRT-RECORD FROM HDR-LINE-3 AFTER 1 DTSBR411
|
|
00306 WRITE PRT-RECORD FROM HDR-LINE-4 AFTER 1 DTSBR411
|
|
00307 WRITE PRT-RECORD FROM HDR-LINE-5 AFTER 1 DTSBR411
|
|
00308 WRITE PRT-RECORD FROM HDR-LINE-6 AFTER 1 DTSBR411
|
|
00309 WRITE PRT-RECORD FROM HDR-LINE-7 AFTER 1 DTSBR411
|
|
00310 WRITE PRT-RECORD FROM HDR-LINE-8 AFTER 1 DTSBR411
|
|
00311 WRITE PRT-RECORD FROM HDR-LINE-9 AFTER 1 DTSBR411
|
|
00312 ADD +9 TO WS-LINE-CNT2. DTSBR411
|
|
00313 P2000-EXIT. DTSBR411
|
|
00314 EXIT. DTSBR411
|
|
00315 DTSBR411
|
|
00316 P3000-PRINT-FOOTER. DTSBR411
|
|
00317 IF WS-LINE-CNT2 > 52 DTSBR411
|
|
00318 ADD +6 TO WS-LINE-CNT2 DTSBR411
|
|
00319 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR411
|
|
00320 END-IF. DTSBR411
|
|
00321 DTSBR411
|
|
00322 MOVE WS-FOOT-NUMBER-ONE TO CTF-FOOT-CNT. DTSBR411
|
|
00323 WRITE PRT-RECORD FROM CTF-LINE-3 AFTER 3. DTSBR411
|
|
00324 MOVE +0 TO WS-FOOT-NUMBER-ONE. DTSBR411
|
|
00325 DTSBR411
|
|
00326 MOVE WS-PAGE-CNT TO WRK-PAGE-TRUNCATE. DTSBR411
|
|
00327 IF WRK-ODD-PAGE-88 DTSBR411
|
|
00328 WRITE PRT-RECORD FROM WS-BLANK-LINE DTSBR411
|
|
00329 AFTER TOP-OF-PAGE DTSBR411
|
|
00330 WRITE PRT-RECORD FROM WS-BLANK-LINE AFTER 58 DTSBR411
|
|
00331 ADD +60 TO WS-LINE-CNT2 DTSBR411
|
|
00332 MOVE +0 TO WS-PAGE-CNT DTSBR411
|
|
00333 END-IF. DTSBR411
|
|
00334 DTSBR411
|
|
00335 P3000-EXIT. DTSBR411
|
|
00336 EXIT. DTSBR411
|
|
00337 DTSBR411
|
|
00338 T1000-TERMINATE. DTSBR411
|
|
00339 DTSBR411
|
|
00340 IF WS-LINE-CNT2 > 52 DTSBR411
|
|
00341 ADD +6 TO WS-LINE-CNT2 DTSBR411
|
|
00342 PERFORM P2000-PRINT-HEADER THRU P2000-EXIT DTSBR411
|
|
00343 END-IF. DTSBR411
|
|
00344 DTSBR411
|
|
00345 ADD +1 TO WS-FOOT-NUMBER-ONE. DTSBR411
|
|
00346 MOVE WS-FOOT-NUMBER-ONE TO CTF-FOOT-CNT. DTSBR411
|
|
00347 MOVE WS-FOOT-NUMBER-TWO TO CFF-SUM-CNT. DTSBR411
|
|
00348 WRITE PRT-RECORD FROM CTF-LINE-3 AFTER 3. DTSBR411
|
|
00349 DTSBR411
|
|
00350 MOVE WS-PAGE-CNT TO WRK-PAGE-TRUNCATE. DTSBR411
|
|
00351 IF WRK-ODD-PAGE-88 DTSBR411
|
|
00352 WRITE PRT-RECORD FROM WS-BLANK-LINE DTSBR411
|
|
00353 AFTER TOP-OF-PAGE DTSBR411
|
|
00354 END-IF. DTSBR411
|
|
00355 DTSBR411
|
|
00356 MOVE +1 TO WS-PAGE-CNT DTSBR411
|
|
00357 MOVE WS-PAGE-CNT TO HDR-PAGE-CNT DTSBR411
|
|
00358 WRITE PRT-RECORD FROM HDR-LINE-1 AFTER TOP-OF-PAGE DTSBR411
|
|
00359 WRITE PRT-RECORD FROM HDR-LINE-2 AFTER 1 DTSBR411
|
|
00360 WRITE PRT-RECORD FROM HDR-LINE-3 AFTER 1 DTSBR411
|
|
00361 WRITE PRT-RECORD FROM HDR-LINE-4 AFTER 1 DTSBR411
|
|
00362 WRITE PRT-RECORD FROM HDR-LINE-5 AFTER 1 DTSBR411
|
|
00363 DTSBR411
|
|
00364 WRITE PRT-RECORD FROM CFF-LINE-2 AFTER 3. DTSBR411
|
|
00365 DTSBR411
|
|
00366 CLOSE PRT-FILE. DTSBR411
|
|
00367 DTSBR411
|
|
00368 T1000-EXIT. DTSBR411
|
|
00369 EXIT. DTSBR411
|
|
00370 DTSBR411
|
|
00371 S001-FROM-FED-8. DTSBR411
|
|
00372 DTSBR411
|
|
00373 SET L001-FROM-FED-8 TO TRUE. DTSBR411
|
|
00374 DTSBR411
|
|
00375 CALL 'DTSBU001' USING L001-LINK-AREA. DTSBR411
|
|
00376 DTSBR411
|
|
00377 S001-EXIT. DTSBR411
|
|
00378 EXIT. DTSBR411
|
|
00379 DTSBR411
|
|
00380 *S999-ABEND. DTSBR411
|
|
00381 * DTSBR411
|
|
00382 * CALL 'DTSBU999' USING WRK-ABEND-CD. DTSBR411
|
|
00383 * DTSBR411
|
|
00384 *S999-EXIT. DTSBR411
|
|
00385 * EXIT. DTSBR411
|
|
00386 DTSBR411
|